arch/sh/cpu/sh4/u-boot.lds

   1 /*
   2  * Copyright (C) 2007
   3  * Nobuhiro Iwamatsu <iwamatsu@nigauri.org>
   4  *
   5  * Copyright (C) 2008-2009
   6  * Yoshihiro Shimoda <shimoda.yoshihiro@renesas.com>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  28 OUTPUT_ARCH(sh)
  29 ENTRY(_start)
  30
  31 SECTIONS
  32 {
  33         /*
  34          * entry and reloct_dst will be provided via ldflags
  35          */
  36         . = .;
  37
  38         PROVIDE (_ftext = .);
  39         PROVIDE (_fcode = .);
  40         PROVIDE (_start = .);
  41
  42         .text :
  43         {
  44                 KEEP(arch/sh/cpu/sh4/start.o            (.text))
  45                 . = ALIGN(8192);
  46                 common/env_embedded.o   (.ppcenv)
  47                 . = ALIGN(8192);
  48                 common/env_embedded.o   (.ppcenvr)
  49                 . = ALIGN(8192);
  50                 *(.text)
  51                 . = ALIGN(4);
  52         } =0xFF
  53         PROVIDE (_ecode = .);
  54         .rodata :
  55         {
  56                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  57                 . = ALIGN(4);
  58         }
  59         PROVIDE (_etext = .);
  60
  61
  62         PROVIDE (_fdata = .);
  63         .data :
  64         {
  65                 *(.data)
  66                 . = ALIGN(4);
  67         }
  68         PROVIDE (_edata = .);
  69
  70         PROVIDE (_fgot = .);
  71         .got :
  72         {
  73                 *(.got)
  74                 . = ALIGN(4);
  75         }
  76         PROVIDE (_egot = .);
  77
  78         PROVIDE (__u_boot_cmd_start = .);
  79         .u_boot_cmd :
  80         {
  81                 *(.u_boot_cmd)
  82                 . = ALIGN(4);
  83         }
  84         PROVIDE (__u_boot_cmd_end = .);
  85
  86         PROVIDE (reloc_dst_end = .);
  87         /* _reloc_dst_end = .; */
  88
  89         PROVIDE (bss_start = .);
  90         PROVIDE (__bss_start = .);
  91         .bss (NOLOAD) :
  92         {
  93                 *(.bss)
  94                 . = ALIGN(4);
  95         }
  96         PROVIDE (bss_end = .);
  97
  98         PROVIDE (_end = .);
  99 }