src/login/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 systemd_logind_sources = files(
   4         'logind.c',
   5 )
   6
   7 logind_gperf_c = custom_target(
   8         'logind_gperf.c',
   9         input : 'logind-gperf.gperf',
  10         output : 'logind-gperf.c',
  11         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  12
  13 liblogind_core_sources = files(
  14         'logind-action.c',
  15         'logind-brightness.c',
  16         'logind-button.c',
  17         'logind-core.c',
  18         'logind-dbus.c',
  19         'logind-device.c',
  20         'logind-inhibit.c',
  21         'logind-polkit.c',
  22         'logind-seat-dbus.c',
  23         'logind-seat.c',
  24         'logind-session-dbus.c',
  25         'logind-session-device.c',
  26         'logind-session.c',
  27         'logind-user-dbus.c',
  28         'logind-user.c',
  29         'logind-utmp.c',
  30 )
  31
  32 liblogind_core_sources += [logind_gperf_c]
  33
  34 liblogind_core = static_library(
  35         'logind-core',
  36         liblogind_core_sources,
  37         include_directories : includes,
  38         dependencies : libacl,
  39         build_by_default : false)
  40
  41 loginctl_sources = files(
  42         'loginctl.c',
  43         'sysfs-show.c',
  44 )
  45
  46 user_runtime_dir_sources = files('user-runtime-dir.c')
  47
  48 pam_systemd_sym = 'src/login/pam_systemd.sym'
  49 pam_systemd_c = files('pam_systemd.c')
  50
  51 enable_logind = conf.get('ENABLE_LOGIND') == 1
  52
  53 custom_target(
  54         'logind.conf',
  55         input : 'logind.conf.in',
  56         output : 'logind.conf',
  57         command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
  58         install : enable_logind and install_sysconfdir_samples and pkgsysconfdir != 'no',
  59         install_dir : pkgsysconfdir)
  60
  61 custom_target(
  62         'systemd-user',
  63         input : 'systemd-user.in',
  64         output : 'systemd-user',
  65         command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
  66         install : enable_logind and pamconfdir != 'no',
  67         install_dir : pamconfdir)
  68
  69 if enable_logind
  70         install_data('org.freedesktop.login1.conf',
  71                      install_dir : dbuspolicydir)
  72         install_data('org.freedesktop.login1.service',
  73                      install_dir : dbussystemservicedir)
  74         install_data('org.freedesktop.login1.policy',
  75                      install_dir : polkitpolicydir)
  76 endif
  77
  78 ############################################################
  79
  80 tests += [
  81         [files('test-login-shared.c')],
  82
  83         [files('test-inhibit.c'),
  84          [], [], [], '', 'manual'],
  85
  86         [files('test-login-tables.c'),
  87          [liblogind_core,
  88           libshared],
  89          [threads]],
  90
  91         [files('test-session-properties.c'),
  92          [], [], [], '', 'manual'],
  93 ]