CMakeLists.txt

   1 #
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.12 FATAL_ERROR)
   3 #
   4 PROJECT(libarchive C)
   5 #
   6 SET(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/build/cmake")
   7 if(NOT CMAKE_RUNTIME_OUTPUT_DIRECTORY)
   8   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${libarchive_BINARY_DIR}/bin)
   9 endif()
  10 #
  11 # Set the Build type for make based generators.
  12 # You can choose following types:
  13 #   Debug          : Debug build
  14 #   Release        : Release build
  15 #   RelWithDebInfo : Release build with Debug Info
  16 #   MinSizeRel     : Release Min Size build
  17 IF(NOT CMAKE_BUILD_TYPE)
  18   SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build Type" FORCE)
  19 ENDIF(NOT CMAKE_BUILD_TYPE)
  20 # Set a value type to properly display CMAKE_BUILD_TYPE on GUI if the
  21 # value type is "UNINITIALIZED".
  22 GET_PROPERTY(cached_type CACHE CMAKE_BUILD_TYPE PROPERTY TYPE)
  23 IF("${cached_type}" STREQUAL "UNINITIALIZED")
  24   SET(CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING "Build Type" FORCE)
  25 ENDIF("${cached_type}" STREQUAL "UNINITIALIZED")
  26 # Check the Build Type.
  27 IF(NOT "${CMAKE_BUILD_TYPE}"
  28        MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)\$")
  29   MESSAGE(FATAL_ERROR
  30           "Unknown keyword for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}\n"
  31           "Acceptable keywords: Debug,Release,RelWithDebInfo,MinSizeRel")
  32 ENDIF(NOT "${CMAKE_BUILD_TYPE}"
  33           MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)\$")
  34
  35 # On MacOS, prefer MacPorts libraries to system libraries.
  36 # I haven't come up with a compelling argument for this to be conditional.
  37 list(APPEND CMAKE_PREFIX_PATH /opt/local)
  38 # Enable @rpath in the install name.
  39 # detail in "cmake  --help-policy CMP0042"
  40 SET(CMAKE_MACOSX_RPATH ON)
  41
  42 #
  43 # Version - read from 'version' file.
  44 #
  45 FILE(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/build/version _version)
  46 STRING(REGEX REPLACE
  47  "^([0-9])[0-9][0-9][0-9][0-9][0-9][0-9][a-z]*$" "\\1" _major ${_version})
  48 STRING(REGEX REPLACE
  49  "^[0-9]([0-9][0-9][0-9])[0-9][0-9][0-9][a-z]*$" "\\1" _minor ${_version})
  50 STRING(REGEX REPLACE
  51  "^[0-9][0-9][0-9][0-9]([0-9][0-9][0-9])[a-z]*$" "\\1" _revision ${_version})
  52 STRING(REGEX REPLACE
  53  "^[0-9][0-9][0-9][0-9][0-9][0-9][0-9]([a-z]*)$" "\\1" _quality ${_version})
  54 SET(_version_number ${_major}${_minor}${_revision})
  55 STRING(REGEX REPLACE "[0]*([^0]*[0-9])$" "\\1" _trimmed_minor ${_minor})
  56 STRING(REGEX REPLACE "[0]*([^0]*[0-9])$" "\\1" _trimmed_revision ${_revision})
  57 #
  58 SET(VERSION                    "${_major}.${_trimmed_minor}.${_trimmed_revision}${_quality}")
  59 SET(BSDCPIO_VERSION_STRING     "${VERSION}")
  60 SET(BSDTAR_VERSION_STRING      "${VERSION}")
  61 SET(BSDCAT_VERSION_STRING      "${VERSION}")
  62 SET(LIBARCHIVE_VERSION_NUMBER  "${_version_number}")
  63 SET(LIBARCHIVE_VERSION_STRING  "${VERSION}")
  64
  65 # INTERFACE_VERSION increments with every release
  66 # libarchive 2.7 == interface version 9 = 2 + 7
  67 # libarchive 2.8 == interface version 10 = 2 + 8
  68 # libarchive 2.9 == interface version 11 = 2 + 9
  69 # libarchive 3.0 == interface version 12
  70 # libarchive 3.1 == interface version 13
  71 math(EXPR INTERFACE_VERSION  "13 + ${_minor}")
  72
  73 # Set SOVERSION == Interface version
  74 # ?? Should there be more here ??
  75 SET(SOVERSION "${INTERFACE_VERSION}")
  76
  77 # Enalbe CMAKE_PUSH_CHECK_STATE() and CMAKE_POP_CHECK_STATE() macros
  78 # saving and restoring the state of the variables.
  79 INCLUDE(CMakePushCheckState)
  80
  81 # Initialize the state of the variables. This initialization is not
  82 # necessary but this shows you what value the variables initially have.
  83 SET(CMAKE_REQUIRED_DEFINITIONS)
  84 SET(CMAKE_REQUIRED_INCLUDES)
  85 SET(CMAKE_REQUIRED_LIBRARIES)
  86 SET(CMAKE_REQUIRED_FLAGS)
  87
  88 # Especially for early development, we want to be a little
  89 # aggressive about diagnosing build problems; this can get
  90 # relaxed somewhat in final shipping versions.
  91 IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$")
  92   SET(CMAKE_REQUIRED_FLAGS "-Wall -Wformat -Wformat-security")
  93   #################################################################
  94   # Set compile flags for all build types.
  95   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wformat -Wformat-security")
  96   #################################################################
  97   # Set compile flags for debug build.
  98   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
  99   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Werror")
 100   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wextra")
 101   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wunused")
 102   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wshadow")
 103   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wmissing-prototypes")
 104   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wcast-qual")
 105 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$")
 106 IF (CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 107   SET(CMAKE_REQUIRED_FLAGS "-Wall -Wformat -Wformat-security")
 108   #################################################################
 109   # Set compile flags for all build types.
 110   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wformat -Wformat-security")
 111   #################################################################
 112   # Set compile flags for debug build.
 113   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 114   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g")
 115   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Werror")
 116   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wextra")
 117   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wunused")
 118   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wshadow")
 119   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wmissing-prototypes")
 120   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wcast-qual")
 121 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 122 IF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 123   SET(CMAKE_C_COMPILER "xlc_r")
 124   SET(CMAKE_REQUIRED_FLAGS "-qflag=e:e -qformat=sec")
 125   #################################################################
 126   # Set compile flags for all build types.
 127   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -qflag=e:e -qformat=sec")
 128   #################################################################
 129   # Set compile flags for debug build.
 130   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 131   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g")
 132   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qhalt=w")
 133   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qflag=w:w")
 134   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qinfo=pro:use")
 135 ENDIF(CMAKE_C_COMPILER_ID MATCHES "^XL$")
 136 IF (MSVC)
 137   #################################################################
 138   # Set compile flags for debug build.
 139   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 140   # Enable level 4 C4061: The enumerate has no associated handler in a switch
 141   #                       statement.
 142   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4061")
 143   # Enable level 4 C4254: A larger bit field was assigned to a smaller bit
 144   #                       field.
 145   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4254")
 146   # Enable level 4 C4295: An array was initialized but the last character in
 147   #                       the array is not a null; accessing the array may
 148   #                       produce unexpected results.
 149   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4295")
 150   # Enable level 4 C4296: An unsigned variable was used in a comparison
 151   #                       operation with zero.
 152   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4296")
 153   # Enable level 4 C4389: An operation involved signed and unsigned variables.
 154   #                       This could result in a loss of data.
 155   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4389")
 156   # Enable level 4 C4505: The given function is local and not referenced in
 157   #                       the body of the module; therefore, the function is
 158   #                       dead code.
 159   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4505")
 160   # Enable level 4 C4514: The optimizer removed an inline function that is not
 161   #                       called.
 162   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4514")
 163   # Enable level 4 C4702: Unreachable code.
 164   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4702")
 165   # Enable level 4 C4706: The test value in a conditional expression was the
 166   #                       result of an assignment.
 167   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4706")
 168   # /WX option is the same as gcc's -Werror option.
 169   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /WX")
 170   # /Oi option enables built-in functions.
 171   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /Oi")
 172   #################################################################
 173   # Set compile flags for release build.
 174   SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /Oi")
 175 ENDIF (MSVC)
 176
 177 # Enable CTest/CDash support
 178 include(CTest)
 179
 180 OPTION(ENABLE_NETTLE "Enable use of Nettle" ON)
 181 OPTION(ENABLE_OPENSSL "Enable use of OpenSSL" ON)
 182 OPTION(ENABLE_LZO "Enable the use of the system LZO library if found" OFF)
 183 OPTION(ENABLE_LZMA "Enable the use of the system LZMA library if found" ON)
 184
 185 OPTION(ENABLE_ZLIB "Enable the use of the system ZLIB library if found" ON)
 186 OPTION(ENABLE_BZip2 "Enable the use of the system BZip2 library if found" ON)
 187 OPTION(ENABLE_LIBXML2 "Enable the use of the system libxml2 library if found" ON)
 188 OPTION(ENABLE_EXPAT "Enable the use of the system EXPAT library if found" ON)
 189 OPTION(ENABLE_PCREPOSIX "Enable the use of the system PCREPOSIX library if found" ON)
 190 OPTION(ENABLE_LibGCC "Enable the use of the system LibGCC library if found" ON)
 191 # CNG is used for encrypt/decrypt Zip archives on Windows.
 192 OPTION(ENABLE_CNG "Enable the use of CNG(Crypto Next Generation)" ON)
 193
 194 OPTION(ENABLE_TAR "Enable tar building" ON)
 195 OPTION(ENABLE_TAR_SHARED "Enable dynamic build of tar" FALSE)
 196 OPTION(ENABLE_CPIO "Enable cpio building" ON)
 197 OPTION(ENABLE_CPIO_SHARED "Enable dynamic build of cpio" FALSE)
 198 OPTION(ENABLE_CAT "Enable cat building" ON)
 199 OPTION(ENABLE_CAT_SHARED "Enable dynamic build of cat" FALSE)
 200 OPTION(ENABLE_XATTR "Enable extended attribute support" ON)
 201 OPTION(ENABLE_ACL "Enable ACL support" ON)
 202 OPTION(ENABLE_ICONV "Enable iconv support" ON)
 203 OPTION(ENABLE_TEST "Enable unit and regression tests" ON)
 204 OPTION(ENABLE_COVERAGE "Enable code coverage (GCC only, automatically sets ENABLE_TEST to ON)" FALSE)
 205 OPTION(ENABLE_INSTALL "Enable installing of libraries" ON)
 206
 207 SET(POSIX_REGEX_LIB "AUTO" CACHE STRING "Choose what library should provide POSIX regular expression support")
 208 SET(ENABLE_SAFESEH "AUTO" CACHE STRING "Enable use of /SAFESEH linker flag (MSVC only)")
 209 SET(WINDOWS_VERSION "WIN7" CACHE STRING "Set Windows version to use (Windows only)")
 210
 211 IF(ENABLE_COVERAGE)
 212         include(LibarchiveCodeCoverage)
 213 ENDIF(ENABLE_COVERAGE)
 214
 215 IF(ENABLE_TEST)
 216         ENABLE_TESTING()
 217 ENDIF(ENABLE_TEST)
 218
 219 IF(WIN32)
 220   IF(WINDOWS_VERSION STREQUAL "WIN8")
 221     SET(NTDDI_VERSION 0x06020000)
 222     SET(_WIN32_WINNT 0x0602)
 223     SET(WINVER 0x0602)
 224   ELSEIF(WINDOWS_VERSION STREQUAL "WIN7")
 225     SET(NTDDI_VERSION 0x06010000)
 226     SET(_WIN32_WINNT 0x0601)
 227     SET(WINVER 0x0601)
 228   ELSEIF(WINDOWS_VERSION STREQUAL "WS08")
 229     SET(NTDDI_VERSION 0x06000100)
 230     SET(_WIN32_WINNT 0x0600)
 231     SET(WINVER 0x0600)
 232   ELSEIF(WINDOWS_VERSION STREQUAL "VISTA")
 233     SET(NTDDI_VERSION 0x06000000)
 234     SET(_WIN32_WINNT 0x0600)
 235     SET(WINVER 0x0600)
 236   ELSEIF(WINDOWS_VERSION STREQUAL "WS03")
 237     SET(NTDDI_VERSION 0x05020000)
 238     SET(_WIN32_WINNT 0x0502)
 239     SET(WINVER 0x0502)
 240   ELSEIF(WINDOWS_VERSION STREQUAL "WINXP")
 241     SET(NTDDI_VERSION 0x05010000)
 242     SET(_WIN32_WINNT 0x0501)
 243     SET(WINVER 0x0501)
 244   ELSE(WINDOWS_VERSION STREQUAL "WIN8")
 245     # Default to Windows Server 2003 API if we don't recognize the specifier
 246     SET(NTDDI_VERSION 0x05020000)
 247     SET(_WIN32_WINNT 0x0502)
 248     SET(WINVER 0x0502)
 249   ENDIF(WINDOWS_VERSION STREQUAL "WIN8")
 250 ENDIF(WIN32)
 251
 252 IF(MSVC)
 253   IF(ENABLE_SAFESEH STREQUAL "YES")
 254     SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH")
 255     SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SAFESEH")
 256     SET(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /SAFESEH")
 257     SET(ENV{LDFLAGS} "$ENV{LDFLAGS} /SAFESEH")
 258   ELSEIF(ENABLE_SAFESEH STREQUAL "NO")
 259     SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH:NO")
 260     SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SAFESEH:NO")
 261     SET(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /SAFESEH:NO")
 262     SET(ENV{LDFLAGS} "$ENV{LDFLAGS} /SAFESEH:NO")
 263   ENDIF(ENABLE_SAFESEH STREQUAL "YES")
 264 ENDIF(MSVC)
 265
 266 IF("${CMAKE_C_PLATFORM_ID}" MATCHES "^(HP-UX)$")
 267   ADD_DEFINITIONS(-D_XOPEN_SOURCE=500) # Ask wchar.h for mbstate_t
 268 ENDIF()
 269
 270 #
 271 INCLUDE(CheckCSourceCompiles)
 272 INCLUDE(CheckCSourceRuns)
 273 INCLUDE(CheckFileOffsetBits)
 274 INCLUDE(CheckFuncs)
 275 INCLUDE(CheckHeaderDirent)
 276 INCLUDE(CheckIncludeFile)
 277 INCLUDE(CheckIncludeFiles)
 278 INCLUDE(CheckLibraryExists)
 279 INCLUDE(CheckStructHasMember)
 280 INCLUDE(CheckSymbolExists)
 281 INCLUDE(CheckTypeExists)
 282 INCLUDE(CheckTypeSize)
 283
 284 #
 285 # Generate list.h
 286 #
 287 MACRO (GENERATE_LIST_H _listfile _cmlist __list_sources)
 288   SET(_argv ${ARGV})
 289   # Remove _listfile and _cmlist from _argv
 290   LIST(REMOVE_AT _argv 0 1)
 291   IF (NOT EXISTS "${_listfile}" OR
 292      ${_cmlist} IS_NEWER_THAN "${_listfile}")
 293
 294     MESSAGE(STATUS "Generating ${_listfile}")
 295     FILE(WRITE ${_listfile} "")
 296     FOREACH (testfile ${_argv})
 297       IF (testfile MATCHES "^test_[^/]+[.]c$")
 298         FILE(STRINGS ${testfile} testvar REGEX "^DEFINE_TEST")
 299         FOREACH (deftest ${testvar})
 300           FILE(APPEND ${_listfile} "${deftest}\n")
 301         ENDFOREACH (deftest)
 302       ENDIF (testfile MATCHES "^test_[^/]+[.]c$")
 303     ENDFOREACH (testfile)
 304
 305   ENDIF (NOT EXISTS "${_listfile}" OR
 306      ${_cmlist} IS_NEWER_THAN "${_listfile}")
 307 ENDMACRO (GENERATE_LIST_H)
 308 #
 309 # Generate installation rules for man pages.
 310 #
 311 MACRO (INSTALL_MAN __mans)
 312   FOREACH (_man ${ARGV})
 313     STRING(REGEX REPLACE "^.+[.]([1-9])" "\\1" _mansect ${_man})
 314     INSTALL(FILES ${_man} DESTINATION "share/man/man${_mansect}")
 315   ENDFOREACH (_man)
 316 ENDMACRO (INSTALL_MAN __mans)
 317 #
 318 # Find out what macro is needed to use libraries on Windows.
 319 #
 320 MACRO (TRY_MACRO_FOR_LIBRARY INCLUDES LIBRARIES
 321        TRY_TYPE SAMPLE_SOURCE MACRO_LIST)
 322   IF(WIN32 AND NOT CYGWIN)
 323     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 324     SET(CMAKE_REQUIRED_INCLUDES ${INCLUDES})
 325     SET(CMAKE_REQUIRED_LIBRARIES ${LIBRARIES})
 326     FOREACH(VAR ${MACRO_LIST})
 327       # Clear ${VAR} from CACHE If the libraries which ${VAR} was
 328       # checked with are changed.
 329       SET(VAR_WITH_LIB "${VAR}_WITH_LIB")
 330       GET_PROPERTY(PREV_VAR_WITH_LIB VARIABLE PROPERTY ${VAR_WITH_LIB})
 331       IF(NOT "${PREV_VAR_WITH_LIB}" STREQUAL "${LIBRARIES}")
 332         UNSET(${VAR} CACHE)
 333       ENDIF(NOT "${PREV_VAR_WITH_LIB}" STREQUAL "${LIBRARIES}")
 334       # Check if the library can be used with the macro.
 335       IF("${TRY_TYPE}" MATCHES "COMPILES")
 336         CHECK_C_SOURCE_COMPILES("${SAMPLE_SOURCE}" ${VAR})
 337       ELSEIF("${TRY_TYPE}" MATCHES "RUNS")
 338         CHECK_C_SOURCE_RUNS("${SAMPLE_SOURCE}" ${VAR})
 339       ELSE("${TRY_TYPE}" MATCHES "COMPILES")
 340         MESSAGE(FATAL_ERROR "UNKNOWN KEYWORD \"${TRY_TYPE}\" FOR TRY_TYPE")
 341       ENDIF("${TRY_TYPE}" MATCHES "COMPILES")
 342       # Save the libraries which ${VAR} is checked with.
 343       SET(${VAR_WITH_LIB} "${LIBRARIES}" CACHE INTERNAL
 344           "Macro ${VAR} is checked with")
 345     ENDFOREACH(VAR)
 346     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 347   ENDIF(WIN32 AND NOT CYGWIN)
 348 ENDMACRO (TRY_MACRO_FOR_LIBRARY)
 349 #
 350 # Check compress/decompress libraries
 351 #
 352 IF(WIN32 AND NOT CMAKE_CL_64 AND NOT CYGWIN)
 353   # GnuWin32 is only for Win32, not Win64.
 354   SET(__GNUWIN32PATH "C:/Program Files/GnuWin32")
 355 ENDIF(WIN32 AND NOT CMAKE_CL_64 AND NOT CYGWIN)
 356 IF(DEFINED __GNUWIN32PATH AND EXISTS "${__GNUWIN32PATH}")
 357   # You have to add a path availabel DLL file into PATH environment variable.
 358   # Maybe DLL path is "C:/Program Files/GnuWin32/bin".
 359   # The zlib and the bzip2 Setup program have installed programs and DLLs into
 360   # "C:/Program Files/GnuWin32" by default.
 361   # This is convenience setting for Windows.
 362   SET(CMAKE_PREFIX_PATH ${__GNUWIN32PATH} $(CMAKE_PREFIX_PATH))
 363   #
 364   # If you didn't use Setup program or installed into nonstandard path,
 365   # cmake cannot find out your zlib or bzip2 libraries and include files,
 366   # you should execute cmake with  -DCMAKE_PREFIX_PATH option.
 367   #   e.g.
 368   #     cmake -DCMAKE_PREFIX_PATH=<your-GnuWin32-path> <path-to-source>
 369   #
 370   # If compiling error occurred in zconf.h, You may need patch to zconf.h.
 371   #--- zconf.h.orig     2005-07-21 00:40:26.000000000
 372   #+++ zconf.h  2009-01-19 11:39:10.093750000
 373   #@@ -286,7 +286,7 @@
 374   #
 375   # #if 1           /* HAVE_UNISTD_H -- this line is updated by ./configure */
 376   # #  include <sys/types.h> /* for off_t */
 377   #-#  include <unistd.h>    /* for SEEK_* and off_t */
 378   #+#  include <stdio.h>    /* for SEEK_* and off_t */
 379   # #  ifdef VMS
 380   # #    include <unixio.h>   /* for off_t */
 381   # #  endif
 382 ENDIF(DEFINED __GNUWIN32PATH AND EXISTS "${__GNUWIN32PATH}")
 383
 384 SET(ADDITIONAL_LIBS "")
 385 #
 386 # Find ZLIB
 387 #
 388 IF(ENABLE_ZLIB)
 389   FIND_PACKAGE(ZLIB)
 390 ELSE()
 391   SET(ZLIB_FOUND FALSE) # Override cached value
 392 ENDIF()
 393 IF(ZLIB_FOUND)
 394   SET(HAVE_LIBZ 1)
 395   SET(HAVE_ZLIB_H 1)
 396   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 397   LIST(APPEND ADDITIONAL_LIBS ${ZLIB_LIBRARIES})
 398   IF(WIN32 AND NOT CYGWIN)
 399     #
 400     # Test if ZLIB_WINAPI macro is needed to use.
 401     #
 402     TRY_MACRO_FOR_LIBRARY(
 403       "${ZLIB_INCLUDE_DIR}" "${ZLIB_LIBRARIES}"
 404       RUNS
 405       "#include <zlib.h>\nint main() {uLong f = zlibCompileFlags(); return (f&(1U<<10))?0:-1; }"
 406       ZLIB_WINAPI)
 407     IF(ZLIB_WINAPI)
 408       ADD_DEFINITIONS(-DZLIB_WINAPI)
 409     ELSE(ZLIB_WINAPI)
 410       # Test if a macro is needed for the library.
 411       TRY_MACRO_FOR_LIBRARY(
 412         "${ZLIB_INCLUDE_DIR}" "${ZLIB_LIBRARIES}"
 413         COMPILES
 414         "#include <zlib.h>\nint main() {return zlibVersion()?1:0; }"
 415         "ZLIB_DLL;WITHOUT_ZLIB_DLL")
 416       IF(ZLIB_DLL)
 417         ADD_DEFINITIONS(-DZLIB_DLL)
 418       ENDIF(ZLIB_DLL)
 419     ENDIF(ZLIB_WINAPI)
 420   ENDIF(WIN32 AND NOT CYGWIN)
 421 ENDIF(ZLIB_FOUND)
 422 MARK_AS_ADVANCED(CLEAR ZLIB_INCLUDE_DIR)
 423 MARK_AS_ADVANCED(CLEAR ZLIB_LIBRARY)
 424 #
 425 # Find BZip2
 426 #
 427 IF(ENABLE_BZip2)
 428   FIND_PACKAGE(BZip2)
 429 ELSE()
 430   SET(BZIP2_FOUND FALSE) # Override cached value
 431 ENDIF()
 432 IF(BZIP2_FOUND)
 433   SET(HAVE_LIBBZ2 1)
 434   SET(HAVE_BZLIB_H 1)
 435   INCLUDE_DIRECTORIES(${BZIP2_INCLUDE_DIR})
 436   LIST(APPEND ADDITIONAL_LIBS ${BZIP2_LIBRARIES})
 437   # Test if a macro is needed for the library.
 438   TRY_MACRO_FOR_LIBRARY(
 439     "${BZIP2_INCLUDE_DIR}" "${BZIP2_LIBRARIES}"
 440     COMPILES
 441     "#include <bzlib.h>\nint main() {return BZ2_bzlibVersion()?1:0; }"
 442     "USE_BZIP2_DLL;USE_BZIP2_STATIC")
 443   IF(USE_BZIP2_DLL)
 444     ADD_DEFINITIONS(-DUSE_BZIP2_DLL)
 445   ELSEIF(USE_BZIP2_STATIC)
 446     ADD_DEFINITIONS(-DUSE_BZIP2_STATIC)
 447   ENDIF(USE_BZIP2_DLL)
 448 ENDIF(BZIP2_FOUND)
 449 MARK_AS_ADVANCED(CLEAR BZIP2_INCLUDE_DIR)
 450 MARK_AS_ADVANCED(CLEAR BZIP2_LIBRARIES)
 451
 452
 453 #
 454 # Find LZMA
 455 #
 456 IF(ENABLE_LZMA)
 457   FIND_PACKAGE(LibLZMA)
 458 ELSE()
 459   SET(LIBZMA_FOUND FALSE) # Override cached value
 460 ENDIF()
 461
 462 IF(LIBLZMA_FOUND)
 463   SET(HAVE_LIBLZMA 1)
 464   SET(HAVE_LZMA_H 1)
 465   SET(CMAKE_REQUIRED_INCLUDES ${LIBLZMA_INCLUDE_DIR})
 466   SET(CMAKE_REQUIRED_LIBRARIES ${LIBLZMA_LIBRARIES})
 467   INCLUDE_DIRECTORIES(${LIBLZMA_INCLUDE_DIRS})
 468   LIST(APPEND ADDITIONAL_LIBS ${LIBLZMA_LIBRARIES})
 469   # Test if a macro is needed for the library.
 470   TRY_MACRO_FOR_LIBRARY(
 471     "${LIBLZMA_INCLUDE_DIRS}" "${LIBLZMA_LIBRARIES}"
 472     COMPILES
 473     "#include <lzma.h>\nint main() {return (int)lzma_version_number(); }"
 474     "WITHOUT_LZMA_API_STATIC;LZMA_API_STATIC")
 475   IF(NOT WITHOUT_LZMA_API_STATIC AND LZMA_API_STATIC)
 476     ADD_DEFINITIONS(-DLZMA_API_STATIC)
 477   ENDIF(NOT WITHOUT_LZMA_API_STATIC AND LZMA_API_STATIC)
 478 ELSE(LIBLZMA_FOUND)
 479 # LZMA not found and will not be used.
 480 ENDIF(LIBLZMA_FOUND)
 481 #
 482 # Find LZO2
 483 #
 484 IF(ENABLE_LZO)
 485   IF (LZO2_INCLUDE_DIR)
 486     # Already in cache, be silent
 487     SET(LZO2_FIND_QUIETLY TRUE)
 488   ENDIF (LZO2_INCLUDE_DIR)
 489
 490   FIND_PATH(LZO2_INCLUDE_DIR lzo/lzoconf.h)
 491   FIND_LIBRARY(LZO2_LIBRARY NAMES lzo2 liblzo2)
 492   INCLUDE(FindPackageHandleStandardArgs)
 493   FIND_PACKAGE_HANDLE_STANDARD_ARGS(LZO2 DEFAULT_MSG LZO2_LIBRARY LZO2_INCLUDE_DIR)
 494 ELSE(ENABLE_LZO)
 495   SET(LIBZMA_FOUND FALSE) # Override cached value
 496 ENDIF(ENABLE_LZO)
 497 IF(LZO2_FOUND)
 498   SET(HAVE_LIBLZO2 1)
 499   SET(HAVE_LZO_LZOCONF_H 1)
 500   SET(HAVE_LZO_LZO1X_H 1)
 501   INCLUDE_DIRECTORIES(${LZO2_INCLUDE_DIR})
 502   LIST(APPEND ADDITIONAL_LIBS ${LZO2_LIBRARY})
 503   #
 504   # TODO: test for static library.
 505   #
 506 ENDIF(LZO2_FOUND)
 507 MARK_AS_ADVANCED(CLEAR LZO2_INCLUDE_DIR)
 508 MARK_AS_ADVANCED(CLEAR LZO2_LIBRARY)
 509 #
 510 # Find LZ4
 511 #
 512 IF (LZ4_INCLUDE_DIR)
 513   # Already in cache, be silent
 514   SET(LZ4_FIND_QUIETLY TRUE)
 515 ENDIF (LZ4_INCLUDE_DIR)
 516
 517 FIND_PATH(LZ4_INCLUDE_DIR lz4.h)
 518 FIND_LIBRARY(LZ4_LIBRARY NAMES lz4 liblz4)
 519 INCLUDE(FindPackageHandleStandardArgs)
 520 FIND_PACKAGE_HANDLE_STANDARD_ARGS(LZ4 DEFAULT_MSG LZ4_LIBRARY LZ4_INCLUDE_DIR)
 521 IF(LZ4_FOUND)
 522   SET(HAVE_LIBLZ4 1)
 523   SET(HAVE_LZ4_H 1)
 524   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
 525   SET(CMAKE_REQUIRED_INCLUDES ${LZ4_INCLUDE_DIR})
 526   CHECK_INCLUDE_FILES("lz4hc.h" HAVE_LZ4HC_H)
 527   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
 528   INCLUDE_DIRECTORIES(${LZ4_INCLUDE_DIR})
 529   LIST(APPEND ADDITIONAL_LIBS ${LZ4_LIBRARY})
 530   #
 531   # TODO: test for static library.
 532   #
 533 ENDIF(LZ4_FOUND)
 534 MARK_AS_ADVANCED(CLEAR LZ4_INCLUDE_DIR)
 535 MARK_AS_ADVANCED(CLEAR LZ4_LIBRARY)
 536
 537 #
 538 # Check headers
 539 #
 540 CHECK_HEADER_DIRENT()
 541
 542 SET(INCLUDES "")
 543 MACRO (LA_CHECK_INCLUDE_FILE header var)
 544       CHECK_INCLUDE_FILES("${INCLUDES};${header}" ${var})
 545       IF (${var})
 546          SET(INCLUDES ${INCLUDES} ${header})
 547       ENDIF (${var})
 548 ENDMACRO (LA_CHECK_INCLUDE_FILE)
 549
 550 # Some FreeBSD headers assume sys/types.h was already included.
 551 LA_CHECK_INCLUDE_FILE("sys/types.h" HAVE_SYS_TYPES_H)
 552
 553 # Alphabetize the rest unless there's a compelling reason
 554 LA_CHECK_INCLUDE_FILE("acl/libacl.h" HAVE_ACL_LIBACL_H)
 555 LA_CHECK_INCLUDE_FILE("ctype.h" HAVE_CTYPE_H)
 556 LA_CHECK_INCLUDE_FILE("copyfile.h" HAVE_COPYFILE_H)
 557 LA_CHECK_INCLUDE_FILE("direct.h" HAVE_DIRECT_H)
 558 LA_CHECK_INCLUDE_FILE("dlfcn.h" HAVE_DLFCN_H)
 559 LA_CHECK_INCLUDE_FILE("errno.h" HAVE_ERRNO_H)
 560 LA_CHECK_INCLUDE_FILE("ext2fs/ext2_fs.h" HAVE_EXT2FS_EXT2_FS_H)
 561
 562 CHECK_C_SOURCE_COMPILES("#include <sys/ioctl.h>
 563 #include <ext2fs/ext2_fs.h>
 564 int main(void) { return EXT2_IOC_GETFLAGS; }" HAVE_WORKING_EXT2_IOC_GETFLAGS)
 565
 566 LA_CHECK_INCLUDE_FILE("fcntl.h" HAVE_FCNTL_H)
 567 LA_CHECK_INCLUDE_FILE("grp.h" HAVE_GRP_H)
 568 LA_CHECK_INCLUDE_FILE("inttypes.h" HAVE_INTTYPES_H)
 569 LA_CHECK_INCLUDE_FILE("io.h" HAVE_IO_H)
 570 LA_CHECK_INCLUDE_FILE("langinfo.h" HAVE_LANGINFO_H)
 571 LA_CHECK_INCLUDE_FILE("limits.h" HAVE_LIMITS_H)
 572 LA_CHECK_INCLUDE_FILE("linux/types.h" HAVE_LINUX_TYPES_H)
 573 LA_CHECK_INCLUDE_FILE("linux/fiemap.h" HAVE_LINUX_FIEMAP_H)
 574 LA_CHECK_INCLUDE_FILE("linux/fs.h" HAVE_LINUX_FS_H)
 575
 576 CHECK_C_SOURCE_COMPILES("#include <sys/ioctl.h>
 577 #include <linux/fs.h>
 578 int main(void) { return FS_IOC_GETFLAGS; }" HAVE_WORKING_FS_IOC_GETFLAGS)
 579
 580 LA_CHECK_INCLUDE_FILE("linux/magic.h" HAVE_LINUX_MAGIC_H)
 581 LA_CHECK_INCLUDE_FILE("locale.h" HAVE_LOCALE_H)
 582 LA_CHECK_INCLUDE_FILE("membership.h" HAVE_MEMBERSHIP_H)
 583 LA_CHECK_INCLUDE_FILE("memory.h" HAVE_MEMORY_H)
 584 LA_CHECK_INCLUDE_FILE("paths.h" HAVE_PATHS_H)
 585 LA_CHECK_INCLUDE_FILE("poll.h" HAVE_POLL_H)
 586 LA_CHECK_INCLUDE_FILE("process.h" HAVE_PROCESS_H)
 587 LA_CHECK_INCLUDE_FILE("pthread.h" HAVE_PTHREAD_H)
 588 LA_CHECK_INCLUDE_FILE("pwd.h" HAVE_PWD_H)
 589 LA_CHECK_INCLUDE_FILE("readpassphrase.h" HAVE_READPASSPHRASE_H)
 590 LA_CHECK_INCLUDE_FILE("regex.h" HAVE_REGEX_H)
 591 LA_CHECK_INCLUDE_FILE("signal.h" HAVE_SIGNAL_H)
 592 LA_CHECK_INCLUDE_FILE("spawn.h" HAVE_SPAWN_H)
 593 LA_CHECK_INCLUDE_FILE("stdarg.h" HAVE_STDARG_H)
 594 LA_CHECK_INCLUDE_FILE("stdint.h" HAVE_STDINT_H)
 595 LA_CHECK_INCLUDE_FILE("stdlib.h" HAVE_STDLIB_H)
 596 LA_CHECK_INCLUDE_FILE("string.h" HAVE_STRING_H)
 597 LA_CHECK_INCLUDE_FILE("strings.h" HAVE_STRINGS_H)
 598 LA_CHECK_INCLUDE_FILE("sys/acl.h" HAVE_SYS_ACL_H)
 599 LA_CHECK_INCLUDE_FILE("sys/cdefs.h" HAVE_SYS_CDEFS_H)
 600 LA_CHECK_INCLUDE_FILE("sys/ioctl.h" HAVE_SYS_IOCTL_H)
 601 LA_CHECK_INCLUDE_FILE("sys/mkdev.h" HAVE_SYS_MKDEV_H)
 602 LA_CHECK_INCLUDE_FILE("sys/mount.h" HAVE_SYS_MOUNT_H)
 603 LA_CHECK_INCLUDE_FILE("sys/param.h" HAVE_SYS_PARAM_H)
 604 LA_CHECK_INCLUDE_FILE("sys/poll.h" HAVE_SYS_POLL_H)
 605 LA_CHECK_INCLUDE_FILE("sys/select.h" HAVE_SYS_SELECT_H)
 606 LA_CHECK_INCLUDE_FILE("sys/stat.h" HAVE_SYS_STAT_H)
 607 LA_CHECK_INCLUDE_FILE("sys/statfs.h" HAVE_SYS_STATFS_H)
 608 LA_CHECK_INCLUDE_FILE("sys/statvfs.h" HAVE_SYS_STATVFS_H)
 609 LA_CHECK_INCLUDE_FILE("sys/time.h" HAVE_SYS_TIME_H)
 610 LA_CHECK_INCLUDE_FILE("sys/utime.h" HAVE_SYS_UTIME_H)
 611 LA_CHECK_INCLUDE_FILE("sys/utsname.h" HAVE_SYS_UTSNAME_H)
 612 LA_CHECK_INCLUDE_FILE("sys/vfs.h" HAVE_SYS_VFS_H)
 613 LA_CHECK_INCLUDE_FILE("sys/wait.h" HAVE_SYS_WAIT_H)
 614 LA_CHECK_INCLUDE_FILE("time.h" HAVE_TIME_H)
 615 LA_CHECK_INCLUDE_FILE("unistd.h" HAVE_UNISTD_H)
 616 LA_CHECK_INCLUDE_FILE("utime.h" HAVE_UTIME_H)
 617 LA_CHECK_INCLUDE_FILE("wchar.h" HAVE_WCHAR_H)
 618 LA_CHECK_INCLUDE_FILE("wctype.h" HAVE_WCTYPE_H)
 619 LA_CHECK_INCLUDE_FILE("windows.h" HAVE_WINDOWS_H)
 620 IF(ENABLE_CNG)
 621   LA_CHECK_INCLUDE_FILE("Bcrypt.h" HAVE_BCRYPT_H)
 622   IF(HAVE_BCRYPT_H)
 623     LIST(APPEND ADDITIONAL_LIBS "Bcrypt")
 624   ENDIF(HAVE_BCRYPT_H)
 625 ELSE(ENABLE_CNG)
 626   UNSET(HAVE_BCRYPT_H CACHE)
 627 ENDIF(ENABLE_CNG)
 628 # Following files need windows.h, so we should test it after windows.h test.
 629 LA_CHECK_INCLUDE_FILE("wincrypt.h" HAVE_WINCRYPT_H)
 630 LA_CHECK_INCLUDE_FILE("winioctl.h" HAVE_WINIOCTL_H)
 631
 632 #
 633 # Check whether use of __EXTENSIONS__ is safe.
 634 # We need some macro such as _GNU_SOURCE to use extension functions.
 635 #
 636 SET(_INCLUDE_FILES)
 637 FOREACH (it ${_HEADER})
 638    SET(_INCLUDE_FILES "${_INCLUDE_FILES}#include <${it}>\n")
 639 ENDFOREACH (it)
 640
 641 CHECK_C_SOURCE_COMPILES(
 642   "#define __EXTENSIONS__ 1
 643    ${_INCLUDE_FILES}
 644    int main() { return 0;}"
 645  SAFE_TO_DEFINE_EXTENSIONS)
 646
 647 #
 648 # Find Nettle
 649 #
 650 IF(ENABLE_NETTLE)
 651   FIND_PACKAGE(Nettle)
 652   IF(NETTLE_FOUND)
 653     SET(HAVE_LIBNETTLE 1)
 654     LIST(APPEND ADDITIONAL_LIBS ${NETTLE_LIBRARIES})
 655     INCLUDE_DIRECTORIES(${NETTLE_INCLUDE_DIR})
 656
 657     LIST(APPEND CMAKE_REQUIRED_INCLUDES ${NETTLE_INCLUDE_DIR})
 658     LA_CHECK_INCLUDE_FILE("nettle/aes.h" HAVE_NETTLE_AES_H)
 659     LA_CHECK_INCLUDE_FILE("nettle/hmac.h" HAVE_NETTLE_HMAC_H)
 660     LA_CHECK_INCLUDE_FILE("nettle/md5.h" HAVE_NETTLE_MD5_H)
 661     LA_CHECK_INCLUDE_FILE("nettle/pbkdf2.h" HAVE_NETTLE_PBKDF2_H)
 662     LA_CHECK_INCLUDE_FILE("nettle/ripemd160.h" HAVE_NETTLE_RIPEMD160_H)
 663     LA_CHECK_INCLUDE_FILE("nettle/sha.h" HAVE_NETTLE_SHA_H)
 664
 665   ENDIF(NETTLE_FOUND)
 666   MARK_AS_ADVANCED(CLEAR NETTLE_INCLUDE_DIR)
 667   MARK_AS_ADVANCED(CLEAR NETTLE_LIBRARIES)
 668 ENDIF(ENABLE_NETTLE)
 669
 670 #
 671 # Find OpenSSL
 672 # (Except on Mac, where OpenSSL is deprecated.)
 673 #
 674 IF(ENABLE_OPENSSL AND NOT CMAKE_SYSTEM_NAME MATCHES "Darwin")
 675   FIND_PACKAGE(OpenSSL)
 676   IF(OPENSSL_FOUND)
 677     SET(HAVE_LIBCRYPTO 1)
 678     INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 679     LIST(APPEND ADDITIONAL_LIBS ${OPENSSL_CRYPTO_LIBRARY})
 680   ENDIF(OPENSSL_FOUND)
 681 ELSE()
 682   SET(OPENSSL_FOUND FALSE) # Override cached value
 683 ENDIF()
 684
 685 # FreeBSD libmd
 686 IF(NOT OPENSSL_FOUND)
 687   CHECK_LIBRARY_EXISTS(md "MD5Init" "" LIBMD_FOUND)
 688   IF(LIBMD_FOUND)
 689     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 690     SET(CMAKE_REQUIRED_LIBRARIES "md")
 691     FIND_LIBRARY(LIBMD_LIBRARY NAMES md)
 692     LIST(APPEND ADDITIONAL_LIBS ${LIBMD_LIBRARY})
 693     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 694   ENDIF(LIBMD_FOUND)
 695 ENDIF(NOT OPENSSL_FOUND)
 696
 697 #
 698 # How to prove that CRYPTO functions, which have several names on various
 699 # platforms, just see if archive_digest.c can compile and link against
 700 # required libraries.
 701 #
 702 MACRO(CHECK_CRYPTO ALGORITHMS IMPLEMENTATION)
 703     FOREACH(ALGORITHM ${ALGORITHMS})
 704       IF(NOT ARCHIVE_CRYPTO_${ALGORITHM})
 705       STRING(TOLOWER "${ALGORITHM}" lower_algorithm)
 706       STRING(TOUPPER "${ALGORITHM}" algorithm)
 707       IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND NOT OPENSSL_FOUND)
 708         SET(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} FALSE)
 709       ELSEIF("${IMPLEMENTATION}" MATCHES "^NETTLE$" AND NOT NETTLE_FOUND)
 710         SET(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} FALSE)
 711       ENDIF("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND NOT OPENSSL_FOUND)
 712
 713       IF(NOT DEFINED ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 714         # Probe the local implementation for whether this
 715         # crypto implementation is available on this platform.
 716         SET(TRY_CRYPTO_REQUIRED_INCLUDES
 717           "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_BINARY_DIR};${CMAKE_CURRENT_SOURCE_DIR}/libarchive;${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp")
 718         SET(TRY_CRYPTO_REQUIRED_LIBS)
 719         IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 720             SET(TRY_CRYPTO_REQUIRED_INCLUDES
 721               "${TRY_CRYPTO_REQUIRED_INCLUDES};${OPENSSL_INCLUDE_DIR}")
 722             SET(TRY_CRYPTO_REQUIRED_LIBS
 723                 "-DLINK_LIBRARIES:STRING=${OPENSSL_LIBRARIES}")
 724         ELSEIF("${IMPLEMENTATION}" MATCHES "^NETTLE$" AND NETTLE_FOUND)
 725             SET(TRY_CRYPTO_REQUIRED_INCLUDES
 726               "${TRY_CRYPTO_REQUIRED_INCLUDES};${NETTLE_INCLUDE_DIR}")
 727             SET(TRY_CRYPTO_REQUIRED_LIBS
 728                 "-DLINK_LIBRARIES:STRING=${NETTLE_LIBRARY}")
 729         ELSEIF("${IMPLEMENTATION}" MATCHES "^LIBMD$" AND LIBMD_FOUND)
 730             SET(TRY_CRYPTO_REQUIRED_LIBS
 731                 "-DLINK_LIBRARIES:STRING=${LIBMD_LIBRARY}")
 732         ENDIF("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 733
 734     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
 735       ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h)
 736         FILE(READ "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h"
 737              CONFDEFS_H)
 738         FILE(READ "${CMAKE_CURRENT_SOURCE_DIR}/libarchive/archive_digest.c"
 739              ARCHIVE_CRYPTO_C)
 740
 741         SET(SOURCE "${CONFDEFS_H}
 742
 743 #define ARCHIVE_${algorithm}_COMPILE_TEST
 744 #define ARCHIVE_CRYPTO_${algorithm}_${IMPLEMENTATION}
 745 #define PLATFORM_CONFIG_H \"check_crypto_md.h\"
 746
 747 ${ARCHIVE_CRYPTO_C}
 748
 749 int
 750 main(int argc, char **argv)
 751 {
 752   archive_${lower_algorithm}_ctx ctx;
 753   archive_${lower_algorithm}_init(&ctx);
 754   archive_${lower_algorithm}_update(&ctx, *argv, argc);
 755   archive_${lower_algorithm}_final(&ctx, NULL);
 756   return 0;
 757 }
 758 ")
 759
 760   FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.h" "")
 761         FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.c" "${SOURCE}")
 762         MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION}")
 763
 764         TRY_COMPILE(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION}
 765           ${CMAKE_BINARY_DIR}
 766           ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.c
 767           CMAKE_FLAGS
 768            "${TRY_CRYPTO_REQUIRED_LIBS}"
 769            "${TRY_CRYPTO_REQUIRED_INCLUDES}"
 770           OUTPUT_VARIABLE OUTPUT)
 771
 772         # Inform user whether or not we found it; if not, log why we didn't.
 773         IF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 774           MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} -- found")
 775                   SET(ARCHIVE_CRYPTO_${ALGORITHM} 1)
 776         ELSE (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 777           MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} -- not found")
 778           FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 779             "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} failed with the following output:\n"
 780             "${OUTPUT}\n"
 781             "Source file was:\n${SOURCE}\n")
 782         ENDIF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 783       ENDIF(NOT DEFINED ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 784
 785       # Add appropriate libs/includes depending on whether the implementation
 786       # was found on this platform.
 787       IF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 788         IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 789           INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 790           LIST(APPEND ADDITIONAL_LIBS ${OPENSSL_LIBRARIES})
 791            LIST(REMOVE_DUPLICATES ADDITIONAL_LIBS)
 792         ENDIF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 793       ENDIF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 794       ENDIF(NOT ARCHIVE_CRYPTO_${ALGORITHM})
 795     ENDFOREACH(ALGORITHM ${ALGORITHMS})
 796 ENDMACRO(CHECK_CRYPTO ALGORITHMS IMPLEMENTATION)
 797
 798 #
 799 # CRYPTO functions on Windows is defined at archive_windows.c, thus we do not
 800 # need the test what the functions can be mapped to archive_{crypto name}_init,
 801 # archive_{crypto name}_update and archive_{crypto name}_final.
 802 # The functions on Windows use CALG_{crypto name} macro to create a crypt object
 803 # and then we need to know what CALG_{crypto name} macros is available to show
 804 # ARCHIVE_CRYPTO_{crypto name}_WIN macros because Windows 2000 and earlier version
 805 # of Windows XP do not support SHA256, SHA384 and SHA512.
 806 #
 807 MACRO(CHECK_CRYPTO_WIN CRYPTO_LIST)
 808   IF(WIN32 AND NOT CYGWIN)
 809     FOREACH(CRYPTO ${CRYPTO_LIST})
 810       IF(NOT ARCHIVE_CRYPTO_${CRYPTO})
 811       IF(NOT DEFINED ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 812         STRING(TOUPPER "${CRYPTO}" crypto)
 813         SET(ALGID "")
 814         IF ("${CRYPTO}" MATCHES "^MD5$")
 815             SET(ALGID "CALG_MD5")
 816         ENDIF ("${CRYPTO}" MATCHES "^MD5$")
 817         IF ("${CRYPTO}" MATCHES "^SHA1$")
 818             SET(ALGID "CALG_SHA1")
 819         ENDIF ("${CRYPTO}" MATCHES "^SHA1$")
 820         IF ("${CRYPTO}" MATCHES "^SHA256$")
 821             SET(ALGID "CALG_SHA_256")
 822         ENDIF ("${CRYPTO}" MATCHES "^SHA256$")
 823         IF ("${CRYPTO}" MATCHES "^SHA384$")
 824             SET(ALGID "CALG_SHA_384")
 825         ENDIF ("${CRYPTO}" MATCHES "^SHA384$")
 826         IF ("${CRYPTO}" MATCHES "^SHA512$")
 827             SET(ALGID "CALG_SHA_512")
 828         ENDIF ("${CRYPTO}" MATCHES "^SHA512$")
 829
 830     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
 831       ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h)
 832         FILE(READ "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h"
 833              CONFDEFS_H)
 834
 835         SET(SOURCE "${CONFDEFS_H}
 836
 837 #define ${crypto}_COMPILE_TEST
 838 #include <windows.h>
 839 #include <wincrypt.h>
 840
 841 int
 842 main(int argc, char **argv)
 843 {
 844         return ${ALGID};
 845 }
 846 ")
 847         SET(SOURCE_FILE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_win.c")
 848
 849         FILE(WRITE "${SOURCE_FILE}" "${SOURCE}")
 850         MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN")
 851
 852         TRY_COMPILE(ARCHIVE_CRYPTO_${CRYPTO}_WIN
 853           ${CMAKE_BINARY_DIR}
 854           ${SOURCE_FILE}
 855           CMAKE_FLAGS "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_BINARY_DIR};${CMAKE_CURRENT_SOURCE_DIR}/libarchive"
 856           OUTPUT_VARIABLE OUTPUT)
 857
 858         IF (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 859             MESSAGE(STATUS
 860                 "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN -- found")
 861                 SET(ARCHIVE_CRYPTO_${CRYPTO} 1)
 862         ELSE (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 863             MESSAGE(STATUS
 864                  "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN -- not found")
 865             FILE(APPEND
 866                 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 867                 "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN failed with the following output:\n"
 868                 "${OUTPUT}\n"
 869                 "Source file was:\n${SOURCE}\n")
 870         ENDIF (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 871
 872       ENDIF(NOT DEFINED ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 873       ENDIF(NOT ARCHIVE_CRYPTO_${CRYPTO})
 874     ENDFOREACH(CRYPTO)
 875   ENDIF(WIN32 AND NOT CYGWIN)
 876 ENDMACRO(CHECK_CRYPTO_WIN CRYPTO_LIST)
 877
 878 #
 879 # Find iconv
 880 # POSIX defines the second arg as const char **
 881 # and requires it to be in libc.  But we can accept
 882 # a non-const argument here and can support iconv()
 883 # being in libiconv.
 884 #
 885 MACRO(CHECK_ICONV LIB TRY_ICONV_CONST)
 886   IF(NOT HAVE_ICONV)
 887     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 888     IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
 889         CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 890       #
 891       # During checking iconv proto type, we should use -Werror to avoid the
 892       # success of iconv detection with a warnig which success is a miss
 893       # detection. So this needs for all build mode(even it's a release mode).
 894       #
 895       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror")
 896     ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
 897            CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 898     IF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 899       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -qhalt=w -qflag=w:w")
 900     ENDIF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 901     IF (MSVC)
 902       # NOTE: /WX option is the same as gcc's -Werror option.
 903       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} /WX")
 904     ENDIF (MSVC)
 905     #
 906     CHECK_C_SOURCE_COMPILES(
 907       "#include <stdlib.h>
 908        #include <iconv.h>
 909        int main() {
 910           ${TRY_ICONV_CONST} char *ccp;
 911           iconv_t cd = iconv_open(\"\", \"\");
 912           iconv(cd, &ccp, (size_t *)0, (char **)0, (size_t *)0);
 913           iconv_close(cd);
 914           return 0;
 915        }"
 916      HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
 917     IF(HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
 918       SET(HAVE_ICONV true)
 919       SET(ICONV_CONST ${TRY_ICONV_CONST})
 920     ENDIF(HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
 921     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 922   ENDIF(NOT HAVE_ICONV)
 923 ENDMACRO(CHECK_ICONV TRY_ICONV_CONST)
 924
 925 IF(ENABLE_ICONV)
 926   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
 927   FIND_PATH(ICONV_INCLUDE_DIR iconv.h)
 928   IF(ICONV_INCLUDE_DIR)
 929     #SET(INCLUDES ${INCLUDES} "iconv.h")
 930     SET(HAVE_ICONV_H 1)
 931     INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 932     SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
 933     CHECK_ICONV("libc" "const")
 934     CHECK_ICONV("libc" "")
 935
 936     # If iconv isn't in libc and we have a libiconv, try that.
 937     FIND_LIBRARY(LIBICONV_PATH NAMES iconv libiconv)
 938     IF(NOT HAVE_ICONV AND LIBICONV_PATH)
 939       LIST(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBICONV_PATH})
 940       # Test if a macro is needed for the library.
 941       TRY_MACRO_FOR_LIBRARY(
 942         "${ICONV_INCLUDE_DIR}" "${LIBICONV_PATH}"
 943         COMPILES
 944         "#include <iconv.h>\nint main() {return iconv_close((iconv_t)0);}"
 945         "WITHOUT_LIBICONV_STATIC;LIBICONV_STATIC")
 946       IF(NOT WITHOUT_LIBICONV_STATIC AND LIBICONV_STATIC)
 947         ADD_DEFINITIONS(-DLIBICONV_STATIC)
 948       ENDIF(NOT WITHOUT_LIBICONV_STATIC AND LIBICONV_STATIC)
 949       #
 950       # Set up CMAKE_REQUIRED_* for CHECK_ICONV
 951       #
 952       SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
 953       SET(CMAKE_REQUIRED_LIBRARIES ${LIBICONV_PATH})
 954       IF(LIBICONV_STATIC)
 955         # LIBICONV_STATIC is necessary for the success of CHECK_ICONV
 956         # on Windows.
 957         SET(CMAKE_REQUIRED_DEFINITIONS "-DLIBICONV_STATIC")
 958       ELSE(LIBICONV_STATIC)
 959         SET(CMAKE_REQUIRED_DEFINITIONS)
 960       ENDIF(LIBICONV_STATIC)
 961       CHECK_ICONV("libiconv" "const")
 962       CHECK_ICONV("libiconv" "")
 963       IF (HAVE_ICONV)
 964         LIST(APPEND ADDITIONAL_LIBS ${LIBICONV_PATH})
 965       ENDIF(HAVE_ICONV)
 966     ENDIF(NOT HAVE_ICONV AND LIBICONV_PATH)
 967   ENDIF(ICONV_INCLUDE_DIR)
 968   #
 969   # Find locale_charset() for libiconv.
 970   #
 971   IF(LIBICONV_PATH)
 972     SET(CMAKE_REQUIRED_DEFINITIONS)
 973     SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
 974     SET(CMAKE_REQUIRED_LIBRARIES)
 975     CHECK_INCLUDE_FILES("localcharset.h" HAVE_LOCALCHARSET_H)
 976     FIND_LIBRARY(LIBCHARSET_PATH NAMES charset libcharset)
 977     IF(LIBCHARSET_PATH)
 978       SET(CMAKE_REQUIRED_LIBRARIES ${LIBCHARSET_PATH})
 979       IF(WIN32 AND NOT CYGWIN)
 980         # Test if a macro is needed for the library.
 981         TRY_MACRO_FOR_LIBRARY(
 982           "${ICONV_INCLUDE_DIR}" "${LIBCHARSET_PATH}"
 983           COMPILES
 984           "#include <localcharset.h>\nint main() {return locale_charset()?1:0;}"
 985           "WITHOUT_LIBCHARSET_STATIC;LIBCHARSET_STATIC")
 986         IF(NOT WITHOUT_LIBCHARSET_STATIC AND LIBCHARSET_STATIC)
 987           ADD_DEFINITIONS(-DLIBCHARSET_STATIC)
 988         ENDIF(NOT WITHOUT_LIBCHARSET_STATIC AND LIBCHARSET_STATIC)
 989         IF(WITHOUT_LIBCHARSET_STATIC OR LIBCHARSET_STATIC)
 990           SET(HAVE_LOCALE_CHARSET ON CACHE INTERNAL
 991               "Have function locale_charset")
 992         ENDIF(WITHOUT_LIBCHARSET_STATIC OR LIBCHARSET_STATIC)
 993       ELSE(WIN32 AND NOT CYGWIN)
 994         CHECK_FUNCTION_EXISTS_GLIBC(locale_charset HAVE_LOCALE_CHARSET)
 995       ENDIF(WIN32 AND NOT CYGWIN)
 996       IF(HAVE_LOCALE_CHARSET)
 997         LIST(APPEND ADDITIONAL_LIBS ${LIBCHARSET_PATH})
 998       ENDIF(HAVE_LOCALE_CHARSET)
 999     ENDIF(LIBCHARSET_PATH)
1000   ENDIF(LIBICONV_PATH)
1001   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
1002 ELSE(ENABLE_ICONV)
1003   # Make sure ICONV variables are not in CACHE after ENABLE_ICONV disabled
1004   # (once enabled).
1005   UNSET(HAVE_LOCALE_CHARSET CACHE)
1006   UNSET(HAVE_ICONV CACHE)
1007   UNSET(HAVE_ICONV_libc_ CACHE)
1008   UNSET(HAVE_ICONV_libc_const CACHE)
1009   UNSET(HAVE_ICONV_libiconv_ CACHE)
1010   UNSET(HAVE_ICONV_libiconv_const CACHE)
1011   UNSET(ICONV_INCLUDE_DIR CACHE)
1012   UNSET(LIBICONV_PATH CACHE)
1013   UNSET(LIBICONV_DLL CACHE)
1014   UNSET(LIBICONV_STATIC CACHE)
1015   UNSET(LIBCHARSET_DLL CACHE)
1016   UNSET(LIBCHARSET_STATIC CACHE)
1017 ENDIF(ENABLE_ICONV)
1018
1019 #
1020 # Find Libxml2
1021 #
1022 IF(ENABLE_LIBXML2)
1023   FIND_PACKAGE(LibXml2)
1024 ELSE()
1025   SET(LIBXML2_FOUND FALSE)
1026 ENDIF()
1027 IF(LIBXML2_FOUND)
1028   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
1029   INCLUDE_DIRECTORIES(${LIBXML2_INCLUDE_DIR})
1030   LIST(APPEND ADDITIONAL_LIBS ${LIBXML2_LIBRARIES})
1031   SET(HAVE_LIBXML2 1)
1032   # libxml2's include files use iconv.h
1033   SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR} ${LIBXML2_INCLUDE_DIR})
1034   CHECK_INCLUDE_FILES("libxml/xmlreader.h" HAVE_LIBXML_XMLREADER_H)
1035   CHECK_INCLUDE_FILES("libxml/xmlwriter.h" HAVE_LIBXML_XMLWRITER_H)
1036   # Test if a macro is needed for the library.
1037   TRY_MACRO_FOR_LIBRARY(
1038     "${ICONV_INCLUDE_DIR};${LIBXML2_INCLUDE_DIR}"
1039     "ws2_32.lib;${ZLIB_LIBRARIES};${LIBICONV_PATH};${LIBXML2_LIBRARIES}"
1040     COMPILES
1041     "#include <stddef.h>\n#include <libxml/xmlreader.h>\nint main() {return xmlTextReaderRead((xmlTextReaderPtr)(void *)0);}"
1042     "WITHOUT_LIBXML_STATIC;LIBXML_STATIC")
1043   IF(NOT WITHOUT_LIBXML_STATIC AND LIBXML_STATIC)
1044     ADD_DEFINITIONS(-DLIBXML_STATIC)
1045   ENDIF(NOT WITHOUT_LIBXML_STATIC AND LIBXML_STATIC)
1046   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
1047 ELSE(LIBXML2_FOUND)
1048   #
1049   # Find Expat
1050   #
1051   IF(ENABLE_EXPAT)
1052     FIND_PACKAGE(EXPAT)
1053   ELSE()
1054     SET(EXPAT_FOUND FALSE)
1055   ENDIF()
1056   IF(EXPAT_FOUND)
1057     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
1058     INCLUDE_DIRECTORIES(${EXPAT_INCLUDE_DIR})
1059     LIST(APPEND ADDITIONAL_LIBS ${EXPAT_LIBRARIES})
1060     SET(HAVE_LIBEXPAT 1)
1061     LA_CHECK_INCLUDE_FILE("expat.h" HAVE_EXPAT_H)
1062     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
1063   ENDIF(EXPAT_FOUND)
1064 ENDIF(LIBXML2_FOUND)
1065 MARK_AS_ADVANCED(CLEAR LIBXML2_INCLUDE_DIR)
1066 MARK_AS_ADVANCED(CLEAR LIBXML2_LIBRARIES)
1067
1068 #
1069 # POSIX Regular Expression support
1070 #
1071 IF(POSIX_REGEX_LIB MATCHES "^(AUTO|LIBC|LIBREGEX)$")
1072   #
1073   # If PCREPOSIX is not found or not requested, try using regex
1074   # from libc or libregex
1075   #
1076   FIND_PATH(REGEX_INCLUDE_DIR regex.h)
1077   IF(REGEX_INCLUDE_DIR)
1078     CHECK_FUNCTION_EXISTS_GLIBC(regcomp HAVE_REGCOMP_LIBC)
1079     #
1080     # If libc does not provide regex, find libregex.
1081     #
1082     IF(NOT HAVE_REGCOMP_LIBC)
1083       CMAKE_PUSH_CHECK_STATE()  # Save the state of the variables
1084       FIND_LIBRARY(REGEX_LIBRARY regex)
1085       IF(REGEX_LIBRARY)
1086         SET(CMAKE_REQUIRED_LIBRARIES ${REGEX_LIBRARY})
1087         CHECK_FUNCTION_EXISTS_GLIBC(regcomp HAVE_REGCOMP_LIBREGEX)
1088         IF(HAVE_REGCOMP_LIBREGEX)
1089           LIST(APPEND ADDITIONAL_LIBS ${REGEX_LIBRARY})
1090           #
1091           # If regex.h is not found, retry looking for regex.h at
1092           # REGEX_INCLUDE_DIR
1093           #
1094           IF(NOT HAVE_REGEX_H)
1095             UNSET(HAVE_REGEX_H CACHE)
1096             INCLUDE_DIRECTORIES(${REGEX_INCLUDE_DIR})
1097             SET(CMAKE_REQUIRED_INCLUDES ${REGEX_INCLUDE_DIR})
1098             LA_CHECK_INCLUDE_FILE("regex.h" HAVE_REGEX_H)
1099           ENDIF(NOT HAVE_REGEX_H)
1100           # Test if a macro is needed for the library.
1101           TRY_MACRO_FOR_LIBRARY(
1102             "${REGEX_INCLUDE_DIR}" "${REGEX_LIBRARY}"
1103             COMPILES
1104             "#include <stddef.h>\n#include <regex.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1105             "USE_REGEX_DLL;USE_REGEX_STATIC")
1106           IF(USE_REGEX_DLL)
1107             ADD_DEFINITIONS(-DUSE_REGEX_DLL)
1108           ELSEIF(USE_REGEX_STATIC)
1109             ADD_DEFINITIONS(-DUSE_REGEX_STATIC)
1110           ENDIF(USE_REGEX_DLL)
1111         ENDIF(HAVE_REGCOMP_LIBREGEX)
1112       ENDIF(REGEX_LIBRARY)
1113       CMAKE_POP_CHECK_STATE()   # Restore the state of the variables
1114     ENDIF(NOT HAVE_REGCOMP_LIBC)
1115   ENDIF(REGEX_INCLUDE_DIR)
1116   IF(HAVE_REGCOMP_LIBC OR HAVE_REGCOMP_LIBREGEX)
1117     SET(FOUND_POSIX_REGEX_LIB 1)
1118   ENDIF(HAVE_REGCOMP_LIBC OR HAVE_REGCOMP_LIBREGEX)
1119 ENDIF(POSIX_REGEX_LIB MATCHES "^(AUTO|LIBC|LIBREGEX)$")
1120
1121 IF(NOT FOUND_POSIX_REGEX_LIB AND POSIX_REGEX_LIB MATCHES "^(AUTO|LIBPCREPOSIX)$")
1122   #
1123   # If requested, try finding library for PCREPOSIX
1124   #
1125   IF(ENABLE_LibGCC)
1126     FIND_PACKAGE(LibGCC)
1127   ELSE()
1128     SET(LIBGCC_FOUND FALSE) # Override cached value
1129   ENDIF()
1130   IF(ENABLE_PCREPOSIX)
1131     FIND_PACKAGE(PCREPOSIX)
1132   ELSE()
1133     SET(PCREPOSIX_FOUND FALSE) # Override cached value
1134   ENDIF()
1135   IF(PCREPOSIX_FOUND)
1136     INCLUDE_DIRECTORIES(${PCRE_INCLUDE_DIR})
1137     LIST(APPEND ADDITIONAL_LIBS ${PCREPOSIX_LIBRARIES})
1138     # Test if a macro is needed for the library.
1139     TRY_MACRO_FOR_LIBRARY(
1140       "${PCRE_INCLUDE_DIR}" "${PCREPOSIX_LIBRARIES}"
1141       COMPILES
1142       "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1143       "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1144     IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1145       ADD_DEFINITIONS(-DPCRE_STATIC)
1146         ELSEIF(NOT WITHOUT_PCRE_STATIC AND NOT PCRE_STATIC AND PCRE_FOUND)
1147           # Determine if pcre static libraries are to be used.
1148       LIST(APPEND ADDITIONAL_LIBS ${PCRE_LIBRARIES})
1149       SET(TMP_LIBRARIES ${PCREPOSIX_LIBRARIES} ${PCRE_LIBRARIES})
1150       MESSAGE(STATUS "trying again with -lpcre included")
1151       TRY_MACRO_FOR_LIBRARY(
1152         "${PCRE_INCLUDE_DIR}" "${TMP_LIBRARIES}"
1153         COMPILES
1154         "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1155         "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1156       IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1157         ADD_DEFINITIONS(-DPCRE_STATIC)
1158       ELSEIF(NOT WITHOUT_PCRE_STATIC AND NOT PCRE_STATIC AND MSVC AND LIBGCC_FOUND)
1159         # When doing a Visual Studio build using pcre static libraries
1160         # built using the mingw toolchain, -lgcc is needed to resolve
1161         # ___chkstk_ms.
1162         MESSAGE(STATUS "Visual Studio build detected, trying again with -lgcc included")
1163         LIST(APPEND ADDITIONAL_LIBS ${LIBGCC_LIBRARIES})
1164         SET(TMP_LIBRARIES ${PCREPOSIX_LIBRARIES} ${PCRE_LIBRARIES} ${LIBGCC_LIBRARIES})
1165           TRY_MACRO_FOR_LIBRARY(
1166             "${PCRE_INCLUDE_DIR}" "${TMP_LIBRARIES}"
1167             COMPILES
1168             "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1169             "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1170           IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1171             ADD_DEFINITIONS(-DPCRE_STATIC)
1172           ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1173       ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1174     ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1175   ENDIF(PCREPOSIX_FOUND)
1176   MARK_AS_ADVANCED(CLEAR PCRE_INCLUDE_DIR)
1177   MARK_AS_ADVANCED(CLEAR PCREPOSIX_LIBRARIES)
1178   MARK_AS_ADVANCED(CLEAR PCRE_LIBRARIES)
1179   MARK_AS_ADVANCED(CLEAR LIBGCC_LIBRARIES)
1180 ENDIF(NOT FOUND_POSIX_REGEX_LIB AND POSIX_REGEX_LIB MATCHES "^(AUTO|LIBPCREPOSIX)$")
1181
1182 #
1183 # Check functions
1184 #
1185 CMAKE_PUSH_CHECK_STATE()        # Save the state of the variables
1186 IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
1187     CMAKE_C_COMPILER_ID MATCHES "^Clang$")
1188   #
1189   # During checking functions, we should use -fno-builtin to avoid the
1190   # failure of function detection which failure is an error "conflicting
1191   # types for built-in function" caused by using -Werror option.
1192   #
1193   SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-builtin")
1194 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
1195        CMAKE_C_COMPILER_ID MATCHES "^Clang$")
1196 CHECK_SYMBOL_EXISTS(_CrtSetReportMode "crtdbg.h" HAVE__CrtSetReportMode)
1197 CHECK_FUNCTION_EXISTS_GLIBC(arc4random_buf HAVE_ARC4RANDOM_BUF)
1198 CHECK_FUNCTION_EXISTS_GLIBC(chflags HAVE_CHFLAGS)
1199 CHECK_FUNCTION_EXISTS_GLIBC(chown HAVE_CHOWN)
1200 CHECK_FUNCTION_EXISTS_GLIBC(chroot HAVE_CHROOT)
1201 CHECK_FUNCTION_EXISTS_GLIBC(ctime_r HAVE_CTIME_R)
1202 CHECK_FUNCTION_EXISTS_GLIBC(dirfd HAVE_DIRFD)
1203 CHECK_FUNCTION_EXISTS_GLIBC(fchdir HAVE_FCHDIR)
1204 CHECK_FUNCTION_EXISTS_GLIBC(fchflags HAVE_FCHFLAGS)
1205 CHECK_FUNCTION_EXISTS_GLIBC(fchmod HAVE_FCHMOD)
1206 CHECK_FUNCTION_EXISTS_GLIBC(fchown HAVE_FCHOWN)
1207 CHECK_FUNCTION_EXISTS_GLIBC(fcntl HAVE_FCNTL)
1208 CHECK_FUNCTION_EXISTS_GLIBC(fdopendir HAVE_FDOPENDIR)
1209 CHECK_FUNCTION_EXISTS_GLIBC(fork HAVE_FORK)
1210 CHECK_FUNCTION_EXISTS_GLIBC(fstat HAVE_FSTAT)
1211 CHECK_FUNCTION_EXISTS_GLIBC(fstatat HAVE_FSTATAT)
1212 CHECK_FUNCTION_EXISTS_GLIBC(fstatfs HAVE_FSTATFS)
1213 CHECK_FUNCTION_EXISTS_GLIBC(fstatvfs HAVE_FSTATVFS)
1214 CHECK_FUNCTION_EXISTS_GLIBC(ftruncate HAVE_FTRUNCATE)
1215 CHECK_FUNCTION_EXISTS_GLIBC(futimens HAVE_FUTIMENS)
1216 CHECK_FUNCTION_EXISTS_GLIBC(futimes HAVE_FUTIMES)
1217 CHECK_FUNCTION_EXISTS_GLIBC(futimesat HAVE_FUTIMESAT)
1218 CHECK_FUNCTION_EXISTS_GLIBC(geteuid HAVE_GETEUID)
1219 CHECK_FUNCTION_EXISTS_GLIBC(getgrgid_r HAVE_GETGRGID_R)
1220 CHECK_FUNCTION_EXISTS_GLIBC(getgrnam_r HAVE_GETGRNAM_R)
1221 CHECK_FUNCTION_EXISTS_GLIBC(getpwnam_r HAVE_GETPWNAM_R)
1222 CHECK_FUNCTION_EXISTS_GLIBC(getpwuid_r HAVE_GETPWUID_R)
1223 CHECK_FUNCTION_EXISTS_GLIBC(getpid HAVE_GETPID)
1224 CHECK_FUNCTION_EXISTS_GLIBC(getvfsbyname HAVE_GETVFSBYNAME)
1225 CHECK_FUNCTION_EXISTS_GLIBC(gmtime_r HAVE_GMTIME_R)
1226 CHECK_FUNCTION_EXISTS_GLIBC(lchflags HAVE_LCHFLAGS)
1227 CHECK_FUNCTION_EXISTS_GLIBC(lchmod HAVE_LCHMOD)
1228 CHECK_FUNCTION_EXISTS_GLIBC(lchown HAVE_LCHOWN)
1229 CHECK_FUNCTION_EXISTS_GLIBC(link HAVE_LINK)
1230 CHECK_FUNCTION_EXISTS_GLIBC(localtime_r HAVE_LOCALTIME_R)
1231 CHECK_FUNCTION_EXISTS_GLIBC(lstat HAVE_LSTAT)
1232 CHECK_FUNCTION_EXISTS_GLIBC(lutimes HAVE_LUTIMES)
1233 CHECK_FUNCTION_EXISTS_GLIBC(mbrtowc HAVE_MBRTOWC)
1234 CHECK_FUNCTION_EXISTS_GLIBC(memmove HAVE_MEMMOVE)
1235 CHECK_FUNCTION_EXISTS_GLIBC(mkdir HAVE_MKDIR)
1236 CHECK_FUNCTION_EXISTS_GLIBC(mkfifo HAVE_MKFIFO)
1237 CHECK_FUNCTION_EXISTS_GLIBC(mknod HAVE_MKNOD)
1238 CHECK_FUNCTION_EXISTS_GLIBC(mkstemp HAVE_MKSTEMP)
1239 CHECK_FUNCTION_EXISTS_GLIBC(nl_langinfo HAVE_NL_LANGINFO)
1240 CHECK_FUNCTION_EXISTS_GLIBC(openat HAVE_OPENAT)
1241 CHECK_FUNCTION_EXISTS_GLIBC(pipe HAVE_PIPE)
1242 CHECK_FUNCTION_EXISTS_GLIBC(poll HAVE_POLL)
1243 CHECK_FUNCTION_EXISTS_GLIBC(posix_spawnp HAVE_POSIX_SPAWNP)
1244 CHECK_FUNCTION_EXISTS_GLIBC(readlink HAVE_READLINK)
1245 CHECK_FUNCTION_EXISTS_GLIBC(readpassphrase HAVE_READPASSPHRASE)
1246 CHECK_FUNCTION_EXISTS_GLIBC(select HAVE_SELECT)
1247 CHECK_FUNCTION_EXISTS_GLIBC(setenv HAVE_SETENV)
1248 CHECK_FUNCTION_EXISTS_GLIBC(setlocale HAVE_SETLOCALE)
1249 CHECK_FUNCTION_EXISTS_GLIBC(sigaction HAVE_SIGACTION)
1250 CHECK_FUNCTION_EXISTS_GLIBC(statfs HAVE_STATFS)
1251 CHECK_FUNCTION_EXISTS_GLIBC(statvfs HAVE_STATVFS)
1252 CHECK_FUNCTION_EXISTS_GLIBC(strchr HAVE_STRCHR)
1253 CHECK_FUNCTION_EXISTS_GLIBC(strdup HAVE_STRDUP)
1254 CHECK_FUNCTION_EXISTS_GLIBC(strerror HAVE_STRERROR)
1255 CHECK_FUNCTION_EXISTS_GLIBC(strncpy_s HAVE_STRNCPY_S)
1256 CHECK_FUNCTION_EXISTS_GLIBC(strrchr HAVE_STRRCHR)
1257 CHECK_FUNCTION_EXISTS_GLIBC(symlink HAVE_SYMLINK)
1258 CHECK_FUNCTION_EXISTS_GLIBC(timegm HAVE_TIMEGM)
1259 CHECK_FUNCTION_EXISTS_GLIBC(tzset HAVE_TZSET)
1260 CHECK_FUNCTION_EXISTS_GLIBC(unsetenv HAVE_UNSETENV)
1261 CHECK_FUNCTION_EXISTS_GLIBC(utime HAVE_UTIME)
1262 CHECK_FUNCTION_EXISTS_GLIBC(utimes HAVE_UTIMES)
1263 CHECK_FUNCTION_EXISTS_GLIBC(utimensat HAVE_UTIMENSAT)
1264 CHECK_FUNCTION_EXISTS_GLIBC(vfork HAVE_VFORK)
1265 CHECK_FUNCTION_EXISTS_GLIBC(wcrtomb HAVE_WCRTOMB)
1266 CHECK_FUNCTION_EXISTS_GLIBC(wcscmp HAVE_WCSCMP)
1267 CHECK_FUNCTION_EXISTS_GLIBC(wcscpy HAVE_WCSCPY)
1268 CHECK_FUNCTION_EXISTS_GLIBC(wcslen HAVE_WCSLEN)
1269 CHECK_FUNCTION_EXISTS_GLIBC(wctomb HAVE_WCTOMB)
1270 CHECK_FUNCTION_EXISTS_GLIBC(_ctime64_s HAVE__CTIME64_S)
1271 CHECK_FUNCTION_EXISTS_GLIBC(_fseeki64 HAVE__FSEEKI64)
1272 CHECK_FUNCTION_EXISTS_GLIBC(_get_timezone HAVE__GET_TIMEZONE)
1273 CHECK_FUNCTION_EXISTS_GLIBC(_localtime64_s HAVE__LOCALTIME64_S)
1274 CHECK_FUNCTION_EXISTS_GLIBC(_mkgmtime64 HAVE__MKGMTIME64)
1275
1276 SET(CMAKE_REQUIRED_LIBRARIES "")
1277 CHECK_FUNCTION_EXISTS(cygwin_conv_path HAVE_CYGWIN_CONV_PATH)
1278 CHECK_FUNCTION_EXISTS(fseeko HAVE_FSEEKO)
1279 CHECK_FUNCTION_EXISTS(strerror_r HAVE_STRERROR_R)
1280 CHECK_FUNCTION_EXISTS(strftime HAVE_STRFTIME)
1281 CHECK_FUNCTION_EXISTS(vprintf HAVE_VPRINTF)
1282 CHECK_FUNCTION_EXISTS(wmemcmp HAVE_WMEMCMP)
1283 CHECK_FUNCTION_EXISTS(wmemcpy HAVE_WMEMCPY)
1284 CHECK_FUNCTION_EXISTS(wmemmove HAVE_WMEMMOVE)
1285
1286 CMAKE_POP_CHECK_STATE() # Restore the state of the variables
1287
1288 CHECK_C_SOURCE_COMPILES(
1289   "#include <sys/types.h>\n#include <sys/mount.h>\nint main(void) { struct vfsconf v; return sizeof(v);}"
1290   HAVE_STRUCT_VFSCONF)
1291
1292 CHECK_C_SOURCE_COMPILES(
1293   "#include <sys/types.h>\n#include <sys/mount.h>\nint main(void) { struct xvfsconf v; return sizeof(v);}"
1294   HAVE_STRUCT_XVFSCONF)
1295
1296 # Make sure we have the POSIX version of readdir_r, not the
1297 # older 2-argument version.
1298 CHECK_C_SOURCE_COMPILES(
1299   "#include <dirent.h>\nint main() {DIR *d = opendir(\".\"); struct dirent e,*r; return readdir_r(d,&e,&r);}"
1300   HAVE_READDIR_R)
1301
1302
1303 # Only detect readlinkat() if we also have AT_FDCWD in unistd.h.
1304 # NOTE: linux requires fcntl.h for AT_FDCWD.
1305 CHECK_C_SOURCE_COMPILES(
1306   "#include <fcntl.h>\n#include <unistd.h>\nint main() {char buf[10]; return readlinkat(AT_FDCWD, \"\", buf, 0);}"
1307   HAVE_READLINKAT)
1308
1309
1310 # To verify major(), we need to both include the header
1311 # of interest and verify that the result can be linked.
1312 # CHECK_FUNCTION_EXISTS doesn't accept a header argument,
1313 # CHECK_SYMBOL_EXISTS doesn't test linkage.
1314 CHECK_C_SOURCE_COMPILES(
1315   "#include <sys/mkdev.h>\nint main() { return major(256); }"
1316   MAJOR_IN_MKDEV)
1317 CHECK_C_SOURCE_COMPILES(
1318   "#include <sys/sysmacros.h>\nint main() { return major(256); }"
1319   MAJOR_IN_SYSMACROS)
1320
1321 CHECK_C_SOURCE_COMPILES(
1322   "#include <lzma.h>\n#if LZMA_VERSION < 50020000\n#error unsupported\n#endif\nint main(void){lzma_stream_encoder_mt(0, 0); return 0;}"
1323   HAVE_LZMA_STREAM_ENCODER_MT)
1324
1325 IF(HAVE_STRERROR_R)
1326   SET(HAVE_DECL_STRERROR_R 1)
1327 ENDIF(HAVE_STRERROR_R)
1328
1329 #
1330 # Check defines
1331 #
1332 SET(headers "limits.h")
1333 IF(HAVE_STDINT_H)
1334   LIST(APPEND headers "stdint.h")
1335 ENDIF(HAVE_STDINT_H)
1336 IF(HAVE_INTTYPES_H)
1337   LIST(APPEND headers "inttypes.h")
1338 ENDIF(HAVE_INTTYPES_H)
1339 CHECK_SYMBOL_EXISTS(EFTYPE           "errno.h"    HAVE_EFTYPE)
1340 CHECK_SYMBOL_EXISTS(EILSEQ           "errno.h"    HAVE_EILSEQ)
1341 CHECK_SYMBOL_EXISTS(D_MD_ORDER       "langinfo.h" HAVE_D_MD_ORDER)
1342 CHECK_SYMBOL_EXISTS(INT32_MAX        "${headers}" HAVE_DECL_INT32_MAX)
1343 CHECK_SYMBOL_EXISTS(INT32_MIN        "${headers}" HAVE_DECL_INT32_MIN)
1344 CHECK_SYMBOL_EXISTS(INT64_MAX        "${headers}" HAVE_DECL_INT64_MAX)
1345 CHECK_SYMBOL_EXISTS(INT64_MIN        "${headers}" HAVE_DECL_INT64_MIN)
1346 CHECK_SYMBOL_EXISTS(INTMAX_MAX       "${headers}" HAVE_DECL_INTMAX_MAX)
1347 CHECK_SYMBOL_EXISTS(INTMAX_MIN       "${headers}" HAVE_DECL_INTMAX_MIN)
1348 CHECK_SYMBOL_EXISTS(UINT32_MAX       "${headers}" HAVE_DECL_UINT32_MAX)
1349 CHECK_SYMBOL_EXISTS(UINT64_MAX       "${headers}" HAVE_DECL_UINT64_MAX)
1350 CHECK_SYMBOL_EXISTS(UINTMAX_MAX      "${headers}" HAVE_DECL_UINTMAX_MAX)
1351 CHECK_SYMBOL_EXISTS(SIZE_MAX         "${headers}" HAVE_DECL_SIZE_MAX)
1352 CHECK_SYMBOL_EXISTS(SSIZE_MAX        "limits.h"   HAVE_DECL_SSIZE_MAX)
1353
1354 #
1355 # Check struct members
1356 #
1357 # Check for tm_gmtoff in struct tm
1358 CHECK_STRUCT_HAS_MEMBER("struct tm" tm_gmtoff
1359     "time.h" HAVE_STRUCT_TM_TM_GMTOFF)
1360 CHECK_STRUCT_HAS_MEMBER("struct tm" __tm_gmtoff
1361     "time.h" HAVE_STRUCT_TM___TM_GMTOFF)
1362
1363 # Check for f_namemax in struct statfs
1364 CHECK_STRUCT_HAS_MEMBER("struct statfs" f_namemax
1365     "sys/param.h;sys/mount.h" HAVE_STRUCT_STATFS_F_NAMEMAX)
1366
1367 # Check for birthtime in struct stat
1368 CHECK_STRUCT_HAS_MEMBER("struct stat" st_birthtime
1369     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BIRTHTIME)
1370
1371 # Check for high-resolution timestamps in struct stat
1372 CHECK_STRUCT_HAS_MEMBER("struct stat" st_birthtimespec.tv_nsec
1373     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BIRTHTIMESPEC_TV_NSEC)
1374 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
1375     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
1376 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
1377     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
1378 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_n
1379     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIME_N)
1380 CHECK_STRUCT_HAS_MEMBER("struct stat" st_umtime
1381     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_UMTIME)
1382 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_usec
1383     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIME_USEC)
1384 # Check for block size support in struct stat
1385 CHECK_STRUCT_HAS_MEMBER("struct stat" st_blksize
1386     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BLKSIZE)
1387 # Check for st_flags in struct stat (BSD fflags)
1388 CHECK_STRUCT_HAS_MEMBER("struct stat" st_flags
1389     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_FLAGS)
1390
1391 IF(HAVE_SYS_STATVFS_H)
1392   CHECK_STRUCT_HAS_MEMBER("struct statvfs" f_iosize
1393     "sys/types.h;sys/statvfs.h" HAVE_STRUCT_STATVFS_F_IOSIZE)
1394 ENDIF()
1395
1396 #
1397 #
1398 CHECK_STRUCT_HAS_MEMBER("struct tm" tm_sec
1399     "sys/types.h;sys/time.h;time.h" TIME_WITH_SYS_TIME)
1400
1401 #
1402 # Check for integer types
1403 #
1404 #
1405 CHECK_TYPE_SIZE("short" SIZE_OF_SHORT)
1406 CHECK_TYPE_SIZE("int" SIZE_OF_INT)
1407 CHECK_TYPE_SIZE("long" SIZE_OF_LONG)
1408 CHECK_TYPE_SIZE("long long"     SIZE_OF_LONG_LONG)
1409
1410 CHECK_TYPE_SIZE("unsigned short" SIZE_OF_UNSIGNED_SHORT)
1411 CHECK_TYPE_SIZE("unsigned" SIZE_OF_UNSIGNED)
1412 CHECK_TYPE_SIZE("unsigned long" SIZE_OF_UNSIGNED_LONG)
1413 CHECK_TYPE_SIZE("unsigned long long" SIZE_OF_UNSIGNED_LONG_LONG)
1414
1415 CHECK_TYPE_SIZE("__int64" __INT64)
1416 CHECK_TYPE_SIZE("unsigned __int64" UNSIGNED___INT64)
1417
1418 CHECK_TYPE_SIZE(int16_t INT16_T)
1419 CHECK_TYPE_SIZE(int32_t INT32_T)
1420 CHECK_TYPE_SIZE(int64_t INT64_T)
1421 CHECK_TYPE_SIZE(intmax_t INTMAX_T)
1422 CHECK_TYPE_SIZE(uint8_t UINT8_T)
1423 CHECK_TYPE_SIZE(uint16_t UINT16_T)
1424 CHECK_TYPE_SIZE(uint32_t UINT32_T)
1425 CHECK_TYPE_SIZE(uint64_t UINT64_T)
1426 CHECK_TYPE_SIZE(uintmax_t UINTMAX_T)
1427
1428 CHECK_TYPE_SIZE(dev_t       DEV_T)
1429 IF(NOT HAVE_DEV_T)
1430   IF(MSVC)
1431     SET(dev_t "unsigned int")
1432   ENDIF(MSVC)
1433 ENDIF(NOT HAVE_DEV_T)
1434 #
1435 CHECK_TYPE_SIZE(gid_t       GID_T)
1436 IF(NOT HAVE_GID_T)
1437   IF(WIN32)
1438     SET(gid_t "short")
1439   ELSE(WIN32)
1440     SET(gid_t "unsigned int")
1441   ENDIF(WIN32)
1442 ENDIF(NOT HAVE_GID_T)
1443 #
1444 CHECK_TYPE_SIZE(id_t        ID_T)
1445 IF(NOT HAVE_ID_T)
1446   IF(WIN32)
1447     SET(id_t "short")
1448   ELSE(WIN32)
1449     SET(id_t "unsigned int")
1450   ENDIF(WIN32)
1451 ENDIF(NOT HAVE_ID_T)
1452 #
1453 CHECK_TYPE_SIZE(mode_t      MODE_T)
1454 IF(NOT HAVE_MODE_T)
1455   IF(WIN32)
1456     SET(mode_t "unsigned short")
1457   ELSE(WIN32)
1458     SET(mode_t "int")
1459   ENDIF(WIN32)
1460 ENDIF(NOT HAVE_MODE_T)
1461 #
1462 CHECK_TYPE_SIZE(off_t       OFF_T)
1463 IF(NOT HAVE_OFF_T)
1464   SET(off_t "__int64")
1465 ENDIF(NOT HAVE_OFF_T)
1466 #
1467 CHECK_TYPE_SIZE(size_t      SIZE_T)
1468 IF(NOT HAVE_SIZE_T)
1469   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1470     SET(size_t "uint64_t")
1471   ELSE("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1472     SET(size_t   "uint32_t")
1473   ENDIF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1474 ENDIF(NOT HAVE_SIZE_T)
1475 #
1476 CHECK_TYPE_SIZE(ssize_t     SSIZE_T)
1477 IF(NOT HAVE_SSIZE_T)
1478   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1479     SET(ssize_t "int64_t")
1480   ELSE("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1481     SET(ssize_t "long")
1482   ENDIF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1483 ENDIF(NOT HAVE_SSIZE_T)
1484 #
1485 CHECK_TYPE_SIZE(uid_t       UID_T)
1486 IF(NOT HAVE_UID_T)
1487   IF(WIN32)
1488     SET(uid_t "short")
1489   ELSE(WIN32)
1490     SET(uid_t "unsigned int")
1491   ENDIF(WIN32)
1492 ENDIF(NOT HAVE_UID_T)
1493 #
1494 CHECK_TYPE_SIZE(pid_t       PID_T)
1495 IF(NOT HAVE_PID_T)
1496   IF(WIN32)
1497     SET(pid_t "int")
1498   ELSE(WIN32)
1499     MESSAGE(FATAL_ERROR "pid_t doesn't exist on this platform?")
1500   ENDIF(WIN32)
1501 ENDIF(NOT HAVE_PID_T)
1502 #
1503 CHECK_TYPE_SIZE(intptr_t   INTPTR_T)
1504 IF(NOT HAVE_INTPTR_T)
1505   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1506     SET(intptr_t "int64_t")
1507   ELSE()
1508     SET(intptr_t "int32_t")
1509   ENDIF()
1510 ENDIF(NOT HAVE_INTPTR_T)
1511 #
1512 CHECK_TYPE_SIZE(uintptr_t   UINTPTR_T)
1513 IF(NOT HAVE_UINTPTR_T)
1514   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1515     SET(uintptr_t "uint64_t")
1516   ELSE()
1517     SET(uintptr_t "uint32_t")
1518   ENDIF()
1519 ENDIF(NOT HAVE_UINTPTR_T)
1520 #
1521 CHECK_TYPE_SIZE(wchar_t     SIZEOF_WCHAR_T)
1522 IF(HAVE_SIZEOF_WCHAR_T)
1523   SET(HAVE_WCHAR_T 1)
1524 ENDIF(HAVE_SIZEOF_WCHAR_T)
1525 #
1526 # Check if _FILE_OFFSET_BITS macro needed for large files
1527 #
1528 CHECK_FILE_OFFSET_BITS()
1529
1530 #
1531 # Check for Extended Attribute libraries, headers, and functions
1532 #
1533 IF(ENABLE_XATTR)
1534   LA_CHECK_INCLUDE_FILE(attr/xattr.h     HAVE_ATTR_XATTR_H)
1535   LA_CHECK_INCLUDE_FILE(sys/xattr.h      HAVE_SYS_XATTR_H)
1536   LA_CHECK_INCLUDE_FILE(sys/extattr.h      HAVE_SYS_EXTATTR_H)
1537   CHECK_LIBRARY_EXISTS(attr "setxattr" "" HAVE_LIBATTR)
1538   IF(HAVE_LIBATTR)
1539     SET(CMAKE_REQUIRED_LIBRARIES "attr")
1540   ENDIF(HAVE_LIBATTR)
1541   CHECK_SYMBOL_EXISTS(EXTATTR_NAMESPACE_USER "sys/types.h;sys/extattr.h" HAVE_DECL_EXTATTR_NAMESPACE_USER)
1542   CHECK_FUNCTION_EXISTS_GLIBC(extattr_get_file HAVE_EXTATTR_GET_FILE)
1543   CHECK_FUNCTION_EXISTS_GLIBC(extattr_list_file HAVE_EXTATTR_LIST_FILE)
1544   CHECK_FUNCTION_EXISTS_GLIBC(extattr_set_fd HAVE_EXTATTR_SET_FD)
1545   CHECK_FUNCTION_EXISTS_GLIBC(extattr_set_file HAVE_EXTATTR_SET_FILE)
1546   CHECK_FUNCTION_EXISTS_GLIBC(fgetxattr HAVE_FGETXATTR)
1547   CHECK_FUNCTION_EXISTS_GLIBC(flistxattr HAVE_FLISTXATTR)
1548   CHECK_FUNCTION_EXISTS_GLIBC(fsetxattr HAVE_FSETXATTR)
1549   CHECK_FUNCTION_EXISTS_GLIBC(getxattr HAVE_GETXATTR)
1550   CHECK_FUNCTION_EXISTS_GLIBC(lgetxattr HAVE_LGETXATTR)
1551   CHECK_FUNCTION_EXISTS_GLIBC(listxattr HAVE_LISTXATTR)
1552   CHECK_FUNCTION_EXISTS_GLIBC(llistxattr HAVE_LLISTXATTR)
1553   CHECK_FUNCTION_EXISTS_GLIBC(lsetxattr HAVE_LSETXATTR)
1554   CHECK_FUNCTION_EXISTS_GLIBC(fgetea HAVE_FGETEA)
1555   CHECK_FUNCTION_EXISTS_GLIBC(flistea HAVE_FLISTEA)
1556   CHECK_FUNCTION_EXISTS_GLIBC(fsetea HAVE_FSETEA)
1557   CHECK_FUNCTION_EXISTS_GLIBC(getea HAVE_GETEA)
1558   CHECK_FUNCTION_EXISTS_GLIBC(lgetea HAVE_LGETEA)
1559   CHECK_FUNCTION_EXISTS_GLIBC(listea HAVE_LISTEA)
1560   CHECK_FUNCTION_EXISTS_GLIBC(llistea HAVE_LLISTEA)
1561   CHECK_FUNCTION_EXISTS_GLIBC(lsetea HAVE_LSETEA)
1562 ELSE(ENABLE_XATTR)
1563   SET(HAVE_ATTR_LIB FALSE)
1564   SET(HAVE_ATTR_XATTR_H FALSE)
1565   SET(HAVE_DECL_EXTATTR_NAMESPACE_USER FALSE)
1566   SET(HAVE_EXTATTR_GET_FILE FALSE)
1567   SET(HAVE_EXTATTR_LIST_FILE FALSE)
1568   SET(HAVE_EXTATTR_SET_FD FALSE)
1569   SET(HAVE_EXTATTR_SET_FILE FALSE)
1570   SET(HAVE_FGETEA FALSE)
1571   SET(HAVE_FGETXATTR FALSE)
1572   SET(HAVE_FLISTEA FALSE)
1573   SET(HAVE_FLISTXATTR FALSE)
1574   SET(HAVE_FSETEA FALSE)
1575   SET(HAVE_FSETXATTR FALSE)
1576   SET(HAVE_GETEA FALSE)
1577   SET(HAVE_GETXATTR FALSE)
1578   SET(HAVE_LGETEA FALSE)
1579   SET(HAVE_LGETXATTR FALSE)
1580   SET(HAVE_LISTEA FALSE)
1581   SET(HAVE_LISTXATTR FALSE)
1582   SET(HAVE_LLISTEA FALSE)
1583   SET(HAVE_LLISTXATTR FALSE)
1584   SET(HAVE_LSETEA FALSE)
1585   SET(HAVE_LSETXATTR FALSE)
1586   SET(HAVE_SYS_EXTATTR_H FALSE)
1587   SET(HAVE_SYS_XATTR_H FALSE)
1588 ENDIF(ENABLE_XATTR)
1589
1590 #
1591 # Check for ACL libraries, headers, and functions
1592 #
1593 # The ACL support in libarchive is written against the POSIX1e draft,
1594 # which was never officially approved and varies quite a bit across
1595 # platforms.  Worse, some systems have completely non-POSIX acl functions,
1596 # which makes the following checks rather more complex than I would like.
1597 #
1598 IF(ENABLE_ACL)
1599   CHECK_LIBRARY_EXISTS(acl "acl_get_file" "" HAVE_LIBACL)
1600   IF(HAVE_LIBACL)
1601     SET(CMAKE_REQUIRED_LIBRARIES "acl")
1602     FIND_LIBRARY(ACL_LIBRARY NAMES acl)
1603     LIST(APPEND ADDITIONAL_LIBS ${ACL_LIBRARY})
1604   ENDIF(HAVE_LIBACL)
1605   #
1606   CHECK_FUNCTION_EXISTS_GLIBC(acl_create_entry HAVE_ACL_CREATE_ENTRY)
1607   CHECK_FUNCTION_EXISTS_GLIBC(acl_init HAVE_ACL_INIT)
1608   CHECK_FUNCTION_EXISTS_GLIBC(acl_set_fd HAVE_ACL_SET_FD)
1609   CHECK_FUNCTION_EXISTS_GLIBC(acl_set_fd_np HAVE_ACL_SET_FD_NP)
1610   CHECK_FUNCTION_EXISTS_GLIBC(acl_set_file HAVE_ACL_SET_FILE)
1611   CHECK_TYPE_EXISTS(acl_permset_t "${INCLUDES}"    HAVE_ACL_PERMSET_T)
1612
1613   # The "acl_get_perm()" function was omitted from the POSIX draft.
1614   # (It's a pretty obvious oversight; otherwise, there's no way to
1615   # test for specific permissions in a permset.)  Linux uses the obvious
1616   # name, FreeBSD adds _np to mark it as "non-Posix extension."
1617   # Test for both as a double-check that we really have POSIX-style ACL support.
1618   CHECK_FUNCTION_EXISTS(acl_get_fd_np HAVE_ACL_GET_FD_NP)
1619   CHECK_FUNCTION_EXISTS(acl_get_perm HAVE_ACL_GET_PERM)
1620   CHECK_FUNCTION_EXISTS(acl_get_perm_np HAVE_ACL_GET_PERM_NP)
1621   CHECK_FUNCTION_EXISTS(acl_get_link HAVE_ACL_GET_LINK)
1622   CHECK_FUNCTION_EXISTS(acl_get_link_np HAVE_ACL_GET_LINK_NP)
1623   CHECK_FUNCTION_EXISTS(acl_is_trivial_np HAVE_ACL_IS_TRIVIAL_NP)
1624   CHECK_FUNCTION_EXISTS(acl_set_link_np HAVE_ACL_SET_LINK_NP)
1625   CHECK_SYMBOL_EXISTS(ACL_TYPE_NFS4 "${INCLUDES}" HAVE_DECL_ACL_TYPE_NFS4)
1626
1627   # MacOS has an acl.h that isn't POSIX.  It can be detected by
1628   # checking for ACL_USER
1629   CHECK_SYMBOL_EXISTS(ACL_USER "${INCLUDES}" HAVE_DECL_ACL_USER)
1630   CHECK_C_SOURCE_COMPILES("#include <sys/types.h>
1631 #include <sys/acl.h>
1632 int main(void) { return ACL_TYPE_EXTENDED; }" HAVE_DECL_ACL_TYPE_EXTENDED)
1633   CHECK_C_SOURCE_COMPILES("#include <sys/types.h>
1634 #include <sys/acl.h>
1635 int main(void) { return ACL_SYNCHRONIZE; }" HAVE_DECL_ACL_SYNCHRONIZE)
1636
1637   # Solaris and derivates ACLs
1638   CHECK_TYPE_EXISTS(aclent_t "${INCLUDES}" HAVE_ACLENT_T)
1639   CHECK_TYPE_EXISTS(ace_t "${INCLUDES}" HAVE_ACE_T)
1640   CHECK_FUNCTION_EXISTS(acl HAVE_ACL)
1641   CHECK_FUNCTION_EXISTS(facl HAVE_FACL)
1642   CHECK_SYMBOL_EXISTS(GETACL "${INCLUDES}" HAVE_DECL_GETACL)
1643   CHECK_SYMBOL_EXISTS(GETACLCNT "${INCLUDES}" HAVE_DECL_GETACLCNT)
1644   CHECK_SYMBOL_EXISTS(SETACL "${INCLUDES}" HAVE_DECL_SETACL)
1645   CHECK_SYMBOL_EXISTS(ACE_GETACL "${INCLUDES}" HAVE_DECL_ACE_GETACL)
1646   CHECK_SYMBOL_EXISTS(ACE_GETACLCNT "${INCLUDES}" HAVE_DECL_ACE_GETACLCNT)
1647   CHECK_SYMBOL_EXISTS(ACE_SETACL "${INCLUDES}" HAVE_DECL_ACE_SETACL)
1648 ELSE(ENABLE_ACL)
1649   # If someone runs cmake, then disables ACL support, we need
1650   # to forcibly override the cached values for these.
1651   SET(HAVE_ACL_CREATE_ENTRY FALSE)
1652   SET(HAVE_ACL_GET_LINK FALSE)
1653   SET(HAVE_ACL_GET_LINK_NP FALSE)
1654   SET(HAVE_ACL_GET_PERM FALSE)
1655   SET(HAVE_ACL_GET_PERM_NP FALSE)
1656   SET(HAVE_ACL_INIT FALSE)
1657   SET(HAVE_ACL_LIB FALSE)
1658   SET(HAVE_ACL_PERMSET_T FALSE)
1659   SET(HAVE_ACL_SET_FD FALSE)
1660   SET(HAVE_ACL_SET_FD_NP FALSE)
1661   SET(HAVE_ACL_SET_FILE FALSE)
1662   SET(HAVE_ACL_TYPE_EXTENDED FALSE)
1663   SET(HAVE_ACLENT_T FALSE)
1664   SET(HAVE_ACE_T FALSE)
1665   SET(HAVE_DECL_ACL_TYPE_NFS4 FALSE)
1666   SET(HAVE_DECL_ACL_USER FALSE)
1667   SET(HAVE_DECL_ACL_SYNCHRONIZE FALSE)
1668   SET(HAVE_DECL_GETACL FALSE)
1669   SET(HAVE_DECL_GETACLCNT FALSE)
1670   SET(HAVE_DECL_SETACL FALSE)
1671   SET(HAVE_DECL_ACE_GETACL FALSE)
1672   SET(HAVE_DECL_ACE_GETACLCNT FALSE)
1673   SET(HAVE_DECL_ACE_SETACL FALSE)
1674   SET(HAVE_ACL FALSE)
1675   SET(HAVE_FACL FALSE)
1676 ENDIF(ENABLE_ACL)
1677
1678 #
1679 # Check MD5/RMD160/SHA support
1680 # NOTE: Crypto checks must be run last before generating config.h
1681 #
1682 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" LIBC)
1683 CHECK_CRYPTO("SHA256;SHA384;SHA512" LIBC2)
1684 CHECK_CRYPTO("SHA256;SHA384;SHA512" LIBC3)
1685 CHECK_CRYPTO("MD5;SHA1;SHA256;SHA384;SHA512" LIBSYSTEM)
1686 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" NETTLE)
1687 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" OPENSSL)
1688
1689 # Libmd has to be probed after OpenSSL.
1690 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA512" LIBMD)
1691
1692 CHECK_CRYPTO_WIN("MD5;SHA1;SHA256;SHA384;SHA512")
1693
1694 # Generate "config.h" from "build/cmake/config.h.in"
1695 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
1696         ${CMAKE_CURRENT_BINARY_DIR}/config.h)
1697 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
1698 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
1699
1700 # Handle generation of the libarchive.pc file for pkg-config
1701 INCLUDE(CreatePkgConfigFile)
1702
1703 #
1704 # Register installation of PDF documents.
1705 #
1706 IF(WIN32 AND NOT CYGWIN)
1707   #
1708   # On Windows platform, It's better that we install PDF documents
1709   # on one's computer.
1710   # These PDF documents are available in the release package.
1711   #
1712   IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf)
1713     INSTALL(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf
1714             DESTINATION share/man
1715             FILES_MATCHING PATTERN "*.pdf"
1716     )
1717   ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf)
1718 ENDIF(WIN32 AND NOT CYGWIN)
1719 #
1720 #
1721 #
1722 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/libarchive)
1723 #
1724 IF(MSVC)
1725   ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
1726 ENDIF(MSVC)
1727
1728 IF(ENABLE_TEST)
1729   ADD_CUSTOM_TARGET(run_all_tests)
1730 ENDIF(ENABLE_TEST)
1731
1732 add_subdirectory(libarchive)
1733 add_subdirectory(cat)
1734 add_subdirectory(tar)
1735 add_subdirectory(cpio)