configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [202],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  71
  72 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  73
  74 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  75 m4_ifdef([GTK_DOC_CHECK], [
  76 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  77 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  78
  79 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  80         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  81 ])
  82
  83 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  84 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  85 ], [
  86    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  87    enable_introspection=no])
  88
  89 AC_CHECK_TOOL(OBJCOPY, objcopy)
  90 AC_CHECK_TOOL(STRINGS, strings)
  91 AC_CHECK_TOOL(GPERF, gperf)
  92 if test -z "$GPERF" ; then
  93         AC_MSG_ERROR([*** gperf not found])
  94 fi
  95
  96 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  97         -pipe \
  98         -Wall \
  99         -Wextra \
 100         -Wno-inline \
 101         -Wundef \
 102         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 103         -Wlogical-op \
 104         -Wsign-compare \
 105         -Wmissing-include-dirs \
 106         -Wold-style-definition \
 107         -Wpointer-arith \
 108         -Winit-self \
 109         -Wdeclaration-after-statement \
 110         -Wfloat-equal \
 111         -Wmissing-prototypes \
 112         -Wstrict-prototypes \
 113         -Wredundant-decls \
 114         -Wmissing-declarations \
 115         -Wmissing-noreturn \
 116         -Wshadow \
 117         -Wendif-labels \
 118         -Wcast-align \
 119         -Wstrict-aliasing=2 \
 120         -Wwrite-strings \
 121         -Wno-long-long \
 122         -Wno-overlength-strings \
 123         -Wno-unused-parameter \
 124         -Wno-missing-field-initializers \
 125         -Wno-unused-result \
 126         -Werror=overflow \
 127         -ffast-math \
 128         -fno-common \
 129         -fdiagnostics-show-option \
 130         -fno-strict-aliasing \
 131         -fvisibility=hidden \
 132         -ffunction-sections \
 133         -fdata-sections \
 134         -fstack-protector \
 135         --param=ssp-buffer-size=4])
 136 AC_SUBST([OUR_CFLAGS], $with_cflags)
 137
 138 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
 139         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 140                -Wp,-D_FORTIFY_SOURCE=2])], [
 141         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 142         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 143 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 144
 145 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 146         -Wl,--as-needed \
 147         -Wl,--no-undefined \
 148         -Wl,--gc-sections \
 149         -Wl,-z,relro \
 150         -Wl,-z,now])
 151 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 152
 153 # ------------------------------------------------------------------------------
 154 # we use python to build the man page index, and for systemd-python
 155 have_python=no
 156 have_python_devel=no
 157
 158 AC_ARG_WITH([python],
 159         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 160
 161 AS_IF([test "x$with_python" != "xno"], [
 162         AM_PATH_PYTHON(,, [:])
 163         AS_IF([test "$PYTHON" != :], [have_python=yes])
 164 ])
 165 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 166 AS_IF([test "x$PYTHON_BINARY" = "x"],
 167       [AS_IF([test "x$have_python" = "xyes"],
 168              [PYTHON_BINARY="$(which "$PYTHON")"],
 169              [PYTHON_BINARY=/usr/bin/python])])
 170 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 171
 172 AS_IF([test "x$with_python" != "xno"], [
 173         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 174         AS_IF([test -n "$PYTHON_CONFIG"], [
 175               have_python_devel=yes
 176               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
 177               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
 178               AC_SUBST(PYTHON_CFLAGS)
 179               AC_SUBST(PYTHON_LIBS)
 180               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 181         ])
 182 ])
 183 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 184
 185 # ------------------------------------------------------------------------------
 186
 187 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 188 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 189
 190 save_LIBS="$LIBS"
 191 LIBS=
 192 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 193 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 194 CAP_LIBS="$LIBS"
 195 LIBS="$save_LIBS"
 196 AC_SUBST(CAP_LIBS)
 197
 198 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 199 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 200 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 201 #include <unistd.h>
 202 #include <sys/mount.h>
 203 #include <fcntl.h>]])
 204
 205 # This makes sure pkg.m4 is available.
 206 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 207
 208 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 209
 210 # ------------------------------------------------------------------------------
 211 have_kmod=no
 212 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 213 if test "x$enable_kmod" != "xno"; then
 214         PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ],
 215                 [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available]) have_kmod=yes], have_kmod=no)
 216         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 217                 AC_MSG_ERROR([*** kmod support requested but libraries not found])
 218         fi
 219 fi
 220 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 221
 222 # ------------------------------------------------------------------------------
 223 have_blkid=no
 224 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 225 if test "x$enable_blkid" != "xno"; then
 226         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 227                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 228         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 229                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 230         fi
 231 fi
 232 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 233
 234 # ------------------------------------------------------------------------------
 235 have_ima=yes
 236 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 237                 [case "${enableval}" in
 238                         yes) have_ima=yes ;;
 239                         no) have_ima=no ;;
 240                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 241                 esac],
 242                 [have_ima=yes])
 243
 244 if test "x${have_ima}" != xno ; then
 245         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 246 fi
 247
 248 # ------------------------------------------------------------------------------
 249 have_chkconfig=yes
 250 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 251                 [case "${enableval}" in
 252                         yes) have_chkconfig=yes ;;
 253                         no) have_chkconfig=no ;;
 254                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 255                 esac],
 256                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 257                 if test -z "$CHKCONFIG"; then
 258                         have_chkconfig=no
 259                 else
 260                         have_chkconfig=yes
 261                 fi])
 262
 263 if test "x${have_chkconfig}" != xno ; then
 264         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 265 fi
 266
 267 # ------------------------------------------------------------------------------
 268 have_selinux=no
 269 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 270 if test "x$enable_selinux" != "xno"; then
 271         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 272                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 273         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 274                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 275         fi
 276 fi
 277 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 278 if test "x${have_selinux}" != xno ; then
 279         SUSHELL=/sbin/sushell
 280 else
 281         SUSHELL=/bin/sh
 282 fi
 283 AC_SUBST(SUSHELL)
 284
 285 # ------------------------------------------------------------------------------
 286 have_xz=no
 287 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 288 if test "x$enable_xz" != "xno"; then
 289         PKG_CHECK_MODULES(XZ, [ liblzma ],
 290                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 291         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 292                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 293         fi
 294 fi
 295 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 296
 297 # ------------------------------------------------------------------------------
 298 AC_ARG_ENABLE([tcpwrap],
 299         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 300                 [case "${enableval}" in
 301                         yes) have_tcpwrap=yes ;;
 302                         no) have_tcpwrap=no ;;
 303                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 304                 esac],
 305                 [have_tcpwrap=auto])
 306
 307 if test "x${have_tcpwrap}" != xno ; then
 308         ACX_LIBWRAP
 309         if test "x${LIBWRAP_LIBS}" = x ; then
 310                 if test "x$have_tcpwrap" = xyes ; then
 311                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 312                 fi
 313                 have_tcpwrap=no
 314         else
 315                 have_tcpwrap=yes
 316         fi
 317 else
 318         LIBWRAP_LIBS=
 319 fi
 320 AC_SUBST(LIBWRAP_LIBS)
 321
 322 # ------------------------------------------------------------------------------
 323 AC_ARG_ENABLE([pam],
 324         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 325                 [case "${enableval}" in
 326                         yes) have_pam=yes ;;
 327                         no) have_pam=no ;;
 328                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 329                 esac],
 330                 [have_pam=auto])
 331
 332 if test "x${have_pam}" != xno ; then
 333         AC_CHECK_HEADERS(
 334                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 335                 [have_pam=yes],
 336                 [if test "x$have_pam" = xyes ; then
 337                         AC_MSG_ERROR([*** PAM headers not found.])
 338                 fi])
 339
 340         AC_CHECK_LIB(
 341                 [pam],
 342                 [pam_syslog],
 343                 [have_pam=yes],
 344                 [if test "x$have_pam" = xyes ; then
 345                         AC_MSG_ERROR([*** libpam not found.])
 346                 fi])
 347
 348         if test "x$have_pam" = xyes ; then
 349                 PAM_LIBS="-lpam -lpam_misc"
 350                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 351         else
 352                 have_pam=no
 353         fi
 354 else
 355         PAM_LIBS=
 356 fi
 357 AC_SUBST(PAM_LIBS)
 358 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 359
 360 # ------------------------------------------------------------------------------
 361 AC_ARG_ENABLE([acl],
 362         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 363                 [case "${enableval}" in
 364                         yes) have_acl=yes ;;
 365                         no) have_acl=no ;;
 366                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 367                 esac],
 368                 [have_acl=auto])
 369
 370 if test "x${have_acl}" != xno ; then
 371         AC_CHECK_HEADERS(
 372                 [sys/acl.h acl/libacl.h],
 373                 [have_acl=yes],
 374                 [if test "x$have_acl" = xyes ; then
 375                         AC_MSG_ERROR([*** ACL headers not found.])
 376                 fi])
 377
 378         AC_CHECK_LIB(
 379                 [acl],
 380                 [acl_get_file],
 381                 [have_acl=yes],
 382                 [if test "x$have_acl" = xyes ; then
 383                         AC_MSG_ERROR([*** libacl not found.])
 384                 fi])
 385
 386         if test "x$have_acl" = xyes ; then
 387                 ACL_LIBS="-lacl"
 388                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 389         else
 390                 have_acl=no
 391         fi
 392 else
 393         ACL_LIBS=
 394 fi
 395 AC_SUBST(ACL_LIBS)
 396 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 397
 398 # ------------------------------------------------------------------------------
 399 AC_ARG_ENABLE([xattr],
 400         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 401                 [case "${enableval}" in
 402                         yes) have_xattr=yes ;;
 403                         no) have_xattr=no ;;
 404                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 405                 esac],
 406                 [have_xattr=auto])
 407
 408 if test "x${have_xattr}" != xno ; then
 409         AC_CHECK_HEADERS(
 410                 [attr/xattr.h],
 411                 [have_xattr=yes],
 412                 [if test "x$have_xattr" = xyes ; then
 413                         AC_MSG_ERROR([*** XATTR headers not found.])
 414                 fi])
 415
 416         AC_CHECK_LIB(
 417                 [attr],
 418                 [fsetxattr],
 419                 [have_xattr=yes],
 420                 [if test "x$have_xattr" = xyes ; then
 421                         AC_MSG_ERROR([*** libattr not found.])
 422                 fi])
 423
 424         if test "x$have_xattr" = xyes ; then
 425                 XATTR_LIBS="-lattr"
 426                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 427         else
 428                 have_xattr=no
 429         fi
 430 else
 431         XATTR_LIBS=
 432 fi
 433 AC_SUBST(XATTR_LIBS)
 434 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 435
 436 # ------------------------------------------------------------------------------
 437 AC_ARG_ENABLE([gcrypt],
 438         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 439                 [case "${enableval}" in
 440                         yes) have_gcrypt=yes ;;
 441                         no) have_gcrypt=no ;;
 442                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 443                 esac],
 444                 [have_gcrypt=auto])
 445
 446 if test "x${have_gcrypt}" != xno ; then
 447         AM_PATH_LIBGCRYPT(
 448                 [1.4.5],
 449                 [have_gcrypt=yes],
 450                 [if test "x$have_gcrypt" = xyes ; then
 451                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 452                 fi])
 453
 454         if test "x$have_gcrypt" = xyes ; then
 455                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 456                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 457                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 458         else
 459                 have_gcrypt=no
 460         fi
 461 else
 462         GCRYPT_LIBS=
 463         GCRYPT_CFLAGS=
 464 fi
 465 AC_SUBST(GCRYPT_LIBS)
 466 AC_SUBST(GCRYPT_CFLAGS)
 467 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 468
 469 # ------------------------------------------------------------------------------
 470 AC_ARG_ENABLE([audit],
 471         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 472                 [case "${enableval}" in
 473                         yes) have_audit=yes ;;
 474                         no) have_audit=no ;;
 475                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 476                 esac],
 477                 [have_audit=auto])
 478
 479 if test "x${have_audit}" != xno ; then
 480         AC_CHECK_HEADERS(
 481                 [libaudit.h],
 482                 [have_audit=yes],
 483                 [if test "x$have_audit" = xyes ; then
 484                         AC_MSG_ERROR([*** AUDIT headers not found.])
 485                 fi])
 486
 487         AC_CHECK_LIB(
 488                 [audit],
 489                 [audit_open],
 490                 [have_audit=yes],
 491                 [if test "x$have_audit" = xyes ; then
 492                         AC_MSG_ERROR([*** libaudit not found.])
 493                 fi])
 494
 495         if test "x$have_audit" = xyes ; then
 496                 AUDIT_LIBS="-laudit"
 497                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 498         else
 499                 have_audit=no
 500         fi
 501 else
 502         AUDIT_LIBS=
 503 fi
 504 AC_SUBST(AUDIT_LIBS)
 505
 506 # ------------------------------------------------------------------------------
 507 have_libcryptsetup=no
 508 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 509 if test "x$enable_libcryptsetup" != "xno"; then
 510         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 511                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 512         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 513                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 514         fi
 515 fi
 516 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 517
 518 # ------------------------------------------------------------------------------
 519 have_qrencode=no
 520 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 521 if test "x$enable_qrencode" != "xno"; then
 522         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 523                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 524         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 525                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 526         fi
 527 fi
 528 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 529
 530 # ------------------------------------------------------------------------------
 531 have_microhttpd=no
 532 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 533 if test "x$enable_microhttpd" != "xno"; then
 534         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 535                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 536         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 537                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 538         fi
 539 fi
 540 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 541
 542 # ------------------------------------------------------------------------------
 543 have_binfmt=no
 544 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 545 if test "x$enable_binfmt" != "xno"; then
 546         have_binfmt=yes
 547 fi
 548 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 549
 550 # ------------------------------------------------------------------------------
 551 have_vconsole=no
 552 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 553 if test "x$enable_vconsole" != "xno"; then
 554         have_vconsole=yes
 555 fi
 556 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 557
 558 # ------------------------------------------------------------------------------
 559 have_readahead=no
 560 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 561 if test "x$enable_readahead" != "xno"; then
 562         have_readahead=yes
 563 fi
 564 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 565
 566 # ------------------------------------------------------------------------------
 567 have_bootchart=no
 568 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 569 if test "x$enable_bootchart" != "xno"; then
 570         have_bootchart=yes
 571 fi
 572 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 573
 574 # ------------------------------------------------------------------------------
 575 have_quotacheck=no
 576 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 577 if test "x$enable_quotacheck" != "xno"; then
 578         have_quotacheck=yes
 579 fi
 580 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 581
 582 # ------------------------------------------------------------------------------
 583 have_randomseed=no
 584 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 585 if test "x$enable_randomseed" != "xno"; then
 586         have_randomseed=yes
 587 fi
 588 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 589
 590 # ------------------------------------------------------------------------------
 591 have_logind=no
 592 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 593 if test "x$enable_logind" != "xno"; then
 594         have_logind=yes
 595 fi
 596 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 597 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 598
 599 # ------------------------------------------------------------------------------
 600 have_hostnamed=no
 601 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 602 if test "x$enable_hostnamed" != "xno"; then
 603         have_hostnamed=yes
 604 fi
 605 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 606
 607 # ------------------------------------------------------------------------------
 608 have_timedated=no
 609 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 610 if test "x$enable_timedated" != "xno"; then
 611         have_timedated=yes
 612 fi
 613 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 614
 615 # ------------------------------------------------------------------------------
 616 have_localed=no
 617 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 618 if test "x$enable_localed" != "xno"; then
 619         have_localed=yes
 620 fi
 621 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 622
 623 # ------------------------------------------------------------------------------
 624 have_coredump=no
 625 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 626 if test "x$enable_coredump" != "xno"; then
 627         have_coredump=yes
 628 fi
 629 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 630
 631 # ------------------------------------------------------------------------------
 632 have_polkit=no
 633 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 634 if test "x$enable_polkit" != "xno"; then
 635         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 636         have_polkit=yes
 637 fi
 638 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 639
 640 # ------------------------------------------------------------------------------
 641 have_efi=no
 642 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 643 if test "x$enable_efi" != "xno"; then
 644         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 645         have_efi=yes
 646 fi
 647 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 648
 649 # ------------------------------------------------------------------------------
 650 AC_ARG_WITH(rc-local-script-path-start,
 651         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 652                 [Path to /etc/rc.local]),
 653         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 654         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 655
 656 AC_ARG_WITH(rc-local-script-path-stop,
 657         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 658                 [Path to /usr/sbin/halt.local]),
 659         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 660         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 661
 662 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 663 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 664
 665 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 666 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 667
 668 # ------------------------------------------------------------------------------
 669 AC_ARG_WITH(kbd-loadkeys,
 670         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 671                 [Path to loadkeys]),
 672         [KBD_LOADKEYS="$withval"],
 673         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 674
 675 AC_ARG_WITH(kbd-setfont,
 676         AS_HELP_STRING([--with-kbd-setfont=PATH],
 677                 [Path to setfont]),
 678         [KBD_SETFONT="$withval"],
 679         [KBD_SETFONT="/usr/bin/setfont"])
 680
 681 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 682 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 683
 684 AC_SUBST(KBD_LOADKEYS)
 685 AC_SUBST(KBD_SETFONT)
 686
 687 AC_ARG_WITH(telinit,
 688         AS_HELP_STRING([--with-telinit=PATH],
 689                 [Path to telinit]),
 690         [TELINIT="$withval"],
 691         [TELINIT="/lib/upstart/telinit"])
 692
 693 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 694
 695 AC_SUBST(TELINIT)
 696
 697 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 698
 699 # ------------------------------------------------------------------------------
 700 have_myhostname=no
 701 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 702 if test "x$enable_myhostname" != "xno"; then
 703         AC_HEADER_STDC
 704         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 705
 706         AC_C_CONST
 707         AC_TYPE_SIZE_T
 708         AC_HEADER_TIME
 709
 710         AC_FUNC_MALLOC
 711         AC_FUNC_SELECT_ARGTYPES
 712         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 713
 714         have_myhostname=yes
 715 fi
 716 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 717
 718 # ------------------------------------------------------------------------------
 719 AC_ARG_WITH(firmware-path,
 720        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 721           [Firmware search path (default="")]),
 722        [], [with_firmware_path=""])
 723 OLD_IFS=$IFS
 724 IFS=:
 725 for i in $with_firmware_path; do
 726        if test "x${FIRMWARE_PATH}" = "x"; then
 727               FIRMWARE_PATH="\\\"${i}/\\\""
 728        else
 729               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 730        fi
 731 done
 732 IFS=$OLD_IFS
 733 AC_SUBST(FIRMWARE_PATH)
 734 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 735 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 736
 737 # ------------------------------------------------------------------------------
 738 AC_ARG_ENABLE([gudev],
 739        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 740        [], [enable_gudev=yes])
 741 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 742 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 743 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 744
 745 # ------------------------------------------------------------------------------
 746 AC_ARG_ENABLE([keymap],
 747        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 748        [], [enable_keymap=yes])
 749 AS_IF([test "x$enable_keymap" = "xyes"], [
 750        AC_PATH_PROG([GPERF], [gperf])
 751        if test -z "$GPERF"; then
 752               AC_MSG_ERROR([gperf is needed])
 753        fi
 754
 755        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 756        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 757 ])
 758 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 759
 760 # ------------------------------------------------------------------------------
 761 DEBUGTTY=/dev/tty9
 762 AC_ARG_WITH([debugshelltty],
 763         [AS_HELP_STRING([--with-debugshelltty=PATH],
 764                 [Specify the tty device for debug shell])],
 765         [DEBUGTTY="$withval"],
 766         [])
 767 AC_SUBST(DEBUGTTY)
 768
 769 # ------------------------------------------------------------------------------
 770 have_manpages=no
 771 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 772 AS_IF([test "x$enable_manpages" != xno], [
 773         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 774                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 775         ])
 776         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 777 ])
 778 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 779
 780 # ------------------------------------------------------------------------------
 781
 782 # Location of the init scripts as mandated by LSB
 783 SYSTEM_SYSVINIT_PATH=/etc/init.d
 784 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 785 M4_DEFINES=
 786
 787 AC_ARG_WITH([sysvinit-path],
 788         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 789                 [Specify the path to where the SysV init scripts are located])],
 790         [SYSTEM_SYSVINIT_PATH="$withval"],
 791         [])
 792
 793 AC_ARG_WITH([sysvrcnd-path],
 794         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 795                 [Specify the path to the base directory for the SysV rcN.d directories])],
 796         [SYSTEM_SYSVRCND_PATH="$withval"],
 797         [])
 798
 799 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 800         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 801         SYSTEM_SYSV_COMPAT="yes"
 802         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 803 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 804         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 805 else
 806         SYSTEM_SYSV_COMPAT="no"
 807 fi
 808
 809 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 810 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 811 AC_SUBST(M4_DEFINES)
 812
 813 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 814
 815 AC_ARG_WITH([tty-gid],
 816         [AS_HELP_STRING([--with-tty-gid=GID],
 817                 [Specify the numeric GID of the 'tty' group])],
 818         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 819         [])
 820
 821 AC_ARG_WITH([dbuspolicydir],
 822         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 823         [],
 824         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 825
 826 AC_ARG_WITH([dbussessionservicedir],
 827         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 828         [],
 829         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 830
 831 AC_ARG_WITH([dbussystemservicedir],
 832         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 833         [],
 834         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 835
 836 AC_ARG_WITH([dbusinterfacedir],
 837         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 838         [],
 839         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 840
 841 AC_ARG_WITH([bashcompletiondir],
 842         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 843         [],
 844         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 845                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 846         ] , [
 847                 with_bashcompletiondir=${datadir}/bash-completion/completions
 848         ])])
 849
 850 AC_ARG_WITH([rootprefix],
 851         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 852         [], [with_rootprefix=${ac_default_prefix}])
 853
 854 AC_ARG_WITH([rootlibdir],
 855         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 856         [],
 857         [with_rootlibdir=${libdir}])
 858
 859 AC_ARG_WITH([pamlibdir],
 860         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 861         [],
 862         [with_pamlibdir=${with_rootlibdir}/security])
 863
 864 AC_ARG_ENABLE([split-usr],
 865         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 866         [],
 867         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 868                 enable_split_usr=yes
 869         ], [
 870                 enable_split_usr=no
 871         ])])
 872
 873 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 874         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 875 ])
 876
 877 # Work around intltoolize and gtk-doc problems in VPATH builds
 878 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 879                                        [Define to do gtk-doc tests])
 880 AS_IF([test "x$0" != "x./configure"], [
 881         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 882 ])
 883
 884 AC_ARG_ENABLE(tests,
 885        [AC_HELP_STRING([--disable-tests], [disable tests])],
 886        enable_tests=$enableval, enable_tests=yes)
 887 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 888
 889 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 890 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 891 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 892 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 893 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 894 AC_SUBST([pamlibdir], [$with_pamlibdir])
 895 AC_SUBST([rootprefix], [$with_rootprefix])
 896 AC_SUBST([rootlibdir], [$with_rootlibdir])
 897
 898 AC_CONFIG_FILES([
 899         Makefile po/Makefile.in
 900         docs/libudev/Makefile
 901         docs/libudev/version.xml
 902         docs/gudev/Makefile
 903         docs/gudev/version.xml
 904 ])
 905
 906 AC_OUTPUT
 907 AC_MSG_RESULT([
 908         $PACKAGE_NAME $VERSION
 909
 910         libcryptsetup:           ${have_libcryptsetup}
 911         tcpwrap:                 ${have_tcpwrap}
 912         PAM:                     ${have_pam}
 913         AUDIT:                   ${have_audit}
 914         IMA:                     ${have_ima}
 915         SELinux:                 ${have_selinux}
 916         XZ:                      ${have_xz}
 917         ACL:                     ${have_acl}
 918         XATTR:                   ${have_xattr}
 919         GCRYPT:                  ${have_gcrypt}
 920         QRENCODE:                ${have_qrencode}
 921         MICROHTTPD:              ${have_microhttpd}
 922         CHKCONFIG:               ${have_chkconfig}
 923         binfmt:                  ${have_binfmt}
 924         vconsole:                ${have_vconsole}
 925         readahead:               ${have_readahead}
 926         bootchart:               ${have_bootchart}
 927         quotacheck:              ${have_quotacheck}
 928         randomseed:              ${have_randomseed}
 929         logind:                  ${have_logind}
 930         hostnamed:               ${have_hostnamed}
 931         timedated:               ${have_timedated}
 932         localed:                 ${have_localed}
 933         coredump:                ${have_coredump}
 934         polkit:                  ${have_polkit}
 935         efi:                     ${have_efi}
 936         kmod:                    ${have_kmod}
 937         blkid:                   ${have_blkid}
 938         nss-myhostname:          ${have_myhostname}
 939         gudev:                   ${enable_gudev}
 940         gintrospection:          ${enable_introspection}
 941         keymap:                  ${enable_keymap}
 942         Python:                  ${have_python}
 943         Python Headers:          ${have_python_devel}
 944         man pages:               ${have_manpages}
 945         gtk-doc:                 ${enable_gtk_doc}
 946         Split /usr:              ${enable_split_usr}
 947         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 948
 949         prefix:                  ${prefix}
 950         rootprefix:              ${with_rootprefix}
 951         sysconf dir:             ${sysconfdir}
 952         datarootdir:             ${datarootdir}
 953         includedir:              ${includedir}
 954         include_prefix:          ${INCLUDE_PREFIX}
 955         lib dir:                 ${libdir}
 956         rootlib dir:             ${with_rootlibdir}
 957         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 958         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 959         Build Python:            ${PYTHON}
 960         Installation Python:     ${PYTHON_BINARY}
 961         firmware path:           ${FIRMWARE_PATH}
 962         PAM modules dir:         ${with_pamlibdir}
 963         D-Bus policy dir:        ${with_dbuspolicydir}
 964         D-Bus session dir:       ${with_dbussessionservicedir}
 965         D-Bus system dir:        ${with_dbussystemservicedir}
 966         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 967         Bash completions dir:    ${with_bashcompletiondir}
 968         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
 969         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
 970
 971         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 972         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 973         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 974         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
 975         PYTHON_LIBS:             ${PYTHON_LIBS}
 976 ])