CMakeLists.txt

   1 #
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.12 FATAL_ERROR)
   3 if(POLICY CMP0074)
   4   cmake_policy(SET CMP0074 NEW) #3.12.0 `find_package()`` uses ``<PackageName>_ROOT`` variables.
   5 endif()
   6 #
   7 PROJECT(libarchive C)
   8 #
   9 SET(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/build/cmake")
  10 if(NOT CMAKE_RUNTIME_OUTPUT_DIRECTORY)
  11   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${libarchive_BINARY_DIR}/bin)
  12 endif()
  13 #
  14 # Set the Build type for make based generators.
  15 # You can choose following types:
  16 #   Debug          : Debug build
  17 #   Release        : Release build
  18 #   RelWithDebInfo : Release build with Debug Info
  19 #   MinSizeRel     : Release Min Size build
  20 IF(NOT CMAKE_BUILD_TYPE)
  21   SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build Type" FORCE)
  22 ENDIF(NOT CMAKE_BUILD_TYPE)
  23 # Set a value type to properly display CMAKE_BUILD_TYPE on GUI if the
  24 # value type is "UNINITIALIZED".
  25 GET_PROPERTY(cached_type CACHE CMAKE_BUILD_TYPE PROPERTY TYPE)
  26 IF("${cached_type}" STREQUAL "UNINITIALIZED")
  27   SET(CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING "Build Type" FORCE)
  28 ENDIF("${cached_type}" STREQUAL "UNINITIALIZED")
  29 # Check the Build Type.
  30 IF(NOT "${CMAKE_BUILD_TYPE}"
  31        MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)\$")
  32   MESSAGE(FATAL_ERROR
  33           "Unknown keyword for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}\n"
  34           "Acceptable keywords: Debug,Release,RelWithDebInfo,MinSizeRel")
  35 ENDIF(NOT "${CMAKE_BUILD_TYPE}"
  36           MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)\$")
  37
  38 # On MacOS, prefer MacPorts libraries to system libraries.
  39 # I haven't come up with a compelling argument for this to be conditional.
  40 list(APPEND CMAKE_PREFIX_PATH /opt/local)
  41 # Enable @rpath in the install name.
  42 # detail in "cmake  --help-policy CMP0042"
  43 SET(CMAKE_MACOSX_RPATH ON)
  44
  45 #
  46 # Version - read from 'version' file.
  47 #
  48 FILE(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/build/version _version)
  49 STRING(REGEX REPLACE
  50  "^([0-9])[0-9][0-9][0-9][0-9][0-9][0-9][a-z]*$" "\\1" _major ${_version})
  51 STRING(REGEX REPLACE
  52  "^[0-9]([0-9][0-9][0-9])[0-9][0-9][0-9][a-z]*$" "\\1" _minor ${_version})
  53 STRING(REGEX REPLACE
  54  "^[0-9][0-9][0-9][0-9]([0-9][0-9][0-9])[a-z]*$" "\\1" _revision ${_version})
  55 STRING(REGEX REPLACE
  56  "^[0-9][0-9][0-9][0-9][0-9][0-9][0-9]([a-z]*)$" "\\1" _quality ${_version})
  57 SET(_version_number ${_major}${_minor}${_revision})
  58 STRING(REGEX REPLACE "[0]*([^0]*[0-9])$" "\\1" _trimmed_minor ${_minor})
  59 STRING(REGEX REPLACE "[0]*([^0]*[0-9])$" "\\1" _trimmed_revision ${_revision})
  60 #
  61 SET(VERSION                    "${_major}.${_trimmed_minor}.${_trimmed_revision}${_quality}")
  62 SET(BSDCPIO_VERSION_STRING     "${VERSION}")
  63 SET(BSDTAR_VERSION_STRING      "${VERSION}")
  64 SET(BSDCAT_VERSION_STRING      "${VERSION}")
  65 SET(LIBARCHIVE_VERSION_NUMBER  "${_version_number}")
  66 SET(LIBARCHIVE_VERSION_STRING  "${VERSION}")
  67
  68 # INTERFACE_VERSION increments with every release
  69 # libarchive 2.7 == interface version 9 = 2 + 7
  70 # libarchive 2.8 == interface version 10 = 2 + 8
  71 # libarchive 2.9 == interface version 11 = 2 + 9
  72 # libarchive 3.0 == interface version 12
  73 # libarchive 3.1 == interface version 13
  74 math(EXPR INTERFACE_VERSION  "13 + ${_minor}")
  75
  76 # Set SOVERSION == Interface version
  77 # ?? Should there be more here ??
  78 SET(SOVERSION "${INTERFACE_VERSION}")
  79
  80 # Enalbe CMAKE_PUSH_CHECK_STATE() and CMAKE_POP_CHECK_STATE() macros
  81 # saving and restoring the state of the variables.
  82 INCLUDE(CMakePushCheckState)
  83
  84 # Initialize the state of the variables. This initialization is not
  85 # necessary but this shows you what value the variables initially have.
  86 SET(CMAKE_REQUIRED_DEFINITIONS)
  87 SET(CMAKE_REQUIRED_INCLUDES)
  88 SET(CMAKE_REQUIRED_LIBRARIES)
  89 SET(CMAKE_REQUIRED_FLAGS)
  90 if (CMAKE_BUILD_TYPE STREQUAL "Debug")
  91   OPTION(ENABLE_WERROR "Treat warnings as errors - default is ON for Debug, OFF otherwise." ON)
  92 else ()
  93   OPTION(ENABLE_WERROR "Treat warnings as errors - default is ON for Debug, OFF otherwise." OFF)
  94 endif ()
  95
  96 # Especially for early development, we want to be a little
  97 # aggressive about diagnosing build problems; this can get
  98 # relaxed somewhat in final shipping versions.
  99 IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$")
 100   SET(CMAKE_REQUIRED_FLAGS "-Wall -Wformat -Wformat-security")
 101   #################################################################
 102   # Set compile flags for all build types.
 103   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wformat -Wformat-security")
 104   if (ENABLE_WERROR)
 105     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror")
 106   endif ()
 107   #################################################################
 108   # Set compile flags for debug build.
 109   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 110   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wextra")
 111   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wunused")
 112   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wshadow")
 113   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wmissing-prototypes")
 114   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wcast-qual")
 115 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$")
 116 IF (CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 117   SET(CMAKE_REQUIRED_FLAGS "-Wall -Wformat -Wformat-security")
 118   #################################################################
 119   # Set compile flags for all build types.
 120   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wformat -Wformat-security")
 121   if (ENABLE_WERROR)
 122     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror")
 123   endif ()
 124   #################################################################
 125   # Set compile flags for debug build.
 126   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 127   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g")
 128   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wextra")
 129   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wunused")
 130   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wshadow")
 131   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wmissing-prototypes")
 132   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wcast-qual")
 133 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 134 IF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 135   SET(CMAKE_C_COMPILER "xlc_r")
 136   SET(CMAKE_REQUIRED_FLAGS "-qflag=e:e -qformat=sec")
 137   #################################################################
 138   # Set compile flags for all build types.
 139   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -qflag=e:e -qformat=sec")
 140   if (ENABLE_WERROR)
 141     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -qhalt=w")
 142   endif ()
 143   #################################################################
 144   # Set compile flags for debug build.
 145   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 146   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g")
 147   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qflag=w:w")
 148   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qinfo=pro:use")
 149 ENDIF(CMAKE_C_COMPILER_ID MATCHES "^XL$")
 150 IF (MSVC)
 151   if (ENABLE_WERROR)
 152     # /WX option is the same as gcc's -Werror option.
 153     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /WX")
 154   endif ()
 155   #################################################################
 156   # Set compile flags for debug build.
 157   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 158   # Enable level 4 C4061: The enumerate has no associated handler in a switch
 159   #                       statement.
 160   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4061")
 161   # Enable level 4 C4254: A larger bit field was assigned to a smaller bit
 162   #                       field.
 163   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4254")
 164   # Enable level 4 C4295: An array was initialized but the last character in
 165   #                       the array is not a null; accessing the array may
 166   #                       produce unexpected results.
 167   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4295")
 168   # Enable level 4 C4296: An unsigned variable was used in a comparison
 169   #                       operation with zero.
 170   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4296")
 171   # Enable level 4 C4389: An operation involved signed and unsigned variables.
 172   #                       This could result in a loss of data.
 173   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4389")
 174   # Enable level 4 C4505: The given function is local and not referenced in
 175   #                       the body of the module; therefore, the function is
 176   #                       dead code.
 177   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4505")
 178   # Enable level 4 C4514: The optimizer removed an inline function that is not
 179   #                       called.
 180   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4514")
 181   # Enable level 4 C4702: Unreachable code.
 182   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4702")
 183   # Enable level 4 C4706: The test value in a conditional expression was the
 184   #                       result of an assignment.
 185   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4706")
 186   # /Oi option enables built-in functions.
 187   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /Oi")
 188   #################################################################
 189   # Set compile flags for release build.
 190   SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /Oi")
 191 ENDIF (MSVC)
 192
 193 # Enable CTest/CDash support
 194 include(CTest)
 195
 196 OPTION(ENABLE_NETTLE "Enable use of Nettle" ON)
 197 OPTION(ENABLE_OPENSSL "Enable use of OpenSSL" ON)
 198 OPTION(ENABLE_LIBB2 "Enable the use of the system LIBB2 library if found" ON)
 199 OPTION(ENABLE_LZ4 "Enable the use of the system LZ4 library if found" ON)
 200 OPTION(ENABLE_LZO "Enable the use of the system LZO library if found" OFF)
 201 OPTION(ENABLE_LZMA "Enable the use of the system LZMA library if found" ON)
 202 OPTION(ENABLE_ZSTD "Enable the use of the system zstd library if found" ON)
 203
 204 OPTION(ENABLE_ZLIB "Enable the use of the system ZLIB library if found" ON)
 205 OPTION(ENABLE_BZip2 "Enable the use of the system BZip2 library if found" ON)
 206 OPTION(ENABLE_LIBXML2 "Enable the use of the system libxml2 library if found" ON)
 207 OPTION(ENABLE_EXPAT "Enable the use of the system EXPAT library if found" ON)
 208 OPTION(ENABLE_PCREPOSIX "Enable the use of the system PCREPOSIX library if found" ON)
 209 OPTION(ENABLE_LibGCC "Enable the use of the system LibGCC library if found" ON)
 210 # CNG is used for encrypt/decrypt Zip archives on Windows.
 211 OPTION(ENABLE_CNG "Enable the use of CNG(Crypto Next Generation)" ON)
 212
 213 OPTION(ENABLE_TAR "Enable tar building" ON)
 214 OPTION(ENABLE_TAR_SHARED "Enable dynamic build of tar" FALSE)
 215 OPTION(ENABLE_CPIO "Enable cpio building" ON)
 216 OPTION(ENABLE_CPIO_SHARED "Enable dynamic build of cpio" FALSE)
 217 OPTION(ENABLE_CAT "Enable cat building" ON)
 218 OPTION(ENABLE_CAT_SHARED "Enable dynamic build of cat" FALSE)
 219 OPTION(ENABLE_XATTR "Enable extended attribute support" ON)
 220 OPTION(ENABLE_ACL "Enable ACL support" ON)
 221 OPTION(ENABLE_ICONV "Enable iconv support" ON)
 222 OPTION(ENABLE_TEST "Enable unit and regression tests" ON)
 223 OPTION(ENABLE_COVERAGE "Enable code coverage (GCC only, automatically sets ENABLE_TEST to ON)" FALSE)
 224 OPTION(ENABLE_INSTALL "Enable installing of libraries" ON)
 225
 226 SET(POSIX_REGEX_LIB "AUTO" CACHE STRING "Choose what library should provide POSIX regular expression support")
 227 SET(ENABLE_SAFESEH "AUTO" CACHE STRING "Enable use of /SAFESEH linker flag (MSVC only)")
 228 SET(WINDOWS_VERSION "WIN7" CACHE STRING "Set Windows version to use (Windows only)")
 229
 230 IF(ENABLE_COVERAGE)
 231         include(LibarchiveCodeCoverage)
 232 ENDIF(ENABLE_COVERAGE)
 233
 234 IF(ENABLE_TEST)
 235         ENABLE_TESTING()
 236 ENDIF(ENABLE_TEST)
 237
 238 IF(WIN32)
 239   IF(WINDOWS_VERSION STREQUAL "WIN8")
 240     SET(NTDDI_VERSION 0x06020000)
 241     SET(_WIN32_WINNT 0x0602)
 242     SET(WINVER 0x0602)
 243   ELSEIF(WINDOWS_VERSION STREQUAL "WIN7")
 244     SET(NTDDI_VERSION 0x06010000)
 245     SET(_WIN32_WINNT 0x0601)
 246     SET(WINVER 0x0601)
 247   ELSEIF(WINDOWS_VERSION STREQUAL "WS08")
 248     SET(NTDDI_VERSION 0x06000100)
 249     SET(_WIN32_WINNT 0x0600)
 250     SET(WINVER 0x0600)
 251   ELSEIF(WINDOWS_VERSION STREQUAL "VISTA")
 252     SET(NTDDI_VERSION 0x06000000)
 253     SET(_WIN32_WINNT 0x0600)
 254     SET(WINVER 0x0600)
 255   ELSEIF(WINDOWS_VERSION STREQUAL "WS03")
 256     SET(NTDDI_VERSION 0x05020000)
 257     SET(_WIN32_WINNT 0x0502)
 258     SET(WINVER 0x0502)
 259   ELSEIF(WINDOWS_VERSION STREQUAL "WINXP")
 260     SET(NTDDI_VERSION 0x05010000)
 261     SET(_WIN32_WINNT 0x0501)
 262     SET(WINVER 0x0501)
 263   ELSE(WINDOWS_VERSION STREQUAL "WIN8")
 264     # Default to Windows Server 2003 API if we don't recognize the specifier
 265     SET(NTDDI_VERSION 0x05020000)
 266     SET(_WIN32_WINNT 0x0502)
 267     SET(WINVER 0x0502)
 268   ENDIF(WINDOWS_VERSION STREQUAL "WIN8")
 269 ENDIF(WIN32)
 270
 271 IF(MSVC)
 272   IF(ENABLE_SAFESEH STREQUAL "YES")
 273     SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH")
 274     SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SAFESEH")
 275     SET(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /SAFESEH")
 276     SET(ENV{LDFLAGS} "$ENV{LDFLAGS} /SAFESEH")
 277   ELSEIF(ENABLE_SAFESEH STREQUAL "NO")
 278     SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH:NO")
 279     SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SAFESEH:NO")
 280     SET(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /SAFESEH:NO")
 281     SET(ENV{LDFLAGS} "$ENV{LDFLAGS} /SAFESEH:NO")
 282   ENDIF(ENABLE_SAFESEH STREQUAL "YES")
 283 ENDIF(MSVC)
 284
 285 IF("${CMAKE_C_PLATFORM_ID}" MATCHES "^(HP-UX)$")
 286   ADD_DEFINITIONS(-D_XOPEN_SOURCE=500) # Ask wchar.h for mbstate_t
 287 ENDIF()
 288
 289 #
 290 INCLUDE(CheckCSourceCompiles)
 291 INCLUDE(CheckCSourceRuns)
 292 INCLUDE(CheckFileOffsetBits)
 293 INCLUDE(CheckFuncs)
 294 INCLUDE(CheckHeaderDirent)
 295 INCLUDE(CheckIncludeFile)
 296 INCLUDE(CheckIncludeFiles)
 297 INCLUDE(CheckLibraryExists)
 298 INCLUDE(CheckStructHasMember)
 299 INCLUDE(CheckSymbolExists)
 300 INCLUDE(CheckTypeExists)
 301 INCLUDE(CheckTypeSize)
 302
 303 #
 304 # Generate list.h
 305 #
 306 MACRO (GENERATE_LIST_H _listfile _cmlist __list_sources)
 307   SET(_argv ${ARGV})
 308   # Remove _listfile and _cmlist from _argv
 309   LIST(REMOVE_AT _argv 0 1)
 310   IF (NOT EXISTS "${_listfile}" OR
 311      ${_cmlist} IS_NEWER_THAN "${_listfile}")
 312
 313     MESSAGE(STATUS "Generating ${_listfile}")
 314     FILE(WRITE ${_listfile} "")
 315     FOREACH (testfile ${_argv})
 316       IF (testfile MATCHES "^test_[^/]+[.]c$")
 317         FILE(STRINGS ${testfile} testvar REGEX "^DEFINE_TEST")
 318         FOREACH (deftest ${testvar})
 319           FILE(APPEND ${_listfile} "${deftest}\n")
 320         ENDFOREACH (deftest)
 321       ENDIF (testfile MATCHES "^test_[^/]+[.]c$")
 322     ENDFOREACH (testfile)
 323
 324   ENDIF (NOT EXISTS "${_listfile}" OR
 325      ${_cmlist} IS_NEWER_THAN "${_listfile}")
 326 ENDMACRO (GENERATE_LIST_H)
 327 #
 328 # Generate installation rules for man pages.
 329 #
 330 MACRO (INSTALL_MAN __mans)
 331   FOREACH (_man ${ARGV})
 332     STRING(REGEX REPLACE "^.+[.]([1-9])" "\\1" _mansect ${_man})
 333     INSTALL(FILES ${_man} DESTINATION "share/man/man${_mansect}")
 334   ENDFOREACH (_man)
 335 ENDMACRO (INSTALL_MAN __mans)
 336 #
 337 # Find out what macro is needed to use libraries on Windows.
 338 #
 339 MACRO (TRY_MACRO_FOR_LIBRARY INCLUDES LIBRARIES
 340        TRY_TYPE SAMPLE_SOURCE MACRO_LIST)
 341   IF(WIN32 AND NOT CYGWIN)
 342     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 343     SET(CMAKE_REQUIRED_INCLUDES ${INCLUDES})
 344     SET(CMAKE_REQUIRED_LIBRARIES ${LIBRARIES})
 345     FOREACH(VAR ${MACRO_LIST})
 346       # Clear ${VAR} from CACHE If the libraries which ${VAR} was
 347       # checked with are changed.
 348       SET(VAR_WITH_LIB "${VAR}_WITH_LIB")
 349       GET_PROPERTY(PREV_VAR_WITH_LIB VARIABLE PROPERTY ${VAR_WITH_LIB})
 350       IF(NOT "${PREV_VAR_WITH_LIB}" STREQUAL "${LIBRARIES}")
 351         UNSET(${VAR} CACHE)
 352       ENDIF(NOT "${PREV_VAR_WITH_LIB}" STREQUAL "${LIBRARIES}")
 353       # Check if the library can be used with the macro.
 354       IF("${TRY_TYPE}" MATCHES "COMPILES")
 355         CHECK_C_SOURCE_COMPILES("${SAMPLE_SOURCE}" ${VAR})
 356       ELSEIF("${TRY_TYPE}" MATCHES "RUNS")
 357         CHECK_C_SOURCE_RUNS("${SAMPLE_SOURCE}" ${VAR})
 358       ELSE("${TRY_TYPE}" MATCHES "COMPILES")
 359         MESSAGE(FATAL_ERROR "UNKNOWN KEYWORD \"${TRY_TYPE}\" FOR TRY_TYPE")
 360       ENDIF("${TRY_TYPE}" MATCHES "COMPILES")
 361       # Save the libraries which ${VAR} is checked with.
 362       SET(${VAR_WITH_LIB} "${LIBRARIES}" CACHE INTERNAL
 363           "Macro ${VAR} is checked with")
 364     ENDFOREACH(VAR)
 365     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 366   ENDIF(WIN32 AND NOT CYGWIN)
 367 ENDMACRO (TRY_MACRO_FOR_LIBRARY)
 368 #
 369 # Check compress/decompress libraries
 370 #
 371 IF(WIN32 AND NOT CMAKE_CL_64 AND NOT CYGWIN)
 372   # GnuWin32 is only for Win32, not Win64.
 373   SET(__GNUWIN32PATH "C:/Program Files/GnuWin32")
 374 ENDIF(WIN32 AND NOT CMAKE_CL_64 AND NOT CYGWIN)
 375 IF(DEFINED __GNUWIN32PATH AND EXISTS "${__GNUWIN32PATH}")
 376   # You have to add a path availabel DLL file into PATH environment variable.
 377   # Maybe DLL path is "C:/Program Files/GnuWin32/bin".
 378   # The zlib and the bzip2 Setup program have installed programs and DLLs into
 379   # "C:/Program Files/GnuWin32" by default.
 380   # This is convenience setting for Windows.
 381   SET(CMAKE_PREFIX_PATH ${__GNUWIN32PATH} $(CMAKE_PREFIX_PATH))
 382   #
 383   # If you didn't use Setup program or installed into nonstandard path,
 384   # cmake cannot find out your zlib or bzip2 libraries and include files,
 385   # you should execute cmake with  -DCMAKE_PREFIX_PATH option.
 386   #   e.g.
 387   #     cmake -DCMAKE_PREFIX_PATH=<your-GnuWin32-path> <path-to-source>
 388   #
 389   # If compiling error occurred in zconf.h, You may need patch to zconf.h.
 390   #--- zconf.h.orig     2005-07-21 00:40:26.000000000
 391   #+++ zconf.h  2009-01-19 11:39:10.093750000
 392   #@@ -286,7 +286,7 @@
 393   #
 394   # #if 1           /* HAVE_UNISTD_H -- this line is updated by ./configure */
 395   # #  include <sys/types.h> /* for off_t */
 396   #-#  include <unistd.h>    /* for SEEK_* and off_t */
 397   #+#  include <stdio.h>    /* for SEEK_* and off_t */
 398   # #  ifdef VMS
 399   # #    include <unixio.h>   /* for off_t */
 400   # #  endif
 401 ENDIF(DEFINED __GNUWIN32PATH AND EXISTS "${__GNUWIN32PATH}")
 402
 403 SET(ADDITIONAL_LIBS "")
 404 #
 405 # Find ZLIB
 406 #
 407 IF(ENABLE_ZLIB)
 408   FIND_PACKAGE(ZLIB)
 409 ELSE()
 410   SET(ZLIB_FOUND FALSE) # Override cached value
 411 ENDIF()
 412 IF(ZLIB_FOUND)
 413   SET(HAVE_LIBZ 1)
 414   SET(HAVE_ZLIB_H 1)
 415   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 416   LIST(APPEND ADDITIONAL_LIBS ${ZLIB_LIBRARIES})
 417   IF(WIN32 AND NOT CYGWIN)
 418     #
 419     # Test if ZLIB_WINAPI macro is needed to use.
 420     #
 421     TRY_MACRO_FOR_LIBRARY(
 422       "${ZLIB_INCLUDE_DIR}" "${ZLIB_LIBRARIES}"
 423       RUNS
 424       "#include <zlib.h>\nint main() {uLong f = zlibCompileFlags(); return (f&(1U<<10))?0:-1; }"
 425       ZLIB_WINAPI)
 426     IF(ZLIB_WINAPI)
 427       ADD_DEFINITIONS(-DZLIB_WINAPI)
 428     ELSE(ZLIB_WINAPI)
 429       # Test if a macro is needed for the library.
 430       TRY_MACRO_FOR_LIBRARY(
 431         "${ZLIB_INCLUDE_DIR}" "${ZLIB_LIBRARIES}"
 432         COMPILES
 433         "#include <zlib.h>\nint main() {return zlibVersion()?1:0; }"
 434         "ZLIB_DLL;WITHOUT_ZLIB_DLL")
 435       IF(ZLIB_DLL)
 436         ADD_DEFINITIONS(-DZLIB_DLL)
 437       ENDIF(ZLIB_DLL)
 438     ENDIF(ZLIB_WINAPI)
 439   ENDIF(WIN32 AND NOT CYGWIN)
 440 ENDIF(ZLIB_FOUND)
 441 MARK_AS_ADVANCED(CLEAR ZLIB_INCLUDE_DIR)
 442 MARK_AS_ADVANCED(CLEAR ZLIB_LIBRARY)
 443 #
 444 # Find BZip2
 445 #
 446 IF(ENABLE_BZip2)
 447   FIND_PACKAGE(BZip2)
 448 ELSE()
 449   SET(BZIP2_FOUND FALSE) # Override cached value
 450 ENDIF()
 451 IF(BZIP2_FOUND)
 452   SET(HAVE_LIBBZ2 1)
 453   SET(HAVE_BZLIB_H 1)
 454   INCLUDE_DIRECTORIES(${BZIP2_INCLUDE_DIR})
 455   LIST(APPEND ADDITIONAL_LIBS ${BZIP2_LIBRARIES})
 456   # Test if a macro is needed for the library.
 457   TRY_MACRO_FOR_LIBRARY(
 458     "${BZIP2_INCLUDE_DIR}" "${BZIP2_LIBRARIES}"
 459     COMPILES
 460     "#include <bzlib.h>\nint main() {return BZ2_bzlibVersion()?1:0; }"
 461     "USE_BZIP2_DLL;USE_BZIP2_STATIC")
 462   IF(USE_BZIP2_DLL)
 463     ADD_DEFINITIONS(-DUSE_BZIP2_DLL)
 464   ELSEIF(USE_BZIP2_STATIC)
 465     ADD_DEFINITIONS(-DUSE_BZIP2_STATIC)
 466   ENDIF(USE_BZIP2_DLL)
 467 ENDIF(BZIP2_FOUND)
 468 MARK_AS_ADVANCED(CLEAR BZIP2_INCLUDE_DIR)
 469 MARK_AS_ADVANCED(CLEAR BZIP2_LIBRARIES)
 470
 471
 472 #
 473 # Find LZMA
 474 #
 475 IF(ENABLE_LZMA)
 476   FIND_PACKAGE(LibLZMA)
 477 ELSE()
 478   SET(LIBLZMA_FOUND FALSE) # Override cached value
 479 ENDIF()
 480
 481 IF(LIBLZMA_FOUND)
 482   SET(HAVE_LIBLZMA 1)
 483   SET(HAVE_LZMA_H 1)
 484   SET(CMAKE_REQUIRED_INCLUDES ${LIBLZMA_INCLUDE_DIR})
 485   SET(CMAKE_REQUIRED_LIBRARIES ${LIBLZMA_LIBRARIES})
 486   INCLUDE_DIRECTORIES(${LIBLZMA_INCLUDE_DIRS})
 487   LIST(APPEND ADDITIONAL_LIBS ${LIBLZMA_LIBRARIES})
 488   # Test if a macro is needed for the library.
 489   TRY_MACRO_FOR_LIBRARY(
 490     "${LIBLZMA_INCLUDE_DIRS}" "${LIBLZMA_LIBRARIES}"
 491     COMPILES
 492     "#include <lzma.h>\nint main() {return (int)lzma_version_number(); }"
 493     "WITHOUT_LZMA_API_STATIC;LZMA_API_STATIC")
 494   IF(NOT WITHOUT_LZMA_API_STATIC AND LZMA_API_STATIC)
 495     ADD_DEFINITIONS(-DLZMA_API_STATIC)
 496   ENDIF(NOT WITHOUT_LZMA_API_STATIC AND LZMA_API_STATIC)
 497 ELSE(LIBLZMA_FOUND)
 498 # LZMA not found and will not be used.
 499 ENDIF(LIBLZMA_FOUND)
 500 MARK_AS_ADVANCED(CLEAR LIBLZMA_INCLUDE_DIR)
 501 MARK_AS_ADVANCED(CLEAR LIBLZMA_LIBRARY)
 502
 503 #
 504 # Find LZO2
 505 #
 506 IF(ENABLE_LZO)
 507   IF (LZO2_INCLUDE_DIR)
 508     # Already in cache, be silent
 509     SET(LZO2_FIND_QUIETLY TRUE)
 510   ENDIF (LZO2_INCLUDE_DIR)
 511
 512   FIND_PATH(LZO2_INCLUDE_DIR lzo/lzoconf.h)
 513   FIND_LIBRARY(LZO2_LIBRARY NAMES lzo2 liblzo2)
 514   INCLUDE(FindPackageHandleStandardArgs)
 515   FIND_PACKAGE_HANDLE_STANDARD_ARGS(LZO2 DEFAULT_MSG LZO2_LIBRARY LZO2_INCLUDE_DIR)
 516 ELSE(ENABLE_LZO)
 517   SET(LZO2_FOUND FALSE) # Override cached value
 518 ENDIF(ENABLE_LZO)
 519 IF(LZO2_FOUND)
 520   SET(HAVE_LIBLZO2 1)
 521   SET(HAVE_LZO_LZOCONF_H 1)
 522   SET(HAVE_LZO_LZO1X_H 1)
 523   INCLUDE_DIRECTORIES(${LZO2_INCLUDE_DIR})
 524   LIST(APPEND ADDITIONAL_LIBS ${LZO2_LIBRARY})
 525   #
 526   # TODO: test for static library.
 527   #
 528 ENDIF(LZO2_FOUND)
 529 MARK_AS_ADVANCED(CLEAR LZO2_INCLUDE_DIR)
 530 MARK_AS_ADVANCED(CLEAR LZO2_LIBRARY)
 531 #
 532 # Find libb2
 533 #
 534 IF(ENABLE_LIBB2)
 535   IF (LIBB2_INCLUDE_DIR)
 536     # Already in cache, be silent
 537     SET(LIBB2_FIND_QUIETLY TRUE)
 538   ENDIF (LIBB2_INCLUDE_DIR)
 539
 540   FIND_PATH(LIBB2_INCLUDE_DIR blake2.h)
 541   FIND_LIBRARY(LIBB2_LIBRARY NAMES b2 libb2)
 542   INCLUDE(FindPackageHandleStandardArgs)
 543   FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBB2 DEFAULT_MSG LIBB2_LIBRARY LIBB2_INCLUDE_DIR)
 544 ELSE(ENABLE_LIBB2)
 545   SET(LIBB2_FOUND FALSE) # Override cached value
 546 ENDIF(ENABLE_LIBB2)
 547 IF(LIBB2_FOUND)
 548   SET(HAVE_LIBB2 1)
 549   SET(HAVE_BLAKE2_H 1)
 550   SET(ARCHIVE_BLAKE2 FALSE)
 551   LIST(APPEND ADDITIONAL_LIBS ${LIBB2_LIBRARY})
 552   SET(CMAKE_REQUIRED_LIBRARIES ${LIBB2_LIBRARY})
 553   SET(CMAKE_REQUIRED_INCLUDES ${LIBB2_INCLUDE_DIR})
 554   CHECK_FUNCTION_EXISTS(blake2sp_init HAVE_LIBB2)
 555 ELSE(LIBB2_FOUND)
 556   SET(ARCHIVE_BLAKE2 TRUE)
 557 ENDIF(LIBB2_FOUND)
 558 #
 559 # Find LZ4
 560 #
 561 IF(ENABLE_LZ4)
 562   IF (LZ4_INCLUDE_DIR)
 563     # Already in cache, be silent
 564     SET(LZ4_FIND_QUIETLY TRUE)
 565   ENDIF (LZ4_INCLUDE_DIR)
 566
 567   FIND_PATH(LZ4_INCLUDE_DIR lz4.h)
 568   FIND_LIBRARY(LZ4_LIBRARY NAMES lz4 liblz4)
 569   INCLUDE(FindPackageHandleStandardArgs)
 570   FIND_PACKAGE_HANDLE_STANDARD_ARGS(LZ4 DEFAULT_MSG LZ4_LIBRARY LZ4_INCLUDE_DIR)
 571 ELSE(ENABLE_LZ4)
 572   SET(LZ4_FOUND FALSE) # Override cached value
 573 ENDIF(ENABLE_LZ4)
 574 IF(LZ4_FOUND)
 575   SET(HAVE_LIBLZ4 1)
 576   SET(HAVE_LZ4_H 1)
 577   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
 578   SET(CMAKE_REQUIRED_INCLUDES ${LZ4_INCLUDE_DIR})
 579   CHECK_INCLUDE_FILES("lz4hc.h" HAVE_LZ4HC_H)
 580   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
 581   INCLUDE_DIRECTORIES(${LZ4_INCLUDE_DIR})
 582   LIST(APPEND ADDITIONAL_LIBS ${LZ4_LIBRARY})
 583   #
 584   # TODO: test for static library.
 585   #
 586 ENDIF(LZ4_FOUND)
 587 MARK_AS_ADVANCED(CLEAR LZ4_INCLUDE_DIR)
 588 MARK_AS_ADVANCED(CLEAR LZ4_LIBRARY)
 589 #
 590 # Find Zstd
 591 #
 592 IF(ENABLE_ZSTD)
 593   IF (ZSTD_INCLUDE_DIR)
 594     # Already in cache, be silent
 595     SET(ZSTD_FIND_QUIETLY TRUE)
 596   ENDIF (ZSTD_INCLUDE_DIR)
 597
 598   FIND_PATH(ZSTD_INCLUDE_DIR zstd.h)
 599   FIND_LIBRARY(ZSTD_LIBRARY NAMES zstd libzstd)
 600   INCLUDE(FindPackageHandleStandardArgs)
 601   FIND_PACKAGE_HANDLE_STANDARD_ARGS(ZSTD DEFAULT_MSG ZSTD_LIBRARY ZSTD_INCLUDE_DIR)
 602 ELSE(ENABLE_ZSTD)
 603   SET(ZSTD_FOUND FALSE) # Override cached value
 604 ENDIF(ENABLE_ZSTD)
 605 IF(ZSTD_FOUND)
 606   SET(HAVE_ZSTD_H 1)
 607   INCLUDE_DIRECTORIES(${ZSTD_INCLUDE_DIR})
 608   LIST(APPEND ADDITIONAL_LIBS ${ZSTD_LIBRARY})
 609   SET(CMAKE_REQUIRED_LIBRARIES ${ZSTD_LIBRARY})
 610   SET(CMAKE_REQUIRED_INCLUDES ${ZSTD_INCLUDE_DIR})
 611   CHECK_FUNCTION_EXISTS(ZSTD_compressStream HAVE_LIBZSTD)
 612   #
 613   # TODO: test for static library.
 614   #
 615 ENDIF(ZSTD_FOUND)
 616 MARK_AS_ADVANCED(CLEAR ZSTD_INCLUDE_DIR)
 617 MARK_AS_ADVANCED(CLEAR ZSTD_LIBRARY)
 618
 619 set(CMAKE_REQUIRED_LIBRARIES)
 620
 621 #
 622 # Check headers
 623 #
 624 CHECK_HEADER_DIRENT()
 625
 626 SET(INCLUDES "")
 627 MACRO (LA_CHECK_INCLUDE_FILE header var)
 628       CHECK_INCLUDE_FILES("${INCLUDES};${header}" ${var})
 629       IF (${var})
 630          SET(INCLUDES ${INCLUDES} ${header})
 631       ENDIF (${var})
 632 ENDMACRO (LA_CHECK_INCLUDE_FILE)
 633
 634 # Some FreeBSD headers assume sys/types.h was already included.
 635 LA_CHECK_INCLUDE_FILE("sys/types.h" HAVE_SYS_TYPES_H)
 636
 637 # Alphabetize the rest unless there's a compelling reason
 638 LA_CHECK_INCLUDE_FILE("acl/libacl.h" HAVE_ACL_LIBACL_H)
 639 LA_CHECK_INCLUDE_FILE("attr/xattr.h" HAVE_ATTR_XATTR_H)
 640 LA_CHECK_INCLUDE_FILE("ctype.h" HAVE_CTYPE_H)
 641 LA_CHECK_INCLUDE_FILE("copyfile.h" HAVE_COPYFILE_H)
 642 LA_CHECK_INCLUDE_FILE("direct.h" HAVE_DIRECT_H)
 643 LA_CHECK_INCLUDE_FILE("dlfcn.h" HAVE_DLFCN_H)
 644 LA_CHECK_INCLUDE_FILE("errno.h" HAVE_ERRNO_H)
 645 LA_CHECK_INCLUDE_FILE("ext2fs/ext2_fs.h" HAVE_EXT2FS_EXT2_FS_H)
 646
 647 CHECK_C_SOURCE_COMPILES("#include <sys/ioctl.h>
 648 #include <ext2fs/ext2_fs.h>
 649 int main(void) { return EXT2_IOC_GETFLAGS; }" HAVE_WORKING_EXT2_IOC_GETFLAGS)
 650
 651 LA_CHECK_INCLUDE_FILE("fcntl.h" HAVE_FCNTL_H)
 652 LA_CHECK_INCLUDE_FILE("grp.h" HAVE_GRP_H)
 653 LA_CHECK_INCLUDE_FILE("inttypes.h" HAVE_INTTYPES_H)
 654 LA_CHECK_INCLUDE_FILE("io.h" HAVE_IO_H)
 655 LA_CHECK_INCLUDE_FILE("langinfo.h" HAVE_LANGINFO_H)
 656 LA_CHECK_INCLUDE_FILE("limits.h" HAVE_LIMITS_H)
 657 LA_CHECK_INCLUDE_FILE("linux/types.h" HAVE_LINUX_TYPES_H)
 658 LA_CHECK_INCLUDE_FILE("linux/fiemap.h" HAVE_LINUX_FIEMAP_H)
 659 LA_CHECK_INCLUDE_FILE("linux/fs.h" HAVE_LINUX_FS_H)
 660
 661 CHECK_C_SOURCE_COMPILES("#include <sys/ioctl.h>
 662 #include <linux/fs.h>
 663 int main(void) { return FS_IOC_GETFLAGS; }" HAVE_WORKING_FS_IOC_GETFLAGS)
 664
 665 LA_CHECK_INCLUDE_FILE("linux/magic.h" HAVE_LINUX_MAGIC_H)
 666 LA_CHECK_INCLUDE_FILE("locale.h" HAVE_LOCALE_H)
 667 LA_CHECK_INCLUDE_FILE("membership.h" HAVE_MEMBERSHIP_H)
 668 LA_CHECK_INCLUDE_FILE("memory.h" HAVE_MEMORY_H)
 669 LA_CHECK_INCLUDE_FILE("paths.h" HAVE_PATHS_H)
 670 LA_CHECK_INCLUDE_FILE("poll.h" HAVE_POLL_H)
 671 LA_CHECK_INCLUDE_FILE("process.h" HAVE_PROCESS_H)
 672 LA_CHECK_INCLUDE_FILE("pthread.h" HAVE_PTHREAD_H)
 673 LA_CHECK_INCLUDE_FILE("pwd.h" HAVE_PWD_H)
 674 LA_CHECK_INCLUDE_FILE("readpassphrase.h" HAVE_READPASSPHRASE_H)
 675 LA_CHECK_INCLUDE_FILE("regex.h" HAVE_REGEX_H)
 676 LA_CHECK_INCLUDE_FILE("signal.h" HAVE_SIGNAL_H)
 677 LA_CHECK_INCLUDE_FILE("spawn.h" HAVE_SPAWN_H)
 678 LA_CHECK_INCLUDE_FILE("stdarg.h" HAVE_STDARG_H)
 679 LA_CHECK_INCLUDE_FILE("stdint.h" HAVE_STDINT_H)
 680 LA_CHECK_INCLUDE_FILE("stdlib.h" HAVE_STDLIB_H)
 681 LA_CHECK_INCLUDE_FILE("string.h" HAVE_STRING_H)
 682 LA_CHECK_INCLUDE_FILE("strings.h" HAVE_STRINGS_H)
 683 LA_CHECK_INCLUDE_FILE("sys/acl.h" HAVE_SYS_ACL_H)
 684 LA_CHECK_INCLUDE_FILE("sys/cdefs.h" HAVE_SYS_CDEFS_H)
 685 LA_CHECK_INCLUDE_FILE("sys/extattr.h" HAVE_SYS_EXTATTR_H)
 686 LA_CHECK_INCLUDE_FILE("sys/ioctl.h" HAVE_SYS_IOCTL_H)
 687 LA_CHECK_INCLUDE_FILE("sys/mkdev.h" HAVE_SYS_MKDEV_H)
 688 LA_CHECK_INCLUDE_FILE("sys/mount.h" HAVE_SYS_MOUNT_H)
 689 LA_CHECK_INCLUDE_FILE("sys/param.h" HAVE_SYS_PARAM_H)
 690 LA_CHECK_INCLUDE_FILE("sys/poll.h" HAVE_SYS_POLL_H)
 691 LA_CHECK_INCLUDE_FILE("sys/richacl.h" HAVE_SYS_RICHACL_H)
 692 LA_CHECK_INCLUDE_FILE("sys/select.h" HAVE_SYS_SELECT_H)
 693 LA_CHECK_INCLUDE_FILE("sys/stat.h" HAVE_SYS_STAT_H)
 694 LA_CHECK_INCLUDE_FILE("sys/statfs.h" HAVE_SYS_STATFS_H)
 695 LA_CHECK_INCLUDE_FILE("sys/statvfs.h" HAVE_SYS_STATVFS_H)
 696 LA_CHECK_INCLUDE_FILE("sys/sysmacros.h" HAVE_SYS_SYSMACROS_H)
 697 LA_CHECK_INCLUDE_FILE("sys/time.h" HAVE_SYS_TIME_H)
 698 LA_CHECK_INCLUDE_FILE("sys/utime.h" HAVE_SYS_UTIME_H)
 699 LA_CHECK_INCLUDE_FILE("sys/utsname.h" HAVE_SYS_UTSNAME_H)
 700 LA_CHECK_INCLUDE_FILE("sys/vfs.h" HAVE_SYS_VFS_H)
 701 LA_CHECK_INCLUDE_FILE("sys/wait.h" HAVE_SYS_WAIT_H)
 702 LA_CHECK_INCLUDE_FILE("sys/xattr.h" HAVE_SYS_XATTR_H)
 703 LA_CHECK_INCLUDE_FILE("time.h" HAVE_TIME_H)
 704 LA_CHECK_INCLUDE_FILE("unistd.h" HAVE_UNISTD_H)
 705 LA_CHECK_INCLUDE_FILE("utime.h" HAVE_UTIME_H)
 706 LA_CHECK_INCLUDE_FILE("wchar.h" HAVE_WCHAR_H)
 707 LA_CHECK_INCLUDE_FILE("wctype.h" HAVE_WCTYPE_H)
 708 LA_CHECK_INCLUDE_FILE("windows.h" HAVE_WINDOWS_H)
 709 IF(ENABLE_CNG)
 710   LA_CHECK_INCLUDE_FILE("Bcrypt.h" HAVE_BCRYPT_H)
 711   IF(HAVE_BCRYPT_H)
 712     LIST(APPEND ADDITIONAL_LIBS "Bcrypt")
 713   ENDIF(HAVE_BCRYPT_H)
 714 ELSE(ENABLE_CNG)
 715   UNSET(HAVE_BCRYPT_H CACHE)
 716 ENDIF(ENABLE_CNG)
 717 # Following files need windows.h, so we should test it after windows.h test.
 718 LA_CHECK_INCLUDE_FILE("wincrypt.h" HAVE_WINCRYPT_H)
 719 LA_CHECK_INCLUDE_FILE("winioctl.h" HAVE_WINIOCTL_H)
 720
 721 #
 722 # Check whether use of __EXTENSIONS__ is safe.
 723 # We need some macro such as _GNU_SOURCE to use extension functions.
 724 #
 725 SET(_INCLUDE_FILES)
 726 FOREACH (it ${_HEADER})
 727    SET(_INCLUDE_FILES "${_INCLUDE_FILES}#include <${it}>\n")
 728 ENDFOREACH (it)
 729
 730 CHECK_C_SOURCE_COMPILES(
 731   "#define __EXTENSIONS__ 1
 732    ${_INCLUDE_FILES}
 733    int main() { return 0;}"
 734  SAFE_TO_DEFINE_EXTENSIONS)
 735
 736 #
 737 # Find Nettle
 738 #
 739 IF(ENABLE_NETTLE)
 740   FIND_PACKAGE(Nettle)
 741   IF(NETTLE_FOUND)
 742     SET(HAVE_LIBNETTLE 1)
 743     LIST(APPEND ADDITIONAL_LIBS ${NETTLE_LIBRARIES})
 744     INCLUDE_DIRECTORIES(${NETTLE_INCLUDE_DIR})
 745
 746     LIST(APPEND CMAKE_REQUIRED_INCLUDES ${NETTLE_INCLUDE_DIR})
 747     LA_CHECK_INCLUDE_FILE("nettle/aes.h" HAVE_NETTLE_AES_H)
 748     LA_CHECK_INCLUDE_FILE("nettle/hmac.h" HAVE_NETTLE_HMAC_H)
 749     LA_CHECK_INCLUDE_FILE("nettle/md5.h" HAVE_NETTLE_MD5_H)
 750     LA_CHECK_INCLUDE_FILE("nettle/pbkdf2.h" HAVE_NETTLE_PBKDF2_H)
 751     LA_CHECK_INCLUDE_FILE("nettle/ripemd160.h" HAVE_NETTLE_RIPEMD160_H)
 752     LA_CHECK_INCLUDE_FILE("nettle/sha.h" HAVE_NETTLE_SHA_H)
 753
 754   ENDIF(NETTLE_FOUND)
 755   MARK_AS_ADVANCED(CLEAR NETTLE_INCLUDE_DIR)
 756   MARK_AS_ADVANCED(CLEAR NETTLE_LIBRARIES)
 757 ENDIF(ENABLE_NETTLE)
 758
 759 #
 760 # Find OpenSSL
 761 # (Except on Mac, where OpenSSL is deprecated.)
 762 #
 763 IF(ENABLE_OPENSSL AND NOT CMAKE_SYSTEM_NAME MATCHES "Darwin")
 764   FIND_PACKAGE(OpenSSL)
 765   IF(OPENSSL_FOUND)
 766     SET(HAVE_LIBCRYPTO 1)
 767     INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 768     LIST(APPEND ADDITIONAL_LIBS ${OPENSSL_CRYPTO_LIBRARY})
 769   ENDIF(OPENSSL_FOUND)
 770 ELSE()
 771   SET(OPENSSL_FOUND FALSE) # Override cached value
 772 ENDIF()
 773
 774 # FreeBSD libmd
 775 IF(NOT OPENSSL_FOUND)
 776   CHECK_LIBRARY_EXISTS(md "MD5Init" "" LIBMD_FOUND)
 777   IF(LIBMD_FOUND)
 778     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 779     SET(CMAKE_REQUIRED_LIBRARIES "md")
 780     FIND_LIBRARY(LIBMD_LIBRARY NAMES md)
 781     LIST(APPEND ADDITIONAL_LIBS ${LIBMD_LIBRARY})
 782     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 783   ENDIF(LIBMD_FOUND)
 784 ENDIF(NOT OPENSSL_FOUND)
 785
 786 #
 787 # How to prove that CRYPTO functions, which have several names on various
 788 # platforms, just see if archive_digest.c can compile and link against
 789 # required libraries.
 790 #
 791 MACRO(CHECK_CRYPTO ALGORITHMS IMPLEMENTATION)
 792     FOREACH(ALGORITHM ${ALGORITHMS})
 793       IF(NOT ARCHIVE_CRYPTO_${ALGORITHM})
 794       STRING(TOLOWER "${ALGORITHM}" lower_algorithm)
 795       STRING(TOUPPER "${ALGORITHM}" algorithm)
 796       IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND NOT OPENSSL_FOUND)
 797         SET(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} FALSE)
 798       ELSEIF("${IMPLEMENTATION}" MATCHES "^NETTLE$" AND NOT NETTLE_FOUND)
 799         SET(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} FALSE)
 800       ENDIF("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND NOT OPENSSL_FOUND)
 801
 802       IF(NOT DEFINED ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 803         # Probe the local implementation for whether this
 804         # crypto implementation is available on this platform.
 805         SET(TRY_CRYPTO_REQUIRED_INCLUDES
 806           "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_BINARY_DIR};${CMAKE_CURRENT_SOURCE_DIR}/libarchive;${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp")
 807         SET(TRY_CRYPTO_REQUIRED_LIBS)
 808         IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 809             SET(TRY_CRYPTO_REQUIRED_INCLUDES
 810               "${TRY_CRYPTO_REQUIRED_INCLUDES};${OPENSSL_INCLUDE_DIR}")
 811             SET(TRY_CRYPTO_REQUIRED_LIBS
 812                 "-DLINK_LIBRARIES:STRING=${OPENSSL_LIBRARIES}")
 813         ELSEIF("${IMPLEMENTATION}" MATCHES "^NETTLE$" AND NETTLE_FOUND)
 814             SET(TRY_CRYPTO_REQUIRED_INCLUDES
 815               "${TRY_CRYPTO_REQUIRED_INCLUDES};${NETTLE_INCLUDE_DIR}")
 816             SET(TRY_CRYPTO_REQUIRED_LIBS
 817                 "-DLINK_LIBRARIES:STRING=${NETTLE_LIBRARY}")
 818         ELSEIF("${IMPLEMENTATION}" MATCHES "^LIBMD$" AND LIBMD_FOUND)
 819             SET(TRY_CRYPTO_REQUIRED_LIBS
 820                 "-DLINK_LIBRARIES:STRING=${LIBMD_LIBRARY}")
 821         ENDIF("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 822
 823     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
 824       ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h)
 825         FILE(READ "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h"
 826              CONFDEFS_H)
 827         FILE(READ "${CMAKE_CURRENT_SOURCE_DIR}/libarchive/archive_digest.c"
 828              ARCHIVE_CRYPTO_C)
 829
 830         SET(SOURCE "${CONFDEFS_H}
 831
 832 #define ARCHIVE_${algorithm}_COMPILE_TEST
 833 #define ARCHIVE_CRYPTO_${algorithm}_${IMPLEMENTATION}
 834 #define PLATFORM_CONFIG_H \"check_crypto_md.h\"
 835
 836 ${ARCHIVE_CRYPTO_C}
 837
 838 int
 839 main(int argc, char **argv)
 840 {
 841   archive_${lower_algorithm}_ctx ctx;
 842   archive_${lower_algorithm}_init(&ctx);
 843   archive_${lower_algorithm}_update(&ctx, *argv, argc);
 844   archive_${lower_algorithm}_final(&ctx, NULL);
 845   return 0;
 846 }
 847 ")
 848
 849   FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.h" "")
 850         FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.c" "${SOURCE}")
 851         MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION}")
 852
 853         TRY_COMPILE(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION}
 854           ${CMAKE_BINARY_DIR}
 855           ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.c
 856           CMAKE_FLAGS
 857            "${TRY_CRYPTO_REQUIRED_LIBS}"
 858            "${TRY_CRYPTO_REQUIRED_INCLUDES}"
 859           OUTPUT_VARIABLE OUTPUT)
 860
 861         # Inform user whether or not we found it; if not, log why we didn't.
 862         IF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 863           MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} -- found")
 864                   SET(ARCHIVE_CRYPTO_${ALGORITHM} 1)
 865         ELSE (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 866           MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} -- not found")
 867           FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 868             "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} failed with the following output:\n"
 869             "${OUTPUT}\n"
 870             "Source file was:\n${SOURCE}\n")
 871         ENDIF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 872       ENDIF(NOT DEFINED ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 873
 874       # Add appropriate libs/includes depending on whether the implementation
 875       # was found on this platform.
 876       IF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 877         IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 878           INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 879           LIST(APPEND ADDITIONAL_LIBS ${OPENSSL_LIBRARIES})
 880            LIST(REMOVE_DUPLICATES ADDITIONAL_LIBS)
 881         ENDIF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 882       ENDIF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 883       ENDIF(NOT ARCHIVE_CRYPTO_${ALGORITHM})
 884     ENDFOREACH(ALGORITHM ${ALGORITHMS})
 885 ENDMACRO(CHECK_CRYPTO ALGORITHMS IMPLEMENTATION)
 886
 887 #
 888 # CRYPTO functions on Windows is defined at archive_windows.c, thus we do not
 889 # need the test what the functions can be mapped to archive_{crypto name}_init,
 890 # archive_{crypto name}_update and archive_{crypto name}_final.
 891 # The functions on Windows use CALG_{crypto name} macro to create a crypt object
 892 # and then we need to know what CALG_{crypto name} macros is available to show
 893 # ARCHIVE_CRYPTO_{crypto name}_WIN macros because Windows 2000 and earlier version
 894 # of Windows XP do not support SHA256, SHA384 and SHA512.
 895 #
 896 MACRO(CHECK_CRYPTO_WIN CRYPTO_LIST)
 897   IF(WIN32 AND NOT CYGWIN)
 898     FOREACH(CRYPTO ${CRYPTO_LIST})
 899       IF(NOT ARCHIVE_CRYPTO_${CRYPTO})
 900       IF(NOT DEFINED ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 901         STRING(TOUPPER "${CRYPTO}" crypto)
 902         SET(ALGID "")
 903         IF ("${CRYPTO}" MATCHES "^MD5$")
 904             SET(ALGID "CALG_MD5")
 905         ENDIF ("${CRYPTO}" MATCHES "^MD5$")
 906         IF ("${CRYPTO}" MATCHES "^SHA1$")
 907             SET(ALGID "CALG_SHA1")
 908         ENDIF ("${CRYPTO}" MATCHES "^SHA1$")
 909         IF ("${CRYPTO}" MATCHES "^SHA256$")
 910             SET(ALGID "CALG_SHA_256")
 911         ENDIF ("${CRYPTO}" MATCHES "^SHA256$")
 912         IF ("${CRYPTO}" MATCHES "^SHA384$")
 913             SET(ALGID "CALG_SHA_384")
 914         ENDIF ("${CRYPTO}" MATCHES "^SHA384$")
 915         IF ("${CRYPTO}" MATCHES "^SHA512$")
 916             SET(ALGID "CALG_SHA_512")
 917         ENDIF ("${CRYPTO}" MATCHES "^SHA512$")
 918
 919     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
 920       ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h)
 921         FILE(READ "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h"
 922              CONFDEFS_H)
 923
 924         SET(SOURCE "${CONFDEFS_H}
 925
 926 #define ${crypto}_COMPILE_TEST
 927 #include <windows.h>
 928 #include <wincrypt.h>
 929
 930 int
 931 main(int argc, char **argv)
 932 {
 933         return ${ALGID};
 934 }
 935 ")
 936         SET(SOURCE_FILE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_win.c")
 937
 938         FILE(WRITE "${SOURCE_FILE}" "${SOURCE}")
 939         MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN")
 940
 941         TRY_COMPILE(ARCHIVE_CRYPTO_${CRYPTO}_WIN
 942           ${CMAKE_BINARY_DIR}
 943           ${SOURCE_FILE}
 944           CMAKE_FLAGS "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_BINARY_DIR};${CMAKE_CURRENT_SOURCE_DIR}/libarchive"
 945           OUTPUT_VARIABLE OUTPUT)
 946
 947         IF (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 948             MESSAGE(STATUS
 949                 "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN -- found")
 950                 SET(ARCHIVE_CRYPTO_${CRYPTO} 1)
 951         ELSE (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 952             MESSAGE(STATUS
 953                  "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN -- not found")
 954             FILE(APPEND
 955                 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 956                 "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN failed with the following output:\n"
 957                 "${OUTPUT}\n"
 958                 "Source file was:\n${SOURCE}\n")
 959         ENDIF (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 960
 961       ENDIF(NOT DEFINED ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 962       ENDIF(NOT ARCHIVE_CRYPTO_${CRYPTO})
 963     ENDFOREACH(CRYPTO)
 964   ENDIF(WIN32 AND NOT CYGWIN)
 965 ENDMACRO(CHECK_CRYPTO_WIN CRYPTO_LIST)
 966
 967 #
 968 # Find iconv
 969 # POSIX defines the second arg as const char **
 970 # and requires it to be in libc.  But we can accept
 971 # a non-const argument here and can support iconv()
 972 # being in libiconv.
 973 #
 974 MACRO(CHECK_ICONV LIB TRY_ICONV_CONST)
 975   IF(NOT HAVE_ICONV)
 976     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 977     IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
 978         CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 979       #
 980       # During checking iconv proto type, we should use -Werror to avoid the
 981       # success of iconv detection with a warnig which success is a miss
 982       # detection. So this needs for all build mode(even it's a release mode).
 983       #
 984       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror")
 985     ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
 986            CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 987     IF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 988       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -qhalt=w -qflag=w:w")
 989     ENDIF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 990     IF (MSVC)
 991       # NOTE: /WX option is the same as gcc's -Werror option.
 992       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} /WX")
 993     ENDIF (MSVC)
 994     #
 995     CHECK_C_SOURCE_COMPILES(
 996       "#include <stdlib.h>
 997        #include <iconv.h>
 998        int main() {
 999           ${TRY_ICONV_CONST} char *ccp;
1000           iconv_t cd = iconv_open(\"\", \"\");
1001           iconv(cd, &ccp, (size_t *)0, (char **)0, (size_t *)0);
1002           iconv_close(cd);
1003           return 0;
1004        }"
1005      HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
1006     IF(HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
1007       SET(HAVE_ICONV true)
1008       SET(ICONV_CONST ${TRY_ICONV_CONST})
1009     ENDIF(HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
1010     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
1011   ENDIF(NOT HAVE_ICONV)
1012 ENDMACRO(CHECK_ICONV TRY_ICONV_CONST)
1013
1014 IF(ENABLE_ICONV)
1015   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
1016   FIND_PATH(ICONV_INCLUDE_DIR iconv.h)
1017   IF(ICONV_INCLUDE_DIR)
1018     #SET(INCLUDES ${INCLUDES} "iconv.h")
1019     SET(HAVE_ICONV_H 1)
1020     INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
1021     SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
1022     CHECK_ICONV("libc" "const")
1023     CHECK_ICONV("libc" "")
1024
1025     # If iconv isn't in libc and we have a libiconv, try that.
1026     FIND_LIBRARY(LIBICONV_PATH NAMES iconv libiconv)
1027     IF(NOT HAVE_ICONV AND LIBICONV_PATH)
1028       LIST(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBICONV_PATH})
1029       # Test if a macro is needed for the library.
1030       TRY_MACRO_FOR_LIBRARY(
1031         "${ICONV_INCLUDE_DIR}" "${LIBICONV_PATH}"
1032         COMPILES
1033         "#include <iconv.h>\nint main() {return iconv_close((iconv_t)0);}"
1034         "WITHOUT_LIBICONV_STATIC;LIBICONV_STATIC")
1035       IF(NOT WITHOUT_LIBICONV_STATIC AND LIBICONV_STATIC)
1036         ADD_DEFINITIONS(-DLIBICONV_STATIC)
1037       ENDIF(NOT WITHOUT_LIBICONV_STATIC AND LIBICONV_STATIC)
1038       #
1039       # Set up CMAKE_REQUIRED_* for CHECK_ICONV
1040       #
1041       SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
1042       SET(CMAKE_REQUIRED_LIBRARIES ${LIBICONV_PATH})
1043       IF(LIBICONV_STATIC)
1044         # LIBICONV_STATIC is necessary for the success of CHECK_ICONV
1045         # on Windows.
1046         SET(CMAKE_REQUIRED_DEFINITIONS "-DLIBICONV_STATIC")
1047       ELSE(LIBICONV_STATIC)
1048         SET(CMAKE_REQUIRED_DEFINITIONS)
1049       ENDIF(LIBICONV_STATIC)
1050       CHECK_ICONV("libiconv" "const")
1051       CHECK_ICONV("libiconv" "")
1052       IF (HAVE_ICONV)
1053         LIST(APPEND ADDITIONAL_LIBS ${LIBICONV_PATH})
1054       ENDIF(HAVE_ICONV)
1055     ENDIF(NOT HAVE_ICONV AND LIBICONV_PATH)
1056   ENDIF(ICONV_INCLUDE_DIR)
1057   #
1058   # Find locale_charset() for libiconv.
1059   #
1060   IF(LIBICONV_PATH)
1061     SET(CMAKE_REQUIRED_DEFINITIONS)
1062     SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
1063     SET(CMAKE_REQUIRED_LIBRARIES)
1064     CHECK_INCLUDE_FILES("localcharset.h" HAVE_LOCALCHARSET_H)
1065     FIND_LIBRARY(LIBCHARSET_PATH NAMES charset libcharset)
1066     IF(LIBCHARSET_PATH)
1067       SET(CMAKE_REQUIRED_LIBRARIES ${LIBCHARSET_PATH})
1068       IF(WIN32 AND NOT CYGWIN)
1069         # Test if a macro is needed for the library.
1070         TRY_MACRO_FOR_LIBRARY(
1071           "${ICONV_INCLUDE_DIR}" "${LIBCHARSET_PATH}"
1072           COMPILES
1073           "#include <localcharset.h>\nint main() {return locale_charset()?1:0;}"
1074           "WITHOUT_LIBCHARSET_STATIC;LIBCHARSET_STATIC")
1075         IF(NOT WITHOUT_LIBCHARSET_STATIC AND LIBCHARSET_STATIC)
1076           ADD_DEFINITIONS(-DLIBCHARSET_STATIC)
1077         ENDIF(NOT WITHOUT_LIBCHARSET_STATIC AND LIBCHARSET_STATIC)
1078         IF(WITHOUT_LIBCHARSET_STATIC OR LIBCHARSET_STATIC)
1079           SET(HAVE_LOCALE_CHARSET ON CACHE INTERNAL
1080               "Have function locale_charset")
1081         ENDIF(WITHOUT_LIBCHARSET_STATIC OR LIBCHARSET_STATIC)
1082       ELSE(WIN32 AND NOT CYGWIN)
1083         CHECK_FUNCTION_EXISTS_GLIBC(locale_charset HAVE_LOCALE_CHARSET)
1084       ENDIF(WIN32 AND NOT CYGWIN)
1085       IF(HAVE_LOCALE_CHARSET)
1086         LIST(APPEND ADDITIONAL_LIBS ${LIBCHARSET_PATH})
1087       ENDIF(HAVE_LOCALE_CHARSET)
1088     ENDIF(LIBCHARSET_PATH)
1089   ENDIF(LIBICONV_PATH)
1090   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
1091 ELSE(ENABLE_ICONV)
1092   # Make sure ICONV variables are not in CACHE after ENABLE_ICONV disabled
1093   # (once enabled).
1094   UNSET(HAVE_LOCALE_CHARSET CACHE)
1095   UNSET(HAVE_ICONV CACHE)
1096   UNSET(HAVE_ICONV_libc_ CACHE)
1097   UNSET(HAVE_ICONV_libc_const CACHE)
1098   UNSET(HAVE_ICONV_libiconv_ CACHE)
1099   UNSET(HAVE_ICONV_libiconv_const CACHE)
1100   UNSET(ICONV_INCLUDE_DIR CACHE)
1101   UNSET(LIBICONV_PATH CACHE)
1102   UNSET(LIBICONV_DLL CACHE)
1103   UNSET(LIBICONV_STATIC CACHE)
1104   UNSET(LIBCHARSET_DLL CACHE)
1105   UNSET(LIBCHARSET_STATIC CACHE)
1106 ENDIF(ENABLE_ICONV)
1107
1108 #
1109 # Find Libxml2
1110 #
1111 IF(ENABLE_LIBXML2)
1112   FIND_PACKAGE(LibXml2)
1113 ELSE()
1114   SET(LIBXML2_FOUND FALSE)
1115 ENDIF()
1116 IF(LIBXML2_FOUND)
1117   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
1118   INCLUDE_DIRECTORIES(${LIBXML2_INCLUDE_DIR})
1119   LIST(APPEND ADDITIONAL_LIBS ${LIBXML2_LIBRARIES})
1120   SET(HAVE_LIBXML2 1)
1121   # libxml2's include files use iconv.h
1122   SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR} ${LIBXML2_INCLUDE_DIR})
1123   CHECK_INCLUDE_FILES("libxml/xmlreader.h" HAVE_LIBXML_XMLREADER_H)
1124   CHECK_INCLUDE_FILES("libxml/xmlwriter.h" HAVE_LIBXML_XMLWRITER_H)
1125   # Test if a macro is needed for the library.
1126   TRY_MACRO_FOR_LIBRARY(
1127     "${ICONV_INCLUDE_DIR};${LIBXML2_INCLUDE_DIR}"
1128     "ws2_32.lib;${ZLIB_LIBRARIES};${LIBICONV_PATH};${LIBXML2_LIBRARIES}"
1129     COMPILES
1130     "#include <stddef.h>\n#include <libxml/xmlreader.h>\nint main() {return xmlTextReaderRead((xmlTextReaderPtr)(void *)0);}"
1131     "WITHOUT_LIBXML_STATIC;LIBXML_STATIC")
1132   IF(NOT WITHOUT_LIBXML_STATIC AND LIBXML_STATIC)
1133     ADD_DEFINITIONS(-DLIBXML_STATIC)
1134   ENDIF(NOT WITHOUT_LIBXML_STATIC AND LIBXML_STATIC)
1135   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
1136 ELSE(LIBXML2_FOUND)
1137   #
1138   # Find Expat
1139   #
1140   IF(ENABLE_EXPAT)
1141     FIND_PACKAGE(EXPAT)
1142   ELSE()
1143     SET(EXPAT_FOUND FALSE)
1144   ENDIF()
1145   IF(EXPAT_FOUND)
1146     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
1147     INCLUDE_DIRECTORIES(${EXPAT_INCLUDE_DIR})
1148     LIST(APPEND ADDITIONAL_LIBS ${EXPAT_LIBRARIES})
1149     SET(HAVE_LIBEXPAT 1)
1150     LA_CHECK_INCLUDE_FILE("expat.h" HAVE_EXPAT_H)
1151     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
1152   ENDIF(EXPAT_FOUND)
1153 ENDIF(LIBXML2_FOUND)
1154 MARK_AS_ADVANCED(CLEAR LIBXML2_INCLUDE_DIR)
1155 MARK_AS_ADVANCED(CLEAR LIBXML2_LIBRARIES)
1156
1157 #
1158 # POSIX Regular Expression support
1159 #
1160 IF(POSIX_REGEX_LIB MATCHES "^(AUTO|LIBC|LIBREGEX)$")
1161   #
1162   # If PCREPOSIX is not found or not requested, try using regex
1163   # from libc or libregex
1164   #
1165   FIND_PATH(REGEX_INCLUDE_DIR regex.h)
1166   IF(REGEX_INCLUDE_DIR)
1167     CHECK_FUNCTION_EXISTS_GLIBC(regcomp HAVE_REGCOMP_LIBC)
1168     #
1169     # If libc does not provide regex, find libregex.
1170     #
1171     IF(NOT HAVE_REGCOMP_LIBC)
1172       CMAKE_PUSH_CHECK_STATE()  # Save the state of the variables
1173       FIND_LIBRARY(REGEX_LIBRARY regex)
1174       IF(REGEX_LIBRARY)
1175         SET(CMAKE_REQUIRED_LIBRARIES ${REGEX_LIBRARY})
1176         CHECK_FUNCTION_EXISTS_GLIBC(regcomp HAVE_REGCOMP_LIBREGEX)
1177         IF(HAVE_REGCOMP_LIBREGEX)
1178           LIST(APPEND ADDITIONAL_LIBS ${REGEX_LIBRARY})
1179           #
1180           # If regex.h is not found, retry looking for regex.h at
1181           # REGEX_INCLUDE_DIR
1182           #
1183           IF(NOT HAVE_REGEX_H)
1184             UNSET(HAVE_REGEX_H CACHE)
1185             INCLUDE_DIRECTORIES(${REGEX_INCLUDE_DIR})
1186             SET(CMAKE_REQUIRED_INCLUDES ${REGEX_INCLUDE_DIR})
1187             LA_CHECK_INCLUDE_FILE("regex.h" HAVE_REGEX_H)
1188           ENDIF(NOT HAVE_REGEX_H)
1189           # Test if a macro is needed for the library.
1190           TRY_MACRO_FOR_LIBRARY(
1191             "${REGEX_INCLUDE_DIR}" "${REGEX_LIBRARY}"
1192             COMPILES
1193             "#include <stddef.h>\n#include <regex.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1194             "USE_REGEX_DLL;USE_REGEX_STATIC")
1195           IF(USE_REGEX_DLL)
1196             ADD_DEFINITIONS(-DUSE_REGEX_DLL)
1197           ELSEIF(USE_REGEX_STATIC)
1198             ADD_DEFINITIONS(-DUSE_REGEX_STATIC)
1199           ENDIF(USE_REGEX_DLL)
1200         ENDIF(HAVE_REGCOMP_LIBREGEX)
1201       ENDIF(REGEX_LIBRARY)
1202       CMAKE_POP_CHECK_STATE()   # Restore the state of the variables
1203     ENDIF(NOT HAVE_REGCOMP_LIBC)
1204   ENDIF(REGEX_INCLUDE_DIR)
1205   IF(HAVE_REGCOMP_LIBC OR HAVE_REGCOMP_LIBREGEX)
1206     SET(FOUND_POSIX_REGEX_LIB 1)
1207   ENDIF(HAVE_REGCOMP_LIBC OR HAVE_REGCOMP_LIBREGEX)
1208 ENDIF(POSIX_REGEX_LIB MATCHES "^(AUTO|LIBC|LIBREGEX)$")
1209
1210 IF(NOT FOUND_POSIX_REGEX_LIB AND POSIX_REGEX_LIB MATCHES "^(AUTO|LIBPCREPOSIX)$")
1211   #
1212   # If requested, try finding library for PCREPOSIX
1213   #
1214   IF(ENABLE_LibGCC)
1215     FIND_PACKAGE(LibGCC)
1216   ELSE()
1217     SET(LIBGCC_FOUND FALSE) # Override cached value
1218   ENDIF()
1219   IF(ENABLE_PCREPOSIX)
1220     FIND_PACKAGE(PCREPOSIX)
1221   ELSE()
1222     SET(PCREPOSIX_FOUND FALSE) # Override cached value
1223   ENDIF()
1224   IF(PCREPOSIX_FOUND)
1225     INCLUDE_DIRECTORIES(${PCRE_INCLUDE_DIR})
1226     LIST(APPEND ADDITIONAL_LIBS ${PCREPOSIX_LIBRARIES})
1227     # Test if a macro is needed for the library.
1228     TRY_MACRO_FOR_LIBRARY(
1229       "${PCRE_INCLUDE_DIR}" "${PCREPOSIX_LIBRARIES}"
1230       COMPILES
1231       "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1232       "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1233     IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1234       ADD_DEFINITIONS(-DPCRE_STATIC)
1235         ELSEIF(NOT WITHOUT_PCRE_STATIC AND NOT PCRE_STATIC AND PCRE_FOUND)
1236           # Determine if pcre static libraries are to be used.
1237       LIST(APPEND ADDITIONAL_LIBS ${PCRE_LIBRARIES})
1238       SET(TMP_LIBRARIES ${PCREPOSIX_LIBRARIES} ${PCRE_LIBRARIES})
1239       MESSAGE(STATUS "trying again with -lpcre included")
1240       TRY_MACRO_FOR_LIBRARY(
1241         "${PCRE_INCLUDE_DIR}" "${TMP_LIBRARIES}"
1242         COMPILES
1243         "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1244         "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1245       IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1246         ADD_DEFINITIONS(-DPCRE_STATIC)
1247       ELSEIF(NOT WITHOUT_PCRE_STATIC AND NOT PCRE_STATIC AND MSVC AND LIBGCC_FOUND)
1248         # When doing a Visual Studio build using pcre static libraries
1249         # built using the mingw toolchain, -lgcc is needed to resolve
1250         # ___chkstk_ms.
1251         MESSAGE(STATUS "Visual Studio build detected, trying again with -lgcc included")
1252         LIST(APPEND ADDITIONAL_LIBS ${LIBGCC_LIBRARIES})
1253         SET(TMP_LIBRARIES ${PCREPOSIX_LIBRARIES} ${PCRE_LIBRARIES} ${LIBGCC_LIBRARIES})
1254           TRY_MACRO_FOR_LIBRARY(
1255             "${PCRE_INCLUDE_DIR}" "${TMP_LIBRARIES}"
1256             COMPILES
1257             "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1258             "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1259           IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1260             ADD_DEFINITIONS(-DPCRE_STATIC)
1261           ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1262       ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1263     ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1264   ENDIF(PCREPOSIX_FOUND)
1265   MARK_AS_ADVANCED(CLEAR PCRE_INCLUDE_DIR)
1266   MARK_AS_ADVANCED(CLEAR PCREPOSIX_LIBRARIES)
1267   MARK_AS_ADVANCED(CLEAR PCRE_LIBRARIES)
1268   MARK_AS_ADVANCED(CLEAR LIBGCC_LIBRARIES)
1269 ENDIF(NOT FOUND_POSIX_REGEX_LIB AND POSIX_REGEX_LIB MATCHES "^(AUTO|LIBPCREPOSIX)$")
1270
1271 #
1272 # Check functions
1273 #
1274 CMAKE_PUSH_CHECK_STATE()        # Save the state of the variables
1275 IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
1276     CMAKE_C_COMPILER_ID MATCHES "^Clang$")
1277   #
1278   # During checking functions, we should use -fno-builtin to avoid the
1279   # failure of function detection which failure is an error "conflicting
1280   # types for built-in function" caused by using -Werror option.
1281   #
1282   SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-builtin")
1283 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
1284        CMAKE_C_COMPILER_ID MATCHES "^Clang$")
1285 CHECK_SYMBOL_EXISTS(_CrtSetReportMode "crtdbg.h" HAVE__CrtSetReportMode)
1286 CHECK_FUNCTION_EXISTS_GLIBC(arc4random_buf HAVE_ARC4RANDOM_BUF)
1287 CHECK_FUNCTION_EXISTS_GLIBC(chflags HAVE_CHFLAGS)
1288 CHECK_FUNCTION_EXISTS_GLIBC(chown HAVE_CHOWN)
1289 CHECK_FUNCTION_EXISTS_GLIBC(chroot HAVE_CHROOT)
1290 CHECK_FUNCTION_EXISTS_GLIBC(ctime_r HAVE_CTIME_R)
1291 CHECK_FUNCTION_EXISTS_GLIBC(fchdir HAVE_FCHDIR)
1292 CHECK_FUNCTION_EXISTS_GLIBC(fchflags HAVE_FCHFLAGS)
1293 CHECK_FUNCTION_EXISTS_GLIBC(fchmod HAVE_FCHMOD)
1294 CHECK_FUNCTION_EXISTS_GLIBC(fchown HAVE_FCHOWN)
1295 CHECK_FUNCTION_EXISTS_GLIBC(fcntl HAVE_FCNTL)
1296 CHECK_FUNCTION_EXISTS_GLIBC(fdopendir HAVE_FDOPENDIR)
1297 CHECK_FUNCTION_EXISTS_GLIBC(fork HAVE_FORK)
1298 CHECK_FUNCTION_EXISTS_GLIBC(fstat HAVE_FSTAT)
1299 CHECK_FUNCTION_EXISTS_GLIBC(fstatat HAVE_FSTATAT)
1300 CHECK_FUNCTION_EXISTS_GLIBC(fstatfs HAVE_FSTATFS)
1301 CHECK_FUNCTION_EXISTS_GLIBC(fstatvfs HAVE_FSTATVFS)
1302 CHECK_FUNCTION_EXISTS_GLIBC(ftruncate HAVE_FTRUNCATE)
1303 CHECK_FUNCTION_EXISTS_GLIBC(futimens HAVE_FUTIMENS)
1304 CHECK_FUNCTION_EXISTS_GLIBC(futimes HAVE_FUTIMES)
1305 CHECK_FUNCTION_EXISTS_GLIBC(futimesat HAVE_FUTIMESAT)
1306 CHECK_FUNCTION_EXISTS_GLIBC(geteuid HAVE_GETEUID)
1307 CHECK_FUNCTION_EXISTS_GLIBC(getgrgid_r HAVE_GETGRGID_R)
1308 CHECK_FUNCTION_EXISTS_GLIBC(getgrnam_r HAVE_GETGRNAM_R)
1309 CHECK_FUNCTION_EXISTS_GLIBC(getpwnam_r HAVE_GETPWNAM_R)
1310 CHECK_FUNCTION_EXISTS_GLIBC(getpwuid_r HAVE_GETPWUID_R)
1311 CHECK_FUNCTION_EXISTS_GLIBC(getpid HAVE_GETPID)
1312 CHECK_FUNCTION_EXISTS_GLIBC(getvfsbyname HAVE_GETVFSBYNAME)
1313 CHECK_FUNCTION_EXISTS_GLIBC(gmtime_r HAVE_GMTIME_R)
1314 CHECK_FUNCTION_EXISTS_GLIBC(lchflags HAVE_LCHFLAGS)
1315 CHECK_FUNCTION_EXISTS_GLIBC(lchmod HAVE_LCHMOD)
1316 CHECK_FUNCTION_EXISTS_GLIBC(lchown HAVE_LCHOWN)
1317 CHECK_FUNCTION_EXISTS_GLIBC(link HAVE_LINK)
1318 CHECK_FUNCTION_EXISTS_GLIBC(localtime_r HAVE_LOCALTIME_R)
1319 CHECK_FUNCTION_EXISTS_GLIBC(lstat HAVE_LSTAT)
1320 CHECK_FUNCTION_EXISTS_GLIBC(lutimes HAVE_LUTIMES)
1321 CHECK_FUNCTION_EXISTS_GLIBC(mbrtowc HAVE_MBRTOWC)
1322 CHECK_FUNCTION_EXISTS_GLIBC(memmove HAVE_MEMMOVE)
1323 CHECK_FUNCTION_EXISTS_GLIBC(mkdir HAVE_MKDIR)
1324 CHECK_FUNCTION_EXISTS_GLIBC(mkfifo HAVE_MKFIFO)
1325 CHECK_FUNCTION_EXISTS_GLIBC(mknod HAVE_MKNOD)
1326 CHECK_FUNCTION_EXISTS_GLIBC(mkstemp HAVE_MKSTEMP)
1327 CHECK_FUNCTION_EXISTS_GLIBC(nl_langinfo HAVE_NL_LANGINFO)
1328 CHECK_FUNCTION_EXISTS_GLIBC(openat HAVE_OPENAT)
1329 CHECK_FUNCTION_EXISTS_GLIBC(pipe HAVE_PIPE)
1330 CHECK_FUNCTION_EXISTS_GLIBC(poll HAVE_POLL)
1331 CHECK_FUNCTION_EXISTS_GLIBC(posix_spawnp HAVE_POSIX_SPAWNP)
1332 CHECK_FUNCTION_EXISTS_GLIBC(readlink HAVE_READLINK)
1333 CHECK_FUNCTION_EXISTS_GLIBC(readpassphrase HAVE_READPASSPHRASE)
1334 CHECK_FUNCTION_EXISTS_GLIBC(select HAVE_SELECT)
1335 CHECK_FUNCTION_EXISTS_GLIBC(setenv HAVE_SETENV)
1336 CHECK_FUNCTION_EXISTS_GLIBC(setlocale HAVE_SETLOCALE)
1337 CHECK_FUNCTION_EXISTS_GLIBC(sigaction HAVE_SIGACTION)
1338 CHECK_FUNCTION_EXISTS_GLIBC(statfs HAVE_STATFS)
1339 CHECK_FUNCTION_EXISTS_GLIBC(statvfs HAVE_STATVFS)
1340 CHECK_FUNCTION_EXISTS_GLIBC(strchr HAVE_STRCHR)
1341 CHECK_FUNCTION_EXISTS_GLIBC(strdup HAVE_STRDUP)
1342 CHECK_FUNCTION_EXISTS_GLIBC(strerror HAVE_STRERROR)
1343 CHECK_FUNCTION_EXISTS_GLIBC(strncpy_s HAVE_STRNCPY_S)
1344 CHECK_FUNCTION_EXISTS_GLIBC(strrchr HAVE_STRRCHR)
1345 CHECK_FUNCTION_EXISTS_GLIBC(symlink HAVE_SYMLINK)
1346 CHECK_FUNCTION_EXISTS_GLIBC(timegm HAVE_TIMEGM)
1347 CHECK_FUNCTION_EXISTS_GLIBC(tzset HAVE_TZSET)
1348 CHECK_FUNCTION_EXISTS_GLIBC(unsetenv HAVE_UNSETENV)
1349 CHECK_FUNCTION_EXISTS_GLIBC(utime HAVE_UTIME)
1350 CHECK_FUNCTION_EXISTS_GLIBC(utimes HAVE_UTIMES)
1351 CHECK_FUNCTION_EXISTS_GLIBC(utimensat HAVE_UTIMENSAT)
1352 CHECK_FUNCTION_EXISTS_GLIBC(vfork HAVE_VFORK)
1353 CHECK_FUNCTION_EXISTS_GLIBC(wcrtomb HAVE_WCRTOMB)
1354 CHECK_FUNCTION_EXISTS_GLIBC(wcscmp HAVE_WCSCMP)
1355 CHECK_FUNCTION_EXISTS_GLIBC(wcscpy HAVE_WCSCPY)
1356 CHECK_FUNCTION_EXISTS_GLIBC(wcslen HAVE_WCSLEN)
1357 CHECK_FUNCTION_EXISTS_GLIBC(wctomb HAVE_WCTOMB)
1358 CHECK_FUNCTION_EXISTS_GLIBC(_ctime64_s HAVE__CTIME64_S)
1359 CHECK_FUNCTION_EXISTS_GLIBC(_fseeki64 HAVE__FSEEKI64)
1360 CHECK_FUNCTION_EXISTS_GLIBC(_get_timezone HAVE__GET_TIMEZONE)
1361 CHECK_FUNCTION_EXISTS_GLIBC(_localtime64_s HAVE__LOCALTIME64_S)
1362 CHECK_FUNCTION_EXISTS_GLIBC(_mkgmtime64 HAVE__MKGMTIME64)
1363
1364 SET(CMAKE_REQUIRED_LIBRARIES "")
1365 CHECK_FUNCTION_EXISTS(cygwin_conv_path HAVE_CYGWIN_CONV_PATH)
1366 CHECK_FUNCTION_EXISTS(fseeko HAVE_FSEEKO)
1367 CHECK_FUNCTION_EXISTS(strerror_r HAVE_STRERROR_R)
1368 CHECK_FUNCTION_EXISTS(strftime HAVE_STRFTIME)
1369 CHECK_FUNCTION_EXISTS(vprintf HAVE_VPRINTF)
1370 CHECK_FUNCTION_EXISTS(wmemcmp HAVE_WMEMCMP)
1371 CHECK_FUNCTION_EXISTS(wmemcpy HAVE_WMEMCPY)
1372 CHECK_FUNCTION_EXISTS(wmemmove HAVE_WMEMMOVE)
1373
1374 CMAKE_POP_CHECK_STATE() # Restore the state of the variables
1375
1376 CHECK_C_SOURCE_COMPILES(
1377   "#include <sys/types.h>\n#include <sys/mount.h>\nint main(void) { struct vfsconf v; return sizeof(v);}"
1378   HAVE_STRUCT_VFSCONF)
1379
1380 CHECK_C_SOURCE_COMPILES(
1381   "#include <sys/types.h>\n#include <sys/mount.h>\nint main(void) { struct xvfsconf v; return sizeof(v);}"
1382   HAVE_STRUCT_XVFSCONF)
1383
1384 # Make sure we have the POSIX version of readdir_r, not the
1385 # older 2-argument version.
1386 CHECK_C_SOURCE_COMPILES(
1387   "#include <dirent.h>\nint main() {DIR *d = opendir(\".\"); struct dirent e,*r; return readdir_r(d,&e,&r);}"
1388   HAVE_READDIR_R)
1389
1390 # dirfd can be either a function or a macro.
1391 CHECK_C_SOURCE_COMPILES(
1392   "#include <dirent.h>\nint main() {DIR *d = opendir(\".\"); return dirfd(d);}"
1393   HAVE_DIRFD)
1394
1395 # Only detect readlinkat() if we also have AT_FDCWD in unistd.h.
1396 # NOTE: linux requires fcntl.h for AT_FDCWD.
1397 CHECK_C_SOURCE_COMPILES(
1398   "#include <fcntl.h>\n#include <unistd.h>\nint main() {char buf[10]; return readlinkat(AT_FDCWD, \"\", buf, 0);}"
1399   HAVE_READLINKAT)
1400
1401
1402 # To verify major(), we need to both include the header
1403 # of interest and verify that the result can be linked.
1404 # CHECK_FUNCTION_EXISTS doesn't accept a header argument,
1405 # CHECK_SYMBOL_EXISTS doesn't test linkage.
1406 CHECK_C_SOURCE_COMPILES(
1407   "#include <sys/mkdev.h>\nint main() { return major(256); }"
1408   MAJOR_IN_MKDEV)
1409 CHECK_C_SOURCE_COMPILES(
1410   "#include <sys/sysmacros.h>\nint main() { return major(256); }"
1411   MAJOR_IN_SYSMACROS)
1412
1413 CHECK_C_SOURCE_COMPILES(
1414   "#include <lzma.h>\n#if LZMA_VERSION < 50020000\n#error unsupported\n#endif\nint main(void){lzma_stream_encoder_mt(0, 0); return 0;}"
1415   HAVE_LZMA_STREAM_ENCODER_MT)
1416
1417 IF(HAVE_STRERROR_R)
1418   SET(HAVE_DECL_STRERROR_R 1)
1419 ENDIF(HAVE_STRERROR_R)
1420
1421 #
1422 # Check defines
1423 #
1424 SET(headers "limits.h")
1425 IF(HAVE_STDINT_H)
1426   LIST(APPEND headers "stdint.h")
1427 ENDIF(HAVE_STDINT_H)
1428 IF(HAVE_INTTYPES_H)
1429   LIST(APPEND headers "inttypes.h")
1430 ENDIF(HAVE_INTTYPES_H)
1431 CHECK_SYMBOL_EXISTS(EFTYPE           "errno.h"    HAVE_EFTYPE)
1432 CHECK_SYMBOL_EXISTS(EILSEQ           "errno.h"    HAVE_EILSEQ)
1433 CHECK_SYMBOL_EXISTS(D_MD_ORDER       "langinfo.h" HAVE_D_MD_ORDER)
1434 CHECK_SYMBOL_EXISTS(INT32_MAX        "${headers}" HAVE_DECL_INT32_MAX)
1435 CHECK_SYMBOL_EXISTS(INT32_MIN        "${headers}" HAVE_DECL_INT32_MIN)
1436 CHECK_SYMBOL_EXISTS(INT64_MAX        "${headers}" HAVE_DECL_INT64_MAX)
1437 CHECK_SYMBOL_EXISTS(INT64_MIN        "${headers}" HAVE_DECL_INT64_MIN)
1438 CHECK_SYMBOL_EXISTS(INTMAX_MAX       "${headers}" HAVE_DECL_INTMAX_MAX)
1439 CHECK_SYMBOL_EXISTS(INTMAX_MIN       "${headers}" HAVE_DECL_INTMAX_MIN)
1440 CHECK_SYMBOL_EXISTS(UINT32_MAX       "${headers}" HAVE_DECL_UINT32_MAX)
1441 CHECK_SYMBOL_EXISTS(UINT64_MAX       "${headers}" HAVE_DECL_UINT64_MAX)
1442 CHECK_SYMBOL_EXISTS(UINTMAX_MAX      "${headers}" HAVE_DECL_UINTMAX_MAX)
1443 CHECK_SYMBOL_EXISTS(SIZE_MAX         "${headers}" HAVE_DECL_SIZE_MAX)
1444 CHECK_SYMBOL_EXISTS(SSIZE_MAX        "limits.h"   HAVE_DECL_SSIZE_MAX)
1445
1446 #
1447 # Check struct members
1448 #
1449 # Check for tm_gmtoff in struct tm
1450 CHECK_STRUCT_HAS_MEMBER("struct tm" tm_gmtoff
1451     "time.h" HAVE_STRUCT_TM_TM_GMTOFF)
1452 CHECK_STRUCT_HAS_MEMBER("struct tm" __tm_gmtoff
1453     "time.h" HAVE_STRUCT_TM___TM_GMTOFF)
1454
1455 # Check for f_namemax in struct statfs
1456 CHECK_STRUCT_HAS_MEMBER("struct statfs" f_namemax
1457     "sys/param.h;sys/mount.h" HAVE_STRUCT_STATFS_F_NAMEMAX)
1458
1459 # Check for birthtime in struct stat
1460 CHECK_STRUCT_HAS_MEMBER("struct stat" st_birthtime
1461     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BIRTHTIME)
1462
1463 # Check for high-resolution timestamps in struct stat
1464 CHECK_STRUCT_HAS_MEMBER("struct stat" st_birthtimespec.tv_nsec
1465     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BIRTHTIMESPEC_TV_NSEC)
1466 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
1467     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
1468 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
1469     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
1470 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_n
1471     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIME_N)
1472 CHECK_STRUCT_HAS_MEMBER("struct stat" st_umtime
1473     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_UMTIME)
1474 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_usec
1475     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIME_USEC)
1476 # Check for block size support in struct stat
1477 CHECK_STRUCT_HAS_MEMBER("struct stat" st_blksize
1478     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BLKSIZE)
1479 # Check for st_flags in struct stat (BSD fflags)
1480 CHECK_STRUCT_HAS_MEMBER("struct stat" st_flags
1481     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_FLAGS)
1482
1483 IF(HAVE_SYS_STATVFS_H)
1484   CHECK_STRUCT_HAS_MEMBER("struct statvfs" f_iosize
1485     "sys/types.h;sys/statvfs.h" HAVE_STRUCT_STATVFS_F_IOSIZE)
1486 ENDIF()
1487
1488 #
1489 #
1490 CHECK_STRUCT_HAS_MEMBER("struct tm" tm_sec
1491     "sys/types.h;sys/time.h;time.h" TIME_WITH_SYS_TIME)
1492
1493 #
1494 # Check for integer types
1495 #
1496 #
1497 CHECK_TYPE_SIZE("short" SIZE_OF_SHORT)
1498 CHECK_TYPE_SIZE("int" SIZE_OF_INT)
1499 CHECK_TYPE_SIZE("long" SIZE_OF_LONG)
1500 CHECK_TYPE_SIZE("long long"     SIZE_OF_LONG_LONG)
1501
1502 CHECK_TYPE_SIZE("unsigned short" SIZE_OF_UNSIGNED_SHORT)
1503 CHECK_TYPE_SIZE("unsigned" SIZE_OF_UNSIGNED)
1504 CHECK_TYPE_SIZE("unsigned long" SIZE_OF_UNSIGNED_LONG)
1505 CHECK_TYPE_SIZE("unsigned long long" SIZE_OF_UNSIGNED_LONG_LONG)
1506
1507 CHECK_TYPE_SIZE("__int64" __INT64)
1508 CHECK_TYPE_SIZE("unsigned __int64" UNSIGNED___INT64)
1509
1510 CHECK_TYPE_SIZE(int16_t INT16_T)
1511 CHECK_TYPE_SIZE(int32_t INT32_T)
1512 CHECK_TYPE_SIZE(int64_t INT64_T)
1513 CHECK_TYPE_SIZE(intmax_t INTMAX_T)
1514 CHECK_TYPE_SIZE(uint8_t UINT8_T)
1515 CHECK_TYPE_SIZE(uint16_t UINT16_T)
1516 CHECK_TYPE_SIZE(uint32_t UINT32_T)
1517 CHECK_TYPE_SIZE(uint64_t UINT64_T)
1518 CHECK_TYPE_SIZE(uintmax_t UINTMAX_T)
1519
1520 CHECK_TYPE_SIZE(dev_t       DEV_T)
1521 IF(NOT HAVE_DEV_T)
1522   IF(MSVC)
1523     SET(dev_t "unsigned int")
1524   ENDIF(MSVC)
1525 ENDIF(NOT HAVE_DEV_T)
1526 #
1527 CHECK_TYPE_SIZE(gid_t       GID_T)
1528 IF(NOT HAVE_GID_T)
1529   IF(WIN32)
1530     SET(gid_t "short")
1531   ELSE(WIN32)
1532     SET(gid_t "unsigned int")
1533   ENDIF(WIN32)
1534 ENDIF(NOT HAVE_GID_T)
1535 #
1536 CHECK_TYPE_SIZE(id_t        ID_T)
1537 IF(NOT HAVE_ID_T)
1538   IF(WIN32)
1539     SET(id_t "short")
1540   ELSE(WIN32)
1541     SET(id_t "unsigned int")
1542   ENDIF(WIN32)
1543 ENDIF(NOT HAVE_ID_T)
1544 #
1545 CHECK_TYPE_SIZE(mode_t      MODE_T)
1546 IF(NOT HAVE_MODE_T)
1547   IF(WIN32)
1548     SET(mode_t "unsigned short")
1549   ELSE(WIN32)
1550     SET(mode_t "int")
1551   ENDIF(WIN32)
1552 ENDIF(NOT HAVE_MODE_T)
1553 #
1554 CHECK_TYPE_SIZE(off_t       OFF_T)
1555 IF(NOT HAVE_OFF_T)
1556   SET(off_t "__int64")
1557 ENDIF(NOT HAVE_OFF_T)
1558 #
1559 CHECK_TYPE_SIZE(size_t      SIZE_T)
1560 IF(NOT HAVE_SIZE_T)
1561   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1562     SET(size_t "uint64_t")
1563   ELSE("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1564     SET(size_t   "uint32_t")
1565   ENDIF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1566 ENDIF(NOT HAVE_SIZE_T)
1567 #
1568 CHECK_TYPE_SIZE(ssize_t     SSIZE_T)
1569 IF(NOT HAVE_SSIZE_T)
1570   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1571     SET(ssize_t "int64_t")
1572   ELSE("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1573     SET(ssize_t "long")
1574   ENDIF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1575 ENDIF(NOT HAVE_SSIZE_T)
1576 #
1577 CHECK_TYPE_SIZE(uid_t       UID_T)
1578 IF(NOT HAVE_UID_T)
1579   IF(WIN32)
1580     SET(uid_t "short")
1581   ELSE(WIN32)
1582     SET(uid_t "unsigned int")
1583   ENDIF(WIN32)
1584 ENDIF(NOT HAVE_UID_T)
1585 #
1586 CHECK_TYPE_SIZE(pid_t       PID_T)
1587 IF(NOT HAVE_PID_T)
1588   IF(WIN32)
1589     SET(pid_t "int")
1590   ELSE(WIN32)
1591     MESSAGE(FATAL_ERROR "pid_t doesn't exist on this platform?")
1592   ENDIF(WIN32)
1593 ENDIF(NOT HAVE_PID_T)
1594 #
1595 CHECK_TYPE_SIZE(intptr_t   INTPTR_T)
1596 IF(NOT HAVE_INTPTR_T)
1597   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1598     SET(intptr_t "int64_t")
1599   ELSE()
1600     SET(intptr_t "int32_t")
1601   ENDIF()
1602 ENDIF(NOT HAVE_INTPTR_T)
1603 #
1604 CHECK_TYPE_SIZE(uintptr_t   UINTPTR_T)
1605 IF(NOT HAVE_UINTPTR_T)
1606   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1607     SET(uintptr_t "uint64_t")
1608   ELSE()
1609     SET(uintptr_t "uint32_t")
1610   ENDIF()
1611 ENDIF(NOT HAVE_UINTPTR_T)
1612 #
1613 CHECK_TYPE_SIZE(wchar_t     SIZEOF_WCHAR_T)
1614 IF(HAVE_SIZEOF_WCHAR_T)
1615   SET(HAVE_WCHAR_T 1)
1616 ENDIF(HAVE_SIZEOF_WCHAR_T)
1617 #
1618 # Check if _FILE_OFFSET_BITS macro needed for large files
1619 #
1620 CHECK_FILE_OFFSET_BITS()
1621
1622 #
1623 # Check for Extended Attribute libraries, headers, and functions
1624 #
1625 IF(ENABLE_XATTR)
1626   CHECK_LIBRARY_EXISTS(attr "setxattr" "" HAVE_LIBATTR)
1627   IF(HAVE_LIBATTR)
1628     SET(CMAKE_REQUIRED_LIBRARIES "attr")
1629   ELSE()
1630     CHECK_LIBRARY_EXISTS(gnu "setxattr" "" HAVE_LIBATTR_GNU)
1631     IF(HAVE_LIBATTR_GNU)
1632       SET(CMAKE_REQUIRED_LIBRARIES "gnu")
1633     ENDIF()
1634   ENDIF(HAVE_LIBATTR)
1635   CHECK_SYMBOL_EXISTS(EXTATTR_NAMESPACE_USER "sys/types.h;sys/extattr.h" HAVE_DECL_EXTATTR_NAMESPACE_USER)
1636   CHECK_SYMBOL_EXISTS(XATTR_NOFOLLOW "sys/xattr.h" HAVE_DECL_XATTR_NOFOLLOW)
1637   IF(HAVE_SYS_XATTR_H AND HAVE_DECL_XATTR_NOFOLLOW)
1638     CHECK_FUNCTION_EXISTS(fgetxattr HAVE_FGETXATTR)
1639     CHECK_FUNCTION_EXISTS(flistxattr HAVE_FLISTXATTR)
1640     CHECK_FUNCTION_EXISTS(fsetxattr HAVE_FSETXATTR)
1641     CHECK_FUNCTION_EXISTS(getxattr HAVE_GETXATTR)
1642     CHECK_FUNCTION_EXISTS(listxattr HAVE_LISTXATTR)
1643     CHECK_FUNCTION_EXISTS(setxattr HAVE_SETXATTR)
1644     IF(HAVE_FGETXATTR AND
1645        HAVE_FLISTXATTR AND
1646        HAVE_FSETXATTR AND
1647        HAVE_GETXATTR AND
1648        HAVE_LISTXATTR AND
1649        HAVE_SETXATTR)
1650       SET(ARCHIVE_XATTR_DARWIN TRUE)
1651     ENDIF()
1652   ELSEIF(HAVE_SYS_EXTATTR_H AND HAVE_DECL_EXTATTR_NAMESPACE_USER)
1653     # FreeBSD xattr support
1654     CHECK_FUNCTION_EXISTS(extattr_get_fd HAVE_EXTATTR_GET_FD)
1655     CHECK_FUNCTION_EXISTS(extattr_get_file HAVE_EXTATTR_GET_FILE)
1656     CHECK_FUNCTION_EXISTS(extattr_get_link HAVE_EXTATTR_GET_LINK)
1657     CHECK_FUNCTION_EXISTS(extattr_list_fd HAVE_EXTATTR_LIST_FD)
1658     CHECK_FUNCTION_EXISTS(extattr_list_file HAVE_EXTATTR_LIST_FILE)
1659     CHECK_FUNCTION_EXISTS(extattr_list_link HAVE_EXTATTR_LIST_LINK)
1660     CHECK_FUNCTION_EXISTS(extattr_set_fd HAVE_EXTATTR_SET_FD)
1661     CHECK_FUNCTION_EXISTS(extattr_set_link HAVE_EXTATTR_SET_LINK)
1662     IF(HAVE_EXTATTR_GET_FD AND
1663        HAVE_EXTATTR_GET_FILE AND
1664        HAVE_EXTATTR_GET_LINK AND
1665        HAVE_EXTATTR_LIST_FD AND
1666        HAVE_EXTATTR_LIST_FILE AND
1667        HAVE_EXTATTR_LIST_LINK AND
1668        HAVE_EXTATTR_SET_FD AND
1669        HAVE_EXTATTR_SET_LINK)
1670       SET(ARCHIVE_XATTR_FREEBSD TRUE)
1671     ENDIF()
1672   ELSEIF(HAVE_SYS_XATTR_H OR HAVE_ATTR_XATTR_H)
1673     # Linux xattr support
1674     CHECK_FUNCTION_EXISTS_GLIBC(fgetxattr HAVE_FGETXATTR)
1675     CHECK_FUNCTION_EXISTS_GLIBC(flistxattr HAVE_FLISTXATTR)
1676     CHECK_FUNCTION_EXISTS_GLIBC(fsetxattr HAVE_FSETXATTR)
1677     CHECK_FUNCTION_EXISTS_GLIBC(getxattr HAVE_GETXATTR)
1678     CHECK_FUNCTION_EXISTS_GLIBC(lgetxattr HAVE_LGETXATTR)
1679     CHECK_FUNCTION_EXISTS_GLIBC(listxattr HAVE_LISTXATTR)
1680     CHECK_FUNCTION_EXISTS_GLIBC(llistxattr HAVE_LLISTXATTR)
1681     CHECK_FUNCTION_EXISTS_GLIBC(lsetxattr HAVE_LSETXATTR)
1682     IF(HAVE_FGETXATTR AND
1683        HAVE_FLISTXATTR AND
1684        HAVE_FSETXATTR AND
1685        HAVE_GETXATTR AND
1686        HAVE_LGETXATTR AND
1687        HAVE_LISTXATTR AND
1688        HAVE_LLISTXATTR AND
1689        HAVE_LSETXATTR)
1690       SET(ARCHIVE_XATTR_LINUX TRUE)
1691     ENDIF()
1692   ELSEIF(HAVE_SYS_EA_H)
1693     # AIX xattr support
1694     CHECK_FUNCTION_EXISTS(fgetea HAVE_FGETEA)
1695     CHECK_FUNCTION_EXISTS(flistea HAVE_FLISTEA)
1696     CHECK_FUNCTION_EXISTS(fsetea HAVE_FSETEA)
1697     CHECK_FUNCTION_EXISTS(getea HAVE_GETEA)
1698     CHECK_FUNCTION_EXISTS(lgetea HAVE_LGETEA)
1699     CHECK_FUNCTION_EXISTS(listea HAVE_LISTEA)
1700     CHECK_FUNCTION_EXISTS(llistea HAVE_LLISTEA)
1701     CHECK_FUNCTION_EXISTS(lsetea HAVE_LSETEA)
1702     IF(HAVE_FGETEA AND
1703        HAVE_FLISTEA AND
1704        HAVE_FSETEA AND
1705        HAVE_GETEA AND
1706        HAVE_LGETEA AND
1707        HAVE_LISTEA AND
1708        HAVE_LLISTEA AND
1709        HAVE_LSETEA)
1710       SET(ARCHIVE_XATTR_AIX TRUE)
1711     ENDIF()
1712   ENDIF()
1713
1714   IF(ARCHIVE_XATTR_DARWIN)
1715     MESSAGE(STATUS "Extended attributes support: Darwin")
1716   ELSEIF(ARCHIVE_XATTR_FREEBSD)
1717     MESSAGE(STATUS "Extended attributes support: FreeBSD")
1718   ELSEIF(ARCHIVE_XATTR_LINUX)
1719     MESSAGE(STATUS "Extended attributes support: Linux")
1720   ELSEIF(ARCHIVE_XATTR_AIX)
1721     MESSAGE(STATUS "Extended attributes support: AIX")
1722   ELSE()
1723     MESSAGE(STATUS "Extended attributes support: none")
1724   ENDIF()
1725 ELSE(ENABLE_XATTR)
1726   SET(ARCHIVE_XATTR_DARWIN FALSE)
1727   SET(ARCHIVE_XATTR_FREEBSD FALSE)
1728   SET(ARCHIVE_XATTR_LINUX FALSE)
1729   SET(ARCHIVE_XATTR_AIX FALSE)
1730 ENDIF(ENABLE_XATTR)
1731
1732 #
1733 # Check for ACL libraries, headers, and functions
1734 #
1735 # The ACL support in libarchive is written against the POSIX1e draft,
1736 # which was never officially approved and varies quite a bit across
1737 # platforms.  Worse, some systems have completely non-POSIX acl functions,
1738 # which makes the following checks rather more complex than I would like.
1739 #
1740 IF(ENABLE_ACL)
1741   # Solaris and derivates ACLs
1742   CHECK_FUNCTION_EXISTS(acl HAVE_ACL)
1743   CHECK_FUNCTION_EXISTS(facl HAVE_FACL)
1744
1745   # Libacl
1746   CHECK_LIBRARY_EXISTS(acl "acl_get_file" "" HAVE_LIBACL)
1747   IF(HAVE_LIBACL)
1748     SET(CMAKE_REQUIRED_LIBRARIES "acl")
1749     FIND_LIBRARY(ACL_LIBRARY NAMES acl)
1750     LIST(APPEND ADDITIONAL_LIBS ${ACL_LIBRARY})
1751   ENDIF(HAVE_LIBACL)
1752
1753   CHECK_TYPE_EXISTS(acl_t "sys/types.h;sys/acl.h" HAVE_ACL_T)
1754   CHECK_TYPE_EXISTS(acl_entry_t "sys/types.h;sys/acl.h" HAVE_ACL_ENTRY_T)
1755   CHECK_TYPE_EXISTS(acl_permset_t "sys/types.h;sys/acl.h" HAVE_ACL_PERMSET_T)
1756   CHECK_TYPE_EXISTS(acl_tag_t "sys/types.h;sys/acl.h" HAVE_ACL_TAG_T)
1757
1758   IF(HAVE_ACL AND HAVE_FACL)
1759     CHECK_TYPE_EXISTS(aclent_t "sys/acl.h" HAVE_ACLENT_T)
1760     IF(HAVE_ACLENT_T)
1761       CHECK_SYMBOL_EXISTS(GETACL "sys/acl.h" HAVE_DECL_GETACL)
1762       CHECK_SYMBOL_EXISTS(GETACLCNT "sys/acl.h" HAVE_DECL_GETACLCNT)
1763       CHECK_SYMBOL_EXISTS(SETACL "sys/acl.h" HAVE_DECL_SETACL)
1764       IF(HAVE_DECL_GETACL AND
1765          HAVE_DECL_GETACLCNT AND
1766          HAVE_DECL_SETACL)
1767         SET(ARCHIVE_ACL_SUNOS TRUE)
1768       ENDIF()
1769       CHECK_TYPE_EXISTS(ace_t "sys/acl.h" HAVE_ACE_T)
1770       IF(HAVE_ACE_T)
1771         CHECK_SYMBOL_EXISTS(ACE_GETACL "sys/acl.h" HAVE_DECL_ACE_GETACL)
1772         CHECK_SYMBOL_EXISTS(ACE_GETACLCNT "sys/acl.h" HAVE_DECL_ACE_GETACLCNT)
1773         CHECK_SYMBOL_EXISTS(ACE_SETACL "sys/acl.h" HAVE_DECL_ACE_SETACL)
1774         IF(HAVE_DECL_ACE_GETACL AND
1775            HAVE_DECL_ACE_GETACLCNT AND
1776            HAVE_DECL_ACE_SETACL)
1777           SET(ARCHIVE_ACL_SUNOS_NFS4 TRUE)
1778         ENDIF()
1779       ENDIF(HAVE_ACE_T)
1780     ENDIF(HAVE_ACLENT_T)
1781   ENDIF(HAVE_ACL AND HAVE_FACL)
1782
1783   IF(HAVE_ACL_T AND HAVE_ACL_ENTRY_T AND HAVE_ACL_PERMSET_T AND HAVE_ACL_TAG_T)
1784     CHECK_FUNCTION_EXISTS_GLIBC(acl_add_perm HAVE_ACL_ADD_PERM)
1785     CHECK_FUNCTION_EXISTS_GLIBC(acl_clear_perms HAVE_ACL_CLEAR_PERMS)
1786     CHECK_FUNCTION_EXISTS_GLIBC(acl_create_entry HAVE_ACL_CREATE_ENTRY)
1787     CHECK_FUNCTION_EXISTS_GLIBC(acl_delete_def_file HAVE_ACL_DELETE_DEF_FILE)
1788     CHECK_FUNCTION_EXISTS_GLIBC(acl_free HAVE_ACL_FREE)
1789     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_entry HAVE_ACL_GET_ENTRY)
1790     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_fd HAVE_ACL_GET_FD)
1791     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_file HAVE_ACL_GET_FILE)
1792     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_permset HAVE_ACL_GET_PERMSET)
1793     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_qualifier HAVE_ACL_GET_QUALIFIER)
1794     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_tag_type HAVE_ACL_GET_TAG_TYPE)
1795     CHECK_FUNCTION_EXISTS_GLIBC(acl_init HAVE_ACL_INIT)
1796     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_fd HAVE_ACL_SET_FD)
1797     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_file HAVE_ACL_SET_FILE)
1798     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_qualifier HAVE_ACL_SET_QUALIFIER)
1799     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_tag_type HAVE_ACL_SET_TAG_TYPE)
1800     IF(HAVE_ACL_ADD_PERM AND
1801        HAVE_ACL_CLEAR_PERMS AND
1802        HAVE_ACL_CREATE_ENTRY AND
1803        HAVE_ACL_DELETE_DEF_FILE AND
1804        HAVE_ACL_FREE AND
1805        HAVE_ACL_GET_ENTRY AND
1806        HAVE_ACL_GET_FD AND
1807        HAVE_ACL_GET_FILE AND
1808        HAVE_ACL_GET_PERMSET AND
1809        HAVE_ACL_GET_QUALIFIER AND
1810        HAVE_ACL_GET_TAG_TYPE AND
1811        HAVE_ACL_INIT AND
1812        HAVE_ACL_SET_FD AND
1813        HAVE_ACL_SET_FILE AND
1814        HAVE_ACL_SET_QUALIFIER AND
1815        HAVE_ACL_SET_TAG_TYPE)
1816          SET(HAVE_POSIX_ACL_FUNCS 1)
1817     ENDIF()
1818
1819     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_perm HAVE_ACL_GET_PERM)
1820
1821     IF(HAVE_POSIX_ACL_FUNCS AND HAVE_ACL_LIBACL_H AND HAVE_LIBACL AND
1822        HAVE_ACL_GET_PERM)
1823       SET(ARCHIVE_ACL_LIBACL TRUE)
1824     ELSE()
1825       CHECK_FUNCTION_EXISTS(acl_add_flag_np HAVE_ACL_ADD_FLAG_NP)
1826       CHECK_FUNCTION_EXISTS(acl_clear_flags_np HAVE_ACL_CLEAR_FLAGS_NP)
1827       CHECK_FUNCTION_EXISTS(acl_get_brand_np HAVE_ACL_GET_BRAND_NP)
1828       CHECK_FUNCTION_EXISTS(acl_get_entry_type_np HAVE_ACL_GET_ENTRY_TYPE_NP)
1829       CHECK_FUNCTION_EXISTS(acl_get_flag_np HAVE_ACL_GET_FLAG_NP)
1830       CHECK_FUNCTION_EXISTS(acl_get_flagset_np HAVE_ACL_GET_FLAGSET_NP)
1831       CHECK_FUNCTION_EXISTS(acl_get_fd_np HAVE_ACL_GET_FD_NP)
1832       CHECK_FUNCTION_EXISTS(acl_get_link_np HAVE_ACL_GET_LINK_NP)
1833       CHECK_FUNCTION_EXISTS(acl_get_perm_np HAVE_ACL_GET_PERM_NP)
1834       CHECK_FUNCTION_EXISTS(acl_is_trivial_np HAVE_ACL_IS_TRIVIAL_NP)
1835       CHECK_FUNCTION_EXISTS(acl_set_entry_type_np HAVE_ACL_SET_ENTRY_TYPE_NP)
1836       CHECK_FUNCTION_EXISTS(acl_set_fd_np HAVE_ACL_SET_FD_NP)
1837       CHECK_FUNCTION_EXISTS(acl_set_link_np HAVE_ACL_SET_LINK_NP)
1838       CHECK_FUNCTION_EXISTS(mbr_gid_to_uuid HAVE_MBR_GID_TO_UUID)
1839       CHECK_FUNCTION_EXISTS(mbr_uid_to_uuid HAVE_MBR_UID_TO_UUID)
1840       CHECK_FUNCTION_EXISTS(mbr_uuid_to_id HAVE_MBR_UUID_TO_ID)
1841
1842       CHECK_C_SOURCE_COMPILES("#include <sys/types.h>
1843 #include <sys/acl.h>
1844 int main(void) { return ACL_TYPE_EXTENDED; }" HAVE_DECL_ACL_TYPE_EXTENDED)
1845       CHECK_C_SOURCE_COMPILES("#include <sys/types.h>
1846 #include <sys/acl.h>
1847 int main(void) { return ACL_SYNCHRONIZE; }" HAVE_DECL_ACL_SYNCHRONIZE)
1848       CHECK_SYMBOL_EXISTS(ACL_TYPE_NFS4 "sys/acl.h" HAVE_DECL_ACL_TYPE_NFS4)
1849       CHECK_SYMBOL_EXISTS(ACL_USER "sys/acl.h" HAVE_DECL_ACL_USER)
1850
1851       IF(HAVE_POSIX_ACL_FUNCS AND
1852          HAVE_ACL_GET_FD_NP AND
1853          HAVE_ACL_GET_PERM_NP AND
1854          NOT HAVE_ACL_GET_PERM AND
1855          HAVE_ACL_SET_FD_NP)
1856         IF(HAVE_DECL_ACL_USER)
1857           SET(ARCHIVE_ACL_FREEBSD TRUE)
1858           IF(HAVE_DECL_ACL_TYPE_NFS4 AND
1859              HAVE_ACL_ADD_FLAG_NP AND
1860              HAVE_ACL_CLEAR_FLAGS_NP AND
1861              HAVE_ACL_GET_BRAND_NP AND
1862              HAVE_ACL_GET_ENTRY_TYPE_NP AND
1863              HAVE_ACL_GET_FLAGSET_NP AND
1864              HAVE_ACL_SET_ENTRY_TYPE_NP)
1865             SET(ARCHIVE_ACL_FREEBSD_NFS4 TRUE)
1866           ENDIF()
1867         ELSEIF(HAVE_DECL_ACL_TYPE_EXTENDED AND
1868                HAVE_MEMBERSHIP_H AND
1869                HAVE_ACL_ADD_FLAG_NP AND
1870                HAVE_ACL_CLEAR_FLAGS_NP AND
1871                HAVE_ACL_GET_FLAGSET_NP AND
1872                HAVE_ACL_GET_LINK_NP AND
1873                HAVE_ACL_SET_LINK_NP AND
1874                HAVE_MBR_UID_TO_UUID AND
1875                HAVE_MBR_GID_TO_UUID AND
1876                HAVE_MBR_UUID_TO_ID)
1877           SET(ARCHIVE_ACL_DARWIN TRUE)
1878         ENDIF()
1879       ENDIF()
1880     ENDIF()
1881   ENDIF(HAVE_ACL_T AND HAVE_ACL_ENTRY_T AND HAVE_ACL_PERMSET_T AND
1882         HAVE_ACL_TAG_T)
1883
1884   # Richacl
1885   CHECK_LIBRARY_EXISTS(richacl "richacl_get_file" "" HAVE_LIBRICHACL)
1886   IF(HAVE_LIBRICHACL)
1887     SET(CMAKE_REQUIRED_LIBRARIES "richacl")
1888     FIND_LIBRARY(RICHACL_LIBRARY NAMES richacl)
1889     LIST(APPEND ADDITIONAL_LIBS ${RICHACL_LIBRARY})
1890   ENDIF(HAVE_LIBRICHACL)
1891
1892   CHECK_STRUCT_HAS_MEMBER("struct richace" e_type "sys/richacl.h"
1893     HAVE_STRUCT_RICHACE)
1894   CHECK_STRUCT_HAS_MEMBER("struct richacl" a_flags "sys/richacl.h"
1895     HAVE_STRUCT_RICHACL)
1896
1897   IF(HAVE_LIBRICHACL AND HAVE_STRUCT_RICHACL AND HAVE_STRUCT_RICHACE)
1898     CHECK_FUNCTION_EXISTS_GLIBC(richacl_alloc HAVE_RICHACL_ALLOC)
1899     CHECK_FUNCTION_EXISTS_GLIBC(richacl_equiv_mode HAVE_RICHACL_EQUIV_MODE)
1900     CHECK_FUNCTION_EXISTS_GLIBC(richacl_free HAVE_RICHACL_FREE)
1901     CHECK_FUNCTION_EXISTS_GLIBC(richacl_get_fd HAVE_RICHACL_GET_FD)
1902     CHECK_FUNCTION_EXISTS_GLIBC(richacl_get_file HAVE_RICHACL_GET_FILE)
1903     CHECK_FUNCTION_EXISTS_GLIBC(richacl_set_fd HAVE_RICHACL_SET_FD)
1904     CHECK_FUNCTION_EXISTS_GLIBC(richacl_set_file HAVE_RICHACL_SET_FILE)
1905     IF(HAVE_RICHACL_ALLOC AND
1906        HAVE_RICHACL_EQUIV_MODE AND
1907        HAVE_RICHACL_FREE AND
1908        HAVE_RICHACL_GET_FD AND
1909        HAVE_RICHACL_GET_FILE AND
1910        HAVE_RICHACL_SET_FD AND
1911        HAVE_RICHACL_SET_FILE)
1912       SET(ARCHIVE_ACL_LIBRICHACL TRUE)
1913     ENDIF()
1914   ENDIF(HAVE_LIBRICHACL AND HAVE_STRUCT_RICHACL AND HAVE_STRUCT_RICHACE)
1915
1916   IF(ARCHIVE_ACL_DARWIN)
1917     MESSAGE(STATUS "ACL support: Darwin (limited NFSv4)")
1918   ELSEIF(ARCHIVE_ACL_FREEBSD_NFS4)
1919     MESSAGE(STATUS "ACL support: FreeBSD (POSIX.1e and NFSv4)")
1920   ELSEIF(ARCHIVE_ACL_FREEBSD)
1921     MESSAGE(STATUS "ACL support: FreeBSD (POSIX.1e)")
1922   ELSEIF(ARCHIVE_ACL_LIBACL OR ARCHIVE_ACL_LIBRICHACL)
1923     IF(ARCHIVE_ACL_LIBACL AND ARCHIVE_ACL_LIBRICHACL)
1924       MESSAGE(STATUS "ACL support: libacl (POSIX.1e) + librichacl (NFSv4)")
1925     ELSEIF(ARCHIVE_ACL_LIBRICHACL)
1926       MESSAGE(STATUS "ACL support: librichacl (NFSv4)")
1927     ELSE()
1928       MESSAGE(STATUS "ACL support: libacl (POSIX.1e)")
1929     ENDIF()
1930   ELSEIF(ARCHIVE_ACL_SUNOS_NFS4)
1931     MESSAGE(STATUS "ACL support: Solaris (POSIX.1e and NFSv4)")
1932   ELSEIF(ARCHIVE_ACL_SUNOS)
1933     MESSAGE(STATUS "ACL support: Solaris (POSIX.1e)")
1934   ELSE()
1935     MESSAGE(STATUS "ACL support: none")
1936   ENDIF()
1937
1938 ELSE(ENABLE_ACL)
1939   # If someone runs cmake, then disables ACL support, we need
1940   # to forcibly override the cached values for these.
1941   SET(ARCHIVE_ACL_DARWIN FALSE)
1942   SET(ARCHIVE_ACL_FREEBSD FALSE)
1943   SET(ARCHIVE_ACL_FREEBSD_NFS4 FALSE)
1944   SET(ARCHIVE_ACL_LIBACL FALSE)
1945   SET(ARCHIVE_ACL_SUNOS FALSE)
1946   SET(ARCHIVE_ACL_SUNOS_NFS4 FALSE)
1947 ENDIF(ENABLE_ACL)
1948
1949 #
1950 # Check MD5/RMD160/SHA support
1951 # NOTE: Crypto checks must be run last before generating config.h
1952 #
1953 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" LIBC)
1954 CHECK_CRYPTO("SHA256;SHA384;SHA512" LIBC2)
1955 CHECK_CRYPTO("SHA256;SHA384;SHA512" LIBC3)
1956 CHECK_CRYPTO("MD5;SHA1;SHA256;SHA384;SHA512" LIBSYSTEM)
1957 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" NETTLE)
1958 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" OPENSSL)
1959
1960 # Libmd has to be probed after OpenSSL.
1961 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA512" LIBMD)
1962
1963 CHECK_CRYPTO_WIN("MD5;SHA1;SHA256;SHA384;SHA512")
1964
1965 # Generate "config.h" from "build/cmake/config.h.in"
1966 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
1967         ${CMAKE_CURRENT_BINARY_DIR}/config.h)
1968 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
1969 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
1970
1971 # Handle generation of the libarchive.pc file for pkg-config
1972 INCLUDE(CreatePkgConfigFile)
1973
1974 #
1975 # Register installation of PDF documents.
1976 #
1977 IF(WIN32 AND NOT CYGWIN)
1978   #
1979   # On Windows platform, It's better that we install PDF documents
1980   # on one's computer.
1981   # These PDF documents are available in the release package.
1982   #
1983   IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf)
1984     INSTALL(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf
1985             DESTINATION share/man
1986             FILES_MATCHING PATTERN "*.pdf"
1987     )
1988   ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf)
1989 ENDIF(WIN32 AND NOT CYGWIN)
1990 #
1991 #
1992 #
1993 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/libarchive)
1994 #
1995 IF(MSVC)
1996   ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
1997 ENDIF(MSVC)
1998
1999 IF(ENABLE_TEST)
2000   ADD_CUSTOM_TARGET(run_all_tests)
2001 ENDIF(ENABLE_TEST)
2002
2003 add_subdirectory(libarchive)
2004 add_subdirectory(cat)
2005 add_subdirectory(tar)
2006 add_subdirectory(cpio)