]>
Commit | Line | Data |
---|---|---|
1 | # -*- Autoconf -*- | |
2 | # Process this file with autoconf to produce a configure script. | |
3 | ||
4 | ## Definitions of private macros. | |
5 | ||
6 | # GIT_CONF_SUBST(VAL, VAR) | |
7 | # ------------------------ | |
8 | # Cause the line "VAR=VAL" to be eventually appended to ${config_file}. | |
9 | AC_DEFUN([GIT_CONF_SUBST], | |
10 | [AC_REQUIRE([GIT_CONF_SUBST_INIT]) | |
11 | config_appended_defs="$config_appended_defs${newline}dnl | |
12 | $1=m4_if([$#],[1],[${$1}],[$2])"]) | |
13 | ||
14 | # GIT_CONF_SUBST_INIT | |
15 | # ------------------- | |
16 | # Prepare shell variables and autoconf machine required by later calls | |
17 | # to GIT_CONF_SUBST. | |
18 | AC_DEFUN([GIT_CONF_SUBST_INIT], | |
19 | [config_appended_defs=; newline=' | |
20 | ' | |
21 | AC_CONFIG_COMMANDS([$config_file], | |
22 | [echo "$config_appended_defs" >> "$config_file"], | |
23 | [config_file=$config_file | |
24 | config_appended_defs="$config_appended_defs"])]) | |
25 | ||
26 | # GIT_ARG_SET_PATH(PROGRAM) | |
27 | # ------------------------- | |
28 | # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM | |
29 | # Optional second argument allows setting NO_PROGRAM=YesPlease if | |
30 | # --without-PROGRAM version used. | |
31 | AC_DEFUN([GIT_ARG_SET_PATH], | |
32 | [AC_ARG_WITH([$1], | |
33 | [AS_HELP_STRING([--with-$1=PATH], | |
34 | [provide PATH to $1])], | |
35 | [GIT_CONF_APPEND_PATH([$1], [$2])], | |
36 | [])]) | |
37 | ||
38 | # GIT_CONF_APPEND_PATH(PROGRAM) | |
39 | # ----------------------------- | |
40 | # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH | |
41 | # Used by GIT_ARG_SET_PATH(PROGRAM) | |
42 | # Optional second argument allows setting NO_PROGRAM=YesPlease if | |
43 | # --without-PROGRAM is used. | |
44 | AC_DEFUN([GIT_CONF_APPEND_PATH], | |
45 | [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl | |
46 | if test "$withval" = "no"; then | |
47 | if test -n "$2"; then | |
48 | GIT_UC_PROGRAM[]_PATH=$withval | |
49 | AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM]) | |
50 | GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease]) | |
51 | GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, []) | |
52 | else | |
53 | AC_MSG_ERROR([You cannot use git without $1]) | |
54 | fi | |
55 | else | |
56 | if test "$withval" = "yes"; then | |
57 | AC_MSG_WARN([You should provide path for --with-$1=PATH]) | |
58 | else | |
59 | GIT_UC_PROGRAM[]_PATH=$withval | |
60 | AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval]) | |
61 | GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval]) | |
62 | fi | |
63 | fi | |
64 | m4_popdef([GIT_UC_PROGRAM])]) | |
65 | ||
66 | # GIT_PARSE_WITH(PACKAGE) | |
67 | # ----------------------- | |
68 | # For use in AC_ARG_WITH action-if-found, for packages default ON. | |
69 | # * Set NO_PACKAGE=YesPlease for --without-PACKAGE | |
70 | # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH | |
71 | # * Unset NO_PACKAGE for --with-PACKAGE without ARG | |
72 | AC_DEFUN([GIT_PARSE_WITH], | |
73 | [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl | |
74 | if test "$withval" = "no"; then | |
75 | NO_[]GIT_UC_PACKAGE=YesPlease | |
76 | elif test "$withval" = "yes"; then | |
77 | NO_[]GIT_UC_PACKAGE= | |
78 | else | |
79 | NO_[]GIT_UC_PACKAGE= | |
80 | GIT_UC_PACKAGE[]DIR=$withval | |
81 | AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval]) | |
82 | GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval]) | |
83 | fi | |
84 | m4_popdef([GIT_UC_PACKAGE])]) | |
85 | ||
86 | # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT) | |
87 | # ----------------------------------------------------- | |
88 | # Set VAR to the value specied by --with-WITHNAME. | |
89 | # No verification of arguments is performed, but warnings are issued | |
90 | # if either 'yes' or 'no' is specified. | |
91 | # HELP_TEXT is presented when --help is called. | |
92 | # This is a direct way to allow setting variables in the Makefile. | |
93 | AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR], | |
94 | [AC_ARG_WITH([$1], | |
95 | [AS_HELP_STRING([--with-$1=VALUE], $3)], | |
96 | if test -n "$withval"; then | |
97 | if test "$withval" = "yes" -o "$withval" = "no"; then | |
98 | AC_MSG_WARN([You likely do not want either 'yes' or 'no' as] | |
99 | [a value for $1 ($2). Maybe you do...?]) | |
100 | fi | |
101 | AC_MSG_NOTICE([Setting $2 to $withval]) | |
102 | GIT_CONF_SUBST([$2], [$withval]) | |
103 | fi)])# GIT_PARSE_WITH_SET_MAKE_VAR | |
104 | ||
105 | # | |
106 | # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE) | |
107 | # ----------------------------------------- | |
108 | # Similar to AC_CHECK_FUNC, but on systems that do not generate | |
109 | # warnings for missing prototypes (e.g. FreeBSD when compiling without | |
110 | # -Wall), it does not work. By looking for function definition in | |
111 | # libraries, this problem can be worked around. | |
112 | AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[ | |
113 | AC_SEARCH_LIBS([$1],, | |
114 | [$2],[$3]) | |
115 | ],[$3])]) | |
116 | ||
117 | # | |
118 | # GIT_STASH_FLAGS(BASEPATH_VAR) | |
119 | # ----------------------------- | |
120 | # Allow for easy stashing of LDFLAGS and CPPFLAGS before running | |
121 | # tests that may want to take user settings into account. | |
122 | AC_DEFUN([GIT_STASH_FLAGS],[ | |
123 | if test -n "$1"; then | |
124 | old_CPPFLAGS="$CPPFLAGS" | |
125 | old_LDFLAGS="$LDFLAGS" | |
126 | CPPFLAGS="-I$1/include $CPPFLAGS" | |
127 | LDFLAGS="-L$1/$lib $LDFLAGS" | |
128 | fi | |
129 | ]) | |
130 | ||
131 | dnl | |
132 | dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR) | |
133 | dnl ----------------------------- | |
134 | dnl Restore the stashed *FLAGS values. | |
135 | AC_DEFUN([GIT_UNSTASH_FLAGS],[ | |
136 | if test -n "$1"; then | |
137 | CPPFLAGS="$old_CPPFLAGS" | |
138 | LDFLAGS="$old_LDFLAGS" | |
139 | fi | |
140 | ]) | |
141 | ||
142 | ## Configure body starts here. | |
143 | ||
144 | AC_PREREQ(2.59) | |
145 | AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org]) | |
146 | ||
147 | AC_CONFIG_SRCDIR([git.c]) | |
148 | ||
149 | config_file=config.mak.autogen | |
150 | config_in=config.mak.in | |
151 | ||
152 | GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease]) | |
153 | ||
154 | # Directories holding "saner" versions of common or POSIX binaries. | |
155 | AC_ARG_WITH([sane-tool-path], | |
156 | [AS_HELP_STRING( | |
157 | [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]], | |
158 | [Directories to prepend to PATH in build system and generated scripts])], | |
159 | [if test "$withval" = "no"; then | |
160 | withval='' | |
161 | else | |
162 | AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval']) | |
163 | fi | |
164 | GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])], | |
165 | [# If the "--with-sane-tool-path" option was not given, don't touch | |
166 | # SANE_TOOL_PATH here, but let defaults in Makefile take care of it. | |
167 | # This should minimize spurious differences in the behaviour of the | |
168 | # Git build system when configure is used w.r.t. when it is not. | |
169 | :]) | |
170 | ||
171 | ## Site configuration related to programs (before tests) | |
172 | ## --with-PACKAGE[=ARG] and --without-PACKAGE | |
173 | # | |
174 | # Set lib to alternative name of lib directory (e.g. lib64) | |
175 | AC_ARG_WITH([lib], | |
176 | [AS_HELP_STRING([--with-lib=ARG], | |
177 | [ARG specifies alternative name for lib directory])], | |
178 | [if test "$withval" = "no" || test "$withval" = "yes"; then | |
179 | AC_MSG_WARN([You should provide name for --with-lib=ARG]) | |
180 | else | |
181 | lib=$withval | |
182 | AC_MSG_NOTICE([Setting lib to '$lib']) | |
183 | GIT_CONF_SUBST([lib]) | |
184 | fi]) | |
185 | ||
186 | if test -z "$lib"; then | |
187 | AC_MSG_NOTICE([Setting lib to 'lib' (the default)]) | |
188 | lib=lib | |
189 | fi | |
190 | ||
191 | AC_ARG_ENABLE([pthreads], | |
192 | [AS_HELP_STRING([--enable-pthreads=FLAGS], | |
193 | [FLAGS is the value to pass to the compiler to enable POSIX Threads.] | |
194 | [The default if FLAGS is not specified is to try first -pthread] | |
195 | [and then -lpthread.] | |
196 | [--disable-pthreads will disable threading.])], | |
197 | [ | |
198 | if test "x$enableval" = "xyes"; then | |
199 | AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads]) | |
200 | elif test "x$enableval" != "xno"; then | |
201 | PTHREAD_CFLAGS=$enableval | |
202 | AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads]) | |
203 | else | |
204 | AC_MSG_NOTICE([POSIX Threads will be disabled.]) | |
205 | NO_PTHREADS=YesPlease | |
206 | USER_NOPTHREAD=1 | |
207 | fi], | |
208 | [ | |
209 | AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.]) | |
210 | ]) | |
211 | ||
212 | # Define option to enable JavaScript minification | |
213 | AC_ARG_ENABLE([jsmin], | |
214 | [AS_HELP_STRING([--enable-jsmin=PATH], | |
215 | [PATH is the name of a JavaScript minifier or the absolute path to one.])], | |
216 | [ | |
217 | JSMIN=$enableval; | |
218 | AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying]) | |
219 | GIT_CONF_SUBST([JSMIN]) | |
220 | ]) | |
221 | ||
222 | # Define option to enable CSS minification | |
223 | AC_ARG_ENABLE([cssmin], | |
224 | [AS_HELP_STRING([--enable-cssmin=PATH], | |
225 | [PATH is the name of a CSS minifier or the absolute path to one.])], | |
226 | [ | |
227 | CSSMIN=$enableval; | |
228 | AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying]) | |
229 | GIT_CONF_SUBST([CSSMIN]) | |
230 | ]) | |
231 | ||
232 | ## Site configuration (override autodetection) | |
233 | ## --with-PACKAGE[=ARG] and --without-PACKAGE | |
234 | AC_MSG_NOTICE([CHECKS for site configuration]) | |
235 | # | |
236 | # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability | |
237 | # tests. These tests take up a significant amount of the total test time | |
238 | # but are not needed unless you plan to talk to SVN repos. | |
239 | # | |
240 | # Define PPC_SHA1 environment variable when running make to make use of | |
241 | # a bundled SHA1 routine optimized for PowerPC. | |
242 | # | |
243 | # Define NO_OPENSSL environment variable if you do not have OpenSSL. | |
244 | # This also implies BLK_SHA1. | |
245 | # | |
246 | # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in | |
247 | # /foo/bar/include and /foo/bar/lib directories. | |
248 | AC_ARG_WITH(openssl, | |
249 | AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)]) | |
250 | AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]), | |
251 | GIT_PARSE_WITH([openssl])) | |
252 | ||
253 | # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be | |
254 | # able to use Perl-compatible regular expressions. | |
255 | # | |
256 | # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in | |
257 | # /foo/bar/include and /foo/bar/lib directories. | |
258 | # | |
259 | AC_ARG_WITH(libpcre, | |
260 | AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)]) | |
261 | AS_HELP_STRING([], [ARG can be also prefix for libpcre library and headers]), | |
262 | if test "$withval" = "no"; then | |
263 | USE_LIBPCRE= | |
264 | elif test "$withval" = "yes"; then | |
265 | USE_LIBPCRE=YesPlease | |
266 | else | |
267 | USE_LIBPCRE=YesPlease | |
268 | LIBPCREDIR=$withval | |
269 | AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR]) | |
270 | dnl USE_LIBPCRE can still be modified below, so don't substitute | |
271 | dnl it yet. | |
272 | GIT_CONF_SUBST([LIBPCREDIR]) | |
273 | fi) | |
274 | # | |
275 | # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header. | |
276 | AC_FUNC_ALLOCA | |
277 | case $ac_cv_working_alloca_h in | |
278 | yes) HAVE_ALLOCA_H=YesPlease;; | |
279 | *) HAVE_ALLOCA_H='';; | |
280 | esac | |
281 | GIT_CONF_SUBST([HAVE_ALLOCA_H]) | |
282 | # | |
283 | # Define NO_CURL if you do not have curl installed. git-http-pull and | |
284 | # git-http-push are not built, and you cannot use http:// and https:// | |
285 | # transports. | |
286 | # | |
287 | # Define CURLDIR=/foo/bar if your curl header and library files are in | |
288 | # /foo/bar/include and /foo/bar/lib directories. | |
289 | AC_ARG_WITH(curl, | |
290 | AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)]) | |
291 | AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]), | |
292 | GIT_PARSE_WITH(curl)) | |
293 | # | |
294 | # Define NO_EXPAT if you do not have expat installed. git-http-push is | |
295 | # not built, and you cannot push using http:// and https:// transports. | |
296 | # | |
297 | # Define EXPATDIR=/foo/bar if your expat header and library files are in | |
298 | # /foo/bar/include and /foo/bar/lib directories. | |
299 | AC_ARG_WITH(expat, | |
300 | AS_HELP_STRING([--with-expat], | |
301 | [support git-push using http:// and https:// transports via WebDAV (default is YES)]) | |
302 | AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]), | |
303 | GIT_PARSE_WITH(expat)) | |
304 | # | |
305 | # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink | |
306 | # installed in /sw, but don't want GIT to link against any libraries | |
307 | # installed there. If defined you may specify your own (or Fink's) | |
308 | # include directories and library directories by defining CFLAGS | |
309 | # and LDFLAGS appropriately. | |
310 | # | |
311 | # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X, | |
312 | # have DarwinPorts installed in /opt/local, but don't want GIT to | |
313 | # link against any libraries installed there. If defined you may | |
314 | # specify your own (or DarwinPort's) include directories and | |
315 | # library directories by defining CFLAGS and LDFLAGS appropriately. | |
316 | # | |
317 | # Define NO_MMAP if you want to avoid mmap. | |
318 | # | |
319 | # Define NO_ICONV if your libc does not properly support iconv. | |
320 | AC_ARG_WITH(iconv, | |
321 | AS_HELP_STRING([--without-iconv], | |
322 | [if your architecture doesn't properly support iconv]) | |
323 | AS_HELP_STRING([--with-iconv=PATH], | |
324 | [PATH is prefix for libiconv library and headers]) | |
325 | AS_HELP_STRING([], | |
326 | [used only if you need linking with libiconv]), | |
327 | GIT_PARSE_WITH(iconv)) | |
328 | ||
329 | ## --enable-FEATURE[=ARG] and --disable-FEATURE | |
330 | # | |
331 | # Define USE_NSEC below if you want git to care about sub-second file mtimes | |
332 | # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and | |
333 | # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely | |
334 | # randomly break unless your underlying filesystem supports those sub-second | |
335 | # times (my ext3 doesn't). | |
336 | # | |
337 | # Define USE_STDEV below if you want git to care about the underlying device | |
338 | # change being considered an inode change from the update-index perspective. | |
339 | ||
340 | # | |
341 | # Allow user to set ETC_GITCONFIG variable | |
342 | GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG, | |
343 | Use VALUE instead of /etc/gitconfig as the | |
344 | global git configuration file. | |
345 | If VALUE is not fully qualified it will be interpreted | |
346 | as a path relative to the computed prefix at runtime.) | |
347 | ||
348 | # | |
349 | # Allow user to set ETC_GITATTRIBUTES variable | |
350 | GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES, | |
351 | Use VALUE instead of /etc/gitattributes as the | |
352 | global git attributes file. | |
353 | If VALUE is not fully qualified it will be interpreted | |
354 | as a path relative to the computed prefix at runtime.) | |
355 | ||
356 | # | |
357 | # Allow user to set the default pager | |
358 | GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER, | |
359 | Use VALUE as the fall-back pager instead of 'less'. | |
360 | This is used by things like 'git log' when the user | |
361 | does not specify a pager to use through alternate | |
362 | methods. eg: /usr/bin/pager) | |
363 | # | |
364 | # Allow user to set the default editor | |
365 | GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR, | |
366 | Use VALUE as the fall-back editor instead of 'vi'. | |
367 | This is used by things like 'git commit' when the user | |
368 | does not specify a preferred editor through other | |
369 | methods. eg: /usr/bin/editor) | |
370 | ||
371 | # | |
372 | # Define SHELL_PATH to provide path to shell. | |
373 | GIT_ARG_SET_PATH(shell) | |
374 | # | |
375 | # Define PERL_PATH to provide path to Perl. | |
376 | GIT_ARG_SET_PATH(perl) | |
377 | # | |
378 | # Define PYTHON_PATH to provide path to Python. | |
379 | GIT_ARG_SET_PATH(python, allow-without) | |
380 | # | |
381 | # Define ZLIB_PATH to provide path to zlib. | |
382 | GIT_ARG_SET_PATH(zlib) | |
383 | # | |
384 | # Declare the with-tcltk/without-tcltk options. | |
385 | AC_ARG_WITH(tcltk, | |
386 | AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)]) | |
387 | AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.]) | |
388 | AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if]) | |
389 | AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]), | |
390 | GIT_PARSE_WITH(tcltk)) | |
391 | # | |
392 | ||
393 | ||
394 | ## Checks for programs. | |
395 | AC_MSG_NOTICE([CHECKS for programs]) | |
396 | # | |
397 | AC_PROG_CC([cc gcc]) | |
398 | AC_C_INLINE | |
399 | case $ac_cv_c_inline in | |
400 | inline | yes | no) INLINE='';; | |
401 | *) INLINE=$ac_cv_c_inline ;; | |
402 | esac | |
403 | GIT_CONF_SUBST([INLINE]) | |
404 | ||
405 | # which switch to pass runtime path to dynamic libraries to the linker | |
406 | AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [ | |
407 | SAVE_LDFLAGS="${LDFLAGS}" | |
408 | LDFLAGS="${SAVE_LDFLAGS} -R /" | |
409 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no]) | |
410 | LDFLAGS="${SAVE_LDFLAGS}" | |
411 | ]) | |
412 | if test "$git_cv_ld_dashr" = "yes"; then | |
413 | CC_LD_DYNPATH=-R | |
414 | else | |
415 | AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [ | |
416 | SAVE_LDFLAGS="${LDFLAGS}" | |
417 | LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/" | |
418 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no]) | |
419 | LDFLAGS="${SAVE_LDFLAGS}" | |
420 | ]) | |
421 | if test "$git_cv_ld_wl_rpath" = "yes"; then | |
422 | CC_LD_DYNPATH=-Wl,-rpath, | |
423 | else | |
424 | AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [ | |
425 | SAVE_LDFLAGS="${LDFLAGS}" | |
426 | LDFLAGS="${SAVE_LDFLAGS} -rpath /" | |
427 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no]) | |
428 | LDFLAGS="${SAVE_LDFLAGS}" | |
429 | ]) | |
430 | if test "$git_cv_ld_rpath" = "yes"; then | |
431 | CC_LD_DYNPATH=-rpath | |
432 | else | |
433 | CC_LD_DYNPATH= | |
434 | AC_MSG_WARN([linker does not support runtime path to dynamic libraries]) | |
435 | fi | |
436 | fi | |
437 | fi | |
438 | GIT_CONF_SUBST([CC_LD_DYNPATH]) | |
439 | #AC_PROG_INSTALL # needs install-sh or install.sh in sources | |
440 | AC_CHECK_TOOLS(AR, [gar ar], :) | |
441 | AC_CHECK_PROGS(TAR, [gtar tar]) | |
442 | AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff]) | |
443 | # TCLTK_PATH will be set to some value if we want Tcl/Tk | |
444 | # or will be empty otherwise. | |
445 | if test -n "$NO_TCLTK"; then | |
446 | TCLTK_PATH= | |
447 | else | |
448 | if test "$with_tcltk" = ""; then | |
449 | # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'. | |
450 | TCLTK_PATH=wish | |
451 | elif test "$with_tcltk" = "yes"; then | |
452 | # Tcl/Tk check requested. | |
453 | AC_CHECK_PROGS(TCLTK_PATH, [wish], ) | |
454 | else | |
455 | AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk]) | |
456 | TCLTK_PATH="$with_tcltk" | |
457 | fi | |
458 | fi | |
459 | GIT_CONF_SUBST([TCLTK_PATH]) | |
460 | AC_CHECK_PROGS(ASCIIDOC, [asciidoc]) | |
461 | if test -n "$ASCIIDOC"; then | |
462 | AC_MSG_CHECKING([for asciidoc version]) | |
463 | asciidoc_version=`$ASCIIDOC --version 2>/dev/null` | |
464 | case "${asciidoc_version}" in | |
465 | asciidoc' '8*) | |
466 | AC_MSG_RESULT([${asciidoc_version}]) | |
467 | ;; | |
468 | *) | |
469 | AC_MSG_RESULT([${asciidoc_version} (unknown)]) | |
470 | ;; | |
471 | esac | |
472 | fi | |
473 | ||
474 | if grep -a ascii configure.ac >/dev/null; then | |
475 | AC_MSG_RESULT([Using 'grep -a' for sane_grep]) | |
476 | SANE_TEXT_GREP=-a | |
477 | else | |
478 | SANE_TEXT_GREP= | |
479 | fi | |
480 | GIT_CONF_SUBST([SANE_TEXT_GREP]) | |
481 | ||
482 | ## Checks for libraries. | |
483 | AC_MSG_NOTICE([CHECKS for libraries]) | |
484 | # | |
485 | # Define NO_OPENSSL environment variable if you do not have OpenSSL. | |
486 | # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin). | |
487 | ||
488 | GIT_STASH_FLAGS($OPENSSLDIR) | |
489 | ||
490 | AC_CHECK_LIB([crypto], [SHA1_Init], | |
491 | [NEEDS_SSL_WITH_CRYPTO=], | |
492 | [AC_CHECK_LIB([ssl], [SHA1_Init], | |
493 | [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=], | |
494 | [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])]) | |
495 | ||
496 | GIT_UNSTASH_FLAGS($OPENSSLDIR) | |
497 | ||
498 | GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO]) | |
499 | GIT_CONF_SUBST([NO_OPENSSL]) | |
500 | ||
501 | # | |
502 | # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be | |
503 | # able to use Perl-compatible regular expressions. | |
504 | # | |
505 | ||
506 | if test -n "$USE_LIBPCRE"; then | |
507 | ||
508 | GIT_STASH_FLAGS($LIBPCREDIR) | |
509 | ||
510 | AC_CHECK_LIB([pcre], [pcre_version], | |
511 | [USE_LIBPCRE=YesPlease], | |
512 | [USE_LIBPCRE=]) | |
513 | ||
514 | GIT_UNSTASH_FLAGS($LIBPCREDIR) | |
515 | ||
516 | GIT_CONF_SUBST([USE_LIBPCRE]) | |
517 | ||
518 | fi | |
519 | ||
520 | # | |
521 | # Define NO_CURL if you do not have libcurl installed. git-http-pull and | |
522 | # git-http-push are not built, and you cannot use http:// and https:// | |
523 | # transports. | |
524 | ||
525 | GIT_STASH_FLAGS($CURLDIR) | |
526 | ||
527 | AC_CHECK_LIB([curl], [curl_global_init], | |
528 | [NO_CURL=], | |
529 | [NO_CURL=YesPlease]) | |
530 | ||
531 | GIT_UNSTASH_FLAGS($CURLDIR) | |
532 | ||
533 | GIT_CONF_SUBST([NO_CURL]) | |
534 | ||
535 | if test -z "$NO_CURL"; then | |
536 | ||
537 | AC_CHECK_PROG([CURL_CONFIG], [curl-config], | |
538 | [curl-config], | |
539 | [no]) | |
540 | ||
541 | if test $CURL_CONFIG != no; then | |
542 | GIT_CONF_SUBST([CURL_CONFIG]) | |
543 | if test -z "${NO_OPENSSL}"; then | |
544 | AC_MSG_CHECKING([if Curl supports SSL]) | |
545 | if test $(curl-config --features|grep SSL) = SSL; then | |
546 | NEEDS_SSL_WITH_CURL=YesPlease | |
547 | AC_MSG_RESULT([yes]) | |
548 | else | |
549 | NEEDS_SSL_WITH_CURL= | |
550 | AC_MSG_RESULT([no]) | |
551 | fi | |
552 | GIT_CONF_SUBST([NEEDS_SSL_WITH_CURL]) | |
553 | fi | |
554 | fi | |
555 | ||
556 | fi | |
557 | ||
558 | ||
559 | # | |
560 | # Define NO_EXPAT if you do not have expat installed. git-http-push is | |
561 | # not built, and you cannot push using http:// and https:// transports. | |
562 | ||
563 | GIT_STASH_FLAGS($EXPATDIR) | |
564 | ||
565 | AC_CHECK_LIB([expat], [XML_ParserCreate], | |
566 | [NO_EXPAT=], | |
567 | [NO_EXPAT=YesPlease]) | |
568 | ||
569 | GIT_UNSTASH_FLAGS($EXPATDIR) | |
570 | ||
571 | GIT_CONF_SUBST([NO_EXPAT]) | |
572 | ||
573 | # | |
574 | # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and | |
575 | # some Solaris installations). | |
576 | # Define NO_ICONV if neither libc nor libiconv support iconv. | |
577 | ||
578 | if test -z "$NO_ICONV"; then | |
579 | ||
580 | GIT_STASH_FLAGS($ICONVDIR) | |
581 | ||
582 | AC_DEFUN([ICONVTEST_SRC], | |
583 | [AC_LANG_PROGRAM([#include <iconv.h>], | |
584 | [iconv_open("", "");])]) | |
585 | ||
586 | if test -n "$ICONVDIR"; then | |
587 | lib_order="-liconv -lc" | |
588 | else | |
589 | lib_order="-lc -liconv" | |
590 | fi | |
591 | ||
592 | NO_ICONV=YesPlease | |
593 | ||
594 | for l in $lib_order; do | |
595 | if test "$l" = "-liconv"; then | |
596 | NEEDS_LIBICONV=YesPlease | |
597 | else | |
598 | NEEDS_LIBICONV= | |
599 | fi | |
600 | ||
601 | old_LIBS="$LIBS" | |
602 | LIBS="$LIBS $l" | |
603 | AC_MSG_CHECKING([for iconv in $l]) | |
604 | AC_LINK_IFELSE([ICONVTEST_SRC], | |
605 | [AC_MSG_RESULT([yes]) | |
606 | NO_ICONV= | |
607 | break], | |
608 | [AC_MSG_RESULT([no])]) | |
609 | LIBS="$old_LIBS" | |
610 | done | |
611 | ||
612 | #in case of break | |
613 | LIBS="$old_LIBS" | |
614 | ||
615 | GIT_UNSTASH_FLAGS($ICONVDIR) | |
616 | ||
617 | GIT_CONF_SUBST([NEEDS_LIBICONV]) | |
618 | GIT_CONF_SUBST([NO_ICONV]) | |
619 | ||
620 | if test -n "$NO_ICONV"; then | |
621 | NEEDS_LIBICONV= | |
622 | fi | |
623 | ||
624 | fi | |
625 | ||
626 | # | |
627 | # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib. | |
628 | ||
629 | GIT_STASH_FLAGS($ZLIB_PATH) | |
630 | ||
631 | AC_DEFUN([ZLIBTEST_SRC], [ | |
632 | AC_LANG_PROGRAM([#include <zlib.h>], | |
633 | [deflateBound(0, 0);])]) | |
634 | AC_MSG_CHECKING([for deflateBound in -lz]) | |
635 | old_LIBS="$LIBS" | |
636 | LIBS="$LIBS -lz" | |
637 | AC_LINK_IFELSE([ZLIBTEST_SRC], | |
638 | [AC_MSG_RESULT([yes])], | |
639 | [AC_MSG_RESULT([no]) | |
640 | NO_DEFLATE_BOUND=yes]) | |
641 | LIBS="$old_LIBS" | |
642 | ||
643 | GIT_UNSTASH_FLAGS($ZLIB_PATH) | |
644 | ||
645 | GIT_CONF_SUBST([NO_DEFLATE_BOUND]) | |
646 | ||
647 | # | |
648 | # Define NEEDS_SOCKET if linking with libc is not enough (SunOS, | |
649 | # Patrick Mauritz). | |
650 | AC_CHECK_LIB([c], [socket], | |
651 | [NEEDS_SOCKET=], | |
652 | [NEEDS_SOCKET=YesPlease]) | |
653 | GIT_CONF_SUBST([NEEDS_SOCKET]) | |
654 | test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket" | |
655 | ||
656 | # | |
657 | # The next few tests will define NEEDS_RESOLV if linking with | |
658 | # libresolv provides some of the functions we would normally get | |
659 | # from libc. | |
660 | NEEDS_RESOLV= | |
661 | # | |
662 | # Define NO_INET_NTOP if linking with -lresolv is not enough. | |
663 | # Solaris 2.7 in particular hos inet_ntop in -lresolv. | |
664 | NO_INET_NTOP= | |
665 | AC_CHECK_FUNC([inet_ntop], | |
666 | [], | |
667 | [AC_CHECK_LIB([resolv], [inet_ntop], | |
668 | [NEEDS_RESOLV=YesPlease], | |
669 | [NO_INET_NTOP=YesPlease]) | |
670 | ]) | |
671 | GIT_CONF_SUBST([NO_INET_NTOP]) | |
672 | # | |
673 | # Define NO_INET_PTON if linking with -lresolv is not enough. | |
674 | # Solaris 2.7 in particular hos inet_pton in -lresolv. | |
675 | NO_INET_PTON= | |
676 | AC_CHECK_FUNC([inet_pton], | |
677 | [], | |
678 | [AC_CHECK_LIB([resolv], [inet_pton], | |
679 | [NEEDS_RESOLV=YesPlease], | |
680 | [NO_INET_PTON=YesPlease]) | |
681 | ]) | |
682 | GIT_CONF_SUBST([NO_INET_PTON]) | |
683 | # | |
684 | # Define NO_HSTRERROR if linking with -lresolv is not enough. | |
685 | # Solaris 2.6 in particular has no hstrerror, even in -lresolv. | |
686 | NO_HSTRERROR= | |
687 | AC_CHECK_FUNC([hstrerror], | |
688 | [], | |
689 | [AC_CHECK_LIB([resolv], [hstrerror], | |
690 | [NEEDS_RESOLV=YesPlease], | |
691 | [NO_HSTRERROR=YesPlease]) | |
692 | ]) | |
693 | GIT_CONF_SUBST([NO_HSTRERROR]) | |
694 | ||
695 | dnl This must go after all the possible places for its initialization, | |
696 | dnl in the AC_CHECK_FUNC invocations above. | |
697 | GIT_CONF_SUBST([NEEDS_RESOLV]) | |
698 | # | |
699 | # If any of the above tests determined that -lresolv is needed at | |
700 | # build-time, also set it here for remaining configure-time checks. | |
701 | test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv" | |
702 | ||
703 | AC_CHECK_LIB([c], [basename], | |
704 | [NEEDS_LIBGEN=], | |
705 | [NEEDS_LIBGEN=YesPlease]) | |
706 | GIT_CONF_SUBST([NEEDS_LIBGEN]) | |
707 | test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen" | |
708 | ||
709 | AC_CHECK_LIB([c], [gettext], | |
710 | [LIBC_CONTAINS_LIBINTL=YesPlease], | |
711 | [LIBC_CONTAINS_LIBINTL=]) | |
712 | GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL]) | |
713 | ||
714 | # | |
715 | # Define NO_GETTEXT if you don't want Git output to be translated. | |
716 | # A translated Git requires GNU libintl or another gettext implementation | |
717 | AC_CHECK_HEADER([libintl.h], | |
718 | [NO_GETTEXT=], | |
719 | [NO_GETTEXT=YesPlease]) | |
720 | GIT_CONF_SUBST([NO_GETTEXT]) | |
721 | ||
722 | if test -z "$NO_GETTEXT"; then | |
723 | test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl" | |
724 | fi | |
725 | ||
726 | ## Checks for header files. | |
727 | AC_MSG_NOTICE([CHECKS for header files]) | |
728 | # | |
729 | # Define NO_SYS_SELECT_H if you don't have sys/select.h. | |
730 | AC_CHECK_HEADER([sys/select.h], | |
731 | [NO_SYS_SELECT_H=], | |
732 | [NO_SYS_SELECT_H=UnfortunatelyYes]) | |
733 | GIT_CONF_SUBST([NO_SYS_SELECT_H]) | |
734 | # | |
735 | # Define NO_SYS_POLL_H if you don't have sys/poll.h | |
736 | AC_CHECK_HEADER([sys/poll.h], | |
737 | [NO_SYS_POLL_H=], | |
738 | [NO_SYS_POLL_H=UnfortunatelyYes]) | |
739 | GIT_CONF_SUBST([NO_SYS_POLL_H]) | |
740 | # | |
741 | # Define NO_INTTYPES_H if you don't have inttypes.h | |
742 | AC_CHECK_HEADER([inttypes.h], | |
743 | [NO_INTTYPES_H=], | |
744 | [NO_INTTYPES_H=UnfortunatelyYes]) | |
745 | GIT_CONF_SUBST([NO_INTTYPES_H]) | |
746 | # | |
747 | # Define OLD_ICONV if your library has an old iconv(), where the second | |
748 | # (input buffer pointer) parameter is declared with type (const char **). | |
749 | AC_DEFUN([OLDICONVTEST_SRC], [ | |
750 | AC_LANG_PROGRAM([[ | |
751 | #include <iconv.h> | |
752 | ||
753 | extern size_t iconv(iconv_t cd, | |
754 | char **inbuf, size_t *inbytesleft, | |
755 | char **outbuf, size_t *outbytesleft); | |
756 | ]], [])]) | |
757 | ||
758 | GIT_STASH_FLAGS($ICONVDIR) | |
759 | ||
760 | AC_MSG_CHECKING([for old iconv()]) | |
761 | AC_COMPILE_IFELSE([OLDICONVTEST_SRC], | |
762 | [AC_MSG_RESULT([no])], | |
763 | [AC_MSG_RESULT([yes]) | |
764 | OLD_ICONV=UnfortunatelyYes]) | |
765 | ||
766 | GIT_UNSTASH_FLAGS($ICONVDIR) | |
767 | ||
768 | GIT_CONF_SUBST([OLD_ICONV]) | |
769 | ||
770 | ## Checks for typedefs, structures, and compiler characteristics. | |
771 | AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics]) | |
772 | # | |
773 | TYPE_SOCKLEN_T | |
774 | case $ac_cv_type_socklen_t in | |
775 | yes) SOCKLEN_T='';; | |
776 | *) SOCKLEN_T=$git_cv_socklen_t_equiv;; | |
777 | esac | |
778 | GIT_CONF_SUBST([SOCKLEN_T]) | |
779 | ||
780 | # | |
781 | # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval. | |
782 | AC_CHECK_TYPES([struct itimerval], | |
783 | [NO_STRUCT_ITIMERVAL=], | |
784 | [NO_STRUCT_ITIMERVAL=UnfortunatelyYes], | |
785 | [#include <sys/time.h>]) | |
786 | GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL]) | |
787 | # | |
788 | # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists. | |
789 | # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor | |
790 | # stat.st_mtimespec.tv_nsec exists. | |
791 | AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec]) | |
792 | AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec]) | |
793 | if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then | |
794 | USE_ST_TIMESPEC=YesPlease | |
795 | GIT_CONF_SUBST([USE_ST_TIMESPEC]) | |
796 | elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then | |
797 | NO_NSEC=YesPlease | |
798 | GIT_CONF_SUBST([NO_NSEC]) | |
799 | fi | |
800 | # | |
801 | # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks | |
802 | # d_type in struct dirent (latest Cygwin -- will be fixed soonish). | |
803 | AC_CHECK_MEMBER(struct dirent.d_type, | |
804 | [NO_D_TYPE_IN_DIRENT=], | |
805 | [NO_D_TYPE_IN_DIRENT=YesPlease], | |
806 | [#include <dirent.h>]) | |
807 | GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT]) | |
808 | # | |
809 | # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd | |
810 | # in the C library. | |
811 | AC_CHECK_MEMBER(struct passwd.pw_gecos, | |
812 | [NO_GECOS_IN_PWENT=], | |
813 | [NO_GECOS_IN_PWENT=YesPlease], | |
814 | [#include <pwd.h>]) | |
815 | GIT_CONF_SUBST([NO_GECOS_IN_PWENT]) | |
816 | # | |
817 | # Define NO_SOCKADDR_STORAGE if your platform does not have struct | |
818 | # sockaddr_storage. | |
819 | AC_CHECK_TYPE(struct sockaddr_storage, | |
820 | [NO_SOCKADDR_STORAGE=], | |
821 | [NO_SOCKADDR_STORAGE=YesPlease],[ | |
822 | #include <sys/types.h> | |
823 | #include <sys/socket.h> | |
824 | ]) | |
825 | GIT_CONF_SUBST([NO_SOCKADDR_STORAGE]) | |
826 | # | |
827 | # Define NO_IPV6 if you lack IPv6 support and getaddrinfo(). | |
828 | AC_CHECK_TYPE([struct addrinfo],[ | |
829 | GIT_CHECK_FUNC([getaddrinfo], | |
830 | [NO_IPV6=], | |
831 | [NO_IPV6=YesPlease]) | |
832 | ],[NO_IPV6=YesPlease],[ | |
833 | #include <sys/types.h> | |
834 | #include <sys/socket.h> | |
835 | #include <netdb.h> | |
836 | ]) | |
837 | GIT_CONF_SUBST([NO_IPV6]) | |
838 | # | |
839 | # Define NO_REGEX if your C library lacks regex support with REG_STARTEND | |
840 | # feature. | |
841 | AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND], | |
842 | [ac_cv_c_regex_with_reg_startend], [ | |
843 | AC_EGREP_CPP(yippeeyeswehaveit, | |
844 | AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT | |
845 | #include <regex.h> | |
846 | ], | |
847 | [#ifdef REG_STARTEND | |
848 | yippeeyeswehaveit | |
849 | #endif | |
850 | ]), | |
851 | [ac_cv_c_regex_with_reg_startend=yes], | |
852 | [ac_cv_c_regex_with_reg_startend=no]) | |
853 | ]) | |
854 | if test $ac_cv_c_regex_with_reg_startend = yes; then | |
855 | NO_REGEX= | |
856 | else | |
857 | NO_REGEX=YesPlease | |
858 | fi | |
859 | GIT_CONF_SUBST([NO_REGEX]) | |
860 | # | |
861 | # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds | |
862 | # when attempting to read from an fopen'ed directory. | |
863 | AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory], | |
864 | [ac_cv_fread_reads_directories], | |
865 | [ | |
866 | AC_RUN_IFELSE( | |
867 | [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], | |
868 | [[char c; | |
869 | FILE *f = fopen(".", "r"); | |
870 | return f && fread(&c, 1, 1, f)]])], | |
871 | [ac_cv_fread_reads_directories=no], | |
872 | [ac_cv_fread_reads_directories=yes]) | |
873 | ]) | |
874 | if test $ac_cv_fread_reads_directories = yes; then | |
875 | FREAD_READS_DIRECTORIES=UnfortunatelyYes | |
876 | else | |
877 | FREAD_READS_DIRECTORIES= | |
878 | fi | |
879 | GIT_CONF_SUBST([FREAD_READS_DIRECTORIES]) | |
880 | # | |
881 | # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf() | |
882 | # or vsnprintf() return -1 instead of number of characters which would | |
883 | # have been written to the final string if enough space had been available. | |
884 | AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value], | |
885 | [ac_cv_snprintf_returns_bogus], | |
886 | [ | |
887 | AC_RUN_IFELSE( | |
888 | [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT | |
889 | #include "stdarg.h" | |
890 | ||
891 | int test_vsnprintf(char *str, size_t maxsize, const char *format, ...) | |
892 | { | |
893 | int ret; | |
894 | va_list ap; | |
895 | va_start(ap, format); | |
896 | ret = vsnprintf(str, maxsize, format, ap); | |
897 | va_end(ap); | |
898 | return ret; | |
899 | }], | |
900 | [[char buf[6]; | |
901 | if (test_vsnprintf(buf, 3, "%s", "12345") != 5 | |
902 | || strcmp(buf, "12")) return 1; | |
903 | if (snprintf(buf, 3, "%s", "12345") != 5 | |
904 | || strcmp(buf, "12")) return 1]])], | |
905 | [ac_cv_snprintf_returns_bogus=no], | |
906 | [ac_cv_snprintf_returns_bogus=yes]) | |
907 | ]) | |
908 | if test $ac_cv_snprintf_returns_bogus = yes; then | |
909 | SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes | |
910 | else | |
911 | SNPRINTF_RETURNS_BOGUS= | |
912 | fi | |
913 | GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS]) | |
914 | # | |
915 | # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type | |
916 | # bits in mode values. | |
917 | AC_CACHE_CHECK([whether the platform uses typical file type bits], | |
918 | [ac_cv_sane_mode_bits], [ | |
919 | AC_EGREP_CPP(yippeeyeswehaveit, | |
920 | AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], | |
921 | [#if S_IFMT == 0170000 && \ | |
922 | S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \ | |
923 | S_IFBLK == 0060000 && S_IFCHR == 0020000 && \ | |
924 | S_IFIFO == 0010000 && S_IFSOCK == 0140000 | |
925 | yippeeyeswehaveit | |
926 | #endif | |
927 | ]), | |
928 | [ac_cv_sane_mode_bits=yes], | |
929 | [ac_cv_sane_mode_bits=no]) | |
930 | ]) | |
931 | if test $ac_cv_sane_mode_bits = yes; then | |
932 | NEEDS_MODE_TRANSLATION= | |
933 | else | |
934 | NEEDS_MODE_TRANSLATION=UnfortunatelyYes | |
935 | fi | |
936 | GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION]) | |
937 | ||
938 | ||
939 | ## Checks for library functions. | |
940 | ## (in default C library and libraries checked by AC_CHECK_LIB) | |
941 | AC_MSG_NOTICE([CHECKS for library functions]) | |
942 | # | |
943 | # Define NO_LIBGEN_H if you don't have libgen.h. | |
944 | AC_CHECK_HEADER([libgen.h], | |
945 | [NO_LIBGEN_H=], | |
946 | [NO_LIBGEN_H=YesPlease]) | |
947 | GIT_CONF_SUBST([NO_LIBGEN_H]) | |
948 | # | |
949 | # Define HAVE_PATHS_H if you have paths.h. | |
950 | AC_CHECK_HEADER([paths.h], | |
951 | [HAVE_PATHS_H=YesPlease], | |
952 | [HAVE_PATHS_H=]) | |
953 | GIT_CONF_SUBST([HAVE_PATHS_H]) | |
954 | # | |
955 | # Define HAVE_LIBCHARSET_H if have libcharset.h | |
956 | AC_CHECK_HEADER([libcharset.h], | |
957 | [HAVE_LIBCHARSET_H=YesPlease], | |
958 | [HAVE_LIBCHARSET_H=]) | |
959 | GIT_CONF_SUBST([HAVE_LIBCHARSET_H]) | |
960 | # | |
961 | # Define HAVE_STRINGS_H if you have strings.h | |
962 | AC_CHECK_HEADER([strings.h], | |
963 | [HAVE_STRINGS_H=YesPlease], | |
964 | [HAVE_STRINGS_H=]) | |
965 | GIT_CONF_SUBST([HAVE_STRINGS_H]) | |
966 | # Define CHARSET_LIB if libiconv does not export the locale_charset symbol | |
967 | # and libcharset does | |
968 | CHARSET_LIB= | |
969 | AC_CHECK_LIB([iconv], [locale_charset], | |
970 | [CHARSET_LIB=-liconv], | |
971 | [AC_CHECK_LIB([charset], [locale_charset], | |
972 | [CHARSET_LIB=-lcharset])]) | |
973 | GIT_CONF_SUBST([CHARSET_LIB]) | |
974 | # | |
975 | # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available. | |
976 | GIT_CHECK_FUNC(clock_gettime, | |
977 | [HAVE_CLOCK_GETTIME=YesPlease], | |
978 | [HAVE_CLOCK_GETTIME=]) | |
979 | GIT_CONF_SUBST([HAVE_CLOCK_GETTIME]) | |
980 | ||
981 | AC_DEFUN([CLOCK_MONOTONIC_SRC], [ | |
982 | AC_LANG_PROGRAM([[ | |
983 | #include <time.h> | |
984 | clockid_t id = CLOCK_MONOTONIC; | |
985 | ]])]) | |
986 | ||
987 | # | |
988 | # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available. | |
989 | AC_MSG_CHECKING([for CLOCK_MONOTONIC]) | |
990 | AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC], | |
991 | [AC_MSG_RESULT([yes]) | |
992 | HAVE_CLOCK_MONOTONIC=YesPlease], | |
993 | [AC_MSG_RESULT([no]) | |
994 | HAVE_CLOCK_MONOTONIC=]) | |
995 | GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC]) | |
996 | # | |
997 | # Define NO_SETITIMER if you don't have setitimer. | |
998 | GIT_CHECK_FUNC(setitimer, | |
999 | [NO_SETITIMER=], | |
1000 | [NO_SETITIMER=YesPlease]) | |
1001 | GIT_CONF_SUBST([NO_SETITIMER]) | |
1002 | # | |
1003 | # Define NO_STRCASESTR if you don't have strcasestr. | |
1004 | GIT_CHECK_FUNC(strcasestr, | |
1005 | [NO_STRCASESTR=], | |
1006 | [NO_STRCASESTR=YesPlease]) | |
1007 | GIT_CONF_SUBST([NO_STRCASESTR]) | |
1008 | # | |
1009 | # Define NO_MEMMEM if you don't have memmem. | |
1010 | GIT_CHECK_FUNC(memmem, | |
1011 | [NO_MEMMEM=], | |
1012 | [NO_MEMMEM=YesPlease]) | |
1013 | GIT_CONF_SUBST([NO_MEMMEM]) | |
1014 | # | |
1015 | # Define NO_STRLCPY if you don't have strlcpy. | |
1016 | GIT_CHECK_FUNC(strlcpy, | |
1017 | [NO_STRLCPY=], | |
1018 | [NO_STRLCPY=YesPlease]) | |
1019 | GIT_CONF_SUBST([NO_STRLCPY]) | |
1020 | # | |
1021 | # Define NO_UINTMAX_T if your platform does not have uintmax_t | |
1022 | AC_CHECK_TYPE(uintmax_t, | |
1023 | [NO_UINTMAX_T=], | |
1024 | [NO_UINTMAX_T=YesPlease],[ | |
1025 | #include <inttypes.h> | |
1026 | ]) | |
1027 | GIT_CONF_SUBST([NO_UINTMAX_T]) | |
1028 | # | |
1029 | # Define NO_STRTOUMAX if you don't have strtoumax in the C library. | |
1030 | GIT_CHECK_FUNC(strtoumax, | |
1031 | [NO_STRTOUMAX=], | |
1032 | [NO_STRTOUMAX=YesPlease]) | |
1033 | GIT_CONF_SUBST([NO_STRTOUMAX]) | |
1034 | # | |
1035 | # Define NO_SETENV if you don't have setenv in the C library. | |
1036 | GIT_CHECK_FUNC(setenv, | |
1037 | [NO_SETENV=], | |
1038 | [NO_SETENV=YesPlease]) | |
1039 | GIT_CONF_SUBST([NO_SETENV]) | |
1040 | # | |
1041 | # Define NO_UNSETENV if you don't have unsetenv in the C library. | |
1042 | GIT_CHECK_FUNC(unsetenv, | |
1043 | [NO_UNSETENV=], | |
1044 | [NO_UNSETENV=YesPlease]) | |
1045 | GIT_CONF_SUBST([NO_UNSETENV]) | |
1046 | # | |
1047 | # Define NO_MKDTEMP if you don't have mkdtemp in the C library. | |
1048 | GIT_CHECK_FUNC(mkdtemp, | |
1049 | [NO_MKDTEMP=], | |
1050 | [NO_MKDTEMP=YesPlease]) | |
1051 | GIT_CONF_SUBST([NO_MKDTEMP]) | |
1052 | # | |
1053 | # Define NO_INITGROUPS if you don't have initgroups in the C library. | |
1054 | GIT_CHECK_FUNC(initgroups, | |
1055 | [NO_INITGROUPS=], | |
1056 | [NO_INITGROUPS=YesPlease]) | |
1057 | GIT_CONF_SUBST([NO_INITGROUPS]) | |
1058 | # | |
1059 | # Define HAVE_GETDELIM if you have getdelim in the C library. | |
1060 | GIT_CHECK_FUNC(getdelim, | |
1061 | [HAVE_GETDELIM=YesPlease], | |
1062 | [HAVE_GETDELIM=]) | |
1063 | GIT_CONF_SUBST([HAVE_GETDELIM]) | |
1064 | # | |
1065 | # | |
1066 | # Define NO_MMAP if you want to avoid mmap. | |
1067 | # | |
1068 | # Define NO_ICONV if your libc does not properly support iconv. | |
1069 | ||
1070 | AC_DEFUN([BSD_SYSCTL_SRC], [ | |
1071 | AC_LANG_PROGRAM([[ | |
1072 | #include <stddef.h> | |
1073 | #include <sys/types.h> | |
1074 | #include <sys/sysctl.h> | |
1075 | ]],[[ | |
1076 | int val, mib[2]; | |
1077 | size_t len; | |
1078 | mib[0] = CTL_HW; | |
1079 | mib[1] = 1; | |
1080 | len = sizeof(val); | |
1081 | return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0; | |
1082 | ]])]) | |
1083 | ||
1084 | # | |
1085 | # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available. | |
1086 | AC_MSG_CHECKING([for BSD sysctl]) | |
1087 | AC_COMPILE_IFELSE([BSD_SYSCTL_SRC], | |
1088 | [AC_MSG_RESULT([yes]) | |
1089 | HAVE_BSD_SYSCTL=YesPlease], | |
1090 | [AC_MSG_RESULT([no]) | |
1091 | HAVE_BSD_SYSCTL=]) | |
1092 | GIT_CONF_SUBST([HAVE_BSD_SYSCTL]) | |
1093 | ||
1094 | ## Other checks. | |
1095 | # Define USE_PIC if you need the main git objects to be built with -fPIC | |
1096 | # in order to build and link perl/Git.so. x86-64 seems to need this. | |
1097 | # | |
1098 | # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link. | |
1099 | # Enable it on Windows. By default, symrefs are still used. | |
1100 | # | |
1101 | # Define NO_PTHREADS if we do not have pthreads. | |
1102 | # | |
1103 | # Define PTHREAD_LIBS to the linker flag used for Pthread support. | |
1104 | AC_DEFUN([PTHREADTEST_SRC], [ | |
1105 | AC_LANG_PROGRAM([[ | |
1106 | #include <pthread.h> | |
1107 | static void *noop(void *ignore) { return ignore; } | |
1108 | ]], [[ | |
1109 | pthread_mutex_t test_mutex; | |
1110 | pthread_key_t test_key; | |
1111 | pthread_t th; | |
1112 | int retcode = 0; | |
1113 | void *ret = (void *)0; | |
1114 | retcode |= pthread_key_create(&test_key, (void *)0); | |
1115 | retcode |= pthread_mutex_init(&test_mutex,(void *)0); | |
1116 | retcode |= pthread_mutex_lock(&test_mutex); | |
1117 | retcode |= pthread_mutex_unlock(&test_mutex); | |
1118 | retcode |= pthread_create(&th, ret, noop, ret); | |
1119 | retcode |= pthread_join(th, &ret); | |
1120 | return retcode; | |
1121 | ]])]) | |
1122 | ||
1123 | dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM( | |
1124 | dnl [[#include <pthread.h>]], | |
1125 | dnl [[pthread_mutex_t test_mutex;]] | |
1126 | dnl )]) | |
1127 | ||
1128 | NO_PTHREADS=UnfortunatelyYes | |
1129 | PTHREAD_LIBS= | |
1130 | ||
1131 | if test -n "$USER_NOPTHREAD"; then | |
1132 | AC_MSG_NOTICE([Skipping POSIX Threads at user request.]) | |
1133 | # handle these separately since PTHREAD_CFLAGS could be '-lpthreads | |
1134 | # -D_REENTRANT' or some such. | |
1135 | elif test -z "$PTHREAD_CFLAGS"; then | |
1136 | threads_found=no | |
1137 | # Attempt to compile and link some code using pthreads to determine | |
1138 | # required linker flags. The order is somewhat important here: We | |
1139 | # first try it without any extra flags, to catch systems where | |
1140 | # pthreads are part of the C library, then go on testing various other | |
1141 | # flags. We do so to avoid false positives. For example, on Mac OS X | |
1142 | # pthreads are part of the C library; moreover, the compiler allows us | |
1143 | # to add "-mt" to the CFLAGS (although it will do nothing except | |
1144 | # trigger a warning about an unused flag). Hence if we checked for | |
1145 | # "-mt" before "" we would end up picking it. But unfortunately this | |
1146 | # would then trigger compiler warnings on every single file we compile. | |
1147 | for opt in "" -mt -pthread -lpthread; do | |
1148 | old_CFLAGS="$CFLAGS" | |
1149 | old_LIBS="$LIBS" | |
1150 | case "$opt" in | |
1151 | -l*) LIBS="$opt $LIBS" ;; | |
1152 | *) CFLAGS="$opt $CFLAGS" ;; | |
1153 | esac | |
1154 | ||
1155 | AC_MSG_CHECKING([for POSIX Threads with '$opt']) | |
1156 | AC_LINK_IFELSE([PTHREADTEST_SRC], | |
1157 | [AC_MSG_RESULT([yes]) | |
1158 | NO_PTHREADS= | |
1159 | PTHREAD_LIBS="$opt" | |
1160 | PTHREAD_CFLAGS="$opt" | |
1161 | threads_found=yes | |
1162 | break | |
1163 | ], | |
1164 | [AC_MSG_RESULT([no])]) | |
1165 | CFLAGS="$old_CFLAGS" | |
1166 | LIBS="$old_LIBS" | |
1167 | done | |
1168 | if test $threads_found != yes; then | |
1169 | AC_CHECK_LIB([pthread], [pthread_create], | |
1170 | [PTHREAD_LIBS="-lpthread"], | |
1171 | [NO_PTHREADS=UnfortunatelyYes]) | |
1172 | fi | |
1173 | else | |
1174 | old_CFLAGS="$CFLAGS" | |
1175 | CFLAGS="$PTHREAD_CFLAGS $CFLAGS" | |
1176 | AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS']) | |
1177 | AC_LINK_IFELSE([PTHREADTEST_SRC], | |
1178 | [AC_MSG_RESULT([yes]) | |
1179 | NO_PTHREADS= | |
1180 | PTHREAD_LIBS="$PTHREAD_CFLAGS" | |
1181 | ], | |
1182 | [AC_MSG_RESULT([no])]) | |
1183 | ||
1184 | CFLAGS="$old_CFLAGS" | |
1185 | fi | |
1186 | ||
1187 | CFLAGS="$old_CFLAGS" | |
1188 | ||
1189 | GIT_CONF_SUBST([PTHREAD_CFLAGS]) | |
1190 | GIT_CONF_SUBST([PTHREAD_LIBS]) | |
1191 | GIT_CONF_SUBST([NO_PTHREADS]) | |
1192 | ||
1193 | ## Output files | |
1194 | AC_CONFIG_FILES(["${config_file}":"${config_in}"]) | |
1195 | AC_OUTPUT |