src/udev/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 udevadm_sources = files('''
   4         udevadm.c
   5         udevadm.h
   6         udevadm-control.c
   7         udevadm-hwdb.c
   8         udevadm-info.c
   9         udevadm-monitor.c
  10         udevadm-settle.c
  11         udevadm-test.c
  12         udevadm-test-builtin.c
  13         udevadm-trigger.c
  14         udevadm-util.c
  15         udevadm-util.h
  16         udevd.c
  17 '''.split())
  18
  19 libudev_core_sources = '''
  20         udev-ctrl.c
  21         udev-ctrl.h
  22         udev-event.c
  23         udev-event.h
  24         udev-node.c
  25         udev-node.h
  26         udev-rules.c
  27         udev-rules.h
  28         udev-watch.c
  29         udev-watch.h
  30         udev-builtin.c
  31         udev-builtin.h
  32         udev-builtin-btrfs.c
  33         udev-builtin-hwdb.c
  34         udev-builtin-input_id.c
  35         udev-builtin-keyboard.c
  36         udev-builtin-net_id.c
  37         udev-builtin-net_setup_link.c
  38         udev-builtin-path_id.c
  39         udev-builtin-usb_id.c
  40         net/link-config.c
  41         net/link-config.h
  42 '''.split()
  43
  44 if conf.get('HAVE_KMOD') == 1
  45         libudev_core_sources += ['udev-builtin-kmod.c']
  46 endif
  47
  48 if conf.get('HAVE_BLKID') == 1
  49         libudev_core_sources += ['udev-builtin-blkid.c']
  50 endif
  51
  52 if conf.get('HAVE_ACL') == 1
  53         libudev_core_sources += ['udev-builtin-uaccess.c',
  54                                  logind_acl_c,
  55                                  sd_login_sources]
  56 endif
  57
  58 ############################################################
  59
  60 generate_keyboard_keys_list = find_program('generate-keyboard-keys-list.sh')
  61 keyboard_keys_list_txt = custom_target(
  62         'keyboard-keys-list.txt',
  63         output : 'keyboard-keys-list.txt',
  64         command : [generate_keyboard_keys_list, cpp],
  65         capture : true)
  66
  67 generate_keyboard_keys_gperf = find_program('generate-keyboard-keys-gperf.sh')
  68 fname = 'keyboard-keys-from-name.gperf'
  69 gperf_file = custom_target(
  70         fname,
  71         input : keyboard_keys_list_txt,
  72         output : fname,
  73         command : [generate_keyboard_keys_gperf, '@INPUT@'],
  74         capture : true)
  75
  76 fname = 'keyboard-keys-from-name.h'
  77 keyboard_keys_from_name_h = custom_target(
  78         fname,
  79         input : gperf_file,
  80         output : fname,
  81         command : [gperf,
  82                    '-L', 'ANSI-C', '-t',
  83                    '-N', 'keyboard_lookup_key',
  84                    '-H', 'hash_key_name',
  85                    '-p', '-C',
  86                    '@INPUT@'],
  87         capture : true)
  88
  89 ############################################################
  90
  91 link_config_gperf_c = custom_target(
  92         'link-config-gperf.c',
  93         input : 'net/link-config-gperf.gperf',
  94         output : 'link-config-gperf.c',
  95         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  96
  97 ############################################################
  98
  99 if get_option('link-udev-shared')
 100         udev_link_with = [libshared]
 101         udev_rpath = rootlibexecdir
 102 else
 103         udev_link_with = [libshared_static,
 104                           libsystemd_static]
 105         udev_rpath = ''
 106 endif
 107
 108 libudev_basic = static_library(
 109         'udev-basic',
 110         libudev_sources,
 111         include_directories : includes,
 112         c_args : ['-fvisibility=default'])
 113
 114 libudev_static = static_library(
 115         'udev_static',
 116         include_directories : includes,
 117         link_with : udev_link_with,
 118         link_whole : libudev_basic)
 119
 120 static_libudev = get_option('static-libudev')
 121 static_libudev_pic = static_libudev == 'true' or static_libudev == 'pic'
 122 install_libudev_static = static_library(
 123         'udev',
 124         basic_sources,
 125         shared_sources,
 126         libsystemd_sources,
 127         libudev_sources,
 128         disable_mempool_c,
 129         include_directories : includes,
 130         build_by_default : static_libudev != 'false',
 131         install : static_libudev != 'false',
 132         install_dir : rootlibdir,
 133         link_depends : libudev_sym,
 134         dependencies : libshared_deps + [libmount],
 135         c_args : static_libudev_pic ? [] : ['-fno-PIC'],
 136         pic : static_libudev_pic)
 137
 138 libudev = shared_library(
 139         'udev',
 140         disable_mempool_c,
 141         version : libudev_version,
 142         include_directories : includes,
 143         link_args : ['-shared',
 144                      '-Wl,--version-script=' + libudev_sym_path],
 145         link_with : [libsystemd_static, libshared_static],
 146         link_whole : libudev_basic,
 147         dependencies : [threads],
 148         link_depends : libudev_sym,
 149         install : true,
 150         install_dir : rootlibdir)
 151
 152 libudev_core_includes = [includes, include_directories('net')]
 153 libudev_core = static_library(
 154         'udev-core',
 155         libudev_core_sources,
 156         link_config_gperf_c,
 157         keyboard_keys_from_name_h,
 158         include_directories : libudev_core_includes,
 159         c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 160         link_with : udev_link_with,
 161         dependencies : [libblkid, libkmod])
 162
 163 foreach prog : [['ata_id/ata_id.c'],
 164                 ['cdrom_id/cdrom_id.c'],
 165                 ['fido_id/fido_id.c',
 166                  'fido_id/fido_id_desc.c',
 167                  'fido_id/fido_id_desc.h'],
 168                 ['scsi_id/scsi_id.c',
 169                  'scsi_id/scsi_id.h',
 170                  'scsi_id/scsi_serial.c',
 171                  'scsi_id/scsi.h'],
 172                 ['v4l_id/v4l_id.c'],
 173                 ['mtd_probe/mtd_probe.c',
 174                  'mtd_probe/mtd_probe.h',
 175                  'mtd_probe/probe_smartmedia.c']]
 176
 177         executable(prog[0].split('/')[0],
 178                    prog,
 179                    include_directories : includes,
 180                    c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 181                    dependencies : [versiondep],
 182                    link_with : [libudev_static],
 183                    install_rpath : udev_rpath,
 184                    install : true,
 185                    install_dir : udevlibexecdir)
 186 endforeach
 187
 188 install_data('udev.conf',
 189              install_dir : join_paths(sysconfdir, 'udev'))
 190
 191 configure_file(
 192         input : 'udev.pc.in',
 193         output : 'udev.pc',
 194         configuration : substs,
 195         install_dir : pkgconfigdatadir == 'no' ? '' : pkgconfigdatadir)
 196
 197 meson.add_install_script('sh', '-c',
 198                          mkdir_p.format(join_paths(sysconfdir, 'udev/rules.d')))
 199
 200 fuzzers += [
 201         [['src/udev/net/fuzz-link-parser.c',
 202           'src/fuzz/fuzz.h'],
 203          [libudev_core,
 204           libudev_static,
 205           libsystemd_network,
 206           libshared],
 207          [threads,
 208           libacl]],
 209
 210         [['src/udev/fido_id/fuzz-fido-id-desc.c',
 211           'src/udev/fido_id/fido_id_desc.c'],
 212          [],
 213          []],
 214         ]
 215
 216 tests += [
 217         [['src/udev/fido_id/test-fido-id-desc.c',
 218           'src/udev/fido_id/fido_id_desc.c'],
 219          [],
 220          []],
 221         ]