configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[4],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30
  31 AM_SILENT_RULES([yes])
  32
  33 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  34
  35 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  36         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  37         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  38 ])
  39
  40 AC_PROG_MKDIR_P
  41 AC_PROG_LN_S
  42 AC_PROG_SED
  43
  44 AC_PROG_CC
  45 AC_PROG_CC_C99
  46 AM_PROG_CC_C_O
  47 AC_PROG_GCC_TRADITIONAL
  48 AC_USE_SYSTEM_EXTENSIONS
  49
  50 CC_CHECK_CFLAGS_APPEND([ \
  51         -pipe \
  52         -Wall \
  53         -W \
  54         -Wextra \
  55         -Wno-inline \
  56         -Wvla \
  57         -Wundef \
  58         -Wformat=2 \
  59         -Wlogical-op \
  60         -Wsign-compare \
  61         -Wformat-security \
  62         -Wmissing-include-dirs \
  63         -Wformat-nonliteral \
  64         -Wold-style-definition \
  65         -Wpointer-arith \
  66         -Winit-self \
  67         -Wdeclaration-after-statement \
  68         -Wfloat-equal \
  69         -Wmissing-prototypes \
  70         -Wstrict-prototypes \
  71         -Wredundant-decls \
  72         -Wmissing-declarations \
  73         -Wmissing-noreturn \
  74         -Wshadow \
  75         -Wendif-labels \
  76         -Wcast-align \
  77         -Wstrict-aliasing=2 \
  78         -Wwrite-strings \
  79         -Wno-long-long \
  80         -Wno-overlength-strings \
  81         -Wno-unused-parameter \
  82         -Wno-missing-field-initializers \
  83         -Wno-unused-result \
  84         -Wp,-D_FORTIFY_SOURCE=2 \
  85         -ffast-math \
  86         -fno-common \
  87         -fdiagnostics-show-option \
  88         -fno-strict-aliasing])
  89
  90 LT_PREREQ(2.2)
  91 LT_INIT
  92
  93 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
  94 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
  95 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
  96
  97 # This makes sure pkg.m4 is available.
  98 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  99
 100 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
 101 AC_SUBST(UDEV_CFLAGS)
 102 AC_SUBST(UDEV_LIBS)
 103
 104 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 105 AC_SUBST(DBUS_CFLAGS)
 106 AC_SUBST(DBUS_LIBS)
 107
 108 PKG_CHECK_MODULES(SELINUX, [ libselinux ])
 109 AC_SUBST(SELINUX_CFLAGS)
 110 AC_SUBST(SELINUX_LIBS)
 111 AC_SEARCH_LIBS([is_selinux_enabled], [selinux], [], [AC_MSG_ERROR([*** libselinux library not found])])
 112
 113 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
 114 AC_SUBST(DBUSGLIB_CFLAGS)
 115 AC_SUBST(DBUSGLIB_LIBS)
 116
 117 AC_ARG_ENABLE([tcpwrap],
 118         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 119                 [case "${enableval}" in
 120                         yes) have_tcpwrap=yes ;;
 121                         no) have_tcpwrap=no ;;
 122                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 123                 esac],
 124                 [have_tcpwrap=auto])
 125
 126 if test "x${have_tcpwrap}" != xno ; then
 127         ACX_LIBWRAP
 128         if test "x${LIBWRAP_LIBS}" = x ; then
 129                 if test "x$have_tcpwrap" = xyes ; then
 130                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 131                 fi
 132                 have_tcpwrap=no
 133         else
 134                 have_tcpwrap=yes
 135         fi
 136 else
 137         LIBWRAP_LIBS=
 138 fi
 139 AC_SUBST(LIBWRAP_LIBS)
 140
 141 AC_ARG_ENABLE([pam],
 142         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 143                 [case "${enableval}" in
 144                         yes) have_pam=yes ;;
 145                         no) have_pam=no ;;
 146                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 147                 esac],
 148                 [have_pam=auto])
 149
 150 if test "x${have_pam}" != xno ; then
 151         AC_CHECK_HEADERS(
 152                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 153                 [have_pam=yes],
 154                 [if test "x$have_pam" = xyes ; then
 155                         AC_MSG_ERROR([*** PAM headers not found.])
 156                 fi])
 157
 158         AC_CHECK_LIB(
 159                 [pam],
 160                 [pam_syslog],
 161                 [have_pam=yes],
 162                 [if test "x$have_pam" = xyes ; then
 163                         AC_MSG_ERROR([*** libpam not found.])
 164                 fi])
 165
 166         if test "x$have_pam" = xyes ; then
 167                 PAM_LIBS="-lpam -lpam_misc"
 168                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 169         else
 170                 have_pam=no
 171         fi
 172 else
 173         PAM_LIBS=
 174 fi
 175 AC_SUBST(PAM_LIBS)
 176 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 177
 178 have_gtk=no
 179 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 180 if test "x$enable_gtk" != "xno"; then
 181         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 ],
 182                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 183         AC_SUBST(GTK_CFLAGS)
 184         AC_SUBST(GTK_LIBS)
 185         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 186              AC_MSG_ERROR([*** gtk support requested but libraries not found])
 187         fi
 188 fi
 189 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 190
 191 AM_PROG_VALAC([0.9])
 192 AC_SUBST(VAPIDIR)
 193 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 194
 195 AC_PATH_PROG([XSLTPROC], [xsltproc])
 196 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 197
 198 AC_PATH_PROG([M4], [m4])
 199
 200 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, arch, gentoo, slackware or other]))
 201 if test "z$with_distro" = "z"; then
 202         if test "$cross_compiling" = yes; then
 203                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 204         else
 205                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 206                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 207                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 208                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 209                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 210                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 211         fi
 212         if test "z$with_distro" = "z"; then
 213                 with_distro=`uname -s`
 214         fi
 215 fi
 216 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 217
 218 # Default generic names
 219 SPECIAL_SYSLOG_SERVICE=syslog.service
 220
 221 # Location of the init scripts as mandated by LSB
 222 SYSTEM_SYSVINIT_PATH=/etc/init.d
 223
 224 M4_DISTRO_FLAG=
 225
 226 case $with_distro in
 227         fedora)
 228                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 229                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 230
 231                 # A little background why we define this special unit
 232                 # names here in configure.ac: SysV services currently
 233                 # cannot have aliases. As long as syslog is started
 234                 # via a SysV init script we hence define this name to
 235                 # the actual SysV name here. Later on when SysV init
 236                 # scripts are not used anymore it is advisable to use
 237                 # the generic name instead and use symlinks in the
 238                 # unit directories to point to the right native unit
 239                 # file.
 240
 241                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 242                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 243                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 244                 ;;
 245         suse)
 246                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 247                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 248                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 249                 ;;
 250         debian)
 251                 SYSTEM_SYSVRCND_PATH=/etc
 252                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 253                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
 254                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 255                 ;;
 256         arch)
 257                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 258                 SYSTEM_SYSVRCND_PATH=/etc
 259                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 260                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 261                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 262                 ;;
 263         gentoo)
 264                 SYSTEM_SYSVRCND_PATH=/etc
 265                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 266                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 267                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 268                 ;;
 269         slackware)
 270                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 271                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 272                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 273                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 274                 ;;
 275         other)
 276                 AS_IF([test "x$with_sysvinit_path" = "x"],
 277                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvinit-path= to configure])])
 278                 AS_IF([test "x$with_sysvrcd_path" = "x"],
 279                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvrcd-path= to configure])])
 280                 AS_IF([test "x$with_syslog_service" = "x"],
 281                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 282                 ;;
 283         *)
 284                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 285                 ;;
 286 esac
 287
 288 AC_ARG_WITH([sysvinit-path],
 289         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 290                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 291         [SYSTEM_SYSVINIT_PATH="$withval"],
 292         [])
 293
 294 AC_ARG_WITH([sysvrcd-path],
 295         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 296                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 297         [SYSTEM_SYSVRCND_PATH="$withval"],
 298         [])
 299
 300 AC_ARG_WITH([syslog-service],
 301         [AS_HELP_STRING([--with-syslog-service=UNIT],
 302                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 303         [SPECIAL_SYSLOG_SERVICE="$withval"],
 304         [])
 305
 306 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 307 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 308 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 309 AC_SUBST(M4_DISTRO_FLAG)
 310
 311 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 312 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 313 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 314 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 315 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 316 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 317
 318 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 319
 320 AC_ARG_WITH([dbuspolicydir],
 321         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 322         [],
 323         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 324
 325 AC_ARG_WITH([dbussessionservicedir],
 326         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 327         [],
 328         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 329
 330 AC_ARG_WITH([dbussystemservicedir],
 331         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 332         [],
 333         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 334
 335 AC_ARG_WITH([dbusinterfacedir],
 336         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 337         [],
 338         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 339
 340 AC_ARG_WITH([udevrulesdir],
 341         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 342         [],
 343         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 344
 345 AC_ARG_WITH([pamlibdir],
 346         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 347         [],
 348         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 349
 350 AC_ARG_WITH([rootdir],
 351         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 352         [],
 353         [with_rootdir=${ac_default_prefix}])
 354
 355 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 356 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 357 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 358 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 359 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 360 AC_SUBST([pamlibdir], [$with_pamlibdir])
 361 AC_SUBST([rootdir], [$with_rootdir])
 362
 363 AC_CONFIG_FILES([Makefile])
 364 AC_OUTPUT
 365
 366 echo "
 367         $PACKAGE_NAME $VERSION
 368
 369         Distribution:            ${with_distro}
 370         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 371         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 372         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 373         Gtk:                     ${have_gtk}
 374         tcpwrap:                 ${have_tcpwrap}
 375         PAM:                     ${have_pam}
 376         prefix:                  ${prefix}
 377         root dir:                ${with_rootdir}
 378         udev rules dir:          ${with_udevrulesdir}
 379         pam modules dir:         ${with_pamlibdir}
 380         dbus policy dir:         ${with_dbuspolicydir}
 381         dbus session dir:        ${with_dbussessionservicedir}
 382         dbus system dir:         ${with_dbussystemservicedir}
 383         dbus interfaces dir:     ${with_dbusinterfacedir}
 384 "