board/bf561-ezkit/u-boot.lds.S

   1 /*
   2  * U-boot - u-boot.lds.S
   3  *
   4  * Copyright (c) 2005-2008 Analog Device Inc.
   5  *
   6  * (C) Copyright 2000-2004
   7  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   8  *
   9  * See file CREDITS for list of people who contributed to this
  10  * project.
  11  *
  12  * This program is free software; you can redistribute it and/or
  13  * modify it under the terms of the GNU General Public License as
  14  * published by the Free Software Foundation; either version 2 of
  15  * the License, or (at your option) any later version.
  16  *
  17  * This program is distributed in the hope that it will be useful,
  18  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  * GNU General Public License for more details.
  21  *
  22  * You should have received a copy of the GNU General Public License
  23  * along with this program; if not, write to the Free Software
  24  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  25  * MA 02111-1307 USA
  26  */
  27
  28 #include <config.h>
  29 #include <asm/blackfin.h>
  30 #undef ALIGN
  31 #undef ENTRY
  32 #undef bfin
  33
  34 /* If we don't actually load anything into L1 data, this will avoid
  35  * a syntax error.  If we do actually load something into L1 data,
  36  * we'll get a linker memory load error (which is what we'd want).
  37  * This is here in the first place so we can quickly test building
  38  * for different CPU's which may lack non-cache L1 data.
  39  */
  40 #ifndef L1_DATA_B_SRAM
  41 # define L1_DATA_B_SRAM      CONFIG_SYS_MONITOR_BASE
  42 # define L1_DATA_B_SRAM_SIZE 0
  43 #endif
  44
  45 OUTPUT_ARCH(bfin)
  46
  47 MEMORY
  48 {
  49         ram     : ORIGIN = CONFIG_SYS_MONITOR_BASE, LENGTH = CONFIG_SYS_MONITOR_LEN
  50         l1_code : ORIGIN = L1_INST_SRAM,            LENGTH = L1_INST_SRAM_SIZE
  51         l1_data : ORIGIN = L1_DATA_B_SRAM,          LENGTH = L1_DATA_B_SRAM_SIZE
  52 }
  53
  54 ENTRY(_start)
  55 SECTIONS
  56 {
  57         .text :
  58         {
  59                 cpu/blackfin/start.o (.text .text.*)
  60
  61 #ifdef ENV_IS_EMBEDDED
  62                 /* WARNING - the following is hand-optimized to fit within
  63                  * the sector before the environment sector. If it throws
  64                  * an error during compilation remove an object here to get
  65                  * it linked after the configuration sector.
  66                  */
  67
  68                 cpu/blackfin/traps.o            (.text .text.*)
  69                 cpu/blackfin/interrupt.o        (.text .text.*)
  70                 cpu/blackfin/serial.o           (.text .text.*)
  71                 common/dlmalloc.o               (.text .text.*)
  72                 lib_generic/crc32.o             (.text .text.*)
  73                 lib_generic/zlib.o              (.text .text.*)
  74                 board/bf561-ezkit/bf561-ezkit.o         (.text .text.*)
  75
  76                 . = DEFINED(env_offset) ? env_offset : .;
  77                 common/env_embedded.o   (.text .text.*)
  78 #endif
  79
  80                 __initcode_start = .;
  81                 cpu/blackfin/initcode.o (.text .text.*)
  82                 __initcode_end = .;
  83
  84                 *(.text .text.*)
  85         } >ram
  86
  87         .rodata :
  88         {
  89                 . = ALIGN(4);
  90                 *(.rodata .rodata.*)
  91                 *(.rodata1)
  92                 *(.eh_frame)
  93                 . = ALIGN(4);
  94         } >ram
  95
  96         .data :
  97         {
  98                 . = ALIGN(256);
  99                 *(.data .data.*)
 100                 *(.data1)
 101                 *(.sdata)
 102                 *(.sdata2)
 103                 *(.dynamic)
 104                 CONSTRUCTORS
 105         } >ram
 106
 107         .u_boot_cmd :
 108         {
 109                 ___u_boot_cmd_start = .;
 110                 *(.u_boot_cmd)
 111                 ___u_boot_cmd_end = .;
 112         } >ram
 113
 114         .text_l1 :
 115         {
 116                 . = ALIGN(4);
 117                 __stext_l1 = .;
 118                 *(.l1.text)
 119                 . = ALIGN(4);
 120                 __etext_l1 = .;
 121         } >l1_code AT>ram
 122         __stext_l1_lma = LOADADDR(.text_l1);
 123
 124         .data_l1 :
 125         {
 126                 . = ALIGN(4);
 127                 __sdata_l1 = .;
 128                 *(.l1.data)
 129                 *(.l1.bss)
 130                 . = ALIGN(4);
 131                 __edata_l1 = .;
 132         } >l1_data AT>ram
 133         __sdata_l1_lma = LOADADDR(.data_l1);
 134
 135         .bss :
 136         {
 137                 . = ALIGN(4);
 138                 __bss_start = .;
 139                 *(.sbss) *(.scommon)
 140                 *(.dynbss)
 141                 *(.bss .bss.*)
 142                 *(COMMON)
 143                 __bss_end = .;
 144         } >ram
 145 }