configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl First, define all of the version numbers up front.
   4 dnl In particular, this allows the version macro to be used in AC_INIT
   5
   6 dnl These first two version numbers are updated automatically on each release.
   7 m4_define([LIBARCHIVE_VERSION_S],[3.3.4dev])
   8 m4_define([LIBARCHIVE_VERSION_N],[3003004])
   9
  10 dnl bsdtar and bsdcpio versioning tracks libarchive
  11 m4_define([BSDTAR_VERSION_S],LIBARCHIVE_VERSION_S())
  12 m4_define([BSDCPIO_VERSION_S],LIBARCHIVE_VERSION_S())
  13 m4_define([BSDCAT_VERSION_S],LIBARCHIVE_VERSION_S())
  14
  15 AC_PREREQ([2.69])
  16
  17 #
  18 # Now starts the "real" configure script.
  19 #
  20
  21 AC_INIT([libarchive],[LIBARCHIVE_VERSION_S()],[libarchive-discuss@googlegroups.com])
  22 # Make sure the srcdir contains "libarchive" directory
  23 AC_CONFIG_SRCDIR([libarchive])
  24 # Use auxiliary subscripts from this subdirectory (cleans up root)
  25 AC_CONFIG_AUX_DIR([build/autoconf])
  26 # M4 scripts
  27 AC_CONFIG_MACRO_DIR([build/autoconf])
  28 # Must follow AC_CONFIG macros above...
  29 AM_INIT_AUTOMAKE()
  30 AM_MAINTAINER_MODE([enable])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 # Libtool's "interface version" can be computed from the libarchive version.
  34
  35 # Libtool interface version bumps on any API change, so increments
  36 # whenever libarchive minor version does.
  37 ARCHIVE_MINOR=$(( (LIBARCHIVE_VERSION_N() / 1000) % 1000 ))
  38 # Libarchive 2.7 == libtool interface 9 = 2 + 7
  39 # Libarchive 2.8 == libtool interface 10 = 2 + 8
  40 # Libarchive 2.9 == libtool interface 11 = 2 + 8
  41 # Libarchive 3.0 == libtool interface 12
  42 # Libarchive 3.1 == libtool interface 13
  43 ARCHIVE_INTERFACE=`echo $((13 + ${ARCHIVE_MINOR}))`
  44 # Libarchive revision is bumped on any source change === libtool revision
  45 ARCHIVE_REVISION=$(( LIBARCHIVE_VERSION_N() % 1000 ))
  46 # Libarchive minor is bumped on any interface addition === libtool age
  47 ARCHIVE_LIBTOOL_VERSION=$ARCHIVE_INTERFACE:$ARCHIVE_REVISION:$ARCHIVE_MINOR
  48
  49 # Stick the version numbers into config.h
  50 AC_DEFINE([LIBARCHIVE_VERSION_STRING],"LIBARCHIVE_VERSION_S()",
  51         [Version number of libarchive])
  52 AC_DEFINE_UNQUOTED([LIBARCHIVE_VERSION_NUMBER],"LIBARCHIVE_VERSION_N()",
  53         [Version number of libarchive as a single integer])
  54 AC_DEFINE([BSDCPIO_VERSION_STRING],"BSDCPIO_VERSION_S()",
  55         [Version number of bsdcpio])
  56 AC_DEFINE([BSDTAR_VERSION_STRING],"BSDTAR_VERSION_S()",
  57         [Version number of bsdtar])
  58 AC_DEFINE([BSDCAT_VERSION_STRING],"BSDTAR_VERSION_S()",
  59         [Version number of bsdcat])
  60
  61 # The shell variables here must be the same as the AC_SUBST() variables
  62 # below, but the shell variable names apparently cannot be the same as
  63 # the m4 macro names above.  Why?  Ask autoconf.
  64 BSDCPIO_VERSION_STRING=BSDCPIO_VERSION_S()
  65 BSDTAR_VERSION_STRING=BSDTAR_VERSION_S()
  66 BSDCAT_VERSION_STRING=BSDCAT_VERSION_S()
  67 LIBARCHIVE_VERSION_STRING=LIBARCHIVE_VERSION_S()
  68 LIBARCHIVE_VERSION_NUMBER=LIBARCHIVE_VERSION_N()
  69
  70 # Substitute the above version numbers into the various files below.
  71 # Yes, I believe this is the fourth time we define what are essentially
  72 # the same symbols.  Why? Ask autoconf.
  73 AC_SUBST(ARCHIVE_LIBTOOL_VERSION)
  74 AC_SUBST(BSDCPIO_VERSION_STRING)
  75 AC_SUBST(BSDTAR_VERSION_STRING)
  76 AC_SUBST(BSDCAT_VERSION_STRING)
  77 AC_SUBST(LIBARCHIVE_VERSION_STRING)
  78 AC_SUBST(LIBARCHIVE_VERSION_NUMBER)
  79
  80 AC_CONFIG_HEADERS([config.h])
  81 AC_CONFIG_FILES([Makefile])
  82 AC_CONFIG_FILES([build/pkgconfig/libarchive.pc])
  83
  84 # Check for host type
  85 AC_CANONICAL_HOST
  86
  87 dnl Compilation on mingw and Cygwin needs special Makefile rules
  88 inc_windows_files=no
  89 inc_cygwin_files=no
  90 case "$host_os" in
  91   *mingw* ) inc_windows_files=yes ;;
  92   *cygwin* | *msys*) inc_cygwin_files=yes ;;
  93 esac
  94 AM_CONDITIONAL([INC_WINDOWS_FILES], [test $inc_windows_files = yes])
  95 AM_CONDITIONAL([INC_CYGWIN_FILES], [test $inc_cygwin_files = yes])
  96
  97 dnl Defines that are required for specific platforms (e.g. -D_POSIX_SOURCE, etc)
  98 PLATFORMCPPFLAGS=
  99 case "$host_os" in
 100   *mingw* ) PLATFORMCPPFLAGS=-D__USE_MINGW_ANSI_STDIO ;;
 101 esac
 102 AC_SUBST(PLATFORMCPPFLAGS)
 103
 104 # Checks for programs.
 105 AC_PROG_CC
 106 AM_PROG_CC_C_O
 107 AC_USE_SYSTEM_EXTENSIONS
 108 AC_LIBTOOL_WIN32_DLL
 109 AC_PROG_LIBTOOL
 110 AC_CHECK_TOOL([STRIP],[strip])
 111 AC_PROG_MKDIR_P
 112
 113 #
 114 # Options for building bsdtar.
 115 #
 116 # Default is to build bsdtar, but allow people to override that.
 117 #
 118 AC_ARG_ENABLE([bsdtar],
 119         [AS_HELP_STRING([--enable-bsdtar], [enable build of bsdtar (default)])
 120         AS_HELP_STRING([--enable-bsdtar=static], [force static build of bsdtar])
 121         AS_HELP_STRING([--enable-bsdtar=shared], [force dynamic build of bsdtar])
 122 AS_HELP_STRING([--disable-bsdtar], [disable build of bsdtar])],
 123         [], [enable_bsdtar=yes])
 124
 125 case "$enable_bsdtar" in
 126 yes)
 127         if test "$enable_static" = "no"; then
 128                 static_bsdtar=no
 129         else
 130                 static_bsdtar=yes
 131         fi
 132         build_bsdtar=yes
 133         ;;
 134 dynamic|shared)
 135         if test "$enable_shared" = "no"; then
 136                 AC_MSG_FAILURE([Shared linking of bsdtar requires shared libarchive])
 137         fi
 138         build_bsdtar=yes
 139         static_bsdtar=no
 140         ;;
 141 static)
 142         build_bsdtar=yes
 143         static_bsdtar=yes
 144         ;;
 145 no)
 146         build_bsdtar=no
 147         static_bsdtar=no
 148         ;;
 149 *)
 150         AC_MSG_FAILURE([Unsupported value for --enable-bsdtar])
 151         ;;
 152 esac
 153
 154 AM_CONDITIONAL([BUILD_BSDTAR], [ test "$build_bsdtar" = yes ])
 155 AM_CONDITIONAL([STATIC_BSDTAR], [ test "$static_bsdtar" = yes ])
 156
 157 #
 158 # Options for building bsdcat.
 159 #
 160 # Default is to build bsdcat, but allow people to override that.
 161 #
 162 AC_ARG_ENABLE([bsdcat],
 163         [AS_HELP_STRING([--enable-bsdcat], [enable build of bsdcat (default)])
 164         AS_HELP_STRING([--enable-bsdcat=static], [force static build of bsdcat])
 165         AS_HELP_STRING([--enable-bsdcat=shared], [force dynamic build of bsdcat])
 166 AS_HELP_STRING([--disable-bsdcat], [disable build of bsdcat])],
 167         [], [enable_bsdcat=yes])
 168
 169 case "$enable_bsdcat" in
 170 yes)
 171         if test "$enable_static" = "no"; then
 172                 static_bsdcat=no
 173         else
 174                 static_bsdcat=yes
 175         fi
 176         build_bsdcat=yes
 177         ;;
 178 dynamic|shared)
 179         if test "$enable_shared" = "no"; then
 180                 AC_MSG_FAILURE([Shared linking of bsdcat requires shared libarchive])
 181         fi
 182         build_bsdcat=yes
 183         static_bsdcat=no
 184         ;;
 185 static)
 186         build_bsdcat=yes
 187         static_bsdcat=yes
 188         ;;
 189 no)
 190         build_bsdcat=no
 191         static_bsdcat=no
 192         ;;
 193 *)
 194         AC_MSG_FAILURE([Unsupported value for --enable-bsdcat])
 195         ;;
 196 esac
 197
 198 AM_CONDITIONAL([BUILD_BSDCAT], [ test "$build_bsdcat" = yes ])
 199 AM_CONDITIONAL([STATIC_BSDCAT], [ test "$static_bsdcat" = yes ])
 200
 201 #
 202 # Options for building bsdcpio.
 203 #
 204 # Default is not to build bsdcpio, but that can be overridden.
 205 #
 206 AC_ARG_ENABLE([bsdcpio],
 207         [AS_HELP_STRING([--enable-bsdcpio], [enable build of bsdcpio (default)])
 208         AS_HELP_STRING([--enable-bsdcpio=static], [static build of bsdcpio])
 209         AS_HELP_STRING([--enable-bsdcpio=shared], [dynamic build of bsdcpio])
 210 AS_HELP_STRING([--disable-bsdcpio], [disable build of bsdcpio])],
 211         [], [enable_bsdcpio=yes])
 212
 213 case "$enable_bsdcpio" in
 214 yes)
 215         if test "$enable_static" = "no"; then
 216            static_bsdcpio=no
 217         else
 218            static_bsdcpio=yes
 219         fi
 220         build_bsdcpio=yes
 221         ;;
 222 dynamic|shared)
 223         if test "$enabled_shared" = "no"; then
 224            AC_MSG_FAILURE([Shared linking of bsdcpio requires shared libarchive])
 225         fi
 226         build_bsdcpio=yes
 227         ;;
 228 static)
 229         build_bsdcpio=yes
 230         static_bsdcpio=yes
 231         ;;
 232 no)
 233         build_bsdcpio=no
 234         static_bsdcpio=no
 235         ;;
 236 *)
 237         AC_MSG_FAILURE([Unsupported value for --enable-bsdcpio])
 238         ;;
 239 esac
 240
 241 AM_CONDITIONAL([BUILD_BSDCPIO], [ test "$build_bsdcpio" = yes ])
 242 AM_CONDITIONAL([STATIC_BSDCPIO], [ test "$static_bsdcpio" = yes ])
 243
 244 # Set up defines needed before including any headers
 245 case $host in
 246   *mingw* | *cygwin* | *msys*  )
 247   AC_DEFINE([_WIN32_WINNT], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 248   AC_DEFINE([WINVER], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 249   AC_DEFINE([NTDDI_VERSION], 0x05020000, [Define to '0x05020000' for Windows Server 2003 APIs.])
 250   ;;
 251 esac
 252
 253 # Checks for header files.
 254 AC_HEADER_DIRENT
 255 AC_HEADER_SYS_WAIT
 256 AC_CHECK_HEADERS([acl/libacl.h attr/xattr.h])
 257 AC_CHECK_HEADERS([copyfile.h ctype.h])
 258 AC_CHECK_HEADERS([errno.h ext2fs/ext2_fs.h fcntl.h grp.h])
 259
 260 AC_CACHE_CHECK([whether EXT2_IOC_GETFLAGS is usable],
 261     [ac_cv_have_decl_EXT2_IOC_GETFLAGS],
 262     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 263 @%:@include <ext2fs/ext2_fs.h>],
 264                                    [int x = EXT2_IOC_GETFLAGS])],
 265                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes])],
 266                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [no])])])
 267
 268 AS_VAR_IF([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes],
 269     [AC_DEFINE_UNQUOTED([HAVE_WORKING_EXT2_IOC_GETFLAGS], [1],
 270                     [Define to 1 if you have a working EXT2_IOC_GETFLAGS])])
 271
 272 AC_CHECK_HEADERS([inttypes.h io.h langinfo.h limits.h])
 273 AC_CHECK_HEADERS([linux/fiemap.h linux/fs.h linux/magic.h linux/types.h])
 274
 275 AC_CACHE_CHECK([whether FS_IOC_GETFLAGS is usable],
 276     [ac_cv_have_decl_FS_IOC_GETFLAGS],
 277     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 278 @%:@include <linux/fs.h>],
 279                                    [int x = FS_IOC_GETFLAGS])],
 280                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes])],
 281                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [no])])])
 282
 283 AS_VAR_IF([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes],
 284     [AC_DEFINE_UNQUOTED([HAVE_WORKING_FS_IOC_GETFLAGS], [1],
 285                     [Define to 1 if you have a working FS_IOC_GETFLAGS])])
 286
 287 AC_CHECK_HEADERS([locale.h membership.h paths.h poll.h pthread.h pwd.h])
 288 AC_CHECK_HEADERS([readpassphrase.h signal.h spawn.h])
 289 AC_CHECK_HEADERS([stdarg.h stdint.h stdlib.h string.h])
 290 AC_CHECK_HEADERS([sys/acl.h sys/cdefs.h sys/ea.h sys/extattr.h])
 291 AC_CHECK_HEADERS([sys/ioctl.h sys/mkdev.h sys/mount.h])
 292 AC_CHECK_HEADERS([sys/param.h sys/poll.h sys/richacl.h])
 293 AC_CHECK_HEADERS([sys/select.h sys/statfs.h sys/statvfs.h sys/sysmacros.h])
 294 AC_CHECK_HEADERS([sys/time.h sys/utime.h sys/utsname.h sys/vfs.h sys/xattr.h])
 295 AC_CHECK_HEADERS([time.h unistd.h utime.h wchar.h wctype.h])
 296 AC_CHECK_HEADERS([windows.h])
 297 # check windows.h first; the other headers require it.
 298 AC_CHECK_HEADERS([wincrypt.h winioctl.h],[],[],
 299 [[#ifdef HAVE_WINDOWS_H
 300 # include <windows.h>
 301 #endif
 302 ]])
 303
 304 # Checks for libraries.
 305 AC_ARG_WITH([zlib],
 306   AS_HELP_STRING([--without-zlib], [Don't build support for gzip through zlib]))
 307
 308 if test "x$with_zlib" != "xno"; then
 309   AC_CHECK_HEADERS([zlib.h])
 310   AC_CHECK_LIB(z,inflate)
 311 fi
 312
 313 AC_ARG_WITH([bz2lib],
 314   AS_HELP_STRING([--without-bz2lib], [Don't build support for bzip2 through bz2lib]))
 315
 316 if test "x$with_bz2lib" != "xno"; then
 317   AC_CHECK_HEADERS([bzlib.h])
 318   case "$host_os" in
 319     *mingw* | *cygwin* | *msys*)
 320       dnl AC_CHECK_LIB cannot be used on the Windows port of libbz2, therefore
 321           dnl use AC_LINK_IFELSE.
 322           AC_MSG_CHECKING([for BZ2_bzDecompressInit in -lbz2])
 323       old_LIBS="$LIBS"
 324       LIBS="-lbz2 $LIBS"
 325       AC_LINK_IFELSE(
 326         [AC_LANG_SOURCE(#include <bzlib.h>
 327           int main() { return BZ2_bzDecompressInit(NULL, 0, 0); })],
 328         [ac_cv_lib_bz2_BZ2_bzDecompressInit=yes],
 329         [ac_cv_lib_bz2_BZ2_bzDecompressInit=no])
 330       LIBS="$old_LIBS"
 331           AC_MSG_RESULT($ac_cv_lib_bz2_BZ2_bzDecompressInit)
 332       if test "x$ac_cv_lib_bz2_BZ2_bzDecompressInit" = xyes; then
 333         AC_DEFINE([HAVE_LIBBZ2], [1], [Define to 1 if you have the `bz2' library (-lbz2).])
 334         LIBS="-lbz2 $LIBS"
 335       fi
 336     ;;
 337     *)
 338       AC_CHECK_LIB(bz2,BZ2_bzDecompressInit)
 339     ;;
 340   esac
 341 fi
 342
 343 AC_ARG_WITH([libb2],
 344   AS_HELP_STRING([--without-libb2], [Don't build support for BLAKE2 through libb2]))
 345
 346 if test "x$with_libb2" != "xno"; then
 347   AC_CHECK_HEADERS([blake2.h])
 348   AC_CHECK_LIB(b2,blake2sp_init)
 349 fi
 350
 351 AM_CONDITIONAL([INC_BLAKE2], [test "x$ac_cv_lib_b2_blake2sp_init" != "xyes"])
 352
 353 AC_ARG_WITH([iconv],
 354   AS_HELP_STRING([--without-iconv], [Don't try to link against iconv]))
 355
 356 if test "x$with_iconv" != "xno"; then
 357   AM_ICONV
 358   AC_CHECK_HEADERS([iconv.h],[],[],[#include <stdlib.h>])
 359   if test "x$am_cv_func_iconv" = "xyes"; then
 360     AC_CHECK_HEADERS([localcharset.h])
 361     am_save_LIBS="$LIBS"
 362     LIBS="${LIBS} ${LIBICONV}"
 363     AC_CHECK_FUNCS([locale_charset])
 364     LIBS="${am_save_LIBS}"
 365     if test "x$ac_cv_func_locale_charset" != "xyes"; then
 366       # If locale_charset() is not in libiconv, we have to find libcharset.
 367       AC_CHECK_LIB(charset,locale_charset)
 368     fi
 369   fi
 370 fi
 371
 372 AC_ARG_WITH([lz4],
 373   AS_HELP_STRING([--without-lz4], [Don't build support for lz4 through liblz4]))
 374
 375 if test "x$with_lz4" != "xno"; then
 376   AC_CHECK_HEADERS([lz4.h lz4hc.h])
 377   AC_CHECK_LIB(lz4,LZ4_decompress_safe)
 378 fi
 379
 380 AC_ARG_WITH([zstd],
 381   AS_HELP_STRING([--without-zstd], [Don't build support for zstd through libzstd]))
 382
 383 if test "x$with_zstd" != "xno"; then
 384   AC_CHECK_HEADERS([zstd.h])
 385   AC_CHECK_LIB(zstd,ZSTD_compressStream)
 386 fi
 387
 388 AC_ARG_WITH([lzma],
 389   AS_HELP_STRING([--without-lzma], [Don't build support for xz through lzma]))
 390
 391 if test "x$with_lzma" != "xno"; then
 392   AC_CHECK_HEADERS([lzma.h])
 393   AC_CHECK_LIB(lzma,lzma_stream_decoder)
 394   # Some pre-release (but widely distributed) versions of liblzma
 395   # included a disabled version of lzma_stream_encoder_mt that
 396   # fools a naive AC_CHECK_LIB or AC_CHECK_FUNC, so we need
 397   # to do something more complex here:
 398   AC_CACHE_CHECK(
 399     [whether we have multithread support in lzma],
 400     ac_cv_lzma_has_mt,
 401     [AC_LINK_IFELSE([
 402       AC_LANG_PROGRAM([[#include <lzma.h>]
 403                        [#if LZMA_VERSION < 50020000]
 404                        [#error unsupported]
 405                        [#endif]],
 406                       [[lzma_stream_encoder_mt(0, 0);]])],
 407       [ac_cv_lzma_has_mt=yes], [ac_cv_lzma_has_mt=no])])
 408   if test "x$ac_cv_lzma_has_mt" != xno; then
 409           AC_DEFINE([HAVE_LZMA_STREAM_ENCODER_MT], [1], [Define to 1 if you have the `lzma_stream_encoder_mt' function.])
 410   fi
 411 fi
 412
 413 AC_ARG_WITH([lzo2],
 414   AS_HELP_STRING([--with-lzo2], [Build with LZO support from liblzo2]))
 415
 416 if test "x$with_lzo2" = "xyes"; then
 417   AC_CHECK_HEADERS([lzo/lzoconf.h lzo/lzo1x.h])
 418   AC_CHECK_LIB(lzo2,lzo1x_decompress_safe)
 419 fi
 420
 421 AC_ARG_WITH([cng],
 422   AS_HELP_STRING([--without-cng], [Don't build support of CNG(Crypto Next Generation)]))
 423
 424 AC_ARG_WITH([nettle],
 425   AS_HELP_STRING([--without-nettle], [Don't build with crypto support from Nettle]))
 426 AC_ARG_WITH([openssl],
 427   AS_HELP_STRING([--without-openssl], [Don't build support for mtree and xar hashes through openssl]))
 428 case "$host_os" in
 429   *darwin* ) with_openssl=no ;;
 430 esac
 431
 432 AC_ARG_WITH([xml2],
 433   AS_HELP_STRING([--without-xml2], [Don't build support for xar through libxml2]))
 434 AC_ARG_WITH([expat],
 435   AS_HELP_STRING([--without-expat], [Don't build support for xar through expat]))
 436
 437 if test "x$with_xml2" != "xno"; then
 438   PKG_PROG_PKG_CONFIG
 439   PKG_CHECK_MODULES(LIBXML2_PC, [libxml-2.0], [
 440     CPPFLAGS="${CPPFLAGS} ${LIBXML2_PC_CFLAGS}"
 441     LIBS="${LIBS} ${LIBXML2_PC_LIBS}"
 442     AC_CHECK_LIB(xml2,xmlInitParser,[true],AC_MSG_FAILURE(Missing xml2 library))
 443   ], [
 444     AC_CHECK_LIB(xml2,xmlInitParser)
 445   ])
 446   AC_CHECK_HEADERS([libxml/xmlreader.h libxml/xmlwriter.h])
 447 fi
 448 if test "x$ac_cv_header_libxml_xmlreader_h" != "xyes"; then
 449   if test "x$with_expat" != "xno"; then
 450     AC_CHECK_HEADERS([expat.h])
 451     AC_CHECK_LIB(expat,XML_ParserCreate)
 452   fi
 453 fi
 454
 455 AC_ARG_ENABLE([posix-regex-lib],
 456   [AS_HELP_STRING([--enable-posix-regex-lib],
 457     [choose what library to use for POSIX regular expression support (default: auto)])
 458   AS_HELP_STRING([--enable-posix-regex-lib=libc], [use libc POSIX regular expression support])
 459   AS_HELP_STRING([--enable-posix-regex-lib=libregex], [use libregex POSIX regular expression support])
 460   AS_HELP_STRING([--enable-posix-regex-lib=libpcreposix], [use libpcreposix POSIX regular expression support])
 461   AS_HELP_STRING([--disable-posix-regex-lib], [don't enable POSIX regular expression support])],
 462   [], [enable_posix_regex_lib=auto])
 463
 464 posix_regex_lib_found=
 465 if test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libc" || test "$enable_posix_regex_lib" = "libregex"; then
 466   AC_CHECK_HEADERS([regex.h])
 467   if test "x$ac_cv_header_regex_h" != "xno"; then
 468     AC_CHECK_FUNC(regcomp)
 469     if test "x$ac_cv_func_regcomp" = xyes; then
 470       posix_regex_lib_found=1
 471     else
 472       AC_CHECK_LIB(regex,regcomp)
 473       if test "x$ac_cv_lib_regex_regcomp" = xyes; then
 474         posix_regex_lib_found=1
 475       fi
 476     fi
 477   fi
 478 fi
 479 if test -z $posix_regex_lib_found && (test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libpcreposix"); then
 480   AC_CHECK_HEADERS([pcreposix.h])
 481   AC_CHECK_LIB(pcreposix,regcomp)
 482   if test "x$ac_cv_lib_pcreposix_regcomp" != xyes; then
 483     AC_MSG_NOTICE(trying libpcreposix check again with libpcre)
 484         unset ac_cv_lib_pcreposix_regcomp
 485         AC_CHECK_LIB(pcre,pcre_exec)
 486     AC_CHECK_LIB(pcreposix,regcomp)
 487     if test "x$ac_cv_lib_pcre_pcre_exec" = xyes && test "x$ac_cv_lib_pcreposix_regcomp" = xyes; then
 488       AC_MSG_CHECKING(if PCRE_STATIC needs to be defined)
 489       AC_LINK_IFELSE(
 490         [AC_LANG_SOURCE(#include <pcreposix.h>
 491           int main() { return regcomp(NULL, NULL, 0); })],
 492         [without_pcre_static=yes],
 493         [without_pcre_static=no])
 494       AC_LINK_IFELSE(
 495         [AC_LANG_SOURCE(#define PCRE_STATIC
 496           #include <pcreposix.h>
 497           int main() { return regcomp(NULL, NULL, 0); })],
 498         [with_pcre_static=yes],
 499         [with_pcre_static=no])
 500       if test "x$without_pcre_static" != xyes && test "x$with_pcre_static" = xyes; then
 501         AC_MSG_RESULT(yes)
 502         AC_DEFINE([PCRE_STATIC], [1], [Define to 1 if PCRE_STATIC needs to be defined.])
 503       elif test "x$without_pcre_static" = xyes || test "x$with_pcre_static" = xyes; then
 504         AC_MSG_RESULT(no)
 505       fi
 506       posix_regex_lib_found=1
 507     fi
 508   else
 509     posix_regex_lib_found=1
 510   fi
 511 fi
 512
 513 # TODO: Give the user the option of using a pre-existing system
 514 # libarchive.  This will define HAVE_LIBARCHIVE which will cause
 515 # bsdtar_platform.h to use #include <...> for the libarchive headers.
 516 # Need to include Makefile.am magic to link against system
 517 # -larchive in that case.
 518 #AC_CHECK_LIB(archive,archive_version)
 519
 520 # Checks for supported compiler flags
 521 AX_APPEND_COMPILE_FLAGS([-Wall -Wformat -Wformat-security])
 522
 523 # Checks for typedefs, structures, and compiler characteristics.
 524 AC_C_CONST
 525 # la_TYPE_UID_T defaults to "int", which is incorrect for MinGW
 526 # and MSVC. Use a customized version.
 527 la_TYPE_UID_T
 528 AC_TYPE_MODE_T
 529 # AC_TYPE_OFF_T defaults to "long", which limits us to 4GB files on
 530 # most systems... default to "long long" instead.
 531 AC_CHECK_TYPE(off_t, [long long])
 532 AC_TYPE_SIZE_T
 533 AC_CHECK_TYPE(id_t, [unsigned long])
 534 AC_CHECK_TYPE(uintptr_t, [unsigned int])
 535
 536 # Check for tm_gmtoff in struct tm
 537 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,
 538 [
 539 #include <time.h>
 540 ])
 541
 542 # Check for f_namemax in struct statfs
 543 AC_CHECK_MEMBERS([struct statfs.f_namemax],,,
 544 [
 545 #include <sys/param.h>
 546 #include <sys/mount.h>
 547 ])
 548
 549 # Check for f_iosize in struct statvfs
 550 AC_CHECK_MEMBERS([struct statvfs.f_iosize],,,
 551 [
 552 #include <sys/statvfs.h>
 553 ])
 554
 555 # Check for birthtime in struct stat
 556 AC_CHECK_MEMBERS([struct stat.st_birthtime])
 557
 558 # Check for high-resolution timestamps in struct stat
 559 AC_CHECK_MEMBERS([struct stat.st_birthtimespec.tv_nsec])
 560 AC_CHECK_MEMBERS([struct stat.st_mtimespec.tv_nsec])
 561 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 562 AC_CHECK_MEMBERS([struct stat.st_mtime_n]) # AIX
 563 AC_CHECK_MEMBERS([struct stat.st_umtime]) # Tru64
 564 AC_CHECK_MEMBERS([struct stat.st_mtime_usec]) # Hurd
 565 # Check for block size support in struct stat
 566 AC_CHECK_MEMBERS([struct stat.st_blksize])
 567 # Check for st_flags in struct stat (BSD fflags)
 568 AC_CHECK_MEMBERS([struct stat.st_flags])
 569
 570 # If you have uintmax_t, we assume printf supports %ju
 571 # If you have unsigned long long, we assume printf supports %llu
 572 # TODO: Check for %ju and %llu support directly.
 573 AC_CHECK_TYPES([uintmax_t, unsigned long long])
 574
 575 # We use C99-style integer types
 576 # Declare them if the local platform doesn't already do so.
 577 AC_TYPE_INTMAX_T
 578 AC_TYPE_UINTMAX_T
 579 AC_TYPE_INT64_T
 580 AC_TYPE_UINT64_T
 581 AC_TYPE_INT32_T
 582 AC_TYPE_UINT32_T
 583 AC_TYPE_INT16_T
 584 AC_TYPE_UINT16_T
 585 AC_TYPE_UINT8_T
 586
 587 AC_CHECK_DECLS([SIZE_MAX, INT32_MAX, INT32_MIN])
 588 AC_CHECK_DECLS([INT64_MAX, INT64_MIN, UINT64_MAX, UINT32_MAX])
 589 AC_CHECK_DECLS([INTMAX_MAX, INTMAX_MIN, UINTMAX_MAX])
 590
 591 AC_CHECK_DECL([SSIZE_MAX],
 592                 [AC_DEFINE(HAVE_DECL_SSIZE_MAX, 1, [Define to 1 if you have the declaration of `SSIZE_MAX', and to 0 if you don't.])],
 593                 [],
 594                 [#include <limits.h>])
 595
 596 AC_CHECK_DECL([EFTYPE],
 597                 [AC_DEFINE(HAVE_EFTYPE, 1, [A possible errno value for invalid file format errors])],
 598                 [],
 599                 [#include <errno.h>])
 600 AC_CHECK_DECL([EILSEQ],
 601                 [AC_DEFINE(HAVE_EILSEQ, 1, [A possible errno value for invalid file format errors])],
 602                 [],
 603                 [#include <errno.h>])
 604 AC_CHECK_TYPE([wchar_t],
 605                 [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]wchar_t), 1, [Define to 1 if the system has the type `wchar_t'.])dnl
 606                 AC_CHECK_SIZEOF([wchar_t])],
 607                 [])
 608
 609 AC_HEADER_TIME
 610
 611 # Checks for library functions.
 612 AC_PROG_GCC_TRADITIONAL
 613 AC_HEADER_MAJOR
 614 AC_FUNC_FSEEKO
 615 AC_FUNC_MEMCMP
 616 AC_FUNC_LSTAT
 617 AC_FUNC_STAT
 618 AC_FUNC_STRERROR_R
 619 AC_FUNC_STRFTIME
 620 AC_FUNC_VPRINTF
 621 # check for:
 622 #   CreateHardLinkA(LPCSTR, LPCSTR, LPSECURITY_ATTRIBUTES)
 623 # To avoid necessity for including windows.h or special forward declaration
 624 # workarounds, we use 'void *' for 'struct SECURITY_ATTRIBUTES *'
 625 AC_CHECK_STDCALL_FUNC([CreateHardLinkA],[const char *, const char *, void *])
 626 AC_CHECK_FUNCS([arc4random_buf chflags chown chroot ctime_r])
 627 AC_CHECK_FUNCS([fchdir fchflags fchmod fchown fcntl fdopendir fork])
 628 AC_CHECK_FUNCS([fstat fstatat fstatfs fstatvfs ftruncate])
 629 AC_CHECK_FUNCS([futimens futimes futimesat])
 630 AC_CHECK_FUNCS([geteuid getpid getgrgid_r getgrnam_r])
 631 AC_CHECK_FUNCS([getpwnam_r getpwuid_r getvfsbyname gmtime_r])
 632 AC_CHECK_FUNCS([lchflags lchmod lchown link localtime_r lstat lutimes])
 633 AC_CHECK_FUNCS([mbrtowc memmove memset])
 634 AC_CHECK_FUNCS([mkdir mkfifo mknod mkstemp])
 635 AC_CHECK_FUNCS([nl_langinfo openat pipe poll posix_spawnp readlink readlinkat])
 636 AC_CHECK_FUNCS([readpassphrase])
 637 AC_CHECK_FUNCS([select setenv setlocale sigaction statfs statvfs])
 638 AC_CHECK_FUNCS([strchr strdup strerror strncpy_s strrchr symlink timegm])
 639 AC_CHECK_FUNCS([tzset unsetenv utime utimensat utimes vfork])
 640 AC_CHECK_FUNCS([wcrtomb wcscmp wcscpy wcslen wctomb wmemcmp wmemcpy wmemmove])
 641 AC_CHECK_FUNCS([_ctime64_s _fseeki64])
 642 AC_CHECK_FUNCS([_get_timezone _localtime64_s _mkgmtime64])
 643 # detects cygwin-1.7, as opposed to older versions
 644 AC_CHECK_FUNCS([cygwin_conv_path])
 645
 646 # DragonFly uses vfsconf, FreeBSD xvfsconf.
 647 AC_CHECK_TYPES(struct vfsconf,,,
 648         [#if HAVE_SYS_TYPES_H
 649         #include <sys/types.h>
 650         #endif
 651         #include <sys/mount.h>
 652         ])
 653
 654 AC_CHECK_TYPES(struct xvfsconf,,,
 655         [#if HAVE_SYS_TYPES_H
 656         #include <sys/types.h>
 657         #endif
 658         #include <sys/mount.h>
 659         ])
 660
 661 # There are several variants of readdir_r around; we only
 662 # accept the POSIX-compliant version.
 663 AC_COMPILE_IFELSE(
 664  [AC_LANG_PROGRAM([[#include <dirent.h>]],
 665                   [[DIR *dir; struct dirent e, *r;
 666                     return(readdir_r(dir, &e, &r));]])],
 667  [AC_DEFINE(HAVE_READDIR_R,1,[Define to 1 if you have a POSIX compatible readdir_r])]
 668 )
 669 # dirfd can be either a function or a macro.
 670 AC_COMPILE_IFELSE(
 671  [AC_LANG_PROGRAM([[#include <dirent.h>
 672                     DIR *dir;]],
 673                   [[return(dirfd(dir));]])],
 674  [AC_DEFINE(HAVE_DIRFD,1,[Define to 1 if you have a dirfd function or macro])]
 675 )
 676
 677 # FreeBSD's nl_langinfo supports an option to specify whether the
 678 # current locale uses month/day or day/month ordering.  It makes the
 679 # output a little prettier...
 680 AC_CHECK_DECL([D_MD_ORDER],
 681 [AC_DEFINE(HAVE_D_MD_ORDER, 1, [Define to 1 if nl_langinfo supports D_MD_ORDER])],
 682 [],
 683 [#if HAVE_LANGINFO_H
 684 #include <langinfo.h>
 685 #endif
 686 ])
 687
 688 # Check for dirent.d_namlen field explicitly
 689 # (This is a bit more straightforward than, if not quite as portable as,
 690 # the recipe given by the autoconf maintainers.)
 691 AC_CHECK_MEMBER(struct dirent.d_namlen,,,
 692 [#if HAVE_DIRENT_H
 693 #include <dirent.h>
 694 #endif
 695 ])
 696
 697 # Check for Extended Attributes support
 698 AC_ARG_ENABLE([xattr],
 699                 AS_HELP_STRING([--disable-xattr],
 700                 [Disable Extended Attributes support (default: check)]))
 701
 702 if test "x$enable_xattr" != "xno"; then
 703     AC_SEARCH_LIBS([setxattr], [attr gnu])
 704     AC_CHECK_DECLS([EXTATTR_NAMESPACE_USER], [], [], [#include <sys/types.h>
 705 #include <sys/extattr.h>
 706 ])
 707     AC_CHECK_DECLS([XATTR_NOFOLLOW], [], [], [#include <sys/xattr.h>
 708 ])
 709     if test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 710          -a "x$ac_cv_have_decl_XATTR_NOFOLLOW" = "xyes"; then
 711         # Darwin extended attributes support
 712         AC_CACHE_VAL([ac_cv_archive_xattr_darwin],
 713           [AC_CHECK_FUNCS(fgetxattr \
 714                           flistxattr \
 715                           fsetxattr \
 716                           getxattr \
 717                           listxattr \
 718                           setxattr,
 719           [ac_cv_archive_xattr_darwin=yes],
 720           [ac_cv_archive_xattr_darwin=no],
 721           [#include <sys/xattr.h>
 722 ])
 723         ]
 724       )
 725     elif test "x$ac_cv_header_sys_extattr_h" = "xyes" \
 726            -a "x$ac_cv_have_decl_EXTATTR_NAMESPACE_USER" = "xyes"; then
 727         # FreeBSD extended attributes support
 728         AC_CACHE_VAL([ac_cv_archive_xattr_freebsd],
 729           [AC_CHECK_FUNCS(extattr_get_fd \
 730                           extattr_get_file \
 731                           extattr_get_link \
 732                           extattr_list_fd \
 733                           extattr_list_file \
 734                           extattr_list_link \
 735                           extattr_set_fd \
 736                           extattr_set_link,
 737           [ac_cv_archive_xattr_freebsd=yes],
 738           [ac_cv_archive_xattr_freebsd=no],
 739           [#include <sys/types.h>
 740 #include <sys/extattr.h>
 741 ])
 742           ]
 743         )
 744     elif test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 745            -o "x$ac_cv_header_attr_xattr_h" = "xyes"; then
 746         # Linux extended attributes support
 747         AC_CACHE_VAL([ac_cv_archive_xattr_linux],
 748           [AC_CHECK_FUNCS(fgetxattr \
 749                           flistxattr \
 750                           fsetxattr \
 751                           getxattr \
 752                           lgetxattr \
 753                           listxattr \
 754                           llistxattr \
 755                           lsetxattr,
 756           [ac_cv_archive_xattr_linux=yes],
 757           [ac_cv_archive_xattr_linux=no],
 758           [#if HAVE_SYS_TYPES_H
 759 #include <sys/types.h>
 760 #endif
 761 #if HAVE_SYS_XATTR_H
 762 #include <sys/xattr.h>
 763 #endif
 764 #if HAVE_ATTR_XATTR_H
 765 #include <attr/xatr.h>
 766 #endif
 767 ])
 768         ]
 769       )
 770     elif test "x$ac_cv_header_sys_ea_h" = "xyes"; then
 771         # AIX extended attributes support
 772         AC_CACHE_VAL([ac_cv_archive_xattr_aix],
 773           [AC_CHECK_FUNCS(fgetea \
 774                           flistea \
 775                           fsetea \
 776                           getea \
 777                           lgetea \
 778                           listea \
 779                           llistea \
 780                           lsetea,
 781           [ac_cv_archive_xattr_aix=yes],
 782           [ac_cv_archive_xattr_aix=no],
 783           [#include <sys/ea.h>
 784 ])
 785           ]
 786         )
 787     fi
 788
 789     AC_MSG_CHECKING([for extended attributes support])
 790     if test "x$ac_cv_archive_xattr_linux" = "xyes"; then
 791         AC_DEFINE([ARCHIVE_XATTR_LINUX], [1], [Linux xattr support])
 792         AC_MSG_RESULT([Linux])
 793     elif test "x$ac_cv_archive_xattr_darwin" = "xyes"; then
 794         AC_DEFINE([ARCHIVE_XATTR_DARWIN], [1], [Darwin xattr support])
 795         AC_MSG_RESULT([Darwin])
 796     elif test "x$ac_cv_archive_xattr_freebsd" = "xyes"; then
 797         AC_DEFINE([ARCHIVE_XATTR_FREEBSD], [1], [FreeBSD xattr support])
 798         AC_MSG_RESULT([FreeBSD])
 799     elif test "x$ac_cv_archive_xattr_aix" = "xyes"; then
 800         AC_DEFINE([ARCHIVE_XATTR_AIX], [1], [AIX xattr support])
 801         AC_MSG_RESULT([AIX])
 802     else
 803         AC_MSG_RESULT([none])
 804     fi
 805 fi
 806
 807 # Check for ACL support
 808 #
 809 # The ACL support in libarchive is written against the POSIX1e draft,
 810 # which was never officially approved and varies quite a bit across
 811 # platforms.  Worse, some systems have completely non-POSIX acl functions,
 812 # which makes the following checks rather more complex than I would like.
 813 #
 814 AC_ARG_ENABLE([acl],
 815                 AS_HELP_STRING([--disable-acl],
 816                 [Disable ACL support (default: check)]))
 817
 818 if test "x$enable_acl" != "xno"; then
 819     # Libacl
 820     AC_CHECK_LIB([acl], [acl_get_file])
 821
 822     AC_CHECK_TYPES([acl_t, acl_entry_t, acl_permset_t, acl_tag_t], [], [], [
 823       #if HAVE_SYS_TYPES_H
 824       #include <sys/types.h>
 825       #endif
 826       #if HAVE_SYS_ACL_H
 827       #include <sys/acl.h>
 828       #endif
 829     ])
 830
 831     AC_CHECK_LIB([richacl], [richacl_get_file])
 832
 833     AC_CHECK_TYPES([[struct richace], [struct richacl]], [], [], [
 834       #if HAVE_SYS_RICHACL_H
 835       #include <sys/richacl.h>
 836       #endif
 837     ])
 838
 839     # Solaris and derivates ACLs
 840     AC_CHECK_FUNCS(acl facl)
 841
 842     if test "x$ac_cv_lib_richacl_richacl_get_file" = "xyes" \
 843          -a "x$ac_cv_type_struct_richace" = "xyes" \
 844          -a "x$ac_cv_type_struct_richacl" = "xyes"; then
 845         AC_CACHE_VAL([ac_cv_archive_acl_librichacl],
 846           [AC_CHECK_FUNCS(richacl_alloc \
 847                           richacl_equiv_mode \
 848                           richacl_free \
 849                           richacl_get_fd \
 850                           richacl_get_file \
 851                           richacl_set_fd \
 852                           richacl_set_file,
 853           [ac_cv_archive_acl_librichacl=yes], [ac_cv_archive_acl_librichacl=no],          [#include <sys/richacl.h>])])
 854     fi
 855
 856     if test "x$ac_cv_func_acl" = "xyes" \
 857          -a "x$ac_cv_func_facl" = "xyes"; then
 858         AC_CHECK_TYPES([aclent_t], [], [], [[#include <sys/acl.h>]])
 859         if test "x$ac_cv_type_aclent_t" = "xyes"; then
 860             AC_CACHE_VAL([ac_cv_archive_acl_sunos],
 861               [AC_CHECK_DECLS([GETACL, SETACL, GETACLCNT],
 862               [ac_cv_archive_acl_sunos=yes], [ac_cv_archive_acl_sunos=no],
 863               [#include <sys/acl.h>])])
 864             AC_CHECK_TYPES([ace_t], [], [], [[#include <sys/acl.h>]])
 865             if test "x$ac_cv_type_ace_t" = "xyes"; then
 866                 AC_CACHE_VAL([ac_cv_archive_acl_sunos_nfs4],
 867                   [AC_CHECK_DECLS([ACE_GETACL, ACE_SETACL, ACE_GETACLCNT],
 868                   [ac_cv_archive_acl_sunos_nfs4=yes],
 869                   [ac_cv_archive_acl_sonos_nfs4=no],
 870                   [#include <sys/acl.h>])])
 871             fi
 872         fi
 873     elif test "x$ac_cv_type_acl_t" = "xyes" \
 874          -a "x$ac_cv_type_acl_entry_t" = "xyes" \
 875          -a "x$ac_cv_type_acl_permset_t" = "xyes" \
 876          -a "x$ac_cv_type_acl_tag_t" = "xyes"; then
 877         # POSIX.1e ACL functions
 878         AC_CACHE_VAL([ac_cv_posix_acl_funcs],
 879           [AC_CHECK_FUNCS(acl_add_perm \
 880                           acl_clear_perms \
 881                           acl_create_entry \
 882                           acl_delete_def_file \
 883                           acl_free \
 884                           acl_get_entry \
 885                           acl_get_fd \
 886                           acl_get_file \
 887                           acl_get_permset \
 888                           acl_get_qualifier \
 889                           acl_get_tag_type \
 890                           acl_init \
 891                           acl_set_fd \
 892                           acl_set_file \
 893                           acl_set_qualifier \
 894                           acl_set_tag_type,
 895           [ac_cv_posix_acl_funcs=yes], [ac_cv_posix_acl_funcs=no],
 896           [#if HAVE_SYS_TYPES_H
 897            #include <sys/types.h>
 898            #endif
 899            #if HAVE_SYS_ACL_H
 900            #include <sys/acl.h>
 901            #endif
 902           ])
 903         ])
 904
 905         AC_CHECK_FUNCS(acl_get_perm)
 906
 907         if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 908              -a "x$ac_cv_header_acl_libacl_h" = "xyes" \
 909              -a "x$ac_cv_lib_acl_acl_get_file" = "xyes" \
 910              -a "x$ac_cv_func_acl_get_perm"; then
 911             AC_CACHE_VAL([ac_cv_archive_acl_libacl],
 912               [ac_cv_archive_acl_libacl=yes])
 913             AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
 914               [POSIX.1e ACL support via libacl])
 915         else
 916              # FreeBSD/Darwin
 917              AC_CHECK_FUNCS(acl_add_flag_np \
 918                             acl_clear_flags_np \
 919                             acl_get_brand_np \
 920                             acl_get_entry_type_np \
 921                             acl_get_flag_np \
 922                             acl_get_flagset_np \
 923                             acl_get_fd_np \
 924                             acl_get_link_np \
 925                             acl_get_perm_np \
 926                             acl_is_trivial_np \
 927                             acl_set_entry_type_np \
 928                             acl_set_fd_np \
 929                             acl_set_link_np,,,
 930               [#include <sys/types.h>
 931                #include <sys/acl.h>])
 932
 933             AC_CHECK_FUNCS(mbr_uid_to_uuid \
 934                            mbr_uuid_to_id \
 935                            mbr_gid_to_uuid,,,
 936               [#include <membership.h>])
 937
 938             AC_CHECK_DECLS([ACL_TYPE_EXTENDED, ACL_TYPE_NFS4, ACL_USER,
 939               ACL_SYNCHRONIZE], [], [],
 940               [#include <sys/types.h>
 941                #include <sys/acl.h>])
 942             if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 943                  -a "x$ac_cv_func_acl_get_fd_np" = "xyes" \
 944                  -a "x$ac_cv_func_acl_get_perm" != "xyes" \
 945                  -a "x$ac_cv_func_acl_get_perm_np" = "xyes" \
 946                  -a "x$ac_cv_func_acl_set_fd_np" = "xyes"; then
 947                 if test "x$ac_cv_have_decl_ACL_USER" = "xyes"; then
 948                     AC_CACHE_VAL([ac_cv_archive_acl_freebsd],
 949                       [ac_cv_archive_acl_freebsd=yes])
 950                     if test "x$ac_cv_have_decl_ACL_TYPE_NFS4" = "xyes" \
 951                          -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
 952                          -a "x$ac_cv_func_acl_get_brand_np" = "xyes" \
 953                          -a "x$ac_cv_func_acl_get_entry_type_np" = "xyes" \
 954                          -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
 955                          -a "x$ac_cv_func_acl_set_entry_type_np" = "xyes"; then
 956                         AC_CACHE_VAL([ac_cv_archive_acl_freebsd_nfs4],
 957                           [ac_cv_archive_acl_freebsd_nfs4=yes])
 958                     fi
 959                 elif test "x$ac_cv_have_decl_ACL_TYPE_EXTENDED" = "xyes" \
 960                        -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
 961                        -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
 962                        -a "x$ac_cv_func_acl_get_link_np" = "xyes" \
 963                        -a "x$ac_cv_func_acl_set_link_np" = "xyes" \
 964                        -a "x$ac_cv_func_mbr_uid_to_uuid" = "xyes" \
 965                        -a "x$ac_cv_func_mbr_uuid_to_id" = "xyes" \
 966                        -a "x$ac_cv_func_mbr_gid_to_uuid" = "xyes"; then
 967                     AC_CACHE_VAL([ac_cv_archive_acl_darwin],
 968                       [ac_cv_archive_acl_darwin=yes])
 969                 fi
 970             fi
 971         fi
 972     fi
 973     AC_MSG_CHECKING([for ACL support])
 974     if test "x$ac_cv_archive_acl_libacl" = "xyes" \
 975          -a "x$ac_cv_archive_acl_librichacl" = "xyes"; then
 976         AC_MSG_RESULT([libacl (POSIX.1e) + librichacl (NFSv4)])
 977         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
 978           [Linux POSIX.1e ACL support via libacl])
 979         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
 980           [Linux NFSv4 ACL support via librichacl])
 981     elif test "x$ac_cv_archive_acl_libacl" = "xyes"; then
 982         AC_MSG_RESULT([libacl (POSIX.1e)])
 983         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
 984           [Linux POSIX.1e ACL support via libacl])
 985     elif test "x$ac_cv_archive_acl_librichacl" = "xyes"; then
 986         AC_MSG_RESULT([librichacl (NFSv4)])
 987         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
 988           [Linux NFSv4 ACL support via librichacl])
 989     elif test "x$ac_cv_archive_acl_darwin" = "xyes"; then
 990         AC_DEFINE([ARCHIVE_ACL_DARWIN], [1], [Darwin ACL support])
 991         AC_MSG_RESULT([Darwin (limited NFSv4)])
 992     elif test "x$ac_cv_archive_acl_sunos" = "xyes"; then
 993         AC_DEFINE([ARCHIVE_ACL_SUNOS], [1], [Solaris ACL support])
 994         if test "x$ac_cv_archive_acl_sunos_nfs4" = "xyes"; then
 995             AC_DEFINE([ARCHIVE_ACL_SUNOS_NFS4], [1],
 996               [Solaris NFSv4 ACL support])
 997             AC_MSG_RESULT([Solaris (POSIX.1e and NFSv4)])
 998         else
 999             AC_MSG_RESULT([Solaris (POSIX.1e)])
1000         fi
1001     elif test "x$ac_cv_archive_acl_freebsd" = "xyes"; then
1002         AC_DEFINE([ARCHIVE_ACL_FREEBSD], [1], [FreeBSD ACL support])
1003         if test "x$ac_cv_archive_acl_freebsd_nfs4" = "xyes"; then
1004             AC_DEFINE([ARCHIVE_ACL_FREEBSD_NFS4], [1],
1005               [FreeBSD NFSv4 ACL support])
1006             AC_MSG_RESULT([FreeBSD (POSIX.1e and NFSv4)])
1007         else
1008             AC_MSG_RESULT([FreeBSD (POSIX.1e)])
1009         fi
1010     else
1011         AC_MSG_RESULT([none])
1012     fi
1013 fi
1014
1015
1016 AM_CONDITIONAL([INC_LINUX_ACL],
1017   [test "x$ac_cv_archive_acl_libacl" = "xyes" \
1018      -o "x$ac_cv_archive_acl_librichacl" = "xyes"])
1019 AM_CONDITIONAL([INC_SUNOS_ACL], [test "x$ac_cv_archive_acl_sunos" = "xyes"])
1020 AM_CONDITIONAL([INC_DARWIN_ACL],
1021           [test "x$ac_cv_archive_acl_darwin" = "xyes"])
1022 AM_CONDITIONAL([INC_FREEBSD_ACL],
1023           [test "x$ac_cv_archive_acl_freebsd" = "xyes"])
1024
1025 # Additional requirements
1026 AC_SYS_LARGEFILE
1027
1028 dnl NOTE: Crypto checks must run last.
1029 AC_DEFUN([CRYPTO_CHECK], [
1030   if test "$found_$1" != yes; then
1031     saved_CPPFLAGS="$CPPFLAGS"
1032     CPPFLAGS="$CPPFLAGS -I. -I$srcdir -I$srcdir/libarchive"
1033     touch "check_crypto_md.h"
1034     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_$2])
1035     AC_LINK_IFELSE([AC_LANG_SOURCE([
1036 #define ARCHIVE_$1_COMPILE_TEST
1037 #define ARCHIVE_CRYPTO_$1_$2
1038 #define PLATFORM_CONFIG_H "check_crypto_md.h"
1039
1040 $(cat "$srcdir/libarchive/archive_digest.c")
1041
1042 int
1043 main(int argc, char **argv)
1044 {
1045   archive_$3_ctx ctx;
1046   archive_$3_init(&ctx);
1047   archive_$3_update(&ctx, *argv, argc);
1048   archive_$3_final(&ctx, NULL);
1049   return 0;
1050 }
1051 ])],
1052     [ AC_MSG_RESULT([yes])
1053       found_$1=yes
1054       found_$2=yes
1055       AC_DEFINE(ARCHIVE_CRYPTO_$1_$2, 1, [ $1 via ARCHIVE_CRYPTO_$1_$2 supported.])
1056     ],
1057     [ AC_MSG_RESULT([no])])
1058     CPPFLAGS="$saved_CPPFLAGS"
1059     rm "check_crypto_md.h"
1060   fi
1061 ])
1062
1063 AC_DEFUN([CRYPTO_CHECK_WIN], [
1064   if test "$found_$1" != yes; then
1065     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_WIN])
1066     AC_LINK_IFELSE([AC_LANG_SOURCE([
1067 #define ARCHIVE_$1_COMPILE_TEST
1068 #include <windows.h>
1069 #include <wincrypt.h>
1070
1071 int
1072 main(int argc, char **argv)
1073 {
1074         (void)argc;
1075         (void)argv;
1076
1077         return ($2);
1078 }
1079 ])],
1080     [ AC_MSG_RESULT([yes])
1081       found_$1=yes
1082       found_WIN=yes
1083       AC_DEFINE(ARCHIVE_CRYPTO_$1_WIN, 1, [ $1 via ARCHIVE_CRYPTO_$1_WIN supported.])
1084     ],
1085     [ AC_MSG_RESULT([no])])
1086   fi
1087 ])
1088
1089 case "$host_os" in
1090   *mingw* | *cygwin* | *msys*)
1091         ;;
1092   *)
1093         CRYPTO_CHECK(MD5, LIBC, md5)
1094         CRYPTO_CHECK(MD5, LIBSYSTEM, md5)
1095         CRYPTO_CHECK(RMD160, LIBC, rmd160)
1096         CRYPTO_CHECK(SHA1, LIBC, sha1)
1097         CRYPTO_CHECK(SHA1, LIBSYSTEM, sha1)
1098         CRYPTO_CHECK(SHA256, LIBC, sha256)
1099         CRYPTO_CHECK(SHA256, LIBC2, sha256)
1100         CRYPTO_CHECK(SHA256, LIBC3, sha256)
1101         CRYPTO_CHECK(SHA256, LIBSYSTEM, sha256)
1102         CRYPTO_CHECK(SHA384, LIBC, sha384)
1103         CRYPTO_CHECK(SHA384, LIBC2, sha384)
1104         CRYPTO_CHECK(SHA384, LIBC3, sha384)
1105         CRYPTO_CHECK(SHA384, LIBSYSTEM, sha384)
1106         CRYPTO_CHECK(SHA512, LIBC, sha512)
1107         CRYPTO_CHECK(SHA512, LIBC2, sha512)
1108         CRYPTO_CHECK(SHA512, LIBC3, sha512)
1109         CRYPTO_CHECK(SHA512, LIBSYSTEM, sha512)
1110         ;;
1111 esac
1112
1113 if test "x$with_cng" != "xno"; then
1114     AC_CHECK_HEADERS([bcrypt.h],[
1115         LIBS="$LIBS -lbcrypt"
1116     ],[],
1117     [[#ifdef HAVE_WINDOWS_H
1118     # include <windows.h>
1119     #endif
1120     ]])
1121 fi
1122
1123 if test "x$with_nettle" != "xno"; then
1124     AC_CHECK_HEADERS([nettle/md5.h nettle/ripemd160.h nettle/sha.h])
1125     AC_CHECK_HEADERS([nettle/pbkdf2.h nettle/aes.h nettle/hmac.h])
1126     saved_LIBS=$LIBS
1127     AC_CHECK_LIB(nettle,nettle_sha1_init)
1128     CRYPTO_CHECK(MD5, NETTLE, md5)
1129     CRYPTO_CHECK(RMD160, NETTLE, rmd160)
1130     CRYPTO_CHECK(SHA1, NETTLE, sha1)
1131     CRYPTO_CHECK(SHA256, NETTLE, sha256)
1132     CRYPTO_CHECK(SHA384, NETTLE, sha384)
1133     CRYPTO_CHECK(SHA512, NETTLE, sha512)
1134     if test "x$found_NETTLE" != "xyes"; then
1135       LIBS=$saved_LIBS
1136     fi
1137 fi
1138
1139 if test "x$with_openssl" != "xno"; then
1140     AC_CHECK_HEADERS([openssl/evp.h])
1141     saved_LIBS=$LIBS
1142     case "$host_os" in
1143       *mingw* | *cygwin* | *msys*)
1144         case "$host_cpu" in
1145           x86_64)
1146             AC_CHECK_LIB(eay64,OPENSSL_config)
1147             if test "x$ac_cv_lib_eay64_main" != "xyes"; then
1148               AC_CHECK_LIB(eay32,OPENSSL_config)
1149             fi
1150             ;;
1151           *)
1152             AC_CHECK_LIB(eay32,OPENSSL_config)
1153             ;;
1154         esac
1155         ;;
1156       *)
1157         AC_CHECK_LIB(crypto,OPENSSL_config)
1158         ;;
1159     esac
1160     CRYPTO_CHECK(MD5, OPENSSL, md5)
1161     CRYPTO_CHECK(RMD160, OPENSSL, rmd160)
1162     CRYPTO_CHECK(SHA1, OPENSSL, sha1)
1163     CRYPTO_CHECK(SHA256, OPENSSL, sha256)
1164     CRYPTO_CHECK(SHA384, OPENSSL, sha384)
1165     CRYPTO_CHECK(SHA512, OPENSSL, sha512)
1166     AC_CHECK_FUNCS([PKCS5_PBKDF2_HMAC_SHA1])
1167 fi
1168
1169 # Probe libmd AFTER OpenSSL/libcrypto.
1170 # The two are incompatible and OpenSSL is more complete.
1171 AC_CHECK_HEADERS([md5.h ripemd.h sha.h sha256.h sha512.h])
1172 saved_LIBS=$LIBS
1173 AC_CHECK_LIB(md,MD5Init)
1174 CRYPTO_CHECK(MD5, LIBMD, md5)
1175 CRYPTO_CHECK(RMD160, LIBMD, rmd160)
1176 CRYPTO_CHECK(SHA1, LIBMD, sha1)
1177 CRYPTO_CHECK(SHA256, LIBMD, sha256)
1178 CRYPTO_CHECK(SHA512, LIBMD, sha512)
1179 if test "x$found_LIBMD" != "xyes"; then
1180   LIBS=$saved_LIBS
1181 fi
1182
1183 case "$host_os" in
1184   *mingw* | *cygwin* | *msys*)
1185         CRYPTO_CHECK_WIN(MD5, CALG_MD5)
1186         CRYPTO_CHECK_WIN(SHA1, CALG_SHA1)
1187         CRYPTO_CHECK_WIN(SHA256, CALG_SHA_256)
1188         CRYPTO_CHECK_WIN(SHA384, CALG_SHA_384)
1189         CRYPTO_CHECK_WIN(SHA512, CALG_SHA_512)
1190         ;;
1191 esac
1192
1193 # Ensure test directories are present if building out-of-tree
1194 AC_CONFIG_COMMANDS([mkdirs],
1195                    [mkdir -p libarchive/test tar/test cat/test cpio/test])
1196
1197 AC_OUTPUT