configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[10],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30
  31 AM_SILENT_RULES([yes])
  32
  33 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  34
  35 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  36         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  37         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  38 ])
  39
  40 AC_PROG_MKDIR_P
  41 AC_PROG_LN_S
  42 AC_PROG_SED
  43
  44 AC_PROG_CC
  45 AC_PROG_CC_C99
  46 AM_PROG_CC_C_O
  47 AC_PROG_GCC_TRADITIONAL
  48 AC_USE_SYSTEM_EXTENSIONS
  49
  50 CC_CHECK_CFLAGS_APPEND([ \
  51         -pipe \
  52         -Wall \
  53         -W \
  54         -Wextra \
  55         -Wno-inline \
  56         -Wvla \
  57         -Wundef \
  58         -Wformat=2 \
  59         -Wlogical-op \
  60         -Wsign-compare \
  61         -Wformat-security \
  62         -Wmissing-include-dirs \
  63         -Wformat-nonliteral \
  64         -Wold-style-definition \
  65         -Wpointer-arith \
  66         -Winit-self \
  67         -Wdeclaration-after-statement \
  68         -Wfloat-equal \
  69         -Wmissing-prototypes \
  70         -Wstrict-prototypes \
  71         -Wredundant-decls \
  72         -Wmissing-declarations \
  73         -Wmissing-noreturn \
  74         -Wshadow \
  75         -Wendif-labels \
  76         -Wcast-align \
  77         -Wstrict-aliasing=2 \
  78         -Wwrite-strings \
  79         -Wno-long-long \
  80         -Wno-overlength-strings \
  81         -Wno-unused-parameter \
  82         -Wno-missing-field-initializers \
  83         -Wno-unused-result \
  84         -Wp,-D_FORTIFY_SOURCE=2 \
  85         -ffast-math \
  86         -fno-common \
  87         -fdiagnostics-show-option \
  88         -fno-strict-aliasing])
  89
  90 LT_PREREQ(2.2)
  91 LT_INIT
  92
  93 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
  94 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
  95 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
  96 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
  97
  98 # This makes sure pkg.m4 is available.
  99 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 100
 101 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
 102 AC_SUBST(UDEV_CFLAGS)
 103 AC_SUBST(UDEV_LIBS)
 104
 105 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 106 AC_SUBST(DBUS_CFLAGS)
 107 AC_SUBST(DBUS_LIBS)
 108
 109 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
 110 AC_SUBST(DBUSGLIB_CFLAGS)
 111 AC_SUBST(DBUSGLIB_LIBS)
 112
 113 have_selinux=no
 114 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 115 if test "x$enable_selinux" != "xno"; then
 116         # not using PKG_CHECK_MODULES as for some reason libselinux didn't
 117         # install any pkg-config modules here
 118         AC_SEARCH_LIBS([getcon], [selinux],
 119                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELINUX is available]) have_selinux=yes],
 120                 have_selinux=no)
 121         AC_SUBST(SELINUX_CFLAGS)
 122         AC_SUBST(SELINUX_LIBS)
 123         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 124                 AC_MSG_ERROR([*** selinux support requested but libraries not found])
 125         fi
 126 fi
 127 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 128
 129 AC_ARG_ENABLE([tcpwrap],
 130         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 131                 [case "${enableval}" in
 132                         yes) have_tcpwrap=yes ;;
 133                         no) have_tcpwrap=no ;;
 134                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 135                 esac],
 136                 [have_tcpwrap=auto])
 137
 138 if test "x${have_tcpwrap}" != xno ; then
 139         ACX_LIBWRAP
 140         if test "x${LIBWRAP_LIBS}" = x ; then
 141                 if test "x$have_tcpwrap" = xyes ; then
 142                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 143                 fi
 144                 have_tcpwrap=no
 145         else
 146                 have_tcpwrap=yes
 147         fi
 148 else
 149         LIBWRAP_LIBS=
 150 fi
 151 AC_SUBST(LIBWRAP_LIBS)
 152
 153 AC_ARG_ENABLE([pam],
 154         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 155                 [case "${enableval}" in
 156                         yes) have_pam=yes ;;
 157                         no) have_pam=no ;;
 158                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 159                 esac],
 160                 [have_pam=auto])
 161
 162 if test "x${have_pam}" != xno ; then
 163         AC_CHECK_HEADERS(
 164                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 165                 [have_pam=yes],
 166                 [if test "x$have_pam" = xyes ; then
 167                         AC_MSG_ERROR([*** PAM headers not found.])
 168                 fi])
 169
 170         AC_CHECK_LIB(
 171                 [pam],
 172                 [pam_syslog],
 173                 [have_pam=yes],
 174                 [if test "x$have_pam" = xyes ; then
 175                         AC_MSG_ERROR([*** libpam not found.])
 176                 fi])
 177
 178         if test "x$have_pam" = xyes ; then
 179                 PAM_LIBS="-lpam -lpam_misc"
 180                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 181         else
 182                 have_pam=no
 183         fi
 184 else
 185         PAM_LIBS=
 186 fi
 187 AC_SUBST(PAM_LIBS)
 188 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 189
 190 AC_ARG_ENABLE([audit],
 191         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 192                 [case "${enableval}" in
 193                         yes) have_audit=yes ;;
 194                         no) have_audit=no ;;
 195                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 196                 esac],
 197                 [have_audit=auto])
 198
 199 if test "x${have_audit}" != xno ; then
 200         AC_CHECK_HEADERS(
 201                 [libaudit.h],
 202                 [have_audit=yes],
 203                 [if test "x$have_audit" = xyes ; then
 204                         AC_MSG_ERROR([*** AUDIT headers not found.])
 205                 fi])
 206
 207         AC_CHECK_LIB(
 208                 [audit],
 209                 [audit_open],
 210                 [have_audit=yes],
 211                 [if test "x$have_audit" = xyes ; then
 212                         AC_MSG_ERROR([*** libaudit not found.])
 213                 fi])
 214
 215         if test "x$have_audit" = xyes ; then
 216                 AUDIT_LIBS="-laudit"
 217                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 218         else
 219                 have_audit=no
 220         fi
 221 else
 222         AUDIT_LIBS=
 223 fi
 224 AC_SUBST(AUDIT_LIBS)
 225
 226 have_gtk=no
 227 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 228 if test "x$enable_gtk" != "xno"; then
 229         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 gio-unix-2.0 ],
 230                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 231         AC_SUBST(GTK_CFLAGS)
 232         AC_SUBST(GTK_LIBS)
 233         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 234              AC_MSG_ERROR([*** gtk support requested but libraries not found])
 235         fi
 236 fi
 237 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 238
 239 AM_PROG_VALAC([0.9])
 240 AC_SUBST(VAPIDIR)
 241 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 242
 243 AC_PATH_PROG([XSLTPROC], [xsltproc])
 244 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 245
 246 AC_PATH_PROG([M4], [m4])
 247
 248 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, arch, gentoo, slackware or other]))
 249 if test "z$with_distro" = "z"; then
 250         if test "$cross_compiling" = yes; then
 251                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 252         else
 253                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 254                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 255                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 256                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 257                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 258                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 259         fi
 260         if test "z$with_distro" = "z"; then
 261                 with_distro=`uname -s`
 262         fi
 263 fi
 264 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 265 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 266
 267 # Default generic names
 268 SPECIAL_SYSLOG_SERVICE=syslog.service
 269
 270 # Location of the init scripts as mandated by LSB
 271 SYSTEM_SYSVINIT_PATH=/etc/init.d
 272
 273 M4_DISTRO_FLAG=
 274
 275 case $with_distro in
 276         fedora)
 277                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 278                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 279
 280                 # A little background why we define this special unit
 281                 # names here in configure.ac: SysV services currently
 282                 # cannot have aliases. As long as syslog is started
 283                 # via a SysV init script we hence define this name to
 284                 # the actual SysV name here. Later on when SysV init
 285                 # scripts are not used anymore it is advisable to use
 286                 # the generic name instead and use symlinks in the
 287                 # unit directories to point to the right native unit
 288                 # file.
 289
 290                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 291                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 292                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 293                 ;;
 294         suse)
 295                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 296                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 297                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 298                 ;;
 299         debian)
 300                 SYSTEM_SYSVRCND_PATH=/etc
 301                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 302                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
 303                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 304                 ;;
 305         arch)
 306                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 307                 SYSTEM_SYSVRCND_PATH=/etc
 308                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 309                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 310                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 311                 ;;
 312         gentoo)
 313                 SYSTEM_SYSVRCND_PATH=/etc
 314                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 315                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 316                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 317                 ;;
 318         slackware)
 319                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 320                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 321                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 322                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 323                 ;;
 324         other)
 325                 AS_IF([test "x$with_sysvinit_path" = "x"],
 326                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvinit-path= to configure])])
 327                 AS_IF([test "x$with_sysvrcd_path" = "x"],
 328                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvrcd-path= to configure])])
 329                 AS_IF([test "x$with_syslog_service" = "x"],
 330                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 331                 ;;
 332         *)
 333                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 334                 ;;
 335 esac
 336
 337 AC_ARG_WITH([sysvinit-path],
 338         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 339                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 340         [SYSTEM_SYSVINIT_PATH="$withval"],
 341         [])
 342
 343 AC_ARG_WITH([sysvrcd-path],
 344         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 345                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 346         [SYSTEM_SYSVRCND_PATH="$withval"],
 347         [])
 348
 349 AC_ARG_WITH([syslog-service],
 350         [AS_HELP_STRING([--with-syslog-service=UNIT],
 351                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 352         [SPECIAL_SYSLOG_SERVICE="$withval"],
 353         [])
 354
 355 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 356 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 357 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 358 AC_SUBST(M4_DISTRO_FLAG)
 359
 360 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 361 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 362 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 363 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 364 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 365 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 366
 367 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 368
 369 AC_ARG_WITH([dbuspolicydir],
 370         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 371         [],
 372         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 373
 374 AC_ARG_WITH([dbussessionservicedir],
 375         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 376         [],
 377         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 378
 379 AC_ARG_WITH([dbussystemservicedir],
 380         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 381         [],
 382         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 383
 384 AC_ARG_WITH([dbusinterfacedir],
 385         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 386         [],
 387         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 388
 389 AC_ARG_WITH([udevrulesdir],
 390         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 391         [],
 392         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 393
 394 AC_ARG_WITH([pamlibdir],
 395         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 396         [],
 397         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 398
 399 AC_ARG_WITH([rootdir],
 400         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 401         [],
 402         [with_rootdir=${ac_default_prefix}])
 403
 404 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 405 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 406 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 407 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 408 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 409 AC_SUBST([pamlibdir], [$with_pamlibdir])
 410 AC_SUBST([rootdir], [$with_rootdir])
 411
 412 AC_CONFIG_FILES([Makefile])
 413 AC_OUTPUT
 414
 415 echo "
 416         $PACKAGE_NAME $VERSION
 417
 418         Distribution:            ${with_distro}
 419         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 420         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 421         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 422         Gtk:                     ${have_gtk}
 423         tcpwrap:                 ${have_tcpwrap}
 424         PAM:                     ${have_pam}
 425         AUDIT:                   ${have_audit}
 426         SELinux:                 ${have_selinux}
 427         prefix:                  ${prefix}
 428         root dir:                ${with_rootdir}
 429         udev rules dir:          ${with_udevrulesdir}
 430         pam modules dir:         ${with_pamlibdir}
 431         dbus policy dir:         ${with_dbuspolicydir}
 432         dbus session dir:        ${with_dbussessionservicedir}
 433         dbus system dir:         ${with_dbussystemservicedir}
 434         dbus interfaces dir:     ${with_dbusinterfacedir}
 435 "