sysdeps/i386/i586/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2    Highly optimized version for ix86, x>=5.
   3    Copyright (C) 1996-2020 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Torbjorn Granlund, <tege@matematik.su.se>
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <https://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include "asm-syntax.h"
  23
  24 #define PARMS   4+4     /* space for 1 saved reg */
  25 #define RTN     PARMS
  26 #define DEST    RTN
  27 #ifdef USE_AS_BZERO
  28 # define LEN    DEST+4
  29 #else
  30 # define CHR    DEST+4
  31 # define LEN    CHR+4
  32 #endif
  33
  34         .text
  35 #if defined SHARED && IS_IN (libc) && !defined USE_AS_BZERO
  36 ENTRY (__memset_chk)
  37         movl    12(%esp), %eax
  38         cmpl    %eax, 16(%esp)
  39         jb      HIDDEN_JUMPTARGET (__chk_fail)
  40 END (__memset_chk)
  41 #endif
  42 ENTRY (memset)
  43
  44         pushl   %edi
  45         cfi_adjust_cfa_offset (4)
  46
  47         movl    DEST(%esp), %edi
  48         cfi_rel_offset (edi, 0)
  49         movl    LEN(%esp), %edx
  50 #ifdef USE_AS_BZERO
  51         xorl    %eax, %eax      /* we fill with 0 */
  52 #else
  53         movb    CHR(%esp), %al
  54         movb    %al, %ah
  55         movl    %eax, %ecx
  56         shll    $16, %eax
  57         movw    %cx, %ax
  58 #endif
  59         cld
  60
  61 /* If less than 36 bytes to write, skip tricky code (it wouldn't work).  */
  62         cmpl    $36, %edx
  63         movl    %edx, %ecx      /* needed when branch is taken! */
  64         jl      L(2)
  65
  66 /* First write 0-3 bytes to make the pointer 32-bit aligned.  */
  67         movl    %edi, %ecx      /* Copy ptr to ecx... */
  68         negl    %ecx            /* ...and negate that and... */
  69         andl    $3, %ecx        /* ...mask to get byte count.  */
  70         subl    %ecx, %edx      /* adjust global byte count */
  71         rep
  72         stosb
  73
  74         subl    $32, %edx       /* offset count for unrolled loop */
  75         movl    (%edi), %ecx    /* Fetch destination cache line */
  76
  77         .align  2, 0x90         /* supply 0x90 for broken assemblers */
  78 L(1):   movl    28(%edi), %ecx  /* allocate cache line for destination */
  79         subl    $32, %edx       /* decr loop count */
  80         movl    %eax, 0(%edi)   /* store words pairwise */
  81         movl    %eax, 4(%edi)
  82         movl    %eax, 8(%edi)
  83         movl    %eax, 12(%edi)
  84         movl    %eax, 16(%edi)
  85         movl    %eax, 20(%edi)
  86         movl    %eax, 24(%edi)
  87         movl    %eax, 28(%edi)
  88         leal    32(%edi), %edi  /* update destination pointer */
  89         jge     L(1)
  90
  91         leal    32(%edx), %ecx  /* reset offset count */
  92
  93 /* Write last 0-7 full 32-bit words (up to 8 words if loop was skipped).  */
  94 L(2):   shrl    $2, %ecx        /* convert byte count to longword count */
  95         rep
  96         stosl
  97
  98 /* Finally write the last 0-3 bytes.  */
  99         movl    %edx, %ecx
 100         andl    $3, %ecx
 101         rep
 102         stosb
 103
 104 #ifndef USE_AS_BZERO
 105         /* Load result (only if used as memset).  */
 106         movl DEST(%esp), %eax   /* start address of destination is result */
 107 #endif
 108         popl    %edi
 109         cfi_adjust_cfa_offset (-4)
 110         cfi_restore (edi)
 111
 112         ret
 113 END (memset)
 114 libc_hidden_builtin_def (memset)