board/adder/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2003
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * Modified by Yuli Barcohen <yuli@arabellasw.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .text          :
  32   {
  33     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  34     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  35     *(.text*)
  36     . = ALIGN(16);
  37     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  38   }
  39
  40   /* Read-write section, merged into data segment: */
  41   . = (. + 0x0FFF) & 0xFFFFF000;
  42   _erotext = .;
  43   PROVIDE (erotext = .);
  44   .reloc   :
  45   {
  46     KEEP(*(.got))
  47     _GOT2_TABLE_ = .;
  48     KEEP(*(.got2))
  49     _FIXUP_TABLE_ = .;
  50     KEEP(*(.fixup))
  51   }
  52   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  53   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  54
  55   .data    :
  56   {
  57     *(.data*)
  58     *(.sdata*)
  59   }
  60   _edata  =  .;
  61   PROVIDE (edata = .);
  62
  63   . = .;
  64   __u_boot_cmd_start = .;
  65   .u_boot_cmd : { *(.u_boot_cmd) }
  66   __u_boot_cmd_end = .;
  67
  68
  69   . = .;
  70   __start___ex_table = .;
  71   __ex_table : { *(__ex_table) }
  72   __stop___ex_table = .;
  73
  74   . = ALIGN(4096);
  75   __init_begin = .;
  76   .text.init : { *(.text.init) }
  77   .data.init : { *(.data.init) }
  78   . = ALIGN(4096);
  79   __init_end = .;
  80
  81   __bss_start = .;
  82   .bss (NOLOAD)       :
  83   {
  84    *(.bss*)
  85    *(.sbss*)
  86    *(COMMON)
  87    . = ALIGN(4);
  88   }
  89   _end = . ;
  90   PROVIDE (end = .);
  91 }
  92 ENTRY(_start)