acinclude/ax_cxx_compile_stdcxx_11.m4

   1 # ============================================================================
   2 #  http://www.gnu.org/software/autoconf-archive/ax_cxx_compile_stdcxx_11.html
   3 # ============================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_CXX_COMPILE_STDCXX_11([ext|noext],[mandatory|optional])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Check for baseline language coverage in the compiler for the C++11
  12 #   standard; if necessary, add switches to CXXFLAGS to enable support.
  13 #
  14 #   The first argument, if specified, indicates whether you insist on an
  15 #   extended mode (e.g. -std=gnu++11) or a strict conformance mode (e.g.
  16 #   -std=c++11).  If neither is specified, you get whatever works, with
  17 #   preference for an extended mode.
  18 #
  19 #   The second argument, if specified 'mandatory' or if left unspecified,
  20 #   indicates that baseline C++11 support is required and that the macro
  21 #   should error out if no mode with that support is found.  If specified
  22 #   'optional', then configuration proceeds regardless, after defining
  23 #   HAVE_CXX11 if and only if a supporting mode is found.
  24 #
  25 # LICENSE
  26 #
  27 #   Copyright (c) 2008 Benjamin Kosnik <bkoz@redhat.com>
  28 #   Copyright (c) 2012 Zack Weinberg <zackw@panix.com>
  29 #   Copyright (c) 2013 Roy Stogner <roystgnr@ices.utexas.edu>
  30 #   Copyright (c) 2014 Alexey Sokolov <sokolov@google.com>
  31 #
  32 #   Copying and distribution of this file, with or without modification, are
  33 #   permitted in any medium without royalty provided the copyright notice
  34 #   and this notice are preserved. This file is offered as-is, without any
  35 #   warranty.
  36
  37 #serial 4
  38
  39 m4_define([_AX_CXX_COMPILE_STDCXX_11_testbody], [[
  40   template <typename T>
  41     struct check
  42     {
  43       static_assert(sizeof(int) <= sizeof(T), "not big enough");
  44     };
  45
  46     struct Base {
  47     virtual void f() {}
  48     };
  49     struct Child : public Base {
  50     virtual void f() override {}
  51     };
  52
  53     typedef check<check<bool>> right_angle_brackets;
  54
  55     int a;
  56     decltype(a) b;
  57
  58     typedef check<int> check_type;
  59     check_type c;
  60     check_type&& cr = static_cast<check_type&&>(c);
  61
  62     auto d = a;
  63     auto l = [](){};
  64 ]])
  65
  66 AC_DEFUN([AX_CXX_COMPILE_STDCXX_11], [dnl
  67   m4_if([$1], [], [],
  68         [$1], [ext], [],
  69         [$1], [noext], [],
  70         [m4_fatal([invalid argument `$1' to AX_CXX_COMPILE_STDCXX_11])])dnl
  71   m4_if([$2], [], [ax_cxx_compile_cxx11_required=true],
  72         [$2], [mandatory], [ax_cxx_compile_cxx11_required=true],
  73         [$2], [optional], [ax_cxx_compile_cxx11_required=false],
  74         [m4_fatal([invalid second argument `$2' to AX_CXX_COMPILE_STDCXX_11])])
  75   AC_LANG_PUSH([C++])dnl
  76   ac_success=no
  77   AC_CACHE_CHECK(whether $CXX supports C++11 features by default,
  78   ax_cv_cxx_compile_cxx11,
  79   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
  80     [ax_cv_cxx_compile_cxx11=yes],
  81     [ax_cv_cxx_compile_cxx11=no])])
  82   if test x$ax_cv_cxx_compile_cxx11 = xyes; then
  83     ac_success=yes
  84   fi
  85
  86   m4_if([$1], [noext], [], [dnl
  87   if test x$ac_success = xno; then
  88     for switch in -std=gnu++11 -std=gnu++0x; do
  89       cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
  90       AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
  91                      $cachevar,
  92         [ac_save_CXXFLAGS="$CXXFLAGS"
  93          CXXFLAGS="$CXXFLAGS $switch"
  94          AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
  95           [eval $cachevar=yes],
  96           [eval $cachevar=no])
  97          CXXFLAGS="$ac_save_CXXFLAGS"])
  98       if eval test x\$$cachevar = xyes; then
  99         CXXFLAGS="$CXXFLAGS $switch"
 100         ac_success=yes
 101         break
 102       fi
 103     done
 104   fi])
 105
 106   m4_if([$1], [ext], [], [dnl
 107   if test x$ac_success = xno; then
 108     for switch in -std=c++11 -std=c++0x; do
 109       cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
 110       AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
 111                      $cachevar,
 112         [ac_save_CXXFLAGS="$CXXFLAGS"
 113          CXXFLAGS="$CXXFLAGS $switch"
 114          AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
 115           [eval $cachevar=yes],
 116           [eval $cachevar=no])
 117          CXXFLAGS="$ac_save_CXXFLAGS"])
 118       if eval test x\$$cachevar = xyes; then
 119         CXXFLAGS="$CXXFLAGS $switch"
 120         ac_success=yes
 121         break
 122       fi
 123     done
 124   fi])
 125   AC_LANG_POP([C++])
 126   if test x$ax_cxx_compile_cxx11_required = xtrue; then
 127     if test x$ac_success = xno; then
 128       AC_MSG_ERROR([*** A compiler with support for C++11 language features is required.])
 129     fi
 130   else
 131     if test x$ac_success = xno; then
 132       HAVE_CXX11=0
 133       AC_MSG_NOTICE([No compiler with C++11 support was found])
 134     else
 135       HAVE_CXX11=1
 136       AC_DEFINE(HAVE_CXX11,1,
 137                 [define if the compiler supports basic C++11 syntax])
 138     fi
 139
 140     AC_SUBST(HAVE_CXX11)
 141   fi
 142 ])