configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234 if test "x$bindnow" = xyes; then
 235   AC_DEFINE(BIND_NOW)
 236 fi
 237
 238 dnl On some platforms we cannot use dynamic loading.  We must provide
 239 dnl static NSS modules.
 240 AC_ARG_ENABLE([static-nss],
 241               AC_HELP_STRING([--enable-static-nss],
 242                              [build static NSS modules @<:@default=no@:>@]),
 243               [static_nss=$enableval],
 244               [static_nss=no])
 245 dnl Enable static NSS also if we build no shared objects.
 246 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 247   static_nss=yes
 248   AC_DEFINE(DO_STATIC_NSS)
 249 fi
 250
 251 AC_ARG_ENABLE([force-install],
 252               AC_HELP_STRING([--disable-force-install],
 253                              [don't force installation of files from this package, even if they are older than the installed files]),
 254               [force_install=$enableval],
 255               [force_install=yes])
 256 AC_SUBST(force_install)
 257
 258 AC_ARG_ENABLE([maintainer-mode],
 259               AC_HELP_STRING([--enable-maintainer-mode],
 260                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 261               [maintainer=$enableval],
 262               [maintainer=no])
 263
 264 dnl On some platforms we allow dropping compatibility with all kernel
 265 dnl versions.
 266 AC_ARG_ENABLE([kernel],
 267               AC_HELP_STRING([--enable-kernel=VERSION],
 268                              [compile for compatibility with kernel not older than VERSION]),
 269               [minimum_kernel=$enableval],
 270               [])
 271 dnl Prevent unreasonable values.
 272 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 273   # Better nothing than this.
 274   minimum_kernel=""
 275 else
 276   if test "$minimum_kernel" = current; then
 277     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 278   fi
 279 fi
 280
 281 dnl For the development we sometimes want gcc to issue even more warnings.
 282 dnl This is not the default since many of the extra warnings are not
 283 dnl appropriate.
 284 AC_ARG_ENABLE([all-warnings],
 285               AC_HELP_STRING([--enable-all-warnings],
 286                              [enable all useful warnings gcc can issue]),
 287               [all_warnings=$enableval],
 288               [])
 289 AC_SUBST(all_warnings)
 290
 291 AC_ARG_ENABLE([werror],
 292               AC_HELP_STRING([--disable-werror],
 293                              [do not build with -Werror]),
 294               [enable_werror=$enableval],
 295               [enable_werror=yes])
 296 AC_SUBST(enable_werror)
 297
 298 AC_ARG_ENABLE([multi-arch],
 299               AC_HELP_STRING([--enable-multi-arch],
 300                              [enable single DSO with optimizations for multiple architectures]),
 301               [multi_arch=$enableval],
 302               [multi_arch=default])
 303
 304 AC_ARG_ENABLE([nss-crypt],
 305               AC_HELP_STRING([--enable-nss-crypt],
 306                              [enable libcrypt to use nss]),
 307               [nss_crypt=$enableval],
 308               [nss_crypt=no])
 309 if test x$nss_crypt = xyes; then
 310   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 311   if test $? -ne 0; then
 312     AC_MSG_ERROR([cannot find include directory with nss-config])
 313   fi
 314   old_CFLAGS="$CFLAGS"
 315   CFLAGS="$CFLAGS $nss_includes"
 316   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 317 #include <hasht.h>
 318 #include <nsslowhash.h>
 319 void f (void) { NSSLOW_Init (); }])],
 320              libc_cv_nss_crypt=yes,
 321              AC_MSG_ERROR([
 322 cannot find NSS headers with lowlevel hash function interfaces]))
 323   old_LIBS="$LIBS"
 324   LIBS="$LIBS -lfreebl3"
 325   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 326 #include <hasht.h>
 327 #include <nsslowhash.h>],
 328                                   [NSSLOW_Init();])],
 329                  libc_cv_nss_crypt=yes,
 330                  AC_MSG_ERROR([
 331 cannot link program using lowlevel NSS hash functions]))
 332   CFLAGS="$old_CFLAGS"
 333   LIBS="$old_LIBS"
 334 else
 335   libc_cv_nss_crypt=no
 336 fi
 337 AC_SUBST(libc_cv_nss_crypt)
 338
 339
 340 AC_ARG_ENABLE([obsolete-rpc],
 341               AC_HELP_STRING([--enable-obsolete-rpc],
 342                              [build and install the obsolete RPC code for link-time usage]),
 343               [link_obsolete_rpc=$enableval],
 344               [link_obsolete_rpc=no])
 345 AC_SUBST(link_obsolete_rpc)
 346
 347 if test "$link_obsolete_rpc" = yes; then
 348   AC_DEFINE(LINK_OBSOLETE_RPC)
 349 fi
 350
 351 AC_ARG_ENABLE([systemtap],
 352               [AS_HELP_STRING([--enable-systemtap],
 353                [enable systemtap static probe points @<:@default=no@:>@])],
 354               [systemtap=$enableval],
 355               [systemtap=no])
 356 if test "x$systemtap" != xno; then
 357   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 358   old_CFLAGS="$CFLAGS"
 359   CFLAGS="-std=gnu11 $CFLAGS"
 360   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 361 void foo (int i, void *p)
 362 {
 363   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 364        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 365 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 366   CFLAGS="$old_CFLAGS"])
 367   if test $libc_cv_sdt = yes; then
 368     AC_DEFINE([USE_STAP_PROBE])
 369   elif test "x$systemtap" != xauto; then
 370     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 371   fi
 372 fi
 373
 374 AC_ARG_ENABLE([build-nscd],
 375               [AS_HELP_STRING([--disable-build-nscd],
 376                [disable building and installing the nscd daemon])],
 377               [build_nscd=$enableval],
 378               [build_nscd=default])
 379 AC_SUBST(build_nscd)
 380
 381 # Note the use of $use_nscd is near the bottom of the file.
 382 AC_ARG_ENABLE([nscd],
 383               [AS_HELP_STRING([--disable-nscd],
 384                [library functions will not contact the nscd daemon])],
 385               [use_nscd=$enableval],
 386               [use_nscd=yes])
 387
 388 AC_ARG_ENABLE([pt_chown],
 389               [AS_HELP_STRING([--enable-pt_chown],
 390                [Enable building and installing pt_chown])],
 391               [build_pt_chown=$enableval],
 392               [build_pt_chown=no])
 393 AC_SUBST(build_pt_chown)
 394 if test "$build_pt_chown" = yes; then
 395   AC_DEFINE(HAVE_PT_CHOWN)
 396 fi
 397
 398 # The abi-tags file uses a fairly simplistic model for name recognition that
 399 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 400 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 401 # This doesn't get used much beyond that, so it's fairly safe.
 402 case "$host_os" in
 403 linux*)
 404   ;;
 405 gnu*)
 406   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 407   ;;
 408 esac
 409
 410 AC_ARG_ENABLE([mathvec],
 411               [AS_HELP_STRING([--enable-mathvec],
 412               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 413               [build_mathvec=$enableval],
 414               [build_mathvec=notset])
 415
 416 # We keep the original values in `$config_*' and never modify them, so we
 417 # can write them unchanged into config.make.  Everything else uses
 418 # $machine, $vendor, and $os, and changes them whenever convenient.
 419 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 420
 421 # Don't allow vendor == "unknown"
 422 test "$config_vendor" = unknown && config_vendor=
 423 config_os="`echo $config_os | sed 's/^unknown-//'`"
 424
 425 # Some configurations imply other options.
 426 elf=yes
 427
 428 # The configure fragment of an add-on port can modify these to supplement
 429 # or override the table in the case statement below.  No fragment should
 430 # ever change the config_* variables, however.
 431 machine=$config_machine
 432 vendor=$config_vendor
 433 os=$config_os
 434 base_os=''
 435
 436 submachine=
 437 AC_ARG_WITH([cpu],
 438             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 439             [dnl
 440   case "$withval" in
 441   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 442   no) ;;
 443   *) submachine="$withval" ;;
 444   esac
 445 ])
 446
 447 # An preconfigure script can set this when it wants to disable the sanity
 448 # check below.
 449 libc_config_ok=no
 450
 451 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 452 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 453
 454 dnl Having this here, though empty, makes sure that if add-ons' fragments
 455 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 456 dnl our AC_OUTPUT will actually use it.
 457 AC_CONFIG_SUBDIRS()
 458
 459 case "$enable_add_ons" in
 460 ''|no) add_ons= ;;
 461 yes|'*')
 462  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 463           sed 's@/[[^/]]*$@@' | sort | uniq`
 464          add_ons_automatic=yes
 465          ;;
 466 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 467        add_ons_automatic=no ;;
 468 esac
 469
 470 configured_add_ons=
 471 add_ons_sfx=
 472 add_ons_pfx=
 473 if test x"$add_ons" != x; then
 474   for f in $add_ons; do
 475     # Some sanity checks
 476     case "$f" in
 477     crypt)
 478       AC_MSG_ERROR([
 479 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 480 *** part of glibc and using the old add-on will not work with this
 481 *** release.  Start again with fresh sources and without the old
 482 *** \`crypt' add-on.])
 483     ;;
 484     localedata)
 485       AC_MSG_ERROR([
 486 *** It seems that you're using an old \`localedata' add-on.  localedata
 487 *** is now part of glibc and using the old add-on will not work with
 488 *** this release.  Start again with fresh sources and without the old
 489 *** \`localedata' add-on.])
 490     ;;
 491     esac
 492   done
 493
 494   # Now source each add-on's configure fragment.
 495   # The fragments can use $srcdir/$libc_add_on to find themselves,
 496   # and test $add_ons_automatic to see if they were explicitly requested.
 497   # A fragment can clear (or even change) $libc_add_on to affect
 498   # whether it goes into the list to be actually used in the build.
 499   use_add_ons=
 500   for libc_add_on in $add_ons; do
 501     # Test whether such a directory really exists.
 502     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 503     case "$libc_add_on" in
 504     /*)
 505       libc_add_on_srcdir=$libc_add_on
 506       ;;
 507     *)
 508       test -d "$srcdir/$libc_add_on" || {
 509         if test -d "$libc_add_on"; then
 510           libc_add_on="`pwd`/$libc_add_on"
 511         else
 512           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 513         fi
 514       }
 515       libc_add_on_srcdir=$srcdir/$libc_add_on
 516       ;;
 517     esac
 518
 519     libc_add_on_frag=$libc_add_on_srcdir/configure
 520     libc_add_on_canonical=
 521     libc_add_on_config_subdirs=
 522     if test -r "$libc_add_on_frag"; then
 523       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 524       libc_add_on_canonical=unknown
 525       libc_add_on_subdirs=
 526       . "$libc_add_on_frag"
 527       test -z "$libc_add_on" || {
 528         configured_add_ons="$configured_add_ons $libc_add_on"
 529         if test "x$libc_add_on_canonical" = xunknown; then
 530           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 531         fi
 532         for d in $libc_add_on_subdirs; do
 533           case "$libc_add_on" in
 534           /*) subdir_srcdir="$libc_add_on" ;;
 535           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 536           esac
 537           case "$d" in
 538           .)
 539             d="${libc_add_on_canonical:-$libc_add_on}"
 540             ;;
 541           /*)
 542             subdir_srcdir="$d"
 543             ;;
 544           *)
 545             subdir_srcdir="$subdir_srcdir/$d"
 546             ;;
 547           esac
 548           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 549           add_on_subdirs="$add_on_subdirs $d"
 550           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 551 $d-srcdir = $subdir_srcdir"
 552         done
 553         for d in $libc_add_on_config_subdirs; do
 554           case "$d" in
 555           /*) AC_MSG_ERROR(dnl
 556 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 557           esac
 558           if test ! -d "$libc_add_on_srcdir/$d"; then
 559             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 560           fi
 561           case "$libc_add_on" in
 562           /*) AC_MSG_ERROR(dnl
 563 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 564           esac
 565           subdirs="$subdirs $libc_add_on/$d"
 566         done
 567       }
 568     fi
 569     if test -n "$libc_add_on"; then
 570       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 571       use_add_ons="$use_add_ons $libc_add_on"
 572       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 573       test -z "$libc_add_on_canonical" ||
 574       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 575     fi
 576   done
 577   # Use echo to strip excess whitespace.
 578   add_ons="`echo $use_add_ons`"
 579 fi
 580 AC_SUBST(add_ons)
 581 AC_SUBST(add_on_subdirs)
 582
 583
 584 ###
 585 ### By using the undocumented --enable-hacker-mode option for configure
 586 ### one can skip this test to make the configuration not fail for unsupported
 587 ### platforms.
 588 ###
 589 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 590   case "$machine-$host_os" in
 591   *-linux* | *-gnu*)
 592     ;;
 593   *)
 594     AC_MSG_ERROR([
 595 *** The GNU C library is currently unavailable for this platform.
 596 *** If you are interested in seeing glibc on this platform visit
 597 *** the "How to submit a new port" in the wiki:
 598 ***   https://sourceware.org/glibc/wiki/#Development
 599 *** and join the community!])
 600     ;;
 601   esac
 602 fi
 603
 604 # Set base_machine if not set by a preconfigure fragment.
 605 test -n "$base_machine" || base_machine=$machine
 606 AC_SUBST(base_machine)
 607
 608 # For the multi-arch option we need support in the assembler & linker.
 609 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 610                libc_cv_ld_gnu_indirect_function, [dnl
 611 cat > conftest.S <<EOF
 612 .type foo,%gnu_indirect_function
 613 foo:
 614 .globl _start
 615 _start:
 616 .globl __start
 617 __start:
 618 .data
 619 #ifdef _LP64
 620 .quad foo
 621 #else
 622 .long foo
 623 #endif
 624 EOF
 625 libc_cv_ld_gnu_indirect_function=no
 626 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 627             -nostartfiles -nostdlib \
 628             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 629   # Do a link to see if the backend supports IFUNC relocs.
 630   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 631   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 632     libc_cv_ld_gnu_indirect_function=yes
 633   }
 634 fi
 635 rm -f conftest*])
 636
 637 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 638   if test x"$multi_arch" = xyes; then
 639     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 640   else
 641     multi_arch=no
 642   fi
 643 fi
 644 multi_arch_d=
 645 if test x"$multi_arch" != xno; then
 646   multi_arch_d=/multiarch
 647 fi
 648
 649 # Compute the list of sysdep directories for this configuration.
 650 # This can take a while to compute.
 651 sysdep_dir=$srcdir/sysdeps
 652 AC_MSG_CHECKING(sysdep dirs)
 653 dnl We need to use [ and ] for other purposes for a while now.
 654 changequote(,)dnl
 655 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 656 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 657
 658 test "x$base_os" != x || case "$os" in
 659 gnu*)
 660   base_os=mach/hurd ;;
 661 linux*)
 662   base_os=unix/sysv ;;
 663 esac
 664
 665 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 666 tail=$os
 667 ostry=$os
 668 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 669   ostry="$ostry /$o"
 670   tail=$o
 671 done
 672 o=`echo $tail | sed 's/[0-9]*$//'`
 673 if test $o != $tail; then
 674   ostry="$ostry /$o"
 675 fi
 676 # For linux-gnu, try linux-gnu, then linux.
 677 o=`echo $tail | sed 's/-.*$//'`
 678 if test $o != $tail; then
 679   ostry="$ostry /$o"
 680 fi
 681
 682 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 683 base=
 684 tail=$base_os
 685 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 686   set $b
 687   base="$base /$1"
 688   tail="$2"
 689 done
 690
 691 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 692 mach=
 693 tail=$machine${submachine:+/$submachine}
 694 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 695   set $m
 696   # Prepend the machine's FPU directory unless --without-fp.
 697   if test "$with_fp" = yes; then
 698     maybe_fpu=/fpu
 699   else
 700     maybe_fpu=/nofpu
 701   fi
 702   # For each machine term, try it with and then without /multiarch.
 703   for try_fpu in $maybe_fpu ''; do
 704     for try_multi in $multi_arch_d ''; do
 705       mach="$mach /$1$try_fpu$try_multi"
 706     done
 707   done
 708   tail="$2"
 709 done
 710
 711 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 712 changequote([,])dnl
 713
 714 # Find what sysdep directories exist.
 715 sysnames_add_ons=
 716 sysnames=
 717 for b in $base ''; do
 718   for m0 in $mach ''; do
 719     for v in /$vendor ''; do
 720       test "$v" = / && continue
 721       for o in /$ostry ''; do
 722         test "$o" = / && continue
 723         for m in $mach ''; do
 724           for d in $add_ons_pfx ''; do
 725             for a in $add_ons_sfx ''; do
 726               try_suffix="$m0$b$v$o$m"
 727               if test -n "$try_suffix"; then
 728                 try_srcdir="${srcdir}/"
 729                 case "$d" in
 730                 /*) try_srcdir= ;;
 731                 esac
 732                 try="${d}sysdeps$try_suffix$a"
 733                 test -n "$enable_debug_configure" &&
 734                 echo "$0 [DEBUG]: try $try" >&2
 735                 if test -d "$try_srcdir$try"; then
 736                   sysnames="$sysnames $try"
 737                   { test -n "$o" || test -n "$b"; } && os_used=t
 738                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 739                   case x${m0:-$m} in
 740                   x*/$submachine) submachine_used=t ;;
 741                   esac
 742                   if test -n "$d"; then
 743                     case "$sysnames_add_ons" in
 744                     *" $d "*) ;;
 745                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 746                     esac
 747                   fi
 748                 fi
 749               fi
 750             done
 751           done
 752         done
 753       done
 754     done
 755   done
 756 done
 757
 758 # If the assembler supports gnu_indirect_function symbol type and the
 759 # architecture supports multi-arch, we enable multi-arch by default.
 760 case $sysnames_add_ons$sysnames in
 761 *"$multi_arch_d"*)
 762   ;;
 763 *)
 764   test x"$multi_arch" = xdefault && multi_arch=no
 765   ;;
 766 esac
 767 if test x"$multi_arch" != xno; then
 768   AC_DEFINE(USE_MULTIARCH)
 769 fi
 770 AC_SUBST(multi_arch)
 771
 772 if test -z "$os_used" && test "$os" != none; then
 773   AC_MSG_ERROR(Operating system $os is not supported.)
 774 fi
 775 if test -z "$machine_used" && test "$machine" != none; then
 776   AC_MSG_ERROR(The $machine is not supported.)
 777 fi
 778 if test -z "$submachine_used" && test -n "$submachine"; then
 779   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 780 fi
 781 AC_SUBST(submachine)
 782
 783 # We have now validated the configuration.
 784
 785 # Expand the list of system names into a full list of directories
 786 # from each element's parent name and Implies file (if present).
 787 set $sysnames
 788 names=
 789 while test $# -gt 0; do
 790   name=$1
 791   shift
 792
 793   case " $names " in *" $name "*)
 794     # Already in the list.
 795     continue
 796   esac
 797
 798   # Report each name as we discover it, so there is no long pause in output.
 799   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 800
 801   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 802
 803   case $name in
 804     /*) xsrcdir= ;;
 805     *)  xsrcdir=$srcdir/ ;;
 806   esac
 807   test -n "$enable_debug_configure" &&
 808   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 809
 810   for implies_file in Implies Implies-before Implies-after; do
 811     implies_type=`echo $implies_file | sed s/-/_/`
 812     eval ${implies_type}=
 813     if test -f $xsrcdir$name/$implies_file; then
 814       # Collect more names from the `Implies' file (removing comments).
 815       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 816       for x in $implied_candidate; do
 817         found=no
 818         if test -d $xsrcdir$name_base/$x; then
 819           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 820           found=yes
 821         fi
 822         for d in $add_ons_pfx ''; do
 823           try="${d}sysdeps/$x"
 824           case $d in
 825            /*) try_srcdir= ;;
 826            *) try_srcdir=$srcdir/ ;;
 827           esac
 828           test -n "$enable_debug_configure" &&
 829            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 830           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 831           then
 832             eval "${implies_type}=\"\$${implies_type} \$try\""
 833             found=yes
 834             case "$sysnames_add_ons" in
 835             *" $d "*) ;;
 836             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 837             esac
 838           fi
 839         done
 840         if test $found = no; then
 841           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 842         fi
 843       done
 844     fi
 845   done
 846
 847   # Add NAME to the list of names.
 848   names="$names $name"
 849
 850   # Find the parent of NAME, using the empty string if it has none.
 851 changequote(,)dnl
 852   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 853 changequote([,])dnl
 854
 855   test -n "$enable_debug_configure" &&
 856     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 857 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 858
 859   # Add the names implied by NAME, and NAME's parent (if it has one), to
 860   # the list of names to be processed (the argument list).  We prepend the
 861   # implied names to the list and append the parent.  We want implied
 862   # directories to come before further directories inferred from the
 863   # configuration components; this ensures that for sysv4, unix/common
 864   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 865   # after sysv4).
 866   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 867   test -n "$sysnames" && set $sysnames
 868 done
 869
 870 # Add the default directories.
 871 default_sysnames="sysdeps/generic"
 872 sysnames="$names $default_sysnames"
 873 AC_SUBST(sysnames)
 874 # The other names were emitted during the scan.
 875 AC_MSG_RESULT($default_sysnames)
 876
 877 # Collect the list of add-ons that supply partial sysdeps trees.
 878 sysdeps_add_ons=
 879 for add_on in $add_ons; do
 880   case "$add_on" in
 881   /*) xsrcdir= ;;
 882   *) xsrcdir="$srcdir/" ;;
 883   esac
 884
 885   test -d "$xsrcdir$add_on/sysdeps" || {
 886     case "$configured_add_ons " in
 887     *" $add_on "*) ;;
 888     *|'')
 889       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 890       ;;
 891     esac
 892     continue
 893   }
 894
 895   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 896   case "$sysnames_add_ons" in
 897   *" $add_on/ "*) ;;
 898   *|'')
 899     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 900     continue ;;
 901   esac
 902
 903   found=no
 904   for d in $sysnames; do
 905     case "$d" in
 906     $add_on/sysdeps/*) ;;
 907     *) continue ;;
 908     esac
 909     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 910        case "$f" in
 911        sys|bits)
 912          for ff in $f/*.h; do
 913            test -d "$ff" || { test -e "$ff" && exit 88; }
 914          done
 915          ;;
 916        *)
 917          test -d "$f" || { test -e "$f" && exit 88; }
 918          ;;
 919        esac
 920      done)
 921     if test $? -eq 88; then
 922       found=yes
 923       break
 924     fi
 925   done
 926   if test $found = no; then
 927     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 928   fi
 929 done
 930 AC_SUBST(sysdeps_add_ons)
 931
 932
 933 ### Locate tools.
 934
 935 AC_PROG_INSTALL
 936 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 937   # The makefiles need to use a different form to find it in $srcdir.
 938   INSTALL='\$(..)./scripts/install-sh -c'
 939 fi
 940 AC_PROG_LN_S
 941
 942 LIBC_PROG_BINUTILS
 943
 944 # Accept binutils 2.22 or newer.
 945 AC_CHECK_PROG_VER(AS, $AS, --version,
 946                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 947                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 948                   AS=: critic_missing="$critic_missing as")
 949 AC_CHECK_PROG_VER(LD, $LD, --version,
 950                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 951                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 952                   LD=: critic_missing="$critic_missing ld")
 953
 954 # These programs are version sensitive.
 955 AC_CHECK_TOOL_PREFIX
 956 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 957   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 958   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 959
 960 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 961   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 962   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 963   MSGFMT=: aux_missing="$aux_missing msgfmt")
 964 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 965   [GNU texinfo.* \([0-9][0-9.]*\)],
 966   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 967   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 968 AC_CHECK_PROG_VER(SED, sed, --version,
 969   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 970   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 971   SED=: aux_missing="$aux_missing sed")
 972 AC_CHECK_PROG_VER(AWK, gawk, --version,
 973   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 974   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 975
 976 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 977 AC_TRY_COMPILE([], [
 978 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 979 #error insufficient compiler
 980 #endif],
 981                [libc_cv_compiler_ok=yes],
 982                [libc_cv_compiler_ok=no])])
 983 AS_IF([test $libc_cv_compiler_ok != yes],
 984       [critic_missing="$critic_missing compiler"])
 985
 986 AC_CHECK_TOOL(NM, nm, false)
 987
 988 if test "x$maintainer" = "xyes"; then
 989   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 990   case "x$AUTOCONF" in
 991   xno|x|x:) AUTOCONF=no ;;
 992   *)
 993     AC_CACHE_CHECK(dnl
 994   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 995     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 996       libc_cv_autoconf_works=yes
 997     else
 998       libc_cv_autoconf_works=no
 999     fi])
1000     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1001     ;;
1002   esac
1003   if test "x$AUTOCONF" = xno; then
1004     aux_missing="$aux_missing autoconf"
1005   fi
1006 else
1007   AUTOCONF=no
1008 fi
1009
1010 test -n "$critic_missing" && AC_MSG_ERROR([
1011 *** These critical programs are missing or too old:$critic_missing
1012 *** Check the INSTALL file for required versions.])
1013
1014 test -n "$aux_missing" && AC_MSG_WARN([
1015 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1016 *** some features will be disabled.
1017 *** Check the INSTALL file for required versions.])
1018
1019 # if using special system headers, find out the compiler's sekrit
1020 # header directory and add that to the list.  NOTE: Only does the right
1021 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1022 if test -n "$sysheaders"; then
1023   SYSINCLUDES=-nostdinc
1024   for d in include include-fixed; do
1025     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1026     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1027   done
1028   SYSINCLUDES="$SYSINCLUDES \
1029 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1030   if test -n "$CXX"; then
1031     CXX_SYSINCLUDES=
1032     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1033     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1034       test "x$cxxheaders" != x &&
1035       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1036     done
1037   fi
1038 fi
1039 AC_SUBST(SYSINCLUDES)
1040 AC_SUBST(CXX_SYSINCLUDES)
1041
1042 # Obtain some C++ header file paths.  This is used to make a local
1043 # copy of those headers in Makerules.
1044 if test -n "$CXX"; then
1045   find_cxx_header () {
1046     echo "#include <$1>" | $CXX -M -MP -x c++ - | sed -n "/$1:/{s/:\$//;p}"
1047   }
1048   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1049   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1050 fi
1051 AC_SUBST(CXX_CSTDLIB_HEADER)
1052 AC_SUBST(CXX_CMATH_HEADER)
1053
1054 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1055 # since this would lead to problems installing/building glibc.
1056 # LD_LIBRARY_PATH contains the current directory if one of the following
1057 # is true:
1058 # - one of the terminals (":" and ";") is the first or last sign
1059 # - two terminals occur directly after each other
1060 # - the path contains an element with a dot in it
1061 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1062 changequote(,)dnl
1063 case ${LD_LIBRARY_PATH} in
1064   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1065     ld_library_path_setting="contains current directory"
1066     ;;
1067   *)
1068     ld_library_path_setting="ok"
1069     ;;
1070 esac
1071 changequote([,])dnl
1072 AC_MSG_RESULT($ld_library_path_setting)
1073 if test "$ld_library_path_setting" != "ok"; then
1074 AC_MSG_ERROR([
1075 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1076 *** building glibc. Please change the environment variable
1077 *** and run configure again.])
1078 fi
1079
1080 AC_PATH_PROG(BASH_SHELL, bash, no)
1081
1082 AC_PATH_PROG(PERL, perl, no)
1083 if test "$PERL" != no &&
1084    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1085   PERL=no
1086 fi
1087 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1088              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1089 AC_CHECK_PROG_VER(BISON, bison, --version,
1090                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1091                   [2.7*|[3-9].*|[1-9][0-9]*],
1092                   BISON=no)
1093
1094 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1095 cat > conftest.s <<EOF
1096 .text
1097 foo:
1098 .set glibc_conftest_frobozz,foo
1099 .globl glibc_conftest_frobozz
1100 EOF
1101 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1102 # (but it doesn't work), so we must do a linking check to be sure.
1103 cat > conftest1.c <<\EOF
1104 extern int glibc_conftest_frobozz;
1105 void _start() { glibc_conftest_frobozz = 1; }
1106 EOF
1107 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1108             -nostartfiles -nostdlib \
1109             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1110   libc_cv_asm_set_directive=yes
1111 else
1112   libc_cv_asm_set_directive=no
1113 fi
1114 rm -f conftest*])
1115 if test $libc_cv_asm_set_directive = yes; then
1116   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1117 fi
1118
1119 AC_CACHE_CHECK(linker support for protected data symbol,
1120                libc_cv_protected_data,
1121                [cat > conftest.c <<EOF
1122                 int bar __attribute__ ((visibility ("protected"))) = 1;
1123 EOF
1124                 libc_cv_protected_data=no
1125                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1126                   cat > conftest.c <<EOF
1127                   extern int bar;
1128                   int main (void) { return bar; }
1129 EOF
1130                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1131                     libc_cv_protected_data=yes
1132                   fi
1133                 fi
1134                 rm -f conftest.*
1135                ])
1136 AC_SUBST(libc_cv_protected_data)
1137
1138 AC_CACHE_CHECK(for broken __attribute__((alias())),
1139                libc_cv_broken_alias_attribute,
1140                [cat > conftest.c <<EOF
1141                extern int foo (int x) __asm ("xyzzy");
1142                int bar (int x) { return x; }
1143                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1144                extern int dfoo;
1145                extern __typeof (dfoo) dfoo __asm ("abccb");
1146                int dfoo = 1;
1147 EOF
1148                libc_cv_broken_alias_attribute=yes
1149                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1150                  if grep 'xyzzy' conftest.s >/dev/null &&
1151                     grep 'abccb' conftest.s >/dev/null; then
1152                    libc_cv_broken_alias_attribute=no
1153                  fi
1154                fi
1155                rm -f conftest.c conftest.s
1156                ])
1157 if test $libc_cv_broken_alias_attribute = yes; then
1158   AC_MSG_ERROR(working alias attribute support required)
1159 fi
1160
1161 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1162                libc_cv_have_sdata_section,
1163                [echo "int i;" > conftest.c
1164                 libc_cv_have_sdata_section=no
1165                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1166                    | grep '\.sdata' >/dev/null; then
1167                   libc_cv_have_sdata_section=yes
1168                 fi
1169                 rm -f conftest.c conftest.so
1170                ])
1171 if test $libc_cv_have_sdata_section = yes; then
1172   AC_DEFINE(HAVE_SDATA_SECTION)
1173 fi
1174
1175 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1176                libc_cv_ctors_header, [dnl
1177   libc_cv_ctors_header=yes
1178   LIBC_TRY_LINK_STATIC([
1179 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1180 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1181 ],
1182               [dnl
1183       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1184         { gsub(/\@<:@ */, "@<:@") }
1185         $2 == ".ctors" || $2 == ".dtors" {
1186           size = strtonum("0x" $6)
1187           align = strtonum("0x" $NF)
1188           seen@<:@$2@:>@ = 1
1189           stub@<:@$2@:>@ = size == align * 2
1190         }
1191         END {
1192           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1193           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1194           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1195         }
1196       '], [libc_cv_ctors_header=no])
1197     ], [dnl
1198       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1199     ])
1200 ])
1201 if test $libc_cv_ctors_header = no; then
1202   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1203 fi
1204
1205 AC_CACHE_CHECK(for libunwind-support in compiler,
1206                libc_cv_cc_with_libunwind, [
1207   cat > conftest.c <<EOF
1208 int main (void) { return 0; }
1209 EOF
1210   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1211      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1212     libc_cv_cc_with_libunwind=yes
1213   else
1214     libc_cv_cc_with_libunwind=no
1215   fi
1216   rm -f conftest*])
1217 AC_SUBST(libc_cv_cc_with_libunwind)
1218 if test $libc_cv_cc_with_libunwind = yes; then
1219   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1220 fi
1221
1222 ASFLAGS_config=
1223 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1224                libc_cv_as_noexecstack, [dnl
1225 cat > conftest.c <<EOF
1226 void foo (void) { }
1227 EOF
1228 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1229                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1230    && grep .note.GNU-stack conftest.s >/dev/null \
1231    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1232                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1233 then
1234   libc_cv_as_noexecstack=yes
1235 else
1236   libc_cv_as_noexecstack=no
1237 fi
1238 rm -f conftest*])
1239 if test $libc_cv_as_noexecstack = yes; then
1240   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1241 fi
1242 AC_SUBST(ASFLAGS_config)
1243
1244 AC_CACHE_CHECK(for -z combreloc,
1245                libc_cv_z_combreloc, [dnl
1246 cat > conftest.c <<EOF
1247 extern int bar (int);
1248 extern int mumble;
1249 int foo (void) { return bar (mumble); }
1250 EOF
1251 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1252                         -fPIC -shared -o conftest.so conftest.c
1253                         -nostdlib -nostartfiles
1254                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1255 then
1256 dnl The following test is a bit weak.  We must use a tool which can test
1257 dnl cross-platform since the gcc used can be a cross compiler.  Without
1258 dnl introducing new options this is not easily doable.  Instead use a tool
1259 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1260 dnl look for a section named .rel.dyn.
1261   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1262     libc_cv_z_combreloc=yes
1263   else
1264     libc_cv_z_combreloc=no
1265   fi
1266 else
1267   libc_cv_z_combreloc=no
1268 fi
1269 rm -f conftest*])
1270 if test "$libc_cv_z_combreloc" = yes; then
1271   AC_DEFINE(HAVE_Z_COMBRELOC)
1272 fi
1273 AC_SUBST(libc_cv_z_combreloc)
1274
1275 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1276                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1277 AC_SUBST(libc_cv_z_execstack)
1278
1279 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1280 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1281 ])
1282
1283 AC_SUBST(libc_cv_fpie)
1284
1285 AC_CACHE_CHECK(for --hash-style option,
1286                libc_cv_hashstyle, [dnl
1287 cat > conftest.c <<EOF
1288 int _start (void) { return 42; }
1289 EOF
1290 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1291                             -fPIC -shared -o conftest.so conftest.c
1292                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1293 then
1294   libc_cv_hashstyle=yes
1295 else
1296   libc_cv_hashstyle=no
1297 fi
1298 rm -f conftest*])
1299 AC_SUBST(libc_cv_hashstyle)
1300
1301 # The linker's default -shared behavior is good enough if it
1302 # does these things that our custom linker scripts ensure that
1303 # all allocated NOTE sections come first.
1304 if test "$use_default_link" = default; then
1305   AC_CACHE_CHECK([for sufficient default -shared layout],
1306                   libc_cv_use_default_link, [dnl
1307   libc_cv_use_default_link=no
1308   cat > conftest.s <<\EOF
1309           .section .note.a,"a",%note
1310           .balign 4
1311           .long 4,4,9
1312           .string "GNU"
1313           .string "foo"
1314           .section .note.b,"a",%note
1315           .balign 4
1316           .long 4,4,9
1317           .string "GNU"
1318           .string "bar"
1319 EOF
1320   if AC_TRY_COMMAND([dnl
1321   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1322        ac_try=`$READELF -S conftest.so | sed -n \
1323          ['${x;p;}
1324           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1325           t a
1326           b
1327           : a
1328           H']`
1329   then
1330     libc_seen_a=no libc_seen_b=no
1331     set -- $ac_try
1332     while test $# -ge 2 -a "$1" = NOTE; do
1333       case "$2" in
1334       .note.a) libc_seen_a=yes ;;
1335       .note.b) libc_seen_b=yes ;;
1336       esac
1337       shift 2
1338     done
1339     case "$libc_seen_a$libc_seen_b" in
1340     yesyes)
1341       libc_cv_use_default_link=yes
1342       ;;
1343     *)
1344       echo >&AS_MESSAGE_LOG_FD "\
1345 $libc_seen_a$libc_seen_b from:
1346 $ac_try"
1347       ;;
1348     esac
1349   fi
1350   rm -f conftest*])
1351   use_default_link=$libc_cv_use_default_link
1352 fi
1353
1354 AC_CACHE_CHECK(for GLOB_DAT reloc,
1355                libc_cv_has_glob_dat, [dnl
1356 cat > conftest.c <<EOF
1357 extern int mumble;
1358 int foo (void) { return mumble; }
1359 EOF
1360 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1361                         -fPIC -shared -o conftest.so conftest.c
1362                         -nostdlib -nostartfiles
1363                         1>&AS_MESSAGE_LOG_FD])
1364 then
1365 dnl look for GLOB_DAT relocation.
1366   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1367     libc_cv_has_glob_dat=yes
1368   else
1369     libc_cv_has_glob_dat=no
1370   fi
1371 else
1372   libc_cv_has_glob_dat=no
1373 fi
1374 rm -f conftest*])
1375 AC_SUBST(libc_cv_has_glob_dat)
1376
1377 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1378 if libc_cv_output_format=`
1379 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1380 then
1381   :
1382 else
1383   libc_cv_output_format=
1384 fi
1385 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1386 AC_SUBST(libc_cv_output_format)
1387
1388 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1389 cat > conftest.c <<EOF
1390 int foo;
1391 EOF
1392 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1393                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1394 then
1395   libc_cv_fno_toplevel_reorder=yes
1396 else
1397   libc_cv_fno_toplevel_reorder=no
1398 fi
1399 rm -f conftest*])
1400 if test $libc_cv_fno_toplevel_reorder = yes; then
1401   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1402 else
1403   fno_unit_at_a_time=-fno-unit-at-a-time
1404 fi
1405 AC_SUBST(fno_unit_at_a_time)
1406
1407 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1408 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1409                    [libc_cv_ssp=yes],
1410                    [libc_cv_ssp=no])
1411 ])
1412
1413 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
1414 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
1415                    [libc_cv_ssp_strong=yes],
1416                    [libc_cv_ssp_strong=no])
1417 ])
1418
1419 stack_protector=
1420 if test "$libc_cv_ssp_strong" = "yes"; then
1421   stack_protector="-fstack-protector-strong"
1422 elif test "$libc_cv_ssp" = "yes"; then
1423   stack_protector="-fstack-protector"
1424 fi
1425 AC_SUBST(stack_protector)
1426
1427 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1428 [dnl
1429 cat > conftest.c <<EOF
1430 __thread int i;
1431 void foo (void)
1432 {
1433   i = 10;
1434 }
1435 EOF
1436 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1437                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1438 then
1439   libc_cv_mtls_dialect_gnu2=yes
1440 else
1441   libc_cv_mtls_dialect_gnu2=no
1442 fi
1443 rm -f conftest*])
1444 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1445 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1446
1447 AC_CACHE_CHECK(whether cc puts quotes around section names,
1448                libc_cv_have_section_quotes,
1449                [cat > conftest.c <<EOF
1450                 static const int foo
1451                 __attribute__ ((section ("bar"))) = 1;
1452 EOF
1453                 if ${CC-cc} -S conftest.c -o conftest.s; then
1454                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1455                     libc_cv_have_section_quotes=yes
1456                   else
1457                     libc_cv_have_section_quotes=no
1458                   fi
1459                 else
1460                   libc_cv_have_section_quotes=unknown
1461                 fi
1462                 rm -f conftest.{c,s}
1463                 ])
1464 if test $libc_cv_have_section_quotes = yes; then
1465   AC_DEFINE(HAVE_SECTION_QUOTES)
1466 fi
1467
1468 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1469 cat > conftest.c <<\EOF
1470 void zero (void *x)
1471 {
1472   __builtin_memset (x, 0, 1000);
1473 }
1474 EOF
1475 dnl
1476 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1477 then
1478   libc_cv_gcc_builtin_memset=no
1479 else
1480   libc_cv_gcc_builtin_memset=yes
1481 fi
1482 rm -f conftest* ])
1483 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1484   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1485 fi
1486
1487 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1488 cat > conftest.c <<\EOF
1489 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1490 char *foo (const char *a, const char *b)
1491 {
1492   return __builtin_strstr (a, b);
1493 }
1494 EOF
1495 dnl
1496 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1497 then
1498   libc_cv_gcc_builtin_redirection=yes
1499 else
1500   libc_cv_gcc_builtin_redirection=no
1501 fi
1502 rm -f conftest* ])
1503 if test "$libc_cv_gcc_builtin_redirection" = no; then
1504   AC_MSG_ERROR([support for the symbol redirection needed])
1505 fi
1506
1507 dnl Determine how to disable generation of FMA instructions.
1508 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1509                libc_cv_cc_nofma, [dnl
1510 libc_cv_cc_nofma=
1511 for opt in -ffp-contract=off -mno-fused-madd; do
1512   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1513 done])
1514 AC_SUBST(libc_cv_cc_nofma)
1515
1516 if test -n "$submachine"; then
1517   AC_CACHE_CHECK([for compiler option for CPU variant],
1518                  libc_cv_cc_submachine, [dnl
1519   libc_cv_cc_submachine=no
1520   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1521     LIBC_TRY_CC_OPTION([$opt], [
1522       libc_cv_cc_submachine="$opt"
1523       break], [])
1524   done])
1525   if test "x$libc_cv_cc_submachine" = xno; then
1526     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1527   fi
1528 fi
1529 AC_SUBST(libc_cv_cc_submachine)
1530
1531 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1532 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1533 cat > conftest.c <<EOF
1534 void
1535 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1536 foo (void) {}
1537 EOF
1538 libc_cv_cc_loop_to_function=no
1539 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1540 then
1541   libc_cv_cc_loop_to_function=yes
1542 fi
1543 rm -f conftest*])
1544 if test $libc_cv_cc_loop_to_function = yes; then
1545   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1546 fi
1547 AC_SUBST(libc_cv_cc_loop_to_function)
1548
1549 dnl Check whether we have the gd library available.
1550 AC_MSG_CHECKING(for libgd)
1551 if test "$with_gd" != "no"; then
1552   old_CFLAGS="$CFLAGS"
1553   CFLAGS="$CFLAGS $libgd_include"
1554   old_LDFLAGS="$LDFLAGS"
1555   LDFLAGS="$LDFLAGS $libgd_ldflags"
1556   old_LIBS="$LIBS"
1557   LIBS="$LIBS -lgd -lpng -lz -lm"
1558   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1559   CFLAGS="$old_CFLAGS"
1560   LDFLAGS="$old_LDFLAGS"
1561   LIBS="$old_LIBS"
1562 else
1563   LIBGD=no
1564 fi
1565 AC_MSG_RESULT($LIBGD)
1566 AC_SUBST(LIBGD)
1567
1568 # SELinux detection
1569 if test x$with_selinux = xno ; then
1570   have_selinux=no;
1571 else
1572   # See if we have the SELinux library
1573   AC_CHECK_LIB(selinux, is_selinux_enabled,
1574                have_selinux=yes, have_selinux=no)
1575   if test x$with_selinux = xyes ; then
1576     if test x$have_selinux = xno ; then
1577       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1578     fi
1579   fi
1580 fi
1581 # Check if we're building with SELinux support.
1582 if test "x$have_selinux" = xyes; then
1583   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1584
1585   # See if we have the libaudit library
1586   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1587                have_libaudit=yes, have_libaudit=no)
1588   if test "x$have_libaudit" = xyes; then
1589     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1590   fi
1591   AC_SUBST(have_libaudit)
1592
1593   # See if we have the libcap library
1594   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1595   if test "x$have_libcap" = xyes; then
1596     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1597   fi
1598   AC_SUBST(have_libcap)
1599 fi
1600 AC_SUBST(have_selinux)
1601
1602 CPPUNDEFS=
1603 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1604 dnl Since we are building the implementations of the fortified functions here,
1605 dnl having the macro defined interacts very badly.
1606 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1607 [AC_TRY_COMPILE([], [
1608 #ifdef _FORTIFY_SOURCE
1609 # error bogon
1610 #endif],
1611                 [libc_cv_predef_fortify_source=no],
1612                 [libc_cv_predef_fortify_source=yes])])
1613 if test $libc_cv_predef_fortify_source = yes; then
1614   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1615 fi
1616 AC_SUBST(CPPUNDEFS)
1617
1618 dnl Check for silly hacked compilers inserting -fstack-protector.
1619 dnl This breaks badly for the early startup code we compile, since
1620 dnl the compiled code can refer to a magic machine-dependent location
1621 dnl for the canary value before we have sufficient setup for that to
1622 dnl work.  It's also questionable to build all of libc with this flag
1623 dnl even when you're doing that for most applications you build, since
1624 dnl libc's code is so heavily-used and performance-sensitive.  If we
1625 dnl ever really want to make that work, it should be enabled explicitly
1626 dnl in the libc build, not inherited from implicit compiler settings.
1627 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1628                libc_cv_predef_stack_protector, [
1629 AC_TRY_COMPILE([extern void foobar (char *);],
1630                [char large_array[2048]; foobar (large_array);], [
1631 libc_undefs=`$NM -u conftest.o |
1632   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1633     2>&AS_MESSAGE_LOG_FD` || {
1634   AC_MSG_ERROR([confusing output from $NM -u])
1635 }
1636 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1637 # On some architectures, there are architecture-specific undefined
1638 # symbols (resolved by the linker), so filter out unknown symbols.
1639 # This will fail to produce the correct result if the compiler
1640 # defaults to -fstack-protector but this produces an undefined symbol
1641 # other than __stack_chk_fail.  However, compilers like that have not
1642 # been encountered in practice.
1643 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1644 case "$libc_undefs" in
1645 foobar) libc_cv_predef_stack_protector=no ;;
1646 '__stack_chk_fail
1647 foobar') libc_cv_predef_stack_protector=yes ;;
1648 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1649 esac],
1650                [AC_MSG_ERROR([test compilation failed])])
1651 ])
1652 libc_extra_cflags=
1653 if test $libc_cv_predef_stack_protector = yes; then
1654   libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1655 fi
1656 libc_extra_cppflags=
1657
1658 # Some linkers on some architectures support __ehdr_start but with
1659 # bugs.  Make sure usage of it does not create relocations in the
1660 # output (as the linker should resolve them all for us).
1661 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1662                libc_cv_ehdr_start, [
1663 old_CFLAGS="$CFLAGS"
1664 old_LDFLAGS="$LDFLAGS"
1665 old_LIBS="$LIBS"
1666 CFLAGS="$CFLAGS -fPIC"
1667 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1668 LIBS=
1669 AC_LINK_IFELSE([AC_LANG_SOURCE([
1670 typedef struct {
1671   char foo;
1672   long val;
1673 } Ehdr;
1674 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1675 long ehdr (void) { return __ehdr_start.val; }
1676 ])],
1677                [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1678                   libc_cv_ehdr_start=broken
1679                 else
1680                   libc_cv_ehdr_start=yes
1681                 fi], [libc_cv_ehdr_start=no])
1682 CFLAGS="$old_CFLAGS"
1683 LDFLAGS="$old_LDFLAGS"
1684 LIBS="$old_LIBS"
1685 ])
1686 if test "$libc_cv_ehdr_start" = yes; then
1687   AC_DEFINE([HAVE_EHDR_START])
1688 elif test "$libc_cv_ehdr_start" = broken; then
1689   AC_MSG_WARN([linker is broken -- you should upgrade])
1690 fi
1691
1692 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1693                libc_cv_builtin_trap, [dnl
1694 libc_cv_builtin_trap=no
1695 AC_TRY_COMPILE([], [__builtin_trap ()], [
1696 libc_undefs=`$NM -u conftest.o |
1697   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1698     2>&AS_MESSAGE_LOG_FD` || {
1699   AC_MSG_ERROR([confusing output from $NM -u])
1700 }
1701 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1702 if test -z "$libc_undefs"; then
1703   libc_cv_builtin_trap=yes
1704 fi])])
1705 if test $libc_cv_builtin_trap = yes; then
1706   AC_DEFINE([HAVE_BUILTIN_TRAP])
1707 fi
1708
1709 dnl C++ feature tests.
1710 AC_LANG_PUSH([C++])
1711
1712 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1713                libc_cv_cxx_thread_local, [
1714 old_CXXFLAGS="$CXXFLAGS"
1715 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1716 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1717 #include <thread>
1718
1719 // Compiler support.
1720 struct S
1721 {
1722   S ();
1723   ~S ();
1724 };
1725 thread_local S s;
1726 S * get () { return &s; }
1727
1728 // libstdc++ support.
1729 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1730 #error __cxa_thread_atexit_impl not supported
1731 #endif
1732 ])],
1733                [libc_cv_cxx_thread_local=yes],
1734                [libc_cv_cxx_thread_local=no])
1735 CXXFLAGS="$old_CXXFLAGS"
1736 ])
1737 AC_SUBST(libc_cv_cxx_thread_local)
1738
1739 AC_LANG_POP([C++])
1740 dnl End of C++ feature tests.
1741
1742 ### End of automated tests.
1743 ### Now run sysdeps configure fragments.
1744
1745 # They also can set these variables.
1746 use_ldconfig=no
1747 ldd_rewrite_script=no
1748 libc_cv_sysconfdir=$sysconfdir
1749 libc_cv_localstatedir=$localstatedir
1750 libc_cv_gcc_unwind_find_fde=no
1751 libc_cv_idn=no
1752
1753 # Iterate over all the sysdep directories we will use, running their
1754 # configure fragments.
1755 for dir in $sysnames; do
1756   case $dir in
1757     /*) dest=$dir ;;
1758     *)  dest=$srcdir/$dir ;;
1759   esac
1760   if test -r $dest/configure; then
1761     AC_MSG_RESULT(running configure fragment for $dir)
1762     . $dest/configure
1763   fi
1764 done
1765
1766 if test x"$build_mathvec" = xnotset; then
1767   build_mathvec=no
1768 fi
1769 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1770
1771 AC_SUBST(libc_extra_cflags)
1772 AC_SUBST(libc_extra_cppflags)
1773
1774 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1775   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1776 fi
1777 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1778
1779 # A sysdeps configure fragment can reset this if IFUNC is not actually
1780 # usable even though the assembler knows how to generate the symbol type.
1781 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1782   AC_DEFINE(HAVE_IFUNC)
1783 fi
1784
1785 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1786 # configure fragment can override the value to prevent this AC_DEFINE.
1787 AC_SUBST(use_nscd)
1788 if test "x$use_nscd" != xno; then
1789   AC_DEFINE([USE_NSCD])
1790 fi
1791 if test "x$build_nscd" = xdefault; then
1792   build_nscd=$use_nscd
1793 fi
1794
1795 AC_SUBST(libc_cv_slibdir)
1796 AC_SUBST(libc_cv_rtlddir)
1797 AC_SUBST(libc_cv_complocaledir)
1798 AC_SUBST(libc_cv_sysconfdir)
1799 AC_SUBST(libc_cv_localstatedir)
1800 AC_SUBST(libc_cv_rootsbindir)
1801
1802 if test x$use_ldconfig = xyes; then
1803   AC_DEFINE(USE_LDCONFIG)
1804 fi
1805 AC_SUBST(use_ldconfig)
1806 AC_SUBST(ldd_rewrite_script)
1807
1808 AC_SUBST(static)
1809 AC_SUBST(shared)
1810
1811 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1812 [libc_cv_pic_default=yes
1813 cat > conftest.c <<EOF
1814 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1815 # error PIC is default.
1816 #endif
1817 EOF
1818 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1819   libc_cv_pic_default=no
1820 fi
1821 rm -f conftest.*])
1822 AC_SUBST(libc_cv_pic_default)
1823
1824 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1825 [libc_cv_pie_default=yes
1826 cat > conftest.c <<EOF
1827 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1828 # error PIE is default.
1829 #endif
1830 EOF
1831 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1832   libc_cv_pie_default=no
1833 fi
1834 rm -f conftest.*])
1835 AC_SUBST(libc_cv_pie_default)
1836
1837 AC_SUBST(profile)
1838 AC_SUBST(static_nss)
1839
1840 AC_SUBST(DEFINES)
1841
1842 dnl See sysdeps/mach/configure.ac for this variable.
1843 AC_SUBST(mach_interface_list)
1844
1845 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1846 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1847 AC_SUBST(VERSION)
1848 AC_SUBST(RELEASE)
1849
1850 AC_CONFIG_FILES([config.make Makefile])
1851 AC_CONFIG_COMMANDS([default],[[
1852 case $CONFIG_FILES in *config.make*)
1853 echo "$config_vars" >> config.make;;
1854 esac
1855 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1856 AC_OUTPUT