arch/powerpc/cpu/mpc512x/u-boot.lds

   1 /*
   2  * (C) Copyright 2007-2010 DENX Software Engineering.
   3  *
   4  * SPDX-License-Identifier:     GPL-2.0+
   5  */
   6
   7 OUTPUT_ARCH(powerpc)
   8 SECTIONS
   9 {
  10   .text      :
  11   {
  12     arch/powerpc/cpu/mpc512x/start.o    (.text*)
  13     *(.text*)
  14     . = ALIGN(16);
  15     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  16   }
  17
  18   /* Read-write section, merged into data segment: */
  19   . = (. + 0x0FFF) & 0xFFFFF000;
  20   _erotext = .;
  21   PROVIDE (erotext = .);
  22   .reloc   :
  23   {
  24     _GOT2_TABLE_ = .;
  25     KEEP(*(.got2))
  26     KEEP(*(.got))
  27     _FIXUP_TABLE_ = .;
  28     KEEP(*(.fixup))
  29     *(.fixup)
  30   }
  31   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  32   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  33
  34   .data    :
  35   {
  36     *(.data*)
  37     *(.sdata*)
  38   }
  39   _edata  =  .;
  40   PROVIDE (edata = .);
  41
  42   . = .;
  43
  44   . = ALIGN(4);
  45   .u_boot_list : {
  46         KEEP(*(SORT(.u_boot_list*)));
  47   }
  48
  49
  50   . = .;
  51   __start___ex_table = .;
  52   __ex_table : { *(__ex_table) }
  53   __stop___ex_table = .;
  54
  55   . = ALIGN(4096);
  56   __init_begin = .;
  57   .text.init : { *(.text.init) }
  58   .data.init : { *(.data.init) }
  59   . = ALIGN(4096);
  60   __init_end = .;
  61
  62   __bss_start = .;
  63   .bss (NOLOAD)       :
  64   {
  65    *(.bss*)
  66    *(.sbss*)
  67    *(COMMON)
  68    . = ALIGN(4);
  69   }
  70   __bss_end = . ;
  71   PROVIDE (end = .);
  72 }
  73 ENTRY(_start)