configure.ac

   1 #
   2 # Copyright (C) 2007-2015 Tobias Brunner
   3 # Copyright (C) 2006-2016 Andreas Steffen
   4 # Copyright (C) 2006-2014 Martin Willi
   5 # HSR Hochschule fuer Technik Rapperswil
   6 #
   7 # This program is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by the
   9 # Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 # for more details.
  16 #
  17
  18 # ============================
  19 #  initialize & set some vars
  20 # ============================
  21
  22 AC_INIT([strongSwan],[5.5.1rc1])
  23 AM_INIT_AUTOMAKE(m4_esyscmd([
  24         echo tar-ustar
  25         echo subdir-objects
  26         case `automake --version | head -n 1` in
  27                 *" 1.9"*);;
  28                 *" 1.10"*);;
  29                 *" 1.11"*);;
  30                 # don't use parallel test harness in 1.12 and up
  31                 *) echo serial-tests;;
  32         esac
  33 ]))
  34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  35 AC_CONFIG_MACRO_DIR([m4/config])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
  38 PKG_PROG_PKG_CONFIG
  39
  40 m4_include(m4/macros/split-package-version.m4)
  41 SPLIT_PACKAGE_VERSION
  42
  43 # =================================
  44 #  check --enable-xxx & --with-xxx
  45 # =================================
  46
  47 m4_include(m4/macros/with.m4)
  48
  49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
  50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
  51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
  52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
  53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
  54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
  55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
  56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
  57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
  58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
  59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
  60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
  61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
  62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
  63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
  64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
  65 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
  66 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
  67 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
  68 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
  69 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
  70 ARG_WITH_SET([pythoneggdir],         ["main site-packages directory"], [path to install python eggs to to])
  71
  72 if test -n "$PKG_CONFIG"; then
  73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
  74 fi
  75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
  76 AC_SUBST(systemdsystemunitdir)
  77
  78 AC_ARG_WITH(
  79         [user],
  80         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
  81         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
  82          AC_SUBST(ipsecuser, "$withval")],
  83         [AC_SUBST(ipsecuser, "root")]
  84 )
  85
  86 AC_ARG_WITH(
  87         [group],
  88         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
  89         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
  90          AC_SUBST(ipsecgroup, "$withval")],
  91         [AC_SUBST(ipsecgroup, "root")]
  92 )
  93
  94 AC_ARG_WITH(
  95         [charon-udp-port],
  96         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
  97         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
  98          AC_SUBST(charon_udp_port, [$withval])],
  99         [AC_SUBST(charon_udp_port, 500)]
 100 )
 101
 102 AC_ARG_WITH(
 103         [charon-natt-port],
 104         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
 105         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
 106          AC_SUBST(charon_natt_port, [$withval])],
 107         [AC_SUBST(charon_natt_port, 4500)]
 108 )
 109
 110 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
 111 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
 112         AC_MSG_ERROR(the ports have to be different)
 113 else
 114         AC_MSG_RESULT(ok)
 115 fi
 116
 117 # convert script name to uppercase
 118 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
 119
 120 m4_include(m4/macros/enable-disable.m4)
 121
 122 # crypto plugins
 123 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
 124 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
 125 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
 126 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
 127 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
 128 ARG_ENABL_SET([chapoly],        [enables the ChaCha20/Poly1305 AEAD plugin.])
 129 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
 130 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
 131 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
 132 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
 133 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
 134 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
 135 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
 136 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
 137 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
 138 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
 139 ARG_ENABL_SET([newhope],        [enable New Hope crypto plugin.])
 140 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
 141 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
 142 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
 143 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
 144 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
 145 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
 146 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
 147 ARG_ENABL_SET([aesni],          [enable Intel AES-NI crypto plugin.])
 148 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
 149 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
 150 ARG_ENABL_SET([sha3],           [enable SHA3_224/SHA3_256/SHA3_384/SHA3_512 software implementation plugin.])
 151 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
 152 ARG_ENABL_SET([mgf1],           [enables the MGF1 software implementation plugin.])
 153 # encoding/decoding plugins
 154 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
 155 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
 156 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
 157 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
 158 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
 159 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
 160 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
 161 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
 162 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
 163 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
 164 # fetcher/resolver plugins
 165 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
 166 ARG_ENABL_SET([files],          [enable simple file:// URI fetcher.])
 167 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
 168 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
 169 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
 170 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
 171 # database plugins
 172 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
 173 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
 174 # authentication/credential plugins
 175 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
 176 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
 177 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
 178 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
 179 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
 180 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
 181 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
 182 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
 183 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
 184 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
 185 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
 186 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
 187 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
 188 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
 189 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
 190 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
 191 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
 192 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
 193 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
 194 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
 195 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
 196 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
 197 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
 198 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
 199 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
 200 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
 201 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
 202 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
 203 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
 204 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
 205 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
 206 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
 207 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
 208 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
 209 # kernel interfaces / sockets
 210 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
 211 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
 212 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
 213 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
 214 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
 215 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
 216 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
 217 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
 218 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
 219 # configuration/control plugins
 220 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
 221 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
 222 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
 223 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
 224 ARG_DISBL_SET([vici],           [disable strongSwan IKE generic IPC interface plugin.])
 225 # attribute provider/consumer plugins
 226 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
 227 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
 228 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
 229 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
 230 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
 231 ARG_ENABL_SET([p-cscf],         [enable plugin to request P-CSCF server addresses from an ePDG.])
 232 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
 233 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
 234 # TNC modules/plugins
 235 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
 236 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
 237 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
 238 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
 239 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
 240 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
 241 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
 242 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
 243 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
 244 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
 245 ARG_ENABL_SET([imc-hcd],        [enable IMC hcd module.])
 246 ARG_ENABL_SET([imv-hcd],        [enable IMV hcd module.])
 247 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
 248 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
 249 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
 250 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
 251 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
 252 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
 253 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
 254 # misc plugins
 255 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
 256 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
 257 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
 258 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
 259 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
 260 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
 261 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
 262 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
 263 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
 264 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
 265 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
 266 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
 267 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
 268 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
 269 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
 270 # programs/components
 271 ARG_ENABL_SET([aikgen],         [enable AIK generator for TPM 1.2.])
 272 ARG_ENABL_SET([aikpub2],        [enable AIK extractor for TPM 2.0.])
 273 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
 274 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
 275 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
 276 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
 277 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
 278 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
 279 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
 280 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
 281 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
 282 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
 283 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
 284 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
 285 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
 286 ARG_ENABL_SET([svc],            [enable charon Windows service.])
 287 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
 288 ARG_DISBL_SET([swanctl],        [disable swanctl configuration and control tool.])
 289 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
 290 # optional features
 291 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
 292 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
 293 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
 294 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
 295 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
 296 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
 297 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
 298 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
 299 ARG_ENABL_SET([ruby-gems],      [enable build of provided ruby gems.])
 300 ARG_ENABL_SET([ruby-gems-install],[enable installation of provided ruby gems.])
 301 ARG_ENABL_SET([python-eggs],    [enable build of provided python eggs.])
 302 ARG_ENABL_SET([python-eggs-install],[enable installation of provided python eggs.])
 303 ARG_ENABL_SET([perl-cpan],      [enable build of provided perl CPAN module.])
 304 ARG_ENABL_SET([perl-cpan-install],[enable installation of provided CPAN module.])
 305 ARG_ENABL_SET([tss-trousers],   [enable the use of the TrouSerS Trusted Software Stack])
 306 ARG_ENABL_SET([tss-tss2],       [enable the use of the TSS 2.0 Trusted Software Stack])
 307
 308 # compile options
 309 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
 310 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
 311 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
 312 ARG_ENABL_SET([log-thread-ids], [use thread ID, if available, instead of an incremented value starting from 1, to identify threads.])
 313 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
 314
 315 # ===================================
 316 #  option to disable default options
 317 # ===================================
 318
 319 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
 320
 321 if test x$defaults = xfalse; then
 322         for option in $enabled_by_default; do
 323                 eval test x\${${option}_given} = xtrue && continue
 324                 eval $option=false
 325         done
 326 fi
 327
 328 # ==============================
 329 #  option to enable all options
 330 # ==============================
 331
 332 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
 333
 334 if test x$all_given = xtrue; then
 335         for option in $disabled_by_default; do
 336                 eval test x\${${option}_given} = xtrue && continue
 337                 eval $option=true
 338         done
 339 fi
 340
 341 # ===========================
 342 #  set up compiler and flags
 343 # ===========================
 344
 345 if test -z "$CFLAGS"; then
 346         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
 347 fi
 348 AC_PROG_CC
 349 AM_PROG_CC_C_O
 350
 351 AC_LIB_PREFIX
 352 AC_C_BIGENDIAN
 353
 354 # =========================
 355 #  check required programs
 356 # =========================
 357
 358 LT_INIT
 359 AC_PROG_INSTALL
 360 AC_PROG_EGREP
 361 AC_PROG_AWK
 362 AC_PROG_LEX
 363 AC_PROG_YACC
 364 AM_PATH_PYTHON(,,[:])
 365 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 366 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 367
 368 # because gperf is not needed by end-users we just report it but do not abort on failure
 369 AC_MSG_CHECKING([gperf version >= 3.0.0])
 370 if test -x "$GPERF"; then
 371         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
 372                 AC_MSG_RESULT([yes])
 373         else
 374                 AC_MSG_RESULT([no])
 375         fi
 376 else
 377         AC_MSG_RESULT([not found])
 378 fi
 379
 380 # ========================
 381 #  dependency calculation
 382 # ========================
 383
 384 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
 385         xauth_generic=false;
 386 fi
 387
 388 if test x$kernel_libipsec = xtrue; then
 389         libipsec=true;
 390 fi
 391
 392 if test x$eap_aka_3gpp2 = xtrue; then
 393         gmp=true;
 394 fi
 395
 396 if test x$eap_aka = xtrue; then
 397         fips_prf=true;
 398         simaka=true;
 399 fi
 400
 401 if test x$eap_sim = xtrue; then
 402         fips_prf=true;
 403         simaka=true;
 404 fi
 405
 406 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
 407         radius=true;
 408 fi
 409
 410 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
 411         tnc_tnccs=true;
 412 fi
 413
 414 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
 415         tls=true;
 416 fi
 417
 418 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue -o x$imc_hcd = xtrue -o x$imv_hcd = xtrue; then
 419         imcv=true;
 420 fi
 421
 422 if test x$fips_prf = xtrue; then
 423         if test x$openssl = xfalse; then
 424                 sha1=true;
 425         fi
 426 fi
 427
 428 if test x$swanctl = xtrue; then
 429         vici=true
 430 fi
 431
 432 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
 433         xml=true
 434 fi
 435
 436 if test x$manager = xtrue; then
 437         fast=true
 438 fi
 439
 440 if test x$medsrv = xtrue; then
 441         mediation=true
 442         fast=true
 443 fi
 444
 445 if test x$medcli = xtrue; then
 446         mediation=true
 447 fi
 448
 449 if test x$ruby_gems_install = xtrue; then
 450         ruby_gems=true
 451 fi
 452
 453 if test x$python_eggs_install = xtrue; then
 454         python_eggs=true
 455 fi
 456
 457 if test x$perl_cpan_install = xtrue; then
 458         perl_cpan=true
 459 fi
 460
 461 if test x$aikgen = xtrue; then
 462         tss_trousers=true
 463 fi
 464
 465 if test x$aikpub2 = xtrue; then
 466         tss_tss2=true
 467 fi
 468
 469 if test x$ntru = xtrue -o x$bliss = xtrue; then
 470         mgf1=true
 471 fi
 472
 473 # ===========================================
 474 #  check required libraries and header files
 475 # ===========================================
 476
 477 AC_HEADER_STDBOOL
 478 AC_FUNC_ALLOCA
 479 AC_FUNC_STRERROR_R
 480
 481 #  libraries needed on some platforms but not on others
 482 # ------------------------------------------------------
 483 saved_LIBS=$LIBS
 484
 485 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
 486 LIBS=""
 487 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 488 AC_SUBST(DLLIB)
 489
 490 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
 491 LIBS=""
 492 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
 493 AC_CHECK_FUNCS(backtrace)
 494 AC_SUBST(BTLIB)
 495
 496 # OpenSolaris needs libsocket and libnsl for socket()
 497 LIBS=""
 498 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
 499         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
 500 )
 501 AC_SUBST(SOCKLIB)
 502
 503 # Android has pthread_* functions in bionic (libc), others need libpthread
 504 LIBS=$DLLIB
 505 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
 506 AC_SUBST(PTHREADLIB)
 507
 508 # Some architectures require explicit -latomic for __atomic_* operations
 509 # AC_SEARCH_LIBS() does not work when checking built-ins due to conflicting types
 510 LIBS=""
 511 AC_MSG_CHECKING(for library containing __atomic_and_fetch)
 512 AC_LINK_IFELSE(
 513         [AC_LANG_PROGRAM([[]], [[int x; __atomic_and_fetch(&x, 1, __ATOMIC_RELAXED);]])],
 514         [AC_MSG_RESULT([none required])],
 515         [LIBS="-latomic";
 516          AC_LINK_IFELSE(
 517                 [AC_LANG_PROGRAM([[]], [[int x; __atomic_and_fetch(&x, 1, __ATOMIC_RELAXED);]])],
 518                 [AC_MSG_RESULT([-latomic]); ATOMICLIB=$LIBS],
 519                 [AC_MSG_RESULT([no])])
 520         ]
 521 )
 522 AC_SUBST(ATOMICLIB)
 523
 524 LIBS=$saved_LIBS
 525 # ------------------------------------------------------
 526
 527 AC_MSG_CHECKING(for dladdr)
 528 AC_COMPILE_IFELSE(
 529         [AC_LANG_PROGRAM(
 530                 [[#define _GNU_SOURCE
 531                   #include <dlfcn.h>]],
 532                 [[Dl_info* info = 0;
 533                   dladdr(0, info);]])],
 534         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
 535         [AC_MSG_RESULT([no])]
 536 )
 537
 538 # check if pthread_condattr_setclock(CLOCK_MONOTONIC) is supported
 539 saved_LIBS=$LIBS
 540 LIBS=$PTHREADLIB
 541 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONIC)])
 542 AC_RUN_IFELSE(
 543         [AC_LANG_SOURCE(
 544                 [[#include <pthread.h>
 545                   int main() { pthread_condattr_t attr;
 546                         pthread_condattr_init(&attr);
 547                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
 548         [AC_MSG_RESULT([yes]);
 549          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 550                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
 551         [AC_MSG_RESULT([no])],
 552         # Check existence of pthread_condattr_setclock if cross-compiling
 553         [AC_MSG_RESULT([unknown]);
 554          AC_CHECK_FUNCS(pthread_condattr_setclock,
 555                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 556                                    [have pthread_condattr_setclock()])]
 557         )]
 558 )
 559 # check if we actually are able to configure attributes on cond vars
 560 AC_CHECK_FUNCS(pthread_condattr_init)
 561 # instead of pthread_condattr_setclock Android has this function
 562 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
 563 # check if we can cancel threads
 564 AC_CHECK_FUNCS(pthread_cancel)
 565 # check if native rwlocks are available
 566 AC_CHECK_FUNCS(pthread_rwlock_init)
 567 # check if pthread spinlocks are available
 568 AC_CHECK_FUNCS(pthread_spin_init)
 569 # check if we have POSIX semaphore functions, including timed-wait
 570 AC_CHECK_FUNCS(sem_timedwait)
 571 LIBS=$saved_LIBS
 572
 573 AC_CHECK_FUNC(
 574         [gettid],
 575         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
 576         [AC_MSG_CHECKING([for SYS_gettid])
 577          AC_COMPILE_IFELSE(
 578                 [AC_LANG_PROGRAM(
 579                         [[#define _GNU_SOURCE
 580                           #include <unistd.h>
 581                           #include <sys/syscall.h>]],
 582                         [[int main() {
 583                           return syscall(SYS_gettid);}]])],
 584                 [AC_MSG_RESULT([yes]);
 585                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
 586                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
 587                 [AC_MSG_RESULT([no])]
 588         )]
 589 )
 590
 591 AC_CHECK_FUNC(
 592         [qsort_r],
 593         [
 594                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
 595                 # set -Werror so that we get an error for "argument ... has
 596                 # incompatible pointer type" warnings
 597                 save_CFLAGS="$CFLAGS"
 598                 CFLAGS="$CFLAGS -Werror -Wno-unused-parameter"
 599                 AC_MSG_CHECKING([for GNU-style qsort_r])
 600                 AC_COMPILE_IFELSE(
 601                         [AC_LANG_PROGRAM(
 602                                 [[#define _GNU_SOURCE
 603                                   #include <stdlib.h>
 604                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
 605                                 [[int arr[] = { 0, 1 };
 606                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
 607                 [AC_MSG_RESULT([yes]);
 608                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
 609                 [
 610                         AC_MSG_RESULT([no]);
 611                         AC_MSG_CHECKING([for BSD-style qsort_r])
 612                         AC_COMPILE_IFELSE(
 613                                 [AC_LANG_PROGRAM(
 614                                         [[#include <stdlib.h>
 615                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
 616                                         [[int arr[] = { 0, 1 };
 617                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
 618                         [AC_MSG_RESULT([yes]);
 619                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
 620                         [AC_MSG_RESULT([no]);
 621                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
 622                 ])
 623                 CFLAGS="$save_CFLAGS"
 624         ]
 625 )
 626
 627 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
 628 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime dirfd sigwaitinfo)
 629
 630 AC_CHECK_FUNC([syslog], [
 631         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
 632         syslog=true
 633 ])
 634 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
 635
 636 AC_CHECK_HEADERS(sys/sockio.h sys/syscall.h sys/param.h glob.h net/if_tun.h)
 637 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
 638 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
 639 [
 640         #include <sys/types.h>
 641         #include <netinet/in.h>
 642 ])
 643
 644 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 645 [
 646         #include <sys/types.h>
 647         #include <sys/socket.h>
 648 ])
 649
 650 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 651 [
 652         #include <sys/types.h>
 653         #ifdef HAVE_NET_PFKEYV2_H
 654         #include <net/pfkeyv2.h>
 655         #else
 656         #include <stdint.h>
 657         #include <linux/pfkeyv2.h>
 658         #endif
 659 ])
 660
 661 AC_MSG_CHECKING([for in6addr_any])
 662 AC_COMPILE_IFELSE(
 663         [AC_LANG_PROGRAM(
 664                 [[#include <sys/types.h>
 665                   #include <sys/socket.h>
 666                   #include <netinet/in.h>]],
 667                 [[struct in6_addr in6 __attribute__((unused));
 668                   in6 = in6addr_any;]])],
 669         [AC_MSG_RESULT([yes]);
 670          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
 671         [AC_MSG_RESULT([no])]
 672 )
 673
 674 AC_MSG_CHECKING([for in6_pktinfo])
 675 AC_COMPILE_IFELSE(
 676         [AC_LANG_PROGRAM(
 677                 [[#define _GNU_SOURCE
 678                   #include <sys/types.h>
 679                   #include <sys/socket.h>
 680                   #include <netinet/in.h>]],
 681                 [[struct in6_pktinfo pi;
 682                   if (pi.ipi6_ifindex)
 683                   {
 684                     return 0;
 685                   }]])],
 686         [AC_MSG_RESULT([yes]);
 687          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
 688         [AC_MSG_RESULT([no])]
 689 )
 690
 691 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
 692 AC_COMPILE_IFELSE(
 693         [AC_LANG_PROGRAM(
 694                 [[#include <sys/socket.h>
 695                   #include <net/if.h>
 696                   #include <net/route.h>]],
 697                 [[return RTM_IFANNOUNCE;]])],
 698         [AC_MSG_RESULT([yes]);
 699          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
 700         [AC_MSG_RESULT([no])]
 701 )
 702
 703 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 704 AC_COMPILE_IFELSE(
 705         [AC_LANG_PROGRAM(
 706                 [[#include <sys/types.h>
 707                   #ifdef HAVE_NETIPSEC_IPSEC_H
 708                   #include <netipsec/ipsec.h>
 709                   #elif defined(HAVE_NETINET6_IPSEC_H)
 710                   #include <netinet6/ipsec.h>
 711                   #else
 712                   #include <stdint.h>
 713                   #include <linux/ipsec.h>
 714                   #endif]],
 715                 [[int mode = IPSEC_MODE_BEET;
 716                   return mode;]])],
 717         [AC_MSG_RESULT([yes]);
 718          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
 719         [AC_MSG_RESULT([no])]
 720 )
 721
 722 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 723 AC_COMPILE_IFELSE(
 724         [AC_LANG_PROGRAM(
 725                 [[#include <sys/types.h>
 726                   #ifdef HAVE_NETIPSEC_IPSEC_H
 727                   #include <netipsec/ipsec.h>
 728                   #elif defined(HAVE_NETINET6_IPSEC_H)
 729                   #include <netinet6/ipsec.h>
 730                   #else
 731                   #include <stdint.h>
 732                   #include <linux/ipsec.h>
 733                   #endif]],
 734                 [[int dir = IPSEC_DIR_FWD;
 735                   return dir;]])],
 736         [AC_MSG_RESULT([yes]);
 737          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
 738         [AC_MSG_RESULT([no])]
 739 )
 740
 741 AC_MSG_CHECKING([for RTA_TABLE])
 742 AC_COMPILE_IFELSE(
 743         [AC_LANG_PROGRAM(
 744                 [[#include <sys/socket.h>
 745                   #include <linux/netlink.h>
 746                   #include <linux/rtnetlink.h>]],
 747                 [[int rta_type = RTA_TABLE;
 748                   return rta_type;]])],
 749         [AC_MSG_RESULT([yes]);
 750          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
 751         [AC_MSG_RESULT([no])]
 752 )
 753
 754 AC_MSG_CHECKING([for __int128])
 755 AC_COMPILE_IFELSE(
 756         [AC_LANG_PROGRAM(
 757                 [[#include <sys/types.h>]],
 758                 [[__int128 x = 0;
 759                   return x;]])],
 760         [AC_MSG_RESULT([yes]);
 761          AC_DEFINE([HAVE_INT128], [], [have __int128 type support])],
 762         [AC_MSG_RESULT([no])]
 763 )
 764
 765 AC_MSG_CHECKING([for GCC __sync operations])
 766 AC_RUN_IFELSE([AC_LANG_SOURCE(
 767         [[
 768                         int main() {
 769                         int ref = 1;
 770                         __sync_fetch_and_add (&ref, 1);
 771                         __sync_sub_and_fetch (&ref, 1);
 772                         __sync_val_compare_and_swap(&ref, 1, 0);
 773                         return ref;
 774                 }
 775         ]])],
 776         [AC_MSG_RESULT([yes]);
 777          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
 778                    [have GCC __sync_* operations])],
 779         [AC_MSG_RESULT([no])],
 780         [AC_MSG_RESULT([no])]
 781 )
 782
 783 case "$printf_hooks" in
 784 auto|builtin|glibc|vstr)
 785         ;;
 786 *)
 787         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
 788         printf_hooks=auto
 789         ;;
 790 esac
 791
 792 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
 793         # check for the new register_printf_specifier function with len argument,
 794         # or the deprecated register_printf_function without
 795         AC_CHECK_FUNC(
 796                 [register_printf_specifier],
 797                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
 798                 [AC_CHECK_FUNC(
 799                         [register_printf_function],
 800                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
 801                         [
 802                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
 803                                 if test x$printf_hooks = xglibc; then
 804                                         AC_MSG_ERROR([please select a different printf hook implementation])
 805                                 else
 806                                         # fallback to builtin printf hook implementation
 807                                         printf_hooks=builtin
 808                                 fi
 809                         ]
 810                 )]
 811         )
 812 fi
 813
 814 AC_MSG_CHECKING([for Windows target])
 815 AC_COMPILE_IFELSE(
 816         [AC_LANG_PROGRAM(
 817                 [[#include <windows.h>]],
 818                 [[#ifndef WIN32
 819                   # error WIN32 undefined
 820                   #endif
 821                 ]])],
 822         [
 823                 AC_MSG_RESULT([yes])
 824                 windows=true
 825                 openssl_lib=eay32
 826                 AC_SUBST(PTHREADLIB, "")
 827                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
 828                 case "$CFLAGS" in
 829                         *ms-bitfields*) ;;
 830                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
 831                 esac
 832         ],
 833         [
 834                 AC_MSG_RESULT([no])
 835                 openssl_lib=crypto
 836
 837                 # check for clock_gettime() on non-Windows only. Otherwise this
 838                 # check might find clock_gettime() in libwinpthread, but we don't want
 839                 # to link against it.
 840                 saved_LIBS=$LIBS
 841                 # FreeBSD has clock_gettime in libc, Linux needs librt
 842                 LIBS=""
 843                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
 844                 AC_CHECK_FUNCS(clock_gettime)
 845                 AC_SUBST(RTLIB)
 846                 LIBS=$saved_LIBS
 847         ]
 848 )
 849 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
 850 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
 851
 852 AC_MSG_CHECKING([for working __attribute__((packed))])
 853 AC_COMPILE_IFELSE(
 854         [AC_LANG_PROGRAM([], [[
 855                 struct test { char a; short b; } __attribute__((packed));
 856                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
 857                         __attribute__((unused));
 858                 return 0;
 859         ]])],
 860         [AC_MSG_RESULT([yes])],
 861         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
 862 )
 863
 864 AC_MSG_CHECKING([clang])
 865 AC_COMPILE_IFELSE(
 866         [AC_LANG_PROGRAM(
 867                 [], [[
 868                  #ifndef __clang__
 869                  # error not using LLVM clang
 870                  #endif
 871                 ]])],
 872         [
 873                 AC_MSG_RESULT([yes])
 874         ],
 875         [
 876                 AC_MSG_RESULT([no])
 877                 # GCC, but not MinGW requires -rdynamic for plugins
 878                 if test x$windows != xtrue; then
 879                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
 880                 fi
 881         ]
 882 )
 883
 884 AC_MSG_CHECKING([x86/x64 target])
 885 AC_COMPILE_IFELSE(
 886         [AC_LANG_PROGRAM(
 887                 [], [[
 888                  #if !defined(__i386__) && !defined(__x86_64__)
 889                  # error not on x86/x64
 890                  #endif
 891                 ]])],
 892         [
 893                 x86x64=true
 894                 AC_MSG_RESULT([yes])
 895         ],
 896         [AC_MSG_RESULT([no])]
 897 )
 898 AM_CONDITIONAL(USE_X86X64, [test "x$x86x64" = xtrue])
 899
 900 if test x$printf_hooks = xvstr; then
 901         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
 902         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
 903 fi
 904
 905 if test x$printf_hooks = xbuiltin; then
 906         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
 907 fi
 908
 909 if test x$gmp = xtrue; then
 910         saved_LIBS=$LIBS
 911         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
 912         AC_MSG_CHECKING([mpz_powm_sec])
 913         if test x$mpz_powm_sec = xyes; then
 914                 AC_COMPILE_IFELSE(
 915                         [AC_LANG_PROGRAM(
 916                                 [[#include "gmp.h"]],
 917                                 [[void *x = mpz_powm_sec;]])],
 918                         [AC_MSG_RESULT([yes]);
 919                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
 920                         [AC_MSG_RESULT([no])]
 921                 )
 922         else
 923                 AC_MSG_RESULT([disabled])
 924         fi
 925         LIBS=$saved_LIBS
 926         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 927         AC_COMPILE_IFELSE(
 928                 [AC_LANG_PROGRAM(
 929                         [[#include "gmp.h"]],
 930                         [[
 931                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 932                                         #error bad gmp
 933                                 #endif]])],
 934                 [AC_MSG_RESULT([yes])],
 935                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 936         )
 937 fi
 938
 939 if test x$ldap = xtrue; then
 940         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
 941         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
 942         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 943 fi
 944
 945 if test x$curl = xtrue; then
 946         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
 947         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 948 fi
 949
 950 if test x$unbound = xtrue; then
 951         AC_CHECK_LIB([ldns],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])],[])
 952         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
 953         AC_CHECK_LIB([unbound],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])],[])
 954         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
 955 fi
 956
 957 if test x$soup = xtrue; then
 958         PKG_CHECK_MODULES(soup, [libsoup-2.4])
 959         AC_SUBST(soup_CFLAGS)
 960         AC_SUBST(soup_LIBS)
 961 fi
 962
 963 if test x$xml = xtrue; then
 964         PKG_CHECK_MODULES(xml, [libxml-2.0])
 965         AC_SUBST(xml_CFLAGS)
 966         AC_SUBST(xml_LIBS)
 967 fi
 968
 969 if test x$systemd = xtrue; then
 970         AC_MSG_CHECKING([for systemd system unit directory])
 971         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 972                 AC_MSG_RESULT([$systemdsystemunitdir])
 973         else
 974                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 975         fi
 976
 977         PKG_CHECK_MODULES(systemd, [libsystemd >= 209],
 978                 [AC_SUBST(systemd_CFLAGS)
 979                  AC_SUBST(systemd_LIBS)],
 980                 [PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
 981                  AC_SUBST(systemd_daemon_CFLAGS)
 982                  AC_SUBST(systemd_daemon_LIBS)
 983                  PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
 984                  AC_SUBST(systemd_journal_CFLAGS)
 985                  AC_SUBST(systemd_journal_LIBS)]
 986         )
 987 fi
 988
 989 if test x$tss_trousers = xtrue; then
 990         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
 991         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
 992         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi])
 993 fi
 994
 995 if test x$tss_tss2 = xtrue; then
 996         PKG_CHECK_MODULES(tss2, [tcti-socket], [AC_DEFINE([TSS_TSS2], [], [use TSS 2.0 libraries])])
 997         AC_SUBST(tss2_CFLAGS)
 998         AC_SUBST(tss2_LIBS)
 999 fi
1000
1001 if test x$imv_swid = xtrue; then
1002         PKG_CHECK_MODULES(json, [json-c], [],
1003                 [PKG_CHECK_MODULES(json, [json])])
1004         AC_SUBST(json_CFLAGS)
1005         AC_SUBST(json_LIBS)
1006 fi
1007
1008 if test x$dumm = xtrue; then
1009         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
1010         AC_SUBST(gtk_CFLAGS)
1011         AC_SUBST(gtk_LIBS)
1012         AC_CHECK_PROGS(RUBY, ruby)
1013         AC_MSG_CHECKING([for Ruby header files])
1014         if test -n "$RUBY"; then
1015                 RUBYINCLUDE=
1016                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
1017                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
1018                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
1019                         if test -n "$RUBYARCH"; then
1020                                 AC_MSG_RESULT([$RUBYDIR])
1021                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
1022                         fi
1023                 else
1024                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
1025                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
1026                                 AC_MSG_RESULT([$RUBYDIR])
1027                                 RUBYINCLUDE="-I$RUBYDIR"
1028                         fi
1029                 fi
1030                 if test -z "$RUBYINCLUDE"; then
1031                         AC_MSG_ERROR([ruby.h not found])
1032                 fi
1033                 AC_SUBST(RUBYINCLUDE)
1034         else
1035                 AC_MSG_ERROR([don't know how to run ruby])
1036         fi
1037         AC_MSG_CHECKING([for libruby])
1038         saved_LIBS=$LIBS
1039         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
1040         AC_TRY_LINK_FUNC(ruby_init,
1041                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
1042                 [AC_MSG_ERROR([not found])])
1043         AC_SUBST(RUBYLIB)
1044         AC_CHECK_FUNCS(rb_errinfo)
1045         LIBS=$saved_LIBS
1046 fi
1047
1048 if test x$fast = xtrue; then
1049         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
1050         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
1051         AC_MSG_CHECKING([ClearSilver requires zlib])
1052         saved_CFLAGS=$CFLAGS
1053         saved_LIBS=$LIBS
1054         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
1055         CFLAGS="-I/usr/include/ClearSilver"
1056         AC_LINK_IFELSE(
1057                 [AC_LANG_PROGRAM(
1058                         [[#include <ClearSilver.h>]],
1059                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
1060                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
1061                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
1062         )
1063         AC_SUBST(clearsilver_LIBS)
1064         LIBS=$saved_LIBS
1065         CFLAGS=$saved_CFLAGS
1066 # autoconf does not like CamelCase!? How to fix this?
1067 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
1068
1069         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
1070         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
1071 fi
1072
1073 if test x$mysql = xtrue; then
1074         if test "x$windows" = xtrue; then
1075                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
1076                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
1077                 AC_SUBST(MYSQLLIB, -lmysql)
1078         else
1079                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1080                 if test x$MYSQLCONFIG = x; then
1081                         AC_MSG_ERROR([mysql_config not found!])
1082                 fi
1083                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
1084                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
1085         fi
1086 fi
1087
1088 if test x$sqlite = xtrue; then
1089         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
1090         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
1091         AC_MSG_CHECKING([sqlite3_prepare_v2])
1092         AC_COMPILE_IFELSE(
1093                 [AC_LANG_PROGRAM(
1094                         [[#include <sqlite3.h>]],
1095                         [[void *test = sqlite3_prepare_v2;]])],
1096                 [AC_MSG_RESULT([yes]);
1097                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1098                 [AC_MSG_RESULT([no])]
1099         )
1100         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1101         AC_COMPILE_IFELSE(
1102                 [AC_LANG_PROGRAM(
1103                         [[#include <sqlite3.h>]],
1104                         [[
1105                                 #if SQLITE_VERSION_NUMBER < 3003001
1106                                         #error bad sqlite
1107                                 #endif]])],
1108                 [AC_MSG_RESULT([yes])],
1109                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1110         )
1111 fi
1112
1113 if test x$openssl = xtrue; then
1114         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],
1115                                  [AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[$DLLIB])
1116         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1117 fi
1118
1119 if test x$gcrypt = xtrue; then
1120         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1121         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1122         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1123         AC_COMPILE_IFELSE(
1124                 [AC_LANG_PROGRAM(
1125                         [[#include <gcrypt.h>]],
1126                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1127                 [AC_MSG_RESULT([yes]);
1128                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1129                 [AC_MSG_RESULT([no])]
1130         )
1131 fi
1132
1133 if test x$uci = xtrue; then
1134         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1135         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1136 fi
1137
1138 if test x$android_dns = xtrue; then
1139         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1140         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1141         # we have to force the use of libdl here because the autodetection
1142         # above does not work correctly when cross-compiling for android.
1143         DLLIB="-ldl"
1144         AC_SUBST(DLLIB)
1145 fi
1146
1147 if test x$eap_sim_pcsc = xtrue; then
1148         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1149         AC_SUBST(pcsclite_CFLAGS)
1150         AC_SUBST(pcsclite_LIBS)
1151 fi
1152
1153 if test x$nm = xtrue; then
1154         PKG_CHECK_EXISTS([libnm-glib],
1155                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1156                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1157         )
1158         AC_SUBST(nm_CFLAGS)
1159         AC_SUBST(nm_LIBS)
1160 fi
1161
1162 if test x$xauth_pam = xtrue; then
1163         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1164         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1165 fi
1166
1167 if test x$connmark = xtrue -o x$forecast = xtrue; then
1168         PKG_CHECK_MODULES(libiptc, [libiptc])
1169         AC_SUBST(libiptc_CFLAGS)
1170         AC_SUBST(libiptc_LIBS)
1171 fi
1172
1173 if test x$capabilities = xnative; then
1174         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1175         # Linux requires the following for capset(), Android does not have it,
1176         # but defines capset() in unistd.h instead.
1177         AC_CHECK_HEADERS([sys/capability.h])
1178         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1179         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1180 fi
1181
1182 if test x$capabilities = xlibcap; then
1183         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1184         AC_CHECK_HEADER([sys/capability.h],
1185                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1186                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1187         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1188 fi
1189
1190 if test x$integrity_test = xtrue; then
1191         AC_MSG_CHECKING([for dladdr()])
1192         AC_COMPILE_IFELSE(
1193                 [AC_LANG_PROGRAM(
1194                         [[#define _GNU_SOURCE
1195                           #include <dlfcn.h>]],
1196                         [[Dl_info info; dladdr(main, &info);]])],
1197                 [AC_MSG_RESULT([yes])],
1198                 [AC_MSG_RESULT([no]);
1199                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1200         )
1201         AC_MSG_CHECKING([for dl_iterate_phdr()])
1202         AC_COMPILE_IFELSE(
1203                 [AC_LANG_PROGRAM(
1204                         [[#define _GNU_SOURCE
1205                           #include <link.h>]],
1206                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1207                 [AC_MSG_RESULT([yes])],
1208                 [AC_MSG_RESULT([no]);
1209                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1210         )
1211 fi
1212
1213 if test x$bfd_backtraces = xtrue; then
1214         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1215         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1216                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1217         BFDLIB="-lbfd"
1218         AC_SUBST(BFDLIB)
1219 fi
1220
1221 if test x$unwind_backtraces = xtrue; then
1222         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1223         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1224                 [AC_MSG_ERROR([libunwind.h header not found!])])
1225         UNWINDLIB="-lunwind"
1226         AC_SUBST(UNWINDLIB)
1227 fi
1228
1229 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1230 if test x$dev_headers = xyes; then
1231         dev_headers="$includedir/strongswan"
1232 fi
1233 AC_SUBST(dev_headers)
1234
1235 CFLAGS="$CFLAGS -include `pwd`/config.h"
1236
1237 if test x$tkm = xtrue; then
1238         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1239         if test x$GPRBUILD = x; then
1240                 AC_MSG_ERROR([gprbuild not found])
1241         fi
1242 fi
1243
1244 if test x$coverage = xtrue; then
1245         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1246         if test x$LCOV = x; then
1247                 AC_MSG_ERROR([lcov not found])
1248         fi
1249         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1250         if test x$GENHTML = x; then
1251                 AC_MSG_ERROR([genhtml not found])
1252         fi
1253
1254         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1255         COVERAGE_LDFLAGS="-fprofile-arcs"
1256         AC_SUBST(COVERAGE_CFLAGS)
1257         AC_SUBST(COVERAGE_LDFLAGS)
1258
1259         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1260         CFLAGS="${CFLAGS} -g -O0"
1261 fi
1262
1263 if test x$ruby_gems = xtrue; then
1264         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1265         if test x$GEM = x; then
1266                 AC_MSG_ERROR(RubyGems package manager not found)
1267         fi
1268         if test "x$rubygemdir" = "xgem environment gemdir"; then
1269                 rubygemdir=$($GEM environment gemdir)
1270         fi
1271         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1272 fi
1273 AM_CONDITIONAL(RUBY_GEMS_INSTALL, [test "x$ruby_gems_install" = xtrue])
1274
1275 if test x$python_eggs = xtrue; then
1276         PYTHON_PACKAGE_VERSION=`echo "$PACKAGE_VERSION" | $SED 's/dr/dev/'`
1277         AC_SUBST([PYTHON_PACKAGE_VERSION])
1278         if test x$python_eggs_install = xtrue; then
1279                 AC_PATH_PROG([EASY_INSTALL], [easy_install], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1280                 if test x$EASY_INSTALL = x; then
1281                         AC_MSG_ERROR(Python easy_install not found)
1282                 fi
1283         fi
1284         if test "x$pythoneggdir" = "xmain site-packages directory"; then
1285                 AC_SUBST(PYTHONEGGINSTALLDIR, "")
1286         else
1287                 AC_SUBST(PYTHONEGGINSTALLDIR, "--install-dir $pythoneggdir")
1288         fi
1289         AC_PATH_PROG([PY_TEST], [py.test], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1290 fi
1291 AM_CONDITIONAL(PYTHON_EGGS_INSTALL, [test "x$python_eggs_install" = xtrue])
1292
1293 AM_CONDITIONAL(PERL_CPAN_INSTALL, [test "x$perl_cpan_install" = xtrue])
1294
1295 # ===============================================
1296 #  collect plugin list for strongSwan components
1297 # ===============================================
1298
1299 m4_include(m4/macros/add-plugin.m4)
1300
1301 # plugin lists for all components
1302 charon_plugins=
1303 starter_plugins=
1304 pool_plugins=
1305 attest_plugins=
1306 scepclient_plugins=
1307 pki_plugins=
1308 scripts_plugins=
1309 manager_plugins=
1310 medsrv_plugins=
1311 nm_plugins=
1312 cmd_plugins=
1313 aikgen_plugins=
1314
1315 # location specific lists for checksumming,
1316 # for src/libcharon, src/libstrongswan and src/libtnccs
1317 c_plugins=
1318 s_plugins=
1319 t_plugins=
1320
1321 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1322 ADD_PLUGIN([unbound],              [s charon scripts])
1323 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1324 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1325 ADD_PLUGIN([aesni],                [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1326 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1327 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1328 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1329 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1330 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1331 ADD_PLUGIN([sha3],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1332 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1333 ADD_PLUGIN([md4],                  [s charon scepclient pki nm cmd])
1334 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1335 ADD_PLUGIN([mgf1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1336 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1337 ADD_PLUGIN([random],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1338 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1339 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1340 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1341 ADD_PLUGIN([constraints],          [s charon nm cmd])
1342 ADD_PLUGIN([acert],                [s charon])
1343 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1344 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1345 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1346 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1347 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1348 ADD_PLUGIN([pgp],                  [s charon])
1349 ADD_PLUGIN([dnskey],               [s charon pki])
1350 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1351 ADD_PLUGIN([dnscert],              [c charon])
1352 ADD_PLUGIN([ipseckey],             [c charon])
1353 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1354 ADD_PLUGIN([padlock],              [s charon])
1355 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1356 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1357 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1358 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1359 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1360 ADD_PLUGIN([agent],                [s charon nm cmd])
1361 ADD_PLUGIN([keychain],             [s charon cmd])
1362 ADD_PLUGIN([chapoly],              [s charon scripts nm cmd])
1363 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1364 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1365 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1366 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1367 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1368 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1369 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1370 ADD_PLUGIN([newhope],              [s charon scripts nm cmd])
1371 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1372 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1373 ADD_PLUGIN([files],                [s charon scepclient pki scripts nm cmd])
1374 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1375 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1376 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1377 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1378 ADD_PLUGIN([attr],                 [c charon])
1379 ADD_PLUGIN([attr-sql],             [c charon])
1380 ADD_PLUGIN([load-tester],          [c charon])
1381 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1382 ADD_PLUGIN([kernel-wfp],           [c charon])
1383 ADD_PLUGIN([kernel-iph],           [c charon])
1384 ADD_PLUGIN([kernel-pfkey],         [c charon starter nm cmd])
1385 ADD_PLUGIN([kernel-pfroute],       [c charon starter nm cmd])
1386 ADD_PLUGIN([kernel-netlink],       [c charon starter nm cmd])
1387 ADD_PLUGIN([resolve],              [c charon cmd])
1388 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1389 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1390 ADD_PLUGIN([socket-win],           [c charon])
1391 ADD_PLUGIN([connmark],             [c charon])
1392 ADD_PLUGIN([forecast],             [c charon])
1393 ADD_PLUGIN([farp],                 [c charon])
1394 ADD_PLUGIN([stroke],               [c charon])
1395 ADD_PLUGIN([vici],                 [c charon])
1396 ADD_PLUGIN([smp],                  [c charon])
1397 ADD_PLUGIN([sql],                  [c charon])
1398 ADD_PLUGIN([updown],               [c charon])
1399 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1400 ADD_PLUGIN([eap-sim],              [c charon])
1401 ADD_PLUGIN([eap-sim-file],         [c charon])
1402 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1403 ADD_PLUGIN([eap-aka],              [c charon])
1404 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1405 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1406 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1407 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1408 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1409 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1410 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1411 ADD_PLUGIN([eap-dynamic],          [c charon])
1412 ADD_PLUGIN([eap-radius],           [c charon])
1413 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1414 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1415 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1416 ADD_PLUGIN([eap-tnc],              [c charon])
1417 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1418 ADD_PLUGIN([xauth-eap],            [c charon])
1419 ADD_PLUGIN([xauth-pam],            [c charon])
1420 ADD_PLUGIN([xauth-noauth],         [c charon])
1421 ADD_PLUGIN([tnc-ifmap],            [c charon])
1422 ADD_PLUGIN([tnc-pdp],              [c charon])
1423 ADD_PLUGIN([tnc-imc],              [t charon])
1424 ADD_PLUGIN([tnc-imv],              [t charon])
1425 ADD_PLUGIN([tnc-tnccs],            [t charon])
1426 ADD_PLUGIN([tnccs-20],             [t charon])
1427 ADD_PLUGIN([tnccs-11],             [t charon])
1428 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1429 ADD_PLUGIN([medsrv],               [c charon])
1430 ADD_PLUGIN([medcli],               [c charon])
1431 ADD_PLUGIN([dhcp],                 [c charon])
1432 ADD_PLUGIN([osx-attr],             [c charon cmd])
1433 ADD_PLUGIN([p-cscf],               [c charon cmd])
1434 ADD_PLUGIN([android-dns],          [c charon])
1435 ADD_PLUGIN([android-log],          [c charon])
1436 ADD_PLUGIN([ha],                   [c charon])
1437 ADD_PLUGIN([whitelist],            [c charon])
1438 ADD_PLUGIN([ext-auth],             [c charon])
1439 ADD_PLUGIN([lookip],               [c charon])
1440 ADD_PLUGIN([error-notify],         [c charon])
1441 ADD_PLUGIN([certexpire],           [c charon])
1442 ADD_PLUGIN([systime-fix],          [c charon])
1443 ADD_PLUGIN([led],                  [c charon])
1444 ADD_PLUGIN([duplicheck],           [c charon])
1445 ADD_PLUGIN([coupling],             [c charon])
1446 ADD_PLUGIN([radattr],              [c charon])
1447 ADD_PLUGIN([uci],                  [c charon])
1448 ADD_PLUGIN([addrblock],            [c charon])
1449 ADD_PLUGIN([unity],                [c charon])
1450
1451 AC_SUBST(charon_plugins)
1452 AC_SUBST(starter_plugins)
1453 AC_SUBST(pool_plugins)
1454 AC_SUBST(attest_plugins)
1455 AC_SUBST(scepclient_plugins)
1456 AC_SUBST(pki_plugins)
1457 AC_SUBST(scripts_plugins)
1458 AC_SUBST(manager_plugins)
1459 AC_SUBST(medsrv_plugins)
1460 AC_SUBST(nm_plugins)
1461 AC_SUBST(cmd_plugins)
1462 AC_SUBST(aikgen_plugins)
1463
1464 AC_SUBST(c_plugins)
1465 AC_SUBST(h_plugins)
1466 AC_SUBST(s_plugins)
1467 AC_SUBST(t_plugins)
1468
1469 # ======================
1470 #  set Makefile.am vars
1471 # ======================
1472
1473 #  libstrongswan plugins
1474 # -----------------------
1475 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1476 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1477 AM_CONDITIONAL(USE_FILES, test x$files = xtrue)
1478 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1479 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1480 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1481 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1482 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1483 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1484 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1485 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1486 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1487 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1488 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1489 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1490 AM_CONDITIONAL(USE_SHA3, test x$sha3 = xtrue)
1491 AM_CONDITIONAL(USE_MGF1, test x$mgf1 = xtrue)
1492 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1493 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1494 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1495 AM_CONDITIONAL(USE_AESNI, test x$aesni = xtrue)
1496 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1497 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1498 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1499 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1500 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1501 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1502 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1503 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1504 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1505 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1506 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1507 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1508 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1509 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1510 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1511 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1512 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1513 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1514 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1515 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1516 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1517 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1518 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1519 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1520 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1521 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1522 AM_CONDITIONAL(USE_CHAPOLY, test x$chapoly = xtrue)
1523 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1524 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1525 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1526 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1527 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1528 AM_CONDITIONAL(USE_NEWHOPE, test x$newhope = xtrue)
1529 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1530
1531 #  charon plugins
1532 # ----------------
1533 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1534 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1535 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1536 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1537 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1538 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1539 AM_CONDITIONAL(USE_P_CSCF, test x$p_cscf = xtrue)
1540 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1541 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1542 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1543 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1544 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1545 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1546 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1547 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1548 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1549 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1550 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1551 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1552 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1553 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1554 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1555 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1556 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1557 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1558 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1559 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1560 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1561 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1562 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1563 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1564 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1565 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1566 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1567 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1568 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1569 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1570 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1571 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1572 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1573 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1574 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1575 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1576 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1577 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1578 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1579 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1580 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1581 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1582 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1583 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1584 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1585 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1586 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1587 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1588 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1589 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1590 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1591 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1592 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1593 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1594 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1595 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1596 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1597 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1598 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1599 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1600 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1601 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1602 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1603 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1604 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1605 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1606 AM_CONDITIONAL(USE_IMC_HCD, test x$imc_hcd = xtrue)
1607 AM_CONDITIONAL(USE_IMV_HCD, test x$imv_hcd = xtrue)
1608 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1609 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1610 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1611 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1612 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1613 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1614 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1615 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1616 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1617 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1618 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1619
1620 #  other options
1621 # ---------------
1622 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1623 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1624 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1625 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1626 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1627 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1628 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1629 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1630 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1631 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1632 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1633 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1634 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1635 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1636 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1637 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1638 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1639 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1640 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$aikpub2 = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1641 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1642 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1643 AM_CONDITIONAL(USE_LIBNTTFFT, test x$bliss = xtrue -o x$newhope = xtrue)
1644 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1645 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1646 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1647 AM_CONDITIONAL(USE_LIBTPMTSS, test x$tss_trousers = xtrue -o x$tss_tss2 = xtrue -o x$aikgen = xtrue -o x$aikpub2 = xtrue -o x$imcv = xtrue)
1648 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1649 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1650 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1651 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1652 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1653 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1654 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1655 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1656 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1657 AM_CONDITIONAL(USE_TROUSERS, test x$tss_trousers = xtrue)
1658 AM_CONDITIONAL(USE_TSS2, test x$tss_tss2 = xtrue)
1659 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1660 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1661 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1662 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1663 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1664 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1665 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1666 AM_CONDITIONAL(USE_AIKPUB2, test x$aikpub2 = xtrue)
1667 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1668 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1669 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1670 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1671 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1672 AM_CONDITIONAL(USE_PYTHON_EGGS, test x$python_eggs = xtrue)
1673 AM_CONDITIONAL(USE_PERL_CPAN, test x$perl_cpan = xtrue)
1674 AM_CONDITIONAL(USE_PY_TEST, test "x$PY_TEST" != x)
1675
1676 # ========================
1677 #  set global definitions
1678 # ========================
1679
1680 if test x$mediation = xtrue; then
1681         AC_DEFINE([ME], [], [mediation extension support])
1682 fi
1683 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1684         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1685 fi
1686 if test x$log_thread_ids = xtrue; then
1687         AC_DEFINE([USE_THREAD_IDS], [], [use thread ID for thread identification, if available])
1688 fi
1689 if test x$monolithic = xtrue; then
1690         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1691 fi
1692 if test x$ikev1 = xtrue; then
1693         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1694 fi
1695 if test x$ikev2 = xtrue; then
1696         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1697 fi
1698
1699 # ====================================================
1700 #  options for enabled modules (see conf/Makefile.am)
1701 # ====================================================
1702
1703 strongswan_options=
1704
1705 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1706 AM_COND_IF([USE_AIKPUB2], [strongswan_options=${strongswan_options}" aikpub2"])
1707 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1708 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1709 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1710 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1711 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1712 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1713 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1714 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1715 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1716 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1717 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1718 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1719
1720 AC_SUBST(strongswan_options)
1721
1722 # =================
1723 #  build Makefiles
1724 # =================
1725
1726 AC_CONFIG_FILES([
1727         Makefile
1728         conf/Makefile
1729         man/Makefile
1730         init/Makefile
1731         init/systemd/Makefile
1732         init/systemd-swanctl/Makefile
1733         src/Makefile
1734         src/include/Makefile
1735         src/libstrongswan/Makefile
1736         src/libstrongswan/math/libnttfft/Makefile
1737         src/libstrongswan/math/libnttfft/tests/Makefile
1738         src/libstrongswan/plugins/aes/Makefile
1739         src/libstrongswan/plugins/cmac/Makefile
1740         src/libstrongswan/plugins/des/Makefile
1741         src/libstrongswan/plugins/blowfish/Makefile
1742         src/libstrongswan/plugins/rc2/Makefile
1743         src/libstrongswan/plugins/md4/Makefile
1744         src/libstrongswan/plugins/md5/Makefile
1745         src/libstrongswan/plugins/sha1/Makefile
1746         src/libstrongswan/plugins/sha2/Makefile
1747         src/libstrongswan/plugins/sha3/Makefile
1748         src/libstrongswan/plugins/mgf1/Makefile
1749         src/libstrongswan/plugins/fips_prf/Makefile
1750         src/libstrongswan/plugins/gmp/Makefile
1751         src/libstrongswan/plugins/rdrand/Makefile
1752         src/libstrongswan/plugins/aesni/Makefile
1753         src/libstrongswan/plugins/random/Makefile
1754         src/libstrongswan/plugins/nonce/Makefile
1755         src/libstrongswan/plugins/hmac/Makefile
1756         src/libstrongswan/plugins/xcbc/Makefile
1757         src/libstrongswan/plugins/x509/Makefile
1758         src/libstrongswan/plugins/revocation/Makefile
1759         src/libstrongswan/plugins/constraints/Makefile
1760         src/libstrongswan/plugins/acert/Makefile
1761         src/libstrongswan/plugins/pubkey/Makefile
1762         src/libstrongswan/plugins/pkcs1/Makefile
1763         src/libstrongswan/plugins/pkcs7/Makefile
1764         src/libstrongswan/plugins/pkcs8/Makefile
1765         src/libstrongswan/plugins/pkcs12/Makefile
1766         src/libstrongswan/plugins/pgp/Makefile
1767         src/libstrongswan/plugins/dnskey/Makefile
1768         src/libstrongswan/plugins/sshkey/Makefile
1769         src/libstrongswan/plugins/pem/Makefile
1770         src/libstrongswan/plugins/curl/Makefile
1771         src/libstrongswan/plugins/files/Makefile
1772         src/libstrongswan/plugins/winhttp/Makefile
1773         src/libstrongswan/plugins/unbound/Makefile
1774         src/libstrongswan/plugins/soup/Makefile
1775         src/libstrongswan/plugins/ldap/Makefile
1776         src/libstrongswan/plugins/mysql/Makefile
1777         src/libstrongswan/plugins/sqlite/Makefile
1778         src/libstrongswan/plugins/padlock/Makefile
1779         src/libstrongswan/plugins/openssl/Makefile
1780         src/libstrongswan/plugins/gcrypt/Makefile
1781         src/libstrongswan/plugins/agent/Makefile
1782         src/libstrongswan/plugins/keychain/Makefile
1783         src/libstrongswan/plugins/pkcs11/Makefile
1784         src/libstrongswan/plugins/chapoly/Makefile
1785         src/libstrongswan/plugins/ctr/Makefile
1786         src/libstrongswan/plugins/ccm/Makefile
1787         src/libstrongswan/plugins/gcm/Makefile
1788         src/libstrongswan/plugins/af_alg/Makefile
1789         src/libstrongswan/plugins/ntru/Makefile
1790         src/libstrongswan/plugins/bliss/Makefile
1791         src/libstrongswan/plugins/bliss/tests/Makefile
1792         src/libstrongswan/plugins/newhope/Makefile
1793         src/libstrongswan/plugins/newhope/tests/Makefile
1794         src/libstrongswan/plugins/test_vectors/Makefile
1795         src/libstrongswan/tests/Makefile
1796         src/libipsec/Makefile
1797         src/libipsec/tests/Makefile
1798         src/libsimaka/Makefile
1799         src/libtls/Makefile
1800         src/libtls/tests/Makefile
1801         src/libradius/Makefile
1802         src/libtncif/Makefile
1803         src/libtnccs/Makefile
1804         src/libtnccs/plugins/tnc_tnccs/Makefile
1805         src/libtnccs/plugins/tnc_imc/Makefile
1806         src/libtnccs/plugins/tnc_imv/Makefile
1807         src/libtnccs/plugins/tnccs_11/Makefile
1808         src/libtnccs/plugins/tnccs_20/Makefile
1809         src/libtnccs/plugins/tnccs_dynamic/Makefile
1810         src/libpttls/Makefile
1811         src/libimcv/Makefile
1812         src/libimcv/plugins/imc_test/Makefile
1813         src/libimcv/plugins/imv_test/Makefile
1814         src/libimcv/plugins/imc_scanner/Makefile
1815         src/libimcv/plugins/imv_scanner/Makefile
1816         src/libimcv/plugins/imc_os/Makefile
1817         src/libimcv/plugins/imv_os/Makefile
1818         src/libimcv/plugins/imc_attestation/Makefile
1819         src/libimcv/plugins/imv_attestation/Makefile
1820         src/libimcv/plugins/imc_swid/Makefile
1821         src/libimcv/plugins/imv_swid/Makefile
1822         src/libimcv/plugins/imc_hcd/Makefile
1823         src/libimcv/plugins/imv_hcd/Makefile
1824         src/charon/Makefile
1825         src/charon-nm/Makefile
1826         src/charon-tkm/Makefile
1827         src/charon-cmd/Makefile
1828         src/charon-svc/Makefile
1829         src/charon-systemd/Makefile
1830         src/libcharon/Makefile
1831         src/libcharon/plugins/eap_aka/Makefile
1832         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1833         src/libcharon/plugins/eap_dynamic/Makefile
1834         src/libcharon/plugins/eap_identity/Makefile
1835         src/libcharon/plugins/eap_md5/Makefile
1836         src/libcharon/plugins/eap_gtc/Makefile
1837         src/libcharon/plugins/eap_sim/Makefile
1838         src/libcharon/plugins/eap_sim_file/Makefile
1839         src/libcharon/plugins/eap_sim_pcsc/Makefile
1840         src/libcharon/plugins/eap_simaka_sql/Makefile
1841         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1842         src/libcharon/plugins/eap_simaka_reauth/Makefile
1843         src/libcharon/plugins/eap_mschapv2/Makefile
1844         src/libcharon/plugins/eap_tls/Makefile
1845         src/libcharon/plugins/eap_ttls/Makefile
1846         src/libcharon/plugins/eap_peap/Makefile
1847         src/libcharon/plugins/eap_tnc/Makefile
1848         src/libcharon/plugins/eap_radius/Makefile
1849         src/libcharon/plugins/xauth_generic/Makefile
1850         src/libcharon/plugins/xauth_eap/Makefile
1851         src/libcharon/plugins/xauth_pam/Makefile
1852         src/libcharon/plugins/xauth_noauth/Makefile
1853         src/libcharon/plugins/tnc_ifmap/Makefile
1854         src/libcharon/plugins/tnc_pdp/Makefile
1855         src/libcharon/plugins/socket_default/Makefile
1856         src/libcharon/plugins/socket_dynamic/Makefile
1857         src/libcharon/plugins/socket_win/Makefile
1858         src/libcharon/plugins/connmark/Makefile
1859         src/libcharon/plugins/forecast/Makefile
1860         src/libcharon/plugins/farp/Makefile
1861         src/libcharon/plugins/smp/Makefile
1862         src/libcharon/plugins/sql/Makefile
1863         src/libcharon/plugins/dnscert/Makefile
1864         src/libcharon/plugins/ipseckey/Makefile
1865         src/libcharon/plugins/medsrv/Makefile
1866         src/libcharon/plugins/medcli/Makefile
1867         src/libcharon/plugins/addrblock/Makefile
1868         src/libcharon/plugins/unity/Makefile
1869         src/libcharon/plugins/uci/Makefile
1870         src/libcharon/plugins/ha/Makefile
1871         src/libcharon/plugins/kernel_netlink/Makefile
1872         src/libcharon/plugins/kernel_pfkey/Makefile
1873         src/libcharon/plugins/kernel_pfroute/Makefile
1874         src/libcharon/plugins/kernel_libipsec/Makefile
1875         src/libcharon/plugins/kernel_wfp/Makefile
1876         src/libcharon/plugins/kernel_iph/Makefile
1877         src/libcharon/plugins/whitelist/Makefile
1878         src/libcharon/plugins/ext_auth/Makefile
1879         src/libcharon/plugins/lookip/Makefile
1880         src/libcharon/plugins/error_notify/Makefile
1881         src/libcharon/plugins/certexpire/Makefile
1882         src/libcharon/plugins/systime_fix/Makefile
1883         src/libcharon/plugins/led/Makefile
1884         src/libcharon/plugins/duplicheck/Makefile
1885         src/libcharon/plugins/coupling/Makefile
1886         src/libcharon/plugins/radattr/Makefile
1887         src/libcharon/plugins/osx_attr/Makefile
1888         src/libcharon/plugins/p_cscf/Makefile
1889         src/libcharon/plugins/android_dns/Makefile
1890         src/libcharon/plugins/android_log/Makefile
1891         src/libcharon/plugins/stroke/Makefile
1892         src/libcharon/plugins/vici/Makefile
1893         src/libcharon/plugins/vici/ruby/Makefile
1894         src/libcharon/plugins/vici/perl/Makefile
1895         src/libcharon/plugins/vici/python/Makefile
1896         src/libcharon/plugins/updown/Makefile
1897         src/libcharon/plugins/dhcp/Makefile
1898         src/libcharon/plugins/load_tester/Makefile
1899         src/libcharon/plugins/resolve/Makefile
1900         src/libcharon/plugins/attr/Makefile
1901         src/libcharon/plugins/attr_sql/Makefile
1902         src/libcharon/tests/Makefile
1903         src/libtpmtss/Makefile
1904         src/stroke/Makefile
1905         src/ipsec/Makefile
1906         src/starter/Makefile
1907         src/starter/tests/Makefile
1908         src/_updown/Makefile
1909         src/_copyright/Makefile
1910         src/scepclient/Makefile
1911         src/aikgen/Makefile
1912         src/aikpub2/Makefile
1913         src/pki/Makefile
1914         src/pki/man/Makefile
1915         src/pool/Makefile
1916         src/dumm/Makefile
1917         src/dumm/ext/extconf.rb
1918         src/libfast/Makefile
1919         src/manager/Makefile
1920         src/medsrv/Makefile
1921         src/checksum/Makefile
1922         src/conftest/Makefile
1923         src/pt-tls-client/Makefile
1924         src/swanctl/Makefile
1925         scripts/Makefile
1926         testing/Makefile
1927 ])
1928
1929 # =================
1930 #  build man pages
1931 # =================
1932
1933 AC_CONFIG_FILES([
1934         conf/strongswan.conf.5.head
1935         conf/strongswan.conf.5.tail
1936         man/ipsec.conf.5
1937         man/ipsec.secrets.5
1938         src/charon-cmd/charon-cmd.8
1939         src/pki/man/pki.1
1940         src/pki/man/pki---acert.1
1941         src/pki/man/pki---dn.1
1942         src/pki/man/pki---gen.1
1943         src/pki/man/pki---issue.1
1944         src/pki/man/pki---keyid.1
1945         src/pki/man/pki---pkcs12.1
1946         src/pki/man/pki---pkcs7.1
1947         src/pki/man/pki---print.1
1948         src/pki/man/pki---pub.1
1949         src/pki/man/pki---req.1
1950         src/pki/man/pki---self.1
1951         src/pki/man/pki---signcrl.1
1952         src/pki/man/pki---verify.1
1953         src/swanctl/swanctl.8
1954         src/swanctl/swanctl.conf.5.head
1955         src/swanctl/swanctl.conf.5.tail
1956 ])
1957
1958 AC_OUTPUT
1959
1960 # ========================
1961 #  report enabled plugins
1962 # ========================
1963
1964 AC_MSG_RESULT([])
1965 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1966 AC_MSG_RESULT([-----------------------------------------------------])
1967
1968 AC_MSG_RESULT([libstrongswan:$s_plugins])
1969 AC_MSG_RESULT([libcharon:    $c_plugins])
1970 AC_MSG_RESULT([libtnccs:     $t_plugins])
1971 AC_MSG_RESULT([])