board/samsung/common/exynos-uboot-spl.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * (C) Copyright 2002
   4  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   5  *
   6  * Copyright (C) 2012 Samsung Electronics
   7  *
   8  * Based on arch/arm/cpu/armv7/omap-common/u-boot-spl.lds
   9  */
  10
  11 MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE, \
  12                 LENGTH = CONFIG_SPL_MAX_FOOTPRINT }
  13
  14 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  15 OUTPUT_ARCH(arm)
  16 ENTRY(_start)
  17
  18 SECTIONS
  19 {
  20         .text :
  21         {
  22                 __start = .;
  23                 *(.vectors)
  24                 arch/arm/cpu/armv7/start.o (.text*)
  25                 *(.text*)
  26         } >.sram
  27         . = ALIGN(4);
  28
  29         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  30         . = ALIGN(4);
  31
  32         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  33         . = ALIGN(4);
  34
  35         .u_boot_list : {
  36                 KEEP(*(SORT(.u_boot_list*)));
  37         } >.sram
  38         . = ALIGN(4);
  39
  40         .machine_param : { *(.machine_param) } >.sram
  41         . = ALIGN(4);
  42
  43         __image_copy_end = .;
  44
  45         .end :
  46         {
  47                 *(.__end)
  48         } >.sram
  49
  50         .bss :
  51         {
  52                 . = ALIGN(4);
  53                 __bss_start = .;
  54                 *(.bss*)
  55                 . = ALIGN(4);
  56                 __bss_end = .;
  57         } >.sram
  58 }