units/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 with_runlevels = conf.get('HAVE_SYSV_COMPAT') == 1
   4
   5 units = [
   6         ['basic.target',                        ''],
   7         ['blockdev@.target',                    ''],
   8         ['bluetooth.target',                    ''],
   9         ['boot-complete.target',                ''],
  10         ['cryptsetup-pre.target',               'HAVE_LIBCRYPTSETUP'],
  11         ['cryptsetup.target',                   'HAVE_LIBCRYPTSETUP',
  12          'sysinit.target.wants/'],
  13         ['dev-hugepages.mount',                 '',
  14          'sysinit.target.wants/'],
  15         ['dev-mqueue.mount',                    '',
  16          'sysinit.target.wants/'],
  17         ['emergency.target',                    ''],
  18         ['exit.target',                         ''],
  19         ['final.target',                        ''],
  20         ['getty.target',                        '',
  21          'multi-user.target.wants/'],
  22         ['getty-pre.target',                    ''],
  23         ['graphical.target',                    '',
  24          (with_runlevels ? 'runlevel5.target default.target' : 'default.target')],
  25         ['halt.target',                         ''],
  26         ['hibernate.target',                    'ENABLE_HIBERNATE'],
  27         ['hybrid-sleep.target',                 'ENABLE_HIBERNATE'],
  28         ['suspend-then-hibernate.target',       'ENABLE_HIBERNATE'],
  29         ['initrd-cleanup.service',              'ENABLE_INITRD'],
  30         ['initrd-fs.target',                    'ENABLE_INITRD'],
  31         ['initrd-parse-etc.service',            'ENABLE_INITRD'],
  32         ['initrd-root-device.target',           'ENABLE_INITRD'],
  33         ['initrd-root-fs.target',               'ENABLE_INITRD'],
  34         ['initrd-switch-root.service',          'ENABLE_INITRD'],
  35         ['initrd-switch-root.target',           'ENABLE_INITRD'],
  36         ['initrd-udevadm-cleanup-db.service',   'ENABLE_INITRD'],
  37         ['initrd.target',                       'ENABLE_INITRD'],
  38         ['kexec.target',                        ''],
  39         ['ldconfig.service',                    'ENABLE_LDCONFIG',
  40          'sysinit.target.wants/'],
  41         ['local-fs-pre.target',                 ''],
  42         ['local-fs.target',                     ''],
  43         ['machine.slice',                       'ENABLE_MACHINED'],
  44         ['machines.target',                     'ENABLE_MACHINED'],
  45         ['modprobe@.service',                   ''],
  46         ['multi-user.target',                   '',
  47          (with_runlevels ? 'runlevel2.target runlevel3.target runlevel4.target' : '')],
  48         ['network-online.target',               ''],
  49         ['network-pre.target',                  ''],
  50         ['network.target',                      ''],
  51         ['nss-lookup.target',                   ''],
  52         ['nss-user-lookup.target',              ''],
  53         ['paths.target',                        ''],
  54         ['poweroff.target',                     '',
  55          (with_runlevels ? 'runlevel0.target' : '')],
  56         ['printer.target',                      ''],
  57         ['proc-sys-fs-binfmt_misc.automount',   'ENABLE_BINFMT',
  58          'sysinit.target.wants/'],
  59         ['proc-sys-fs-binfmt_misc.mount',       'ENABLE_BINFMT'],
  60         ['reboot.target',                       '',
  61          (with_runlevels ? 'runlevel6.target ctrl-alt-del.target' : 'ctrl-alt-del.target')],
  62         ['remote-cryptsetup.target',            'HAVE_LIBCRYPTSETUP'],
  63         ['remote-fs-pre.target',                ''],
  64         ['remote-fs.target',                    ''],
  65         ['rescue.target',                       '',
  66          (with_runlevels ? 'runlevel1.target' : '')],
  67         ['rpcbind.target',                      ''],
  68         ['shutdown.target',                     ''],
  69         ['sigpwr.target',                       ''],
  70         ['sleep.target',                        ''],
  71         ['slices.target',                       ''],
  72         ['smartcard.target',                    ''],
  73         ['sockets.target',                      ''],
  74         ['sound.target',                        ''],
  75         ['suspend.target',                      ''],
  76         ['swap.target',                         ''],
  77         ['sys-fs-fuse-connections.mount',       '',
  78          'sysinit.target.wants/'],
  79         ['sys-kernel-config.mount',             '',
  80          'sysinit.target.wants/'],
  81         ['sys-kernel-debug.mount',              '',
  82          'sysinit.target.wants/'],
  83         ['sys-kernel-tracing.mount',            '',
  84          'sysinit.target.wants/'],
  85         ['sysinit.target',                      ''],
  86         ['syslog.socket',                       ''],
  87         ['system-systemd\\x2dcryptsetup.slice', 'HAVE_LIBCRYPTSETUP'],
  88         ['system-update.target',                ''],
  89         ['system-update-pre.target',            ''],
  90         ['system-update-cleanup.service',       ''],
  91         ['systemd-ask-password-console.path',   '',
  92          'sysinit.target.wants/'],
  93         ['systemd-ask-password-console.service', ''],
  94         ['systemd-ask-password-wall.path',      '',
  95          'multi-user.target.wants/'],
  96         ['systemd-ask-password-wall.service',   ''],
  97         ['systemd-boot-system-token.service',   'ENABLE_EFI',
  98          'sysinit.target.wants/'],
  99         ['systemd-coredump.socket',             'ENABLE_COREDUMP',
 100          'sockets.target.wants/'],
 101         ['systemd-exit.service',                ''],
 102         ['systemd-firstboot.service',           'ENABLE_FIRSTBOOT',
 103          'sysinit.target.wants/'],
 104         ['systemd-halt.service',                ''],
 105         ['systemd-initctl.socket',              'HAVE_SYSV_COMPAT',
 106          'sockets.target.wants/'],
 107         ['systemd-journal-catalog-update.service', '',
 108          'sysinit.target.wants/'],
 109         ['systemd-journal-flush.service',       '',
 110          'sysinit.target.wants/'],
 111         ['systemd-journal-gatewayd.socket',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
 112         ['systemd-journal-remote.socket',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
 113         ['systemd-journald-audit.socket',       '',
 114          'sockets.target.wants/'],
 115         ['systemd-journald-dev-log.socket',     '',
 116          'sockets.target.wants/'],
 117         ['systemd-journald.socket',             '',
 118          'sockets.target.wants/'],
 119         ['systemd-kexec.service',               ''],
 120         ['systemd-machine-id-commit.service',   '',
 121          'sysinit.target.wants/'],
 122         ['systemd-journald@.socket',            ''],
 123         ['systemd-journald-varlink@.socket',    ''],
 124         ['systemd-networkd.socket',             'ENABLE_NETWORKD'],
 125         ['systemd-poweroff.service',            ''],
 126         ['systemd-reboot.service',              ''],
 127         ['systemd-rfkill.socket',               'ENABLE_RFKILL'],
 128         ['systemd-sysusers.service',            'ENABLE_SYSUSERS',
 129          'sysinit.target.wants/'],
 130         ['systemd-tmpfiles-clean.service',      'ENABLE_TMPFILES'],
 131         ['systemd-tmpfiles-clean.timer',        'ENABLE_TMPFILES',
 132          'timers.target.wants/'],
 133         ['systemd-tmpfiles-setup-dev.service',  'ENABLE_TMPFILES',
 134          'sysinit.target.wants/'],
 135         ['systemd-tmpfiles-setup.service',      'ENABLE_TMPFILES',
 136          'sysinit.target.wants/'],
 137         ['systemd-udevd-control.socket',        '',
 138          'sockets.target.wants/'],
 139         ['systemd-udev-settle.service',         ''],
 140         ['systemd-udev-trigger.service',        '',
 141          'sysinit.target.wants/'],
 142         ['systemd-udevd-kernel.socket',         '',
 143          'sockets.target.wants/'],
 144         ['systemd-userdbd.socket',              'ENABLE_USERDB'],
 145         ['time-set.target',                     ''],
 146         ['time-sync.target',                    ''],
 147         ['timers.target',                       ''],
 148         ['tmp.mount',                           '',
 149          'local-fs.target.wants/'],
 150         ['umount.target',                       ''],
 151         ['usb-gadget.target',                   ''],
 152         ['user.slice',                          ''],
 153         ['var-lib-machines.mount',              'ENABLE_MACHINED',
 154          'remote-fs.target.wants/ machines.target.wants/'],
 155 ]
 156
 157 in_units = [
 158         ['debug-shell.service',                  ''],
 159         ['emergency.service',                    ''],
 160         ['kmod-static-nodes.service',            'HAVE_KMOD ENABLE_TMPFILES',
 161          'sysinit.target.wants/'],
 162         ['quotaon.service',                      'ENABLE_QUOTACHECK'],
 163         ['rc-local.service',                     'HAVE_SYSV_COMPAT'],
 164         ['rescue.service',                       ''],
 165         ['systemd-backlight@.service',           'ENABLE_BACKLIGHT'],
 166         ['systemd-binfmt.service',               'ENABLE_BINFMT',
 167          'sysinit.target.wants/'],
 168         ['systemd-bless-boot.service',           'ENABLE_EFI HAVE_BLKID'],
 169         ['systemd-boot-check-no-failures.service', ''],
 170         ['systemd-coredump@.service',            'ENABLE_COREDUMP'],
 171         ['systemd-pstore.service',               'ENABLE_PSTORE'],
 172         ['systemd-fsck-root.service',            ''],
 173         ['systemd-fsck@.service',                ''],
 174         ['systemd-hibernate-resume@.service',    'ENABLE_HIBERNATE'],
 175         ['systemd-hibernate.service',            'ENABLE_HIBERNATE'],
 176         ['systemd-hybrid-sleep.service',         'ENABLE_HIBERNATE'],
 177         ['systemd-suspend-then-hibernate.service', 'ENABLE_HIBERNATE'],
 178         ['systemd-hostnamed.service',            'ENABLE_HOSTNAMED',
 179          'dbus-org.freedesktop.hostname1.service'],
 180         ['systemd-hwdb-update.service',          'ENABLE_HWDB',
 181          'sysinit.target.wants/'],
 182         ['systemd-importd.service',              'ENABLE_IMPORTD',
 183          'dbus-org.freedesktop.import1.service'],
 184         ['systemd-initctl.service',              'HAVE_SYSV_COMPAT'],
 185         ['systemd-journal-gatewayd.service',     'ENABLE_REMOTE HAVE_MICROHTTPD'],
 186         ['systemd-journal-remote.service',       'ENABLE_REMOTE HAVE_MICROHTTPD'],
 187         ['systemd-journal-upload.service',       'ENABLE_REMOTE HAVE_LIBCURL'],
 188         ['systemd-journald.service',             '',
 189          'sysinit.target.wants/'],
 190         ['systemd-journald@.service',            ''],
 191         ['systemd-localed.service',              'ENABLE_LOCALED',
 192          'dbus-org.freedesktop.locale1.service'],
 193         ['systemd-logind.service',               'ENABLE_LOGIND',
 194          'multi-user.target.wants/ dbus-org.freedesktop.login1.service'],
 195         ['systemd-machined.service',             'ENABLE_MACHINED',
 196          'dbus-org.freedesktop.machine1.service'],
 197         ['systemd-modules-load.service',         'HAVE_KMOD',
 198          'sysinit.target.wants/'],
 199         ['systemd-network-generator.service',    'ENABLE_NETWORKD'],
 200         ['systemd-networkd.service',             'ENABLE_NETWORKD'],
 201         ['systemd-networkd-wait-online.service', 'ENABLE_NETWORKD'],
 202         ['systemd-nspawn@.service',              ''],
 203         ['systemd-portabled.service',            'ENABLE_PORTABLED',
 204          'dbus-org.freedesktop.portable1.service'],
 205         ['systemd-userdbd.service',              'ENABLE_USERDB'],
 206         ['systemd-homed.service',                'ENABLE_HOMED'],
 207         ['systemd-quotacheck.service',           'ENABLE_QUOTACHECK'],
 208         ['systemd-random-seed.service',          'ENABLE_RANDOMSEED',
 209          'sysinit.target.wants/'],
 210         ['systemd-remount-fs.service',           ''],
 211         ['systemd-resolved.service',             'ENABLE_RESOLVE'],
 212         ['systemd-rfkill.service',               'ENABLE_RFKILL'],
 213         ['systemd-suspend.service',              ''],
 214         ['systemd-sysctl.service',               '',
 215          'sysinit.target.wants/'],
 216         ['systemd-timedated.service',            'ENABLE_TIMEDATED',
 217          'dbus-org.freedesktop.timedate1.service'],
 218         ['systemd-timesyncd.service',            'ENABLE_TIMESYNCD'],
 219         ['systemd-time-wait-sync.service',       'ENABLE_TIMESYNCD'],
 220         ['systemd-udevd.service',                '',
 221          'sysinit.target.wants/'],
 222         ['systemd-update-done.service',          '',
 223          'sysinit.target.wants/'],
 224         ['systemd-update-utmp-runlevel.service', 'ENABLE_UTMP HAVE_SYSV_COMPAT',
 225          'multi-user.target.wants/ graphical.target.wants/ rescue.target.wants/'],
 226         ['systemd-update-utmp.service',          'ENABLE_UTMP',
 227          'sysinit.target.wants/'],
 228         ['systemd-user-sessions.service',        'HAVE_PAM',
 229          'multi-user.target.wants/'],
 230         ['systemd-vconsole-setup.service',       'ENABLE_VCONSOLE'],
 231         ['systemd-volatile-root.service',        'ENABLE_INITRD'],
 232         ['systemd-repart.service',               'ENABLE_REPART',
 233          'sysinit.target.wants/ initrd-root-fs.target.wants/'],
 234         ['user-runtime-dir@.service',            ''],
 235         ['user@.service',                        ''],
 236 ]
 237
 238 m4_units = [
 239         ['console-getty.service',              ''],
 240         ['container-getty@.service',           ''],
 241         ['getty@.service',                     '',
 242          'autovt@.service '],
 243         ['serial-getty@.service',              ''],
 244 ]
 245
 246 foreach tuple : in_units
 247         file = tuple[0]
 248
 249         # we do this here because install_data does not accept custom_target output
 250         conds = tuple[1].split(' ')
 251         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 252                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 253
 254         gen1 = configure_file(
 255                 input : file + '.in',
 256                 output : file + '.tmp',
 257                 configuration : substs)
 258         gen2 = custom_target(
 259                 file,
 260                 input : gen1,
 261                 output : file,
 262                 command : [sed, '/^## /d', '@INPUT@'],
 263                 capture : true,
 264                 install : install,
 265                 install_dir : systemunitdir)
 266
 267         if install and tuple.length() > 2
 268                 foreach target : tuple[2].split()
 269                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 270                 endforeach
 271         endif
 272 endforeach
 273
 274 foreach tuple : m4_units
 275         file = tuple[0]
 276         input = tuple.get(3, file + '.m4')
 277
 278         # we do this here because install_data does not accept custom_target output
 279         conds = tuple[1].split(' ')
 280         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 281                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 282
 283         custom_target(
 284                 file,
 285                 input : input,
 286                 output: file,
 287                 command : [meson_apply_m4, config_h, '@INPUT@'],
 288                 capture : true,
 289                 install : install,
 290                 install_dir : systemunitdir)
 291
 292         if tuple.length() > 2 and install
 293                 foreach target : tuple[2].split()
 294                         meson.add_install_script('meson-add-wants.sh', systemunitdir, target, file)
 295                 endforeach
 296         endif
 297 endforeach
 298
 299 foreach tuple : units
 300         file = tuple[0]
 301         input = tuple.get(3, file)
 302
 303         conds = tuple[1].split(' ')
 304         install = ((conds.get(0, '') == '' or conf.get(conds[0]) == 1) and
 305                    (conds.get(1, '') == '' or conf.get(conds[1]) == 1))
 306
 307         if install
 308                 install_data(input,
 309                              install_dir : systemunitdir)
 310
 311                 if tuple.length() > 2
 312                         foreach target : tuple[2].split()
 313                                 meson.add_install_script(
 314                                         'meson-add-wants.sh', systemunitdir, target, file)
 315                         endforeach
 316                 endif
 317         endif
 318 endforeach
 319
 320 install_data('user-.slice.d/10-defaults.conf',
 321              install_dir : systemunitdir + '/user-.slice.d')
 322
 323 ############################################################
 324
 325 meson.add_install_script(meson_make_symlink,
 326                          join_paths(pkgsysconfdir, 'user'),
 327                          join_paths(sysconfdir, 'xdg/systemd/user'))
 328 meson.add_install_script(meson_make_symlink,
 329                          join_paths(dbussystemservicedir, 'org.freedesktop.systemd1.service'),
 330                          join_paths(dbussessionservicedir, 'org.freedesktop.systemd1.service'))
 331 if conf.get('HAVE_SYSV_COMPAT') == 1
 332         foreach i : [1, 2, 3, 4, 5]
 333                 meson.add_install_script(
 334                         'sh', '-c',
 335                         mkdir_p
 336                         .format(join_paths(systemunitdir, 'runlevel@0@.target.wants'.format(i))))
 337         endforeach
 338 endif
 339
 340 subdir('user')