arch/sparc/kernel/sys32.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * sys32.S: I-cache tricks for 32-bit compatibility layer simple
   4  *          conversions.
   5  *
   6  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
   7  * Copyright (C) 1998 Jakub Jelinek   (jj@ultra.linux.cz)
   8  */
   9
  10 #include <asm/errno.h>
  11
  12 /* NOTE: call as jump breaks return stack, we have to avoid that */
  13
  14         .text
  15
  16 #define SIGN1(STUB,SYSCALL,REG1) \
  17         .align  32; \
  18         .globl  STUB; \
  19 STUB:   sethi   %hi(SYSCALL), %g1; \
  20         jmpl    %g1 + %lo(SYSCALL), %g0; \
  21         sra     REG1, 0, REG1
  22
  23 #define SIGN2(STUB,SYSCALL,REG1,REG2) \
  24         .align  32; \
  25         .globl  STUB; \
  26 STUB:   sethi   %hi(SYSCALL), %g1; \
  27         sra     REG1, 0, REG1; \
  28         jmpl    %g1 + %lo(SYSCALL), %g0; \
  29         sra     REG2, 0, REG2
  30
  31 #define SIGN3(STUB,SYSCALL,REG1,REG2,REG3) \
  32         .align  32; \
  33         .globl  STUB; \
  34 STUB:   sra     REG1, 0, REG1; \
  35         sethi   %hi(SYSCALL), %g1; \
  36         sra     REG2, 0, REG2; \
  37         jmpl    %g1 + %lo(SYSCALL), %g0; \
  38         sra     REG3, 0, REG3
  39
  40 SIGN1(sys32_readahead, compat_sys_readahead, %o0)
  41 SIGN2(sys32_fadvise64, compat_sys_fadvise64, %o0, %o4)
  42 SIGN2(sys32_fadvise64_64, compat_sys_fadvise64_64, %o0, %o5)
  43 SIGN1(sys32_clock_nanosleep, compat_sys_clock_nanosleep, %o1)
  44 SIGN1(sys32_timer_settime, compat_sys_timer_settime, %o1)
  45 SIGN1(sys32_io_submit, compat_sys_io_submit, %o1)
  46 SIGN1(sys32_mq_open, compat_sys_mq_open, %o1)
  47 SIGN1(sys32_select, compat_sys_select, %o0)
  48 SIGN1(sys32_futex, compat_sys_futex, %o1)
  49 SIGN1(sys32_recvfrom, compat_sys_recvfrom, %o0)
  50 SIGN1(sys32_recvmsg, compat_sys_recvmsg, %o0)
  51 SIGN1(sys32_sendmsg, compat_sys_sendmsg, %o0)
  52 SIGN2(sys32_renameat2, sys_renameat2, %o0, %o2)
  53
  54         .globl          sys32_mmap2
  55 sys32_mmap2:
  56         sethi           %hi(sys_mmap), %g1
  57         jmpl            %g1 + %lo(sys_mmap), %g0
  58          sllx           %o5, 12, %o5
  59
  60         .align          32
  61         .globl          sys32_socketcall
  62 sys32_socketcall:       /* %o0=call, %o1=args */
  63         cmp             %o0, 1
  64         bl,pn           %xcc, do_einval
  65          cmp            %o0, 18
  66         bg,pn           %xcc, do_einval
  67          sub            %o0, 1, %o0
  68         sllx            %o0, 5, %o0
  69         sethi           %hi(__socketcall_table_begin), %g2
  70         or              %g2, %lo(__socketcall_table_begin), %g2
  71         jmpl            %g2 + %o0, %g0
  72          nop
  73 do_einval:
  74         retl
  75          mov            -EINVAL, %o0
  76
  77         .align          32
  78 __socketcall_table_begin:
  79
  80         /* Each entry is exactly 32 bytes. */
  81 do_sys_socket: /* sys_socket(int, int, int) */
  82 1:      ldswa           [%o1 + 0x0] %asi, %o0
  83         sethi           %hi(sys_socket), %g1
  84 2:      ldswa           [%o1 + 0x8] %asi, %o2
  85         jmpl            %g1 + %lo(sys_socket), %g0
  86 3:       ldswa          [%o1 + 0x4] %asi, %o1
  87         nop
  88         nop
  89         nop
  90 do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
  91 4:      ldswa           [%o1 + 0x0] %asi, %o0
  92         sethi           %hi(sys_bind), %g1
  93 5:      ldswa           [%o1 + 0x8] %asi, %o2
  94         jmpl            %g1 + %lo(sys_bind), %g0
  95 6:       lduwa          [%o1 + 0x4] %asi, %o1
  96         nop
  97         nop
  98         nop
  99 do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
 100 7:      ldswa           [%o1 + 0x0] %asi, %o0
 101         sethi           %hi(sys_connect), %g1
 102 8:      ldswa           [%o1 + 0x8] %asi, %o2
 103         jmpl            %g1 + %lo(sys_connect), %g0
 104 9:       lduwa          [%o1 + 0x4] %asi, %o1
 105         nop
 106         nop
 107         nop
 108 do_sys_listen: /* sys_listen(int, int) */
 109 10:     ldswa           [%o1 + 0x0] %asi, %o0
 110         sethi           %hi(sys_listen), %g1
 111         jmpl            %g1 + %lo(sys_listen), %g0
 112 11:      ldswa          [%o1 + 0x4] %asi, %o1
 113         nop
 114         nop
 115         nop
 116         nop
 117 do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
 118 12:     ldswa           [%o1 + 0x0] %asi, %o0
 119         sethi           %hi(sys_accept), %g1
 120 13:     lduwa           [%o1 + 0x8] %asi, %o2
 121         jmpl            %g1 + %lo(sys_accept), %g0
 122 14:      lduwa          [%o1 + 0x4] %asi, %o1
 123         nop
 124         nop
 125         nop
 126 do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
 127 15:     ldswa           [%o1 + 0x0] %asi, %o0
 128         sethi           %hi(sys_getsockname), %g1
 129 16:     lduwa           [%o1 + 0x8] %asi, %o2
 130         jmpl            %g1 + %lo(sys_getsockname), %g0
 131 17:      lduwa          [%o1 + 0x4] %asi, %o1
 132         nop
 133         nop
 134         nop
 135 do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
 136 18:     ldswa           [%o1 + 0x0] %asi, %o0
 137         sethi           %hi(sys_getpeername), %g1
 138 19:     lduwa           [%o1 + 0x8] %asi, %o2
 139         jmpl            %g1 + %lo(sys_getpeername), %g0
 140 20:      lduwa          [%o1 + 0x4] %asi, %o1
 141         nop
 142         nop
 143         nop
 144 do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
 145 21:     ldswa           [%o1 + 0x0] %asi, %o0
 146         sethi           %hi(sys_socketpair), %g1
 147 22:     ldswa           [%o1 + 0x8] %asi, %o2
 148 23:     lduwa           [%o1 + 0xc] %asi, %o3
 149         jmpl            %g1 + %lo(sys_socketpair), %g0
 150 24:      ldswa          [%o1 + 0x4] %asi, %o1
 151         nop
 152         nop
 153 do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
 154 25:     ldswa           [%o1 + 0x0] %asi, %o0
 155         sethi           %hi(sys_send), %g1
 156 26:     lduwa           [%o1 + 0x8] %asi, %o2
 157 27:     lduwa           [%o1 + 0xc] %asi, %o3
 158         jmpl            %g1 + %lo(sys_send), %g0
 159 28:      lduwa          [%o1 + 0x4] %asi, %o1
 160         nop
 161         nop
 162 do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
 163 29:     ldswa           [%o1 + 0x0] %asi, %o0
 164         sethi           %hi(sys_recv), %g1
 165 30:     lduwa           [%o1 + 0x8] %asi, %o2
 166 31:     lduwa           [%o1 + 0xc] %asi, %o3
 167         jmpl            %g1 + %lo(sys_recv), %g0
 168 32:      lduwa          [%o1 + 0x4] %asi, %o1
 169         nop
 170         nop
 171 do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
 172 33:     ldswa           [%o1 + 0x0] %asi, %o0
 173         sethi           %hi(sys_sendto), %g1
 174 34:     lduwa           [%o1 + 0x8] %asi, %o2
 175 35:     lduwa           [%o1 + 0xc] %asi, %o3
 176 36:     lduwa           [%o1 + 0x10] %asi, %o4
 177 37:     ldswa           [%o1 + 0x14] %asi, %o5
 178         jmpl            %g1 + %lo(sys_sendto), %g0
 179 38:      lduwa          [%o1 + 0x4] %asi, %o1
 180 do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
 181 39:     ldswa           [%o1 + 0x0] %asi, %o0
 182         sethi           %hi(sys_recvfrom), %g1
 183 40:     lduwa           [%o1 + 0x8] %asi, %o2
 184 41:     lduwa           [%o1 + 0xc] %asi, %o3
 185 42:     lduwa           [%o1 + 0x10] %asi, %o4
 186 43:     lduwa           [%o1 + 0x14] %asi, %o5
 187         jmpl            %g1 + %lo(sys_recvfrom), %g0
 188 44:      lduwa          [%o1 + 0x4] %asi, %o1
 189 do_sys_shutdown: /* sys_shutdown(int, int) */
 190 45:     ldswa           [%o1 + 0x0] %asi, %o0
 191         sethi           %hi(sys_shutdown), %g1
 192         jmpl            %g1 + %lo(sys_shutdown), %g0
 193 46:      ldswa          [%o1 + 0x4] %asi, %o1
 194         nop
 195         nop
 196         nop
 197         nop
 198 do_sys_setsockopt: /* compat_sys_setsockopt(int, int, int, char *, int) */
 199 47:     ldswa           [%o1 + 0x0] %asi, %o0
 200         sethi           %hi(compat_sys_setsockopt), %g1
 201 48:     ldswa           [%o1 + 0x8] %asi, %o2
 202 49:     lduwa           [%o1 + 0xc] %asi, %o3
 203 50:     ldswa           [%o1 + 0x10] %asi, %o4
 204         jmpl            %g1 + %lo(compat_sys_setsockopt), %g0
 205 51:      ldswa          [%o1 + 0x4] %asi, %o1
 206         nop
 207 do_sys_getsockopt: /* compat_sys_getsockopt(int, int, int, u32, u32) */
 208 52:     ldswa           [%o1 + 0x0] %asi, %o0
 209         sethi           %hi(compat_sys_getsockopt), %g1
 210 53:     ldswa           [%o1 + 0x8] %asi, %o2
 211 54:     lduwa           [%o1 + 0xc] %asi, %o3
 212 55:     lduwa           [%o1 + 0x10] %asi, %o4
 213         jmpl            %g1 + %lo(compat_sys_getsockopt), %g0
 214 56:      ldswa          [%o1 + 0x4] %asi, %o1
 215         nop
 216 do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
 217 57:     ldswa           [%o1 + 0x0] %asi, %o0
 218         sethi           %hi(compat_sys_sendmsg), %g1
 219 58:     lduwa           [%o1 + 0x8] %asi, %o2
 220         jmpl            %g1 + %lo(compat_sys_sendmsg), %g0
 221 59:      lduwa          [%o1 + 0x4] %asi, %o1
 222         nop
 223         nop
 224         nop
 225 do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
 226 60:     ldswa           [%o1 + 0x0] %asi, %o0
 227         sethi           %hi(compat_sys_recvmsg), %g1
 228 61:     lduwa           [%o1 + 0x8] %asi, %o2
 229         jmpl            %g1 + %lo(compat_sys_recvmsg), %g0
 230 62:      lduwa          [%o1 + 0x4] %asi, %o1
 231         nop
 232         nop
 233         nop
 234 do_sys_accept4: /* sys_accept4(int, struct sockaddr *, int *, int) */
 235 63:     ldswa           [%o1 + 0x0] %asi, %o0
 236         sethi           %hi(sys_accept4), %g1
 237 64:     lduwa           [%o1 + 0x8] %asi, %o2
 238 65:     ldswa           [%o1 + 0xc] %asi, %o3
 239         jmpl            %g1 + %lo(sys_accept4), %g0
 240 66:      lduwa          [%o1 + 0x4] %asi, %o1
 241         nop
 242         nop
 243
 244         .section        __ex_table,"a"
 245         .align          4
 246         .word           1b, __retl_efault, 2b, __retl_efault
 247         .word           3b, __retl_efault, 4b, __retl_efault
 248         .word           5b, __retl_efault, 6b, __retl_efault
 249         .word           7b, __retl_efault, 8b, __retl_efault
 250         .word           9b, __retl_efault, 10b, __retl_efault
 251         .word           11b, __retl_efault, 12b, __retl_efault
 252         .word           13b, __retl_efault, 14b, __retl_efault
 253         .word           15b, __retl_efault, 16b, __retl_efault
 254         .word           17b, __retl_efault, 18b, __retl_efault
 255         .word           19b, __retl_efault, 20b, __retl_efault
 256         .word           21b, __retl_efault, 22b, __retl_efault
 257         .word           23b, __retl_efault, 24b, __retl_efault
 258         .word           25b, __retl_efault, 26b, __retl_efault
 259         .word           27b, __retl_efault, 28b, __retl_efault
 260         .word           29b, __retl_efault, 30b, __retl_efault
 261         .word           31b, __retl_efault, 32b, __retl_efault
 262         .word           33b, __retl_efault, 34b, __retl_efault
 263         .word           35b, __retl_efault, 36b, __retl_efault
 264         .word           37b, __retl_efault, 38b, __retl_efault
 265         .word           39b, __retl_efault, 40b, __retl_efault
 266         .word           41b, __retl_efault, 42b, __retl_efault
 267         .word           43b, __retl_efault, 44b, __retl_efault
 268         .word           45b, __retl_efault, 46b, __retl_efault
 269         .word           47b, __retl_efault, 48b, __retl_efault
 270         .word           49b, __retl_efault, 50b, __retl_efault
 271         .word           51b, __retl_efault, 52b, __retl_efault
 272         .word           53b, __retl_efault, 54b, __retl_efault
 273         .word           55b, __retl_efault, 56b, __retl_efault
 274         .word           57b, __retl_efault, 58b, __retl_efault
 275         .word           59b, __retl_efault, 60b, __retl_efault
 276         .word           61b, __retl_efault, 62b, __retl_efault
 277         .word           63b, __retl_efault, 64b, __retl_efault
 278         .word           65b, __retl_efault, 66b, __retl_efault
 279         .previous