tmpfiles.d/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 if conf.get('ENABLE_TMPFILES') != 1
   4         subdir_done()
   5 endif
   6
   7 files = [['README'],
   8          ['home.conf'],
   9          ['journal-nocow.conf'],
  10          ['portables.conf',       'ENABLE_PORTABLED'],
  11          ['systemd-network.conf', 'ENABLE_NETWORKD'],
  12          ['systemd-nologin.conf', 'HAVE_PAM'],
  13          ['systemd-nspawn.conf',  'ENABLE_MACHINED'],
  14          ['systemd-pstore.conf',  'ENABLE_PSTORE'],
  15          ['systemd-resolve.conf', 'ENABLE_RESOLVE'],
  16          ['systemd-tmp.conf'],
  17          ['tmp.conf'],
  18          ['x11.conf'],
  19          ['provision.conf'],
  20          ['credstore.conf'],
  21         ]
  22
  23 foreach f : files
  24         if f.length() == 1 or conf.get(f[1]) == 1
  25                 install_data(f[0], install_dir : tmpfilesdir)
  26         else
  27                 message('Not installing tmpfiles.d/@0@ because @1@ is @2@'
  28                         .format(f[0], f[1], conf.get(f[1], 0)))
  29         endif
  30 endforeach
  31
  32 in_files = [
  33         ['20-systemd-shell-extra.conf',   'LINK_SHELL_EXTRA_DROPIN'],
  34         ['20-systemd-osc-context.conf',   'LINK_OSC_CONTEXT_DROPIN'],
  35         ['20-systemd-ssh-generator.conf', 'ENABLE_SSH_PROXY_CONFIG'],
  36         ['20-systemd-stub.conf',          'ENABLE_EFI'],
  37         ['20-systemd-userdb.conf',        'ENABLE_SSH_USERDB_CONFIG'],
  38         ['etc.conf'],
  39         ['legacy.conf'],
  40         ['static-nodes-permissions.conf'],
  41         ['systemd.conf'],
  42         ['var.conf'],
  43 ]
  44
  45 foreach f : in_files
  46         if f.length() == 1 or conf.get(f[1]) == 1
  47                 custom_target(
  48                         input : f[0] + '.in',
  49                         output: f[0],
  50                         command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
  51                         install : true,
  52                         install_dir : tmpfilesdir)
  53         else
  54                 message('Not installing tmpfiles.d/@0@ because @1@ is @2@'
  55                         .format(f[0], f[1], conf.get(f[1], 0)))
  56         endif
  57 endforeach
  58
  59 if install_sysconfdir
  60         install_emptydir(sysconfdir / 'tmpfiles.d')
  61 endif