board/snmc/qs850/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9
  10 SECTIONS
  11 {
  12   /* Read-only sections, merged into text segment: */
  13   . = + SIZEOF_HEADERS;
  14   .text      :
  15   {
  16     /* WARNING - the following is hand-optimized to fit within  */
  17     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  18
  19     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  20     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  21
  22     *(.text*)
  23   }
  24   _etext = .;
  25   PROVIDE (etext = .);
  26   .rodata    :
  27   {
  28     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  29   }
  30
  31   /* Read-write section, merged into data segment: */
  32   . = (. + 0x00FF) & 0xFFFFFF00;
  33   _erotext = .;
  34   PROVIDE (erotext = .);
  35   .reloc   :
  36   {
  37     _GOT2_TABLE_ = .;
  38     KEEP(*(.got2))
  39     KEEP(*(.got))
  40     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  41     _FIXUP_TABLE_ = .;
  42     KEEP(*(.fixup))
  43   }
  44   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  45   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  46
  47   .data    :
  48   {
  49     *(.data*)
  50     *(.sdata*)
  51   }
  52   _edata  =  .;
  53   PROVIDE (edata = .);
  54
  55   . = .;
  56
  57   . = ALIGN(4);
  58   .u_boot_list : {
  59         KEEP(*(SORT(.u_boot_list*)));
  60   }
  61
  62
  63   . = .;
  64   __start___ex_table = .;
  65   __ex_table : { *(__ex_table) }
  66   __stop___ex_table = .;
  67
  68   . = ALIGN(256);
  69   __init_begin = .;
  70   .text.init : { *(.text.init) }
  71   .data.init : { *(.data.init) }
  72   . = ALIGN(256);
  73   __init_end = .;
  74
  75   __bss_start = .;
  76   .bss (NOLOAD)       :
  77   {
  78    *(.bss*)
  79    *(.sbss*)
  80    *(COMMON)
  81    . = ALIGN(4);
  82   }
  83   __bss_end = . ;
  84   PROVIDE (end = .);
  85 }