src/resolve/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 resolve_includes = [includes, include_directories('.')]
   4
   5 basic_dns_sources = files('''
   6         resolved-dns-dnssec.c
   7         resolved-dns-dnssec.h
   8         resolved-dns-packet.c
   9         resolved-dns-packet.h
  10         resolved-dns-rr.c
  11         resolved-dns-rr.h
  12         resolved-dns-answer.c
  13         resolved-dns-answer.h
  14         resolved-dns-question.c
  15         resolved-dns-question.h
  16         dns-type.c
  17         dns-type.h
  18 '''.split())
  19
  20 systemd_resolved_sources = files('''
  21         resolved-bus.c
  22         resolved-bus.h
  23         resolved-conf.c
  24         resolved-conf.h
  25         resolved-def.h
  26         resolved-dns-cache.c
  27         resolved-dns-cache.h
  28         resolved-dns-query.c
  29         resolved-dns-query.h
  30         resolved-dns-scope.c
  31         resolved-dns-scope.h
  32         resolved-dns-search-domain.c
  33         resolved-dns-search-domain.h
  34         resolved-dns-server.c
  35         resolved-dns-server.h
  36         resolved-dns-stream.c
  37         resolved-dns-stream.h
  38         resolved-dns-stub.c
  39         resolved-dns-stub.h
  40         resolved-dns-synthesize.c
  41         resolved-dns-synthesize.h
  42         resolved-dns-transaction.c
  43         resolved-dns-transaction.h
  44         resolved-dns-trust-anchor.c
  45         resolved-dns-trust-anchor.h
  46         resolved-dns-zone.c
  47         resolved-dns-zone.h
  48         resolved-dnssd-bus.c
  49         resolved-dnssd-bus.h
  50         resolved-dnssd.c
  51         resolved-dnssd.h
  52         resolved-dnstls.h
  53         resolved-etc-hosts.c
  54         resolved-etc-hosts.h
  55         resolved-link-bus.c
  56         resolved-link-bus.h
  57         resolved-link.c
  58         resolved-link.h
  59         resolved-llmnr.c
  60         resolved-llmnr.h
  61         resolved-manager.c
  62         resolved-manager.h
  63         resolved-mdns.c
  64         resolved-mdns.h
  65         resolved-resolv-conf.c
  66         resolved-resolv-conf.h
  67         resolved-socket-graveyard.c
  68         resolved-socket-graveyard.h
  69         resolved-varlink.c
  70         resolved-varlink.h
  71         resolved.c
  72 '''.split())
  73
  74 resolvectl_sources = files('''
  75          resolvconf-compat.c
  76          resolvconf-compat.h
  77          resolvectl.c
  78          resolvectl.h
  79 '''.split())
  80
  81 ############################################################
  82
  83 dns_type_list_txt = custom_target(
  84         'dns_type-list.txt',
  85         input : ['generate-dns_type-list.sed', 'dns-type.h'],
  86         output : 'dns_type-list.txt',
  87         command : [sed, '-n', '-r', '-f', '@INPUT0@', '@INPUT1@'],
  88         capture : true)
  89
  90 generate_dns_type_gperf = find_program('generate-dns_type-gperf.py')
  91
  92 gperf_file = custom_target(
  93         'dns_type-from-name.gperf',
  94         input : dns_type_list_txt,
  95         output : 'dns_type-from-name.gperf',
  96         command : [generate_dns_type_gperf, 'dns_type', 'DNS_TYPE_', '@INPUT@'],
  97         capture : true)
  98
  99 basic_dns_sources += custom_target(
 100         'dns_type-from-name.h',
 101         input : gperf_file,
 102         output : 'dns_type-from-name.h',
 103         command : [gperf,
 104                    '-L', 'ANSI-C', '-t', '--ignore-case',
 105                    '-N', 'lookup_dns_type',
 106                    '-H', 'hash_dns_type_name',
 107                    '-p', '-C',
 108                    '@INPUT@'],
 109         capture : true)
 110
 111 basic_dns_sources += custom_target(
 112         'dns_type-to-name.h',
 113         input : ['dns_type-to-name.awk', dns_type_list_txt],
 114         output : 'dns_type-to-name.h',
 115         command : [awk, '-f', '@INPUT0@', '@INPUT1@'],
 116         capture : true)
 117
 118 libsystemd_resolve_core = static_library(
 119         'systemd-resolve-core',
 120         basic_dns_sources,
 121         include_directories : includes)
 122
 123 systemd_resolved_sources += custom_target(
 124         'resolved_gperf.c',
 125         input : 'resolved-gperf.gperf',
 126         output : 'resolved-gperf.c',
 127         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 128
 129 systemd_resolved_sources += custom_target(
 130         'resolved_dnssd_gperf.c',
 131         input : 'resolved-dnssd-gperf.gperf',
 132         output : 'resolved-dnssd-gperf.c',
 133         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 134
 135 systemd_resolved_dependencies = [threads, libgpg_error, libm]
 136 if conf.get('ENABLE_DNS_OVER_TLS') == 1
 137         if conf.get('DNS_OVER_TLS_USE_GNUTLS') == 1
 138                 systemd_resolved_sources += files(
 139                         'resolved-dnstls-gnutls.c',
 140                         'resolved-dnstls-gnutls.h')
 141                 systemd_resolved_dependencies += libgnutls
 142         elif conf.get('DNS_OVER_TLS_USE_OPENSSL') == 1
 143                 systemd_resolved_sources += files(
 144                         'resolved-dnstls-openssl.c',
 145                         'resolved-dnstls-openssl.h')
 146                 systemd_resolved_dependencies += libopenssl
 147         else
 148                 error('unknown dependency for supporting DNS-over-TLS')
 149         endif
 150 endif
 151
 152 if conf.get('ENABLE_RESOLVE') == 1
 153         install_data('org.freedesktop.resolve1.conf',
 154                      install_dir : dbuspolicydir)
 155         install_data('org.freedesktop.resolve1.service',
 156                      install_dir : dbussystemservicedir)
 157         install_data('org.freedesktop.resolve1.policy',
 158                      install_dir : polkitpolicydir)
 159
 160         resolved_conf = configure_file(
 161                 input : 'resolved.conf.in',
 162                 output : 'resolved.conf',
 163                 configuration : substs)
 164         if install_sysconfdir_samples
 165                 install_data(resolved_conf,
 166                              install_dir : pkgsysconfdir)
 167         endif
 168
 169         install_data('resolv.conf',
 170                      install_dir : rootlibexecdir)
 171 endif
 172
 173 ############################################################
 174
 175 tests += [
 176         [['src/resolve/test-resolve-tables.c'],
 177          [libsystemd_resolve_core,
 178           libshared],
 179          [libgcrypt,
 180           libgpg_error,
 181           libm]],
 182
 183         [['src/resolve/test-dns-packet.c'],
 184          [libsystemd_resolve_core,
 185           libshared],
 186          [libgcrypt,
 187           libgpg_error,
 188           libm]],
 189
 190         [['src/resolve/test-resolved-etc-hosts.c',
 191           'src/resolve/resolved-etc-hosts.c',
 192           'src/resolve/resolved-etc-hosts.h'],
 193          [libsystemd_resolve_core,
 194           libshared],
 195          [libgcrypt,
 196           libgpg_error,
 197           libm]],
 198
 199         [['src/resolve/test-resolved-packet.c'],
 200          [libsystemd_resolve_core,
 201           libshared],
 202          [libgcrypt,
 203           libgpg_error,
 204           libm]],
 205
 206         [['src/resolve/test-dnssec.c'],
 207          [libsystemd_resolve_core,
 208           libshared],
 209          [libgcrypt,
 210           libgpg_error,
 211           libm]],
 212
 213         [['src/resolve/test-dnssec-complex.c',
 214           'src/resolve/dns-type.c'],
 215          [], [], resolve_includes, '', 'manual'],
 216 ]
 217
 218 fuzzers += [
 219         [['src/resolve/fuzz-dns-packet.c'],
 220          [libsystemd_resolve_core,
 221           libshared],
 222          [libgcrypt,
 223           libgpg_error,
 224           libm]],
 225 ]