configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl First, define all of the version numbers up front.
   4 dnl In particular, this allows the version macro to be used in AC_INIT
   5
   6 dnl These first two version numbers are updated automatically on each release.
   7 m4_define([LIBARCHIVE_VERSION_S],[3.5.3dev])
   8 m4_define([LIBARCHIVE_VERSION_N],[3005003])
   9
  10 dnl bsdtar and bsdcpio versioning tracks libarchive
  11 m4_define([BSDTAR_VERSION_S],LIBARCHIVE_VERSION_S())
  12 m4_define([BSDCPIO_VERSION_S],LIBARCHIVE_VERSION_S())
  13 m4_define([BSDCAT_VERSION_S],LIBARCHIVE_VERSION_S())
  14
  15 AC_PREREQ([2.69])
  16
  17 #
  18 # Now starts the "real" configure script.
  19 #
  20
  21 AC_INIT([libarchive],[LIBARCHIVE_VERSION_S()],[libarchive-discuss@googlegroups.com])
  22 # Make sure the srcdir contains "libarchive" directory
  23 AC_CONFIG_SRCDIR([libarchive])
  24 # Use auxiliary subscripts from this subdirectory (cleans up root)
  25 AC_CONFIG_AUX_DIR([build/autoconf])
  26 # M4 scripts
  27 AC_CONFIG_MACRO_DIR([build/autoconf])
  28 # Must follow AC_CONFIG macros above...
  29 AM_INIT_AUTOMAKE([1.11 dist-xz dist-zip])
  30 AM_MAINTAINER_MODE([enable])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 # Libtool's "interface version" can be computed from the libarchive version.
  34
  35 # Libtool interface version bumps on any API change, so increments
  36 # whenever libarchive minor version does.
  37 ARCHIVE_MINOR=$(( (LIBARCHIVE_VERSION_N() / 1000) % 1000 ))
  38 # Libarchive 2.7 == libtool interface 9 = 2 + 7
  39 # Libarchive 2.8 == libtool interface 10 = 2 + 8
  40 # Libarchive 2.9 == libtool interface 11 = 2 + 8
  41 # Libarchive 3.0 == libtool interface 12
  42 # Libarchive 3.1 == libtool interface 13
  43 ARCHIVE_INTERFACE=`echo $((13 + ${ARCHIVE_MINOR}))`
  44 # Libarchive revision is bumped on any source change === libtool revision
  45 ARCHIVE_REVISION=$(( LIBARCHIVE_VERSION_N() % 1000 ))
  46 # Libarchive minor is bumped on any interface addition === libtool age
  47 ARCHIVE_LIBTOOL_VERSION=$ARCHIVE_INTERFACE:$ARCHIVE_REVISION:$ARCHIVE_MINOR
  48
  49 # Stick the version numbers into config.h
  50 AC_DEFINE([__LIBARCHIVE_CONFIG_H_INCLUDED], [1],
  51         [Internal macro for sanity checks])
  52 AC_DEFINE([LIBARCHIVE_VERSION_STRING],"LIBARCHIVE_VERSION_S()",
  53         [Version number of libarchive])
  54 AC_DEFINE_UNQUOTED([LIBARCHIVE_VERSION_NUMBER],"LIBARCHIVE_VERSION_N()",
  55         [Version number of libarchive as a single integer])
  56 AC_DEFINE([BSDCPIO_VERSION_STRING],"BSDCPIO_VERSION_S()",
  57         [Version number of bsdcpio])
  58 AC_DEFINE([BSDTAR_VERSION_STRING],"BSDTAR_VERSION_S()",
  59         [Version number of bsdtar])
  60 AC_DEFINE([BSDCAT_VERSION_STRING],"BSDTAR_VERSION_S()",
  61         [Version number of bsdcat])
  62
  63 # The shell variables here must be the same as the AC_SUBST() variables
  64 # below, but the shell variable names apparently cannot be the same as
  65 # the m4 macro names above.  Why?  Ask autoconf.
  66 BSDCPIO_VERSION_STRING=BSDCPIO_VERSION_S()
  67 BSDTAR_VERSION_STRING=BSDTAR_VERSION_S()
  68 BSDCAT_VERSION_STRING=BSDCAT_VERSION_S()
  69 LIBARCHIVE_VERSION_STRING=LIBARCHIVE_VERSION_S()
  70 LIBARCHIVE_VERSION_NUMBER=LIBARCHIVE_VERSION_N()
  71
  72 # Substitute the above version numbers into the various files below.
  73 # Yes, I believe this is the fourth time we define what are essentially
  74 # the same symbols.  Why? Ask autoconf.
  75 AC_SUBST(ARCHIVE_LIBTOOL_VERSION)
  76 AC_SUBST(BSDCPIO_VERSION_STRING)
  77 AC_SUBST(BSDTAR_VERSION_STRING)
  78 AC_SUBST(BSDCAT_VERSION_STRING)
  79 AC_SUBST(LIBARCHIVE_VERSION_STRING)
  80 AC_SUBST(LIBARCHIVE_VERSION_NUMBER)
  81
  82 AC_CONFIG_HEADERS([config.h])
  83 AC_CONFIG_FILES([Makefile])
  84 AC_CONFIG_FILES([build/pkgconfig/libarchive.pc])
  85
  86 # Check for host type
  87 AC_CANONICAL_HOST
  88
  89 dnl Compilation on mingw and Cygwin needs special Makefile rules
  90 inc_windows_files=no
  91 inc_cygwin_files=no
  92 case "$host_os" in
  93   *mingw* ) inc_windows_files=yes ;;
  94   *cygwin* | *msys*) inc_cygwin_files=yes ;;
  95 esac
  96 AM_CONDITIONAL([INC_WINDOWS_FILES], [test $inc_windows_files = yes])
  97 AM_CONDITIONAL([INC_CYGWIN_FILES], [test $inc_cygwin_files = yes])
  98
  99 dnl Defines that are required for specific platforms (e.g. -D_POSIX_SOURCE, etc)
 100 PLATFORMCPPFLAGS=
 101 case "$host_os" in
 102   *mingw* ) PLATFORMCPPFLAGS=-D__USE_MINGW_ANSI_STDIO ;;
 103 esac
 104 AC_SUBST(PLATFORMCPPFLAGS)
 105
 106 # Checks for programs.
 107 AC_PROG_CC
 108 AC_PROG_CC_C99
 109 AM_PROG_CC_C_O
 110 AC_PROG_CPP
 111 AC_USE_SYSTEM_EXTENSIONS
 112 AC_LIBTOOL_WIN32_DLL
 113 AC_PROG_LIBTOOL
 114 AC_CHECK_TOOL([STRIP],[strip])
 115 AC_PROG_MKDIR_P
 116
 117 #
 118 # Options for building bsdtar.
 119 #
 120 # Default is to build bsdtar, but allow people to override that.
 121 #
 122 AC_ARG_ENABLE([bsdtar],
 123         [AS_HELP_STRING([--enable-bsdtar], [enable build of bsdtar (default)])
 124         AS_HELP_STRING([--enable-bsdtar=static], [force static build of bsdtar])
 125         AS_HELP_STRING([--enable-bsdtar=shared], [force dynamic build of bsdtar])
 126 AS_HELP_STRING([--disable-bsdtar], [disable build of bsdtar])],
 127         [], [enable_bsdtar=yes])
 128
 129 case "$enable_bsdtar" in
 130 yes)
 131         if test "$enable_static" = "no"; then
 132                 static_bsdtar=no
 133         else
 134                 static_bsdtar=yes
 135         fi
 136         build_bsdtar=yes
 137         ;;
 138 dynamic|shared)
 139         if test "$enable_shared" = "no"; then
 140                 AC_MSG_FAILURE([Shared linking of bsdtar requires shared libarchive])
 141         fi
 142         build_bsdtar=yes
 143         static_bsdtar=no
 144         ;;
 145 static)
 146         build_bsdtar=yes
 147         static_bsdtar=yes
 148         ;;
 149 no)
 150         build_bsdtar=no
 151         static_bsdtar=no
 152         ;;
 153 *)
 154         AC_MSG_FAILURE([Unsupported value for --enable-bsdtar])
 155         ;;
 156 esac
 157
 158 AM_CONDITIONAL([BUILD_BSDTAR], [ test "$build_bsdtar" = yes ])
 159 AM_CONDITIONAL([STATIC_BSDTAR], [ test "$static_bsdtar" = yes ])
 160
 161 #
 162 # Options for building bsdcat.
 163 #
 164 # Default is to build bsdcat, but allow people to override that.
 165 #
 166 AC_ARG_ENABLE([bsdcat],
 167         [AS_HELP_STRING([--enable-bsdcat], [enable build of bsdcat (default)])
 168         AS_HELP_STRING([--enable-bsdcat=static], [force static build of bsdcat])
 169         AS_HELP_STRING([--enable-bsdcat=shared], [force dynamic build of bsdcat])
 170 AS_HELP_STRING([--disable-bsdcat], [disable build of bsdcat])],
 171         [], [enable_bsdcat=yes])
 172
 173 case "$enable_bsdcat" in
 174 yes)
 175         if test "$enable_static" = "no"; then
 176                 static_bsdcat=no
 177         else
 178                 static_bsdcat=yes
 179         fi
 180         build_bsdcat=yes
 181         ;;
 182 dynamic|shared)
 183         if test "$enable_shared" = "no"; then
 184                 AC_MSG_FAILURE([Shared linking of bsdcat requires shared libarchive])
 185         fi
 186         build_bsdcat=yes
 187         static_bsdcat=no
 188         ;;
 189 static)
 190         build_bsdcat=yes
 191         static_bsdcat=yes
 192         ;;
 193 no)
 194         build_bsdcat=no
 195         static_bsdcat=no
 196         ;;
 197 *)
 198         AC_MSG_FAILURE([Unsupported value for --enable-bsdcat])
 199         ;;
 200 esac
 201
 202 AM_CONDITIONAL([BUILD_BSDCAT], [ test "$build_bsdcat" = yes ])
 203 AM_CONDITIONAL([STATIC_BSDCAT], [ test "$static_bsdcat" = yes ])
 204
 205 #
 206 # Options for building bsdcpio.
 207 #
 208 # Default is not to build bsdcpio, but that can be overridden.
 209 #
 210 AC_ARG_ENABLE([bsdcpio],
 211         [AS_HELP_STRING([--enable-bsdcpio], [enable build of bsdcpio (default)])
 212         AS_HELP_STRING([--enable-bsdcpio=static], [static build of bsdcpio])
 213         AS_HELP_STRING([--enable-bsdcpio=shared], [dynamic build of bsdcpio])
 214 AS_HELP_STRING([--disable-bsdcpio], [disable build of bsdcpio])],
 215         [], [enable_bsdcpio=yes])
 216
 217 case "$enable_bsdcpio" in
 218 yes)
 219         if test "$enable_static" = "no"; then
 220            static_bsdcpio=no
 221         else
 222            static_bsdcpio=yes
 223         fi
 224         build_bsdcpio=yes
 225         ;;
 226 dynamic|shared)
 227         if test "$enabled_shared" = "no"; then
 228            AC_MSG_FAILURE([Shared linking of bsdcpio requires shared libarchive])
 229         fi
 230         build_bsdcpio=yes
 231         ;;
 232 static)
 233         build_bsdcpio=yes
 234         static_bsdcpio=yes
 235         ;;
 236 no)
 237         build_bsdcpio=no
 238         static_bsdcpio=no
 239         ;;
 240 *)
 241         AC_MSG_FAILURE([Unsupported value for --enable-bsdcpio])
 242         ;;
 243 esac
 244
 245 AM_CONDITIONAL([BUILD_BSDCPIO], [ test "$build_bsdcpio" = yes ])
 246 AM_CONDITIONAL([STATIC_BSDCPIO], [ test "$static_bsdcpio" = yes ])
 247
 248 # Set up defines needed before including any headers
 249 case $host in
 250   *mingw* | *cygwin* | *msys*  )
 251   AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 252     [[#ifdef _WIN32_WINNT
 253      # error _WIN32_WINNT already defined
 254      #endif
 255     ]],[[;]])
 256   ],[
 257     AC_DEFINE([_WIN32_WINNT], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 258     AC_DEFINE([NTDDI_VERSION], 0x05020000, [Define to '0x05020000' for Windows Server 2003 APIs.])
 259   ])
 260   AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 261     [[#ifdef WINVER
 262      # error WINVER already defined
 263      #endif
 264     ]],[[;]])
 265   ],[
 266     AC_DEFINE([WINVER], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 267   ])
 268   ;;
 269 esac
 270
 271 # Checks for header files.
 272 AC_HEADER_DIRENT
 273 AC_HEADER_SYS_WAIT
 274 AC_CHECK_HEADERS([acl/libacl.h attr/xattr.h])
 275 AC_CHECK_HEADERS([copyfile.h ctype.h])
 276 AC_CHECK_HEADERS([errno.h ext2fs/ext2_fs.h fcntl.h grp.h])
 277
 278 AC_CACHE_CHECK([whether EXT2_IOC_GETFLAGS is usable],
 279     [ac_cv_have_decl_EXT2_IOC_GETFLAGS],
 280     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 281 @%:@include <ext2fs/ext2_fs.h>],
 282                                    [int x = EXT2_IOC_GETFLAGS])],
 283                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes])],
 284                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [no])])])
 285
 286 AS_VAR_IF([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes],
 287     [AC_DEFINE_UNQUOTED([HAVE_WORKING_EXT2_IOC_GETFLAGS], [1],
 288                     [Define to 1 if you have a working EXT2_IOC_GETFLAGS])])
 289
 290 AC_CHECK_HEADERS([inttypes.h io.h langinfo.h limits.h])
 291 AC_CHECK_HEADERS([linux/fiemap.h linux/fs.h linux/magic.h linux/types.h])
 292
 293 AC_CACHE_CHECK([whether FS_IOC_GETFLAGS is usable],
 294     [ac_cv_have_decl_FS_IOC_GETFLAGS],
 295     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 296 @%:@include <linux/fs.h>],
 297                                    [int x = FS_IOC_GETFLAGS])],
 298                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes])],
 299                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [no])])])
 300
 301 AS_VAR_IF([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes],
 302     [AC_DEFINE_UNQUOTED([HAVE_WORKING_FS_IOC_GETFLAGS], [1],
 303                     [Define to 1 if you have a working FS_IOC_GETFLAGS])])
 304
 305 AC_CHECK_HEADERS([locale.h membership.h paths.h poll.h pthread.h pwd.h])
 306 AC_CHECK_HEADERS([readpassphrase.h signal.h spawn.h])
 307 AC_CHECK_HEADERS([stdarg.h stdint.h stdlib.h string.h])
 308 AC_CHECK_HEADERS([sys/acl.h sys/cdefs.h sys/ea.h sys/extattr.h])
 309 AC_CHECK_HEADERS([sys/ioctl.h sys/mkdev.h sys/mount.h])
 310 AC_CHECK_HEADERS([sys/param.h sys/poll.h sys/richacl.h])
 311 AC_CHECK_HEADERS([sys/select.h sys/statfs.h sys/statvfs.h sys/sysmacros.h])
 312 AC_CHECK_HEADERS([sys/time.h sys/utime.h sys/utsname.h sys/vfs.h sys/xattr.h])
 313 AC_CHECK_HEADERS([time.h unistd.h utime.h wchar.h wctype.h])
 314 AC_CHECK_HEADERS([windows.h])
 315 # check windows.h first; the other headers require it.
 316 AC_CHECK_HEADERS([wincrypt.h winioctl.h],[],[],
 317 [[#ifdef HAVE_WINDOWS_H
 318 # include <windows.h>
 319 #endif
 320 ]])
 321
 322 # Checks for libraries.
 323 AC_ARG_WITH([zlib],
 324   AS_HELP_STRING([--without-zlib], [Don't build support for gzip through zlib]))
 325
 326 if test "x$with_zlib" != "xno"; then
 327   AC_CHECK_HEADERS([zlib.h])
 328   AC_CHECK_LIB(z,inflate)
 329 fi
 330
 331 AC_ARG_WITH([bz2lib],
 332   AS_HELP_STRING([--without-bz2lib], [Don't build support for bzip2 through bz2lib]))
 333
 334 if test "x$with_bz2lib" != "xno"; then
 335   AC_CHECK_HEADERS([bzlib.h])
 336   case "$host_os" in
 337     *mingw* | *cygwin* | *msys*)
 338       dnl AC_CHECK_LIB cannot be used on the Windows port of libbz2, therefore
 339           dnl use AC_LINK_IFELSE.
 340           AC_MSG_CHECKING([for BZ2_bzDecompressInit in -lbz2])
 341       old_LIBS="$LIBS"
 342       LIBS="-lbz2 $LIBS"
 343       AC_LINK_IFELSE(
 344         [AC_LANG_SOURCE(#include <bzlib.h>
 345           int main() { return BZ2_bzDecompressInit(NULL, 0, 0); })],
 346         [ac_cv_lib_bz2_BZ2_bzDecompressInit=yes],
 347         [ac_cv_lib_bz2_BZ2_bzDecompressInit=no])
 348       LIBS="$old_LIBS"
 349           AC_MSG_RESULT($ac_cv_lib_bz2_BZ2_bzDecompressInit)
 350       if test "x$ac_cv_lib_bz2_BZ2_bzDecompressInit" = xyes; then
 351         AC_DEFINE([HAVE_LIBBZ2], [1], [Define to 1 if you have the `bz2' library (-lbz2).])
 352         LIBS="-lbz2 $LIBS"
 353       fi
 354     ;;
 355     *)
 356       AC_CHECK_LIB(bz2,BZ2_bzDecompressInit)
 357     ;;
 358   esac
 359 fi
 360
 361 AC_ARG_WITH([libb2],
 362   AS_HELP_STRING([--without-libb2], [Don't build support for BLAKE2 through libb2]))
 363
 364 if test "x$with_libb2" != "xno"; then
 365   AC_CHECK_HEADERS([blake2.h])
 366   AC_CHECK_LIB(b2,blake2sp_init)
 367 fi
 368
 369 AM_CONDITIONAL([INC_BLAKE2], [test "x$ac_cv_lib_b2_blake2sp_init" != "xyes"])
 370
 371 AC_ARG_WITH([iconv],
 372   AS_HELP_STRING([--without-iconv], [Don't try to link against iconv]))
 373
 374 if test "x$with_iconv" != "xno"; then
 375   AM_ICONV
 376   AC_CHECK_HEADERS([iconv.h],[],[],[#include <stdlib.h>])
 377   if test "x$am_cv_func_iconv" = "xyes"; then
 378     AC_CHECK_HEADERS([localcharset.h])
 379     am_save_LIBS="$LIBS"
 380     LIBS="${LIBS} ${LIBICONV}"
 381     AC_CHECK_FUNCS([locale_charset])
 382     LIBS="${am_save_LIBS}"
 383     if test "x$ac_cv_func_locale_charset" != "xyes"; then
 384       # If locale_charset() is not in libiconv, we have to find libcharset.
 385       AC_CHECK_LIB(charset,locale_charset)
 386     fi
 387   fi
 388 fi
 389
 390 AC_ARG_WITH([lz4],
 391   AS_HELP_STRING([--without-lz4], [Don't build support for lz4 through liblz4]))
 392
 393 if test "x$with_lz4" != "xno"; then
 394   AC_CHECK_HEADERS([lz4.h lz4hc.h])
 395   AC_CHECK_LIB(lz4,LZ4_decompress_safe)
 396 fi
 397
 398 AC_ARG_WITH([zstd],
 399   AS_HELP_STRING([--without-zstd], [Don't build support for zstd through libzstd]))
 400
 401 if test "x$with_zstd" != "xno"; then
 402   AC_CHECK_HEADERS([zstd.h])
 403   AC_CHECK_LIB(zstd,ZSTD_compressStream)
 404 fi
 405
 406 AC_ARG_WITH([lzma],
 407   AS_HELP_STRING([--without-lzma], [Don't build support for xz through lzma]))
 408
 409 if test "x$with_lzma" != "xno"; then
 410   AC_CHECK_HEADERS([lzma.h])
 411   AC_CHECK_LIB(lzma,lzma_stream_decoder)
 412   # Some pre-release (but widely distributed) versions of liblzma
 413   # included a disabled version of lzma_stream_encoder_mt that
 414   # fools a naive AC_CHECK_LIB or AC_CHECK_FUNC, so we need
 415   # to do something more complex here:
 416   AC_CACHE_CHECK(
 417     [whether we have multithread support in lzma],
 418     ac_cv_lzma_has_mt,
 419     [AC_LINK_IFELSE([
 420       AC_LANG_PROGRAM([[#include <lzma.h>]
 421                        [#if LZMA_VERSION < 50020000]
 422                        [#error unsupported]
 423                        [#endif]],
 424                       [[lzma_stream_encoder_mt(0, 0);]])],
 425       [ac_cv_lzma_has_mt=yes], [ac_cv_lzma_has_mt=no])])
 426   if test "x$ac_cv_lzma_has_mt" != xno; then
 427           AC_DEFINE([HAVE_LZMA_STREAM_ENCODER_MT], [1], [Define to 1 if you have the `lzma_stream_encoder_mt' function.])
 428   fi
 429 fi
 430
 431 AC_ARG_WITH([lzo2],
 432   AS_HELP_STRING([--with-lzo2], [Build with LZO support from liblzo2]))
 433
 434 if test "x$with_lzo2" = "xyes"; then
 435   AC_CHECK_HEADERS([lzo/lzoconf.h lzo/lzo1x.h])
 436   AC_CHECK_LIB(lzo2,lzo1x_decompress_safe)
 437 fi
 438
 439 AC_ARG_WITH([cng],
 440   AS_HELP_STRING([--without-cng], [Don't build support of CNG(Crypto Next Generation)]))
 441
 442 AC_ARG_WITH([mbedtls],
 443   AS_HELP_STRING([--with-mbedtls], [Build with crypto support from mbed TLS]))
 444 AC_ARG_WITH([nettle],
 445   AS_HELP_STRING([--with-nettle], [Build with crypto support from Nettle]))
 446 AC_ARG_WITH([openssl],
 447   AS_HELP_STRING([--without-openssl], [Don't build support for mtree and xar hashes through openssl]))
 448 case "$host_os" in
 449   *darwin* ) with_openssl=no ;;
 450 esac
 451
 452 AC_ARG_WITH([xml2],
 453   AS_HELP_STRING([--without-xml2], [Don't build support for xar through libxml2]))
 454 AC_ARG_WITH([expat],
 455   AS_HELP_STRING([--without-expat], [Don't build support for xar through expat]))
 456
 457 if test "x$with_xml2" != "xno"; then
 458   PKG_PROG_PKG_CONFIG
 459   PKG_CHECK_MODULES(LIBXML2_PC, [libxml-2.0], [
 460     CPPFLAGS="${CPPFLAGS} ${LIBXML2_PC_CFLAGS}"
 461     LIBS="${LIBS} ${LIBXML2_PC_LIBS}"
 462     AC_CHECK_LIB(xml2,xmlInitParser,[true],AC_MSG_FAILURE(Missing xml2 library))
 463   ], [
 464     AC_CHECK_LIB(xml2,xmlInitParser)
 465   ])
 466   AC_CHECK_HEADERS([libxml/xmlreader.h libxml/xmlwriter.h])
 467 fi
 468 if test "x$ac_cv_header_libxml_xmlreader_h" != "xyes"; then
 469   if test "x$with_expat" != "xno"; then
 470     AC_CHECK_HEADERS([expat.h])
 471     AC_CHECK_LIB(expat,XML_ParserCreate)
 472   fi
 473 fi
 474
 475 AC_ARG_ENABLE([posix-regex-lib],
 476   [AS_HELP_STRING([--enable-posix-regex-lib],
 477     [choose what library to use for POSIX regular expression support (default: auto)])
 478   AS_HELP_STRING([--enable-posix-regex-lib=libc], [use libc POSIX regular expression support])
 479   AS_HELP_STRING([--enable-posix-regex-lib=libregex], [use libregex POSIX regular expression support])
 480   AS_HELP_STRING([--enable-posix-regex-lib=libpcreposix], [use libpcreposix POSIX regular expression support])
 481   AS_HELP_STRING([--disable-posix-regex-lib], [don't enable POSIX regular expression support])],
 482   [], [enable_posix_regex_lib=auto])
 483
 484 posix_regex_lib_found=
 485 if test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libc" || test "$enable_posix_regex_lib" = "libregex"; then
 486   AC_CHECK_HEADERS([regex.h])
 487   if test "x$ac_cv_header_regex_h" != "xno"; then
 488     AC_CHECK_FUNC(regcomp)
 489     if test "x$ac_cv_func_regcomp" = xyes; then
 490       posix_regex_lib_found=1
 491     else
 492       AC_CHECK_LIB(regex,regcomp)
 493       if test "x$ac_cv_lib_regex_regcomp" = xyes; then
 494         posix_regex_lib_found=1
 495       fi
 496     fi
 497   fi
 498 fi
 499 if test -z $posix_regex_lib_found && (test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libpcreposix"); then
 500   AC_CHECK_HEADERS([pcreposix.h])
 501   AC_CHECK_LIB(pcreposix,regcomp)
 502   if test "x$ac_cv_lib_pcreposix_regcomp" != xyes; then
 503     AC_MSG_NOTICE(trying libpcreposix check again with libpcre)
 504         unset ac_cv_lib_pcreposix_regcomp
 505         AC_CHECK_LIB(pcre,pcre_exec)
 506     AC_CHECK_LIB(pcreposix,regcomp)
 507     if test "x$ac_cv_lib_pcre_pcre_exec" = xyes && test "x$ac_cv_lib_pcreposix_regcomp" = xyes; then
 508       AC_MSG_CHECKING(if PCRE_STATIC needs to be defined)
 509       AC_LINK_IFELSE(
 510         [AC_LANG_SOURCE(#include <pcreposix.h>
 511           int main() { return regcomp(NULL, NULL, 0); })],
 512         [without_pcre_static=yes],
 513         [without_pcre_static=no])
 514       AC_LINK_IFELSE(
 515         [AC_LANG_SOURCE(#define PCRE_STATIC
 516           #include <pcreposix.h>
 517           int main() { return regcomp(NULL, NULL, 0); })],
 518         [with_pcre_static=yes],
 519         [with_pcre_static=no])
 520       if test "x$without_pcre_static" != xyes && test "x$with_pcre_static" = xyes; then
 521         AC_MSG_RESULT(yes)
 522         AC_DEFINE([PCRE_STATIC], [1], [Define to 1 if PCRE_STATIC needs to be defined.])
 523       elif test "x$without_pcre_static" = xyes || test "x$with_pcre_static" = xyes; then
 524         AC_MSG_RESULT(no)
 525       fi
 526       posix_regex_lib_found=1
 527     fi
 528   else
 529     posix_regex_lib_found=1
 530   fi
 531 fi
 532
 533 # TODO: Give the user the option of using a pre-existing system
 534 # libarchive.  This will define HAVE_LIBARCHIVE which will cause
 535 # bsdtar_platform.h to use #include <...> for the libarchive headers.
 536 # Need to include Makefile.am magic to link against system
 537 # -larchive in that case.
 538 #AC_CHECK_LIB(archive,archive_version)
 539
 540 # Checks for supported compiler flags
 541 AX_APPEND_COMPILE_FLAGS([-Wall -Wformat -Wformat-security])
 542
 543 # Checks for typedefs, structures, and compiler characteristics.
 544 AC_C_CONST
 545 # la_TYPE_UID_T defaults to "int", which is incorrect for MinGW
 546 # and MSVC. Use a customized version.
 547 la_TYPE_UID_T
 548 AC_TYPE_MODE_T
 549 # AC_TYPE_OFF_T defaults to "long", which limits us to 4GB files on
 550 # most systems... default to "long long" instead.
 551 AC_CHECK_TYPE(off_t, [long long])
 552 AC_TYPE_SIZE_T
 553 AC_CHECK_TYPE(id_t, [unsigned long])
 554 AC_CHECK_TYPE(uintptr_t, [unsigned int])
 555
 556 # Check for tm_gmtoff in struct tm
 557 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,
 558 [
 559 #include <time.h>
 560 ])
 561
 562 # Check for f_namemax in struct statfs
 563 AC_CHECK_MEMBERS([struct statfs.f_namemax],,,
 564 [
 565 #include <sys/param.h>
 566 #include <sys/mount.h>
 567 ])
 568
 569 # Check for f_iosize in struct statfs
 570 AC_CHECK_MEMBERS([struct statfs.f_iosize],,,
 571 [
 572 #include <sys/param.h>
 573 #include <sys/mount.h>
 574 ])
 575
 576 # Check for f_iosize in struct statvfs
 577 AC_CHECK_MEMBERS([struct statvfs.f_iosize],,,
 578 [
 579 #include <sys/statvfs.h>
 580 ])
 581
 582 # Check for birthtime in struct stat
 583 AC_CHECK_MEMBERS([struct stat.st_birthtime])
 584
 585 # Check for high-resolution timestamps in struct stat
 586 AC_CHECK_MEMBERS([struct stat.st_birthtimespec.tv_nsec])
 587 AC_CHECK_MEMBERS([struct stat.st_mtimespec.tv_nsec])
 588 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 589 AC_CHECK_MEMBERS([struct stat.st_mtime_n]) # AIX
 590 AC_CHECK_MEMBERS([struct stat.st_umtime]) # Tru64
 591 AC_CHECK_MEMBERS([struct stat.st_mtime_usec]) # Hurd
 592 # Check for block size support in struct stat
 593 AC_CHECK_MEMBERS([struct stat.st_blksize])
 594 # Check for st_flags in struct stat (BSD fflags)
 595 AC_CHECK_MEMBERS([struct stat.st_flags])
 596
 597 # If you have uintmax_t, we assume printf supports %ju
 598 # If you have unsigned long long, we assume printf supports %llu
 599 # TODO: Check for %ju and %llu support directly.
 600 AC_CHECK_TYPES([uintmax_t, unsigned long long])
 601
 602 # We use C99-style integer types
 603 # Declare them if the local platform doesn't already do so.
 604 AC_TYPE_INTMAX_T
 605 AC_TYPE_UINTMAX_T
 606 AC_TYPE_INT64_T
 607 AC_TYPE_UINT64_T
 608 AC_TYPE_INT32_T
 609 AC_TYPE_UINT32_T
 610 AC_TYPE_INT16_T
 611 AC_TYPE_UINT16_T
 612 AC_TYPE_UINT8_T
 613
 614 AC_CHECK_DECLS([SIZE_MAX, INT32_MAX, INT32_MIN])
 615 AC_CHECK_DECLS([INT64_MAX, INT64_MIN, UINT64_MAX, UINT32_MAX])
 616 AC_CHECK_DECLS([INTMAX_MAX, INTMAX_MIN, UINTMAX_MAX])
 617
 618 AC_CHECK_DECL([SSIZE_MAX],
 619                 [AC_DEFINE(HAVE_DECL_SSIZE_MAX, 1, [Define to 1 if you have the declaration of `SSIZE_MAX', and to 0 if you don't.])],
 620                 [],
 621                 [#include <limits.h>])
 622
 623 AC_CHECK_DECL([EFTYPE],
 624                 [AC_DEFINE(HAVE_EFTYPE, 1, [A possible errno value for invalid file format errors])],
 625                 [],
 626                 [#include <errno.h>])
 627 AC_CHECK_DECL([EILSEQ],
 628                 [AC_DEFINE(HAVE_EILSEQ, 1, [A possible errno value for invalid file format errors])],
 629                 [],
 630                 [#include <errno.h>])
 631 AC_CHECK_TYPE([wchar_t],
 632                 [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]wchar_t), 1, [Define to 1 if the system has the type `wchar_t'.])dnl
 633                 AC_CHECK_SIZEOF([wchar_t])],
 634                 [])
 635
 636 AC_HEADER_TIME
 637
 638 # Checks for library functions.
 639 AC_PROG_GCC_TRADITIONAL
 640 AC_HEADER_MAJOR
 641 AC_FUNC_FSEEKO
 642 AC_FUNC_MEMCMP
 643 AC_FUNC_LSTAT
 644 AC_FUNC_STAT
 645 AC_FUNC_STRERROR_R
 646 AC_FUNC_STRFTIME
 647 AC_FUNC_VPRINTF
 648 # check for:
 649 #   CreateHardLinkA(LPCSTR, LPCSTR, LPSECURITY_ATTRIBUTES)
 650 # To avoid necessity for including windows.h or special forward declaration
 651 # workarounds, we use 'void *' for 'struct SECURITY_ATTRIBUTES *'
 652 AC_CHECK_STDCALL_FUNC([CreateHardLinkA],[const char *, const char *, void *])
 653 AC_CHECK_FUNCS([arc4random_buf chflags chown chroot ctime_r])
 654 AC_CHECK_FUNCS([fchdir fchflags fchmod fchown fcntl fdopendir fork])
 655 AC_CHECK_FUNCS([fstat fstatat fstatfs fstatvfs ftruncate])
 656 AC_CHECK_FUNCS([futimens futimes futimesat])
 657 AC_CHECK_FUNCS([geteuid getpid getgrgid_r getgrnam_r])
 658 AC_CHECK_FUNCS([getpwnam_r getpwuid_r getvfsbyname gmtime_r])
 659 AC_CHECK_FUNCS([lchflags lchmod lchown link linkat localtime_r lstat lutimes])
 660 AC_CHECK_FUNCS([mbrtowc memmove memset])
 661 AC_CHECK_FUNCS([mkdir mkfifo mknod mkstemp])
 662 AC_CHECK_FUNCS([nl_langinfo openat pipe poll posix_spawnp readlink readlinkat])
 663 AC_CHECK_FUNCS([readpassphrase])
 664 AC_CHECK_FUNCS([select setenv setlocale sigaction statfs statvfs])
 665 AC_CHECK_FUNCS([strchr strdup strerror strncpy_s strnlen strrchr symlink])
 666 AC_CHECK_FUNCS([timegm tzset unlinkat unsetenv utime utimensat utimes vfork])
 667 AC_CHECK_FUNCS([wcrtomb wcscmp wcscpy wcslen wctomb wmemcmp wmemcpy wmemmove])
 668 AC_CHECK_FUNCS([_ctime64_s _fseeki64])
 669 AC_CHECK_FUNCS([_get_timezone _gmtime64_s _localtime64_s _mkgmtime64])
 670 # detects cygwin-1.7, as opposed to older versions
 671 AC_CHECK_FUNCS([cygwin_conv_path])
 672
 673 # DragonFly uses vfsconf, FreeBSD xvfsconf.
 674 AC_CHECK_TYPES(struct vfsconf,,,
 675         [#if HAVE_SYS_TYPES_H
 676         #include <sys/types.h>
 677         #endif
 678         #include <sys/mount.h>
 679         ])
 680
 681 AC_CHECK_TYPES(struct xvfsconf,,,
 682         [#if HAVE_SYS_TYPES_H
 683         #include <sys/types.h>
 684         #endif
 685         #include <sys/mount.h>
 686         ])
 687
 688 AC_CHECK_TYPES(struct statfs,,,
 689         [#if HAVE_SYS_TYPES_H
 690         #include <sys/types.h>
 691         #endif
 692         #include <sys/mount.h>
 693         ])
 694
 695 # There are several variants of readdir_r around; we only
 696 # accept the POSIX-compliant version.
 697 AC_COMPILE_IFELSE(
 698  [AC_LANG_PROGRAM([[#include <dirent.h>]],
 699                   [[DIR *dir; struct dirent e, *r;
 700                     return(readdir_r(dir, &e, &r));]])],
 701  [AC_DEFINE(HAVE_READDIR_R,1,[Define to 1 if you have a POSIX compatible readdir_r])]
 702 )
 703 # dirfd can be either a function or a macro.
 704 AC_COMPILE_IFELSE(
 705  [AC_LANG_PROGRAM([[#include <dirent.h>
 706                     DIR *dir;]],
 707                   [[return(dirfd(dir));]])],
 708  [AC_DEFINE(HAVE_DIRFD,1,[Define to 1 if you have a dirfd function or macro])]
 709 )
 710
 711 # FreeBSD's nl_langinfo supports an option to specify whether the
 712 # current locale uses month/day or day/month ordering.  It makes the
 713 # output a little prettier...
 714 AC_CHECK_DECL([D_MD_ORDER],
 715 [AC_DEFINE(HAVE_D_MD_ORDER, 1, [Define to 1 if nl_langinfo supports D_MD_ORDER])],
 716 [],
 717 [#if HAVE_LANGINFO_H
 718 #include <langinfo.h>
 719 #endif
 720 ])
 721
 722 # Check for dirent.d_namlen field explicitly
 723 # (This is a bit more straightforward than, if not quite as portable as,
 724 # the recipe given by the autoconf maintainers.)
 725 AC_CHECK_MEMBER(struct dirent.d_namlen,,,
 726 [#if HAVE_DIRENT_H
 727 #include <dirent.h>
 728 #endif
 729 ])
 730
 731 # Check for Extended Attributes support
 732 AC_ARG_ENABLE([xattr],
 733                 AS_HELP_STRING([--disable-xattr],
 734                 [Disable Extended Attributes support (default: check)]))
 735
 736 if test "x$enable_xattr" != "xno"; then
 737     AC_SEARCH_LIBS([setxattr], [attr gnu])
 738     AC_CHECK_DECLS([EXTATTR_NAMESPACE_USER], [], [], [#include <sys/types.h>
 739 #include <sys/extattr.h>
 740 ])
 741     AC_CHECK_DECLS([XATTR_NOFOLLOW], [], [], [#include <sys/xattr.h>
 742 ])
 743     if test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 744          -a "x$ac_cv_have_decl_XATTR_NOFOLLOW" = "xyes"; then
 745         # Darwin extended attributes support
 746         AC_CACHE_VAL([ac_cv_archive_xattr_darwin],
 747           [AC_CHECK_FUNCS(fgetxattr \
 748                           flistxattr \
 749                           fsetxattr \
 750                           getxattr \
 751                           listxattr \
 752                           setxattr,
 753           [ac_cv_archive_xattr_darwin=yes],
 754           [ac_cv_archive_xattr_darwin=no],
 755           [#include <sys/xattr.h>
 756 ])
 757         ]
 758       )
 759     elif test "x$ac_cv_header_sys_extattr_h" = "xyes" \
 760            -a "x$ac_cv_have_decl_EXTATTR_NAMESPACE_USER" = "xyes"; then
 761         # FreeBSD extended attributes support
 762         AC_CACHE_VAL([ac_cv_archive_xattr_freebsd],
 763           [AC_CHECK_FUNCS(extattr_get_fd \
 764                           extattr_get_file \
 765                           extattr_get_link \
 766                           extattr_list_fd \
 767                           extattr_list_file \
 768                           extattr_list_link \
 769                           extattr_set_fd \
 770                           extattr_set_link,
 771           [ac_cv_archive_xattr_freebsd=yes],
 772           [ac_cv_archive_xattr_freebsd=no],
 773           [#include <sys/types.h>
 774 #include <sys/extattr.h>
 775 ])
 776           ]
 777         )
 778     elif test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 779            -o "x$ac_cv_header_attr_xattr_h" = "xyes"; then
 780         # Linux extended attributes support
 781         AC_CACHE_VAL([ac_cv_archive_xattr_linux],
 782           [AC_CHECK_FUNCS(fgetxattr \
 783                           flistxattr \
 784                           fsetxattr \
 785                           getxattr \
 786                           lgetxattr \
 787                           listxattr \
 788                           llistxattr \
 789                           lsetxattr,
 790           [ac_cv_archive_xattr_linux=yes],
 791           [ac_cv_archive_xattr_linux=no],
 792           [#if HAVE_SYS_TYPES_H
 793 #include <sys/types.h>
 794 #endif
 795 #if HAVE_SYS_XATTR_H
 796 #include <sys/xattr.h>
 797 #endif
 798 #if HAVE_ATTR_XATTR_H
 799 #include <attr/xatr.h>
 800 #endif
 801 ])
 802         ]
 803       )
 804     elif test "x$ac_cv_header_sys_ea_h" = "xyes"; then
 805         # AIX extended attributes support
 806         AC_CACHE_VAL([ac_cv_archive_xattr_aix],
 807           [AC_CHECK_FUNCS(fgetea \
 808                           flistea \
 809                           fsetea \
 810                           getea \
 811                           lgetea \
 812                           listea \
 813                           llistea \
 814                           lsetea,
 815           [ac_cv_archive_xattr_aix=yes],
 816           [ac_cv_archive_xattr_aix=no],
 817           [#include <sys/ea.h>
 818 ])
 819           ]
 820         )
 821     fi
 822
 823     AC_MSG_CHECKING([for extended attributes support])
 824     if test "x$ac_cv_archive_xattr_linux" = "xyes"; then
 825         AC_DEFINE([ARCHIVE_XATTR_LINUX], [1], [Linux xattr support])
 826         AC_MSG_RESULT([Linux])
 827     elif test "x$ac_cv_archive_xattr_darwin" = "xyes"; then
 828         AC_DEFINE([ARCHIVE_XATTR_DARWIN], [1], [Darwin xattr support])
 829         AC_MSG_RESULT([Darwin])
 830     elif test "x$ac_cv_archive_xattr_freebsd" = "xyes"; then
 831         AC_DEFINE([ARCHIVE_XATTR_FREEBSD], [1], [FreeBSD xattr support])
 832         AC_MSG_RESULT([FreeBSD])
 833     elif test "x$ac_cv_archive_xattr_aix" = "xyes"; then
 834         AC_DEFINE([ARCHIVE_XATTR_AIX], [1], [AIX xattr support])
 835         AC_MSG_RESULT([AIX])
 836     else
 837         AC_MSG_RESULT([none])
 838     fi
 839 fi
 840
 841 # Check for ACL support
 842 #
 843 # The ACL support in libarchive is written against the POSIX1e draft,
 844 # which was never officially approved and varies quite a bit across
 845 # platforms.  Worse, some systems have completely non-POSIX acl functions,
 846 # which makes the following checks rather more complex than I would like.
 847 #
 848 AC_ARG_ENABLE([acl],
 849                 AS_HELP_STRING([--disable-acl],
 850                 [Disable ACL support (default: check)]))
 851
 852 if test "x$enable_acl" != "xno"; then
 853     # Libacl
 854     AC_CHECK_LIB([acl], [acl_get_file])
 855
 856     AC_CHECK_TYPES([acl_t, acl_entry_t, acl_permset_t, acl_tag_t], [], [], [
 857       #if HAVE_SYS_TYPES_H
 858       #include <sys/types.h>
 859       #endif
 860       #if HAVE_SYS_ACL_H
 861       #include <sys/acl.h>
 862       #endif
 863     ])
 864
 865     AC_CHECK_LIB([richacl], [richacl_get_file])
 866
 867     AC_CHECK_TYPES([[struct richace], [struct richacl]], [], [], [
 868       #if HAVE_SYS_RICHACL_H
 869       #include <sys/richacl.h>
 870       #endif
 871     ])
 872
 873     # Solaris and derivates ACLs
 874     AC_CHECK_FUNCS(acl facl)
 875
 876     if test "x$ac_cv_lib_richacl_richacl_get_file" = "xyes" \
 877          -a "x$ac_cv_type_struct_richace" = "xyes" \
 878          -a "x$ac_cv_type_struct_richacl" = "xyes"; then
 879         AC_CACHE_VAL([ac_cv_archive_acl_librichacl],
 880           [AC_CHECK_FUNCS(richacl_alloc \
 881                           richacl_equiv_mode \
 882                           richacl_free \
 883                           richacl_get_fd \
 884                           richacl_get_file \
 885                           richacl_set_fd \
 886                           richacl_set_file,
 887           [ac_cv_archive_acl_librichacl=yes], [ac_cv_archive_acl_librichacl=no],          [#include <sys/richacl.h>])])
 888     fi
 889
 890     if test "x$ac_cv_func_acl" = "xyes" \
 891          -a "x$ac_cv_func_facl" = "xyes"; then
 892         AC_CHECK_TYPES([aclent_t], [], [], [[#include <sys/acl.h>]])
 893         if test "x$ac_cv_type_aclent_t" = "xyes"; then
 894             AC_CACHE_VAL([ac_cv_archive_acl_sunos],
 895               [AC_CHECK_DECLS([GETACL, SETACL, GETACLCNT],
 896               [ac_cv_archive_acl_sunos=yes], [ac_cv_archive_acl_sunos=no],
 897               [#include <sys/acl.h>])])
 898             AC_CHECK_TYPES([ace_t], [], [], [[#include <sys/acl.h>]])
 899             if test "x$ac_cv_type_ace_t" = "xyes"; then
 900                 AC_CACHE_VAL([ac_cv_archive_acl_sunos_nfs4],
 901                   [AC_CHECK_DECLS([ACE_GETACL, ACE_SETACL, ACE_GETACLCNT],
 902                   [ac_cv_archive_acl_sunos_nfs4=yes],
 903                   [ac_cv_archive_acl_sonos_nfs4=no],
 904                   [#include <sys/acl.h>])])
 905             fi
 906         fi
 907     elif test "x$ac_cv_type_acl_t" = "xyes" \
 908          -a "x$ac_cv_type_acl_entry_t" = "xyes" \
 909          -a "x$ac_cv_type_acl_permset_t" = "xyes" \
 910          -a "x$ac_cv_type_acl_tag_t" = "xyes"; then
 911         # POSIX.1e ACL functions
 912         AC_CACHE_VAL([ac_cv_posix_acl_funcs],
 913           [AC_CHECK_FUNCS(acl_add_perm \
 914                           acl_clear_perms \
 915                           acl_create_entry \
 916                           acl_delete_def_file \
 917                           acl_free \
 918                           acl_get_entry \
 919                           acl_get_fd \
 920                           acl_get_file \
 921                           acl_get_permset \
 922                           acl_get_qualifier \
 923                           acl_get_tag_type \
 924                           acl_init \
 925                           acl_set_fd \
 926                           acl_set_file \
 927                           acl_set_qualifier \
 928                           acl_set_tag_type,
 929           [ac_cv_posix_acl_funcs=yes], [ac_cv_posix_acl_funcs=no],
 930           [#if HAVE_SYS_TYPES_H
 931            #include <sys/types.h>
 932            #endif
 933            #if HAVE_SYS_ACL_H
 934            #include <sys/acl.h>
 935            #endif
 936           ])
 937         ])
 938
 939         AC_CHECK_FUNCS(acl_get_perm)
 940
 941         if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 942              -a "x$ac_cv_header_acl_libacl_h" = "xyes" \
 943              -a "x$ac_cv_lib_acl_acl_get_file" = "xyes" \
 944              -a "x$ac_cv_func_acl_get_perm"; then
 945             AC_CACHE_VAL([ac_cv_archive_acl_libacl],
 946               [ac_cv_archive_acl_libacl=yes])
 947             AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
 948               [POSIX.1e ACL support via libacl])
 949         else
 950              # FreeBSD/Darwin
 951              AC_CHECK_FUNCS(acl_add_flag_np \
 952                             acl_clear_flags_np \
 953                             acl_get_brand_np \
 954                             acl_get_entry_type_np \
 955                             acl_get_flag_np \
 956                             acl_get_flagset_np \
 957                             acl_get_fd_np \
 958                             acl_get_link_np \
 959                             acl_get_perm_np \
 960                             acl_is_trivial_np \
 961                             acl_set_entry_type_np \
 962                             acl_set_fd_np \
 963                             acl_set_link_np,,,
 964               [#include <sys/types.h>
 965                #include <sys/acl.h>])
 966
 967             AC_CHECK_FUNCS(mbr_uid_to_uuid \
 968                            mbr_uuid_to_id \
 969                            mbr_gid_to_uuid,,,
 970               [#include <membership.h>])
 971
 972             AC_CHECK_DECLS([ACL_TYPE_EXTENDED, ACL_TYPE_NFS4, ACL_USER,
 973               ACL_SYNCHRONIZE], [], [],
 974               [#include <sys/types.h>
 975                #include <sys/acl.h>])
 976             if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 977                  -a "x$ac_cv_func_acl_get_fd_np" = "xyes" \
 978                  -a "x$ac_cv_func_acl_get_perm" != "xyes" \
 979                  -a "x$ac_cv_func_acl_get_perm_np" = "xyes" \
 980                  -a "x$ac_cv_func_acl_set_fd_np" = "xyes"; then
 981                 if test "x$ac_cv_have_decl_ACL_USER" = "xyes"; then
 982                     AC_CACHE_VAL([ac_cv_archive_acl_freebsd],
 983                       [ac_cv_archive_acl_freebsd=yes])
 984                     if test "x$ac_cv_have_decl_ACL_TYPE_NFS4" = "xyes" \
 985                          -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
 986                          -a "x$ac_cv_func_acl_get_brand_np" = "xyes" \
 987                          -a "x$ac_cv_func_acl_get_entry_type_np" = "xyes" \
 988                          -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
 989                          -a "x$ac_cv_func_acl_set_entry_type_np" = "xyes"; then
 990                         AC_CACHE_VAL([ac_cv_archive_acl_freebsd_nfs4],
 991                           [ac_cv_archive_acl_freebsd_nfs4=yes])
 992                     fi
 993                 elif test "x$ac_cv_have_decl_ACL_TYPE_EXTENDED" = "xyes" \
 994                        -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
 995                        -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
 996                        -a "x$ac_cv_func_acl_get_link_np" = "xyes" \
 997                        -a "x$ac_cv_func_acl_set_link_np" = "xyes" \
 998                        -a "x$ac_cv_func_mbr_uid_to_uuid" = "xyes" \
 999                        -a "x$ac_cv_func_mbr_uuid_to_id" = "xyes" \
1000                        -a "x$ac_cv_func_mbr_gid_to_uuid" = "xyes"; then
1001                     AC_CACHE_VAL([ac_cv_archive_acl_darwin],
1002                       [ac_cv_archive_acl_darwin=yes])
1003                 fi
1004             fi
1005         fi
1006     fi
1007     AC_MSG_CHECKING([for ACL support])
1008     if test "x$ac_cv_archive_acl_libacl" = "xyes" \
1009          -a "x$ac_cv_archive_acl_librichacl" = "xyes"; then
1010         AC_MSG_RESULT([libacl (POSIX.1e) + librichacl (NFSv4)])
1011         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
1012           [Linux POSIX.1e ACL support via libacl])
1013         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
1014           [Linux NFSv4 ACL support via librichacl])
1015     elif test "x$ac_cv_archive_acl_libacl" = "xyes"; then
1016         AC_MSG_RESULT([libacl (POSIX.1e)])
1017         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
1018           [Linux POSIX.1e ACL support via libacl])
1019     elif test "x$ac_cv_archive_acl_librichacl" = "xyes"; then
1020         AC_MSG_RESULT([librichacl (NFSv4)])
1021         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
1022           [Linux NFSv4 ACL support via librichacl])
1023     elif test "x$ac_cv_archive_acl_darwin" = "xyes"; then
1024         AC_DEFINE([ARCHIVE_ACL_DARWIN], [1], [Darwin ACL support])
1025         AC_MSG_RESULT([Darwin (limited NFSv4)])
1026     elif test "x$ac_cv_archive_acl_sunos" = "xyes"; then
1027         AC_DEFINE([ARCHIVE_ACL_SUNOS], [1], [Solaris ACL support])
1028         if test "x$ac_cv_archive_acl_sunos_nfs4" = "xyes"; then
1029             AC_DEFINE([ARCHIVE_ACL_SUNOS_NFS4], [1],
1030               [Solaris NFSv4 ACL support])
1031             AC_MSG_RESULT([Solaris (POSIX.1e and NFSv4)])
1032         else
1033             AC_MSG_RESULT([Solaris (POSIX.1e)])
1034         fi
1035     elif test "x$ac_cv_archive_acl_freebsd" = "xyes"; then
1036         AC_DEFINE([ARCHIVE_ACL_FREEBSD], [1], [FreeBSD ACL support])
1037         if test "x$ac_cv_archive_acl_freebsd_nfs4" = "xyes"; then
1038             AC_DEFINE([ARCHIVE_ACL_FREEBSD_NFS4], [1],
1039               [FreeBSD NFSv4 ACL support])
1040             AC_MSG_RESULT([FreeBSD (POSIX.1e and NFSv4)])
1041         else
1042             AC_MSG_RESULT([FreeBSD (POSIX.1e)])
1043         fi
1044     else
1045         AC_MSG_RESULT([none])
1046     fi
1047 fi
1048
1049
1050 AM_CONDITIONAL([INC_LINUX_ACL],
1051   [test "x$ac_cv_archive_acl_libacl" = "xyes" \
1052      -o "x$ac_cv_archive_acl_librichacl" = "xyes"])
1053 AM_CONDITIONAL([INC_SUNOS_ACL], [test "x$ac_cv_archive_acl_sunos" = "xyes"])
1054 AM_CONDITIONAL([INC_DARWIN_ACL],
1055           [test "x$ac_cv_archive_acl_darwin" = "xyes"])
1056 AM_CONDITIONAL([INC_FREEBSD_ACL],
1057           [test "x$ac_cv_archive_acl_freebsd" = "xyes"])
1058
1059 # Additional requirements
1060 AC_SYS_LARGEFILE
1061
1062 dnl NOTE: Crypto checks must run last.
1063 AC_DEFUN([CRYPTO_CHECK], [
1064   if test "$found_$1" != yes; then
1065     saved_CPPFLAGS="$CPPFLAGS"
1066     CPPFLAGS="$CPPFLAGS -I. -I$srcdir -I$srcdir/libarchive"
1067     touch "check_crypto_md.h"
1068     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_$2])
1069     AC_LINK_IFELSE([AC_LANG_SOURCE([
1070 #define ARCHIVE_$1_COMPILE_TEST
1071 #define ARCHIVE_CRYPTO_$1_$2
1072 #define PLATFORM_CONFIG_H "check_crypto_md.h"
1073
1074 $(cat "$srcdir/libarchive/archive_digest.c")
1075
1076 int
1077 main(int argc, char **argv)
1078 {
1079   archive_$3_ctx ctx;
1080   archive_$3_init(&ctx);
1081   archive_$3_update(&ctx, *argv, argc);
1082   archive_$3_final(&ctx, NULL);
1083   return 0;
1084 }
1085 ])],
1086     [ AC_MSG_RESULT([yes])
1087       found_$1=yes
1088       found_$2=yes
1089       AC_DEFINE(ARCHIVE_CRYPTO_$1_$2, 1, [ $1 via ARCHIVE_CRYPTO_$1_$2 supported.])
1090     ],
1091     [ AC_MSG_RESULT([no])])
1092     CPPFLAGS="$saved_CPPFLAGS"
1093     rm "check_crypto_md.h"
1094   fi
1095 ])
1096
1097 AC_DEFUN([CRYPTO_CHECK_WIN], [
1098   if test "$found_$1" != yes; then
1099     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_WIN])
1100     AC_LINK_IFELSE([AC_LANG_SOURCE([
1101 #define ARCHIVE_$1_COMPILE_TEST
1102 #include <windows.h>
1103 #include <wincrypt.h>
1104
1105 int
1106 main(int argc, char **argv)
1107 {
1108         (void)argc;
1109         (void)argv;
1110
1111         return ($2);
1112 }
1113 ])],
1114     [ AC_MSG_RESULT([yes])
1115       found_$1=yes
1116       found_WIN=yes
1117       AC_DEFINE(ARCHIVE_CRYPTO_$1_WIN, 1, [ $1 via ARCHIVE_CRYPTO_$1_WIN supported.])
1118     ],
1119     [ AC_MSG_RESULT([no])])
1120   fi
1121 ])
1122
1123 case "$host_os" in
1124   *mingw* | *cygwin* | *msys*)
1125         ;;
1126   *)
1127         CRYPTO_CHECK(MD5, LIBC, md5)
1128         CRYPTO_CHECK(MD5, LIBSYSTEM, md5)
1129         CRYPTO_CHECK(RMD160, LIBC, rmd160)
1130         CRYPTO_CHECK(SHA1, LIBC, sha1)
1131         CRYPTO_CHECK(SHA1, LIBSYSTEM, sha1)
1132         CRYPTO_CHECK(SHA256, LIBC, sha256)
1133         CRYPTO_CHECK(SHA256, LIBC2, sha256)
1134         CRYPTO_CHECK(SHA256, LIBC3, sha256)
1135         CRYPTO_CHECK(SHA256, LIBSYSTEM, sha256)
1136         CRYPTO_CHECK(SHA384, LIBC, sha384)
1137         CRYPTO_CHECK(SHA384, LIBC2, sha384)
1138         CRYPTO_CHECK(SHA384, LIBC3, sha384)
1139         CRYPTO_CHECK(SHA384, LIBSYSTEM, sha384)
1140         CRYPTO_CHECK(SHA512, LIBC, sha512)
1141         CRYPTO_CHECK(SHA512, LIBC2, sha512)
1142         CRYPTO_CHECK(SHA512, LIBC3, sha512)
1143         CRYPTO_CHECK(SHA512, LIBSYSTEM, sha512)
1144         ;;
1145 esac
1146
1147 if test "x$with_cng" != "xno"; then
1148     AC_CHECK_HEADERS([bcrypt.h],[
1149         LIBS="$LIBS -lbcrypt"
1150     ],[],
1151     [[#ifdef HAVE_WINDOWS_H
1152     # include <windows.h>
1153     #endif
1154     ]])
1155 fi
1156
1157 if test "x$with_mbedtls" = "xyes"; then
1158     AC_CHECK_HEADERS([mbedtls/aes.h mbedtls/md.h mbedtls/pkcs5.h])
1159     saved_LIBS=$LIBS
1160     AC_CHECK_LIB(mbedcrypto,mbedtls_sha1_init)
1161     CRYPTO_CHECK(MD5, MBEDTLS, md5)
1162     CRYPTO_CHECK(RMD160, MBEDTLS, rmd160)
1163     CRYPTO_CHECK(SHA1, MBEDTLS, sha1)
1164     CRYPTO_CHECK(SHA256, MBEDTLS, sha256)
1165     CRYPTO_CHECK(SHA384, MBEDTLS, sha384)
1166     CRYPTO_CHECK(SHA512, MBEDTLS, sha512)
1167     if test "x$found_MBEDTLS" != "xyes"; then
1168       LIBS=$saved_LIBS
1169     fi
1170 fi
1171
1172 if test "x$with_nettle" = "xyes"; then
1173     AC_CHECK_HEADERS([nettle/md5.h nettle/ripemd160.h nettle/sha.h])
1174     AC_CHECK_HEADERS([nettle/pbkdf2.h nettle/aes.h nettle/hmac.h])
1175     saved_LIBS=$LIBS
1176     AC_CHECK_LIB(nettle,nettle_sha1_init)
1177     CRYPTO_CHECK(MD5, NETTLE, md5)
1178     CRYPTO_CHECK(RMD160, NETTLE, rmd160)
1179     CRYPTO_CHECK(SHA1, NETTLE, sha1)
1180     CRYPTO_CHECK(SHA256, NETTLE, sha256)
1181     CRYPTO_CHECK(SHA384, NETTLE, sha384)
1182     CRYPTO_CHECK(SHA512, NETTLE, sha512)
1183     if test "x$found_NETTLE" != "xyes"; then
1184       LIBS=$saved_LIBS
1185     fi
1186 fi
1187
1188 if test "x$with_openssl" != "xno"; then
1189     AC_CHECK_HEADERS([openssl/evp.h])
1190     saved_LIBS=$LIBS
1191     case "$host_os" in
1192       *mingw* | *cygwin* | *msys*)
1193         case "$host_cpu" in
1194           x86_64)
1195             AC_CHECK_LIB(eay64,OPENSSL_config)
1196             if test "x$ac_cv_lib_eay64_main" != "xyes"; then
1197               AC_CHECK_LIB(eay32,OPENSSL_config)
1198             fi
1199             ;;
1200           *)
1201             AC_CHECK_LIB(eay32,OPENSSL_config)
1202             ;;
1203         esac
1204         ;;
1205       *)
1206         AC_CHECK_LIB(crypto,OPENSSL_config)
1207         ;;
1208     esac
1209     CRYPTO_CHECK(MD5, OPENSSL, md5)
1210     CRYPTO_CHECK(RMD160, OPENSSL, rmd160)
1211     CRYPTO_CHECK(SHA1, OPENSSL, sha1)
1212     CRYPTO_CHECK(SHA256, OPENSSL, sha256)
1213     CRYPTO_CHECK(SHA384, OPENSSL, sha384)
1214     CRYPTO_CHECK(SHA512, OPENSSL, sha512)
1215     AC_CHECK_FUNCS([PKCS5_PBKDF2_HMAC_SHA1])
1216 fi
1217
1218 # Probe libmd AFTER OpenSSL/libcrypto.
1219 # The two are incompatible and OpenSSL is more complete.
1220 AC_CHECK_HEADERS([md5.h ripemd.h sha.h sha256.h sha512.h])
1221 saved_LIBS=$LIBS
1222 AC_CHECK_LIB(md,MD5Init)
1223 CRYPTO_CHECK(MD5, LIBMD, md5)
1224 CRYPTO_CHECK(RMD160, LIBMD, rmd160)
1225 CRYPTO_CHECK(SHA1, LIBMD, sha1)
1226 CRYPTO_CHECK(SHA256, LIBMD, sha256)
1227 CRYPTO_CHECK(SHA512, LIBMD, sha512)
1228 if test "x$found_LIBMD" != "xyes"; then
1229   LIBS=$saved_LIBS
1230 fi
1231
1232 case "$host_os" in
1233   *mingw* | *cygwin* | *msys*)
1234         CRYPTO_CHECK_WIN(MD5, CALG_MD5)
1235         CRYPTO_CHECK_WIN(SHA1, CALG_SHA1)
1236         CRYPTO_CHECK_WIN(SHA256, CALG_SHA_256)
1237         CRYPTO_CHECK_WIN(SHA384, CALG_SHA_384)
1238         CRYPTO_CHECK_WIN(SHA512, CALG_SHA_512)
1239         ;;
1240 esac
1241
1242 # Ensure test directories are present if building out-of-tree
1243 AC_CONFIG_COMMANDS([mkdirs],
1244                    [mkdir -p libarchive/test tar/test cat/test cpio/test])
1245
1246 AC_OUTPUT