configure.ac

   1 AC_PREREQ([2.61])
   2
   3 AC_INIT([pdns], m4_esyscmd([build-aux/gen-version]))
   4
   5 AC_CONFIG_SRCDIR([pdns/receiver.cc])
   6 AC_CONFIG_MACRO_DIR([m4])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_AUX_DIR([build-aux])
   9
  10 AC_SUBST([pdns_configure_args], ["$ac_configure_args"])
  11 AC_DEFINE_UNQUOTED([PDNS_CONFIG_ARGS],
  12   ["$pdns_configure_args"],
  13   [pdns configure arguments]
  14 )
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar -Wno-portability subdir-objects parallel-tests 1.11])
  17 AM_SILENT_RULES([yes])
  18
  19 AC_CANONICAL_HOST
  20 : ${CFLAGS="-Wall -g -O2"}
  21 : ${CXXFLAGS="-Wall -g -O2"}
  22
  23 AC_PROG_CC
  24 AM_PROG_CC_C_O
  25 PDNS_CHECK_BISON
  26 PDNS_CHECK_FLEX
  27 AC_PROG_INSTALL
  28 AC_PROG_MAKE_SET
  29
  30 AC_PROG_CXX
  31 AS_IF([test "x$CXX" = "xno" || test "x$CXX:x$GXX" = "xg++:x"],
  32   [AC_MSG_ERROR([no C++ compiler found])]
  33 )
  34
  35 AC_LANG([C++])
  36
  37 AC_DEFINE([_GNU_SOURCE], [1],
  38   [Define _GNU_SOURCE so that we get all necessary prototypes]
  39 )
  40
  41 # Warn when pkg.m4 is missing
  42 m4_pattern_forbid([^_?PKG_[A-Z_]+$], [*** pkg.m4 missing, please install pkg-config])
  43
  44 PDNS_CHECK_OS
  45
  46 PDNS_WITH_LUA
  47 PDNS_CHECK_LUA_HPP
  48
  49 AX_CXX_COMPILE_STDCXX_11
  50
  51 AC_MSG_CHECKING([whether we will enable compiler security checks])
  52 AC_ARG_ENABLE([hardening],
  53   [AS_HELP_STRING([--disable-hardening], [disable compiler security checks @<:@default=no@:>@])],
  54   [enable_hardening=$enableval],
  55   [enable_hardening=yes]
  56 )
  57 AC_MSG_RESULT([$enable_hardening])
  58
  59 AS_IF([test "x$enable_hardening" != "xno"], [
  60   AC_CC_PIE
  61   AC_CC_STACK_PROTECTOR
  62   AC_CC_PARAM_SSP_BUFFER_SIZE([4])
  63   AC_CC_D_FORTIFY_SOURCE
  64   AC_LD_RELRO
  65 ])
  66
  67 PDNS_ENABLE_KISS
  68
  69 PDNS_CHECK_NETWORK_LIBS
  70
  71 LT_PREREQ([2.2.2])
  72 LT_INIT([disable-static dlopen])
  73
  74
  75 MC_TM_GMTOFF
  76
  77 # Define full_libdir to be the fully expanded (${exec_prefix}, etc.)
  78 # "system" library path.
  79 # We use this to search for other libraries.
  80 eval full_libdir="\"$libdir\""
  81
  82 # detect pkg-config explicitly
  83 PKG_PROG_PKG_CONFIG
  84
  85 AC_CHECK_HEADERS(
  86         [sys/mman.h],
  87         [AC_CHECK_FUNC(
  88                 [mmap],
  89                 [AC_DEFINE(HAVE_MMAP, [1], [Define to 1 if you have mmap])],
  90                 [have_mmap=no]
  91         )],
  92         [have_mmap=no]
  93 )
  94
  95 PDNS_ENABLE_BOTAN
  96 PDNS_CHECK_LIBSODIUM
  97 PDNS_CHECK_LIBDECAF
  98 PDNS_CHECK_LIBCRYPTO([
  99 ],[
 100    AC_MSG_ERROR([OpenSSL/libcrypto not found])
 101   ]
 102 )
 103 PDNS_CHECK_LIBCRYPTO_ECDSA
 104
 105 PDNS_CHECK_RAGEL([pdns/dnslabeltext.cc], [www.powerdns.com])
 106 PDNS_CHECK_CLOCK_GETTIME
 107
 108 BOOST_REQUIRE([1.35])
 109 # Boost accumulators, as used by dnsbulktest and dnstcpbench, need 1.48+
 110 # to be compatible with C++11
 111 AM_CONDITIONAL([HAVE_BOOST_GE_148], [test "$boost_major_version" -ge 148])
 112
 113 BOOST_PROGRAM_OPTIONS([mt])
 114 AS_IF([test "$boost_cv_lib_program_options" = "no"], [
 115   AC_MSG_ERROR([Boost Program Options library not found])
 116 ])
 117 PDNS_ENABLE_UNIT_TESTS
 118 PDNS_ENABLE_BACKEND_UNIT_TESTS
 119 PDNS_ENABLE_REPRODUCIBLE
 120
 121 PDNS_WITH_SQLITE3
 122
 123 PDNS_CHECK_VIRTUALENV
 124 PDNS_FROM_GIT
 125
 126 dnl Checks for library functions.
 127 AC_CHECK_FUNCS_ONCE([strcasestr localtime_r recvmmsg getrandom arc4random])
 128
 129 AM_CONDITIONAL([HAVE_RECVMMSG], [test "x$ac_cv_func_recvmmsg" = "xyes"])
 130
 131 AS_IF([test "x$lt_cv_dlopen" = "xno"],
 132   [AC_MSG_ERROR([Your system does not support dlopen])]
 133 )
 134
 135 AC_SUBST([LIBDL], [$lt_cv_dlopen_libs])
 136
 137 PDNS_ENABLE_VERBOSE_LOGGING
 138 PDNS_ENABLE_PKCS11
 139 PDNS_ENABLE_GSS_TSIG
 140
 141 AC_SUBST([socketdir])
 142 socketdir="/var/run"
 143 AC_ARG_WITH([socketdir],
 144   [AS_HELP_STRING([--with-socketdir], [where the controlsocket lives @<:@default=/var/run@:>@])],
 145   [socketdir="$withval"]
 146 )
 147
 148 modules="bind gmysql random"
 149 AC_ARG_WITH([modules],
 150   [AS_HELP_STRING([--with-modules], [which backends to compile with @<:@default=bind gmysql random@:>@])],
 151   [modules="$withval"]
 152 )
 153
 154 dynmodules="pipe"
 155 AC_ARG_WITH([dynmodules],
 156   [AS_HELP_STRING([--with-dynmodules], [which backends to build for dynamic loading @<:@default=pipe@:>@])],
 157   [dynmodules="$withval"]
 158 )
 159
 160 AC_SUBST([moduledirs])
 161 AC_SUBST([moduleobjects])
 162 AC_SUBST([modulelibs])
 163 AC_DEFINE_UNQUOTED([PDNS_MODULES], "$modules", [Built-in modules])
 164
 165 AS_IF([test x"$modules" = "xno"], [modules=""])
 166 AS_IF([test x"$dynmodules" = "xno"], [dynmodules=""])
 167
 168 for a in $modules $dynmodules; do
 169   case "$a" in
 170     oracle|goracle)
 171       PDNS_WITH_ORACLE
 172       needoracle=yes
 173       ;;
 174     godbc)
 175       PDNS_WITH_UNIXODBC
 176       ;;
 177     mydns|gmysql|pdns)
 178       PDNS_WITH_MYSQL
 179       ;;
 180     gpgsql)
 181       PDNS_WITH_POSTGRESQL
 182       ;;
 183     gsqlite3)
 184       needsqlite3=yes
 185       ;;
 186     ldap)
 187       PDNS_CHECK_LDAP
 188       needldap=yes
 189       ;;
 190     opendbx)
 191       PDNS_CHECK_OPENDBX
 192       ;;
 193     remote)
 194       AS_IF([test "x$enable_unit_tests" = "xyes"],
 195         [PDNS_CHECK_CURL_PROGRAM]
 196       )
 197       have_remotebackend=yes
 198       ;;
 199     tinydns)
 200       PDNS_CHECK_CDB
 201       ;;
 202     geoip)
 203       PDNS_CHECK_GEOIP
 204       ;;
 205     lua*)
 206       AS_IF([test "x$with_lua" = "xno"],
 207         [AC_MSG_ERROR([${a} backend needs lua, run ./configure --with-lua])]
 208       )
 209       AS_IF([test "x$LUAPC" = "x"],
 210         [AC_MSG_ERROR([${a} backend needs lua but we cannot find it])]
 211       )
 212       ;;
 213   esac
 214 done
 215
 216 PDNS_ENABLE_REMOTEBACKEND_ZEROMQ
 217
 218 AC_MSG_CHECKING([whether we will be building and installing the extra tools])
 219 AC_ARG_ENABLE([tools],
 220   [AS_HELP_STRING([--enable-tools], [if we should build and install the tools @<:@default=no@:>@])],
 221   [enable_tools=$enableval],
 222   [enable_tools=no]
 223 )
 224
 225 AC_MSG_RESULT([$enable_tools])
 226 AM_CONDITIONAL([TOOLS], [test "x$enable_tools" != "xno"])
 227
 228 PDNS_WITH_PROTOBUF
 229
 230 PDNS_WITH_LUA_RECORDS
 231
 232 AM_CONDITIONAL([ORACLE], [test "x$needoracle" = "xyes"])
 233
 234 AM_CONDITIONAL([LDAP], [test "x$needldap" = "xyes"])
 235
 236 PDNS_CHECK_SQLITE3
 237 AM_CONDITIONAL([SQLITE3], [test "x$needsqlite3" = "xyes"])
 238
 239 for a in $modules; do
 240   AC_MSG_CHECKING([whether we can build module "${a}"])
 241   if [[ -d "$srcdir/modules/${a}backend" ]]; then
 242     AC_MSG_RESULT([yes])
 243     moduledirs="$moduledirs ${a}backend"
 244
 245     for b in `cat $srcdir/modules/${a}backend/OBJECTFILES`; do
 246       moduleobjects="$moduleobjects ../modules/${a}backend/$b"
 247     done
 248     modulelibs="$modulelibs `cat $srcdir/modules/${a}backend/OBJECTLIBS`"
 249   else
 250     AC_MSG_RESULT([no])
 251     AC_MSG_ERROR([Do not know how to build module "$a", "$srcdir/modules/${a}backend" does not exist! Please review --with-modules parameter for supported values.])
 252   fi
 253 done
 254
 255 for a in $dynmodules; do
 256   AC_MSG_CHECKING([whether we can build dynamic module "${a}"])
 257   if [[ -d "$srcdir/modules/${a}backend" ]]; then
 258     AC_MSG_RESULT([yes])
 259     moduledirs="$moduledirs ${a}backend"
 260   else
 261     AC_MSG_RESULT([no])
 262     AC_MSG_ERROR([Do not know how to build module "$a", "$srcdir/modules/${a}backend" does not exist! Please review --with-dynmodules parameter for supported values.])
 263   fi
 264 done
 265
 266 AX_AVAILABLE_SYSTEMD
 267 AM_CONDITIONAL([HAVE_SYSTEMD], [ test x"$systemd" = "xy" ])
 268
 269 LDFLAGS="$RELRO_LDFLAGS $LDFLAGS"
 270
 271 CFLAGS="$PIE_CFLAGS $CFLAGS"
 272 CXXFLAGS="$PIE_CFLAGS $CXXFLAGS"
 273 PROGRAM_LDFLAGS="$PIE_LDFLAGS $PROGRAM_LDFLAGS"
 274 AC_SUBST([PROGRAM_LDFLAGS])
 275
 276 PDNS_ENABLE_COVERAGE
 277 PDNS_ENABLE_SANITIZERS
 278 PDNS_ENABLE_MALLOC_TRACE
 279
 280 AC_SUBST(LIBS)
 281
 282 AC_SUBST([AM_CPPFLAGS],
 283   ["AS_ESCAPE([-I$(top_builddir) -I$(top_srcdir)]) $THREADFLAGS $BOOST_CPPFLAGS"]
 284 )
 285
 286 AC_SUBST([YAHTTP_CFLAGS], ['-I$(top_srcdir)/ext/yahttp'])
 287 AC_SUBST([YAHTTP_LIBS], ['$(top_builddir)/ext/yahttp/yahttp/libyahttp.la'])
 288
 289 CXXFLAGS="$SANITIZER_FLAGS $CXXFLAGS"
 290
 291 AC_ARG_VAR(PACKAGEVERSION, [The version used in secpoll queries])
 292 AS_IF([test "x$PACKAGEVERSION" != "x"],
 293   [AC_DEFINE_UNQUOTED([PACKAGEVERSION], "$PACKAGEVERSION", [Set to the package version used for secpoll])]
 294 )
 295
 296 export moduledirs moduleobjects modulelibs
 297
 298 AC_CONFIG_FILES([
 299   Makefile
 300   modules/Makefile
 301   pdns/Makefile
 302   codedocs/Makefile
 303   docs/Makefile
 304   pdns/pdns.init
 305   ext/Makefile
 306   ext/yahttp/Makefile
 307   ext/yahttp/yahttp/Makefile
 308   ext/json11/Makefile
 309   modules/bindbackend/Makefile
 310   modules/geoipbackend/Makefile
 311   modules/gmysqlbackend/Makefile
 312   modules/godbcbackend/Makefile
 313   modules/goraclebackend/Makefile
 314   modules/gpgsqlbackend/Makefile
 315   modules/gsqlite3backend/Makefile
 316   modules/ldapbackend/Makefile
 317   modules/luabackend/Makefile
 318   modules/lua2backend/Makefile
 319   modules/mydnsbackend/Makefile
 320   modules/opendbxbackend/Makefile
 321   modules/oraclebackend/Makefile
 322   modules/pipebackend/Makefile
 323   modules/randombackend/Makefile
 324   modules/remotebackend/Makefile
 325   modules/tinydnsbackend/Makefile
 326 ])
 327 AC_OUTPUT
 328
 329 AC_MSG_NOTICE([])
 330 AC_MSG_NOTICE([Configuration summary])
 331 AC_MSG_NOTICE([=====================])
 332 AC_MSG_NOTICE([])
 333 AC_MSG_NOTICE([Configured with: $pdns_configure_args])
 334 AC_MSG_NOTICE([])
 335 AC_MSG_NOTICE([CC: $CC])
 336 AC_MSG_NOTICE([CXX: $CXX])
 337 AC_MSG_NOTICE([LD: $LD])
 338 AC_MSG_NOTICE([CFLAGS: $CFLAGS])
 339 AC_MSG_NOTICE([CPPFLAGS: $CPPFLAGS])
 340 AC_MSG_NOTICE([CXXFLAGS: $CXXFLAGS])
 341 AC_MSG_NOTICE([LDFLAGS: $LDFLAGS])
 342 AC_MSG_NOTICE([LIBS: $LIBS])
 343 AC_MSG_NOTICE([BOOST_CPPFLAGS: $BOOST_CPPFLAGS])
 344 AC_MSG_NOTICE([])
 345 AC_MSG_NOTICE([Features enabled])
 346 AC_MSG_NOTICE([----------------])
 347 AC_MSG_NOTICE([Built-in modules: $modules])
 348 AC_MSG_NOTICE([Dynamic modules: $dynmodules])
 349 AC_MSG_NOTICE([])
 350 AS_IF([test "x$libcrypto_ecdsa" = "xyes"],
 351   [AC_MSG_NOTICE([OpenSSL ecdsa: yes])],
 352   [AC_MSG_NOTICE([OpenSSL ecdsa: no])]
 353 )
 354 AS_IF([test "x$LIBSODIUM_LIBS" != "x" || test "x$LIBDECAF_LIBS" != "x"],
 355   [AC_MSG_NOTICE([ed25519: yes])],
 356   [AC_MSG_NOTICE([ed25519: no])]
 357 )
 358 AS_IF([test "x$LIBDECAF_LIBS" != "x"],
 359   [AC_MSG_NOTICE([ed448: yes])],
 360   [AC_MSG_NOTICE([ed448: no])]
 361 )
 362 AS_IF([test "x$BOTAN_LIBS" != "x"],
 363   [AC_MSG_NOTICE([gost: yes])],
 364   [AC_MSG_NOTICE([gost: no])]
 365 )
 366 AS_IF([test "x$needsqlite3" != "x"],
 367   [AC_MSG_NOTICE([SQLite3: yes])],
 368   [AC_MSG_NOTICE([SQLite3: no])]
 369 )
 370 AS_IF([test "x$LUAPC" != "x"],
 371   [AC_MSG_NOTICE([Lua: $LUAPC])],
 372   [AS_IF([test "x$LUAJITPC" != "x"],
 373     [AC_MSG_NOTICE([LuaJit: $LUAJITPC])],
 374     [AC_MSG_NOTICE([Lua/LuaJit: no])])
 375 ])
 376 AS_IF([test "x$enable_experimental_pkcs11" = "xyes"],
 377   [AC_MSG_NOTICE([PKCS-11: yes])]
 378 )
 379 AS_IF([test "x$enable_experimental_gss_tsig" = "xyes"],
 380   [AC_MSG_NOTICE([GSS-TSIG: yes])]
 381 )
 382 AS_IF([test "x$systemd" != "xn"],
 383   [AC_MSG_NOTICE([systemd: yes])],
 384   [AC_MSG_NOTICE([systemd: no])]
 385 )
 386 AS_IF([test "x$enable_remotebackend_zeromq" != "xno"],
 387   [AC_MSG_NOTICE([ZeroMQ connector for remotebackend: yes])]
 388 )
 389 AC_MSG_NOTICE([])