]>
Commit | Line | Data |
---|---|---|
1 | # -*- Autoconf -*- | |
2 | # Process this file with autoconf to produce a configure script. | |
3 | ||
4 | ## Definitions of private macros. | |
5 | ||
6 | # GIT_CONF_SUBST(VAL, VAR) | |
7 | # ------------------------ | |
8 | # Cause the line "VAR=VAL" to be eventually appended to ${config_file}. | |
9 | AC_DEFUN([GIT_CONF_SUBST], | |
10 | [AC_REQUIRE([GIT_CONF_SUBST_INIT]) | |
11 | config_appended_defs="$config_appended_defs${newline}dnl | |
12 | $1=m4_if([$#],[1],[${$1}],[$2])"]) | |
13 | ||
14 | # GIT_CONF_SUBST_INIT | |
15 | # ------------------- | |
16 | # Prepare shell variables and autoconf machine required by later calls | |
17 | # to GIT_CONF_SUBST. | |
18 | AC_DEFUN([GIT_CONF_SUBST_INIT], | |
19 | [config_appended_defs=; newline=' | |
20 | ' | |
21 | AC_CONFIG_COMMANDS([$config_file], | |
22 | [echo "$config_appended_defs" >> "$config_file"], | |
23 | [config_file=$config_file | |
24 | config_appended_defs="$config_appended_defs"])]) | |
25 | ||
26 | # GIT_ARG_SET_PATH(PROGRAM) | |
27 | # ------------------------- | |
28 | # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM | |
29 | # Optional second argument allows setting NO_PROGRAM=YesPlease if | |
30 | # --without-PROGRAM version used. | |
31 | AC_DEFUN([GIT_ARG_SET_PATH], | |
32 | [AC_ARG_WITH([$1], | |
33 | [AS_HELP_STRING([--with-$1=PATH], | |
34 | [provide PATH to $1])], | |
35 | [GIT_CONF_APPEND_PATH([$1], [$2])], | |
36 | [])]) | |
37 | ||
38 | # GIT_CONF_APPEND_PATH(PROGRAM) | |
39 | # ----------------------------- | |
40 | # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH | |
41 | # Used by GIT_ARG_SET_PATH(PROGRAM) | |
42 | # Optional second argument allows setting NO_PROGRAM=YesPlease if | |
43 | # --without-PROGRAM is used. | |
44 | AC_DEFUN([GIT_CONF_APPEND_PATH], | |
45 | [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl | |
46 | if test "$withval" = "no"; then | |
47 | if test -n "$2"; then | |
48 | GIT_UC_PROGRAM[]_PATH=$withval | |
49 | AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM]) | |
50 | GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease]) | |
51 | GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, []) | |
52 | else | |
53 | AC_MSG_ERROR([You cannot use git without $1]) | |
54 | fi | |
55 | else | |
56 | if test "$withval" = "yes"; then | |
57 | AC_MSG_WARN([You should provide path for --with-$1=PATH]) | |
58 | else | |
59 | GIT_UC_PROGRAM[]_PATH=$withval | |
60 | AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval]) | |
61 | GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval]) | |
62 | fi | |
63 | fi | |
64 | m4_popdef([GIT_UC_PROGRAM])]) | |
65 | ||
66 | # GIT_PARSE_WITH(PACKAGE) | |
67 | # ----------------------- | |
68 | # For use in AC_ARG_WITH action-if-found, for packages default ON. | |
69 | # * Set NO_PACKAGE=YesPlease for --without-PACKAGE | |
70 | # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH | |
71 | # * Unset NO_PACKAGE for --with-PACKAGE without ARG | |
72 | AC_DEFUN([GIT_PARSE_WITH], | |
73 | [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl | |
74 | if test "$withval" = "no"; then | |
75 | NO_[]GIT_UC_PACKAGE=YesPlease | |
76 | elif test "$withval" = "yes"; then | |
77 | NO_[]GIT_UC_PACKAGE= | |
78 | else | |
79 | NO_[]GIT_UC_PACKAGE= | |
80 | GIT_UC_PACKAGE[]DIR=$withval | |
81 | AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval]) | |
82 | GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval]) | |
83 | fi | |
84 | m4_popdef([GIT_UC_PACKAGE])]) | |
85 | ||
86 | # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT) | |
87 | # ----------------------------------------------------- | |
88 | # Set VAR to the value specied by --with-WITHNAME. | |
89 | # No verification of arguments is performed, but warnings are issued | |
90 | # if either 'yes' or 'no' is specified. | |
91 | # HELP_TEXT is presented when --help is called. | |
92 | # This is a direct way to allow setting variables in the Makefile. | |
93 | AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR], | |
94 | [AC_ARG_WITH([$1], | |
95 | [AS_HELP_STRING([--with-$1=VALUE], $3)], | |
96 | if test -n "$withval"; then | |
97 | if test "$withval" = "yes" -o "$withval" = "no"; then | |
98 | AC_MSG_WARN([You likely do not want either 'yes' or 'no' as] | |
99 | [a value for $1 ($2). Maybe you do...?]) | |
100 | fi | |
101 | AC_MSG_NOTICE([Setting $2 to $withval]) | |
102 | GIT_CONF_SUBST([$2], [$withval]) | |
103 | fi)])# GIT_PARSE_WITH_SET_MAKE_VAR | |
104 | ||
105 | # | |
106 | # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE) | |
107 | # ----------------------------------------- | |
108 | # Similar to AC_CHECK_FUNC, but on systems that do not generate | |
109 | # warnings for missing prototypes (e.g. FreeBSD when compiling without | |
110 | # -Wall), it does not work. By looking for function definition in | |
111 | # libraries, this problem can be worked around. | |
112 | AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[ | |
113 | AC_SEARCH_LIBS([$1],, | |
114 | [$2],[$3]) | |
115 | ],[$3])]) | |
116 | ||
117 | # | |
118 | # GIT_STASH_FLAGS(BASEPATH_VAR) | |
119 | # ----------------------------- | |
120 | # Allow for easy stashing of LDFLAGS and CPPFLAGS before running | |
121 | # tests that may want to take user settings into account. | |
122 | AC_DEFUN([GIT_STASH_FLAGS],[ | |
123 | if test -n "$1"; then | |
124 | old_CPPFLAGS="$CPPFLAGS" | |
125 | old_LDFLAGS="$LDFLAGS" | |
126 | CPPFLAGS="-I$1/include $CPPFLAGS" | |
127 | LDFLAGS="-L$1/$lib $LDFLAGS" | |
128 | fi | |
129 | ]) | |
130 | ||
131 | dnl | |
132 | dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR) | |
133 | dnl ----------------------------- | |
134 | dnl Restore the stashed *FLAGS values. | |
135 | AC_DEFUN([GIT_UNSTASH_FLAGS],[ | |
136 | if test -n "$1"; then | |
137 | CPPFLAGS="$old_CPPFLAGS" | |
138 | LDFLAGS="$old_LDFLAGS" | |
139 | fi | |
140 | ]) | |
141 | ||
142 | ## Configure body starts here. | |
143 | ||
144 | AC_PREREQ(2.59) | |
145 | AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org]) | |
146 | ||
147 | AC_CONFIG_SRCDIR([git.c]) | |
148 | ||
149 | config_file=config.mak.autogen | |
150 | config_in=config.mak.in | |
151 | ||
152 | GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease]) | |
153 | ||
154 | # Directories holding "saner" versions of common or POSIX binaries. | |
155 | AC_ARG_WITH([sane-tool-path], | |
156 | [AS_HELP_STRING( | |
157 | [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]], | |
158 | [Directories to prepend to PATH in build system and generated scripts])], | |
159 | [if test "$withval" = "no"; then | |
160 | withval='' | |
161 | else | |
162 | AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval']) | |
163 | fi | |
164 | GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])], | |
165 | [# If the "--with-sane-tool-path" option was not given, don't touch | |
166 | # SANE_TOOL_PATH here, but let defaults in Makefile take care of it. | |
167 | # This should minimize spurious differences in the behaviour of the | |
168 | # Git build system when configure is used w.r.t. when it is not. | |
169 | :]) | |
170 | ||
171 | ## Site configuration related to programs (before tests) | |
172 | ## --with-PACKAGE[=ARG] and --without-PACKAGE | |
173 | # | |
174 | # Set lib to alternative name of lib directory (e.g. lib64) | |
175 | AC_ARG_WITH([lib], | |
176 | [AS_HELP_STRING([--with-lib=ARG], | |
177 | [ARG specifies alternative name for lib directory])], | |
178 | [if test "$withval" = "no" || test "$withval" = "yes"; then | |
179 | AC_MSG_WARN([You should provide name for --with-lib=ARG]) | |
180 | else | |
181 | lib=$withval | |
182 | AC_MSG_NOTICE([Setting lib to '$lib']) | |
183 | GIT_CONF_SUBST([lib]) | |
184 | fi]) | |
185 | ||
186 | if test -z "$lib"; then | |
187 | AC_MSG_NOTICE([Setting lib to 'lib' (the default)]) | |
188 | lib=lib | |
189 | fi | |
190 | ||
191 | AC_ARG_ENABLE([pthreads], | |
192 | [AS_HELP_STRING([--enable-pthreads=FLAGS], | |
193 | [FLAGS is the value to pass to the compiler to enable POSIX Threads.] | |
194 | [The default if FLAGS is not specified is to try first -pthread] | |
195 | [and then -lpthread.] | |
196 | [--disable-pthreads will disable threading.])], | |
197 | [ | |
198 | if test "x$enableval" = "xyes"; then | |
199 | AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads]) | |
200 | elif test "x$enableval" != "xno"; then | |
201 | PTHREAD_CFLAGS=$enableval | |
202 | AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads]) | |
203 | else | |
204 | AC_MSG_NOTICE([POSIX Threads will be disabled.]) | |
205 | NO_PTHREADS=YesPlease | |
206 | USER_NOPTHREAD=1 | |
207 | fi], | |
208 | [ | |
209 | AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.]) | |
210 | ]) | |
211 | ||
212 | # Define option to enable JavaScript minification | |
213 | AC_ARG_ENABLE([jsmin], | |
214 | [AS_HELP_STRING([--enable-jsmin=PATH], | |
215 | [PATH is the name of a JavaScript minifier or the absolute path to one.])], | |
216 | [ | |
217 | JSMIN=$enableval; | |
218 | AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying]) | |
219 | GIT_CONF_SUBST([JSMIN]) | |
220 | ]) | |
221 | ||
222 | # Define option to enable CSS minification | |
223 | AC_ARG_ENABLE([cssmin], | |
224 | [AS_HELP_STRING([--enable-cssmin=PATH], | |
225 | [PATH is the name of a CSS minifier or the absolute path to one.])], | |
226 | [ | |
227 | CSSMIN=$enableval; | |
228 | AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying]) | |
229 | GIT_CONF_SUBST([CSSMIN]) | |
230 | ]) | |
231 | ||
232 | ## Site configuration (override autodetection) | |
233 | ## --with-PACKAGE[=ARG] and --without-PACKAGE | |
234 | AC_MSG_NOTICE([CHECKS for site configuration]) | |
235 | # | |
236 | # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability | |
237 | # tests. These tests take up a significant amount of the total test time | |
238 | # but are not needed unless you plan to talk to SVN repos. | |
239 | # | |
240 | # Define PPC_SHA1 environment variable when running make to make use of | |
241 | # a bundled SHA1 routine optimized for PowerPC. | |
242 | # | |
243 | # Define NO_OPENSSL environment variable if you do not have OpenSSL. | |
244 | # This also implies BLK_SHA1. | |
245 | # | |
246 | # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in | |
247 | # /foo/bar/include and /foo/bar/lib directories. | |
248 | AC_ARG_WITH(openssl, | |
249 | AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)]) | |
250 | AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]), | |
251 | GIT_PARSE_WITH([openssl])) | |
252 | ||
253 | # Define USE_LIBPCRE if you have and want to use libpcre. Various | |
254 | # commands such as log and grep offer runtime options to use | |
255 | # Perl-compatible regular expressions instead of standard or extended | |
256 | # POSIX regular expressions. | |
257 | # | |
258 | # Currently USE_LIBPCRE is a synonym for USE_LIBPCRE1, define | |
259 | # USE_LIBPCRE2 instead if you'd like to use version 2 of the PCRE | |
260 | # library. The USE_LIBPCRE flag will likely be changed to mean v2 by | |
261 | # default in future releases. | |
262 | # | |
263 | # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in | |
264 | # /foo/bar/include and /foo/bar/lib directories. | |
265 | # | |
266 | AC_ARG_WITH(libpcre, | |
267 | AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre1]), | |
268 | if test "$withval" = "no"; then | |
269 | USE_LIBPCRE1= | |
270 | elif test "$withval" = "yes"; then | |
271 | USE_LIBPCRE1=YesPlease | |
272 | else | |
273 | USE_LIBPCRE1=YesPlease | |
274 | LIBPCREDIR=$withval | |
275 | AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR]) | |
276 | dnl USE_LIBPCRE1 can still be modified below, so don't substitute | |
277 | dnl it yet. | |
278 | GIT_CONF_SUBST([LIBPCREDIR]) | |
279 | fi) | |
280 | ||
281 | AC_ARG_WITH(libpcre1, | |
282 | AS_HELP_STRING([--with-libpcre1],[support Perl-compatible regexes via libpcre1 (default is NO)]) | |
283 | AS_HELP_STRING([], [ARG can be also prefix for libpcre library and headers]), | |
284 | if test "$withval" = "no"; then | |
285 | USE_LIBPCRE1= | |
286 | elif test "$withval" = "yes"; then | |
287 | USE_LIBPCRE1=YesPlease | |
288 | else | |
289 | USE_LIBPCRE1=YesPlease | |
290 | LIBPCREDIR=$withval | |
291 | AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR]) | |
292 | dnl USE_LIBPCRE1 can still be modified below, so don't substitute | |
293 | dnl it yet. | |
294 | GIT_CONF_SUBST([LIBPCREDIR]) | |
295 | fi) | |
296 | ||
297 | AC_ARG_WITH(libpcre2, | |
298 | AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)]) | |
299 | AS_HELP_STRING([], [ARG can be also prefix for libpcre library and headers]), | |
300 | if test -n "$USE_LIBPCRE1"; then | |
301 | AC_MSG_ERROR([Only supply one of --with-libpcre1 or --with-libpcre2!]) | |
302 | fi | |
303 | ||
304 | if test "$withval" = "no"; then | |
305 | USE_LIBPCRE2= | |
306 | elif test "$withval" = "yes"; then | |
307 | USE_LIBPCRE2=YesPlease | |
308 | else | |
309 | USE_LIBPCRE2=YesPlease | |
310 | LIBPCREDIR=$withval | |
311 | AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR]) | |
312 | dnl USE_LIBPCRE2 can still be modified below, so don't substitute | |
313 | dnl it yet. | |
314 | GIT_CONF_SUBST([LIBPCREDIR]) | |
315 | fi) | |
316 | # | |
317 | # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header. | |
318 | AC_FUNC_ALLOCA | |
319 | case $ac_cv_working_alloca_h in | |
320 | yes) HAVE_ALLOCA_H=YesPlease;; | |
321 | *) HAVE_ALLOCA_H='';; | |
322 | esac | |
323 | GIT_CONF_SUBST([HAVE_ALLOCA_H]) | |
324 | # | |
325 | # Define NO_CURL if you do not have curl installed. git-http-pull and | |
326 | # git-http-push are not built, and you cannot use http:// and https:// | |
327 | # transports. | |
328 | # | |
329 | # Define CURLDIR=/foo/bar if your curl header and library files are in | |
330 | # /foo/bar/include and /foo/bar/lib directories. | |
331 | AC_ARG_WITH(curl, | |
332 | AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)]) | |
333 | AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]), | |
334 | GIT_PARSE_WITH(curl)) | |
335 | # | |
336 | # Define NO_EXPAT if you do not have expat installed. git-http-push is | |
337 | # not built, and you cannot push using http:// and https:// transports. | |
338 | # | |
339 | # Define EXPATDIR=/foo/bar if your expat header and library files are in | |
340 | # /foo/bar/include and /foo/bar/lib directories. | |
341 | AC_ARG_WITH(expat, | |
342 | AS_HELP_STRING([--with-expat], | |
343 | [support git-push using http:// and https:// transports via WebDAV (default is YES)]) | |
344 | AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]), | |
345 | GIT_PARSE_WITH(expat)) | |
346 | # | |
347 | # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink | |
348 | # installed in /sw, but don't want GIT to link against any libraries | |
349 | # installed there. If defined you may specify your own (or Fink's) | |
350 | # include directories and library directories by defining CFLAGS | |
351 | # and LDFLAGS appropriately. | |
352 | # | |
353 | # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X, | |
354 | # have DarwinPorts installed in /opt/local, but don't want GIT to | |
355 | # link against any libraries installed there. If defined you may | |
356 | # specify your own (or DarwinPort's) include directories and | |
357 | # library directories by defining CFLAGS and LDFLAGS appropriately. | |
358 | # | |
359 | # Define NO_MMAP if you want to avoid mmap. | |
360 | # | |
361 | # Define NO_ICONV if your libc does not properly support iconv. | |
362 | AC_ARG_WITH(iconv, | |
363 | AS_HELP_STRING([--without-iconv], | |
364 | [if your architecture doesn't properly support iconv]) | |
365 | AS_HELP_STRING([--with-iconv=PATH], | |
366 | [PATH is prefix for libiconv library and headers]) | |
367 | AS_HELP_STRING([], | |
368 | [used only if you need linking with libiconv]), | |
369 | GIT_PARSE_WITH(iconv)) | |
370 | ||
371 | ## --enable-FEATURE[=ARG] and --disable-FEATURE | |
372 | # | |
373 | # Define USE_NSEC below if you want git to care about sub-second file mtimes | |
374 | # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and | |
375 | # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely | |
376 | # randomly break unless your underlying filesystem supports those sub-second | |
377 | # times (my ext3 doesn't). | |
378 | # | |
379 | # Define USE_STDEV below if you want git to care about the underlying device | |
380 | # change being considered an inode change from the update-index perspective. | |
381 | ||
382 | # | |
383 | # Allow user to set ETC_GITCONFIG variable | |
384 | GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG, | |
385 | Use VALUE instead of /etc/gitconfig as the | |
386 | global git configuration file. | |
387 | If VALUE is not fully qualified it will be interpreted | |
388 | as a path relative to the computed prefix at runtime.) | |
389 | ||
390 | # | |
391 | # Allow user to set ETC_GITATTRIBUTES variable | |
392 | GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES, | |
393 | Use VALUE instead of /etc/gitattributes as the | |
394 | global git attributes file. | |
395 | If VALUE is not fully qualified it will be interpreted | |
396 | as a path relative to the computed prefix at runtime.) | |
397 | ||
398 | # | |
399 | # Allow user to set the default pager | |
400 | GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER, | |
401 | Use VALUE as the fall-back pager instead of 'less'. | |
402 | This is used by things like 'git log' when the user | |
403 | does not specify a pager to use through alternate | |
404 | methods. eg: /usr/bin/pager) | |
405 | # | |
406 | # Allow user to set the default editor | |
407 | GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR, | |
408 | Use VALUE as the fall-back editor instead of 'vi'. | |
409 | This is used by things like 'git commit' when the user | |
410 | does not specify a preferred editor through other | |
411 | methods. eg: /usr/bin/editor) | |
412 | ||
413 | # | |
414 | # Define SHELL_PATH to provide path to shell. | |
415 | GIT_ARG_SET_PATH(shell) | |
416 | # | |
417 | # Define PERL_PATH to provide path to Perl. | |
418 | GIT_ARG_SET_PATH(perl) | |
419 | # | |
420 | # Define PYTHON_PATH to provide path to Python. | |
421 | GIT_ARG_SET_PATH(python, allow-without) | |
422 | # | |
423 | # Define ZLIB_PATH to provide path to zlib. | |
424 | GIT_ARG_SET_PATH(zlib) | |
425 | # | |
426 | # Declare the with-tcltk/without-tcltk options. | |
427 | AC_ARG_WITH(tcltk, | |
428 | AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)]) | |
429 | AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.]) | |
430 | AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if]) | |
431 | AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]), | |
432 | GIT_PARSE_WITH(tcltk)) | |
433 | # | |
434 | ||
435 | ||
436 | ## Checks for programs. | |
437 | AC_MSG_NOTICE([CHECKS for programs]) | |
438 | # | |
439 | AC_PROG_CC([cc gcc]) | |
440 | AC_C_INLINE | |
441 | case $ac_cv_c_inline in | |
442 | inline | yes | no) INLINE='';; | |
443 | *) INLINE=$ac_cv_c_inline ;; | |
444 | esac | |
445 | GIT_CONF_SUBST([INLINE]) | |
446 | ||
447 | # which switch to pass runtime path to dynamic libraries to the linker | |
448 | AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [ | |
449 | SAVE_LDFLAGS="${LDFLAGS}" | |
450 | LDFLAGS="${SAVE_LDFLAGS} -R /" | |
451 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no]) | |
452 | LDFLAGS="${SAVE_LDFLAGS}" | |
453 | ]) | |
454 | if test "$git_cv_ld_dashr" = "yes"; then | |
455 | CC_LD_DYNPATH=-R | |
456 | else | |
457 | AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [ | |
458 | SAVE_LDFLAGS="${LDFLAGS}" | |
459 | LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/" | |
460 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no]) | |
461 | LDFLAGS="${SAVE_LDFLAGS}" | |
462 | ]) | |
463 | if test "$git_cv_ld_wl_rpath" = "yes"; then | |
464 | CC_LD_DYNPATH=-Wl,-rpath, | |
465 | else | |
466 | AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [ | |
467 | SAVE_LDFLAGS="${LDFLAGS}" | |
468 | LDFLAGS="${SAVE_LDFLAGS} -rpath /" | |
469 | AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no]) | |
470 | LDFLAGS="${SAVE_LDFLAGS}" | |
471 | ]) | |
472 | if test "$git_cv_ld_rpath" = "yes"; then | |
473 | CC_LD_DYNPATH=-rpath | |
474 | else | |
475 | CC_LD_DYNPATH= | |
476 | AC_MSG_WARN([linker does not support runtime path to dynamic libraries]) | |
477 | fi | |
478 | fi | |
479 | fi | |
480 | GIT_CONF_SUBST([CC_LD_DYNPATH]) | |
481 | #AC_PROG_INSTALL # needs install-sh or install.sh in sources | |
482 | AC_CHECK_TOOLS(AR, [gar ar], :) | |
483 | AC_CHECK_PROGS(TAR, [gtar tar]) | |
484 | AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff]) | |
485 | # TCLTK_PATH will be set to some value if we want Tcl/Tk | |
486 | # or will be empty otherwise. | |
487 | if test -n "$NO_TCLTK"; then | |
488 | TCLTK_PATH= | |
489 | else | |
490 | if test "$with_tcltk" = ""; then | |
491 | # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'. | |
492 | TCLTK_PATH=wish | |
493 | elif test "$with_tcltk" = "yes"; then | |
494 | # Tcl/Tk check requested. | |
495 | AC_CHECK_PROGS(TCLTK_PATH, [wish], ) | |
496 | else | |
497 | AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk]) | |
498 | TCLTK_PATH="$with_tcltk" | |
499 | fi | |
500 | fi | |
501 | GIT_CONF_SUBST([TCLTK_PATH]) | |
502 | AC_CHECK_PROGS(ASCIIDOC, [asciidoc]) | |
503 | if test -n "$ASCIIDOC"; then | |
504 | AC_MSG_CHECKING([for asciidoc version]) | |
505 | asciidoc_version=`$ASCIIDOC --version 2>/dev/null` | |
506 | case "${asciidoc_version}" in | |
507 | asciidoc' '8*) | |
508 | AC_MSG_RESULT([${asciidoc_version}]) | |
509 | ;; | |
510 | *) | |
511 | AC_MSG_RESULT([${asciidoc_version} (unknown)]) | |
512 | ;; | |
513 | esac | |
514 | fi | |
515 | ||
516 | if grep -a ascii configure.ac >/dev/null; then | |
517 | AC_MSG_RESULT([Using 'grep -a' for sane_grep]) | |
518 | SANE_TEXT_GREP=-a | |
519 | else | |
520 | SANE_TEXT_GREP= | |
521 | fi | |
522 | GIT_CONF_SUBST([SANE_TEXT_GREP]) | |
523 | ||
524 | ## Checks for libraries. | |
525 | AC_MSG_NOTICE([CHECKS for libraries]) | |
526 | # | |
527 | # Define NO_OPENSSL environment variable if you do not have OpenSSL. | |
528 | # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin). | |
529 | ||
530 | GIT_STASH_FLAGS($OPENSSLDIR) | |
531 | ||
532 | AC_CHECK_LIB([crypto], [SHA1_Init], | |
533 | [NEEDS_SSL_WITH_CRYPTO=], | |
534 | [AC_CHECK_LIB([ssl], [SHA1_Init], | |
535 | [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=], | |
536 | [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])]) | |
537 | ||
538 | GIT_UNSTASH_FLAGS($OPENSSLDIR) | |
539 | ||
540 | GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO]) | |
541 | GIT_CONF_SUBST([NO_OPENSSL]) | |
542 | ||
543 | # | |
544 | # Handle the USE_LIBPCRE1 and USE_LIBPCRE2 options potentially set | |
545 | # above. | |
546 | # | |
547 | ||
548 | if test -n "$USE_LIBPCRE1"; then | |
549 | ||
550 | GIT_STASH_FLAGS($LIBPCREDIR) | |
551 | ||
552 | AC_CHECK_LIB([pcre], [pcre_version], | |
553 | [USE_LIBPCRE=YesPlease], | |
554 | [USE_LIBPCRE=]) | |
555 | ||
556 | GIT_UNSTASH_FLAGS($LIBPCREDIR) | |
557 | ||
558 | GIT_CONF_SUBST([USE_LIBPCRE1]) | |
559 | ||
560 | fi | |
561 | ||
562 | ||
563 | if test -n "$USE_LIBPCRE2"; then | |
564 | ||
565 | GIT_STASH_FLAGS($LIBPCREDIR) | |
566 | ||
567 | AC_CHECK_LIB([pcre2-8], [pcre2_config_8], | |
568 | [USE_LIBPCRE2=YesPlease], | |
569 | [USE_LIBPCRE2=]) | |
570 | ||
571 | GIT_UNSTASH_FLAGS($LIBPCREDIR) | |
572 | ||
573 | GIT_CONF_SUBST([USE_LIBPCRE2]) | |
574 | ||
575 | fi | |
576 | ||
577 | # | |
578 | # Define NO_CURL if you do not have libcurl installed. git-http-pull and | |
579 | # git-http-push are not built, and you cannot use http:// and https:// | |
580 | # transports. | |
581 | ||
582 | GIT_STASH_FLAGS($CURLDIR) | |
583 | ||
584 | AC_CHECK_LIB([curl], [curl_global_init], | |
585 | [NO_CURL=], | |
586 | [NO_CURL=YesPlease]) | |
587 | ||
588 | GIT_UNSTASH_FLAGS($CURLDIR) | |
589 | ||
590 | GIT_CONF_SUBST([NO_CURL]) | |
591 | ||
592 | if test -z "$NO_CURL"; then | |
593 | ||
594 | AC_CHECK_PROG([CURL_CONFIG], [curl-config], | |
595 | [curl-config], | |
596 | [no]) | |
597 | ||
598 | if test $CURL_CONFIG != no; then | |
599 | GIT_CONF_SUBST([CURL_CONFIG]) | |
600 | if test -z "${NO_OPENSSL}"; then | |
601 | AC_MSG_CHECKING([if Curl supports SSL]) | |
602 | if test $(curl-config --features|grep SSL) = SSL; then | |
603 | NEEDS_SSL_WITH_CURL=YesPlease | |
604 | AC_MSG_RESULT([yes]) | |
605 | else | |
606 | NEEDS_SSL_WITH_CURL= | |
607 | AC_MSG_RESULT([no]) | |
608 | fi | |
609 | GIT_CONF_SUBST([NEEDS_SSL_WITH_CURL]) | |
610 | fi | |
611 | fi | |
612 | ||
613 | fi | |
614 | ||
615 | ||
616 | # | |
617 | # Define NO_EXPAT if you do not have expat installed. git-http-push is | |
618 | # not built, and you cannot push using http:// and https:// transports. | |
619 | ||
620 | GIT_STASH_FLAGS($EXPATDIR) | |
621 | ||
622 | AC_CHECK_LIB([expat], [XML_ParserCreate], | |
623 | [NO_EXPAT=], | |
624 | [NO_EXPAT=YesPlease]) | |
625 | ||
626 | GIT_UNSTASH_FLAGS($EXPATDIR) | |
627 | ||
628 | GIT_CONF_SUBST([NO_EXPAT]) | |
629 | ||
630 | # | |
631 | # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and | |
632 | # some Solaris installations). | |
633 | # Define NO_ICONV if neither libc nor libiconv support iconv. | |
634 | ||
635 | if test -z "$NO_ICONV"; then | |
636 | ||
637 | GIT_STASH_FLAGS($ICONVDIR) | |
638 | ||
639 | AC_DEFUN([ICONVTEST_SRC], | |
640 | [AC_LANG_PROGRAM([#include <iconv.h>], | |
641 | [iconv_open("", "");])]) | |
642 | ||
643 | if test -n "$ICONVDIR"; then | |
644 | lib_order="-liconv -lc" | |
645 | else | |
646 | lib_order="-lc -liconv" | |
647 | fi | |
648 | ||
649 | NO_ICONV=YesPlease | |
650 | ||
651 | for l in $lib_order; do | |
652 | if test "$l" = "-liconv"; then | |
653 | NEEDS_LIBICONV=YesPlease | |
654 | else | |
655 | NEEDS_LIBICONV= | |
656 | fi | |
657 | ||
658 | old_LIBS="$LIBS" | |
659 | LIBS="$LIBS $l" | |
660 | AC_MSG_CHECKING([for iconv in $l]) | |
661 | AC_LINK_IFELSE([ICONVTEST_SRC], | |
662 | [AC_MSG_RESULT([yes]) | |
663 | NO_ICONV= | |
664 | break], | |
665 | [AC_MSG_RESULT([no])]) | |
666 | LIBS="$old_LIBS" | |
667 | done | |
668 | ||
669 | #in case of break | |
670 | LIBS="$old_LIBS" | |
671 | ||
672 | GIT_UNSTASH_FLAGS($ICONVDIR) | |
673 | ||
674 | GIT_CONF_SUBST([NEEDS_LIBICONV]) | |
675 | GIT_CONF_SUBST([NO_ICONV]) | |
676 | ||
677 | if test -n "$NO_ICONV"; then | |
678 | NEEDS_LIBICONV= | |
679 | fi | |
680 | ||
681 | fi | |
682 | ||
683 | # | |
684 | # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib. | |
685 | ||
686 | GIT_STASH_FLAGS($ZLIB_PATH) | |
687 | ||
688 | AC_DEFUN([ZLIBTEST_SRC], [ | |
689 | AC_LANG_PROGRAM([#include <zlib.h>], | |
690 | [deflateBound(0, 0);])]) | |
691 | AC_MSG_CHECKING([for deflateBound in -lz]) | |
692 | old_LIBS="$LIBS" | |
693 | LIBS="$LIBS -lz" | |
694 | AC_LINK_IFELSE([ZLIBTEST_SRC], | |
695 | [AC_MSG_RESULT([yes])], | |
696 | [AC_MSG_RESULT([no]) | |
697 | NO_DEFLATE_BOUND=yes]) | |
698 | LIBS="$old_LIBS" | |
699 | ||
700 | GIT_UNSTASH_FLAGS($ZLIB_PATH) | |
701 | ||
702 | GIT_CONF_SUBST([NO_DEFLATE_BOUND]) | |
703 | ||
704 | # | |
705 | # Define NEEDS_SOCKET if linking with libc is not enough (SunOS, | |
706 | # Patrick Mauritz). | |
707 | AC_CHECK_LIB([c], [socket], | |
708 | [NEEDS_SOCKET=], | |
709 | [NEEDS_SOCKET=YesPlease]) | |
710 | GIT_CONF_SUBST([NEEDS_SOCKET]) | |
711 | test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket" | |
712 | ||
713 | # | |
714 | # The next few tests will define NEEDS_RESOLV if linking with | |
715 | # libresolv provides some of the functions we would normally get | |
716 | # from libc. | |
717 | NEEDS_RESOLV= | |
718 | # | |
719 | # Define NO_INET_NTOP if linking with -lresolv is not enough. | |
720 | # Solaris 2.7 in particular hos inet_ntop in -lresolv. | |
721 | NO_INET_NTOP= | |
722 | AC_CHECK_FUNC([inet_ntop], | |
723 | [], | |
724 | [AC_CHECK_LIB([resolv], [inet_ntop], | |
725 | [NEEDS_RESOLV=YesPlease], | |
726 | [NO_INET_NTOP=YesPlease]) | |
727 | ]) | |
728 | GIT_CONF_SUBST([NO_INET_NTOP]) | |
729 | # | |
730 | # Define NO_INET_PTON if linking with -lresolv is not enough. | |
731 | # Solaris 2.7 in particular hos inet_pton in -lresolv. | |
732 | NO_INET_PTON= | |
733 | AC_CHECK_FUNC([inet_pton], | |
734 | [], | |
735 | [AC_CHECK_LIB([resolv], [inet_pton], | |
736 | [NEEDS_RESOLV=YesPlease], | |
737 | [NO_INET_PTON=YesPlease]) | |
738 | ]) | |
739 | GIT_CONF_SUBST([NO_INET_PTON]) | |
740 | # | |
741 | # Define NO_HSTRERROR if linking with -lresolv is not enough. | |
742 | # Solaris 2.6 in particular has no hstrerror, even in -lresolv. | |
743 | NO_HSTRERROR= | |
744 | AC_CHECK_FUNC([hstrerror], | |
745 | [], | |
746 | [AC_CHECK_LIB([resolv], [hstrerror], | |
747 | [NEEDS_RESOLV=YesPlease], | |
748 | [NO_HSTRERROR=YesPlease]) | |
749 | ]) | |
750 | GIT_CONF_SUBST([NO_HSTRERROR]) | |
751 | ||
752 | dnl This must go after all the possible places for its initialization, | |
753 | dnl in the AC_CHECK_FUNC invocations above. | |
754 | GIT_CONF_SUBST([NEEDS_RESOLV]) | |
755 | # | |
756 | # If any of the above tests determined that -lresolv is needed at | |
757 | # build-time, also set it here for remaining configure-time checks. | |
758 | test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv" | |
759 | ||
760 | AC_CHECK_LIB([c], [basename], | |
761 | [NEEDS_LIBGEN=], | |
762 | [NEEDS_LIBGEN=YesPlease]) | |
763 | GIT_CONF_SUBST([NEEDS_LIBGEN]) | |
764 | test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen" | |
765 | ||
766 | AC_CHECK_LIB([c], [gettext], | |
767 | [LIBC_CONTAINS_LIBINTL=YesPlease], | |
768 | [LIBC_CONTAINS_LIBINTL=]) | |
769 | GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL]) | |
770 | ||
771 | # | |
772 | # Define NO_GETTEXT if you don't want Git output to be translated. | |
773 | # A translated Git requires GNU libintl or another gettext implementation | |
774 | AC_CHECK_HEADER([libintl.h], | |
775 | [NO_GETTEXT=], | |
776 | [NO_GETTEXT=YesPlease]) | |
777 | GIT_CONF_SUBST([NO_GETTEXT]) | |
778 | ||
779 | if test -z "$NO_GETTEXT"; then | |
780 | test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl" | |
781 | fi | |
782 | ||
783 | ## Checks for header files. | |
784 | AC_MSG_NOTICE([CHECKS for header files]) | |
785 | # | |
786 | # Define NO_SYS_SELECT_H if you don't have sys/select.h. | |
787 | AC_CHECK_HEADER([sys/select.h], | |
788 | [NO_SYS_SELECT_H=], | |
789 | [NO_SYS_SELECT_H=UnfortunatelyYes]) | |
790 | GIT_CONF_SUBST([NO_SYS_SELECT_H]) | |
791 | # | |
792 | # Define NO_SYS_POLL_H if you don't have sys/poll.h | |
793 | AC_CHECK_HEADER([sys/poll.h], | |
794 | [NO_SYS_POLL_H=], | |
795 | [NO_SYS_POLL_H=UnfortunatelyYes]) | |
796 | GIT_CONF_SUBST([NO_SYS_POLL_H]) | |
797 | # | |
798 | # Define NO_INTTYPES_H if you don't have inttypes.h | |
799 | AC_CHECK_HEADER([inttypes.h], | |
800 | [NO_INTTYPES_H=], | |
801 | [NO_INTTYPES_H=UnfortunatelyYes]) | |
802 | GIT_CONF_SUBST([NO_INTTYPES_H]) | |
803 | # | |
804 | # Define OLD_ICONV if your library has an old iconv(), where the second | |
805 | # (input buffer pointer) parameter is declared with type (const char **). | |
806 | AC_DEFUN([OLDICONVTEST_SRC], [ | |
807 | AC_LANG_PROGRAM([[ | |
808 | #include <iconv.h> | |
809 | ||
810 | extern size_t iconv(iconv_t cd, | |
811 | char **inbuf, size_t *inbytesleft, | |
812 | char **outbuf, size_t *outbytesleft); | |
813 | ]], [])]) | |
814 | ||
815 | GIT_STASH_FLAGS($ICONVDIR) | |
816 | ||
817 | AC_MSG_CHECKING([for old iconv()]) | |
818 | AC_COMPILE_IFELSE([OLDICONVTEST_SRC], | |
819 | [AC_MSG_RESULT([no])], | |
820 | [AC_MSG_RESULT([yes]) | |
821 | OLD_ICONV=UnfortunatelyYes]) | |
822 | ||
823 | GIT_UNSTASH_FLAGS($ICONVDIR) | |
824 | ||
825 | GIT_CONF_SUBST([OLD_ICONV]) | |
826 | ||
827 | ## Checks for typedefs, structures, and compiler characteristics. | |
828 | AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics]) | |
829 | # | |
830 | TYPE_SOCKLEN_T | |
831 | case $ac_cv_type_socklen_t in | |
832 | yes) SOCKLEN_T='';; | |
833 | *) SOCKLEN_T=$git_cv_socklen_t_equiv;; | |
834 | esac | |
835 | GIT_CONF_SUBST([SOCKLEN_T]) | |
836 | ||
837 | # | |
838 | # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval. | |
839 | AC_CHECK_TYPES([struct itimerval], | |
840 | [NO_STRUCT_ITIMERVAL=], | |
841 | [NO_STRUCT_ITIMERVAL=UnfortunatelyYes], | |
842 | [#include <sys/time.h>]) | |
843 | GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL]) | |
844 | # | |
845 | # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists. | |
846 | # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor | |
847 | # stat.st_mtimespec.tv_nsec exists. | |
848 | AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec]) | |
849 | AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec]) | |
850 | if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then | |
851 | USE_ST_TIMESPEC=YesPlease | |
852 | GIT_CONF_SUBST([USE_ST_TIMESPEC]) | |
853 | elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then | |
854 | NO_NSEC=YesPlease | |
855 | GIT_CONF_SUBST([NO_NSEC]) | |
856 | fi | |
857 | # | |
858 | # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks | |
859 | # d_type in struct dirent (latest Cygwin -- will be fixed soonish). | |
860 | AC_CHECK_MEMBER(struct dirent.d_type, | |
861 | [NO_D_TYPE_IN_DIRENT=], | |
862 | [NO_D_TYPE_IN_DIRENT=YesPlease], | |
863 | [#include <dirent.h>]) | |
864 | GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT]) | |
865 | # | |
866 | # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd | |
867 | # in the C library. | |
868 | AC_CHECK_MEMBER(struct passwd.pw_gecos, | |
869 | [NO_GECOS_IN_PWENT=], | |
870 | [NO_GECOS_IN_PWENT=YesPlease], | |
871 | [#include <pwd.h>]) | |
872 | GIT_CONF_SUBST([NO_GECOS_IN_PWENT]) | |
873 | # | |
874 | # Define NO_SOCKADDR_STORAGE if your platform does not have struct | |
875 | # sockaddr_storage. | |
876 | AC_CHECK_TYPE(struct sockaddr_storage, | |
877 | [NO_SOCKADDR_STORAGE=], | |
878 | [NO_SOCKADDR_STORAGE=YesPlease],[ | |
879 | #include <sys/types.h> | |
880 | #include <sys/socket.h> | |
881 | ]) | |
882 | GIT_CONF_SUBST([NO_SOCKADDR_STORAGE]) | |
883 | # | |
884 | # Define NO_IPV6 if you lack IPv6 support and getaddrinfo(). | |
885 | AC_CHECK_TYPE([struct addrinfo],[ | |
886 | GIT_CHECK_FUNC([getaddrinfo], | |
887 | [NO_IPV6=], | |
888 | [NO_IPV6=YesPlease]) | |
889 | ],[NO_IPV6=YesPlease],[ | |
890 | #include <sys/types.h> | |
891 | #include <sys/socket.h> | |
892 | #include <netdb.h> | |
893 | ]) | |
894 | GIT_CONF_SUBST([NO_IPV6]) | |
895 | # | |
896 | # Define NO_REGEX if your C library lacks regex support with REG_STARTEND | |
897 | # feature. | |
898 | AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND], | |
899 | [ac_cv_c_regex_with_reg_startend], [ | |
900 | AC_EGREP_CPP(yippeeyeswehaveit, | |
901 | AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT | |
902 | #include <regex.h> | |
903 | ], | |
904 | [#ifdef REG_STARTEND | |
905 | yippeeyeswehaveit | |
906 | #endif | |
907 | ]), | |
908 | [ac_cv_c_regex_with_reg_startend=yes], | |
909 | [ac_cv_c_regex_with_reg_startend=no]) | |
910 | ]) | |
911 | if test $ac_cv_c_regex_with_reg_startend = yes; then | |
912 | NO_REGEX= | |
913 | else | |
914 | NO_REGEX=YesPlease | |
915 | fi | |
916 | GIT_CONF_SUBST([NO_REGEX]) | |
917 | # | |
918 | # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds | |
919 | # when attempting to read from an fopen'ed directory. | |
920 | AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory], | |
921 | [ac_cv_fread_reads_directories], | |
922 | [ | |
923 | AC_RUN_IFELSE( | |
924 | [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], | |
925 | [[ | |
926 | FILE *f = fopen(".", "r"); | |
927 | return f)]])], | |
928 | [ac_cv_fread_reads_directories=no], | |
929 | [ac_cv_fread_reads_directories=yes]) | |
930 | ]) | |
931 | if test $ac_cv_fread_reads_directories = yes; then | |
932 | FREAD_READS_DIRECTORIES=UnfortunatelyYes | |
933 | else | |
934 | FREAD_READS_DIRECTORIES= | |
935 | fi | |
936 | GIT_CONF_SUBST([FREAD_READS_DIRECTORIES]) | |
937 | # | |
938 | # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf() | |
939 | # or vsnprintf() return -1 instead of number of characters which would | |
940 | # have been written to the final string if enough space had been available. | |
941 | AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value], | |
942 | [ac_cv_snprintf_returns_bogus], | |
943 | [ | |
944 | AC_RUN_IFELSE( | |
945 | [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT | |
946 | #include "stdarg.h" | |
947 | ||
948 | int test_vsnprintf(char *str, size_t maxsize, const char *format, ...) | |
949 | { | |
950 | int ret; | |
951 | va_list ap; | |
952 | va_start(ap, format); | |
953 | ret = vsnprintf(str, maxsize, format, ap); | |
954 | va_end(ap); | |
955 | return ret; | |
956 | }], | |
957 | [[char buf[6]; | |
958 | if (test_vsnprintf(buf, 3, "%s", "12345") != 5 | |
959 | || strcmp(buf, "12")) return 1; | |
960 | if (snprintf(buf, 3, "%s", "12345") != 5 | |
961 | || strcmp(buf, "12")) return 1]])], | |
962 | [ac_cv_snprintf_returns_bogus=no], | |
963 | [ac_cv_snprintf_returns_bogus=yes]) | |
964 | ]) | |
965 | if test $ac_cv_snprintf_returns_bogus = yes; then | |
966 | SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes | |
967 | else | |
968 | SNPRINTF_RETURNS_BOGUS= | |
969 | fi | |
970 | GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS]) | |
971 | # | |
972 | # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type | |
973 | # bits in mode values. | |
974 | AC_CACHE_CHECK([whether the platform uses typical file type bits], | |
975 | [ac_cv_sane_mode_bits], [ | |
976 | AC_EGREP_CPP(yippeeyeswehaveit, | |
977 | AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], | |
978 | [#if S_IFMT == 0170000 && \ | |
979 | S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \ | |
980 | S_IFBLK == 0060000 && S_IFCHR == 0020000 && \ | |
981 | S_IFIFO == 0010000 && S_IFSOCK == 0140000 | |
982 | yippeeyeswehaveit | |
983 | #endif | |
984 | ]), | |
985 | [ac_cv_sane_mode_bits=yes], | |
986 | [ac_cv_sane_mode_bits=no]) | |
987 | ]) | |
988 | if test $ac_cv_sane_mode_bits = yes; then | |
989 | NEEDS_MODE_TRANSLATION= | |
990 | else | |
991 | NEEDS_MODE_TRANSLATION=UnfortunatelyYes | |
992 | fi | |
993 | GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION]) | |
994 | ||
995 | ||
996 | ## Checks for library functions. | |
997 | ## (in default C library and libraries checked by AC_CHECK_LIB) | |
998 | AC_MSG_NOTICE([CHECKS for library functions]) | |
999 | # | |
1000 | # Define NO_LIBGEN_H if you don't have libgen.h. | |
1001 | AC_CHECK_HEADER([libgen.h], | |
1002 | [NO_LIBGEN_H=], | |
1003 | [NO_LIBGEN_H=YesPlease]) | |
1004 | GIT_CONF_SUBST([NO_LIBGEN_H]) | |
1005 | # | |
1006 | # Define HAVE_PATHS_H if you have paths.h. | |
1007 | AC_CHECK_HEADER([paths.h], | |
1008 | [HAVE_PATHS_H=YesPlease], | |
1009 | [HAVE_PATHS_H=]) | |
1010 | GIT_CONF_SUBST([HAVE_PATHS_H]) | |
1011 | # | |
1012 | # Define HAVE_LIBCHARSET_H if have libcharset.h | |
1013 | AC_CHECK_HEADER([libcharset.h], | |
1014 | [HAVE_LIBCHARSET_H=YesPlease], | |
1015 | [HAVE_LIBCHARSET_H=]) | |
1016 | GIT_CONF_SUBST([HAVE_LIBCHARSET_H]) | |
1017 | # | |
1018 | # Define HAVE_STRINGS_H if you have strings.h | |
1019 | AC_CHECK_HEADER([strings.h], | |
1020 | [HAVE_STRINGS_H=YesPlease], | |
1021 | [HAVE_STRINGS_H=]) | |
1022 | GIT_CONF_SUBST([HAVE_STRINGS_H]) | |
1023 | # Define CHARSET_LIB if libiconv does not export the locale_charset symbol | |
1024 | # and libcharset does | |
1025 | CHARSET_LIB= | |
1026 | AC_CHECK_LIB([iconv], [locale_charset], | |
1027 | [CHARSET_LIB=-liconv], | |
1028 | [AC_CHECK_LIB([charset], [locale_charset], | |
1029 | [CHARSET_LIB=-lcharset])]) | |
1030 | GIT_CONF_SUBST([CHARSET_LIB]) | |
1031 | # | |
1032 | # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available. | |
1033 | GIT_CHECK_FUNC(clock_gettime, | |
1034 | [HAVE_CLOCK_GETTIME=YesPlease], | |
1035 | [HAVE_CLOCK_GETTIME=]) | |
1036 | GIT_CONF_SUBST([HAVE_CLOCK_GETTIME]) | |
1037 | ||
1038 | AC_DEFUN([CLOCK_MONOTONIC_SRC], [ | |
1039 | AC_LANG_PROGRAM([[ | |
1040 | #include <time.h> | |
1041 | clockid_t id = CLOCK_MONOTONIC; | |
1042 | ]])]) | |
1043 | ||
1044 | # | |
1045 | # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available. | |
1046 | AC_MSG_CHECKING([for CLOCK_MONOTONIC]) | |
1047 | AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC], | |
1048 | [AC_MSG_RESULT([yes]) | |
1049 | HAVE_CLOCK_MONOTONIC=YesPlease], | |
1050 | [AC_MSG_RESULT([no]) | |
1051 | HAVE_CLOCK_MONOTONIC=]) | |
1052 | GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC]) | |
1053 | # | |
1054 | # Define NO_SETITIMER if you don't have setitimer. | |
1055 | GIT_CHECK_FUNC(setitimer, | |
1056 | [NO_SETITIMER=], | |
1057 | [NO_SETITIMER=YesPlease]) | |
1058 | GIT_CONF_SUBST([NO_SETITIMER]) | |
1059 | # | |
1060 | # Define NO_STRCASESTR if you don't have strcasestr. | |
1061 | GIT_CHECK_FUNC(strcasestr, | |
1062 | [NO_STRCASESTR=], | |
1063 | [NO_STRCASESTR=YesPlease]) | |
1064 | GIT_CONF_SUBST([NO_STRCASESTR]) | |
1065 | # | |
1066 | # Define NO_MEMMEM if you don't have memmem. | |
1067 | GIT_CHECK_FUNC(memmem, | |
1068 | [NO_MEMMEM=], | |
1069 | [NO_MEMMEM=YesPlease]) | |
1070 | GIT_CONF_SUBST([NO_MEMMEM]) | |
1071 | # | |
1072 | # Define NO_STRLCPY if you don't have strlcpy. | |
1073 | GIT_CHECK_FUNC(strlcpy, | |
1074 | [NO_STRLCPY=], | |
1075 | [NO_STRLCPY=YesPlease]) | |
1076 | GIT_CONF_SUBST([NO_STRLCPY]) | |
1077 | # | |
1078 | # Define NO_UINTMAX_T if your platform does not have uintmax_t | |
1079 | AC_CHECK_TYPE(uintmax_t, | |
1080 | [NO_UINTMAX_T=], | |
1081 | [NO_UINTMAX_T=YesPlease],[ | |
1082 | #include <inttypes.h> | |
1083 | ]) | |
1084 | GIT_CONF_SUBST([NO_UINTMAX_T]) | |
1085 | # | |
1086 | # Define NO_STRTOUMAX if you don't have strtoumax in the C library. | |
1087 | GIT_CHECK_FUNC(strtoumax, | |
1088 | [NO_STRTOUMAX=], | |
1089 | [NO_STRTOUMAX=YesPlease]) | |
1090 | GIT_CONF_SUBST([NO_STRTOUMAX]) | |
1091 | # | |
1092 | # Define NO_SETENV if you don't have setenv in the C library. | |
1093 | GIT_CHECK_FUNC(setenv, | |
1094 | [NO_SETENV=], | |
1095 | [NO_SETENV=YesPlease]) | |
1096 | GIT_CONF_SUBST([NO_SETENV]) | |
1097 | # | |
1098 | # Define NO_UNSETENV if you don't have unsetenv in the C library. | |
1099 | GIT_CHECK_FUNC(unsetenv, | |
1100 | [NO_UNSETENV=], | |
1101 | [NO_UNSETENV=YesPlease]) | |
1102 | GIT_CONF_SUBST([NO_UNSETENV]) | |
1103 | # | |
1104 | # Define NO_MKDTEMP if you don't have mkdtemp in the C library. | |
1105 | GIT_CHECK_FUNC(mkdtemp, | |
1106 | [NO_MKDTEMP=], | |
1107 | [NO_MKDTEMP=YesPlease]) | |
1108 | GIT_CONF_SUBST([NO_MKDTEMP]) | |
1109 | # | |
1110 | # Define NO_INITGROUPS if you don't have initgroups in the C library. | |
1111 | GIT_CHECK_FUNC(initgroups, | |
1112 | [NO_INITGROUPS=], | |
1113 | [NO_INITGROUPS=YesPlease]) | |
1114 | GIT_CONF_SUBST([NO_INITGROUPS]) | |
1115 | # | |
1116 | # Define HAVE_GETDELIM if you have getdelim in the C library. | |
1117 | GIT_CHECK_FUNC(getdelim, | |
1118 | [HAVE_GETDELIM=YesPlease], | |
1119 | [HAVE_GETDELIM=]) | |
1120 | GIT_CONF_SUBST([HAVE_GETDELIM]) | |
1121 | # | |
1122 | # | |
1123 | # Define NO_MMAP if you want to avoid mmap. | |
1124 | # | |
1125 | # Define NO_ICONV if your libc does not properly support iconv. | |
1126 | ||
1127 | AC_DEFUN([BSD_SYSCTL_SRC], [ | |
1128 | AC_LANG_PROGRAM([[ | |
1129 | #include <stddef.h> | |
1130 | #include <sys/types.h> | |
1131 | #include <sys/sysctl.h> | |
1132 | ]],[[ | |
1133 | int val, mib[2]; | |
1134 | size_t len; | |
1135 | mib[0] = CTL_HW; | |
1136 | mib[1] = 1; | |
1137 | len = sizeof(val); | |
1138 | return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0; | |
1139 | ]])]) | |
1140 | ||
1141 | # | |
1142 | # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available. | |
1143 | AC_MSG_CHECKING([for BSD sysctl]) | |
1144 | AC_COMPILE_IFELSE([BSD_SYSCTL_SRC], | |
1145 | [AC_MSG_RESULT([yes]) | |
1146 | HAVE_BSD_SYSCTL=YesPlease], | |
1147 | [AC_MSG_RESULT([no]) | |
1148 | HAVE_BSD_SYSCTL=]) | |
1149 | GIT_CONF_SUBST([HAVE_BSD_SYSCTL]) | |
1150 | ||
1151 | ## Other checks. | |
1152 | # Define USE_PIC if you need the main git objects to be built with -fPIC | |
1153 | # in order to build and link perl/Git.so. x86-64 seems to need this. | |
1154 | # | |
1155 | # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link. | |
1156 | # Enable it on Windows. By default, symrefs are still used. | |
1157 | # | |
1158 | # Define NO_PTHREADS if we do not have pthreads. | |
1159 | # | |
1160 | # Define PTHREAD_LIBS to the linker flag used for Pthread support. | |
1161 | AC_DEFUN([PTHREADTEST_SRC], [ | |
1162 | AC_LANG_PROGRAM([[ | |
1163 | #include <pthread.h> | |
1164 | static void *noop(void *ignore) { return ignore; } | |
1165 | ]], [[ | |
1166 | pthread_mutex_t test_mutex; | |
1167 | pthread_key_t test_key; | |
1168 | pthread_t th; | |
1169 | int retcode = 0; | |
1170 | void *ret = (void *)0; | |
1171 | retcode |= pthread_key_create(&test_key, (void *)0); | |
1172 | retcode |= pthread_mutex_init(&test_mutex,(void *)0); | |
1173 | retcode |= pthread_mutex_lock(&test_mutex); | |
1174 | retcode |= pthread_mutex_unlock(&test_mutex); | |
1175 | retcode |= pthread_create(&th, ret, noop, ret); | |
1176 | retcode |= pthread_join(th, &ret); | |
1177 | return retcode; | |
1178 | ]])]) | |
1179 | ||
1180 | dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM( | |
1181 | dnl [[#include <pthread.h>]], | |
1182 | dnl [[pthread_mutex_t test_mutex;]] | |
1183 | dnl )]) | |
1184 | ||
1185 | NO_PTHREADS=UnfortunatelyYes | |
1186 | PTHREAD_LIBS= | |
1187 | ||
1188 | if test -n "$USER_NOPTHREAD"; then | |
1189 | AC_MSG_NOTICE([Skipping POSIX Threads at user request.]) | |
1190 | # handle these separately since PTHREAD_CFLAGS could be '-lpthreads | |
1191 | # -D_REENTRANT' or some such. | |
1192 | elif test -z "$PTHREAD_CFLAGS"; then | |
1193 | threads_found=no | |
1194 | # Attempt to compile and link some code using pthreads to determine | |
1195 | # required linker flags. The order is somewhat important here: We | |
1196 | # first try it without any extra flags, to catch systems where | |
1197 | # pthreads are part of the C library, then go on testing various other | |
1198 | # flags. We do so to avoid false positives. For example, on Mac OS X | |
1199 | # pthreads are part of the C library; moreover, the compiler allows us | |
1200 | # to add "-mt" to the CFLAGS (although it will do nothing except | |
1201 | # trigger a warning about an unused flag). Hence if we checked for | |
1202 | # "-mt" before "" we would end up picking it. But unfortunately this | |
1203 | # would then trigger compiler warnings on every single file we compile. | |
1204 | for opt in "" -mt -pthread -lpthread; do | |
1205 | old_CFLAGS="$CFLAGS" | |
1206 | old_LIBS="$LIBS" | |
1207 | case "$opt" in | |
1208 | -l*) LIBS="$opt $LIBS" ;; | |
1209 | *) CFLAGS="$opt $CFLAGS" ;; | |
1210 | esac | |
1211 | ||
1212 | AC_MSG_CHECKING([for POSIX Threads with '$opt']) | |
1213 | AC_LINK_IFELSE([PTHREADTEST_SRC], | |
1214 | [AC_MSG_RESULT([yes]) | |
1215 | NO_PTHREADS= | |
1216 | PTHREAD_LIBS="$opt" | |
1217 | PTHREAD_CFLAGS="$opt" | |
1218 | threads_found=yes | |
1219 | break | |
1220 | ], | |
1221 | [AC_MSG_RESULT([no])]) | |
1222 | CFLAGS="$old_CFLAGS" | |
1223 | LIBS="$old_LIBS" | |
1224 | done | |
1225 | if test $threads_found != yes; then | |
1226 | AC_CHECK_LIB([pthread], [pthread_create], | |
1227 | [PTHREAD_LIBS="-lpthread"], | |
1228 | [NO_PTHREADS=UnfortunatelyYes]) | |
1229 | fi | |
1230 | else | |
1231 | old_CFLAGS="$CFLAGS" | |
1232 | CFLAGS="$PTHREAD_CFLAGS $CFLAGS" | |
1233 | AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS']) | |
1234 | AC_LINK_IFELSE([PTHREADTEST_SRC], | |
1235 | [AC_MSG_RESULT([yes]) | |
1236 | NO_PTHREADS= | |
1237 | PTHREAD_LIBS="$PTHREAD_CFLAGS" | |
1238 | ], | |
1239 | [AC_MSG_RESULT([no])]) | |
1240 | ||
1241 | CFLAGS="$old_CFLAGS" | |
1242 | fi | |
1243 | ||
1244 | CFLAGS="$old_CFLAGS" | |
1245 | ||
1246 | GIT_CONF_SUBST([PTHREAD_CFLAGS]) | |
1247 | GIT_CONF_SUBST([PTHREAD_LIBS]) | |
1248 | GIT_CONF_SUBST([NO_PTHREADS]) | |
1249 | ||
1250 | ## Output files | |
1251 | AC_CONFIG_FILES(["${config_file}":"${config_in}"]) | |
1252 | AC_OUTPUT |