arch/arm/lib/crt0.S

   1 /*
   2  *  crt0 - C-runtime startup Code for ARM U-Boot
   3  *
   4  *  Copyright (c) 2012  Albert ARIBAUD <albert.u.boot@aribaud.net>
   5  *
   6  * SPDX-License-Identifier:     GPL-2.0+
   7  */
   8
   9 #include <config.h>
  10 #include <asm-offsets.h>
  11 #include <linux/linkage.h>
  12 #ifdef CONFIG_CPU_V7M
  13 #include <asm/armv7m.h>
  14 #endif
  15
  16 /*
  17  * This file handles the target-independent stages of the U-Boot
  18  * start-up where a C runtime environment is needed. Its entry point
  19  * is _main and is branched into from the target's start.S file.
  20  *
  21  * _main execution sequence is:
  22  *
  23  * 1. Set up initial environment for calling board_init_f().
  24  *    This environment only provides a stack and a place to store
  25  *    the GD ('global data') structure, both located in some readily
  26  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  27  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  28  *    CONSTANT initialized data are available. GD should be zeroed
  29  *    before board_init_f() is called.
  30  *
  31  * 2. Call board_init_f(). This function prepares the hardware for
  32  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  33  *    be available yet, , board_init_f() must use the current GD to
  34  *    store any data which must be passed on to later stages. These
  35  *    data include the relocation destination, the future stack, and
  36  *    the future GD location.
  37  *
  38  * 3. Set up intermediate environment where the stack and GD are the
  39  *    ones allocated by board_init_f() in system RAM, but BSS and
  40  *    initialized non-const data are still not available.
  41  *
  42  * 4a.For U-Boot proper (not SPL), call relocate_code(). This function
  43  *    relocates U-Boot from its current location into the relocation
  44  *    destination computed by board_init_f().
  45  *
  46  * 4b.For SPL, board_init_f() just returns (to crt0). There is no
  47  *    code relocation in SPL.
  48  *
  49  * 5. Set up final environment for calling board_init_r(). This
  50  *    environment has BSS (initialized to 0), initialized non-const
  51  *    data (initialized to their intended value), and stack in system
  52  *    RAM (for SPL moving the stack and GD into RAM is optional - see
  53  *    CONFIG_SPL_STACK_R). GD has retained values set by board_init_f().
  54  *
  55  * 6. For U-Boot proper (not SPL), some CPUs have some work left to do
  56  *    at this point regarding memory, so call c_runtime_cpu_setup.
  57  *
  58  * 7. Branch to board_init_r().
  59  *
  60  * For more information see 'Board Initialisation Flow in README.
  61  */
  62
  63 /*
  64  * entry point of crt0 sequence
  65  */
  66
  67 ENTRY(_main)
  68
  69 /*
  70  * Set up initial C runtime environment and call board_init_f(0).
  71  */
  72
  73 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
  74         ldr     r0, =(CONFIG_SPL_STACK)
  75 #else
  76         ldr     r0, =(CONFIG_SYS_INIT_SP_ADDR)
  77 #endif
  78         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
  79         mov     sp, r0
  80         bl      board_init_f_alloc_reserve
  81         mov     sp, r0
  82         /* set up gd here, outside any C code */
  83         mov     r9, r0
  84         bl      board_init_f_init_reserve
  85
  86         mov     r0, #0
  87         bl      board_init_f
  88
  89 #if ! defined(CONFIG_SPL_BUILD)
  90
  91 /*
  92  * Set up intermediate environment (new sp and gd) and call
  93  * relocate_code(addr_moni). Trick here is that we'll return
  94  * 'here' but relocated.
  95  */
  96
  97         ldr     r0, [r9, #GD_START_ADDR_SP]     /* sp = gd->start_addr_sp */
  98         bic     r0, r0, #7      /* 8-byte alignment for ABI compliance */
  99         mov     sp, r0
 100         ldr     r9, [r9, #GD_BD]                /* r9 = gd->bd */
 101         sub     r9, r9, #GD_SIZE                /* new GD is below bd */
 102
 103         adr     lr, here
 104         ldr     r0, [r9, #GD_RELOC_OFF]         /* r0 = gd->reloc_off */
 105         add     lr, lr, r0
 106 #if defined(CONFIG_CPU_V7M)
 107         orr     lr, #1                          /* As required by Thumb-only */
 108 #endif
 109         ldr     r0, [r9, #GD_RELOCADDR]         /* r0 = gd->relocaddr */
 110         b       relocate_code
 111 here:
 112 /*
 113  * now relocate vectors
 114  */
 115
 116         bl      relocate_vectors
 117
 118 /* Set up final (full) environment */
 119
 120         bl      c_runtime_cpu_setup     /* we still call old routine here */
 121 #endif
 122 #if !defined(CONFIG_SPL_BUILD) || defined(CONFIG_SPL_FRAMEWORK)
 123 # ifdef CONFIG_SPL_BUILD
 124         /* Use a DRAM stack for the rest of SPL, if requested */
 125         bl      spl_relocate_stack_gd
 126         cmp     r0, #0
 127         movne   sp, r0
 128         movne   r9, r0
 129 # endif
 130         ldr     r0, =__bss_start        /* this is auto-relocated! */
 131
 132 #ifdef CONFIG_USE_ARCH_MEMSET
 133         ldr     r3, =__bss_end          /* this is auto-relocated! */
 134         mov     r1, #0x00000000         /* prepare zero to clear BSS */
 135
 136         subs    r2, r3, r0              /* r2 = memset len */
 137         bl      memset
 138 #else
 139         ldr     r1, =__bss_end          /* this is auto-relocated! */
 140         mov     r2, #0x00000000         /* prepare zero to clear BSS */
 141
 142 clbss_l:cmp     r0, r1                  /* while not at end of BSS */
 143 #if defined(CONFIG_CPU_V7M)
 144         itt     lo
 145 #endif
 146         strlo   r2, [r0]                /* clear 32-bit BSS word */
 147         addlo   r0, r0, #4              /* move to next */
 148         blo     clbss_l
 149 #endif
 150
 151 #if ! defined(CONFIG_SPL_BUILD)
 152         bl coloured_LED_init
 153         bl red_led_on
 154 #endif
 155         /* call board_init_r(gd_t *id, ulong dest_addr) */
 156         mov     r0, r9                  /* gd_t */
 157         ldr     r1, [r9, #GD_RELOCADDR] /* dest_addr */
 158         /* call board_init_r */
 159 #if CONFIG_IS_ENABLED(SYS_THUMB_BUILD)
 160         ldr     lr, =board_init_r       /* this is auto-relocated! */
 161         bx      lr
 162 #else
 163         ldr     pc, =board_init_r       /* this is auto-relocated! */
 164 #endif
 165         /* we should not return here. */
 166 #endif
 167
 168 ENDPROC(_main)