]>
Commit | Line | Data |
---|---|---|
1 | #!/usr/bin/perl | |
2 | # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net> | |
3 | # License: GPL v2 or later | |
4 | use 5.008; | |
5 | use warnings; | |
6 | use strict; | |
7 | use vars qw/ $AUTHOR $VERSION | |
8 | $sha1 $sha1_short $_revision $_repository | |
9 | $_q $_authors $_authors_prog %users/; | |
10 | $AUTHOR = 'Eric Wong <normalperson@yhbt.net>'; | |
11 | $VERSION = '@@GIT_VERSION@@'; | |
12 | ||
13 | use Carp qw/croak/; | |
14 | use File::Basename qw/dirname basename/; | |
15 | use File::Path qw/mkpath/; | |
16 | use File::Spec; | |
17 | use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/; | |
18 | use Memoize; | |
19 | ||
20 | use Git::SVN; | |
21 | use Git::SVN::Editor; | |
22 | use Git::SVN::Fetcher; | |
23 | use Git::SVN::Ra; | |
24 | use Git::SVN::Prompt; | |
25 | use Git::SVN::Log; | |
26 | use Git::SVN::Migration; | |
27 | ||
28 | use Git::SVN::Utils qw( | |
29 | fatal | |
30 | can_compress | |
31 | canonicalize_path | |
32 | canonicalize_url | |
33 | join_paths | |
34 | add_path_to_url | |
35 | join_paths | |
36 | ); | |
37 | ||
38 | use Git qw( | |
39 | git_cmd_try | |
40 | command | |
41 | command_oneline | |
42 | command_noisy | |
43 | command_output_pipe | |
44 | command_close_pipe | |
45 | command_bidi_pipe | |
46 | command_close_bidi_pipe | |
47 | ); | |
48 | ||
49 | BEGIN { | |
50 | Memoize::memoize 'Git::config'; | |
51 | Memoize::memoize 'Git::config_bool'; | |
52 | } | |
53 | ||
54 | ||
55 | # From which subdir have we been invoked? | |
56 | my $cmd_dir_prefix = eval { | |
57 | command_oneline([qw/rev-parse --show-prefix/], STDERR => 0) | |
58 | } || ''; | |
59 | ||
60 | $Git::SVN::Ra::_log_window_size = 100; | |
61 | ||
62 | if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) { | |
63 | $ENV{SVN_SSH} = $ENV{GIT_SSH}; | |
64 | } | |
65 | ||
66 | if (exists $ENV{SVN_SSH} && $^O eq 'msys') { | |
67 | $ENV{SVN_SSH} =~ s/\\/\\\\/g; | |
68 | $ENV{SVN_SSH} =~ s/(.*)/"$1"/; | |
69 | } | |
70 | ||
71 | $Git::SVN::Log::TZ = $ENV{TZ}; | |
72 | $ENV{TZ} = 'UTC'; | |
73 | $| = 1; # unbuffer STDOUT | |
74 | ||
75 | # All SVN commands do it. Otherwise we may die on SIGPIPE when the remote | |
76 | # repository decides to close the connection which we expect to be kept alive. | |
77 | $SIG{PIPE} = 'IGNORE'; | |
78 | ||
79 | # Given a dot separated version number, "subtract" it from | |
80 | # the SVN::Core::VERSION; non-negaitive return means the SVN::Core | |
81 | # is at least at the version the caller asked for. | |
82 | sub compare_svn_version { | |
83 | my (@ours) = split(/\./, $SVN::Core::VERSION); | |
84 | my (@theirs) = split(/\./, $_[0]); | |
85 | my ($i, $diff); | |
86 | ||
87 | for ($i = 0; $i < @ours && $i < @theirs; $i++) { | |
88 | $diff = $ours[$i] - $theirs[$i]; | |
89 | return $diff if ($diff); | |
90 | } | |
91 | return 1 if ($i < @ours); | |
92 | return -1 if ($i < @theirs); | |
93 | return 0; | |
94 | } | |
95 | ||
96 | sub _req_svn { | |
97 | require SVN::Core; # use()-ing this causes segfaults for me... *shrug* | |
98 | require SVN::Ra; | |
99 | require SVN::Delta; | |
100 | if (::compare_svn_version('1.1.0') < 0) { | |
101 | fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)"; | |
102 | } | |
103 | } | |
104 | ||
105 | $sha1 = qr/[a-f\d]{40}/; | |
106 | $sha1_short = qr/[a-f\d]{4,40}/; | |
107 | my ($_stdin, $_help, $_edit, | |
108 | $_message, $_file, $_branch_dest, | |
109 | $_template, $_shared, | |
110 | $_version, $_fetch_all, $_no_rebase, $_fetch_parent, | |
111 | $_before, $_after, | |
112 | $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local, | |
113 | $_prefix, $_no_checkout, $_url, $_verbose, | |
114 | $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props); | |
115 | ||
116 | # This is a refactoring artifact so Git::SVN can get at this git-svn switch. | |
117 | sub opt_prefix { return $_prefix || '' } | |
118 | ||
119 | $Git::SVN::Fetcher::_placeholder_filename = ".gitignore"; | |
120 | $_q ||= 0; | |
121 | my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username, | |
122 | 'config-dir=s' => \$Git::SVN::Ra::config_dir, | |
123 | 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache, | |
124 | 'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex, | |
125 | 'include-paths=s' => \$Git::SVN::Fetcher::_include_regex, | |
126 | 'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex ); | |
127 | my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent, | |
128 | 'authors-file|A=s' => \$_authors, | |
129 | 'authors-prog=s' => \$_authors_prog, | |
130 | 'repack:i' => \$Git::SVN::_repack, | |
131 | 'noMetadata' => \$Git::SVN::_no_metadata, | |
132 | 'useSvmProps' => \$Git::SVN::_use_svm_props, | |
133 | 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props, | |
134 | 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size, | |
135 | 'no-checkout' => \$_no_checkout, | |
136 | 'quiet|q+' => \$_q, | |
137 | 'repack-flags|repack-args|repack-opts=s' => | |
138 | \$Git::SVN::_repack_flags, | |
139 | 'use-log-author' => \$Git::SVN::_use_log_author, | |
140 | 'add-author-from' => \$Git::SVN::_add_author_from, | |
141 | 'localtime' => \$Git::SVN::_localtime, | |
142 | %remote_opts ); | |
143 | ||
144 | my ($_trunk, @_tags, @_branches, $_stdlayout); | |
145 | my %icv; | |
146 | my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared, | |
147 | 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags, | |
148 | 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix, | |
149 | 'stdlayout|s' => \$_stdlayout, | |
150 | 'minimize-url|m!' => \$Git::SVN::_minimize_url, | |
151 | 'no-metadata' => sub { $icv{noMetadata} = 1 }, | |
152 | 'use-svm-props' => sub { $icv{useSvmProps} = 1 }, | |
153 | 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 }, | |
154 | 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] }, | |
155 | 'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] }, | |
156 | %remote_opts ); | |
157 | my %cmt_opts = ( 'edit|e' => \$_edit, | |
158 | 'rmdir' => \$Git::SVN::Editor::_rmdir, | |
159 | 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder, | |
160 | 'l=i' => \$Git::SVN::Editor::_rename_limit, | |
161 | 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity | |
162 | ); | |
163 | ||
164 | my %cmd = ( | |
165 | fetch => [ \&cmd_fetch, "Download new revisions from SVN", | |
166 | { 'revision|r=s' => \$_revision, | |
167 | 'fetch-all|all' => \$_fetch_all, | |
168 | 'parent|p' => \$_fetch_parent, | |
169 | %fc_opts } ], | |
170 | clone => [ \&cmd_clone, "Initialize and fetch revisions", | |
171 | { 'revision|r=s' => \$_revision, | |
172 | 'preserve-empty-dirs' => | |
173 | \$Git::SVN::Fetcher::_preserve_empty_dirs, | |
174 | 'placeholder-filename=s' => | |
175 | \$Git::SVN::Fetcher::_placeholder_filename, | |
176 | %fc_opts, %init_opts } ], | |
177 | init => [ \&cmd_init, "Initialize a repo for tracking" . | |
178 | " (requires URL argument)", | |
179 | \%init_opts ], | |
180 | 'multi-init' => [ \&cmd_multi_init, | |
181 | "Deprecated alias for ". | |
182 | "'$0 init -T<trunk> -b<branches> -t<tags>'", | |
183 | \%init_opts ], | |
184 | dcommit => [ \&cmd_dcommit, | |
185 | 'Commit several diffs to merge with upstream', | |
186 | { 'merge|m|M' => \$_merge, | |
187 | 'strategy|s=s' => \$_strategy, | |
188 | 'verbose|v' => \$_verbose, | |
189 | 'dry-run|n' => \$_dry_run, | |
190 | 'fetch-all|all' => \$_fetch_all, | |
191 | 'commit-url=s' => \$_commit_url, | |
192 | 'set-svn-props=s' => \$_set_svn_props, | |
193 | 'revision|r=i' => \$_revision, | |
194 | 'no-rebase' => \$_no_rebase, | |
195 | 'mergeinfo=s' => \$_merge_info, | |
196 | 'interactive|i' => \$_interactive, | |
197 | %cmt_opts, %fc_opts } ], | |
198 | branch => [ \&cmd_branch, | |
199 | 'Create a branch in the SVN repository', | |
200 | { 'message|m=s' => \$_message, | |
201 | 'destination|d=s' => \$_branch_dest, | |
202 | 'dry-run|n' => \$_dry_run, | |
203 | 'parents' => \$_parents, | |
204 | 'tag|t' => \$_tag, | |
205 | 'username=s' => \$Git::SVN::Prompt::_username, | |
206 | 'commit-url=s' => \$_commit_url } ], | |
207 | tag => [ sub { $_tag = 1; cmd_branch(@_) }, | |
208 | 'Create a tag in the SVN repository', | |
209 | { 'message|m=s' => \$_message, | |
210 | 'destination|d=s' => \$_branch_dest, | |
211 | 'dry-run|n' => \$_dry_run, | |
212 | 'parents' => \$_parents, | |
213 | 'username=s' => \$Git::SVN::Prompt::_username, | |
214 | 'commit-url=s' => \$_commit_url } ], | |
215 | 'set-tree' => [ \&cmd_set_tree, | |
216 | "Set an SVN repository to a git tree-ish", | |
217 | { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ], | |
218 | 'create-ignore' => [ \&cmd_create_ignore, | |
219 | 'Create a .gitignore per svn:ignore', | |
220 | { 'revision|r=i' => \$_revision | |
221 | } ], | |
222 | 'mkdirs' => [ \&cmd_mkdirs , | |
223 | "recreate empty directories after a checkout", | |
224 | { 'revision|r=i' => \$_revision } ], | |
225 | 'propget' => [ \&cmd_propget, | |
226 | 'Print the value of a property on a file or directory', | |
227 | { 'revision|r=i' => \$_revision } ], | |
228 | 'propset' => [ \&cmd_propset, | |
229 | 'Set the value of a property on a file or directory - will be set on commit', | |
230 | {} ], | |
231 | 'proplist' => [ \&cmd_proplist, | |
232 | 'List all properties of a file or directory', | |
233 | { 'revision|r=i' => \$_revision } ], | |
234 | 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings", | |
235 | { 'revision|r=i' => \$_revision | |
236 | } ], | |
237 | 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings", | |
238 | { 'revision|r=i' => \$_revision | |
239 | } ], | |
240 | 'multi-fetch' => [ \&cmd_multi_fetch, | |
241 | "Deprecated alias for $0 fetch --all", | |
242 | { 'revision|r=s' => \$_revision, %fc_opts } ], | |
243 | 'migrate' => [ sub { }, | |
244 | # no-op, we automatically run this anyways, | |
245 | 'Migrate configuration/metadata/layout from | |
246 | previous versions of git-svn', | |
247 | { 'minimize' => \$Git::SVN::Migration::_minimize, | |
248 | %remote_opts } ], | |
249 | 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs', | |
250 | { 'limit=i' => \$Git::SVN::Log::limit, | |
251 | 'revision|r=s' => \$_revision, | |
252 | 'verbose|v' => \$Git::SVN::Log::verbose, | |
253 | 'incremental' => \$Git::SVN::Log::incremental, | |
254 | 'oneline' => \$Git::SVN::Log::oneline, | |
255 | 'show-commit' => \$Git::SVN::Log::show_commit, | |
256 | 'non-recursive' => \$Git::SVN::Log::non_recursive, | |
257 | 'authors-file|A=s' => \$_authors, | |
258 | 'color' => \$Git::SVN::Log::color, | |
259 | 'pager=s' => \$Git::SVN::Log::pager | |
260 | } ], | |
261 | 'find-rev' => [ \&cmd_find_rev, | |
262 | "Translate between SVN revision numbers and tree-ish", | |
263 | { 'B|before' => \$_before, | |
264 | 'A|after' => \$_after } ], | |
265 | 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory", | |
266 | { 'merge|m|M' => \$_merge, | |
267 | 'verbose|v' => \$_verbose, | |
268 | 'strategy|s=s' => \$_strategy, | |
269 | 'local|l' => \$_local, | |
270 | 'fetch-all|all' => \$_fetch_all, | |
271 | 'dry-run|n' => \$_dry_run, | |
272 | 'preserve-merges|p' => \$_preserve_merges, | |
273 | %fc_opts } ], | |
274 | 'commit-diff' => [ \&cmd_commit_diff, | |
275 | 'Commit a diff between two trees', | |
276 | { 'message|m=s' => \$_message, | |
277 | 'file|F=s' => \$_file, | |
278 | 'revision|r=s' => \$_revision, | |
279 | %cmt_opts } ], | |
280 | 'info' => [ \&cmd_info, | |
281 | "Show info about the latest SVN revision | |
282 | on the current branch", | |
283 | { 'url' => \$_url, } ], | |
284 | 'blame' => [ \&Git::SVN::Log::cmd_blame, | |
285 | "Show what revision and author last modified each line of a file", | |
286 | { 'git-format' => \$Git::SVN::Log::_git_format } ], | |
287 | 'reset' => [ \&cmd_reset, | |
288 | "Undo fetches back to the specified SVN revision", | |
289 | { 'revision|r=s' => \$_revision, | |
290 | 'parent|p' => \$_fetch_parent } ], | |
291 | 'gc' => [ \&cmd_gc, | |
292 | "Compress unhandled.log files in .git/svn and remove " . | |
293 | "index files in .git/svn", | |
294 | {} ], | |
295 | ); | |
296 | ||
297 | package FakeTerm; | |
298 | sub new { | |
299 | my ($class, $reason) = @_; | |
300 | return bless \$reason, shift; | |
301 | } | |
302 | sub readline { | |
303 | my $self = shift; | |
304 | die "Cannot use readline on FakeTerm: $$self"; | |
305 | } | |
306 | package main; | |
307 | ||
308 | my $term; | |
309 | sub term_init { | |
310 | $term = eval { | |
311 | require Term::ReadLine; | |
312 | $ENV{"GIT_SVN_NOTTY"} | |
313 | ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT | |
314 | : new Term::ReadLine 'git-svn'; | |
315 | }; | |
316 | if ($@) { | |
317 | $term = new FakeTerm "$@: going non-interactive"; | |
318 | } | |
319 | } | |
320 | ||
321 | my $cmd; | |
322 | for (my $i = 0; $i < @ARGV; $i++) { | |
323 | if (defined $cmd{$ARGV[$i]}) { | |
324 | $cmd = $ARGV[$i]; | |
325 | splice @ARGV, $i, 1; | |
326 | last; | |
327 | } elsif ($ARGV[$i] eq 'help') { | |
328 | $cmd = $ARGV[$i+1]; | |
329 | usage(0); | |
330 | } | |
331 | }; | |
332 | ||
333 | # make sure we're always running at the top-level working directory | |
334 | if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) { | |
335 | $ENV{GIT_DIR} ||= ".git"; | |
336 | # catch the submodule case | |
337 | if (-f $ENV{GIT_DIR}) { | |
338 | open(my $fh, '<', $ENV{GIT_DIR}) or | |
339 | die "failed to open $ENV{GIT_DIR}: $!\n"; | |
340 | $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/; | |
341 | } | |
342 | } else { | |
343 | my ($git_dir, $cdup); | |
344 | git_cmd_try { | |
345 | $git_dir = command_oneline([qw/rev-parse --git-dir/]); | |
346 | } "Unable to find .git directory\n"; | |
347 | git_cmd_try { | |
348 | $cdup = command_oneline(qw/rev-parse --show-cdup/); | |
349 | chomp $cdup if ($cdup); | |
350 | $cdup = "." unless ($cdup && length $cdup); | |
351 | } "Already at toplevel, but $git_dir not found\n"; | |
352 | $ENV{GIT_DIR} = $git_dir; | |
353 | chdir $cdup or die "Unable to chdir up to '$cdup'\n"; | |
354 | $_repository = Git->repository(Repository => $ENV{GIT_DIR}); | |
355 | } | |
356 | ||
357 | my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd); | |
358 | ||
359 | read_git_config(\%opts); | |
360 | if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) { | |
361 | Getopt::Long::Configure('pass_through'); | |
362 | } | |
363 | my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version, | |
364 | 'minimize-connections' => \$Git::SVN::Migration::_minimize, | |
365 | 'id|i=s' => \$Git::SVN::default_ref_id, | |
366 | 'svn-remote|remote|R=s' => sub { | |
367 | $Git::SVN::no_reuse_existing = 1; | |
368 | $Git::SVN::default_repo_id = $_[1] }); | |
369 | exit 1 if (!$rv && $cmd && $cmd ne 'log'); | |
370 | ||
371 | usage(0) if $_help; | |
372 | version() if $_version; | |
373 | usage(1) unless defined $cmd; | |
374 | load_authors() if $_authors; | |
375 | if (defined $_authors_prog) { | |
376 | $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'"; | |
377 | } | |
378 | ||
379 | unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) { | |
380 | Git::SVN::Migration::migration_check(); | |
381 | } | |
382 | Git::SVN::init_vars(); | |
383 | eval { | |
384 | Git::SVN::verify_remotes_sanity(); | |
385 | $cmd{$cmd}->[0]->(@ARGV); | |
386 | post_fetch_checkout(); | |
387 | }; | |
388 | fatal $@ if $@; | |
389 | exit 0; | |
390 | ||
391 | ####################### primary functions ###################### | |
392 | sub usage { | |
393 | my $exit = shift || 0; | |
394 | my $fd = $exit ? \*STDERR : \*STDOUT; | |
395 | print $fd <<""; | |
396 | git-svn - bidirectional operations between a single Subversion tree and git | |
397 | usage: git svn <command> [options] [arguments]\n | |
398 | ||
399 | print $fd "Available commands:\n" unless $cmd; | |
400 | ||
401 | foreach (sort keys %cmd) { | |
402 | next if $cmd && $cmd ne $_; | |
403 | next if /^multi-/; # don't show deprecated commands | |
404 | print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n"; | |
405 | foreach (sort keys %{$cmd{$_}->[2]}) { | |
406 | # mixed-case options are for .git/config only | |
407 | next if /[A-Z]/ && /^[a-z]+$/i; | |
408 | # prints out arguments as they should be passed: | |
409 | my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : ''; | |
410 | print $fd ' ' x 21, join(', ', map { length $_ > 1 ? | |
411 | "--$_" : "-$_" } | |
412 | split /\|/,$_)," $x\n"; | |
413 | } | |
414 | } | |
415 | print $fd <<""; | |
416 | \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an | |
417 | arbitrary identifier if you're tracking multiple SVN branches/repositories in | |
418 | one git repository and want to keep them separate. See git-svn(1) for more | |
419 | information. | |
420 | ||
421 | exit $exit; | |
422 | } | |
423 | ||
424 | sub version { | |
425 | ::_req_svn(); | |
426 | print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n"; | |
427 | exit 0; | |
428 | } | |
429 | ||
430 | sub ask { | |
431 | my ($prompt, %arg) = @_; | |
432 | my $valid_re = $arg{valid_re}; | |
433 | my $default = $arg{default}; | |
434 | my $resp; | |
435 | my $i = 0; | |
436 | term_init() unless $term; | |
437 | ||
438 | if ( !( defined($term->IN) | |
439 | && defined( fileno($term->IN) ) | |
440 | && defined( $term->OUT ) | |
441 | && defined( fileno($term->OUT) ) ) ){ | |
442 | return defined($default) ? $default : undef; | |
443 | } | |
444 | ||
445 | while ($i++ < 10) { | |
446 | $resp = $term->readline($prompt); | |
447 | if (!defined $resp) { # EOF | |
448 | print "\n"; | |
449 | return defined $default ? $default : undef; | |
450 | } | |
451 | if ($resp eq '' and defined $default) { | |
452 | return $default; | |
453 | } | |
454 | if (!defined $valid_re or $resp =~ /$valid_re/) { | |
455 | return $resp; | |
456 | } | |
457 | } | |
458 | return undef; | |
459 | } | |
460 | ||
461 | sub do_git_init_db { | |
462 | unless (-d $ENV{GIT_DIR}) { | |
463 | my @init_db = ('init'); | |
464 | push @init_db, "--template=$_template" if defined $_template; | |
465 | if (defined $_shared) { | |
466 | if ($_shared =~ /[a-z]/) { | |
467 | push @init_db, "--shared=$_shared"; | |
468 | } else { | |
469 | push @init_db, "--shared"; | |
470 | } | |
471 | } | |
472 | command_noisy(@init_db); | |
473 | $_repository = Git->repository(Repository => ".git"); | |
474 | } | |
475 | my $set; | |
476 | my $pfx = "svn-remote.$Git::SVN::default_repo_id"; | |
477 | foreach my $i (keys %icv) { | |
478 | die "'$set' and '$i' cannot both be set\n" if $set; | |
479 | next unless defined $icv{$i}; | |
480 | command_noisy('config', "$pfx.$i", $icv{$i}); | |
481 | $set = $i; | |
482 | } | |
483 | my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex; | |
484 | command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex) | |
485 | if defined $$ignore_paths_regex; | |
486 | my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex; | |
487 | command_noisy('config', "$pfx.include-paths", $$include_paths_regex) | |
488 | if defined $$include_paths_regex; | |
489 | my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex; | |
490 | command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex) | |
491 | if defined $$ignore_refs_regex; | |
492 | ||
493 | if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) { | |
494 | my $fname = \$Git::SVN::Fetcher::_placeholder_filename; | |
495 | command_noisy('config', "$pfx.preserve-empty-dirs", 'true'); | |
496 | command_noisy('config', "$pfx.placeholder-filename", $$fname); | |
497 | } | |
498 | } | |
499 | ||
500 | sub init_subdir { | |
501 | my $repo_path = shift or return; | |
502 | mkpath([$repo_path]) unless -d $repo_path; | |
503 | chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n"; | |
504 | $ENV{GIT_DIR} = '.git'; | |
505 | $_repository = Git->repository(Repository => $ENV{GIT_DIR}); | |
506 | } | |
507 | ||
508 | sub cmd_clone { | |
509 | my ($url, $path) = @_; | |
510 | if (!defined $path && | |
511 | (defined $_trunk || @_branches || @_tags || | |
512 | defined $_stdlayout) && | |
513 | $url !~ m#^[a-z\+]+://#) { | |
514 | $path = $url; | |
515 | } | |
516 | $path = basename($url) if !defined $path || !length $path; | |
517 | my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : ""; | |
518 | cmd_init($url, $path); | |
519 | command_oneline('config', 'svn.authorsfile', $authors_absolute) | |
520 | if $_authors; | |
521 | Git::SVN::fetch_all($Git::SVN::default_repo_id); | |
522 | } | |
523 | ||
524 | sub cmd_init { | |
525 | if (defined $_stdlayout) { | |
526 | $_trunk = 'trunk' if (!defined $_trunk); | |
527 | @_tags = 'tags' if (! @_tags); | |
528 | @_branches = 'branches' if (! @_branches); | |
529 | } | |
530 | if (defined $_trunk || @_branches || @_tags) { | |
531 | return cmd_multi_init(@_); | |
532 | } | |
533 | my $url = shift or die "SVN repository location required ", | |
534 | "as a command-line argument\n"; | |
535 | $url = canonicalize_url($url); | |
536 | init_subdir(@_); | |
537 | do_git_init_db(); | |
538 | ||
539 | if ($Git::SVN::_minimize_url eq 'unset') { | |
540 | $Git::SVN::_minimize_url = 0; | |
541 | } | |
542 | ||
543 | Git::SVN->init($url); | |
544 | } | |
545 | ||
546 | sub cmd_fetch { | |
547 | if (grep /^\d+=./, @_) { | |
548 | die "'<rev>=<commit>' fetch arguments are ", | |
549 | "no longer supported.\n"; | |
550 | } | |
551 | my ($remote) = @_; | |
552 | if (@_ > 1) { | |
553 | die "usage: $0 fetch [--all] [--parent] [svn-remote]\n"; | |
554 | } | |
555 | $Git::SVN::no_reuse_existing = undef; | |
556 | if ($_fetch_parent) { | |
557 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
558 | unless ($gs) { | |
559 | die "Unable to determine upstream SVN information from ", | |
560 | "working tree history\n"; | |
561 | } | |
562 | # just fetch, don't checkout. | |
563 | $_no_checkout = 'true'; | |
564 | $_fetch_all ? $gs->fetch_all : $gs->fetch; | |
565 | } elsif ($_fetch_all) { | |
566 | cmd_multi_fetch(); | |
567 | } else { | |
568 | $remote ||= $Git::SVN::default_repo_id; | |
569 | Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes()); | |
570 | } | |
571 | } | |
572 | ||
573 | sub cmd_set_tree { | |
574 | my (@commits) = @_; | |
575 | if ($_stdin || !@commits) { | |
576 | print "Reading from stdin...\n"; | |
577 | @commits = (); | |
578 | while (<STDIN>) { | |
579 | if (/\b($sha1_short)\b/o) { | |
580 | unshift @commits, $1; | |
581 | } | |
582 | } | |
583 | } | |
584 | my @revs; | |
585 | foreach my $c (@commits) { | |
586 | my @tmp = command('rev-parse',$c); | |
587 | if (scalar @tmp == 1) { | |
588 | push @revs, $tmp[0]; | |
589 | } elsif (scalar @tmp > 1) { | |
590 | push @revs, reverse(command('rev-list',@tmp)); | |
591 | } else { | |
592 | fatal "Failed to rev-parse $c"; | |
593 | } | |
594 | } | |
595 | my $gs = Git::SVN->new; | |
596 | my ($r_last, $cmt_last) = $gs->last_rev_commit; | |
597 | $gs->fetch; | |
598 | if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) { | |
599 | fatal "There are new revisions that were fetched ", | |
600 | "and need to be merged (or acknowledged) ", | |
601 | "before committing.\nlast rev: $r_last\n", | |
602 | " current: $gs->{last_rev}"; | |
603 | } | |
604 | $gs->set_tree($_) foreach @revs; | |
605 | print "Done committing ",scalar @revs," revisions to SVN\n"; | |
606 | unlink $gs->{index}; | |
607 | } | |
608 | ||
609 | sub split_merge_info_range { | |
610 | my ($range) = @_; | |
611 | if ($range =~ /(\d+)-(\d+)/) { | |
612 | return (int($1), int($2)); | |
613 | } else { | |
614 | return (int($range), int($range)); | |
615 | } | |
616 | } | |
617 | ||
618 | sub combine_ranges { | |
619 | my ($in) = @_; | |
620 | ||
621 | my @fnums = (); | |
622 | my @arr = split(/,/, $in); | |
623 | for my $element (@arr) { | |
624 | my ($start, $end) = split_merge_info_range($element); | |
625 | push @fnums, $start; | |
626 | } | |
627 | ||
628 | my @sorted = @arr [ sort { | |
629 | $fnums[$a] <=> $fnums[$b] | |
630 | } 0..$#arr ]; | |
631 | ||
632 | my @return = (); | |
633 | my $last = -1; | |
634 | my $first = -1; | |
635 | for my $element (@sorted) { | |
636 | my ($start, $end) = split_merge_info_range($element); | |
637 | ||
638 | if ($last == -1) { | |
639 | $first = $start; | |
640 | $last = $end; | |
641 | next; | |
642 | } | |
643 | if ($start <= $last+1) { | |
644 | if ($end > $last) { | |
645 | $last = $end; | |
646 | } | |
647 | next; | |
648 | } | |
649 | if ($first == $last) { | |
650 | push @return, "$first"; | |
651 | } else { | |
652 | push @return, "$first-$last"; | |
653 | } | |
654 | $first = $start; | |
655 | $last = $end; | |
656 | } | |
657 | ||
658 | if ($first != -1) { | |
659 | if ($first == $last) { | |
660 | push @return, "$first"; | |
661 | } else { | |
662 | push @return, "$first-$last"; | |
663 | } | |
664 | } | |
665 | ||
666 | return join(',', @return); | |
667 | } | |
668 | ||
669 | sub merge_revs_into_hash { | |
670 | my ($hash, $minfo) = @_; | |
671 | my @lines = split(' ', $minfo); | |
672 | ||
673 | for my $line (@lines) { | |
674 | my ($branchpath, $revs) = split(/:/, $line); | |
675 | ||
676 | if (exists($hash->{$branchpath})) { | |
677 | # Merge the two revision sets | |
678 | my $combined = "$hash->{$branchpath},$revs"; | |
679 | $hash->{$branchpath} = combine_ranges($combined); | |
680 | } else { | |
681 | # Just do range combining for consolidation | |
682 | $hash->{$branchpath} = combine_ranges($revs); | |
683 | } | |
684 | } | |
685 | } | |
686 | ||
687 | sub merge_merge_info { | |
688 | my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_; | |
689 | my %result_hash = (); | |
690 | ||
691 | merge_revs_into_hash(\%result_hash, $mergeinfo_one); | |
692 | merge_revs_into_hash(\%result_hash, $mergeinfo_two); | |
693 | ||
694 | delete $result_hash{$ignore_branch} if $ignore_branch; | |
695 | ||
696 | my $result = ''; | |
697 | # Sort below is for consistency's sake | |
698 | for my $branchname (sort keys(%result_hash)) { | |
699 | my $revlist = $result_hash{$branchname}; | |
700 | $result .= "$branchname:$revlist\n" | |
701 | } | |
702 | return $result; | |
703 | } | |
704 | ||
705 | sub populate_merge_info { | |
706 | my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_; | |
707 | ||
708 | my %parentshash; | |
709 | read_commit_parents(\%parentshash, $d); | |
710 | my @parents = @{$parentshash{$d}}; | |
711 | if ($#parents > 0) { | |
712 | # Merge commit | |
713 | my $all_parents_ok = 1; | |
714 | my $aggregate_mergeinfo = ''; | |
715 | my $rooturl = $gs->repos_root; | |
716 | my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/; | |
717 | ||
718 | if (defined($rewritten_parent)) { | |
719 | # Replace first parent with newly-rewritten version | |
720 | shift @parents; | |
721 | unshift @parents, $rewritten_parent; | |
722 | } | |
723 | ||
724 | foreach my $parent (@parents) { | |
725 | my ($branchurl, $svnrev, $paruuid) = | |
726 | cmt_metadata($parent); | |
727 | ||
728 | unless (defined($svnrev)) { | |
729 | # Should have been caught be preflight check | |
730 | fatal "merge commit $d has ancestor $parent, but that change " | |
731 | ."does not have git-svn metadata!"; | |
732 | } | |
733 | unless ($branchurl =~ /^\Q$rooturl\E(.*)/) { | |
734 | fatal "commit $parent git-svn metadata changed mid-run!"; | |
735 | } | |
736 | my $branchpath = $1; | |
737 | ||
738 | my $ra = Git::SVN::Ra->new($branchurl); | |
739 | my (undef, undef, $props) = | |
740 | $ra->get_dir(canonicalize_path("."), $svnrev); | |
741 | my $par_mergeinfo = $props->{'svn:mergeinfo'}; | |
742 | unless (defined $par_mergeinfo) { | |
743 | $par_mergeinfo = ''; | |
744 | } | |
745 | # Merge previous mergeinfo values | |
746 | $aggregate_mergeinfo = | |
747 | merge_merge_info($aggregate_mergeinfo, | |
748 | $par_mergeinfo, | |
749 | $target_branch); | |
750 | ||
751 | next if $parent eq $parents[0]; # Skip first parent | |
752 | # Add new changes being placed in tree by merge | |
753 | my @cmd = (qw/rev-list --reverse/, | |
754 | $parent, qw/--not/); | |
755 | foreach my $par (@parents) { | |
756 | unless ($par eq $parent) { | |
757 | push @cmd, $par; | |
758 | } | |
759 | } | |
760 | my @revsin = (); | |
761 | my ($revlist, $ctx) = command_output_pipe(@cmd); | |
762 | while (<$revlist>) { | |
763 | my $irev = $_; | |
764 | chomp $irev; | |
765 | my (undef, $csvnrev, undef) = | |
766 | cmt_metadata($irev); | |
767 | unless (defined $csvnrev) { | |
768 | # A child is missing SVN annotations... | |
769 | # this might be OK, or might not be. | |
770 | warn "W:child $irev is merged into revision " | |
771 | ."$d but does not have git-svn metadata. " | |
772 | ."This means git-svn cannot determine the " | |
773 | ."svn revision numbers to place into the " | |
774 | ."svn:mergeinfo property. You must ensure " | |
775 | ."a branch is entirely committed to " | |
776 | ."SVN before merging it in order for " | |
777 | ."svn:mergeinfo population to function " | |
778 | ."properly"; | |
779 | } | |
780 | push @revsin, $csvnrev; | |
781 | } | |
782 | command_close_pipe($revlist, $ctx); | |
783 | ||
784 | last unless $all_parents_ok; | |
785 | ||
786 | # We now have a list of all SVN revnos which are | |
787 | # merged by this particular parent. Integrate them. | |
788 | next if $#revsin == -1; | |
789 | my $newmergeinfo = "$branchpath:" . join(',', @revsin); | |
790 | $aggregate_mergeinfo = | |
791 | merge_merge_info($aggregate_mergeinfo, | |
792 | $newmergeinfo, | |
793 | $target_branch); | |
794 | } | |
795 | if ($all_parents_ok and $aggregate_mergeinfo) { | |
796 | return $aggregate_mergeinfo; | |
797 | } | |
798 | } | |
799 | ||
800 | return undef; | |
801 | } | |
802 | ||
803 | sub dcommit_rebase { | |
804 | my ($is_last, $current, $fetched_ref, $svn_error) = @_; | |
805 | my @diff; | |
806 | ||
807 | if ($svn_error) { | |
808 | print STDERR "\nERROR from SVN:\n", | |
809 | $svn_error->expanded_message, "\n"; | |
810 | } | |
811 | unless ($_no_rebase) { | |
812 | # we always want to rebase against the current HEAD, | |
813 | # not any head that was passed to us | |
814 | @diff = command('diff-tree', $current, | |
815 | $fetched_ref, '--'); | |
816 | my @finish; | |
817 | if (@diff) { | |
818 | @finish = rebase_cmd(); | |
819 | print STDERR "W: $current and ", $fetched_ref, | |
820 | " differ, using @finish:\n", | |
821 | join("\n", @diff), "\n"; | |
822 | } elsif ($is_last) { | |
823 | print "No changes between ", $current, " and ", | |
824 | $fetched_ref, | |
825 | "\nResetting to the latest ", | |
826 | $fetched_ref, "\n"; | |
827 | @finish = qw/reset --mixed/; | |
828 | } | |
829 | command_noisy(@finish, $fetched_ref) if @finish; | |
830 | } | |
831 | if ($svn_error) { | |
832 | die "ERROR: Not all changes have been committed into SVN" | |
833 | .($_no_rebase ? ".\n" : ", however the committed\n" | |
834 | ."ones (if any) seem to be successfully integrated " | |
835 | ."into the working tree.\n") | |
836 | ."Please see the above messages for details.\n"; | |
837 | } | |
838 | return @diff; | |
839 | } | |
840 | ||
841 | sub cmd_dcommit { | |
842 | my $head = shift; | |
843 | command_noisy(qw/update-index --refresh/); | |
844 | git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) } | |
845 | 'Cannot dcommit with a dirty index. Commit your changes first, ' | |
846 | . "or stash them with `git stash'.\n"; | |
847 | $head ||= 'HEAD'; | |
848 | ||
849 | my $old_head; | |
850 | if ($head ne 'HEAD') { | |
851 | $old_head = eval { | |
852 | command_oneline([qw/symbolic-ref -q HEAD/]) | |
853 | }; | |
854 | if ($old_head) { | |
855 | $old_head =~ s{^refs/heads/}{}; | |
856 | } else { | |
857 | $old_head = eval { command_oneline(qw/rev-parse HEAD/) }; | |
858 | } | |
859 | command(['checkout', $head], STDERR => 0); | |
860 | } | |
861 | ||
862 | my @refs; | |
863 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs); | |
864 | unless ($gs) { | |
865 | die "Unable to determine upstream SVN information from ", | |
866 | "$head history.\nPerhaps the repository is empty."; | |
867 | } | |
868 | ||
869 | if (defined $_commit_url) { | |
870 | $url = $_commit_url; | |
871 | } else { | |
872 | $url = eval { command_oneline('config', '--get', | |
873 | "svn-remote.$gs->{repo_id}.commiturl") }; | |
874 | if (!$url) { | |
875 | $url = $gs->full_pushurl | |
876 | } | |
877 | } | |
878 | ||
879 | my $last_rev = $_revision if defined $_revision; | |
880 | if ($url) { | |
881 | print "Committing to $url ...\n"; | |
882 | } | |
883 | my ($linear_refs, $parents) = linearize_history($gs, \@refs); | |
884 | if ($_no_rebase && scalar(@$linear_refs) > 1) { | |
885 | warn "Attempting to commit more than one change while ", | |
886 | "--no-rebase is enabled.\n", | |
887 | "If these changes depend on each other, re-running ", | |
888 | "without --no-rebase may be required." | |
889 | } | |
890 | ||
891 | if (defined $_interactive){ | |
892 | my $ask_default = "y"; | |
893 | foreach my $d (@$linear_refs){ | |
894 | my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d"); | |
895 | while (<$fh>){ | |
896 | print $_; | |
897 | } | |
898 | command_close_pipe($fh, $ctx); | |
899 | $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ", | |
900 | valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i, | |
901 | default => $ask_default); | |
902 | die "Commit this patch reply required" unless defined $_; | |
903 | if (/^[nq]/i) { | |
904 | exit(0); | |
905 | } elsif (/^a/i) { | |
906 | last; | |
907 | } | |
908 | } | |
909 | } | |
910 | ||
911 | my $expect_url = $url; | |
912 | ||
913 | my $push_merge_info = eval { | |
914 | command_oneline(qw/config --get svn.pushmergeinfo/) | |
915 | }; | |
916 | if (not defined($push_merge_info) | |
917 | or $push_merge_info eq "false" | |
918 | or $push_merge_info eq "no" | |
919 | or $push_merge_info eq "never") { | |
920 | $push_merge_info = 0; | |
921 | } | |
922 | ||
923 | unless (defined($_merge_info) || ! $push_merge_info) { | |
924 | # Preflight check of changes to ensure no issues with mergeinfo | |
925 | # This includes check for uncommitted-to-SVN parents | |
926 | # (other than the first parent, which we will handle), | |
927 | # information from different SVN repos, and paths | |
928 | # which are not underneath this repository root. | |
929 | my $rooturl = $gs->repos_root; | |
930 | foreach my $d (@$linear_refs) { | |
931 | my %parentshash; | |
932 | read_commit_parents(\%parentshash, $d); | |
933 | my @realparents = @{$parentshash{$d}}; | |
934 | if ($#realparents > 0) { | |
935 | # Merge commit | |
936 | shift @realparents; # Remove/ignore first parent | |
937 | foreach my $parent (@realparents) { | |
938 | my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent); | |
939 | unless (defined $paruuid) { | |
940 | # A parent is missing SVN annotations... | |
941 | # abort the whole operation. | |
942 | fatal "$parent is merged into revision $d, " | |
943 | ."but does not have git-svn metadata. " | |
944 | ."Either dcommit the branch or use a " | |
945 | ."local cherry-pick, FF merge, or rebase " | |
946 | ."instead of an explicit merge commit."; | |
947 | } | |
948 | ||
949 | unless ($paruuid eq $uuid) { | |
950 | # Parent has SVN metadata from different repository | |
951 | fatal "merge parent $parent for change $d has " | |
952 | ."git-svn uuid $paruuid, while current change " | |
953 | ."has uuid $uuid!"; | |
954 | } | |
955 | ||
956 | unless ($branchurl =~ /^\Q$rooturl\E(.*)/) { | |
957 | # This branch is very strange indeed. | |
958 | fatal "merge parent $parent for $d is on branch " | |
959 | ."$branchurl, which is not under the " | |
960 | ."git-svn root $rooturl!"; | |
961 | } | |
962 | } | |
963 | } | |
964 | } | |
965 | } | |
966 | ||
967 | my $rewritten_parent; | |
968 | my $current_head = command_oneline(qw/rev-parse HEAD/); | |
969 | Git::SVN::remove_username($expect_url); | |
970 | if (defined($_merge_info)) { | |
971 | $_merge_info =~ tr{ }{\n}; | |
972 | } | |
973 | while (1) { | |
974 | my $d = shift @$linear_refs or last; | |
975 | unless (defined $last_rev) { | |
976 | (undef, $last_rev, undef) = cmt_metadata("$d~1"); | |
977 | unless (defined $last_rev) { | |
978 | fatal "Unable to extract revision information ", | |
979 | "from commit $d~1"; | |
980 | } | |
981 | } | |
982 | if ($_dry_run) { | |
983 | print "diff-tree $d~1 $d\n"; | |
984 | } else { | |
985 | my $cmt_rev; | |
986 | ||
987 | unless (defined($_merge_info) || ! $push_merge_info) { | |
988 | $_merge_info = populate_merge_info($d, $gs, | |
989 | $uuid, | |
990 | $linear_refs, | |
991 | $rewritten_parent); | |
992 | } | |
993 | ||
994 | my %ed_opts = ( r => $last_rev, | |
995 | log => get_commit_entry($d)->{log}, | |
996 | ra => Git::SVN::Ra->new($url), | |
997 | config => SVN::Core::config_get_config( | |
998 | $Git::SVN::Ra::config_dir | |
999 | ), | |
1000 | tree_a => "$d~1", | |
1001 | tree_b => $d, | |
1002 | editor_cb => sub { | |
1003 | print "Committed r$_[0]\n"; | |
1004 | $cmt_rev = $_[0]; | |
1005 | }, | |
1006 | mergeinfo => $_merge_info, | |
1007 | svn_path => ''); | |
1008 | ||
1009 | my $err_handler = $SVN::Error::handler; | |
1010 | $SVN::Error::handler = sub { | |
1011 | my $err = shift; | |
1012 | dcommit_rebase(1, $current_head, $gs->refname, | |
1013 | $err); | |
1014 | }; | |
1015 | ||
1016 | if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) { | |
1017 | print "No changes\n$d~1 == $d\n"; | |
1018 | } elsif ($parents->{$d} && @{$parents->{$d}}) { | |
1019 | $gs->{inject_parents_dcommit}->{$cmt_rev} = | |
1020 | $parents->{$d}; | |
1021 | } | |
1022 | $_fetch_all ? $gs->fetch_all : $gs->fetch; | |
1023 | $SVN::Error::handler = $err_handler; | |
1024 | $last_rev = $cmt_rev; | |
1025 | next if $_no_rebase; | |
1026 | ||
1027 | my @diff = dcommit_rebase(@$linear_refs == 0, $d, | |
1028 | $gs->refname, undef); | |
1029 | ||
1030 | $rewritten_parent = command_oneline(qw/rev-parse/, | |
1031 | $gs->refname); | |
1032 | ||
1033 | if (@diff) { | |
1034 | $current_head = command_oneline(qw/rev-parse | |
1035 | HEAD/); | |
1036 | @refs = (); | |
1037 | my ($url_, $rev_, $uuid_, $gs_) = | |
1038 | working_head_info('HEAD', \@refs); | |
1039 | my ($linear_refs_, $parents_) = | |
1040 | linearize_history($gs_, \@refs); | |
1041 | if (scalar(@$linear_refs) != | |
1042 | scalar(@$linear_refs_)) { | |
1043 | fatal "# of revisions changed ", | |
1044 | "\nbefore:\n", | |
1045 | join("\n", @$linear_refs), | |
1046 | "\n\nafter:\n", | |
1047 | join("\n", @$linear_refs_), "\n", | |
1048 | 'If you are attempting to commit ', | |
1049 | "merges, try running:\n\t", | |
1050 | 'git rebase --interactive', | |
1051 | '--preserve-merges ', | |
1052 | $gs->refname, | |
1053 | "\nBefore dcommitting"; | |
1054 | } | |
1055 | if ($url_ ne $expect_url) { | |
1056 | if ($url_ eq $gs->metadata_url) { | |
1057 | ||
1058 | "Accepting rewritten URL:", | |
1059 | " $url_\n"; | |
1060 | } else { | |
1061 | fatal | |
1062 | "URL mismatch after rebase:", | |
1063 | " $url_ != $expect_url"; | |
1064 | } | |
1065 | } | |
1066 | if ($uuid_ ne $uuid) { | |
1067 | fatal "uuid mismatch after rebase: ", | |
1068 | "$uuid_ != $uuid"; | |
1069 | } | |
1070 | # remap parents | |
1071 | my (%p, @l, $i); | |
1072 | for ($i = 0; $i < scalar @$linear_refs; $i++) { | |
1073 | my $new = $linear_refs_->[$i] or next; | |
1074 | $p{$new} = | |
1075 | $parents->{$linear_refs->[$i]}; | |
1076 | push @l, $new; | |
1077 | } | |
1078 | $parents = \%p; | |
1079 | $linear_refs = \@l; | |
1080 | undef $last_rev; | |
1081 | } | |
1082 | } | |
1083 | } | |
1084 | ||
1085 | if ($old_head) { | |
1086 | my $new_head = command_oneline(qw/rev-parse HEAD/); | |
1087 | my $new_is_symbolic = eval { | |
1088 | command_oneline(qw/symbolic-ref -q HEAD/); | |
1089 | }; | |
1090 | if ($new_is_symbolic) { | |
1091 | print "dcommitted the branch ", $head, "\n"; | |
1092 | } else { | |
1093 | print "dcommitted on a detached HEAD because you gave ", | |
1094 | "a revision argument.\n", | |
1095 | "The rewritten commit is: ", $new_head, "\n"; | |
1096 | } | |
1097 | command(['checkout', $old_head], STDERR => 0); | |
1098 | } | |
1099 | ||
1100 | unlink $gs->{index}; | |
1101 | } | |
1102 | ||
1103 | sub cmd_branch { | |
1104 | my ($branch_name, $head) = @_; | |
1105 | ||
1106 | unless (defined $branch_name && length $branch_name) { | |
1107 | die(($_tag ? "tag" : "branch") . " name required\n"); | |
1108 | } | |
1109 | $head ||= 'HEAD'; | |
1110 | ||
1111 | my (undef, $rev, undef, $gs) = working_head_info($head); | |
1112 | my $src = $gs->full_pushurl; | |
1113 | ||
1114 | my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}}; | |
1115 | my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' }; | |
1116 | my $glob; | |
1117 | if ($#{$allglobs} == 0) { | |
1118 | $glob = $allglobs->[0]; | |
1119 | } else { | |
1120 | unless(defined $_branch_dest) { | |
1121 | die "Multiple ", | |
1122 | $_tag ? "tag" : "branch", | |
1123 | " paths defined for Subversion repository.\n", | |
1124 | "You must specify where you want to create the ", | |
1125 | $_tag ? "tag" : "branch", | |
1126 | " with the --destination argument.\n"; | |
1127 | } | |
1128 | foreach my $g (@{$allglobs}) { | |
1129 | my $re = Git::SVN::Editor::glob2pat($g->{path}->{left}); | |
1130 | if ($_branch_dest =~ /$re/) { | |
1131 | $glob = $g; | |
1132 | last; | |
1133 | } | |
1134 | } | |
1135 | unless (defined $glob) { | |
1136 | my $dest_re = qr/\b\Q$_branch_dest\E\b/; | |
1137 | foreach my $g (@{$allglobs}) { | |
1138 | $g->{path}->{left} =~ /$dest_re/ or next; | |
1139 | if (defined $glob) { | |
1140 | die "Ambiguous destination: ", | |
1141 | $_branch_dest, "\nmatches both '", | |
1142 | $glob->{path}->{left}, "' and '", | |
1143 | $g->{path}->{left}, "'\n"; | |
1144 | } | |
1145 | $glob = $g; | |
1146 | } | |
1147 | unless (defined $glob) { | |
1148 | die "Unknown ", | |
1149 | $_tag ? "tag" : "branch", | |
1150 | " destination $_branch_dest\n"; | |
1151 | } | |
1152 | } | |
1153 | } | |
1154 | my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/}; | |
1155 | my $url; | |
1156 | if (defined $_commit_url) { | |
1157 | $url = $_commit_url; | |
1158 | } else { | |
1159 | $url = eval { command_oneline('config', '--get', | |
1160 | "svn-remote.$gs->{repo_id}.commiturl") }; | |
1161 | if (!$url) { | |
1162 | $url = $remote->{pushurl} || $remote->{url}; | |
1163 | } | |
1164 | } | |
1165 | my $dst = join '/', $url, $lft, $branch_name, ($rgt || ()); | |
1166 | ||
1167 | if ($dst =~ /^https:/ && $src =~ /^http:/) { | |
1168 | $src=~s/^http:/https:/; | |
1169 | } | |
1170 | ||
1171 | ::_req_svn(); | |
1172 | require SVN::Client; | |
1173 | ||
1174 | my $ctx = SVN::Client->new( | |
1175 | config => SVN::Core::config_get_config( | |
1176 | $Git::SVN::Ra::config_dir | |
1177 | ), | |
1178 | log_msg => sub { | |
1179 | ${ $_[0] } = defined $_message | |
1180 | ? $_message | |
1181 | : 'Create ' . ($_tag ? 'tag ' : 'branch ' ) | |
1182 | . $branch_name; | |
1183 | }, | |
1184 | ); | |
1185 | ||
1186 | eval { | |
1187 | $ctx->ls($dst, 'HEAD', 0); | |
1188 | } and die "branch ${branch_name} already exists\n"; | |
1189 | ||
1190 | if ($_parents) { | |
1191 | mk_parent_dirs($ctx, $dst); | |
1192 | } | |
1193 | ||
1194 | print "Copying ${src} at r${rev} to ${dst}...\n"; | |
1195 | $ctx->copy($src, $rev, $dst) | |
1196 | unless $_dry_run; | |
1197 | ||
1198 | $gs->fetch_all; | |
1199 | } | |
1200 | ||
1201 | sub mk_parent_dirs { | |
1202 | my ($ctx, $parent) = @_; | |
1203 | $parent =~ s{/[^/]*$}{}; | |
1204 | ||
1205 | if (!eval{$ctx->ls($parent, 'HEAD', 0)}) { | |
1206 | mk_parent_dirs($ctx, $parent); | |
1207 | print "Creating parent folder ${parent} ...\n"; | |
1208 | $ctx->mkdir($parent) unless $_dry_run; | |
1209 | } | |
1210 | } | |
1211 | ||
1212 | sub cmd_find_rev { | |
1213 | my $revision_or_hash = shift or die "SVN or git revision required ", | |
1214 | "as a command-line argument\n"; | |
1215 | my $result; | |
1216 | if ($revision_or_hash =~ /^r\d+$/) { | |
1217 | my $head = shift; | |
1218 | $head ||= 'HEAD'; | |
1219 | my @refs; | |
1220 | my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs); | |
1221 | unless ($gs) { | |
1222 | die "Unable to determine upstream SVN information from ", | |
1223 | "$head history\n"; | |
1224 | } | |
1225 | my $desired_revision = substr($revision_or_hash, 1); | |
1226 | if ($_before) { | |
1227 | $result = $gs->find_rev_before($desired_revision, 1); | |
1228 | } elsif ($_after) { | |
1229 | $result = $gs->find_rev_after($desired_revision, 1); | |
1230 | } else { | |
1231 | $result = $gs->rev_map_get($desired_revision, $uuid); | |
1232 | } | |
1233 | } else { | |
1234 | my (undef, $rev, undef) = cmt_metadata($revision_or_hash); | |
1235 | $result = $rev; | |
1236 | } | |
1237 | print "$result\n" if $result; | |
1238 | } | |
1239 | ||
1240 | sub auto_create_empty_directories { | |
1241 | my ($gs) = @_; | |
1242 | my $var = eval { command_oneline('config', '--get', '--bool', | |
1243 | "svn-remote.$gs->{repo_id}.automkdirs") }; | |
1244 | # By default, create empty directories by consulting the unhandled log, | |
1245 | # but allow setting it to 'false' to skip it. | |
1246 | return !($var && $var eq 'false'); | |
1247 | } | |
1248 | ||
1249 | sub cmd_rebase { | |
1250 | command_noisy(qw/update-index --refresh/); | |
1251 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1252 | unless ($gs) { | |
1253 | die "Unable to determine upstream SVN information from ", | |
1254 | "working tree history\n"; | |
1255 | } | |
1256 | if ($_dry_run) { | |
1257 | print "Remote Branch: " . $gs->refname . "\n"; | |
1258 | print "SVN URL: " . $url . "\n"; | |
1259 | return; | |
1260 | } | |
1261 | if (command(qw/diff-index HEAD --/)) { | |
1262 | print STDERR "Cannot rebase with uncommitted changes:\n"; | |
1263 | command_noisy('status'); | |
1264 | exit 1; | |
1265 | } | |
1266 | unless ($_local) { | |
1267 | # rebase will checkout for us, so no need to do it explicitly | |
1268 | $_no_checkout = 'true'; | |
1269 | $_fetch_all ? $gs->fetch_all : $gs->fetch; | |
1270 | } | |
1271 | command_noisy(rebase_cmd(), $gs->refname); | |
1272 | if (auto_create_empty_directories($gs)) { | |
1273 | $gs->mkemptydirs; | |
1274 | } | |
1275 | } | |
1276 | ||
1277 | sub cmd_show_ignore { | |
1278 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1279 | $gs ||= Git::SVN->new; | |
1280 | my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum); | |
1281 | $gs->prop_walk($gs->path, $r, sub { | |
1282 | my ($gs, $path, $props) = @_; | |
1283 | print STDOUT "\n# $path\n"; | |
1284 | my $s = $props->{'svn:ignore'} or return; | |
1285 | $s =~ s/[\r\n]+/\n/g; | |
1286 | $s =~ s/^\n+//; | |
1287 | chomp $s; | |
1288 | $s =~ s#^#$path#gm; | |
1289 | print STDOUT "$s\n"; | |
1290 | }); | |
1291 | } | |
1292 | ||
1293 | sub cmd_show_externals { | |
1294 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1295 | $gs ||= Git::SVN->new; | |
1296 | my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum); | |
1297 | $gs->prop_walk($gs->path, $r, sub { | |
1298 | my ($gs, $path, $props) = @_; | |
1299 | print STDOUT "\n# $path\n"; | |
1300 | my $s = $props->{'svn:externals'} or return; | |
1301 | $s =~ s/[\r\n]+/\n/g; | |
1302 | chomp $s; | |
1303 | $s =~ s#^#$path#gm; | |
1304 | print STDOUT "$s\n"; | |
1305 | }); | |
1306 | } | |
1307 | ||
1308 | sub cmd_create_ignore { | |
1309 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1310 | $gs ||= Git::SVN->new; | |
1311 | my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum); | |
1312 | $gs->prop_walk($gs->path, $r, sub { | |
1313 | my ($gs, $path, $props) = @_; | |
1314 | # $path is of the form /path/to/dir/ | |
1315 | $path = '.' . $path; | |
1316 | # SVN can have attributes on empty directories, | |
1317 | # which git won't track | |
1318 | mkpath([$path]) unless -d $path; | |
1319 | my $ignore = $path . '.gitignore'; | |
1320 | my $s = $props->{'svn:ignore'} or return; | |
1321 | open(GITIGNORE, '>', $ignore) | |
1322 | or fatal("Failed to open `$ignore' for writing: $!"); | |
1323 | $s =~ s/[\r\n]+/\n/g; | |
1324 | $s =~ s/^\n+//; | |
1325 | chomp $s; | |
1326 | # Prefix all patterns so that the ignore doesn't apply | |
1327 | # to sub-directories. | |
1328 | $s =~ s#^#/#gm; | |
1329 | print GITIGNORE "$s\n"; | |
1330 | close(GITIGNORE) | |
1331 | or fatal("Failed to close `$ignore': $!"); | |
1332 | command_noisy('add', '-f', $ignore); | |
1333 | }); | |
1334 | } | |
1335 | ||
1336 | sub cmd_mkdirs { | |
1337 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1338 | $gs ||= Git::SVN->new; | |
1339 | $gs->mkemptydirs($_revision); | |
1340 | } | |
1341 | ||
1342 | # get_svnprops(PATH) | |
1343 | # ------------------ | |
1344 | # Helper for cmd_propget and cmd_proplist below. | |
1345 | sub get_svnprops { | |
1346 | my $path = shift; | |
1347 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1348 | $gs ||= Git::SVN->new; | |
1349 | ||
1350 | # prefix THE PATH by the sub-directory from which the user | |
1351 | # invoked us. | |
1352 | $path = $cmd_dir_prefix . $path; | |
1353 | fatal("No such file or directory: $path") unless -e $path; | |
1354 | my $is_dir = -d $path ? 1 : 0; | |
1355 | $path = join_paths($gs->path, $path); | |
1356 | ||
1357 | # canonicalize the path (otherwise libsvn will abort or fail to | |
1358 | # find the file) | |
1359 | $path = canonicalize_path($path); | |
1360 | ||
1361 | my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum); | |
1362 | my $props; | |
1363 | if ($is_dir) { | |
1364 | (undef, undef, $props) = $gs->ra->get_dir($path, $r); | |
1365 | } | |
1366 | else { | |
1367 | (undef, $props) = $gs->ra->get_file($path, $r, undef); | |
1368 | } | |
1369 | return $props; | |
1370 | } | |
1371 | ||
1372 | # cmd_propget (PROP, PATH) | |
1373 | # ------------------------ | |
1374 | # Print the SVN property PROP for PATH. | |
1375 | sub cmd_propget { | |
1376 | my ($prop, $path) = @_; | |
1377 | $path = '.' if not defined $path; | |
1378 | usage(1) if not defined $prop; | |
1379 | my $props = get_svnprops($path); | |
1380 | if (not defined $props->{$prop}) { | |
1381 | fatal("`$path' does not have a `$prop' SVN property."); | |
1382 | } | |
1383 | print $props->{$prop} . "\n"; | |
1384 | } | |
1385 | ||
1386 | # cmd_propset (PROPNAME, PROPVAL, PATH) | |
1387 | # ------------------------ | |
1388 | # Adjust the SVN property PROPNAME to PROPVAL for PATH. | |
1389 | sub cmd_propset { | |
1390 | my ($propname, $propval, $path) = @_; | |
1391 | $path = '.' if not defined $path; | |
1392 | $path = $cmd_dir_prefix . $path; | |
1393 | usage(1) if not defined $propname; | |
1394 | usage(1) if not defined $propval; | |
1395 | my $file = basename($path); | |
1396 | my $dn = dirname($path); | |
1397 | my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path ); | |
1398 | my @new_props; | |
1399 | if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") { | |
1400 | push @new_props, "$propname=$propval"; | |
1401 | } else { | |
1402 | # TODO: handle combining properties better | |
1403 | my @props = split(/;/, $cur_props); | |
1404 | my $replaced_prop; | |
1405 | foreach my $prop (@props) { | |
1406 | # Parse 'name=value' syntax and set the property. | |
1407 | if ($prop =~ /([^=]+)=(.*)/) { | |
1408 | my ($n,$v) = ($1,$2); | |
1409 | if ($n eq $propname) { | |
1410 | $v = $propval; | |
1411 | $replaced_prop = 1; | |
1412 | } | |
1413 | push @new_props, "$n=$v"; | |
1414 | } | |
1415 | } | |
1416 | if (!$replaced_prop) { | |
1417 | push @new_props, "$propname=$propval"; | |
1418 | } | |
1419 | } | |
1420 | my $attrfile = "$dn/.gitattributes"; | |
1421 | open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n"; | |
1422 | # TODO: don't simply append here if $file already has svn-properties | |
1423 | my $new_props = join(';', @new_props); | |
1424 | print $attrfh "$file svn-properties=$new_props\n" or | |
1425 | die "write to $attrfile: $!\n"; | |
1426 | close $attrfh or die "close $attrfile: $!\n"; | |
1427 | } | |
1428 | ||
1429 | # cmd_proplist (PATH) | |
1430 | # ------------------- | |
1431 | # Print the list of SVN properties for PATH. | |
1432 | sub cmd_proplist { | |
1433 | my $path = shift; | |
1434 | $path = '.' if not defined $path; | |
1435 | my $props = get_svnprops($path); | |
1436 | print "Properties on '$path':\n"; | |
1437 | foreach (sort keys %{$props}) { | |
1438 | print " $_\n"; | |
1439 | } | |
1440 | } | |
1441 | ||
1442 | sub cmd_multi_init { | |
1443 | my $url = shift; | |
1444 | unless (defined $_trunk || @_branches || @_tags) { | |
1445 | usage(1); | |
1446 | } | |
1447 | ||
1448 | $_prefix = 'origin/' unless defined $_prefix; | |
1449 | if (defined $url) { | |
1450 | $url = canonicalize_url($url); | |
1451 | init_subdir(@_); | |
1452 | } | |
1453 | do_git_init_db(); | |
1454 | if (defined $_trunk) { | |
1455 | $_trunk =~ s#^/+##; | |
1456 | my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk'; | |
1457 | # try both old-style and new-style lookups: | |
1458 | my $gs_trunk = eval { Git::SVN->new($trunk_ref) }; | |
1459 | unless ($gs_trunk) { | |
1460 | my ($trunk_url, $trunk_path) = | |
1461 | complete_svn_url($url, $_trunk); | |
1462 | $gs_trunk = Git::SVN->init($trunk_url, $trunk_path, | |
1463 | undef, $trunk_ref); | |
1464 | } | |
1465 | } | |
1466 | return unless @_branches || @_tags; | |
1467 | my $ra = $url ? Git::SVN::Ra->new($url) : undef; | |
1468 | foreach my $path (@_branches) { | |
1469 | complete_url_ls_init($ra, $path, '--branches/-b', $_prefix); | |
1470 | } | |
1471 | foreach my $path (@_tags) { | |
1472 | complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/'); | |
1473 | } | |
1474 | } | |
1475 | ||
1476 | sub cmd_multi_fetch { | |
1477 | $Git::SVN::no_reuse_existing = undef; | |
1478 | my $remotes = Git::SVN::read_all_remotes(); | |
1479 | foreach my $repo_id (sort keys %$remotes) { | |
1480 | if ($remotes->{$repo_id}->{url}) { | |
1481 | Git::SVN::fetch_all($repo_id, $remotes); | |
1482 | } | |
1483 | } | |
1484 | } | |
1485 | ||
1486 | # this command is special because it requires no metadata | |
1487 | sub cmd_commit_diff { | |
1488 | my ($ta, $tb, $url) = @_; | |
1489 | my $usage = "usage: $0 commit-diff -r<revision> ". | |
1490 | "<tree-ish> <tree-ish> [<URL>]"; | |
1491 | fatal($usage) if (!defined $ta || !defined $tb); | |
1492 | my $svn_path = ''; | |
1493 | if (!defined $url) { | |
1494 | my $gs = eval { Git::SVN->new }; | |
1495 | if (!$gs) { | |
1496 | fatal("Needed URL or usable git-svn --id in ", | |
1497 | "the command-line\n", $usage); | |
1498 | } | |
1499 | $url = $gs->url; | |
1500 | $svn_path = $gs->path; | |
1501 | } | |
1502 | unless (defined $_revision) { | |
1503 | fatal("-r|--revision is a required argument\n", $usage); | |
1504 | } | |
1505 | if (defined $_message && defined $_file) { | |
1506 | fatal("Both --message/-m and --file/-F specified ", | |
1507 | "for the commit message.\n", | |
1508 | "I have no idea what you mean"); | |
1509 | } | |
1510 | if (defined $_file) { | |
1511 | $_message = file_to_s($_file); | |
1512 | } else { | |
1513 | $_message ||= get_commit_entry($tb)->{log}; | |
1514 | } | |
1515 | my $ra ||= Git::SVN::Ra->new($url); | |
1516 | my $r = $_revision; | |
1517 | if ($r eq 'HEAD') { | |
1518 | $r = $ra->get_latest_revnum; | |
1519 | } elsif ($r !~ /^\d+$/) { | |
1520 | die "revision argument: $r not understood by git-svn\n"; | |
1521 | } | |
1522 | my %ed_opts = ( r => $r, | |
1523 | log => $_message, | |
1524 | ra => $ra, | |
1525 | tree_a => $ta, | |
1526 | tree_b => $tb, | |
1527 | editor_cb => sub { print "Committed r$_[0]\n" }, | |
1528 | svn_path => $svn_path ); | |
1529 | if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) { | |
1530 | print "No changes\n$ta == $tb\n"; | |
1531 | } | |
1532 | } | |
1533 | ||
1534 | sub cmd_info { | |
1535 | my $path_arg = defined($_[0]) ? $_[0] : '.'; | |
1536 | my $path = $path_arg; | |
1537 | if (File::Spec->file_name_is_absolute($path)) { | |
1538 | $path = canonicalize_path($path); | |
1539 | ||
1540 | my $toplevel = eval { | |
1541 | my @cmd = qw/rev-parse --show-toplevel/; | |
1542 | command_oneline(\@cmd, STDERR => 0); | |
1543 | }; | |
1544 | ||
1545 | # remove $toplevel from the absolute path: | |
1546 | my ($vol, $dirs, $file) = File::Spec->splitpath($path); | |
1547 | my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel); | |
1548 | my @dirs = File::Spec->splitdir($dirs); | |
1549 | my @tdirs = File::Spec->splitdir($tdirs); | |
1550 | pop @dirs if $dirs[-1] eq ''; | |
1551 | pop @tdirs if $tdirs[-1] eq ''; | |
1552 | push @dirs, $file; | |
1553 | push @tdirs, $tfile; | |
1554 | while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) { | |
1555 | shift @dirs; | |
1556 | shift @tdirs; | |
1557 | } | |
1558 | $dirs = File::Spec->catdir(@dirs); | |
1559 | $path = File::Spec->catpath($vol, $dirs); | |
1560 | ||
1561 | $path = canonicalize_path($path); | |
1562 | } else { | |
1563 | $path = canonicalize_path($cmd_dir_prefix . $path); | |
1564 | } | |
1565 | if (exists $_[1]) { | |
1566 | die "Too many arguments specified\n"; | |
1567 | } | |
1568 | ||
1569 | my ($file_type, $diff_status) = find_file_type_and_diff_status($path); | |
1570 | ||
1571 | if (!$file_type && !$diff_status) { | |
1572 | print STDERR "svn: '$path' is not under version control\n"; | |
1573 | exit 1; | |
1574 | } | |
1575 | ||
1576 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1577 | unless ($gs) { | |
1578 | die "Unable to determine upstream SVN information from ", | |
1579 | "working tree history\n"; | |
1580 | } | |
1581 | ||
1582 | # canonicalize_path() will return "" to make libsvn 1.5.x happy, | |
1583 | $path = "." if $path eq ""; | |
1584 | ||
1585 | my $full_url = canonicalize_url( add_path_to_url( $url, $path ) ); | |
1586 | ||
1587 | if ($_url) { | |
1588 | print "$full_url\n"; | |
1589 | return; | |
1590 | } | |
1591 | ||
1592 | my $result = "Path: $path_arg\n"; | |
1593 | $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir"; | |
1594 | $result .= "URL: $full_url\n"; | |
1595 | ||
1596 | eval { | |
1597 | my $repos_root = $gs->repos_root; | |
1598 | Git::SVN::remove_username($repos_root); | |
1599 | $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n"; | |
1600 | }; | |
1601 | if ($@) { | |
1602 | $result .= "Repository Root: (offline)\n"; | |
1603 | } | |
1604 | ::_req_svn(); | |
1605 | $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" && | |
1606 | (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir"); | |
1607 | $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n"; | |
1608 | ||
1609 | $result .= "Node Kind: " . | |
1610 | ($file_type eq "dir" ? "directory" : "file") . "\n"; | |
1611 | ||
1612 | my $schedule = $diff_status eq "A" | |
1613 | ? "add" | |
1614 | : ($diff_status eq "D" ? "delete" : "normal"); | |
1615 | $result .= "Schedule: $schedule\n"; | |
1616 | ||
1617 | if ($diff_status eq "A") { | |
1618 | print $result, "\n"; | |
1619 | return; | |
1620 | } | |
1621 | ||
1622 | my ($lc_author, $lc_rev, $lc_date_utc); | |
1623 | my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path); | |
1624 | my $log = command_output_pipe(@args); | |
1625 | my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/; | |
1626 | while (<$log>) { | |
1627 | if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) { | |
1628 | $lc_author = $1; | |
1629 | $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3); | |
1630 | } elsif (/^${esc_color} (git-svn-id:.+)$/o) { | |
1631 | (undef, $lc_rev, undef) = ::extract_metadata($1); | |
1632 | } | |
1633 | } | |
1634 | close $log; | |
1635 | ||
1636 | Git::SVN::Log::set_local_timezone(); | |
1637 | ||
1638 | $result .= "Last Changed Author: $lc_author\n"; | |
1639 | $result .= "Last Changed Rev: $lc_rev\n"; | |
1640 | $result .= "Last Changed Date: " . | |
1641 | Git::SVN::Log::format_svn_date($lc_date_utc) . "\n"; | |
1642 | ||
1643 | if ($file_type ne "dir") { | |
1644 | my $text_last_updated_date = | |
1645 | ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]); | |
1646 | $result .= | |
1647 | "Text Last Updated: " . | |
1648 | Git::SVN::Log::format_svn_date($text_last_updated_date) . | |
1649 | "\n"; | |
1650 | my $checksum; | |
1651 | if ($diff_status eq "D") { | |
1652 | my ($fh, $ctx) = | |
1653 | command_output_pipe(qw(cat-file blob), "HEAD:$path"); | |
1654 | if ($file_type eq "link") { | |
1655 | my $file_name = <$fh>; | |
1656 | $checksum = md5sum("link $file_name"); | |
1657 | } else { | |
1658 | $checksum = md5sum($fh); | |
1659 | } | |
1660 | command_close_pipe($fh, $ctx); | |
1661 | } elsif ($file_type eq "link") { | |
1662 | my $file_name = | |
1663 | command(qw(cat-file blob), "HEAD:$path"); | |
1664 | $checksum = | |
1665 | md5sum("link " . $file_name); | |
1666 | } else { | |
1667 | open FILE, "<", $path or die $!; | |
1668 | $checksum = md5sum(\*FILE); | |
1669 | close FILE or die $!; | |
1670 | } | |
1671 | $result .= "Checksum: " . $checksum . "\n"; | |
1672 | } | |
1673 | ||
1674 | print $result, "\n"; | |
1675 | } | |
1676 | ||
1677 | sub cmd_reset { | |
1678 | my $target = shift || $_revision or die "SVN revision required\n"; | |
1679 | $target = $1 if $target =~ /^r(\d+)$/; | |
1680 | $target =~ /^\d+$/ or die "Numeric SVN revision expected\n"; | |
1681 | my ($url, $rev, $uuid, $gs) = working_head_info('HEAD'); | |
1682 | unless ($gs) { | |
1683 | die "Unable to determine upstream SVN information from ". | |
1684 | "history\n"; | |
1685 | } | |
1686 | my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent); | |
1687 | die "Cannot find SVN revision $target\n" unless defined($c); | |
1688 | $gs->rev_map_set($r, $c, 'reset', $uuid); | |
1689 | print "r$r = $c ($gs->{ref_id})\n"; | |
1690 | } | |
1691 | ||
1692 | sub cmd_gc { | |
1693 | require File::Find; | |
1694 | if (!can_compress()) { | |
1695 | warn "Compress::Zlib could not be found; unhandled.log " . | |
1696 | "files will not be compressed.\n"; | |
1697 | } | |
1698 | File::Find::find({ wanted => \&gc_directory, no_chdir => 1}, | |
1699 | "$ENV{GIT_DIR}/svn"); | |
1700 | } | |
1701 | ||
1702 | ########################### utility functions ######################### | |
1703 | ||
1704 | sub rebase_cmd { | |
1705 | my @cmd = qw/rebase/; | |
1706 | push @cmd, '-v' if $_verbose; | |
1707 | push @cmd, qw/--merge/ if $_merge; | |
1708 | push @cmd, "--strategy=$_strategy" if $_strategy; | |
1709 | push @cmd, "--preserve-merges" if $_preserve_merges; | |
1710 | @cmd; | |
1711 | } | |
1712 | ||
1713 | sub post_fetch_checkout { | |
1714 | return if $_no_checkout; | |
1715 | return if verify_ref('HEAD^0'); | |
1716 | my $gs = $Git::SVN::_head or return; | |
1717 | ||
1718 | # look for "trunk" ref if it exists | |
1719 | my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}}; | |
1720 | my $fetch = $remote->{fetch}; | |
1721 | if ($fetch) { | |
1722 | foreach my $p (keys %$fetch) { | |
1723 | basename($fetch->{$p}) eq 'trunk' or next; | |
1724 | $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p); | |
1725 | last; | |
1726 | } | |
1727 | } | |
1728 | ||
1729 | command_noisy(qw(update-ref HEAD), $gs->refname); | |
1730 | return unless verify_ref('HEAD^0'); | |
1731 | ||
1732 | return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#; | |
1733 | my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index"; | |
1734 | return if -f $index; | |
1735 | ||
1736 | return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false'; | |
1737 | return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true'; | |
1738 | command_noisy(qw/read-tree -m -u -v HEAD HEAD/); | |
1739 | print STDERR "Checked out HEAD:\n ", | |
1740 | $gs->full_url, " r", $gs->last_rev, "\n"; | |
1741 | if (auto_create_empty_directories($gs)) { | |
1742 | $gs->mkemptydirs($gs->last_rev); | |
1743 | } | |
1744 | } | |
1745 | ||
1746 | sub complete_svn_url { | |
1747 | my ($url, $path) = @_; | |
1748 | $path = canonicalize_path($path); | |
1749 | ||
1750 | # If the path is not a URL... | |
1751 | if ($path !~ m#^[a-z\+]+://#) { | |
1752 | if (!defined $url || $url !~ m#^[a-z\+]+://#) { | |
1753 | fatal("E: '$path' is not a complete URL ", | |
1754 | "and a separate URL is not specified"); | |
1755 | } | |
1756 | return ($url, $path); | |
1757 | } | |
1758 | return ($path, ''); | |
1759 | } | |
1760 | ||
1761 | sub complete_url_ls_init { | |
1762 | my ($ra, $repo_path, $switch, $pfx) = @_; | |
1763 | unless ($repo_path) { | |
1764 | print STDERR "W: $switch not specified\n"; | |
1765 | return; | |
1766 | } | |
1767 | $repo_path = canonicalize_path($repo_path); | |
1768 | if ($repo_path =~ m#^[a-z\+]+://#) { | |
1769 | $ra = Git::SVN::Ra->new($repo_path); | |
1770 | $repo_path = ''; | |
1771 | } else { | |
1772 | $repo_path =~ s#^/+##; | |
1773 | unless ($ra) { | |
1774 | fatal("E: '$repo_path' is not a complete URL ", | |
1775 | "and a separate URL is not specified"); | |
1776 | } | |
1777 | } | |
1778 | my $url = $ra->url; | |
1779 | my $gs = Git::SVN->init($url, undef, undef, undef, 1); | |
1780 | my $k = "svn-remote.$gs->{repo_id}.url"; | |
1781 | my $orig_url = eval { command_oneline(qw/config --get/, $k) }; | |
1782 | if ($orig_url && ($orig_url ne $gs->url)) { | |
1783 | die "$k already set: $orig_url\n", | |
1784 | "wanted to set to: $gs->url\n"; | |
1785 | } | |
1786 | command_oneline('config', $k, $gs->url) unless $orig_url; | |
1787 | ||
1788 | my $remote_path = join_paths( $gs->path, $repo_path ); | |
1789 | $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg; | |
1790 | $remote_path =~ s#^/##g; | |
1791 | $remote_path .= "/*" if $remote_path !~ /\*/; | |
1792 | my ($n) = ($switch =~ /^--(\w+)/); | |
1793 | if (length $pfx && $pfx !~ m#/$#) { | |
1794 | die "--prefix='$pfx' must have a trailing slash '/'\n"; | |
1795 | } | |
1796 | command_noisy('config', | |
1797 | '--add', | |
1798 | "svn-remote.$gs->{repo_id}.$n", | |
1799 | "$remote_path:refs/remotes/$pfx*" . | |
1800 | ('/*' x (($remote_path =~ tr/*/*/) - 1)) ); | |
1801 | } | |
1802 | ||
1803 | sub verify_ref { | |
1804 | my ($ref) = @_; | |
1805 | eval { command_oneline([ 'rev-parse', '--verify', $ref ], | |
1806 | { STDERR => 0 }); }; | |
1807 | } | |
1808 | ||
1809 | sub get_tree_from_treeish { | |
1810 | my ($treeish) = @_; | |
1811 | # $treeish can be a symbolic ref, too: | |
1812 | my $type = command_oneline(qw/cat-file -t/, $treeish); | |
1813 | my $expected; | |
1814 | while ($type eq 'tag') { | |
1815 | ($treeish, $type) = command(qw/cat-file tag/, $treeish); | |
1816 | } | |
1817 | if ($type eq 'commit') { | |
1818 | $expected = (grep /^tree /, command(qw/cat-file commit/, | |
1819 | $treeish))[0]; | |
1820 | ($expected) = ($expected =~ /^tree ($sha1)$/o); | |
1821 | die "Unable to get tree from $treeish\n" unless $expected; | |
1822 | } elsif ($type eq 'tree') { | |
1823 | $expected = $treeish; | |
1824 | } else { | |
1825 | die "$treeish is a $type, expected tree, tag or commit\n"; | |
1826 | } | |
1827 | return $expected; | |
1828 | } | |
1829 | ||
1830 | sub get_commit_entry { | |
1831 | my ($treeish) = shift; | |
1832 | my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) ); | |
1833 | my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG"; | |
1834 | my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG"; | |
1835 | open my $log_fh, '>', $commit_editmsg or croak $!; | |
1836 | ||
1837 | my $type = command_oneline(qw/cat-file -t/, $treeish); | |
1838 | if ($type eq 'commit' || $type eq 'tag') { | |
1839 | my ($msg_fh, $ctx) = command_output_pipe('cat-file', | |
1840 | $type, $treeish); | |
1841 | my $in_msg = 0; | |
1842 | my $author; | |
1843 | my $saw_from = 0; | |
1844 | my $msgbuf = ""; | |
1845 | while (<$msg_fh>) { | |
1846 | if (!$in_msg) { | |
1847 | $in_msg = 1 if (/^$/); | |
1848 | $author = $1 if (/^author (.*>)/); | |
1849 | } elsif (/^git-svn-id: /) { | |
1850 | # skip this for now, we regenerate the | |
1851 | # correct one on re-fetch anyways | |
1852 | # TODO: set *:merge properties or like... | |
1853 | } else { | |
1854 | if (/^From:/ || /^Signed-off-by:/) { | |
1855 | $saw_from = 1; | |
1856 | } | |
1857 | $msgbuf .= $_; | |
1858 | } | |
1859 | } | |
1860 | $msgbuf =~ s/\s+$//s; | |
1861 | if ($Git::SVN::_add_author_from && defined($author) | |
1862 | && !$saw_from) { | |
1863 | $msgbuf .= "\n\nFrom: $author"; | |
1864 | } | |
1865 | print $log_fh $msgbuf or croak $!; | |
1866 | command_close_pipe($msg_fh, $ctx); | |
1867 | } | |
1868 | close $log_fh or croak $!; | |
1869 | ||
1870 | if ($_edit || ($type eq 'tree')) { | |
1871 | chomp(my $editor = command_oneline(qw(var GIT_EDITOR))); | |
1872 | system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg); | |
1873 | } | |
1874 | rename $commit_editmsg, $commit_msg or croak $!; | |
1875 | { | |
1876 | require Encode; | |
1877 | # SVN requires messages to be UTF-8 when entering the repo | |
1878 | local $/; | |
1879 | open $log_fh, '<', $commit_msg or croak $!; | |
1880 | binmode $log_fh; | |
1881 | chomp($log_entry{log} = <$log_fh>); | |
1882 | ||
1883 | my $enc = Git::config('i18n.commitencoding') || 'UTF-8'; | |
1884 | my $msg = $log_entry{log}; | |
1885 | ||
1886 | eval { $msg = Encode::decode($enc, $msg, 1) }; | |
1887 | if ($@) { | |
1888 | die "Could not decode as $enc:\n", $msg, | |
1889 | "\nPerhaps you need to set i18n.commitencoding\n"; | |
1890 | } | |
1891 | ||
1892 | eval { $msg = Encode::encode('UTF-8', $msg, 1) }; | |
1893 | die "Could not encode as UTF-8:\n$msg\n" if $@; | |
1894 | ||
1895 | $log_entry{log} = $msg; | |
1896 | ||
1897 | close $log_fh or croak $!; | |
1898 | } | |
1899 | unlink $commit_msg; | |
1900 | \%log_entry; | |
1901 | } | |
1902 | ||
1903 | sub s_to_file { | |
1904 | my ($str, $file, $mode) = @_; | |
1905 | open my $fd,'>',$file or croak $!; | |
1906 | print $fd $str,"\n" or croak $!; | |
1907 | close $fd or croak $!; | |
1908 | chmod ($mode &~ umask, $file) if (defined $mode); | |
1909 | } | |
1910 | ||
1911 | sub file_to_s { | |
1912 | my $file = shift; | |
1913 | open my $fd,'<',$file or croak "$!: file: $file\n"; | |
1914 | local $/; | |
1915 | my $ret = <$fd>; | |
1916 | close $fd or croak $!; | |
1917 | $ret =~ s/\s*$//s; | |
1918 | return $ret; | |
1919 | } | |
1920 | ||
1921 | # '<svn username> = real-name <email address>' mapping based on git-svnimport: | |
1922 | sub load_authors { | |
1923 | open my $authors, '<', $_authors or die "Can't open $_authors $!\n"; | |
1924 | my $log = $cmd eq 'log'; | |
1925 | while (<$authors>) { | |
1926 | chomp; | |
1927 | next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/; | |
1928 | my ($user, $name, $email) = ($1, $2, $3); | |
1929 | if ($log) { | |
1930 | $Git::SVN::Log::rusers{"$name <$email>"} = $user; | |
1931 | } else { | |
1932 | $users{$user} = [$name, $email]; | |
1933 | } | |
1934 | } | |
1935 | close $authors or croak $!; | |
1936 | } | |
1937 | ||
1938 | # convert GetOpt::Long specs for use by git-config | |
1939 | sub read_git_config { | |
1940 | my $opts = shift; | |
1941 | my @config_only; | |
1942 | foreach my $o (keys %$opts) { | |
1943 | # if we have mixedCase and a long option-only, then | |
1944 | # it's a config-only variable that we don't need for | |
1945 | # the command-line. | |
1946 | push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i); | |
1947 | my $v = $opts->{$o}; | |
1948 | my ($key) = ($o =~ /^([a-zA-Z\-]+)/); | |
1949 | $key =~ s/-//g; | |
1950 | my $arg = 'git config'; | |
1951 | $arg .= ' --int' if ($o =~ /[:=]i$/); | |
1952 | $arg .= ' --bool' if ($o !~ /[:=][sfi]$/); | |
1953 | if (ref $v eq 'ARRAY') { | |
1954 | chomp(my @tmp = `$arg --get-all svn.$key`); | |
1955 | @$v = @tmp if @tmp; | |
1956 | } else { | |
1957 | chomp(my $tmp = `$arg --get svn.$key`); | |
1958 | if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) { | |
1959 | $$v = $tmp; | |
1960 | } | |
1961 | } | |
1962 | } | |
1963 | delete @$opts{@config_only} if @config_only; | |
1964 | } | |
1965 | ||
1966 | sub extract_metadata { | |
1967 | my $id = shift or return (undef, undef, undef); | |
1968 | my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+) | |
1969 | \s([a-f\d\-]+)$/ix); | |
1970 | if (!defined $rev || !$uuid || !$url) { | |
1971 | # some of the original repositories I made had | |
1972 | # identifiers like this: | |
1973 | ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i); | |
1974 | } | |
1975 | return ($url, $rev, $uuid); | |
1976 | } | |
1977 | ||
1978 | sub cmt_metadata { | |
1979 | return extract_metadata((grep(/^git-svn-id: /, | |
1980 | command(qw/cat-file commit/, shift)))[-1]); | |
1981 | } | |
1982 | ||
1983 | sub cmt_sha2rev_batch { | |
1984 | my %s2r; | |
1985 | my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/); | |
1986 | my $list = shift; | |
1987 | ||
1988 | foreach my $sha (@{$list}) { | |
1989 | my $first = 1; | |
1990 | my $size = 0; | |
1991 | print $out $sha, "\n"; | |
1992 | ||
1993 | while (my $line = <$in>) { | |
1994 | if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) { | |
1995 | last; | |
1996 | } elsif ($first && | |
1997 | $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) { | |
1998 | $first = 0; | |
1999 | $size = $1; | |
2000 | next; | |
2001 | } elsif ($line =~ /^(git-svn-id: )/) { | |
2002 | my (undef, $rev, undef) = | |
2003 | extract_metadata($line); | |
2004 | $s2r{$sha} = $rev; | |
2005 | } | |
2006 | ||
2007 | $size -= length($line); | |
2008 | last if ($size == 0); | |
2009 | } | |
2010 | } | |
2011 | ||
2012 | command_close_bidi_pipe($pid, $in, $out, $ctx); | |
2013 | ||
2014 | return \%s2r; | |
2015 | } | |
2016 | ||
2017 | sub working_head_info { | |
2018 | my ($head, $refs) = @_; | |
2019 | my @args = qw/rev-list --first-parent --pretty=medium/; | |
2020 | my ($fh, $ctx) = command_output_pipe(@args, $head, "--"); | |
2021 | my $hash; | |
2022 | my %max; | |
2023 | while (<$fh>) { | |
2024 | if ( m{^commit ($::sha1)$} ) { | |
2025 | unshift @$refs, $hash if $hash and $refs; | |
2026 | $hash = $1; | |
2027 | next; | |
2028 | } | |
2029 | next unless s{^\s*(git-svn-id:)}{$1}; | |
2030 | my ($url, $rev, $uuid) = extract_metadata($_); | |
2031 | if (defined $url && defined $rev) { | |
2032 | next if $max{$url} and $max{$url} < $rev; | |
2033 | if (my $gs = Git::SVN->find_by_url($url)) { | |
2034 | my $c = $gs->rev_map_get($rev, $uuid); | |
2035 | if ($c && $c eq $hash) { | |
2036 | close $fh; # break the pipe | |
2037 | return ($url, $rev, $uuid, $gs); | |
2038 | } else { | |
2039 | $max{$url} ||= $gs->rev_map_max; | |
2040 | } | |
2041 | } | |
2042 | } | |
2043 | } | |
2044 | command_close_pipe($fh, $ctx); | |
2045 | (undef, undef, undef, undef); | |
2046 | } | |
2047 | ||
2048 | sub read_commit_parents { | |
2049 | my ($parents, $c) = @_; | |
2050 | chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c)); | |
2051 | $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n"; | |
2052 | @{$parents->{$c}} = split(/ /, $p); | |
2053 | } | |
2054 | ||
2055 | sub linearize_history { | |
2056 | my ($gs, $refs) = @_; | |
2057 | my %parents; | |
2058 | foreach my $c (@$refs) { | |
2059 | read_commit_parents(\%parents, $c); | |
2060 | } | |
2061 | ||
2062 | my @linear_refs; | |
2063 | my %skip = (); | |
2064 | my $last_svn_commit = $gs->last_commit; | |
2065 | foreach my $c (reverse @$refs) { | |
2066 | next if $c eq $last_svn_commit; | |
2067 | last if $skip{$c}; | |
2068 | ||
2069 | unshift @linear_refs, $c; | |
2070 | $skip{$c} = 1; | |
2071 | ||
2072 | # we only want the first parent to diff against for linear | |
2073 | # history, we save the rest to inject when we finalize the | |
2074 | # svn commit | |
2075 | my $fp_a = verify_ref("$c~1"); | |
2076 | my $fp_b = shift @{$parents{$c}} if $parents{$c}; | |
2077 | if (!$fp_a || !$fp_b) { | |
2078 | die "Commit $c\n", | |
2079 | "has no parent commit, and therefore ", | |
2080 | "nothing to diff against.\n", | |
2081 | "You should be working from a repository ", | |
2082 | "originally created by git-svn\n"; | |
2083 | } | |
2084 | if ($fp_a ne $fp_b) { | |
2085 | die "$c~1 = $fp_a, however parsing commit $c ", | |
2086 | "revealed that:\n$c~1 = $fp_b\nBUG!\n"; | |
2087 | } | |
2088 | ||
2089 | foreach my $p (@{$parents{$c}}) { | |
2090 | $skip{$p} = 1; | |
2091 | } | |
2092 | } | |
2093 | (\@linear_refs, \%parents); | |
2094 | } | |
2095 | ||
2096 | sub find_file_type_and_diff_status { | |
2097 | my ($path) = @_; | |
2098 | return ('dir', '') if $path eq ''; | |
2099 | ||
2100 | my $diff_output = | |
2101 | command_oneline(qw(diff --cached --name-status --), $path) || ""; | |
2102 | my $diff_status = (split(' ', $diff_output))[0] || ""; | |
2103 | ||
2104 | my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || ""; | |
2105 | ||
2106 | return (undef, undef) if !$diff_status && !$ls_tree; | |
2107 | ||
2108 | if ($diff_status eq "A") { | |
2109 | return ("link", $diff_status) if -l $path; | |
2110 | return ("dir", $diff_status) if -d $path; | |
2111 | return ("file", $diff_status); | |
2112 | } | |
2113 | ||
2114 | my $mode = (split(' ', $ls_tree))[0] || ""; | |
2115 | ||
2116 | return ("link", $diff_status) if $mode eq "120000"; | |
2117 | return ("dir", $diff_status) if $mode eq "040000"; | |
2118 | return ("file", $diff_status); | |
2119 | } | |
2120 | ||
2121 | sub md5sum { | |
2122 | my $arg = shift; | |
2123 | my $ref = ref $arg; | |
2124 | require Digest::MD5; | |
2125 | my $md5 = Digest::MD5->new(); | |
2126 | if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') { | |
2127 | $md5->addfile($arg) or croak $!; | |
2128 | } elsif ($ref eq 'SCALAR') { | |
2129 | $md5->add($$arg) or croak $!; | |
2130 | } elsif (!$ref) { | |
2131 | $md5->add($arg) or croak $!; | |
2132 | } else { | |
2133 | fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'"; | |
2134 | } | |
2135 | return $md5->hexdigest(); | |
2136 | } | |
2137 | ||
2138 | sub gc_directory { | |
2139 | if (can_compress() && -f $_ && basename($_) eq "unhandled.log") { | |
2140 | my $out_filename = $_ . ".gz"; | |
2141 | open my $in_fh, "<", $_ or die "Unable to open $_: $!\n"; | |
2142 | binmode $in_fh; | |
2143 | my $gz = Compress::Zlib::gzopen($out_filename, "ab") or | |
2144 | die "Unable to open $out_filename: $!\n"; | |
2145 | ||
2146 | my $res; | |
2147 | while ($res = sysread($in_fh, my $str, 1024)) { | |
2148 | $gz->gzwrite($str) or | |
2149 | die "Unable to write: ".$gz->gzerror()."!\n"; | |
2150 | } | |
2151 | no warnings 'once'; # $File::Find::name would warn | |
2152 | unlink $_ or die "unlink $File::Find::name: $!\n"; | |
2153 | } elsif (-f $_ && basename($_) eq "index") { | |
2154 | unlink $_ or die "unlink $_: $!\n"; | |
2155 | } | |
2156 | } | |
2157 | ||
2158 | __END__ | |
2159 | ||
2160 | Data structures: | |
2161 | ||
2162 | ||
2163 | $remotes = { # returned by read_all_remotes() | |
2164 | 'svn' => { | |
2165 | # svn-remote.svn.url=https://svn.musicpd.org | |
2166 | url => 'https://svn.musicpd.org', | |
2167 | # svn-remote.svn.fetch=mpd/trunk:trunk | |
2168 | fetch => { | |
2169 | 'mpd/trunk' => 'trunk', | |
2170 | }, | |
2171 | # svn-remote.svn.tags=mpd/tags/*:tags/* | |
2172 | tags => { | |
2173 | path => { | |
2174 | left => 'mpd/tags', | |
2175 | right => '', | |
2176 | regex => qr!mpd/tags/([^/]+)$!, | |
2177 | glob => 'tags/*', | |
2178 | }, | |
2179 | ref => { | |
2180 | left => 'tags', | |
2181 | right => '', | |
2182 | regex => qr!tags/([^/]+)$!, | |
2183 | glob => 'tags/*', | |
2184 | }, | |
2185 | } | |
2186 | } | |
2187 | }; | |
2188 | ||
2189 | $log_entry hashref as returned by libsvn_log_entry() | |
2190 | { | |
2191 | log => 'whitespace-formatted log entry | |
2192 | ', # trailing newline is preserved | |
2193 | revision => '8', # integer | |
2194 | date => '2004-02-24T17:01:44.108345Z', # commit date | |
2195 | author => 'committer name' | |
2196 | }; | |
2197 | ||
2198 | ||
2199 | # this is generated by generate_diff(); | |
2200 | @mods = array of diff-index line hashes, each element represents one line | |
2201 | of diff-index output | |
2202 | ||
2203 | diff-index line ($m hash) | |
2204 | { | |
2205 | mode_a => first column of diff-index output, no leading ':', | |
2206 | mode_b => second column of diff-index output, | |
2207 | sha1_b => sha1sum of the final blob, | |
2208 | chg => change type [MCRADT], | |
2209 | file_a => original file name of a file (iff chg is 'C' or 'R') | |
2210 | file_b => new/current file name of a file (any chg) | |
2211 | } | |
2212 | ; | |
2213 | ||
2214 | # retval of read_url_paths{,_all}(); | |
2215 | $l_map = { | |
2216 | # repository root url | |
2217 | 'https://svn.musicpd.org' => { | |
2218 | # repository path # GIT_SVN_ID | |
2219 | 'mpd/trunk' => 'trunk', | |
2220 | 'mpd/tags/0.11.5' => 'tags/0.11.5', | |
2221 | }, | |
2222 | } | |
2223 | ||
2224 | Notes: | |
2225 | I don't trust the each() function on unless I created %hash myself | |
2226 | because the internal iterator may not have started at base. |