sysdeps/i386/fpu/s_expm1.S

   1 /* ix87 specific implementation of exp(x)-1.
   2    Copyright (C) 1996-2020 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5    Based on code by John C. Bowman <bowman@ipp-garching.mpg.de>.
   6    Corrections by H.J. Lu (hjl@gnu.ai.mit.edu), 1997.
   7
   8    The GNU C Library is free software; you can redistribute it and/or
   9    modify it under the terms of the GNU Lesser General Public
  10    License as published by the Free Software Foundation; either
  11    version 2.1 of the License, or (at your option) any later version.
  12
  13    The GNU C Library is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    Lesser General Public License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public
  19    License along with the GNU C Library; if not, see
  20    <https://www.gnu.org/licenses/>.  */
  21
  22         /* Using: e^x - 1 = 2^(x * log2(e)) - 1 */
  23
  24 #include <sysdep.h>
  25 #include <machine/asm.h>
  26 #include <i386-math-asm.h>
  27 #include <libm-alias-double.h>
  28
  29         .section .rodata
  30
  31         .align ALIGNARG(4)
  32         .type minus1,@object
  33 minus1: .double -1.0
  34         ASM_SIZE_DIRECTIVE(minus1)
  35         .type one,@object
  36 one:    .double 1.0
  37         ASM_SIZE_DIRECTIVE(one)
  38         .type l2e,@object
  39 l2e:    .tfloat 1.442695040888963407359924681002
  40         ASM_SIZE_DIRECTIVE(l2e)
  41
  42 DEFINE_DBL_MIN
  43
  44 #ifdef PIC
  45 #define MO(op) op##@GOTOFF(%edx)
  46 #else
  47 #define MO(op) op
  48 #endif
  49
  50         .text
  51 ENTRY(__expm1)
  52         movzwl  4+6(%esp), %eax
  53         xorb    $0x80, %ah      // invert sign bit (now 1 is "positive")
  54         cmpl    $0xc086, %eax   // is num >= 704?
  55         jae     HIDDEN_JUMPTARGET (__exp)
  56
  57         fldl    4(%esp)         // x
  58         fxam                    // Is NaN, +-Inf or +-0?
  59         xorb    $0x80, %ah
  60         cmpl    $0xc043, %eax   // is num <= -38.0?
  61         fstsw   %ax
  62         movb    $0x45, %ch
  63         jb      4f
  64
  65         // Below -38.0 (may be -NaN or -Inf).
  66         andb    %ah, %ch
  67 #ifdef  PIC
  68         LOAD_PIC_REG (dx)
  69 #endif
  70         cmpb    $0x01, %ch
  71         je      5f              // If -NaN, jump.
  72         jmp     2f              // -large, possibly -Inf.
  73
  74 4:      // In range -38.0 to 704.0 (may be +-0 but not NaN or +-Inf).
  75         andb    %ah, %ch
  76         cmpb    $0x40, %ch
  77         je      3f              // If +-0, jump.
  78 #ifdef  PIC
  79         LOAD_PIC_REG (dx)
  80 #endif
  81
  82 5:      fldt    MO(l2e)         // log2(e) : x
  83         fmulp                   // log2(e)*x
  84         fld     %st             // log2(e)*x : log2(e)*x
  85         // Set round-to-nearest temporarily.
  86         subl    $8, %esp
  87         cfi_adjust_cfa_offset (8)
  88         fstcw   4(%esp)
  89         movl    $0xf3ff, %ecx
  90         andl    4(%esp), %ecx
  91         movl    %ecx, (%esp)
  92         fldcw   (%esp)
  93         frndint                 // int(log2(e)*x) : log2(e)*x
  94         fldcw   4(%esp)
  95         addl    $8, %esp
  96         cfi_adjust_cfa_offset (-8)
  97         fsubr   %st, %st(1)     // int(log2(e)*x) : fract(log2(e)*x)
  98         fxch                    // fract(log2(e)*x) : int(log2(e)*x)
  99         f2xm1                   // 2^fract(log2(e)*x)-1 : int(log2(e)*x)
 100         fscale                  // 2^(log2(e)*x)-2^int(log2(e)*x) : int(log2(e)*x)
 101         fxch                    // int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
 102         fldl    MO(one)         // 1 : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
 103         fscale                  // 2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
 104         fsubrl  MO(one)         // 1-2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
 105         fstp    %st(1)          // 1-2^int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
 106         fsubrp  %st, %st(1)     // 2^(log2(e)*x)
 107         DBL_CHECK_FORCE_UFLOW
 108         ret
 109
 110 2:      fstp    %st
 111         fldl    MO(minus1)      // Set result to -1.0.
 112 3:      ret
 113 END(__expm1)
 114 libm_alias_double (__expm1, expm1)