sysdeps/i386/fpu/e_acosh.S

   1 /* ix87 specific implementation of arcsinh.
   2    Copyright (C) 1996-2021 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <https://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21 #include <libm-alias-finite.h>
  22
  23         .section .rodata.cst8,"aM",@progbits,8
  24
  25         .p2align 3
  26         .type one,@object
  27 one:    .double 1.0
  28         ASM_SIZE_DIRECTIVE(one)
  29         .type limit,@object
  30 limit:  .double 0.29
  31         ASM_SIZE_DIRECTIVE(limit)
  32
  33 #ifdef PIC
  34 #define MO(op) op##@GOTOFF(%edx)
  35 #else
  36 #define MO(op) op
  37 #endif
  38
  39         .text
  40 ENTRY(__ieee754_acosh)
  41         movl    8(%esp), %ecx
  42         cmpl    $0x3ff00000, %ecx
  43         jl      5f                      // < 1 => invalid
  44         fldln2                          // log(2)
  45         fldl    4(%esp)                 // x : log(2)
  46         cmpl    $0x41b00000, %ecx
  47         ja      3f                      // x > 2^28
  48 #ifdef  PIC
  49         LOAD_PIC_REG (dx)
  50 #endif
  51         cmpl    $0x40000000, %ecx
  52         ja      4f                      // x > 2
  53
  54         // 1 <= x <= 2 => y = log1p(x-1+sqrt(2*(x-1)+(x-1)^2))
  55         fsubl   MO(one)                 // x-1 : log(2)
  56         fabs                            // acosh(1) is +0 in all rounding modes
  57         fld     %st                     // x-1 : x-1 : log(2)
  58         fmul    %st(1)                  // (x-1)^2 : x-1 : log(2)
  59         fadd    %st(1)                  // x-1+(x-1)^2 : x-1 : log(2)
  60         fadd    %st(1)                  // 2*(x-1)+(x-1)^2 : x-1 : log(2)
  61         fsqrt                           // sqrt(2*(x-1)+(x-1)^2) : x-1 : log(2)
  62         faddp                           // x-1+sqrt(2*(x-1)+(x-1)^2) : log(2)
  63         fcoml   MO(limit)
  64         fnstsw
  65         sahf
  66         ja      2f
  67         fyl2xp1                         // log1p(x-1+sqrt(2*(x-1)+(x-1)^2))
  68         ret
  69
  70 2:      faddl   MO(one)                 // x+sqrt(2*(x-1)+(x-1)^2) : log(2)
  71         fyl2x                           // log(x+sqrt(2*(x-1)+(x-1)^2))
  72         ret
  73
  74         // x > 2^28 => y = log(x) + log(2)
  75         .align ALIGNARG(4)
  76 3:      fyl2x                           // log(x)
  77         fldln2                          // log(2) : log(x)
  78         faddp                           // log(x)+log(2)
  79         ret
  80
  81         // 2^28 > x > 2 => y = log(2*x - 1/(x+sqrt(x*x-1)))
  82         .align ALIGNARG(4)
  83 4:      fld     %st                     // x : x : log(2)
  84         fadd    %st, %st(1)             // x : 2*x : log(2)
  85         fld     %st                     // x : x : 2*x : log(2)
  86         fmul    %st(1)                  // x^2 : x : 2*x : log(2)
  87         fsubl   MO(one)                 // x^2-1 : x : 2*x : log(2)
  88         fsqrt                           // sqrt(x^2-1) : x : 2*x : log(2)
  89         faddp                           // x+sqrt(x^2-1) : 2*x : log(2)
  90         fdivrl  MO(one)                 // 1/(x+sqrt(x^2-1)) : 2*x : log(2)
  91         fsubrp                          // 2*x+1/(x+sqrt(x^2)-1) : log(2)
  92         fyl2x                           // log(2*x+1/(x+sqrt(x^2-1)))
  93         ret
  94
  95         // x < 1 (or -NaN) => NaN
  96         .align ALIGNARG(4)
  97 5:      fldl    4(%esp)
  98         fsub    %st
  99         fdiv    %st, %st(0)
 100         ret
 101 END(__ieee754_acosh)
 102 libm_alias_finite (__ieee754_acosh, __acosh)