configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [232],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 109 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 110
 111 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 112
 113 M4_DEFINES=
 114
 115 AC_CHECK_TOOL(OBJCOPY, objcopy)
 116 AC_CHECK_TOOL(STRINGS, strings)
 117 AC_CHECK_TOOL(GPERF, gperf)
 118 if test -z "$GPERF" ; then
 119         AC_MSG_ERROR([*** gperf not found])
 120 fi
 121
 122 # ------------------------------------------------------------------------------
 123 address_sanitizer_cflags=
 124 address_sanitizer_cppflags=
 125 address_sanitizer_ldflags=
 126 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 127 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 128             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 129             AS_IF([test -z "$with_as_cflags"],
 130                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 131             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 132             address_sanitizer_cppflags="-DVALGRIND=1"
 133             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 134       ])
 135
 136 undefined_sanitizer_cflags=
 137 undefined_sanitizer_cppflags=
 138 undefined_sanitizer_ldflags=
 139 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 140 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 141             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 142             AS_IF([test -z "$with_us_cflags"],
 143                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 144             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 145             undefined_sanitizer_cppflags="-DVALGRIND=1"
 146             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 147       ])
 148
 149 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 150 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 151 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 152
 153 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 154         -pipe \
 155         -Wall \
 156         -Wextra \
 157         -Wundef \
 158         -Wlogical-op \
 159         -Wmissing-include-dirs \
 160         -Wold-style-definition \
 161         -Wpointer-arith \
 162         -Winit-self \
 163         -Wdeclaration-after-statement \
 164         -Wfloat-equal \
 165         -Wsuggest-attribute=noreturn \
 166         -Werror=missing-prototypes \
 167         -Werror=implicit-function-declaration \
 168         -Werror=missing-declarations \
 169         -Werror=return-type \
 170         -Werror=format=2 \
 171         -Wstrict-prototypes \
 172         -Wredundant-decls \
 173         -Wmissing-noreturn \
 174         -Wshadow \
 175         -Wendif-labels \
 176         -Wstrict-aliasing=2 \
 177         -Wwrite-strings \
 178         -Wno-unused-parameter \
 179         -Wno-missing-field-initializers \
 180         -Wno-unused-result \
 181         -Wno-format-signedness \
 182         -Werror=overflow \
 183         -Wdate-time \
 184         -Wnested-externs \
 185         -ffast-math \
 186         -fno-common \
 187         -fdiagnostics-show-option \
 188         -fno-strict-aliasing \
 189         -fvisibility=hidden \
 190         -fstack-protector \
 191         -fstack-protector-strong \
 192         -fPIE \
 193         --param=ssp-buffer-size=4])
 194
 195 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 196 #include <time.h>
 197 #include <inttypes.h>
 198 typedef uint64_t usec_t;
 199 usec_t now(clockid_t clock);
 200 int main(void) {
 201         struct timespec now;
 202         return 0;
 203 }
 204 ])
 205
 206 AS_CASE([$CC], [*clang*],
 207         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 208                -Wno-typedef-redefinition \
 209                -Wno-gnu-variable-sized-type-not-at-end \
 210         ])])
 211
 212 AC_ARG_ENABLE([lto], [AS_HELP_STRING([--disable-lto], [disable -flto])],
 213                      [], [enable_lto=yes])
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [AS_IF([test "x$enable_lto" = "xyes"],
 216                [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-flto])],
 217                [AC_MSG_RESULT([disabling -flto as requested])])],
 218         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 222                -Wp,-D_FORTIFY_SOURCE=2])],
 223         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 224
 225 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 226         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 227                -Wl,--gc-sections])],
 228         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 229
 230 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 231         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 232                -ffunction-sections -fdata-sections])],
 233         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 234
 235 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 236         -Wl,--as-needed \
 237         -Wl,--no-undefined \
 238         -Wl,-z,relro \
 239         -Wl,-z,now \
 240         -pie \
 241         -Wl,-fuse-ld=gold])
 242
 243 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 244 AC_SUBST([OUR_CFLAGS], "-D__SANE_USERSPACE_TYPES__ $with_cflags $sanitizer_cflags")
 245 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 246
 247 AC_CHECK_SIZEOF(pid_t)
 248 AC_CHECK_SIZEOF(uid_t)
 249 AC_CHECK_SIZEOF(gid_t)
 250 AC_CHECK_SIZEOF(time_t)
 251 AC_CHECK_SIZEOF(dev_t)
 252 AC_CHECK_SIZEOF(ino_t)
 253 AC_CHECK_SIZEOF(rlim_t,,[
 254        #include <sys/time.h>
 255        #include <sys/resource.h>
 256 ])
 257
 258 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
 259
 260 AC_COMPILE_IFELSE(
 261         [AC_LANG_PROGRAM([
 262                 #include <string.h>
 263                 const char * in_word_set(const char *, size_t);
 264                 $GPERF_TEST]
 265         )],
 266         [GPERF_LEN_TYPE=size_t],
 267         [AC_COMPILE_IFELSE(
 268                 [AC_LANG_PROGRAM([
 269                         #include <string.h>
 270                         const char * in_word_set(const char *, unsigned);
 271                         $GPERF_TEST]
 272                 )],
 273                 [GPERF_LEN_TYPE=unsigned],
 274                 [AC_MSG_ERROR([** unable to determine gperf len type])]
 275         )]
 276 )
 277
 278 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
 279
 280 # ------------------------------------------------------------------------------
 281 # we use python to build the man page index
 282 have_python=no
 283 AC_ARG_WITH([python],
 284         [AS_HELP_STRING([--without-python], [disable building the man page index and systemd-python (default: test)])])
 285
 286 have_lxml=no
 287 AS_IF([test "x$with_python" != "xno"], [
 288         AM_PATH_PYTHON([3],, [:])
 289         AS_IF([test "x$PYTHON" != "x:"], [
 290                 AC_MSG_CHECKING([for python lxml module])
 291                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 292                 AC_MSG_RESULT([$have_lxml])
 293                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 294                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 295         ])
 296 ])
 297 AS_IF([test "$have_python" != "yes"], [
 298       AS_IF([test "$with_python" = "yes"],
 299             [AC_MSG_ERROR([*** python support requested but python support not found])])
 300       AS_IF([test "$with_python" != "no"],
 301             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 302 ])
 303 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 304
 305 # ------------------------------------------------------------------------------
 306
 307 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 308 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 309 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 310 AC_CHECK_HEADERS([linux/vm_sockets.h], [], [], [#include <sys/socket.h>])
 311
 312 # unconditionally pull-in librt with old glibc versions
 313 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 314
 315 save_LIBS="$LIBS"
 316 LIBS=
 317 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 318 CAP_LIBS="$LIBS"
 319 LIBS="$save_LIBS"
 320 AC_SUBST(CAP_LIBS)
 321
 322 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 323 AC_CHECK_DECLS([
 324         memfd_create,
 325         gettid,
 326         pivot_root,
 327         name_to_handle_at,
 328         setns,
 329         getrandom,
 330         renameat2,
 331         kcmp,
 332         keyctl,
 333         LO_FLAGS_PARTSCAN,
 334         copy_file_range],
 335         [], [], [[
 336 #include <sys/types.h>
 337 #include <unistd.h>
 338 #include <sys/mount.h>
 339 #include <fcntl.h>
 340 #include <sched.h>
 341 #include <linux/loop.h>
 342 #include <linux/random.h>
 343 ]])
 344
 345 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t, struct ethtool_link_settings],
 346                [], [], [[
 347 #include <uchar.h>
 348 #include <linux/ethtool.h>
 349 ]])
 350
 351 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 352                 IN6_ADDR_GEN_MODE_STABLE_PRIVACY,
 353                 IFLA_VRF_TABLE,
 354                 IFLA_MACVLAN_FLAGS,
 355                 IFLA_IPVLAN_MODE,
 356                 IFLA_VTI_REMOTE,
 357                 IFLA_PHYS_PORT_ID,
 358                 IFLA_BOND_AD_INFO,
 359                 IFLA_VLAN_PROTOCOL,
 360                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 361                 IFLA_IPTUN_ENCAP_DPORT,
 362                 IFLA_GRE_ENCAP_DPORT,
 363                 IFLA_BRIDGE_VLAN_INFO,
 364                 IFLA_BRPORT_PROXYARP,
 365                 IFLA_BRPORT_LEARNING_SYNC,
 366                 IFLA_BR_VLAN_DEFAULT_PVID,
 367                 NDA_IFINDEX,
 368                 IFA_FLAGS],
 369 [], [], [[
 370 #include <inttypes.h>
 371 #include <netinet/in.h>
 372 #include <netinet/ether.h>
 373 #include <linux/rtnetlink.h>
 374 #include <net/if.h>
 375 #include <linux/ip.h>
 376 #include <linux/if_tunnel.h>
 377 #include <linux/if_link.h>
 378 #include <linux/if_bridge.h>
 379 #include <linux/if_addr.h>
 380 #include <linux/neighbour.h>
 381 ]])
 382
 383 # This makes sure pkg.m4 is available.
 384 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 385
 386 # ------------------------------------------------------------------------------
 387 have_dbus=no
 388 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 389 AS_IF([test "x$enable_dbus" != "xno"], [
 390         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 391                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 392                 [have_dbus=no])
 393         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 394                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 395 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 396
 397 # ------------------------------------------------------------------------------
 398 have_utmp=yes
 399 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 400         AS_CASE("x${enableval}",
 401                 [xyes], [have_utmp=yes],
 402                 [xno],  [have_utmp=no],
 403                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 404 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 405 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 406
 407 # ------------------------------------------------------------------------------
 408 have_coverage=no
 409 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 410 if test "x$enable_coverage" = "xyes" ; then
 411         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 412         if test "x$lcov_found" = xno ; then
 413                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 414         else
 415                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 416                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 417                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 418                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 419                 else
 420                         have_coverage=yes
 421                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 422                         -fprofile-arcs \
 423                         -ftest-coverage])
 424                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 425                 fi
 426         fi
 427 fi
 428 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 429
 430 # ------------------------------------------------------------------------------
 431 have_kmod=no
 432 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 433 if test "x$enable_kmod" != "xno"; then
 434         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 435         if test "x$have_kmod" = "xyes"; then
 436                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 437                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 438                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 439         fi
 440         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 441                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 442         fi
 443 fi
 444 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 445
 446 # ------------------------------------------------------------------------------
 447 have_xkbcommon=no
 448 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 449 if test "x$enable_xkbcommon" != "xno"; then
 450         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 451                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 452         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 453                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 454         fi
 455 fi
 456 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 457
 458 # ------------------------------------------------------------------------------
 459 have_blkid=no
 460 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 461 if test "x$enable_blkid" != "xno"; then
 462         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 463                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 464         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 465                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 466         fi
 467 fi
 468 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 469
 470 # ------------------------------------------------------------------------------
 471 have_libmount=no
 472 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 473         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 474 if test "x$have_libmount" = xno; then
 475         AC_MSG_ERROR([*** libmount support required but libraries not found])
 476 fi
 477 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 478
 479 # ------------------------------------------------------------------------------
 480 have_seccomp=no
 481 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [disable optional SECCOMP support]))
 482 if test "x$enable_seccomp" != "xno"; then
 483         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 2.3.1],
 484                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 485                 have_seccomp=yes
 486                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 487                [have_seccomp=no])
 488         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 489                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 490         fi
 491 fi
 492 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 493
 494 # ------------------------------------------------------------------------------
 495 have_ima=yes
 496 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima], [disable optional IMA support]),
 497                 [case "${enableval}" in
 498                         yes) have_ima=yes ;;
 499                         no) have_ima=no ;;
 500                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 501                 esac],
 502                 [have_ima=yes])
 503
 504 if test "x${have_ima}" != xno ; then
 505         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 506 fi
 507
 508 # ------------------------------------------------------------------------------
 509 have_selinux=no
 510 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [disable optional SELINUX support]))
 511 if test "x$enable_selinux" != "xno"; then
 512         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 513                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 514                  have_selinux=yes
 515                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 516                 [have_selinux=no])
 517         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 518                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 519         fi
 520 fi
 521 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 522
 523 have_apparmor=no
 524 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [disable optional AppArmor support]))
 525 if test "x$enable_apparmor" != "xno"; then
 526         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 527                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 528                  have_apparmor=yes
 529                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 530                 [have_apparmor=no])
 531         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 532                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 533         fi
 534 fi
 535 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 536
 537 have_adm_group=no
 538 AC_ARG_ENABLE(adm-group, AS_HELP_STRING([--disable-adm-group], [disable adm group]))
 539 AS_IF([test "x$enable_adm_group" != "xno"], [
 540         AC_DEFINE(ENABLE_ADM_GROUP, 1, [Define if the ACL for adm group should be enabled])
 541         have_adm_group=yes
 542         M4_DEFINES="$M4_DEFINES -DENABLE_ADM_GROUP"
 543 ])
 544
 545 have_wheel_group=no
 546 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 547 AS_IF([test "x$enable_wheel_group" != "xno"], [
 548         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 549         have_wheel_group=yes
 550         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 551 ])
 552
 553
 554 AC_ARG_WITH(debug-shell,
 555         AS_HELP_STRING([--with-debug-shell=PATH],
 556                 [path to debug shell binary]),
 557         [SUSHELL="$withval"],
 558         [SUSHELL="/bin/sh"])
 559
 560 AC_SUBST(SUSHELL)
 561
 562 AC_ARG_WITH([debug-tty],
 563         AS_HELP_STRING([--with-debug-tty=PATH],
 564                 [specify the tty device for debug shell]),
 565         [DEBUGTTY="$withval"],
 566         [DEBUGTTY=/dev/tty9])
 567
 568 AC_SUBST(DEBUGTTY)
 569
 570 AC_ARG_WITH([certificate-root],
 571         AS_HELP_STRING([--with-certificate-root=PATH],
 572                 [specify the prefix for TLS certificates [/etc/ssl]]),
 573         [CERTIFICATEROOT="$withval"],
 574         [CERTIFICATEROOT="/etc/ssl"])
 575
 576 AC_SUBST(CERTIFICATEROOT)
 577
 578 AC_ARG_WITH([support-url],
 579         AS_HELP_STRING([--with-support-url=URL],
 580                 [specify the support URL to show in catalog entries included in systemd]),
 581         [SUPPORT_URL="$withval"],
 582         [SUPPORT_URL=http://lists.freedesktop.org/mailman/listinfo/systemd-devel])
 583
 584 AC_SUBST(SUPPORT_URL)
 585
 586 AC_ARG_WITH([nobody-user],
 587         AS_HELP_STRING([--with-nobody-user=NAME],
 588                 [specify the name of the nobody user (the one with UID 65534)]),
 589         [NOBODY_USER_NAME="$withval"],
 590         [NOBODY_USER_NAME=nobody])
 591
 592 AC_SUBST(NOBODY_USER_NAME)
 593 AC_DEFINE_UNQUOTED(NOBODY_USER_NAME, ["$NOBODY_USER_NAME"], [The name of the nobody user (the one with UID 65534)])
 594
 595 AC_ARG_WITH([nobody-group],
 596         AS_HELP_STRING([--with-nobody-group=NAME],
 597                 [specify the name of the nobody group (the one with GID 65534)]),
 598         [NOBODY_GROUP_NAME="$withval"],
 599         [NOBODY_GROUP_NAME=nobody])
 600
 601 AC_SUBST(NOBODY_GROUP_NAME)
 602 AC_DEFINE_UNQUOTED(NOBODY_GROUP_NAME, ["$NOBODY_GROUP_NAME"], [The name of the nobody group (the one with GID 65534)])
 603
 604 AC_ARG_WITH([fallback-hostname],
 605         AS_HELP_STRING([--with-fallback-hostname=NAME],
 606                 [specify the hostname used if none configured]),
 607         [FALLBACK_HOSTNAME="$withval"],
 608         [FALLBACK_HOSTNAME=localhost])
 609
 610 AC_SUBST(FALLBACK_HOSTNAME)
 611 AC_DEFINE_UNQUOTED(FALLBACK_HOSTNAME, ["$FALLBACK_HOSTNAME"], [The hostname used if none configured])
 612
 613 # ------------------------------------------------------------------------------
 614 have_xz=no
 615 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [disable optional XZ support]))
 616 AS_IF([test "x$enable_xz" != "xno"], [
 617         PKG_CHECK_MODULES(XZ, [ liblzma ],
 618                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 619                  have_xz=yes],
 620                  have_xz=no)
 621         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 622               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 623 ])
 624 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 625
 626 # ------------------------------------------------------------------------------
 627 have_zlib=no
 628 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [disable optional ZLIB support]))
 629 AS_IF([test "x$enable_zlib" != "xno"], [
 630         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 631                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 632                  have_zlib=yes],
 633                  have_zlib=no)
 634         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 635               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 636 ])
 637 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 638
 639 # ------------------------------------------------------------------------------
 640 have_bzip2=no
 641 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--disable-bzip2], [disable optional BZIP2 support]))
 642 AS_IF([test "x$enable_bzip2" != "xno"], [
 643         AC_CHECK_HEADERS(bzlib.h,
 644                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 645                  have_bzip2=yes],
 646                 [AS_IF([test "x$enable_bzip2" = xyes],
 647                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 648         )
 649 ])
 650 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 651
 652 # ------------------------------------------------------------------------------
 653 have_lz4=no
 654 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [disable optional LZ4 support]))
 655 AS_IF([test "x$enable_lz4" != "xno"], [
 656         PKG_CHECK_MODULES(LZ4, [ liblz4 < 10 ],
 657                [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 658                 have_lz4=yes],
 659                 [PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 660                       [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 661                       have_lz4=yes],
 662                       have_lz4=no)])
 663         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 664               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 665 ])
 666 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 667
 668 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 669
 670 # ------------------------------------------------------------------------------
 671 AC_ARG_ENABLE([pam],
 672         AS_HELP_STRING([--disable-pam], [disable optional PAM support]),
 673                 [case "${enableval}" in
 674                         yes) have_pam=yes ;;
 675                         no) have_pam=no ;;
 676                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 677                 esac],
 678                 [have_pam=auto])
 679
 680 if test "x${have_pam}" != xno ; then
 681         AC_CHECK_HEADERS(
 682                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 683                 [have_pam=yes],
 684                 [if test "x$have_pam" = xyes ; then
 685                         AC_MSG_ERROR([*** PAM headers not found.])
 686                 fi])
 687
 688         AC_CHECK_LIB(
 689                 [pam],
 690                 [pam_syslog],
 691                 [have_pam=yes],
 692                 [if test "x$have_pam" = xyes ; then
 693                         AC_MSG_ERROR([*** libpam not found.])
 694                 fi])
 695
 696         if test "x$have_pam" = xyes ; then
 697                 PAM_LIBS="-lpam -lpam_misc"
 698                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 699                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 700         else
 701                 have_pam=no
 702         fi
 703 else
 704         PAM_LIBS=
 705 fi
 706 AC_SUBST(PAM_LIBS)
 707 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 708
 709 # ------------------------------------------------------------------------------
 710 AC_ARG_ENABLE([acl],
 711         AS_HELP_STRING([--disable-acl], [disable optional ACL support]),
 712                 [case "${enableval}" in
 713                         yes) have_acl=yes ;;
 714                         no) have_acl=no ;;
 715                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 716                 esac],
 717                 [have_acl=auto])
 718
 719 if test "x${have_acl}" != xno ; then
 720         AC_CHECK_HEADERS(
 721                 [sys/acl.h acl/libacl.h],
 722                 [have_acl=yes],
 723                 [if test "x$have_acl" = xyes ; then
 724                         AC_MSG_ERROR([*** ACL headers not found.])
 725                 fi])
 726
 727         AC_CHECK_LIB(
 728                 [acl],
 729                 [acl_get_file],
 730                 [have_acl=yes],
 731                 [if test "x$have_acl" = xyes ; then
 732                         AC_MSG_ERROR([*** libacl not found.])
 733                 fi])
 734
 735         if test "x$have_acl" = xyes ; then
 736                 ACL_LIBS="-lacl"
 737                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 738                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 739         else
 740                 have_acl=no
 741         fi
 742 else
 743         ACL_LIBS=
 744 fi
 745 AC_SUBST(ACL_LIBS)
 746 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 747
 748 # ------------------------------------------------------------------------------
 749 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack], [disable optional SMACK support]),
 750                 [case "${enableval}" in
 751                         yes) have_smack=yes ;;
 752                         no) have_smack=no ;;
 753                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 754                 esac],
 755                 [have_smack=auto])
 756
 757 if test "x${have_smack}" != xno; then
 758         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 759         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 760         have_smack=yes
 761 fi
 762
 763 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 764
 765 have_smack_run_label=no
 766 AC_ARG_WITH(smack-run-label,
 767 AS_HELP_STRING([--with-smack-run-label=STRING],
 768         [run systemd --system itself with a specific SMACK label]),
 769         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 770         [])
 771
 772 if test "x${have_smack_run_label}" = xyes; then
 773         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 774 fi
 775
 776 AC_ARG_WITH(smack-default-process-label,
 777 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 778         [default SMACK label for executed processes]),
 779         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 780         [])
 781
 782 # ------------------------------------------------------------------------------
 783 AC_ARG_ENABLE([gcrypt],
 784         AS_HELP_STRING([--disable-gcrypt], [disable optional GCRYPT support]),
 785                 [case "${enableval}" in
 786                         yes) have_gcrypt=yes ;;
 787                         no) have_gcrypt=no ;;
 788                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 789                 esac],
 790                 [have_gcrypt=auto])
 791
 792 if test "x${have_gcrypt}" != xno ; then
 793         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 794                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 795         )
 796         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 797                         [1.4.5],
 798                         [have_gcrypt=yes],
 799                         dnl  If we have the gcrypt m4 macros, but don't have
 800                         dnl  gcrypt, throw an error if gcrypt is explicitly
 801                         dnl  requested.
 802                         [AM_PATH_LIBGCRYPT_FAIL]
 803                 )],
 804                 dnl  If we don't have the gcrypt m4 macros, but build with
 805                 dnl  gcrypt explicitly requested, throw an error.
 806                 [AM_PATH_LIBGCRYPT_FAIL]
 807         )
 808
 809         have_gpg_error=no
 810         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 811                         [1.12],
 812                         [have_gpg_error=yes],
 813                         [AM_PATH_LIBGCRYPT_FAIL]
 814                 )],
 815                 [AM_PATH_LIBGCRYPT_FAIL]
 816         )
 817
 818         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 819                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 820                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 821                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 822         else
 823                 have_gcrypt=no
 824                 have_gpg_error=no
 825         fi
 826 else
 827         GCRYPT_LIBS=
 828         GCRYPT_CFLAGS=
 829 fi
 830 AC_SUBST(GCRYPT_LIBS)
 831 AC_SUBST(GCRYPT_CFLAGS)
 832 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 833
 834 # ------------------------------------------------------------------------------
 835 AC_ARG_ENABLE([audit],
 836         AS_HELP_STRING([--disable-audit], [disable optional AUDIT support]),
 837                 [case "${enableval}" in
 838                         yes) have_audit=yes ;;
 839                         no) have_audit=no ;;
 840                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 841                 esac],
 842                 [have_audit=auto])
 843
 844 if test "x${have_audit}" != xno ; then
 845         AC_CHECK_HEADERS(
 846                 [libaudit.h],
 847                 [have_audit=yes],
 848                 [if test "x$have_audit" = xyes ; then
 849                         AC_MSG_ERROR([*** AUDIT headers not found.])
 850                 fi])
 851
 852         AC_CHECK_LIB(
 853                 [audit],
 854                 [audit_open],
 855                 [have_audit=yes],
 856                 [if test "x$have_audit" = xyes ; then
 857                         AC_MSG_ERROR([*** libaudit not found.])
 858                 fi])
 859
 860         if test "x$have_audit" = xyes ; then
 861                 AUDIT_LIBS="-laudit"
 862                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 863         else
 864                 have_audit=no
 865         fi
 866 else
 867         AUDIT_LIBS=
 868 fi
 869 AC_SUBST(AUDIT_LIBS)
 870 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 871
 872 # ------------------------------------------------------------------------------
 873 AC_ARG_ENABLE([elfutils],
 874         AS_HELP_STRING([--disable-elfutils], [disable optional ELFUTILS support]),
 875                 [case "${enableval}" in
 876                         yes) have_elfutils=yes ;;
 877                         no) have_elfutils=no ;;
 878                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 879                 esac],
 880                 [have_elfutils=auto])
 881
 882 if test "x${have_elfutils}" != xno ; then
 883         AC_CHECK_HEADERS(
 884                 [elfutils/libdwfl.h],
 885                 [],
 886                 [if test "x$have_elfutils" = xyes ; then
 887                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 888                 fi])
 889
 890         AC_CHECK_LIB(
 891                 [dw],
 892                 [dwfl_core_file_attach],
 893                 [have_elfutils=yes],
 894                 [if test "x$have_elfutils" = xyes ; then
 895                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 896                 fi])
 897
 898         if test "x$have_elfutils" = xyes ; then
 899                 ELFUTILS_LIBS="-lelf -ldw"
 900                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 901         else
 902                 have_elfutils=no
 903         fi
 904 else
 905         ELFUTILS_LIBS=
 906 fi
 907 AC_SUBST(ELFUTILS_LIBS)
 908 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 909
 910 # ------------------------------------------------------------------------------
 911 have_libcryptsetup=no
 912 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 913 if test "x$enable_libcryptsetup" != "xno"; then
 914         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 915                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 916         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 917                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 918         fi
 919 fi
 920 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 921
 922 # ------------------------------------------------------------------------------
 923 have_qrencode=no
 924 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 925 if test "x$enable_qrencode" != "xno"; then
 926         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 927                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 928         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 929                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 930         fi
 931 fi
 932 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 933
 934 # ------------------------------------------------------------------------------
 935 have_gnutls=no
 936 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 937 if test "x$enable_gnutls" != "xno"; then
 938         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 939                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 940         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 941                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 942         fi
 943 fi
 944 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 945
 946 # ------------------------------------------------------------------------------
 947 have_microhttpd=no
 948 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 949 if test "x$enable_microhttpd" != "xno"; then
 950         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 951                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 952                  have_microhttpd=yes
 953                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 954                 [have_microhttpd=no])
 955         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 956                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 957         fi
 958 fi
 959 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 960
 961 # ------------------------------------------------------------------------------
 962 have_libcurl=no
 963 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 964 if test "x$enable_libcurl" != "xno"; then
 965         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
 966                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 967                  have_libcurl=yes
 968                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 969                 [have_libcurl=no])
 970         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 971                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 972         fi
 973 fi
 974 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 975
 976 # ------------------------------------------------------------------------------
 977 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 978
 979 # ------------------------------------------------------------------------------
 980 have_libidn=no
 981 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [disable optional LIBIDN support]))
 982 if test "x$enable_libidn" != "xno"; then
 983         PKG_CHECK_MODULES(LIBIDN, [libidn],
 984                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 985                 have_libidn=yes
 986                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 987                [have_libidn=no])
 988         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 989                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 990         fi
 991 fi
 992 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 993
 994 # ------------------------------------------------------------------------------
 995 have_libiptc=no
 996 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [disable optional LIBIPTC support]))
 997 if test "x$enable_libiptc" != "xno"; then
 998         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 999                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
1000                 have_libiptc=yes
1001                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
1002                [have_libiptc=no])
1003         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
1004                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
1005         fi
1006 fi
1007 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
1008
1009 # ------------------------------------------------------------------------------
1010 have_binfmt=no
1011 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
1012 if test "x$enable_binfmt" != "xno"; then
1013         have_binfmt=yes
1014 fi
1015 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
1016
1017 # ------------------------------------------------------------------------------
1018 have_vconsole=no
1019 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
1020 if test "x$enable_vconsole" != "xno"; then
1021         have_vconsole=yes
1022 fi
1023 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
1024
1025 # ------------------------------------------------------------------------------
1026 have_quotacheck=no
1027 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
1028 if test "x$enable_quotacheck" != "xno"; then
1029         have_quotacheck=yes
1030 fi
1031 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
1032
1033 # ------------------------------------------------------------------------------
1034 have_tmpfiles=no
1035 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
1036 if test "x$enable_tmpfiles" != "xno"; then
1037         have_tmpfiles=yes
1038 fi
1039 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
1040
1041 # ------------------------------------------------------------------------------
1042 have_sysusers=no
1043 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
1044 if test "x$enable_sysusers" != "xno"; then
1045         have_sysusers=yes
1046 fi
1047 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
1048
1049 # ------------------------------------------------------------------------------
1050 have_firstboot=no
1051 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
1052 if test "x$enable_firstboot" != "xno"; then
1053         have_firstboot=yes
1054 fi
1055 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
1056
1057 # ------------------------------------------------------------------------------
1058 have_randomseed=no
1059 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
1060 if test "x$enable_randomseed" != "xno"; then
1061         have_randomseed=yes
1062 fi
1063 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
1064
1065 # ------------------------------------------------------------------------------
1066 have_backlight=no
1067 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
1068 if test "x$enable_backlight" != "xno"; then
1069         have_backlight=yes
1070 fi
1071 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
1072
1073 # ------------------------------------------------------------------------------
1074 have_rfkill=no
1075 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1076 if test "x$enable_rfkill" != "xno"; then
1077         have_rfkill=yes
1078 fi
1079 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1080
1081 # ------------------------------------------------------------------------------
1082 have_logind=no
1083 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1084 if test "x$enable_logind" != "xno"; then
1085         have_logind=yes
1086 fi
1087 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1088 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1089
1090 AC_ARG_WITH([kill-user-processes],
1091         [AS_HELP_STRING([--without-kill-user-processes], [set logind's KillUserProcesses=no by default])])
1092 AS_IF([test "$with_kill_user_processes" != "no"],
1093        [kill_user_processes=true
1094         KILL_USER_PROCESSES=yes],
1095        [kill_user_processes=false
1096         KILL_USER_PROCESSES=no])
1097 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
1098 AC_SUBST(KILL_USER_PROCESSES)
1099
1100 # ------------------------------------------------------------------------------
1101 have_machined=no
1102 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1103 if test "x$enable_machined" != "xno"; then
1104         have_machined=yes
1105         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1106 fi
1107 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1108
1109 # ------------------------------------------------------------------------------
1110 have_importd=no
1111 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1112 if test "x$enable_importd" != "xno"; then
1113         have_importd=yes
1114 fi
1115 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1116 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1117
1118 # ------------------------------------------------------------------------------
1119 have_hostnamed=no
1120 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1121 if test "x$enable_hostnamed" != "xno"; then
1122         have_hostnamed=yes
1123 fi
1124 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1125
1126 # ------------------------------------------------------------------------------
1127 have_timedated=no
1128 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1129 if test "x$enable_timedated" != "xno"; then
1130         have_timedated=yes
1131 fi
1132 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1133
1134 # ------------------------------------------------------------------------------
1135 have_timesyncd=no
1136 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1137 if test "x$enable_timesyncd" != "xno"; then
1138         have_timesyncd=yes
1139         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1140 fi
1141 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1142
1143 AC_ARG_WITH(ntp-servers,
1144         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1145                 [space-separated list of default NTP servers]),
1146         [NTP_SERVERS="$withval"],
1147         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1148         AC_MSG_WARN([*** Using Google NTP servers.
1149                         Do not ship OSes or devices with these default settings.
1150                         See DISTRO_PORTING for details!])])
1151
1152 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1153 AC_SUBST(NTP_SERVERS)
1154
1155 AC_ARG_WITH(time-epoch,
1156         AS_HELP_STRING([--with-time-epoch=SECONDS],
1157                 [time epoch for time clients]),
1158         [TIME_EPOCH="$withval"],
1159         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1160
1161 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1162
1163 # ------------------------------------------------------------------------------
1164 AC_ARG_WITH(system-uid-max,
1165         AS_HELP_STRING([--with-system-uid-max=UID]
1166                 [maximum UID for system users]),
1167         [SYSTEM_UID_MAX="$withval"],
1168         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1169
1170 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1171 AC_SUBST(SYSTEM_UID_MAX)
1172
1173 # ------------------------------------------------------------------------------
1174 AC_ARG_WITH(system-gid-max,
1175         AS_HELP_STRING([--with-system-gid-max=GID]
1176                 [maximum GID for system groups]),
1177         [SYSTEM_GID_MAX="$withval"],
1178         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1179
1180 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1181 AC_SUBST(SYSTEM_GID_MAX)
1182
1183 # ------------------------------------------------------------------------------
1184 have_localed=no
1185 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1186 if test "x$enable_localed" != "xno"; then
1187         have_localed=yes
1188 fi
1189 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1190
1191 # ------------------------------------------------------------------------------
1192 have_coredump=no
1193 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1194 if test "x$enable_coredump" != "xno"; then
1195         have_coredump=yes
1196         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1197 fi
1198 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1199
1200 # ------------------------------------------------------------------------------
1201 have_polkit=no
1202 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1203 if test "x$enable_polkit" != "xno"; then
1204         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1205         have_polkit=yes
1206 fi
1207 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1208
1209 # ------------------------------------------------------------------------------
1210 have_resolved=no
1211 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1212 AS_IF([test "x$enable_resolved" != "xno"], [
1213         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1214
1215         have_resolved=yes
1216         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1217         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1218 ])
1219 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1220
1221 AC_ARG_WITH(dns-servers,
1222         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1223                 [space-separated list of default DNS servers]),
1224         [DNS_SERVERS="$withval"],
1225         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1226
1227 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1228 AC_SUBST(DNS_SERVERS)
1229
1230 AC_ARG_WITH(default-dnssec,
1231         AS_HELP_STRING([--with-default-dnssec=MODE],
1232                [default DNSSEC mode, defaults to "allow-downgrade"]),
1233         [DEFAULT_DNSSEC_MODE="$withval"],
1234         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1235
1236 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1237         [xno], [mode=DNSSEC_NO],
1238         [xyes], [mode=DNSSEC_YES],
1239         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1240         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1241 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1242 AC_SUBST(DEFAULT_DNSSEC_MODE)
1243
1244 # ------------------------------------------------------------------------------
1245 have_networkd=no
1246 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1247 AS_IF([test "x$enable_networkd" != "xno"], [
1248         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1249         have_networkd=yes
1250         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1251 ])
1252 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1253
1254 # ------------------------------------------------------------------------------
1255 have_efi=no
1256 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable systemd-boot and bootctl (EFI support)]))
1257 if test "x$enable_efi" != "xno"; then
1258         AC_DEFINE(ENABLE_EFI, 1, [Define if systemd-boot and bootctl are to be enabled])
1259         have_efi=yes
1260 fi
1261 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1262
1263 # ------------------------------------------------------------------------------
1264 AC_CHECK_TOOL(EFI_CC, gcc)
1265
1266 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1267
1268 AM_COND_IF(ARCH_IA32, [
1269         EFI_ARCH=ia32
1270         EFI_MACHINE_TYPE_NAME=ia32])
1271
1272 AM_COND_IF(ARCH_X86_64, [
1273         EFI_MACHINE_TYPE_NAME=x64])
1274
1275 AM_COND_IF(ARCH_AARCH64, [
1276         EFI_MACHINE_TYPE_NAME=aa64])
1277
1278 AC_SUBST([EFI_ARCH])
1279 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1280
1281 have_gnuefi=no
1282 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [enable optional gnuefi support]))
1283 AS_IF([test "x$enable_gnuefi" != "xno"], [
1284         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1285                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1286                  have_gnuefi=yes],
1287                 [AS_IF([test "x$enable_gnuefi" = xyes],
1288                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1289         ])
1290
1291         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1292
1293         EFI_LIB_DIR="$efiroot"
1294         AC_ARG_WITH(efi-libdir,
1295                 AS_HELP_STRING([--with-efi-libdir=PATH], [path to EFI lib directory]),
1296                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1297         )
1298         AC_SUBST([EFI_LIB_DIR])
1299
1300         have_efi_lds=no
1301         AC_ARG_WITH(efi-ldsdir,
1302                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [path to EFI lds directory]),
1303                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1304                         [have_efi_lds=yes])],
1305                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1306                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1307                                        [have_efi_lds=yes && break])])])
1308         AS_IF([test "x$have_efi_lds" = xyes],
1309               [AC_SUBST([EFI_LDS_DIR])],
1310               [AS_IF([test "x$enable_gnuefi" = xyes],
1311                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1312                      [have_gnuefi=no])])
1313
1314         AC_ARG_WITH(efi-includedir,
1315                 AS_HELP_STRING([--with-efi-includedir=PATH], [path to EFI include directory]),
1316                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1317         )
1318         AC_SUBST([EFI_INC_DIR])
1319 ])
1320 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1321
1322 # ------------------------------------------------------------------------------
1323 have_tpm=no
1324 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm], [enable optional TPM support]),
1325                 [case "${enableval}" in
1326                         yes) have_tpm=yes ;;
1327                         no) have_tpm=no ;;
1328                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1329                 esac],
1330                 [have_tpm=no])
1331
1332 if test "x${have_tpm}" != xno ; then
1333         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1334 fi
1335
1336 AC_ARG_WITH(tpm-pcrindex,
1337         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1338                 [TPM PCR register number to use]),
1339         [SD_TPM_PCR="$withval"],
1340         [SD_TPM_PCR="8"])
1341
1342 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1343
1344 # ------------------------------------------------------------------------------
1345 AC_ARG_WITH(rc-local-script-path-start,
1346         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1347                 [path to /etc/rc.local]),
1348         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1349         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1350
1351 AC_ARG_WITH(rc-local-script-path-stop,
1352         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1353                 [path to /usr/sbin/halt.local]),
1354         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1355         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1356
1357 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1358 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1359
1360 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1361 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1362
1363 # ------------------------------------------------------------------------------
1364 AC_ARG_WITH(kbd-loadkeys,
1365         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1366                 [path to loadkeys]),
1367         [KBD_LOADKEYS="$withval"],
1368         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1369
1370 AC_ARG_WITH(kbd-setfont,
1371         AS_HELP_STRING([--with-kbd-setfont=PATH],
1372                 [path to setfont]),
1373         [KBD_SETFONT="$withval"],
1374         [KBD_SETFONT="/usr/bin/setfont"])
1375
1376 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1377 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1378
1379 AC_SUBST(KBD_LOADKEYS)
1380 AC_SUBST(KBD_SETFONT)
1381
1382 AC_ARG_WITH(telinit,
1383         AS_HELP_STRING([--with-telinit=PATH],
1384                 [path to telinit]),
1385         [TELINIT="$withval"],
1386         [TELINIT="/lib/sysvinit/telinit"])
1387
1388 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1389
1390 AC_SUBST(TELINIT)
1391
1392 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1393
1394 # ------------------------------------------------------------------------------
1395 have_myhostname=no
1396 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1397 if test "x$enable_myhostname" != "xno"; then
1398         AC_HEADER_STDC
1399         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1400
1401         AC_C_CONST
1402         AC_TYPE_SIZE_T
1403         AC_HEADER_TIME
1404
1405         AC_FUNC_SELECT_ARGTYPES
1406         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1407
1408         have_myhostname=yes
1409         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1410 fi
1411 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1412
1413 # ------------------------------------------------------------------------------
1414 AC_ARG_ENABLE(hwdb, [AS_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1415        enable_hwdb=$enableval, enable_hwdb=yes)
1416 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1417
1418 # ------------------------------------------------------------------------------
1419 have_manpages=no
1420 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1421 AC_PATH_PROG([XSLTPROC], [xsltproc])
1422 AS_IF([test "x$enable_manpages" != xno], [
1423        have_manpages=yes
1424        AS_IF([test -z "$XSLTPROC"],
1425              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1426 ])
1427 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1428
1429 # ------------------------------------------------------------------------------
1430 AC_ARG_ENABLE(hibernate,
1431        [AS_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1432        enable_hibernate=$enableval, enable_hibernate=yes)
1433 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1434
1435 # ------------------------------------------------------------------------------
1436 AC_ARG_ENABLE(ldconfig,
1437        [AS_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1438        enable_ldconfig=$enableval, enable_ldconfig=yes)
1439 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1440
1441 # ------------------------------------------------------------------------------
1442 # Location of the init scripts as mandated by LSB
1443 SYSTEM_SYSVINIT_PATH=/etc/init.d
1444 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1445
1446 AC_ARG_WITH([sysvinit-path],
1447         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1448                 [specify the path to where the SysV init scripts are located])],
1449         [SYSTEM_SYSVINIT_PATH="$withval"],
1450         [])
1451
1452 AC_ARG_WITH([sysvrcnd-path],
1453         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1454                 [specify the path to the base directory for the SysV rcN.d directories])],
1455         [SYSTEM_SYSVRCND_PATH="$withval"],
1456         [])
1457
1458 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1459         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1460         SYSTEM_SYSV_COMPAT="yes"
1461         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1462 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1463         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1464 else
1465         SYSTEM_SYSV_COMPAT="no"
1466 fi
1467
1468 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1469 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1470 AC_SUBST(M4_DEFINES)
1471
1472 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1473
1474 AC_ARG_WITH([tty-gid],
1475         [AS_HELP_STRING([--with-tty-gid=GID],
1476                 [specify the numeric GID of the 'tty' group])],
1477         [TTY_GID="$withval"],
1478         [TTY_GID="5"])
1479
1480 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1481 AC_SUBST(TTY_GID)
1482
1483 AC_ARG_WITH([dbuspolicydir],
1484         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1485         [],
1486         [with_dbuspolicydir=${datadir}/dbus-1/system.d])
1487 AX_NORMALIZE_PATH([with_dbuspolicydir])
1488
1489 AC_ARG_WITH([dbussessionservicedir],
1490         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1491         [],
1492         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1493 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1494
1495 AC_ARG_WITH([dbussystemservicedir],
1496         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1497         [],
1498         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1499 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1500
1501 AC_ARG_WITH([bashcompletiondir],
1502         AS_HELP_STRING([--with-bashcompletiondir=DIR], [bash completions directory]),
1503         [],
1504         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1505                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1506         ] , [
1507                 with_bashcompletiondir=${datadir}/bash-completion/completions
1508         ])])
1509 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1510 AX_NORMALIZE_PATH([with_bashcompletiondir])
1511
1512 AC_ARG_WITH([zshcompletiondir],
1513         AS_HELP_STRING([--with-zshcompletiondir=DIR], [zsh completions directory]),
1514         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1515 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1516 AX_NORMALIZE_PATH([with_zshcompletiondir])
1517
1518 AC_ARG_WITH([rootprefix],
1519         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1520         [], [with_rootprefix=${ac_default_prefix}])
1521 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1522 # defaults those to ".", solve that here for now until we can find a suitable
1523 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1524 # See: https://github.com/systemd/systemd/issues/54
1525 if test "x${with_rootprefix}" = "x"; then
1526         with_rootprefix="/"
1527 fi
1528 AX_NORMALIZE_PATH([with_rootprefix])
1529
1530 AC_ARG_WITH([rootlibdir],
1531         AS_HELP_STRING([--with-rootlibdir=DIR], [root directory for libraries necessary for boot]),
1532         [],
1533         [with_rootlibdir=${libdir}])
1534 AX_NORMALIZE_PATH([with_rootlibdir])
1535
1536 AC_ARG_WITH([pamlibdir],
1537         AS_HELP_STRING([--with-pamlibdir=DIR], [directory for PAM modules]),
1538         [],
1539         [with_pamlibdir=${with_rootlibdir}/security])
1540 AX_NORMALIZE_PATH([with_pamlibdir])
1541
1542 AC_ARG_WITH([pamconfdir],
1543         AS_HELP_STRING([--with-pamconfdir=DIR], [directory for PAM configuration (pass no to disable installing)]),
1544         [],
1545         [with_pamconfdir=${sysconfdir}/pam.d])
1546 AM_CONDITIONAL(ENABLE_PAM_CONFIG, [test "$with_pamconfdir" != "no"])
1547 AX_NORMALIZE_PATH([with_pamconfdir])
1548
1549 AC_ARG_ENABLE([split-usr],
1550         AS_HELP_STRING([--enable-split-usr], [assume that /bin, /sbin aren't symlinks into /usr]),
1551         [],
1552         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1553                 enable_split_usr=yes
1554         ], [
1555                 enable_split_usr=no
1556         ])])
1557
1558 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1559         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1560 ])
1561 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1562
1563 # work around intltool-update issues during 'make distcheck'
1564 AS_IF([test "x$0" != "x./configure"], [
1565         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1566 ])
1567
1568 # QEMU and OVMF UEFI firmware
1569 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1570         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1571         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1572                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1573         AC_SUBST([QEMU_BIOS])
1574 ])
1575
1576 AC_ARG_ENABLE(tests,
1577         [AS_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1578         enable_tests=$enableval, enable_tests=yes)
1579 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1580 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1581
1582 AC_ARG_ENABLE(debug,
1583         [AS_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1584         [if test "x$enableval" = "xyes"; then
1585                 enableval="hashmap,mmap-cache"
1586         fi
1587         saved_ifs="$IFS"
1588         IFS="$IFS$PATH_SEPARATOR,"
1589         for name in $enableval; do
1590                 case $name in
1591                 hashmap)
1592                         enable_debug_hashmap=yes
1593                         ;;
1594                 mmap-cache)
1595                         enable_debug_mmap_cache=yes
1596                         ;;
1597                 esac
1598         done
1599         IFS="$saved_ifs"],[])
1600
1601 enable_debug=""
1602 AS_IF([test x$enable_debug_hashmap = xyes], [
1603         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1604         enable_debug="hashmap $enable_debug"
1605 ])
1606 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1607         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1608         enable_debug="mmap-cache $enable_debug"
1609 ])
1610 test -z "$enable_debug" && enable_debug="none"
1611
1612 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1613 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1614 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1615 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1616 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1617 AC_SUBST([pamlibdir], [$with_pamlibdir])
1618 AC_SUBST([pamconfdir], [$with_pamconfdir])
1619 AC_SUBST([rootprefix], [$with_rootprefix])
1620 AC_SUBST([rootlibdir], [$with_rootlibdir])
1621
1622 AC_CONFIG_FILES([
1623         Makefile
1624         po/Makefile.in
1625 ])
1626
1627 AC_OUTPUT
1628 AC_MSG_RESULT([
1629         $PACKAGE_NAME $VERSION
1630
1631         libcryptsetup:                     ${have_libcryptsetup}
1632         PAM:                               ${have_pam}
1633         AUDIT:                             ${have_audit}
1634         IMA:                               ${have_ima}
1635         AppArmor:                          ${have_apparmor}
1636         SELinux:                           ${have_selinux}
1637         SECCOMP:                           ${have_seccomp}
1638         SMACK:                             ${have_smack}
1639         ZLIB:                              ${have_zlib}
1640         XZ:                                ${have_xz}
1641         LZ4:                               ${have_lz4}
1642         BZIP2:                             ${have_bzip2}
1643         ACL:                               ${have_acl}
1644         GCRYPT:                            ${have_gcrypt}
1645         QRENCODE:                          ${have_qrencode}
1646         MICROHTTPD:                        ${have_microhttpd}
1647         GNUTLS:                            ${have_gnutls}
1648         libcurl:                           ${have_libcurl}
1649         libidn:                            ${have_libidn}
1650         libiptc:                           ${have_libiptc}
1651         ELFUTILS:                          ${have_elfutils}
1652         binfmt:                            ${have_binfmt}
1653         vconsole:                          ${have_vconsole}
1654         quotacheck:                        ${have_quotacheck}
1655         tmpfiles:                          ${have_tmpfiles}
1656         sysusers:                          ${have_sysusers}
1657         firstboot:                         ${have_firstboot}
1658         randomseed:                        ${have_randomseed}
1659         backlight:                         ${have_backlight}
1660         rfkill:                            ${have_rfkill}
1661         logind:                            ${have_logind}
1662         Default KillUserProcesses setting: ${KILL_USER_PROCESSES}
1663         machined:                          ${have_machined}
1664         importd:                           ${have_importd}
1665         hostnamed:                         ${have_hostnamed}
1666         timedated:                         ${have_timedated}
1667         timesyncd:                         ${have_timesyncd}
1668         Default NTP servers:               ${NTP_SERVERS}
1669         time epoch:                        ${TIME_EPOCH}
1670         localed:                           ${have_localed}
1671         networkd:                          ${have_networkd}
1672         resolved:                          ${have_resolved}
1673         Default DNS servers:               ${DNS_SERVERS}
1674         Default DNSSEC mode:               ${DEFAULT_DNSSEC_MODE}
1675         coredump:                          ${have_coredump}
1676         polkit:                            ${have_polkit}
1677         efi:                               ${have_efi}
1678         gnuefi:                            ${have_gnuefi}
1679         efi arch:                          ${EFI_ARCH}
1680         EFI machine type:                  ${EFI_MACHINE_TYPE_NAME}
1681         EFI CC                             ${EFI_CC}
1682         EFI libdir:                        ${EFI_LIB_DIR}
1683         EFI ldsdir:                        ${EFI_LDS_DIR}
1684         EFI includedir:                    ${EFI_INC_DIR}
1685         kmod:                              ${have_kmod}
1686         xkbcommon:                         ${have_xkbcommon}
1687         blkid:                             ${have_blkid}
1688         libmount:                          ${have_libmount}
1689         dbus:                              ${have_dbus}
1690         nss-myhostname:                    ${have_myhostname}
1691         hwdb:                              ${enable_hwdb}
1692         tpm:                               ${have_tpm}
1693         Python:                            ${have_python}
1694         man pages:                         ${have_manpages}
1695         test coverage:                     ${have_coverage}
1696         Split /usr:                        ${enable_split_usr}
1697         SysV compatibility:                ${SYSTEM_SYSV_COMPAT}
1698         utmp/wtmp support:                 ${have_utmp}
1699         ldconfig support:                  ${enable_ldconfig}
1700         hibernate support:                 ${enable_hibernate}
1701         extra debugging:                   ${enable_debug}
1702         tests:                             ${enable_tests}
1703
1704         prefix:                            ${prefix}
1705         rootprefix:                        ${with_rootprefix}
1706         sysconf dir:                       ${sysconfdir}
1707         datarootdir:                       ${datarootdir}
1708         includedir:                        ${includedir}
1709         lib dir:                           ${libdir}
1710         rootlib dir:                       ${with_rootlibdir}
1711         SysV init scripts:                 ${SYSTEM_SYSVINIT_PATH}
1712         SysV rc?.d directories:            ${SYSTEM_SYSVRCND_PATH}
1713         Build Python:                      ${PYTHON}
1714         PAM modules dir:                   ${with_pamlibdir}
1715         PAM configuration dir:             ${with_pamconfdir}
1716         D-Bus policy dir:                  ${with_dbuspolicydir}
1717         D-Bus session dir:                 ${with_dbussessionservicedir}
1718         D-Bus system dir:                  ${with_dbussystemservicedir}
1719         Bash completions dir:              ${with_bashcompletiondir}
1720         Zsh completions dir:               ${with_zshcompletiondir}
1721         Extra start script:                ${RC_LOCAL_SCRIPT_PATH_START}
1722         Extra stop script:                 ${RC_LOCAL_SCRIPT_PATH_STOP}
1723         Adm group:                         ${have_adm_group}
1724         Wheel group:                       ${have_wheel_group}
1725         Debug shell:                       ${SUSHELL} @ ${DEBUGTTY}
1726         TTY GID:                           ${TTY_GID}
1727         Maximum system UID:                ${SYSTEM_UID_MAX}
1728         Maximum system GID:                ${SYSTEM_GID_MAX}
1729         Certificate root:                  ${CERTIFICATEROOT}
1730         Support URL:                       ${SUPPORT_URL}
1731         nobody user name:                  ${NOBODY_USER_NAME}
1732         nobody group name:                 ${NOBODY_GROUP_NAME}
1733         Fallback hostname:                 ${FALLBACK_HOSTNAME}
1734
1735         CFLAGS:   ${OUR_CFLAGS} ${CFLAGS}
1736         CPPFLAGS: ${OUR_CPPFLAGS} ${CPPFLAGS}
1737         LDFLAGS:  ${OUR_LDFLAGS} ${LDFLAGS}
1738 ])