board/LEOX/elpt860/u-boot.lds

   1 /*
   2 **=====================================================================
   3 **
   4 ** Copyright (C) 2000, 2001, 2002, 2003
   5 ** The LEOX team <team@leox.org>, http://www.leox.org
   6 **
   7 ** LEOX.org is about the development of free hardware and software resources
   8 **   for system on chip.
   9 **
  10 ** Description: U-Boot port on the LEOX's ELPT860 CPU board
  11 ** ~~~~~~~~~~~
  12 **
  13 **=====================================================================
  14 **
  15 ** This program is free software; you can redistribute it and/or
  16 ** modify it under the terms of the GNU General Public License as
  17 ** published by the Free Software Foundation; either version 2 of
  18 ** the License, or (at your option) any later version.
  19 **
  20 ** This program is distributed in the hope that it will be useful,
  21 ** but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ** MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ** GNU General Public License for more details.
  24 **
  25 ** You should have received a copy of the GNU General Public License
  26 ** along with this program; if not, write to the Free Software
  27 ** Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  28 ** MA 02111-1307 USA
  29 **
  30 **=====================================================================
  31 */
  32
  33 OUTPUT_ARCH(powerpc)
  34
  35 SECTIONS
  36 {
  37   /* Read-only sections, merged into text segment: */
  38   . = + SIZEOF_HEADERS;
  39   .text      :
  40   {
  41     /* WARNING - the following is hand-optimized to fit within  */
  42     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  43
  44     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  45     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  46     common/libcommon.o                  (.text*)
  47     arch/powerpc/cpu/mpc8xx/libmpc8xx.o (.text*)
  48     board/LEOX/elpt860/libelpt860.o     (.text*)
  49     arch/powerpc/lib/libpowerpc.o       (.text*)
  50 /*    drivers/rtc/librtc.o              (.text*)        */
  51
  52     . = env_offset;
  53     common/env_embedded.o               (.text*)
  54
  55     *(.text*)
  56   }
  57   _etext = .;
  58   PROVIDE (etext = .);
  59   .rodata    :
  60   {
  61     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  62   }
  63
  64   /* Read-write section, merged into data segment: */
  65   . = (. + 0x00FF) & 0xFFFFFF00;
  66   _erotext = .;
  67   PROVIDE (erotext = .);
  68   .reloc   :
  69   {
  70     KEEP(*(.got))
  71     _GOT2_TABLE_ = .;
  72     KEEP(*(.got2))
  73     _FIXUP_TABLE_ = .;
  74     KEEP(*(.fixup))
  75   }
  76   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  77   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  78
  79   .data    :
  80   {
  81     *(.data*)
  82     *(.sdata*)
  83   }
  84   _edata  =  .;
  85   PROVIDE (edata = .);
  86
  87   . = .;
  88   __u_boot_cmd_start = .;
  89   .u_boot_cmd : { *(.u_boot_cmd) }
  90   __u_boot_cmd_end = .;
  91
  92   . = .;
  93   __start___ex_table = .;
  94   __ex_table : { *(__ex_table) }
  95   __stop___ex_table = .;
  96
  97   . = ALIGN(256);
  98   __init_begin = .;
  99   .text.init : { *(.text.init) }
 100   .data.init : { *(.data.init) }
 101   . = ALIGN(256);
 102   __init_end = .;
 103
 104   __bss_start = .;
 105   .bss (NOLOAD)       :
 106   {
 107    *(.bss*)
 108    *(.sbss*)
 109    *(COMMON)
 110    . = ALIGN(4);
 111   }
 112   __bss_end__ = . ;
 113   PROVIDE (end = .);
 114 }