board/davinci/da8xxevm/u-boot-spl-hawk.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   4  *
   5  * (C) Copyright 2008
   6  * Guennadi Liakhovetki, DENX Software Engineering, <lg@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  28 OUTPUT_ARCH(arm)
  29 ENTRY(_start)
  30 SECTIONS
  31 {
  32         . = 0xc1080000;
  33
  34         . = ALIGN(4);
  35         .text      :
  36         {
  37           arch/arm/cpu/arm926ejs/start.o                (.text)
  38           arch/arm/cpu/arm926ejs/davinci/libdavinci.o   (.text)
  39           drivers/mtd/nand/libnand.o                    (.text)
  40
  41           *(.text*)
  42         }
  43
  44         . = ALIGN(4);
  45         .rodata : { *(.rodata) }
  46
  47         . = ALIGN(4);
  48         .data : {
  49                 *(.data)
  50         __datarel_start = .;
  51                 *(.data.rel)
  52         __datarelrolocal_start = .;
  53                 *(.data.rel.ro.local)
  54         __datarellocal_start = .;
  55                 *(.data.rel.local)
  56         __datarelro_start = .;
  57                 *(.data.rel.ro)
  58         }
  59
  60         . = ALIGN(4);
  61         .u_boot_list : {
  62                 #include <u-boot.lst>
  63         }
  64
  65         . = ALIGN(4);
  66         __rel_dyn_start = .;
  67         __rel_dyn_end = .;
  68         __dynsym_start = .;
  69
  70         __got_start = .;
  71         . = ALIGN(4);
  72         .got : { *(.got) }
  73
  74         __got_end = .;
  75
  76         .bss :
  77         {
  78                 . = ALIGN(4);
  79                 __bss_start = .;
  80                 *(.bss*)
  81                 . = ALIGN(4);
  82                 __bss_end = .;
  83         }
  84
  85         _end = .;
  86 }