configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 AC_ARG_ENABLE(offload-defaulted,
 303 [AS_HELP_STRING([--enable-offload-defaulted]
 304                 [If enabled, configured but not installed offload compilers and
 305                 libgomp plugins are silently ignored.  Useful for distribution
 306                 compilers where those are in separate optional packages.])],
 307 [enable_offload_defaulted=$enableval],
 308 [enable_offload_defaulted=])
 309
 310 # Handle --enable-gold, --enable-ld.
 311 # --disable-gold [--enable-ld]
 312 #     Build only ld.  Default option.
 313 # --enable-gold [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 315 #     as "ld.bfd" and "ld".
 316 # --enable-gold=default [--enable-ld]
 317 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 318 #     install ld as "ld.bfd".
 319 # --enable-gold[=default] --disable-ld
 320 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 321 # --enable-gold --enable-ld=default
 322 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 323 #     and ld.bfd).
 324 #     In other words, ld is default
 325 # --enable-gold=default --enable-ld=default
 326 #     Error.
 327
 328 default_ld=
 329 AC_ARG_ENABLE(gold,
 330 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 331                 [build gold @<:@ARG={default,yes,no}@:>@])],
 332 ENABLE_GOLD=$enableval,
 333 ENABLE_GOLD=no)
 334 case "${ENABLE_GOLD}" in
 335   yes|default)
 336     # Check for ELF target.
 337     is_elf=no
 338     case "${target}" in
 339       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 340       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 341       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 342       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 343         case "${target}" in
 344           *-*-linux*aout* | *-*-linux*oldld*)
 345             ;;
 346           *)
 347             is_elf=yes
 348             ;;
 349         esac
 350     esac
 351
 352     if test "$is_elf" = "yes"; then
 353       # Check for target supported by gold.
 354       case "${target}" in
 355         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 356         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 357           configdirs="$configdirs gold"
 358           if test x${ENABLE_GOLD} = xdefault; then
 359             default_ld=gold
 360           fi
 361           ENABLE_GOLD=yes
 362           ;;
 363       esac
 364     fi
 365     ;;
 366   no)
 367     ;;
 368   *)
 369     AC_MSG_ERROR([invalid --enable-gold argument])
 370     ;;
 371 esac
 372
 373 AC_ARG_ENABLE(ld,
 374 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 375                 [build ld @<:@ARG={default,yes,no}@:>@])],
 376 ENABLE_LD=$enableval,
 377 ENABLE_LD=yes)
 378
 379 case "${ENABLE_LD}" in
 380   default)
 381     if test x${default_ld} != x; then
 382       AC_MSG_ERROR([either gold or ld can be the default ld])
 383     fi
 384     ;;
 385   yes)
 386     ;;
 387   no)
 388     if test x${ENABLE_GOLD} != xyes; then
 389       AC_MSG_WARN([neither ld nor gold are enabled])
 390     fi
 391     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 392     ;;
 393   *)
 394     AC_MSG_ERROR([invalid --enable-ld argument])
 395     ;;
 396 esac
 397
 398 # PR gas/19109
 399 # Decide the default method for compressing debug sections.
 400 # Provide a configure time option to override our default.
 401 AC_ARG_ENABLE(compressed_debug_sections,
 402 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 403                 [Enable compressed debug sections for gas, gold or ld by
 404                  default])],
 405 [
 406   if test x"$enable_compressed_debug_sections" = xyes; then
 407     AC_MSG_ERROR([no program with compressed debug sections specified])
 408   fi
 409 ], [enable_compressed_debug_sections=])
 410
 411 # Configure extra directories which are host specific
 412
 413 case "${host}" in
 414   *-cygwin*)
 415     configdirs="$configdirs libtermcap" ;;
 416 esac
 417
 418 # A target can indicate whether a language isn't supported for some reason.
 419 # Only spaces may be used in this macro; not newlines or tabs.
 420 unsupported_languages=
 421
 422 # Remove more programs from consideration, based on the host or
 423 # target this usually means that a port of the program doesn't
 424 # exist yet.
 425
 426 case "${host}" in
 427   i[[3456789]]86-*-msdosdjgpp*)
 428     noconfigdirs="$noconfigdirs tcl tk itcl"
 429     ;;
 430 esac
 431
 432
 433 AC_ARG_ENABLE(libquadmath,
 434 AS_HELP_STRING([--disable-libquadmath],
 435   [do not build libquadmath directory]),
 436 ENABLE_LIBQUADMATH=$enableval,
 437 ENABLE_LIBQUADMATH=yes)
 438 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 439   noconfigdirs="$noconfigdirs target-libquadmath"
 440 fi
 441
 442
 443 AC_ARG_ENABLE(libquadmath-support,
 444 AS_HELP_STRING([--disable-libquadmath-support],
 445   [disable libquadmath support for Fortran]),
 446 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 447 ENABLE_LIBQUADMATH_SUPPORT=yes)
 448 enable_libquadmath_support=
 449 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 450   enable_libquadmath_support=no
 451 fi
 452
 453
 454 AC_ARG_ENABLE(libada,
 455 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 456 ENABLE_LIBADA=$enableval,
 457 ENABLE_LIBADA=yes)
 458 if test "${ENABLE_LIBADA}" != "yes" ; then
 459   noconfigdirs="$noconfigdirs gnattools"
 460 fi
 461
 462 AC_ARG_ENABLE(libssp,
 463 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 464 ENABLE_LIBSSP=$enableval,
 465 ENABLE_LIBSSP=yes)
 466
 467 AC_ARG_ENABLE(libstdcxx,
 468 AS_HELP_STRING([--disable-libstdcxx],
 469   [do not build libstdc++-v3 directory]),
 470 ENABLE_LIBSTDCXX=$enableval,
 471 ENABLE_LIBSTDCXX=default)
 472 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 473   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 474 fi]
 475
 476 # If this is accelerator compiler and its target is intelmic we enable
 477 # target liboffloadmic by default.  If this is compiler with offloading
 478 # for intelmic we enable host liboffloadmic by default.  Otherwise
 479 # liboffloadmic is disabled by default.
 480 AC_ARG_ENABLE([liboffloadmic],
 481 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 482                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 483 [case "$enableval" in
 484   no | host | target)
 485     enable_liboffloadmic=$enableval ;;
 486   *)
 487     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 488 esac],
 489 [if test x"$enable_as_accelerator_for" != x; then
 490   case "${target}" in
 491     *-intelmic-* | *-intelmicemul-*)
 492       enable_liboffloadmic=target
 493       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 494       ;;
 495     *)
 496       enable_liboffloadmic=no
 497       ;;
 498   esac
 499 else
 500   case "${enable_offload_targets}" in
 501     *-intelmic-* | *-intelmicemul-*)
 502       enable_liboffloadmic=host
 503       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 504       ;;
 505     *)
 506       enable_liboffloadmic=no
 507       ;;
 508     esac
 509 fi])
 510 AC_SUBST(extra_liboffloadmic_configure_flags)
 511
 512 # Enable libgomp by default on hosted POSIX systems, and a few others.
 513 if test x$enable_libgomp = x ; then
 514     case "${target}" in
 515     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 516         ;;
 517     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 518         ;;
 519     *-*-solaris2* | *-*-hpux11*)
 520         ;;
 521     *-*-darwin* | *-*-aix*)
 522         ;;
 523     nvptx*-*-* | amdgcn*-*-*)
 524         ;;
 525     *)
 526         noconfigdirs="$noconfigdirs target-libgomp"
 527         ;;
 528     esac
 529 fi
 530
 531 # Disable libatomic on unsupported systems.
 532 if test -d ${srcdir}/libatomic; then
 533     if test x$enable_libatomic = x; then
 534         AC_MSG_CHECKING([for libatomic support])
 535         if (srcdir=${srcdir}/libatomic; \
 536                 . ${srcdir}/configure.tgt; \
 537                 test -n "$UNSUPPORTED")
 538         then
 539             AC_MSG_RESULT([no])
 540             noconfigdirs="$noconfigdirs target-libatomic"
 541         else
 542             AC_MSG_RESULT([yes])
 543         fi
 544     fi
 545 fi
 546
 547 # Disable liboffloadmic on unsupported systems.
 548 if test -d ${srcdir}/liboffloadmic; then
 549     if test x$enable_liboffloadmic != xno; then
 550         AC_MSG_CHECKING([for liboffloadmic support])
 551         if (srcdir=${srcdir}/liboffloadmic; \
 552                 . ${srcdir}/configure.tgt; \
 553                 test -n "$UNSUPPORTED")
 554         then
 555             AC_MSG_RESULT([no])
 556             noconfigdirs="$noconfigdirs target-liboffloadmic"
 557         else
 558             AC_MSG_RESULT([yes])
 559         fi
 560     fi
 561 fi
 562
 563 # Disable libitm on unsupported systems.
 564 if test -d ${srcdir}/libitm; then
 565     if test x$enable_libitm = x; then
 566         AC_MSG_CHECKING([for libitm support])
 567         if (srcdir=${srcdir}/libitm; \
 568                 . ${srcdir}/configure.tgt; \
 569                 test -n "$UNSUPPORTED")
 570         then
 571             AC_MSG_RESULT([no])
 572             noconfigdirs="$noconfigdirs target-libitm"
 573         else
 574             AC_MSG_RESULT([yes])
 575         fi
 576     fi
 577 fi
 578
 579 # Disable libsanitizer on unsupported systems.
 580 if test -d ${srcdir}/libsanitizer; then
 581     if test x$enable_libsanitizer = x; then
 582         AC_MSG_CHECKING([for libsanitizer support])
 583         if (srcdir=${srcdir}/libsanitizer; \
 584                 . ${srcdir}/configure.tgt; \
 585                 test -n "$UNSUPPORTED")
 586         then
 587             AC_MSG_RESULT([no])
 588             noconfigdirs="$noconfigdirs target-libsanitizer"
 589         else
 590             AC_MSG_RESULT([yes])
 591         fi
 592     fi
 593 fi
 594
 595 # Disable libvtv on unsupported systems.
 596 if test -d ${srcdir}/libvtv; then
 597     if test x$enable_libvtv = x; then
 598         AC_MSG_CHECKING([for libvtv support])
 599         if (srcdir=${srcdir}/libvtv; \
 600                 . ${srcdir}/configure.tgt; \
 601                 test "$VTV_SUPPORTED" != "yes")
 602         then
 603             AC_MSG_RESULT([no])
 604             noconfigdirs="$noconfigdirs target-libvtv"
 605         else
 606             AC_MSG_RESULT([yes])
 607         fi
 608     fi
 609 fi
 610
 611 # Disable libquadmath for some systems.
 612 case "${target}" in
 613   avr-*-*)
 614     noconfigdirs="$noconfigdirs target-libquadmath"
 615     ;;
 616   # libquadmath is unused on AIX and libquadmath build process use of
 617   # LD_LIBRARY_PATH can break AIX bootstrap.
 618   powerpc-*-aix* | rs6000-*-aix*)
 619     noconfigdirs="$noconfigdirs target-libquadmath"
 620     ;;
 621 esac
 622
 623 # Disable libssp for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     # No hosted I/O support.
 627     noconfigdirs="$noconfigdirs target-libssp"
 628     ;;
 629   bpf-*-*)
 630     noconfigdirs="$noconfigdirs target-libssp"
 631     ;;
 632   powerpc-*-aix* | rs6000-*-aix*)
 633     noconfigdirs="$noconfigdirs target-libssp"
 634     ;;
 635   pru-*-*)
 636     # No hosted I/O support.
 637     noconfigdirs="$noconfigdirs target-libssp"
 638     ;;
 639   rl78-*-*)
 640     # libssp uses a misaligned load to trigger a fault, but the RL78
 641     # doesn't fault for those - instead, it gives a build-time error
 642     # for explicit misaligned loads.
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   visium-*-*)
 646     # No hosted I/O support.
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649 esac
 650
 651 # Disable libstdc++-v3 for some systems.
 652 # Allow user to override this if they pass --enable-libstdcxx
 653 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 654   case "${target}" in
 655     *-*-vxworks*)
 656       # VxWorks uses the Dinkumware C++ library.
 657       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 658       ;;
 659     amdgcn*-*-*)
 660       # Not ported/fails to build when using newlib.
 661       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 662       ;;
 663     arm*-wince-pe*)
 664       # the C++ libraries don't build on top of CE's C libraries
 665       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 666       ;;
 667     avr-*-*)
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     bpf-*-*)
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     ft32-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676   esac
 677 fi
 678
 679 # Disable C++ on systems where it is known to not work.
 680 # For testing, you can override this with --enable-languages=c++.
 681 case ,${enable_languages}, in
 682   *,c++,*)
 683     ;;
 684   *)
 685       case "${target}" in
 686         bpf-*-*)
 687           unsupported_languages="$unsupported_languages c++"
 688           ;;
 689       esac
 690       ;;
 691 esac
 692
 693 # Disable Objc on systems where it is known to not work.
 694 # For testing, you can override this with --enable-languages=objc.
 695 case ,${enable_languages}, in
 696   *,objc,*)
 697     ;;
 698   *)
 699       case "${target}" in
 700         bpf-*-*)
 701           unsupported_languages="$unsupported_languages objc"
 702           ;;
 703       esac
 704       ;;
 705 esac
 706
 707 # Disable D on systems where it is known to not work.
 708 # For testing, you can override this with --enable-languages=d.
 709 case ,${enable_languages}, in
 710   *,d,*)
 711     ;;
 712   *)
 713     case "${target}" in
 714       bpf-*-*)
 715         unsupported_languages="$unsupported_languages d"
 716         ;;
 717     esac
 718     ;;
 719 esac
 720
 721 # Disable libphobos on unsupported systems.
 722 # For testing, you can override this with --enable-libphobos.
 723 if test -d ${srcdir}/libphobos; then
 724     if test x$enable_libphobos = x; then
 725         AC_MSG_CHECKING([for libphobos support])
 726         if (srcdir=${srcdir}/libphobos; \
 727                 . ${srcdir}/configure.tgt; \
 728                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 729         then
 730             AC_MSG_RESULT([no])
 731             noconfigdirs="$noconfigdirs target-libphobos"
 732         else
 733             AC_MSG_RESULT([yes])
 734         fi
 735     fi
 736 fi
 737
 738 # Disable Fortran for some systems.
 739 case "${target}" in
 740   mmix-*-*)
 741     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 742     unsupported_languages="$unsupported_languages fortran"
 743     ;;
 744   bpf-*-*)
 745     unsupported_languages="$unsupported_languages fortran"
 746     ;;
 747 esac
 748
 749 # Disable libffi for some systems.
 750 case "${target}" in
 751   powerpc-*-darwin*)
 752     ;;
 753   i[[3456789]]86-*-darwin*)
 754     ;;
 755   x86_64-*-darwin[[912]]*)
 756     ;;
 757   *-*-darwin*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   *-*-netware*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   *-*-phoenix*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   *-*-rtems*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   *-*-tpf*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-uclinux*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   *-*-vxworks*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   aarch64*-*-freebsd*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   alpha*-*-*vms*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   arm*-*-freebsd*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   arm-wince-pe)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   arm*-*-symbianelf*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   bpf-*-*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   cris-*-* | crisv32-*-*)
 797     case "${target}" in
 798       *-*-linux*)
 799         ;;
 800       *) # See PR46792 regarding target-libffi.
 801         noconfigdirs="$noconfigdirs target-libffi";;
 802     esac
 803     ;;
 804   hppa*64*-*-hpux*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   hppa*-hp-hpux11*)
 808     ;;
 809   hppa*-*-hpux*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   ia64*-*-*vms*)
 813     noconfigdirs="$noconfigdirs target-libffi"
 814     ;;
 815   i[[3456789]]86-w64-mingw*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   i[[3456789]]86-*-mingw*)
 819     noconfigdirs="$noconfigdirs target-libffi"
 820     ;;
 821   x86_64-*-mingw*)
 822     noconfigdirs="$noconfigdirs target-libffi"
 823     ;;
 824   mmix-*-*)
 825     noconfigdirs="$noconfigdirs target-libffi"
 826     ;;
 827   powerpc-*-aix*)
 828     ;;
 829   rs6000-*-aix*)
 830     ;;
 831   ft32-*-*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   *-*-lynxos*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837 esac
 838
 839 # Disable the go frontend on systems where it is known to not work. Please keep
 840 # this in sync with contrib/config-list.mk.
 841 case "${target}" in
 842 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 843     unsupported_languages="$unsupported_languages go"
 844     ;;
 845 esac
 846
 847 # Only allow gdbserver on some systems.
 848 if test -d ${srcdir}/gdbserver; then
 849     if test x$enable_gdbserver = x; then
 850         AC_MSG_CHECKING([for gdbserver support])
 851         if (srcdir=${srcdir}/gdbserver; \
 852                 . ${srcdir}/configure.srv; \
 853                 test -n "$UNSUPPORTED")
 854         then
 855             AC_MSG_RESULT([no])
 856             noconfigdirs="$noconfigdirs gdbserver"
 857         else
 858             AC_MSG_RESULT([yes])
 859         fi
 860     fi
 861 fi
 862
 863 # Disable libgo for some systems where it is known to not work.
 864 # For testing, you can easily override this with --enable-libgo.
 865 if test x$enable_libgo = x; then
 866     case "${target}" in
 867     *-*-darwin*)
 868         # PR 46986
 869         noconfigdirs="$noconfigdirs target-libgo"
 870         ;;
 871     *-*-cygwin* | *-*-mingw*)
 872         noconfigdirs="$noconfigdirs target-libgo"
 873         ;;
 874     bpf-*-*)
 875         noconfigdirs="$noconfigdirs target-libgo"
 876         ;;
 877     esac
 878 fi
 879
 880 # Default libgloss CPU subdirectory.
 881 libgloss_dir="$target_cpu"
 882
 883 case "${target}" in
 884   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 885     libgloss_dir=wince
 886     ;;
 887   aarch64*-*-* )
 888     libgloss_dir=aarch64
 889     ;;
 890   arm*-*-*)
 891     libgloss_dir=arm
 892     ;;
 893   cris-*-* | crisv32-*-*)
 894     libgloss_dir=cris
 895     ;;
 896   hppa*-*-*)
 897     libgloss_dir=pa
 898     ;;
 899   i[[3456789]]86-*-*)
 900     libgloss_dir=i386
 901     ;;
 902   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 903     libgloss_dir=m68hc11
 904     ;;
 905   m68*-*-* | fido-*-*)
 906     libgloss_dir=m68k
 907     ;;
 908   mips*-*-*)
 909     libgloss_dir=mips
 910     ;;
 911   powerpc*-*-*)
 912     libgloss_dir=rs6000
 913     ;;
 914   pru-*-*)
 915     libgloss_dir=pru
 916     ;;
 917   sparc*-*-*)
 918     libgloss_dir=sparc
 919     ;;
 920 esac
 921
 922 # Disable newlib and libgloss for various target OSes.
 923 case "${target}" in
 924   alpha*-dec-osf*)
 925     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 926     ;;
 927   i[[3456789]]86-*-linux*)
 928     # This section makes it possible to build newlib natively on linux.
 929     # If we are using a cross compiler then don't configure newlib.
 930     if test x${is_cross_compiler} != xno ; then
 931       noconfigdirs="$noconfigdirs target-newlib"
 932     fi
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     # If we are not using a cross compiler, do configure newlib.
 935     # Note however, that newlib will only be configured in this situation
 936     # if the --with-newlib option has been given, because otherwise
 937     # 'target-newlib' will appear in skipdirs.
 938     ;;
 939   i[[3456789]]86-*-rdos*)
 940     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 941     ;;
 942   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 943     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 944     ;;
 945   sparc-*-sunos4*)
 946     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 947     ;;
 948   bpf-*-*)
 949     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 950     ;;
 951   *-*-aix*)
 952     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 953     ;;
 954   *-*-beos*)
 955     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 956     ;;
 957   *-*-chorusos)
 958     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 959     ;;
 960   *-*-dragonfly*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   *-*-freebsd*)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   *-*-lynxos*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-mingw*)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-netbsd*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-netware*)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-tpf*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-uclinux*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-vxworks*)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990 esac
 991
 992 case "${target}" in
 993   *-*-chorusos)
 994     ;;
 995   aarch64-*-darwin*)
 996     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 997     noconfigdirs="$noconfigdirs sim target-rda"
 998     ;;
 999   amdgcn*-*-*)
1000     ;;
1001   arm-*-darwin*)
1002     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1003     noconfigdirs="$noconfigdirs sim target-rda"
1004     ;;
1005   powerpc-*-darwin*)
1006     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1007     noconfigdirs="$noconfigdirs sim target-rda"
1008     ;;
1009   i[[3456789]]86-*-darwin*)
1010     noconfigdirs="$noconfigdirs ld gprof"
1011     noconfigdirs="$noconfigdirs sim target-rda"
1012     ;;
1013   x86_64-*-darwin[[912]]*)
1014     noconfigdirs="$noconfigdirs ld gas gprof"
1015     noconfigdirs="$noconfigdirs sim target-rda"
1016     ;;
1017   *-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   *-*-dragonfly*)
1022     ;;
1023   *-*-freebsd*)
1024     if test "x$with_gmp" = x \
1025         && ! test -d ${srcdir}/gmp \
1026         && test -f /usr/local/include/gmp.h; then
1027       with_gmp=/usr/local
1028     fi
1029     ;;
1030   *-*-kaos*)
1031     # Remove unsupported stuff on all kaOS configurations.
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   *-*-netbsd*)
1035     ;;
1036   *-*-netware*)
1037     ;;
1038   *-*-phoenix*)
1039     noconfigdirs="$noconfigdirs target-libgloss"
1040     ;;
1041   *-*-rtems*)
1042     noconfigdirs="$noconfigdirs target-libgloss"
1043     ;;
1044     # The tpf target doesn't support gdb yet.
1045   *-*-tpf*)
1046     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1047     ;;
1048   *-*-uclinux*)
1049     noconfigdirs="$noconfigdirs target-rda"
1050     ;;
1051   *-*-vxworks*)
1052     ;;
1053   alpha*-dec-osf*)
1054     # ld works, but does not support shared libraries.
1055     # gas doesn't generate exception information.
1056     noconfigdirs="$noconfigdirs gas ld"
1057     ;;
1058   alpha*-*-*vms*)
1059     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1060     ;;
1061   alpha*-*-*)
1062     # newlib is not 64 bit ready
1063     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1064     ;;
1065   bpf-*-*)
1066     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1067     ;;
1068   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1069     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1070     ;;
1071   arc*-*-*)
1072     noconfigdirs="$noconfigdirs sim"
1073     ;;
1074   arm-*-pe*)
1075     noconfigdirs="$noconfigdirs target-libgloss"
1076     ;;
1077   arm-*-riscix*)
1078     noconfigdirs="$noconfigdirs ld target-libgloss"
1079     ;;
1080   avr-*-*)
1081     if test x${with_avrlibc} != xno; then
1082       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1083     fi
1084     ;;
1085   c4x-*-* | tic4x-*-*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   tic54x-*-*)
1089     noconfigdirs="$noconfigdirs target-libgloss gdb"
1090     ;;
1091   d10v-*-*)
1092     noconfigdirs="$noconfigdirs target-libgloss"
1093     ;;
1094   d30v-*-*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   fr30-*-elf*)
1098     noconfigdirs="$noconfigdirs gdb"
1099     ;;
1100   ft32-*-*)
1101     noconfigdirs="$noconfigdirs target-rda gprof"
1102     ;;
1103   moxie-*-*)
1104     noconfigdirs="$noconfigdirs"
1105     ;;
1106   h8300*-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   h8500-*-*)
1110     noconfigdirs="$noconfigdirs target-libgloss"
1111     ;;
1112   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1113     ;;
1114   hppa*64*-*-hpux*)
1115     noconfigdirs="$noconfigdirs gdb"
1116     ;;
1117   hppa*-*-hpux11*)
1118     noconfigdirs="$noconfigdirs gdb ld"
1119     ;;
1120   hppa*64*-*-linux*)
1121     ;;
1122   hppa*-*-linux*)
1123     ;;
1124   hppa*-*-*elf* | \
1125   hppa*-*-lites* | \
1126   hppa*-*-openbsd* | \
1127   hppa*64*-*-*)
1128     ;;
1129   hppa*-*-pro*)
1130     ;;
1131   hppa*-*-*)
1132     noconfigdirs="$noconfigdirs ld"
1133     ;;
1134   i960-*-*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   ia64*-*-elf*)
1138     # No gdb support yet.
1139     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1140     ;;
1141   ia64*-**-hpux*)
1142     # No ld support yet.
1143     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1144     ;;
1145   ia64*-*-*vms*)
1146     # No ld support yet.
1147     noconfigdirs="$noconfigdirs libgui itcl ld"
1148     ;;
1149   i[[3456789]]86-w64-mingw*)
1150     ;;
1151   i[[3456789]]86-*-mingw*)
1152     target_configdirs="$target_configdirs target-winsup"
1153     ;;
1154   *-*-cygwin*)
1155     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1156     noconfigdirs="$noconfigdirs target-libgloss"
1157     # always build newlib if winsup directory is present.
1158     if test -d "$srcdir/winsup/cygwin"; then
1159       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1160     elif test -d "$srcdir/newlib"; then
1161       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1162     fi
1163     ;;
1164   i[[3456789]]86-*-pe)
1165     noconfigdirs="$noconfigdirs target-libgloss"
1166     ;;
1167   i[[3456789]]86-*-sco3.2v5*)
1168     # The linker does not yet know about weak symbols in COFF,
1169     # and is not configured to handle mixed ELF and COFF.
1170     noconfigdirs="$noconfigdirs ld target-libgloss"
1171     ;;
1172   i[[3456789]]86-*-sco*)
1173     noconfigdirs="$noconfigdirs gprof target-libgloss"
1174     ;;
1175   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1176     noconfigdirs="$noconfigdirs target-libgloss"
1177     ;;
1178   i[[3456789]]86-*-sysv4*)
1179     noconfigdirs="$noconfigdirs target-libgloss"
1180     ;;
1181   i[[3456789]]86-*-beos*)
1182     noconfigdirs="$noconfigdirs gdb"
1183     ;;
1184   i[[3456789]]86-*-rdos*)
1185     noconfigdirs="$noconfigdirs gdb"
1186     ;;
1187   mmix-*-*)
1188     noconfigdirs="$noconfigdirs gdb"
1189     ;;
1190   mt-*-*)
1191     noconfigdirs="$noconfigdirs sim"
1192     ;;
1193   nfp-*-*)
1194     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1195     noconfigdirs="$noconfigdirs $target_libraries"
1196     ;;
1197   pdp11-*-*)
1198     noconfigdirs="$noconfigdirs gdb gprof"
1199     ;;
1200   powerpc-*-aix*)
1201     # copied from rs6000-*-* entry
1202     noconfigdirs="$noconfigdirs gprof"
1203     ;;
1204   powerpc*-*-winnt* | powerpc*-*-pe*)
1205     target_configdirs="$target_configdirs target-winsup"
1206     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1207     # always build newlib.
1208     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1209     ;;
1210     # This is temporary until we can link against shared libraries
1211   powerpcle-*-solaris*)
1212     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1213     ;;
1214   powerpc-*-beos*)
1215     noconfigdirs="$noconfigdirs gdb"
1216     ;;
1217   rs6000-*-lynxos*)
1218     noconfigdirs="$noconfigdirs gprof"
1219     ;;
1220   rs6000-*-aix*)
1221     noconfigdirs="$noconfigdirs gprof"
1222     ;;
1223   rs6000-*-*)
1224     noconfigdirs="$noconfigdirs gprof"
1225     ;;
1226   m68k-apollo-*)
1227     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1228     ;;
1229   microblaze*)
1230     noconfigdirs="$noconfigdirs gprof"
1231     ;;
1232   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1233     if test x$with_newlib = xyes; then
1234       noconfigdirs="$noconfigdirs gprof"
1235     fi
1236     ;;
1237   mips*-*-irix5*)
1238     noconfigdirs="$noconfigdirs gprof target-libgloss"
1239     ;;
1240   mips*-*-irix6*)
1241     noconfigdirs="$noconfigdirs gprof target-libgloss"
1242     ;;
1243   mips*-*-bsd*)
1244     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1245     ;;
1246   mips*-*-linux*)
1247     ;;
1248   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1249   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1250     noconfigdirs="$noconfigdirs ld gas gprof"
1251     ;;
1252   mips*-*-*)
1253     noconfigdirs="$noconfigdirs gprof"
1254     ;;
1255   nvptx*-*-*)
1256     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1257     ;;
1258   sh-*-*)
1259     case "${target}" in
1260       sh*-*-elf)
1261          ;;
1262       *)
1263          noconfigdirs="$noconfigdirs target-libgloss" ;;
1264     esac
1265     ;;
1266   sparc-*-sunos4*)
1267     if test x${is_cross_compiler} = xno ; then
1268            use_gnu_ld=no
1269     fi
1270     ;;
1271   tic6x-*-*)
1272     noconfigdirs="$noconfigdirs sim"
1273     ;;
1274   tilepro*-*-* | tilegx*-*-*)
1275     noconfigdirs="$noconfigdirs sim"
1276     ;;
1277   v810-*-*)
1278     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1279     ;;
1280   vax-*-*)
1281     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1282     ;;
1283   wasm32-*-*)
1284     noconfigdirs="$noconfigdirs ld"
1285     ;;
1286 esac
1287
1288 # If we aren't building newlib, then don't build libgloss, since libgloss
1289 # depends upon some newlib header files.
1290 case "${noconfigdirs}" in
1291   *target-libgloss*) ;;
1292   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1293 esac
1294
1295 # Work in distributions that contain no compiler tools, like Autoconf.
1296 host_makefile_frag=/dev/null
1297 if test -d ${srcdir}/config ; then
1298 case "${host}" in
1299   i[[3456789]]86-*-msdosdjgpp*)
1300     host_makefile_frag="config/mh-djgpp"
1301     ;;
1302   *-cygwin*)
1303     ACX_CHECK_CYGWIN_CAT_WORKS
1304     host_makefile_frag="config/mh-cygwin"
1305     ;;
1306   *-mingw*)
1307     host_makefile_frag="config/mh-mingw"
1308     ;;
1309   alpha*-linux*)
1310     host_makefile_frag="config/mh-alpha-linux"
1311     ;;
1312   hppa*-hp-hpux10*)
1313     host_makefile_frag="config/mh-pa-hpux10"
1314     ;;
1315   hppa*-hp-hpux*)
1316     host_makefile_frag="config/mh-pa"
1317     ;;
1318   hppa*-*)
1319     host_makefile_frag="config/mh-pa"
1320     ;;
1321   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1322     host_makefile_frag="config/mh-darwin"
1323     ;;
1324   powerpc-*-aix*)
1325     host_makefile_frag="config/mh-ppc-aix"
1326     ;;
1327   rs6000-*-aix*)
1328     host_makefile_frag="config/mh-ppc-aix"
1329     ;;
1330 esac
1331 fi
1332
1333 if test "${build}" != "${host}" ; then
1334   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1335   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1336   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1337   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1338   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1339   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1340   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1341   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1342   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1343   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1344   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1345   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1346   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1347   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1348   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1349 else
1350   AR_FOR_BUILD="\$(AR)"
1351   AS_FOR_BUILD="\$(AS)"
1352   CC_FOR_BUILD="\$(CC)"
1353   CXX_FOR_BUILD="\$(CXX)"
1354   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1355   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1356   GOC_FOR_BUILD="\$(GOC)"
1357   GDC_FOR_BUILD="\$(GDC)"
1358   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1359   LD_FOR_BUILD="\$(LD)"
1360   NM_FOR_BUILD="\$(NM)"
1361   RANLIB_FOR_BUILD="\$(RANLIB)"
1362   WINDRES_FOR_BUILD="\$(WINDRES)"
1363   WINDMC_FOR_BUILD="\$(WINDMC)"
1364 fi
1365
1366 AC_PROG_CC_C99
1367 AC_PROG_CXX
1368
1369 # We must set the default linker to the linker used by gcc for the correct
1370 # operation of libtool.  If LD is not defined and we are using gcc, try to
1371 # set the LD default to the ld used by gcc.
1372 if test -z "$LD"; then
1373   if test "$GCC" = yes; then
1374     case $build in
1375     *-*-mingw*)
1376       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1377     *)
1378       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1379     esac
1380     case $gcc_prog_ld in
1381     # Accept absolute paths.
1382     [[\\/]* | [A-Za-z]:[\\/]*)]
1383       LD="$gcc_prog_ld" ;;
1384     esac
1385   fi
1386 fi
1387
1388 # Check whether -static-libstdc++ -static-libgcc is supported.
1389 have_static_libs=no
1390 if test "$GCC" = yes; then
1391   saved_LDFLAGS="$LDFLAGS"
1392
1393   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1394   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1395   AC_LANG_PUSH(C++)
1396   AC_LINK_IFELSE([AC_LANG_SOURCE([
1397 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1398 #error -static-libstdc++ not implemented
1399 #endif
1400 int main() {}])],
1401     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1402     [AC_MSG_RESULT([no])])
1403   AC_LANG_POP(C++)
1404
1405   LDFLAGS="$saved_LDFLAGS"
1406 fi
1407
1408 ACX_PROG_GNAT
1409 ACX_PROG_GDC
1410 ACX_PROG_CMP_IGNORE_INITIAL
1411
1412 AC_ARG_ENABLE([bootstrap],
1413 [AS_HELP_STRING([--enable-bootstrap],
1414                 [enable bootstrapping @<:@yes if native build@:>@])],,
1415 enable_bootstrap=default)
1416
1417 # Issue errors and warnings for invalid/strange bootstrap combinations.
1418 if test -r $srcdir/gcc/configure; then
1419   have_compiler=yes
1420 else
1421   have_compiler=no
1422 fi
1423
1424 case "$have_compiler:$host:$target:$enable_bootstrap" in
1425   *:*:*:no) ;;
1426
1427   # Default behavior.  Enable bootstrap if we have a compiler
1428   # and we are in a native configuration.
1429   yes:$build:$build:default)
1430     enable_bootstrap=yes ;;
1431
1432   *:*:*:default)
1433     enable_bootstrap=no ;;
1434
1435   # We have a compiler and we are in a native configuration, bootstrap is ok
1436   yes:$build:$build:yes)
1437     ;;
1438
1439   # Other configurations, but we have a compiler.  Assume the user knows
1440   # what he's doing.
1441   yes:*:*:yes)
1442     AC_MSG_WARN([trying to bootstrap a cross compiler])
1443     ;;
1444
1445   # No compiler: if they passed --enable-bootstrap explicitly, fail
1446   no:*:*:yes)
1447     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1448
1449   # Fail if wrong command line
1450   *)
1451     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1452     ;;
1453 esac
1454
1455 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1456 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1457 # require C++11 (or higher).
1458 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1459   CXX="$CXX -std=c++11"
1460 elif test "$have_compiler" = yes; then
1461   AX_CXX_COMPILE_STDCXX(11)
1462
1463   if test "${build}" != "${host}"; then
1464     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1465   fi
1466 fi
1467
1468 AC_ARG_ENABLE([pgo-build],
1469 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1470                 [enable the PGO build])],
1471 [enable_pgo_build=$enableval],
1472 [enable_pgo_build=no])
1473
1474 # Issue errors and warnings for invalid/strange PGO build combinations.
1475 case "$have_compiler:$host:$target:$enable_pgo_build" in
1476   *:*:*:no) ;;
1477
1478   # Allow the PGO build only if we aren't building a compiler and
1479   # we are in a native configuration.
1480   no:$build:$build:yes | no:$build:$build:lto) ;;
1481
1482   # Disallow the PGO bootstrap if we are building a compiler.
1483   yes:*:*:yes | yes:*:*:lto)
1484     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1485
1486   *)
1487     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1488     ;;
1489 esac
1490
1491 if test "$enable_pgo_build" != "no"; then
1492   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1493   old_CFLAGS="$CFLAGS"
1494   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1495   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1496   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1497                     [PGO_BUILD_GEN_CFLAGS=])
1498   CFLAGS="$old_CFLAGS"
1499   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1500     AC_MSG_RESULT([yes])
1501     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1502   else
1503     AC_MSG_RESULT([no])
1504     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1505   fi
1506
1507   if test "$enable_pgo_build" = "lto"; then
1508     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1509     old_CFLAGS="$CFLAGS"
1510     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1511     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1512     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1513                       [PGO_BUILD_LTO_CFLAGS=])
1514     CFLAGS="$old_CFLAGS"
1515     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1516       AC_MSG_RESULT([yes])
1517     else
1518       AC_MSG_RESULT([no])
1519       AC_MSG_WARN([LTO is disabled for the PGO build])
1520     fi
1521   fi
1522 fi
1523 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1524 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1525 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1526
1527 # Used for setting $lt_cv_objdir
1528 _LT_CHECK_OBJDIR
1529
1530 # Check for GMP, MPFR and MPC
1531 gmplibs="-lmpc -lmpfr -lgmp"
1532 gmpinc=
1533 have_gmp=no
1534
1535 # Specify a location for mpc
1536 # check for this first so it ends up on the link line before mpfr.
1537 AC_ARG_WITH(mpc,
1538 [AS_HELP_STRING([--with-mpc=PATH],
1539                 [specify prefix directory for installed MPC package.
1540                  Equivalent to --with-mpc-include=PATH/include
1541                  plus --with-mpc-lib=PATH/lib])])
1542 AC_ARG_WITH(mpc-include,
1543 [AS_HELP_STRING([--with-mpc-include=PATH],
1544                 [specify directory for installed MPC include files])])
1545 AC_ARG_WITH(mpc-lib,
1546 [AS_HELP_STRING([--with-mpc-lib=PATH],
1547                 [specify directory for the installed MPC library])])
1548
1549 if test "x$with_mpc" != x; then
1550   gmplibs="-L$with_mpc/lib $gmplibs"
1551   gmpinc="-I$with_mpc/include $gmpinc"
1552 fi
1553 if test "x$with_mpc_include" != x; then
1554   gmpinc="-I$with_mpc_include $gmpinc"
1555 fi
1556 if test "x$with_mpc_lib" != x; then
1557   gmplibs="-L$with_mpc_lib $gmplibs"
1558 fi
1559 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1560   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1561   gmpinc='-I$$s/mpc/src '"$gmpinc"
1562   # Do not test the mpc version.  Assume that it is sufficient, since
1563   # it is in the source tree, and the library has not been built yet
1564   # but it would be included on the link line in the version check below
1565   # hence making the test fail.
1566   have_gmp=yes
1567 fi
1568
1569 # Specify a location for mpfr
1570 # check for this first so it ends up on the link line before gmp.
1571 AC_ARG_WITH(mpfr,
1572 [AS_HELP_STRING([--with-mpfr=PATH],
1573                 [specify prefix directory for installed MPFR package.
1574                  Equivalent to --with-mpfr-include=PATH/include
1575                  plus --with-mpfr-lib=PATH/lib])])
1576 AC_ARG_WITH(mpfr-include,
1577 [AS_HELP_STRING([--with-mpfr-include=PATH],
1578                 [specify directory for installed MPFR include files])])
1579 AC_ARG_WITH(mpfr-lib,
1580 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1581                 [specify directory for the installed MPFR library])])
1582
1583 if test "x$with_mpfr" != x; then
1584   gmplibs="-L$with_mpfr/lib $gmplibs"
1585   gmpinc="-I$with_mpfr/include $gmpinc"
1586 fi
1587 if test "x$with_mpfr_include" != x; then
1588   gmpinc="-I$with_mpfr_include $gmpinc"
1589 fi
1590 if test "x$with_mpfr_lib" != x; then
1591   gmplibs="-L$with_mpfr_lib $gmplibs"
1592 fi
1593 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1594   # MPFR v3.1.0 moved the sources into a src sub-directory.
1595   if ! test -d ${srcdir}/mpfr/src; then
1596     AC_MSG_ERROR([dnl
1597 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1598   fi
1599   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1600   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1601   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1602   # Do not test the mpfr version.  Assume that it is sufficient, since
1603   # it is in the source tree, and the library has not been built yet
1604   # but it would be included on the link line in the version check below
1605   # hence making the test fail.
1606   have_gmp=yes
1607 fi
1608
1609 # Specify a location for gmp
1610 AC_ARG_WITH(gmp,
1611 [AS_HELP_STRING([--with-gmp=PATH],
1612                 [specify prefix directory for the installed GMP package.
1613                  Equivalent to --with-gmp-include=PATH/include
1614                  plus --with-gmp-lib=PATH/lib])])
1615 AC_ARG_WITH(gmp-include,
1616 [AS_HELP_STRING([--with-gmp-include=PATH],
1617                 [specify directory for installed GMP include files])])
1618 AC_ARG_WITH(gmp-lib,
1619 [AS_HELP_STRING([--with-gmp-lib=PATH],
1620                 [specify directory for the installed GMP library])])
1621
1622
1623 if test "x$with_gmp" != x; then
1624   gmplibs="-L$with_gmp/lib $gmplibs"
1625   gmpinc="-I$with_gmp/include $gmpinc"
1626 fi
1627 if test "x$with_gmp_include" != x; then
1628   gmpinc="-I$with_gmp_include $gmpinc"
1629 fi
1630 if test "x$with_gmp_lib" != x; then
1631   gmplibs="-L$with_gmp_lib $gmplibs"
1632 fi
1633 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1634   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1635   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1636   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1637   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1638   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1639   # Do not test the gmp version.  Assume that it is sufficient, since
1640   # it is in the source tree, and the library has not been built yet
1641   # but it would be included on the link line in the version check below
1642   # hence making the test fail.
1643   have_gmp=yes
1644 fi
1645
1646 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1647   have_gmp=yes
1648   saved_CFLAGS="$CFLAGS"
1649   CFLAGS="$CFLAGS $gmpinc"
1650   # Check for the recommended and required versions of GMP.
1651   AC_MSG_CHECKING([for the correct version of gmp.h])
1652   AC_TRY_COMPILE([#include "gmp.h"],[
1653   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1654   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1655   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1656   choke me
1657   #endif
1658   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1659   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1660   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1661   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1662   choke me
1663   #endif
1664   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1665    [AC_MSG_RESULT([no]); have_gmp=no])
1666
1667   # If we have GMP, check the MPFR version.
1668   if test x"$have_gmp" = xyes; then
1669     # Check for the recommended and required versions of MPFR.
1670     AC_MSG_CHECKING([for the correct version of mpfr.h])
1671     AC_TRY_COMPILE([#include <gmp.h>
1672     #include <mpfr.h>],[
1673     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1674     choke me
1675     #endif
1676     ], [AC_TRY_COMPILE([#include <gmp.h>
1677     #include <mpfr.h>],[
1678     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1679     choke me
1680     #endif
1681     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1682      [AC_MSG_RESULT([no]); have_gmp=no])
1683   fi
1684
1685   # Check for the MPC header version.
1686   if test x"$have_gmp" = xyes ; then
1687     # Check for the recommended and required versions of MPC.
1688     AC_MSG_CHECKING([for the correct version of mpc.h])
1689     AC_TRY_COMPILE([#include <mpc.h>],[
1690     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1691     choke me
1692     #endif
1693     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1694     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1695     choke me
1696     #endif
1697     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1698      [AC_MSG_RESULT([no]); have_gmp=no])
1699   fi
1700
1701   # Now check the MPFR library.
1702   if test x"$have_gmp" = xyes; then
1703     saved_LIBS="$LIBS"
1704     LIBS="$LIBS $gmplibs"
1705     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1706     AC_TRY_LINK([#include <mpc.h>],[
1707     mpfr_t n;
1708     mpfr_t x;
1709     mpc_t c;
1710     int t;
1711     mpfr_init (n);
1712     mpfr_init (x);
1713     mpfr_atan2 (n, n, x, MPFR_RNDN);
1714     mpfr_erfc (n, x, MPFR_RNDN);
1715     mpfr_subnormalize (x, t, MPFR_RNDN);
1716     mpfr_clear(n);
1717     mpfr_clear(x);
1718     mpc_init2 (c, 53);
1719     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1720     mpc_cosh (c, c, MPC_RNDNN);
1721     mpc_pow (c, c, c, MPC_RNDNN);
1722     mpc_acosh (c, c, MPC_RNDNN);
1723     mpc_clear (c);
1724     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1725     LIBS="$saved_LIBS"
1726   fi
1727
1728   CFLAGS="$saved_CFLAGS"
1729
1730 # The library versions listed in the error message below should match
1731 # the HARD-minimums enforced above.
1732   if test x$have_gmp != xyes; then
1733     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1734 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1735 their locations.  Source code for these libraries can be found at
1736 their respective hosting sites as well as at
1737 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1738 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1739 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1740 make sure that you have installed both the libraries and the header
1741 files.  They may be located in separate packages.])
1742   fi
1743 fi
1744
1745 # Flags needed for both GMP, MPFR and/or MPC.
1746 AC_SUBST(gmplibs)
1747 AC_SUBST(gmpinc)
1748 AC_SUBST(extra_mpfr_configure_flags)
1749 AC_SUBST(extra_mpc_gmp_configure_flags)
1750 AC_SUBST(extra_mpc_mpfr_configure_flags)
1751 AC_SUBST(extra_isl_gmp_configure_flags)
1752
1753 # Libraries to use for stage1 or when not bootstrapping.
1754 AC_ARG_WITH(stage1-libs,
1755 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1756 [if test "$withval" = "no" -o "$withval" = "yes"; then
1757    stage1_libs=
1758  else
1759    stage1_libs=$withval
1760  fi],
1761 [stage1_libs=])
1762 AC_SUBST(stage1_libs)
1763
1764 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1765 # default is yes if gcc is being built; no otherwise.  The reason for
1766 # this default is that gdb is sometimes linked against GNU Source
1767 # Highlight, which is a shared library that uses C++ exceptions.  In
1768 # this case, -static-libstdc++ will cause crashes.
1769 AC_ARG_WITH(static-standard-libraries,
1770 [AS_HELP_STRING([--with-static-standard-libraries],
1771                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1772 [], [with_static_standard_libraries=auto])
1773 if test "$with_static_standard_libraries" = auto; then
1774   with_static_standard_libraries=$have_compiler
1775 fi
1776
1777 # Linker flags to use for stage1 or when not bootstrapping.
1778 AC_ARG_WITH(stage1-ldflags,
1779 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1780 [if test "$withval" = "no" -o "$withval" = "yes"; then
1781    stage1_ldflags=
1782  else
1783    stage1_ldflags=$withval
1784  fi],
1785 [stage1_ldflags=
1786  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1787  # if supported.  But if the user explicitly specified the libraries to use,
1788  # trust that they are doing what they want.
1789  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1790      -a "$have_static_libs" = yes; then
1791    stage1_ldflags="-static-libstdc++ -static-libgcc"
1792  fi])
1793 AC_SUBST(stage1_ldflags)
1794
1795 # Libraries to use for stage2 and later builds.
1796 AC_ARG_WITH(boot-libs,
1797 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1798 [if test "$withval" = "no" -o "$withval" = "yes"; then
1799    poststage1_libs=
1800  else
1801    poststage1_libs=$withval
1802  fi],
1803 [poststage1_libs=])
1804 AC_SUBST(poststage1_libs)
1805
1806 # Linker flags to use for stage2 and later builds.
1807 AC_ARG_WITH(boot-ldflags,
1808 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1809                 [linker flags for stage2 and later])],
1810 [if test "$withval" = "no" -o "$withval" = "yes"; then
1811    poststage1_ldflags=
1812  else
1813    poststage1_ldflags=$withval
1814  fi],
1815 [poststage1_ldflags=
1816  # In stages 2 and 3, default to linking libstdc++ and libgcc
1817  # statically.  But if the user explicitly specified the libraries to
1818  # use, trust that they are doing what they want.
1819  if test "$poststage1_libs" = ""; then
1820    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1821  fi])
1822 AC_SUBST(poststage1_ldflags)
1823
1824 # GCC GRAPHITE dependency isl.
1825 # Basic setup is inlined here, actual checks are in config/isl.m4
1826
1827 AC_ARG_WITH(isl,
1828   [AS_HELP_STRING(
1829    [--with-isl=PATH],
1830    [Specify prefix directory for the installed isl package.
1831     Equivalent to --with-isl-include=PATH/include
1832     plus --with-isl-lib=PATH/lib])])
1833
1834 # Treat --without-isl as a request to disable
1835 # GRAPHITE support and skip all following checks.
1836 if test "x$with_isl" != "xno"; then
1837   # Check for isl
1838   dnl Provide configure switches and initialize islinc & isllibs
1839   dnl with user input.
1840   ISL_INIT_FLAGS
1841   dnl The versions of isl that work for Graphite
1842   ISL_CHECK_VERSION()
1843   dnl Only execute fail-action, if isl has been requested.
1844   ISL_IF_FAILED([
1845     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1846 fi
1847
1848 # If the isl check failed, disable builds of in-tree variant of isl
1849 if test "x$with_isl" = xno ||
1850    test "x$gcc_cv_isl" = xno; then
1851   noconfigdirs="$noconfigdirs isl"
1852   islinc=
1853 fi
1854
1855 AC_SUBST(isllibs)
1856 AC_SUBST(islinc)
1857
1858 # Check for LTO support.
1859 AC_ARG_ENABLE(lto,
1860 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1861 enable_lto=$enableval,
1862 enable_lto=yes; default_enable_lto=yes)
1863
1864 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1865   build_lto_plugin=yes
1866 ],[if test x"$default_enable_lto" = x"yes" ; then
1867     case $target in
1868       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1869       # On other non-ELF platforms, LTO has yet to be validated.
1870       *) enable_lto=no ;;
1871     esac
1872   else
1873   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1874   # It would also be nice to check the binutils support, but we don't
1875   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1876   # warn during gcc/ subconfigure; unless you're bootstrapping with
1877   # -flto it won't be needed until after installation anyway.
1878     case $target in
1879       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1880       *) if test x"$enable_lto" = x"yes"; then
1881         AC_MSG_ERROR([LTO support is not enabled for this target.])
1882         fi
1883       ;;
1884     esac
1885   fi
1886   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1887   # Build it unless LTO was explicitly disabled.
1888   case $target in
1889     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1890     *) ;;
1891   esac
1892 ])
1893
1894 AC_ARG_ENABLE(linker-plugin-configure-flags,
1895   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1896     [additional flags for configuring linker plugins @<:@none@:>@])],
1897   extra_linker_plugin_configure_flags=$enableval,
1898   extra_linker_plugin_configure_flags=)
1899 AC_SUBST(extra_linker_plugin_configure_flags)
1900 AC_ARG_ENABLE(linker-plugin-flags,
1901   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1902     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1903   extra_linker_plugin_flags=$enableval,
1904   extra_linker_plugin_flags=)
1905 AC_SUBST(extra_linker_plugin_flags)
1906
1907 # Enable --enable-host-shared.
1908 # Checked early to determine whether jit is an 'all' language
1909 AC_ARG_ENABLE(host-shared,
1910 [AS_HELP_STRING([--enable-host-shared],
1911                 [build host code as shared libraries])],
1912 [host_shared=$enableval
1913  case $target in
1914    x86_64-*-darwin* | aarch64-*-darwin*)
1915      if test x$host_shared != xyes ; then
1916        # PIC is the default, and actually cannot be switched off.
1917        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1918        host_shared=yes
1919      fi ;;
1920   *) ;;
1921  esac],
1922 [case $target in
1923   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1924   *) host_shared=no ;;
1925  esac])
1926 AC_SUBST(host_shared)
1927
1928 # By default, C and C++ are the only stage 1 languages.
1929 stage1_languages=,c,
1930
1931 # Target libraries that we bootstrap.
1932 bootstrap_target_libs=,target-libgcc,
1933
1934 # Figure out what language subdirectories are present.
1935 # Look if the user specified --enable-languages="..."; if not, use
1936 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1937 # go away some day.
1938 # NB:  embedded tabs in this IF block -- do not untabify
1939 if test -d ${srcdir}/gcc; then
1940   if test x"${enable_languages+set}" != xset; then
1941     if test x"${LANGUAGES+set}" = xset; then
1942       enable_languages="${LANGUAGES}"
1943         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1944     else
1945       enable_languages=default
1946     fi
1947   else
1948     if test x"${enable_languages}" = x ||
1949        test x"${enable_languages}" = xyes;
1950        then
1951       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1952       exit 1
1953     fi
1954   fi
1955   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1956
1957   # 'f95' is the old name for the 'fortran' language. We issue a warning
1958   # and make the substitution.
1959   case ,${enable_languages}, in
1960     *,f95,*)
1961       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1962       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1963       ;;
1964   esac
1965
1966   # If bootstrapping, C++ must be enabled.
1967   case ",$enable_languages,:$enable_bootstrap" in
1968     *,c++,*:*) ;;
1969     *:yes)
1970       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1971         enable_languages="${enable_languages},c++"
1972       else
1973         AC_MSG_ERROR([bootstrapping requires c++ sources])
1974       fi
1975       ;;
1976   esac
1977
1978   # First scan to see if an enabled language requires some other language.
1979   # We assume that a given config-lang.in will list all the language
1980   # front ends it requires, even if some are required indirectly.
1981   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1982     case ${lang_frag} in
1983       ..) ;;
1984       # The odd quoting in the next line works around
1985       # an apparent bug in bash 1.12 on linux.
1986       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1987       *)
1988         # From the config-lang.in, get $language, $lang_requires, and
1989         # $lang_requires_boot_languages.
1990         language=
1991         lang_requires=
1992         lang_requires_boot_languages=
1993         # set srcdir during sourcing lang_frag to the gcc dir.
1994         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1995         # polutes this shell
1996         saved_srcdir=${srcdir}
1997         srcdir=${srcdir}/gcc . ${lang_frag}
1998         srcdir=${saved_srcdir}
1999         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2000           case ,${enable_languages}, in
2001             *,$other,*) ;;
2002             *,default,*) ;;
2003             *,all,*) ;;
2004             *,$language,*)
2005               echo " \`$other' language required by \`$language'; enabling" 1>&2
2006               enable_languages="${enable_languages},${other}"
2007               ;;
2008           esac
2009         done
2010         for other in ${lang_requires_boot_languages} ; do
2011           if test "$other" != "c"; then
2012             case ,${enable_stage1_languages}, in
2013               *,$other,*) ;;
2014               *,default,*) ;;
2015               *,all,*) ;;
2016               *)
2017                 case ,${enable_languages}, in
2018                   *,$language,*)
2019                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2020                     enable_stage1_languages="$enable_stage1_languages,${other}"
2021                     ;;
2022                 esac
2023                 ;;
2024             esac
2025           fi
2026         done
2027         ;;
2028     esac
2029   done
2030
2031   new_enable_languages=,c,
2032
2033   # If LTO is enabled, add the LTO front end.
2034   if test "$enable_lto" = "yes" ; then
2035     case ,${enable_languages}, in
2036       *,lto,*) ;;
2037       *) enable_languages="${enable_languages},lto" ;;
2038     esac
2039     if test "${build_lto_plugin}" = "yes" ; then
2040       configdirs="$configdirs lto-plugin"
2041     fi
2042   fi
2043
2044   # If we're building an offloading compiler, add the LTO front end.
2045   if test x"$enable_as_accelerator_for" != x ; then
2046     case ,${enable_languages}, in
2047       *,lto,*) ;;
2048       *) enable_languages="${enable_languages},lto" ;;
2049     esac
2050   fi
2051
2052   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2053   potential_languages=,c,
2054
2055   enabled_target_libs=
2056   disabled_target_libs=
2057
2058   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2059     case ${lang_frag} in
2060       ..) ;;
2061       # The odd quoting in the next line works around
2062       # an apparent bug in bash 1.12 on linux.
2063       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2064       *)
2065         # From the config-lang.in, get $language, $target_libs,
2066         # $lang_dirs, $boot_language, and $build_by_default
2067         language=
2068         target_libs=
2069         lang_dirs=
2070         subdir_requires=
2071         boot_language=no
2072         build_by_default=yes
2073         # set srcdir during sourcing.  See above about save & restore
2074         saved_srcdir=${srcdir}
2075         srcdir=${srcdir}/gcc . ${lang_frag}
2076         srcdir=${saved_srcdir}
2077         if test x${language} = x; then
2078           echo "${lang_frag} doesn't set \$language." 1>&2
2079           exit 1
2080         fi
2081
2082         if test "$language" = "c++"; then
2083           boot_language=yes
2084         fi
2085
2086         add_this_lang=no
2087         # C is always enabled, so no need to add it again
2088         if test "$language" != "c"; then
2089           case ,${enable_languages}, in
2090             *,${language},*)
2091               # Language was explicitly selected; include it
2092               add_this_lang=yes
2093               ;;
2094             *,all,*)
2095               # All languages are enabled
2096               add_this_lang=all
2097               ;;
2098             *,default,*)
2099               # 'default' was selected, select it if it is a default language
2100               add_this_lang=${build_by_default}
2101               ;;
2102           esac
2103         fi
2104
2105         # Disable languages that need other directories if these aren't available.
2106         for i in $subdir_requires; do
2107           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2108           case ${add_this_lang} in
2109             yes)
2110               # Specifically requested language; tell them.
2111               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2112               ;;
2113             all)
2114               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2115               add_this_lang=unsupported
2116               ;;
2117             *)
2118               # Silently disable.
2119               add_this_lang=unsupported
2120               ;;
2121           esac
2122         done
2123
2124         # Disable Ada if no preexisting GNAT is available.
2125         case ${add_this_lang}:${language}:${have_gnat} in
2126           yes:ada:no)
2127             # Specifically requested language; tell them.
2128             AC_MSG_ERROR([GNAT is required to build $language])
2129             ;;
2130           all:ada:no)
2131             AC_MSG_WARN([GNAT is required to build $language])
2132             add_this_lang=unsupported
2133             ;;
2134           *:ada:no)
2135             # Silently disable.
2136             add_this_lang=unsupported
2137             ;;
2138         esac
2139
2140         # Disable D if no preexisting GDC is available.
2141         case ${add_this_lang}:${language}:${have_gdc} in
2142           yes:d:no)
2143             # Specifically requested language; tell them.
2144             AC_MSG_ERROR([GDC is required to build $language])
2145            ;;
2146           all:d:no)
2147             AC_MSG_WARN([GDC is required to build $language])
2148             add_this_lang=unsupported
2149             ;;
2150           *:d:no)
2151             # Silently disable.
2152             add_this_lang=unsupported
2153             ;;
2154         esac
2155
2156         # Disable jit if -enable-host-shared not specified
2157         # but not if building for Mingw. All code in Windows
2158         # is position independent code (PIC).
2159         case $target in
2160           *mingw*) ;;
2161           *)
2162           case ${add_this_lang}:${language}:${host_shared} in
2163             yes:jit:no)
2164                    # PR jit/64780: explicitly specify --enable-host-shared
2165             AC_MSG_ERROR([
2166 Enabling language "jit" requires --enable-host-shared.
2167
2168 --enable-host-shared typically slows the rest of the compiler down by
2169 a few %, so you must explicitly enable it.
2170
2171 If you want to build both the jit and the regular compiler, it is often
2172 best to do this via two separate configure/builds, in separate
2173 directories, to avoid imposing the performance cost of
2174 --enable-host-shared on the regular compiler.])
2175                     ;;
2176             all:jit:no)
2177               AC_MSG_WARN([--enable-host-shared required to build $language])
2178               add_this_lang=unsupported
2179               ;;
2180             *:jit:no)
2181               # Silently disable.
2182               add_this_lang=unsupported
2183               ;;
2184                 esac
2185           ;;
2186         esac
2187
2188         # Disable a language that is unsupported by the target.
2189         case "${add_this_lang}: $unsupported_languages " in
2190           no:*) ;;
2191           unsupported:*) ;;
2192           *:*" $language "*)
2193             AC_MSG_WARN([${language} not supported for this target])
2194             add_this_lang=unsupported
2195             ;;
2196         esac
2197
2198         case $add_this_lang in
2199           unsupported)
2200             # Remove language-dependent dirs.
2201             disabled_target_libs="$disabled_target_libs $target_libs"
2202             noconfigdirs="$noconfigdirs $lang_dirs"
2203             ;;
2204           no)
2205             # Remove language-dependent dirs; still show language as supported.
2206             disabled_target_libs="$disabled_target_libs $target_libs"
2207             noconfigdirs="$noconfigdirs $lang_dirs"
2208             potential_languages="${potential_languages}${language},"
2209             ;;
2210           all|yes)
2211             new_enable_languages="${new_enable_languages}${language},"
2212             potential_languages="${potential_languages}${language},"
2213             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2214             enabled_target_libs="$enabled_target_libs $target_libs"
2215             case "${boot_language}:,$enable_stage1_languages," in
2216               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2217                 # Add to (comma-separated) list of stage 1 languages.
2218                 case ",$stage1_languages," in
2219                   *,$language,* | ,yes, | ,all,) ;;
2220                   *) stage1_languages="${stage1_languages}${language}," ;;
2221                 esac
2222                 # We need to bootstrap any supporting libraries.
2223                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2224                 ;;
2225             esac
2226             ;;
2227         esac
2228         ;;
2229     esac
2230   done
2231
2232   # Add target libraries which are only needed for disabled languages
2233   # to noconfigdirs.
2234   if test -n "$disabled_target_libs"; then
2235     for dir in $disabled_target_libs; do
2236       case " $enabled_target_libs " in
2237       *" ${dir} "*) ;;
2238       *) noconfigdirs="$noconfigdirs $dir" ;;
2239       esac
2240     done
2241   fi
2242
2243   AC_ARG_ENABLE(stage1-languages,
2244   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2245                   [choose additional languages to build during
2246                   stage1.  Mostly useful for compiler development])],
2247   [case ,${enable_stage1_languages}, in
2248     ,no,|,,)
2249       # Set it to something that will have no effect in the loop below
2250       enable_stage1_languages=c ;;
2251     ,yes,)
2252       enable_stage1_languages=`echo $new_enable_languages | \
2253         sed -e "s/^,//" -e "s/,$//" ` ;;
2254     *,all,*)
2255       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2256         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2257   esac
2258
2259   # Add "good" languages from enable_stage1_languages to stage1_languages,
2260   # while "bad" languages go in missing_languages.  Leave no duplicates.
2261   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2262     case $potential_languages in
2263       *,$i,*)
2264         case $stage1_languages in
2265           *,$i,*) ;;
2266           *) stage1_languages="$stage1_languages$i," ;;
2267         esac ;;
2268       *)
2269         case $missing_languages in
2270           *,$i,*) ;;
2271           *) missing_languages="$missing_languages$i," ;;
2272         esac ;;
2273      esac
2274   done])
2275
2276   # Remove leading/trailing commas that were added for simplicity
2277   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2278   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2279   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2280   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2281
2282   if test "x$missing_languages" != x; then
2283     AC_MSG_ERROR([
2284 The following requested languages could not be built: ${missing_languages}
2285 Supported languages are: ${potential_languages}])
2286   fi
2287   if test "x$new_enable_languages" != "x$enable_languages"; then
2288     echo The following languages will be built: ${new_enable_languages}
2289     enable_languages="$new_enable_languages"
2290   fi
2291
2292   AC_SUBST(stage1_languages)
2293   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2294 fi
2295
2296 # Handle --disable-<component> generically.
2297 for dir in $configdirs $build_configdirs $target_configdirs ; do
2298   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2299   varname=`echo $dirname | sed -e s/+/_/g`
2300   if eval test x\${enable_${varname}} "=" xno ; then
2301     noconfigdirs="$noconfigdirs $dir"
2302   fi
2303 done
2304
2305 # Check for Boehm's garbage collector
2306 AC_ARG_ENABLE(objc-gc,
2307 [AS_HELP_STRING([--enable-objc-gc],
2308                 [enable use of Boehm's garbage collector with the
2309                  GNU Objective-C runtime])])
2310 AC_ARG_WITH([target-bdw-gc],
2311 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2312                 [specify prefix directory for installed bdw-gc package.
2313                  Equivalent to --with-target-bdw-gc-include=PATH/include
2314                  plus --with-target-bdw-gc-lib=PATH/lib])])
2315 AC_ARG_WITH([target-bdw-gc-include],
2316 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2317                 [specify directories for installed bdw-gc include files])])
2318 AC_ARG_WITH([target-bdw-gc-lib],
2319 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2320                 [specify directories for installed bdw-gc library])])
2321
2322 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2323   AC_MSG_CHECKING([for bdw garbage collector])
2324   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2325     dnl no bdw-gw options, assume default locations
2326     AC_MSG_RESULT([using bdw-gc in default locations])
2327   else
2328     dnl bdw-gw options, first error checking, complete checking in libobjc
2329     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2330       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2331     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2332       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2333     else
2334       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2335     fi
2336   fi
2337 esac
2338
2339 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2340 case ,${enable_languages}, in
2341   *,c++,*)
2342     # Disable libitm, libsanitizer if we're not building libstdc++
2343     case "${noconfigdirs}" in
2344       *target-libstdc++-v3*)
2345         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2346         ;;
2347       *) ;;
2348     esac
2349     ;;
2350   *)
2351     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2352     ;;
2353 esac
2354
2355 # If gcc/ is not in the source tree then we'll not be building a
2356 # target compiler, assume in that case we don't want to build any
2357 # target libraries or tools.
2358 #
2359 # This was added primarily for the benefit for binutils-gdb who reuse
2360 # this configure script, but don't always have target tools available.
2361 if test ! -d ${srcdir}/gcc; then
2362    skipdirs="${skipdirs} ${target_configdirs}"
2363 fi
2364
2365 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2366 # $build_configdirs and $target_configdirs.
2367 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2368
2369 notsupp=""
2370 for dir in . $skipdirs $noconfigdirs ; do
2371   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2372   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2373     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2374     if test -r $srcdir/$dirname/configure ; then
2375       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2376         true
2377       else
2378         notsupp="$notsupp $dir"
2379       fi
2380     fi
2381   fi
2382   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2383     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2384     if test -r $srcdir/$dirname/configure ; then
2385       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2386         true
2387       else
2388         notsupp="$notsupp $dir"
2389       fi
2390     fi
2391   fi
2392   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2393     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2394     if test -r $srcdir/$dirname/configure ; then
2395       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2396         true
2397       else
2398         notsupp="$notsupp $dir"
2399       fi
2400     fi
2401   fi
2402 done
2403
2404 # Quietly strip out all directories which aren't configurable in this tree.
2405 # This relies on all configurable subdirectories being autoconfiscated, which
2406 # is now the case.
2407 build_configdirs_all="$build_configdirs"
2408 build_configdirs=
2409 for i in ${build_configdirs_all} ; do
2410   j=`echo $i | sed -e s/build-//g`
2411   if test -f ${srcdir}/$j/configure ; then
2412     build_configdirs="${build_configdirs} $i"
2413   fi
2414 done
2415
2416 configdirs_all="$configdirs"
2417 configdirs=
2418 for i in ${configdirs_all} ; do
2419   if test -f ${srcdir}/$i/configure ; then
2420     configdirs="${configdirs} $i"
2421   fi
2422 done
2423
2424 target_configdirs_all="$target_configdirs"
2425 target_configdirs=
2426 for i in ${target_configdirs_all} ; do
2427   j=`echo $i | sed -e s/target-//g`
2428   if test -f ${srcdir}/$j/configure ; then
2429     target_configdirs="${target_configdirs} $i"
2430   fi
2431 done
2432
2433 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2434 # so we have to add it after the preceding checks.
2435 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2436 then
2437   case " $configdirs " in
2438     *" libiberty "*)
2439       # If we can build libiberty, we can also build libiberty-linker-plugin.
2440       configdirs="$configdirs libiberty-linker-plugin"
2441       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2442         --with-libiberty=../libiberty-linker-plugin";;
2443     *)
2444       AC_MSG_ERROR([libiberty missing]);;
2445   esac
2446 fi
2447
2448 # Sometimes we have special requirements for the host libiberty.
2449 extra_host_libiberty_configure_flags=
2450 extra_host_zlib_configure_flags=
2451 case " $configdirs " in
2452   *" lto-plugin "* | *" libcc1 "*)
2453     # When these are to be built as shared libraries, the same applies to
2454     # libiberty.
2455     extra_host_libiberty_configure_flags=--enable-shared
2456     ;;
2457   *" bfd "*)
2458     # When bfd is to be built as a shared library, the same applies to
2459     # zlib.
2460     if test "$enable_shared" = "yes"; then
2461       extra_host_zlib_configure_flags=--enable-host-shared
2462     fi
2463     ;;
2464 esac
2465 AC_SUBST(extra_host_libiberty_configure_flags)
2466 AC_SUBST(extra_host_zlib_configure_flags)
2467
2468 # Produce a warning message for the subdirs we can't configure.
2469 # This isn't especially interesting in the Cygnus tree, but in the individual
2470 # FSF releases, it's important to let people know when their machine isn't
2471 # supported by the one or two programs in a package.
2472
2473 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2474   # If $appdirs is non-empty, at least one of those directories must still
2475   # be configured, or we error out.  (E.g., if the gas release supports a
2476   # specified target in some subdirs but not the gas subdir, we shouldn't
2477   # pretend that all is well.)
2478   if test -n "$appdirs" ; then
2479     for dir in $appdirs ; do
2480       if test -r $dir/Makefile.in ; then
2481         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2482           appdirs=""
2483           break
2484         fi
2485         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2486           appdirs=""
2487           break
2488         fi
2489       fi
2490     done
2491     if test -n "$appdirs" ; then
2492       echo "*** This configuration is not supported by this package." 1>&2
2493       exit 1
2494     fi
2495   fi
2496   # Okay, some application will build, or we don't care to check.  Still
2497   # notify of subdirs not getting built.
2498   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2499   echo "    ${notsupp}" 1>&2
2500   echo "    (Any other directories should still work fine.)" 1>&2
2501 fi
2502
2503 case "$host" in
2504   *msdosdjgpp*)
2505     enable_gdbtk=no ;;
2506 esac
2507
2508 # To find our prefix, in gcc_cv_tool_prefix.
2509 ACX_TOOL_DIRS
2510
2511 copy_dirs=
2512
2513 AC_ARG_WITH([build-sysroot],
2514   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2515                   [use sysroot as the system root during the build])],
2516   [if test x"$withval" != x ; then
2517      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2518    fi],
2519   [SYSROOT_CFLAGS_FOR_TARGET=])
2520 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2521
2522 AC_ARG_WITH([debug-prefix-map],
2523   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2524                   [map A to B, C to D ... in debug information])],
2525   [if test x"$withval" != x; then
2526      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2527      for debug_map in $withval; do
2528        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2529      done
2530    fi],
2531   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2532 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2533
2534 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2535 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2536 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2537 # We want to ensure that TARGET libraries (which we know are built with
2538 # gcc) are built with "-O2 -g", so include those options when setting
2539 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2540 if test "x$CFLAGS_FOR_TARGET" = x; then
2541   if test "x${is_cross_compiler}" = xyes; then
2542     CFLAGS_FOR_TARGET="-g -O2"
2543   else
2544     CFLAGS_FOR_TARGET=$CFLAGS
2545     case " $CFLAGS " in
2546       *" -O2 "*) ;;
2547       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2548     esac
2549     case " $CFLAGS " in
2550       *" -g "* | *" -g3 "*) ;;
2551       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2552     esac
2553   fi
2554 fi
2555 AC_SUBST(CFLAGS_FOR_TARGET)
2556
2557 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2558   if test "x${is_cross_compiler}" = xyes; then
2559     CXXFLAGS_FOR_TARGET="-g -O2"
2560   else
2561     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2562     case " $CXXFLAGS " in
2563       *" -O2 "*) ;;
2564       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2565     esac
2566     case " $CXXFLAGS " in
2567       *" -g "* | *" -g3 "*) ;;
2568       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2569     esac
2570   fi
2571 fi
2572 AC_SUBST(CXXFLAGS_FOR_TARGET)
2573
2574 AC_SUBST(LDFLAGS_FOR_TARGET)
2575
2576 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2577 # the named directory are copied to $(tooldir)/sys-include.
2578 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2579   if test x${is_cross_compiler} = xno ; then
2580     echo 1>&2 '***' --with-headers is only supported when cross compiling
2581     exit 1
2582   fi
2583   if test x"${with_headers}" != xyes ; then
2584     x=${gcc_cv_tool_prefix}
2585     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2586   fi
2587 fi
2588
2589 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2590 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2591 # are permitted.
2592 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2593   if test x${is_cross_compiler} = xno ; then
2594     echo 1>&2 '***' --with-libs is only supported when cross compiling
2595     exit 1
2596   fi
2597   if test x"${with_libs}" != xyes ; then
2598     # Copy the libraries in reverse order, so that files in the first named
2599     # library override files in subsequent libraries.
2600     x=${gcc_cv_tool_prefix}
2601     for l in ${with_libs}; do
2602       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2603     done
2604   fi
2605 fi
2606
2607 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2608 #
2609 # This is done by determining whether or not the appropriate directory
2610 # is available, and by checking whether or not specific configurations
2611 # have requested that this magic not happen.
2612 #
2613 # The command line options always override the explicit settings in
2614 # configure.ac, and the settings in configure.ac override this magic.
2615 #
2616 # If the default for a toolchain is to use GNU as and ld, and you don't
2617 # want to do that, then you should use the --without-gnu-as and
2618 # --without-gnu-ld options for the configure script.  Similarly, if
2619 # the default is to use the included zlib and you don't want to do that,
2620 # you should use the --with-system-zlib option for the configure script.
2621
2622 if test x${use_gnu_as} = x &&
2623    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2624   with_gnu_as=yes
2625   extra_host_args="$extra_host_args --with-gnu-as"
2626 fi
2627
2628 if test x${use_gnu_ld} = x &&
2629    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2630   with_gnu_ld=yes
2631   extra_host_args="$extra_host_args --with-gnu-ld"
2632 fi
2633
2634 if test x${use_included_zlib} = x &&
2635    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2636   :
2637 else
2638   with_system_zlib=yes
2639   extra_host_args="$extra_host_args --with-system-zlib"
2640 fi
2641
2642 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2643 # can detect this case.
2644
2645 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2646   with_newlib=yes
2647   extra_host_args="$extra_host_args --with-newlib"
2648 fi
2649
2650 # Handle ${copy_dirs}
2651 set fnord ${copy_dirs}
2652 shift
2653 while test $# != 0 ; do
2654   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2655     :
2656   else
2657     echo Copying $1 to $2
2658
2659     # Use the install script to create the directory and all required
2660     # parent directories.
2661     if test -d $2 ; then
2662       :
2663     else
2664       echo >config.temp
2665       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2666     fi
2667
2668     # Copy the directory, assuming we have tar.
2669     # FIXME: Should we use B in the second tar?  Not all systems support it.
2670     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2671
2672     # It is the responsibility of the user to correctly adjust all
2673     # symlinks.  If somebody can figure out how to handle them correctly
2674     # here, feel free to add the code.
2675
2676     echo $1 > $2/COPIED
2677   fi
2678   shift; shift
2679 done
2680
2681 # Determine a target-dependent exec_prefix that the installed
2682 # gcc will search in.  Keep this list sorted by triplet, with
2683 # the *-*-osname triplets last.
2684 md_exec_prefix=
2685 case "${target}" in
2686   i[[34567]]86-pc-msdosdjgpp*)
2687     md_exec_prefix=/dev/env/DJDIR/bin
2688     ;;
2689   *-*-hpux* | \
2690   *-*-nto-qnx* | \
2691   *-*-solaris2*)
2692     md_exec_prefix=/usr/ccs/bin
2693     ;;
2694 esac
2695
2696 extra_arflags_for_target=
2697 extra_nmflags_for_target=
2698 extra_ranlibflags_for_target=
2699 target_makefile_frag=/dev/null
2700 case "${target}" in
2701   spu-*-*)
2702     target_makefile_frag="config/mt-spu"
2703     ;;
2704   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2705     target_makefile_frag="config/mt-sde"
2706     ;;
2707   mipsisa*-*-elfoabi*)
2708     target_makefile_frag="config/mt-mips-elfoabi"
2709     ;;
2710   mips*-*-*linux* | mips*-*-gnu*)
2711     target_makefile_frag="config/mt-mips-gnu"
2712     ;;
2713   nios2-*-elf*)
2714     target_makefile_frag="config/mt-nios2-elf"
2715     ;;
2716   *-*-linux-android*)
2717     target_makefile_frag="config/mt-android"
2718     ;;
2719   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2720     target_makefile_frag="config/mt-gnu"
2721     ;;
2722   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2723     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2724     # commands to handle both 32-bit and 64-bit objects.  These flags are
2725     # harmless if we're using GNU nm or ar.
2726     extra_arflags_for_target=" -X32_64"
2727     extra_nmflags_for_target=" -B -X32_64"
2728     ;;
2729 esac
2730
2731 alphaieee_frag=/dev/null
2732 case $target in
2733   alpha*-*-*)
2734     # This just makes sure to use the -mieee option to build target libs.
2735     # This should probably be set individually by each library.
2736     alphaieee_frag="config/mt-alphaieee"
2737     ;;
2738 esac
2739
2740 # If --enable-target-optspace always use -Os instead of -O2 to build
2741 # the target libraries, similarly if it is not specified, use -Os
2742 # on selected platforms.
2743 ospace_frag=/dev/null
2744 case "${enable_target_optspace}:${target}" in
2745   yes:*)
2746     ospace_frag="config/mt-ospace"
2747     ;;
2748   :d30v-*)
2749     ospace_frag="config/mt-d30v"
2750     ;;
2751   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2752     ospace_frag="config/mt-ospace"
2753     ;;
2754   no:* | :*)
2755     ;;
2756   *)
2757     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2758     ;;
2759 esac
2760
2761 # Some systems (e.g., one of the i386-aix systems the gas testers are
2762 # using) don't handle "\$" correctly, so don't use it here.
2763 tooldir='${exec_prefix}'/${target_noncanonical}
2764 build_tooldir=${tooldir}
2765
2766 # Create a .gdbinit file which runs the one in srcdir
2767 # and tells GDB to look there for source files.
2768
2769 if test -r ${srcdir}/.gdbinit ; then
2770   case ${srcdir} in
2771     .) ;;
2772     *) cat > ./.gdbinit <<EOF
2773 # ${NO_EDIT}
2774 dir ${srcdir}
2775 dir .
2776 source ${srcdir}/.gdbinit
2777 EOF
2778     ;;
2779   esac
2780 fi
2781
2782 # Make sure that the compiler is able to generate an executable.  If it
2783 # can't, we are probably in trouble.  We don't care whether we can run the
2784 # executable--we might be using a cross compiler--we only care whether it
2785 # can be created.  At this point the main configure script has set CC.
2786 we_are_ok=no
2787 echo "int main () { return 0; }" > conftest.c
2788 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2789 if test $? = 0 ; then
2790   if test -s conftest || test -s conftest.exe ; then
2791     we_are_ok=yes
2792   fi
2793 fi
2794 case $we_are_ok in
2795   no)
2796     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2797     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2798     rm -f conftest*
2799     exit 1
2800     ;;
2801 esac
2802 rm -f conftest*
2803
2804 # Decide which environment variable is used to find dynamic libraries.
2805 case "${host}" in
2806   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2807   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2808   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2809   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2810 esac
2811
2812 # On systems where the dynamic library environment variable is PATH,
2813 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2814 # built executables to PATH.
2815 if test "$RPATH_ENVVAR" = PATH; then
2816   GCC_SHLIB_SUBDIR=/shlib
2817 else
2818   GCC_SHLIB_SUBDIR=
2819 fi
2820
2821 # Adjust the toplevel makefile according to whether bootstrap was selected.
2822 case $enable_bootstrap in
2823   yes)
2824     bootstrap_suffix=bootstrap
2825     BUILD_CONFIG=bootstrap-debug
2826     ;;
2827   no)
2828     bootstrap_suffix=no-bootstrap
2829     BUILD_CONFIG=
2830     ;;
2831 esac
2832
2833 AC_MSG_CHECKING(for default BUILD_CONFIG)
2834
2835 AC_ARG_WITH([build-config],
2836   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2837                   [use config/NAME.mk build configuration])],
2838   [case $with_build_config in
2839    yes) with_build_config= ;;
2840    no) with_build_config= BUILD_CONFIG= ;;
2841    esac])
2842
2843 if test "x${with_build_config}" != x; then
2844   BUILD_CONFIG=$with_build_config
2845 else
2846   case $BUILD_CONFIG in
2847   bootstrap-debug)
2848     if echo "int f (void) { return 0; }" > conftest.c &&
2849        ${CC} -c conftest.c &&
2850        mv conftest.o conftest.o.g0 &&
2851        ${CC} -c -g conftest.c &&
2852        mv conftest.o conftest.o.g &&
2853        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2854       :
2855     else
2856       BUILD_CONFIG=
2857     fi
2858     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2859     ;;
2860   esac
2861 fi
2862 AC_MSG_RESULT($BUILD_CONFIG)
2863 AC_SUBST(BUILD_CONFIG)
2864
2865 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2866 AC_MSG_CHECKING([for --enable-vtable-verify])
2867 AC_ARG_ENABLE(vtable-verify,
2868 [AS_HELP_STRING([--enable-vtable-verify],
2869                 [Enable vtable verification feature])],
2870 [case "$enableval" in
2871  yes) enable_vtable_verify=yes ;;
2872  no)  enable_vtable_verify=no ;;
2873  *)   enable_vtable_verify=no;;
2874  esac],
2875 [enable_vtable_verify=no])
2876 AC_MSG_RESULT($enable_vtable_verify)
2877
2878 # Record target_configdirs and the configure arguments for target and
2879 # build configuration in Makefile.
2880 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2881 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2882 bootstrap_fixincludes=no
2883
2884 # If we are building libgomp, bootstrap it.
2885 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2886   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2887 fi
2888
2889 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2890 # or bootstrap-ubsan, bootstrap it.
2891 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2892   case "$BUILD_CONFIG" in
2893     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2894       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2895       bootstrap_fixincludes=yes
2896       ;;
2897   esac
2898 fi
2899
2900 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2901 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2902    test "$enable_vtable_verify" != no; then
2903   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2904 fi
2905
2906 # If we are building libatomic and the list of enabled languages includes the
2907 # D frontend, bootstrap it.
2908 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2909   case ,${enable_languages}, in
2910     *,d,*)
2911       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2912       ;;
2913   esac
2914 fi
2915
2916 # Determine whether gdb needs tk/tcl or not.
2917 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2918 # and in that case we want gdb to be built without tk.  Ugh!
2919 # In fact I believe gdb is the *only* package directly dependent on tk,
2920 # so we should be able to put the 'maybe's in unconditionally and
2921 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2922 # 100% sure that that's safe though.
2923
2924 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2925 case "$enable_gdbtk" in
2926   no)
2927     GDB_TK="" ;;
2928   yes)
2929     GDB_TK="${gdb_tk}" ;;
2930   *)
2931     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2932     # distro.  Eventually someone will fix this and move Insight, nee
2933     # gdbtk to a separate directory.
2934     if test -d ${srcdir}/gdb/gdbtk ; then
2935       GDB_TK="${gdb_tk}"
2936     else
2937       GDB_TK=""
2938     fi
2939     ;;
2940 esac
2941 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2942 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2943
2944 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2945 # else does, only include them if one of these is built.  The Makefile
2946 # provides the ordering, so it's enough here to add to the list.
2947 case " ${configdirs} " in
2948   *\ gdb\ *)
2949     configdirs="${configdirs} gnulib gdbsupport"
2950     ;;
2951   *\ gdbserver\ *)
2952     configdirs="${configdirs} gnulib gdbsupport"
2953     ;;
2954   *\ sim\ *)
2955     configdirs="${configdirs} gnulib"
2956     ;;
2957 esac
2958
2959 # Strip out unwanted targets.
2960
2961 # While at that, we remove Makefiles if we were started for recursive
2962 # configuration, so that the top-level Makefile reconfigures them,
2963 # like we used to do when configure itself was recursive.
2964
2965 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2966 # but now we're fixing up the Makefile ourselves with the additional
2967 # commands passed to AC_CONFIG_FILES.  Use separate variables
2968 # extrasub-{build,host,target} not because there is any reason to split
2969 # the substitutions up that way, but only to remain below the limit of
2970 # 99 commands in a script, for HP-UX sed.
2971
2972 # Do not nest @if/@endif or @unless/@endunless pairs, because
2973 # configure will not warn you at all.
2974
2975 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2976   yes:yes:*\ gold\ *:*,c++,*) ;;
2977   yes:yes:*\ gold\ *:*)
2978     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2979     ;;
2980 esac
2981
2982 extrasub_build=
2983 for module in ${build_configdirs} ; do
2984   if test -z "${no_recursion}" \
2985      && test -f ${build_subdir}/${module}/Makefile; then
2986     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2987     rm -f ${build_subdir}/${module}/Makefile
2988   fi
2989   extrasub_build="$extrasub_build
2990 /^@if build-$module\$/d
2991 /^@endif build-$module\$/d
2992 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2993 /^@if build-$module-$bootstrap_suffix\$/d
2994 /^@endif build-$module-$bootstrap_suffix\$/d
2995 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2996 done
2997 extrasub_host=
2998 for module in ${configdirs} ; do
2999   if test -z "${no_recursion}"; then
3000     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3001       if test -f ${file}; then
3002         echo 1>&2 "*** removing ${file} to force reconfigure"
3003         rm -f ${file}
3004       fi
3005     done
3006   fi
3007   case ${module},${bootstrap_fixincludes} in
3008     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3009     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3010   esac
3011   extrasub_host="$extrasub_host
3012 /^@if $module\$/d
3013 /^@endif $module\$/d
3014 /^@unless $module\$/,/^@endunless $module\$/d
3015 /^@if $module-$host_bootstrap_suffix\$/d
3016 /^@endif $module-$host_bootstrap_suffix\$/d
3017 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3018 done
3019 extrasub_target=
3020 for module in ${target_configdirs} ; do
3021   if test -z "${no_recursion}" \
3022      && test -f ${target_subdir}/${module}/Makefile; then
3023     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3024     rm -f ${target_subdir}/${module}/Makefile
3025   fi
3026
3027   # We only bootstrap target libraries listed in bootstrap_target_libs.
3028   case $bootstrap_target_libs in
3029     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3030     *) target_bootstrap_suffix=no-bootstrap ;;
3031   esac
3032
3033   extrasub_target="$extrasub_target
3034 /^@if target-$module\$/d
3035 /^@endif target-$module\$/d
3036 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3037 /^@if target-$module-$target_bootstrap_suffix\$/d
3038 /^@endif target-$module-$target_bootstrap_suffix\$/d
3039 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3040 done
3041
3042 # Do the final fixup along with target modules.
3043 extrasub_target="$extrasub_target
3044 /^@if /,/^@endif /d
3045 /^@unless /d
3046 /^@endunless /d"
3047
3048 if test "$enable_pgo_build" != "no"; then
3049   extrasub_build="$extrasub_build
3050 /^@if pgo-build\$/d
3051 /^@endif pgo-build\$/d"
3052 fi
3053
3054 # Create the serialization dependencies.  This uses a temporary file.
3055
3056 AC_ARG_ENABLE([serial-configure],
3057 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3058                 [force sequential configuration of
3059                  sub-packages for the host, target or build
3060                  machine, or all sub-packages])])
3061
3062 case ${enable_serial_configure} in
3063   yes)
3064     enable_serial_build_configure=yes
3065     enable_serial_host_configure=yes
3066     enable_serial_target_configure=yes
3067     ;;
3068 esac
3069
3070 # These force 'configure's to be done one at a time, to avoid problems
3071 # with contention over a shared config.cache.
3072 rm -f serdep.tmp
3073 echo '# serdep.tmp' > serdep.tmp
3074 olditem=
3075 test "x${enable_serial_build_configure}" = xyes &&
3076 for item in ${build_configdirs} ; do
3077   case ${olditem} in
3078     "") ;;
3079     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3080   esac
3081   olditem=${item}
3082 done
3083 olditem=
3084 test "x${enable_serial_host_configure}" = xyes &&
3085 for item in ${configdirs} ; do
3086   case ${olditem} in
3087     "") ;;
3088     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3089   esac
3090   olditem=${item}
3091 done
3092 olditem=
3093 test "x${enable_serial_target_configure}" = xyes &&
3094 for item in ${target_configdirs} ; do
3095   case ${olditem} in
3096     "") ;;
3097     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3098   esac
3099   olditem=${item}
3100 done
3101 serialization_dependencies=serdep.tmp
3102 AC_SUBST_FILE(serialization_dependencies)
3103
3104 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3105 # target, nonopt, and variable assignments.  These are the ones we
3106 # might not want to pass down to subconfigures.  The exception being
3107 # --cache-file=/dev/null, which is used to turn off the use of cache
3108 # files altogether, and which should be passed on to subconfigures.
3109 # Also strip program-prefix, program-suffix, and program-transform-name,
3110 # so that we can pass down a consistent program-transform-name.
3111 baseargs=
3112 tbaseargs=
3113 keep_next=no
3114 skip_next=no
3115 eval "set -- $ac_configure_args"
3116 for ac_arg
3117 do
3118   if test X"$skip_next" = X"yes"; then
3119     skip_next=no
3120     continue
3121   fi
3122   if test X"$keep_next" = X"yes"; then
3123     case $ac_arg in
3124       *\'*)
3125         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3126     esac
3127     baseargs="$baseargs '$ac_arg'"
3128     tbaseargs="$tbaseargs '$ac_arg'"
3129     keep_next=no
3130     continue
3131   fi
3132
3133   # Handle separated arguments.  Based on the logic generated by
3134   # autoconf 2.59.
3135   case $ac_arg in
3136     *=* | --config-cache | -C | -disable-* | --disable-* \
3137       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3138       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3139       | -with-* | --with-* | -without-* | --without-* | --x)
3140       separate_arg=no
3141       ;;
3142     -*)
3143       separate_arg=yes
3144       ;;
3145     *)
3146       separate_arg=no
3147       ;;
3148   esac
3149
3150   skip_targ=no
3151   case $ac_arg in
3152 changequote(,)
3153   --with-* | --without-*)
3154     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3155
3156     case $libopt in
3157     *[-_]include)
3158       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3159       ;;
3160     *[-_]lib)
3161       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3162       ;;
3163     *)
3164       lib=$libopt
3165       ;;
3166     esac
3167 changequote([,])
3168
3169     case $lib in
3170     mpc | mpfr | gmp | isl)
3171       # If we're processing --with-$lib, --with-$lib-include or
3172       # --with-$lib-lib, for one of the libs above, and target is
3173       # different from host, don't pass the current argument to any
3174       # target library's configure.
3175       if test x$is_cross_compiler = xyes; then
3176         skip_targ=yes
3177       fi
3178       ;;
3179     esac
3180     ;;
3181   esac
3182
3183   case "$ac_arg" in
3184     --cache-file=/dev/null | \
3185     -cache-file=/dev/null )
3186       # Handled here to avoid the test to skip args below.
3187       baseargs="$baseargs '$ac_arg'"
3188       tbaseargs="$tbaseargs '$ac_arg'"
3189       # Assert: $separate_arg should always be no.
3190       keep_next=$separate_arg
3191       ;;
3192     --no*)
3193       continue
3194       ;;
3195     --c* | \
3196     --sr* | \
3197     --ho* | \
3198     --bu* | \
3199     --t* | \
3200     --program-* | \
3201     -cache_file* | \
3202     -srcdir* | \
3203     -host* | \
3204     -build* | \
3205     -target* | \
3206     -program-prefix* | \
3207     -program-suffix* | \
3208     -program-transform-name* )
3209       skip_next=$separate_arg
3210       continue
3211       ;;
3212     -*)
3213       # An option.  Add it.
3214       case $ac_arg in
3215         *\'*)
3216           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3217       esac
3218       baseargs="$baseargs '$ac_arg'"
3219       if test X"$skip_targ" = Xno; then
3220         tbaseargs="$tbaseargs '$ac_arg'"
3221       fi
3222       keep_next=$separate_arg
3223       ;;
3224     *)
3225       # Either a variable assignment, or a nonopt (triplet).  Don't
3226       # pass it down; let the Makefile handle this.
3227       continue
3228       ;;
3229   esac
3230 done
3231 # Remove the initial space we just introduced and, as these will be
3232 # expanded by make, quote '$'.
3233 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3234
3235 # Add in --program-transform-name, after --program-prefix and
3236 # --program-suffix have been applied to it.  Autoconf has already
3237 # doubled dollar signs and backslashes in program_transform_name; we want
3238 # the backslashes un-doubled, and then the entire thing wrapped in single
3239 # quotes, because this will be expanded first by make and then by the shell.
3240 # Also, because we want to override the logic in subdir configure scripts to
3241 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3242 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3243 ${program_transform_name}
3244 EOF_SED
3245 gcc_transform_name=`cat conftestsed.out`
3246 rm -f conftestsed.out
3247 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3248 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3249 if test "$silent" = yes; then
3250   baseargs="$baseargs --silent"
3251   tbaseargs="$tbaseargs --silent"
3252 fi
3253 baseargs="$baseargs --disable-option-checking"
3254 tbaseargs="$tbaseargs --disable-option-checking"
3255
3256 # Record and document user additions to sub configure arguments.
3257 AC_ARG_VAR([build_configargs],
3258            [additional configure arguments for build directories])
3259 AC_ARG_VAR([host_configargs],
3260            [additional configure arguments for host directories])
3261 AC_ARG_VAR([target_configargs],
3262            [additional configure arguments for target directories])
3263
3264 # For the build-side libraries, we just need to pretend we're native,
3265 # and not use the same cache file.  Multilibs are neither needed nor
3266 # desired.  We can't even use the same cache file for all build-side
3267 # libraries, as they're compiled differently; some with C, some with
3268 # C++ or with different feature-enabling options.
3269 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3270
3271 # For host modules, accept cache file option, or specification as blank.
3272 case "${cache_file}" in
3273 "") # empty
3274   cache_file_option="" ;;
3275 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3276   cache_file_option="--cache-file=${cache_file}" ;;
3277 *) # relative path
3278   cache_file_option="--cache-file=../${cache_file}" ;;
3279 esac
3280
3281 # Host dirs don't like to share a cache file either, horribly enough.
3282 # This seems to be due to autoconf 2.5x stupidity.
3283 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3284
3285 target_configargs="$target_configargs ${tbaseargs}"
3286
3287 # Passing a --with-cross-host argument lets the target libraries know
3288 # whether they are being built with a cross-compiler or being built
3289 # native.  However, it would be better to use other mechanisms to make the
3290 # sorts of decisions they want to make on this basis.  Please consider
3291 # this option to be deprecated.  FIXME.
3292 if test x${is_cross_compiler} = xyes ; then
3293   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3294 fi
3295
3296 # Special user-friendly check for native x86_64-linux build, if
3297 # multilib is not explicitly enabled.
3298 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3299   x86_64-*linux*:yes:$build:$build:)
3300     # Make sure we have a development environment that handles 32-bit
3301     dev64=no
3302     echo "int main () { return 0; }" > conftest.c
3303     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3304     if test $? = 0 ; then
3305       if test -s conftest || test -s conftest.exe ; then
3306         dev64=yes
3307       fi
3308     fi
3309     rm -f conftest*
3310     if test x${dev64} != xyes ; then
3311       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3312     fi
3313     ;;
3314 esac
3315
3316 # Default to --enable-multilib.
3317 if test x${enable_multilib} = x ; then
3318   target_configargs="--enable-multilib ${target_configargs}"
3319 fi
3320
3321 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3322 # changed from the earlier setting of with_newlib.
3323 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3324   target_configargs="--with-newlib ${target_configargs}"
3325 fi
3326
3327 # Different target subdirs use different values of certain variables
3328 # (notably CXX).  Worse, multilibs use *lots* of different values.
3329 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3330 # it doesn't automatically accept command-line overrides of them.
3331 # This means it's not safe for target subdirs to share a cache file,
3332 # which is disgusting, but there you have it.  Hopefully this can be
3333 # fixed in future.  It's still worthwhile to use a cache file for each
3334 # directory.  I think.
3335
3336 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3337 # We need to pass --target, as newer autoconf's requires consistency
3338 # for target_alias and gcc doesn't manage it consistently.
3339 target_configargs="--cache-file=./config.cache ${target_configargs}"
3340
3341 FLAGS_FOR_TARGET=
3342 case " $target_configdirs " in
3343  *" newlib "*)
3344   case " $target_configargs " in
3345   *" --with-newlib "*)
3346    case "$target" in
3347     *-cygwin*)
3348       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3349       ;;
3350    esac
3351
3352    # If we're not building GCC, don't discard standard headers.
3353    if test -d ${srcdir}/gcc; then
3354      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3355
3356      if test "${build}" != "${host}"; then
3357        # On Canadian crosses, CC_FOR_TARGET will have already been set
3358        # by `configure', so we won't have an opportunity to add -Bgcc/
3359        # to it.  This is right: we don't want to search that directory
3360        # for binaries, but we want the header files in there, so add
3361        # them explicitly.
3362        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3363
3364        # Someone might think of using the pre-installed headers on
3365        # Canadian crosses, in case the installed compiler is not fully
3366        # compatible with the compiler being built.  In this case, it
3367        # would be better to flag an error than risking having
3368        # incompatible object files being constructed.  We can't
3369        # guarantee that an error will be flagged, but let's hope the
3370        # compiler will do it, when presented with incompatible header
3371        # files.
3372      fi
3373    fi
3374
3375    case "${target}-${is_cross_compiler}" in
3376    i[[3456789]]86-*-linux*-no)
3377       # Here host == target, so we don't need to build gcc,
3378       # so we don't want to discard standard headers.
3379       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3380       ;;
3381    *)
3382       # If we're building newlib, use its generic headers last, but search
3383       # for any libc-related directories first (so make it the last -B
3384       # switch).
3385       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3386
3387       # If we're building libgloss, find the startup file, simulator library
3388       # and linker script.
3389       case " $target_configdirs " in
3390         *" libgloss "*)
3391         # Look for startup file, simulator library and maybe linker script.
3392         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3393         # Look for libnosys.a in case the target needs it.
3394         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3395         # Most targets have the linker script in the source directory.
3396         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3397         ;;
3398       esac
3399       ;;
3400    esac
3401    ;;
3402   esac
3403   ;;
3404 esac
3405
3406 case "$target" in
3407   x86_64-*mingw* | *-w64-mingw*)
3408   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3409   # however, use a symlink named 'mingw' in ${prefix} .
3410     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3411     ;;
3412   *-mingw*)
3413   # MinGW can't be handled as Cygwin above since it does not use newlib.
3414     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3415     ;;
3416 esac
3417
3418 # Allow the user to override the flags for
3419 # our build compiler if desired.
3420 if test x"${build}" = x"${host}" ; then
3421   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3422   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3423   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3424   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3425 fi
3426
3427 # On Canadian crosses, we'll be searching the right directories for
3428 # the previously-installed cross compiler, so don't bother to add
3429 # flags for directories within the install tree of the compiler
3430 # being built; programs in there won't even run.
3431 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3432   # Search for pre-installed headers if nothing else fits.
3433   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3434 fi
3435
3436 if test "x${use_gnu_ld}" = x &&
3437    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3438   # Arrange for us to find uninstalled linker scripts.
3439   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3440 fi
3441
3442 # Search for other target-specific linker scripts and such.
3443 case "${target}" in
3444   mep*)
3445     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3446     ;;
3447 esac
3448
3449 # Makefile fragments.
3450 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3451 do
3452   eval fragval=\$$frag
3453   if test $fragval != /dev/null; then
3454     eval $frag=${srcdir}/$fragval
3455   fi
3456 done
3457 AC_SUBST_FILE(host_makefile_frag)
3458 AC_SUBST_FILE(target_makefile_frag)
3459 AC_SUBST_FILE(alphaieee_frag)
3460 AC_SUBST_FILE(ospace_frag)
3461
3462 # Miscellanea: directories, flags, etc.
3463 AC_SUBST(RPATH_ENVVAR)
3464 AC_SUBST(GCC_SHLIB_SUBDIR)
3465 AC_SUBST(tooldir)
3466 AC_SUBST(build_tooldir)
3467 AC_SUBST(CONFIGURE_GDB_TK)
3468 AC_SUBST(GDB_TK)
3469 AC_SUBST(INSTALL_GDB_TK)
3470
3471 # Build module lists & subconfigure args.
3472 AC_SUBST(build_configargs)
3473 AC_SUBST(build_configdirs)
3474
3475 # Host module lists & subconfigure args.
3476 AC_SUBST(host_configargs)
3477 AC_SUBST(configdirs)
3478 AC_SUBST(target_configdirs)
3479
3480 # Target module lists & subconfigure args.
3481 AC_SUBST(target_configargs)
3482
3483
3484 # Build tools.
3485 AC_SUBST(AR_FOR_BUILD)
3486 AC_SUBST(AS_FOR_BUILD)
3487 AC_SUBST(CC_FOR_BUILD)
3488 AC_SUBST(CFLAGS_FOR_BUILD)
3489 AC_SUBST(CPP_FOR_BUILD)
3490 AC_SUBST(CPPFLAGS_FOR_BUILD)
3491 AC_SUBST(CXXFLAGS_FOR_BUILD)
3492 AC_SUBST(CXX_FOR_BUILD)
3493 AC_SUBST(DLLTOOL_FOR_BUILD)
3494 AC_SUBST(DSYMUTIL_FOR_BUILD)
3495 AC_SUBST(GFORTRAN_FOR_BUILD)
3496 AC_SUBST(GOC_FOR_BUILD)
3497 AC_SUBST(GDC_FOR_BUILD)
3498 AC_SUBST(LDFLAGS_FOR_BUILD)
3499 AC_SUBST(LD_FOR_BUILD)
3500 AC_SUBST(NM_FOR_BUILD)
3501 AC_SUBST(RANLIB_FOR_BUILD)
3502 AC_SUBST(WINDMC_FOR_BUILD)
3503 AC_SUBST(WINDRES_FOR_BUILD)
3504
3505 # Generate default definitions for YACC, M4, LEX and other programs that run
3506 # on the build machine.  These are used if the Makefile can't locate these
3507 # programs in objdir.
3508 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3509
3510 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3511 case " $build_configdirs " in
3512   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3513 esac
3514
3515 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3516 case " $build_configdirs " in
3517   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3518 esac
3519
3520 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3521 case " $build_configdirs " in
3522   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3523 esac
3524
3525 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3526 case " $build_configdirs " in
3527   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3528   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3529 esac
3530
3531 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3532 case " $build_configdirs " in
3533   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3534 esac
3535
3536 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3537 case " $build_configdirs " in
3538   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3539   *)
3540 changequote(,)
3541     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3542     # higher, else we use the "missing" dummy.
3543     if ${MAKEINFO} --version \
3544        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3545       :
3546     else
3547       MAKEINFO="$MISSING makeinfo"
3548     fi
3549     ;;
3550 changequote([,])
3551 esac
3552
3553 # FIXME: expect and dejagnu may become build tools?
3554
3555 AC_CHECK_PROGS(EXPECT, expect, expect)
3556 case " $configdirs " in
3557   *" expect "*)
3558     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3559     ;;
3560 esac
3561
3562 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3563 case " $configdirs " in
3564   *" dejagnu "*)
3565     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3566     ;;
3567 esac
3568
3569
3570 # Host tools.
3571 NCN_STRICT_CHECK_TOOLS(AR, ar)
3572 NCN_STRICT_CHECK_TOOLS(AS, as)
3573 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3574 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3575 NCN_STRICT_CHECK_TOOLS(LD, ld)
3576 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3577 NCN_STRICT_CHECK_TOOLS(NM, nm)
3578 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3579 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3580 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3581 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3582 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3583 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3584 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3585 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3586 AC_SUBST(CC)
3587 AC_SUBST(CXX)
3588 AC_SUBST(CFLAGS)
3589 AC_SUBST(CXXFLAGS)
3590 AC_SUBST(GDC)
3591 AC_SUBST(GDCFLAGS)
3592
3593 # Target tools.
3594 AC_ARG_WITH([build-time-tools],
3595   [AS_HELP_STRING([--with-build-time-tools=PATH],
3596                   [use given path to find target tools during the build])],
3597   [case x"$withval" in
3598      x/*) ;;
3599      *)
3600        with_build_time_tools=
3601        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3602        ;;
3603    esac],
3604   [with_build_time_tools=])
3605
3606 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3607 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3608 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3609 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3610 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3611 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3612
3613 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3614 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3615 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3616 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3617 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3618 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3619 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3620 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3621 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3622 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3623 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3624 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3625 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3626 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3627 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3628
3629 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3630
3631 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3632 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3633 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3634 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3635 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3636                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3637                 c++)
3638 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3639                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3640                 c++)
3641 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3642 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3643 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3644 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3645                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3646 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3647                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3648 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3649                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3650 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3651 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3652 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3653 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3654 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3655 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3656 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3657 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3658 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3659 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3660 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3661
3662 AC_SUBST(FLAGS_FOR_TARGET)
3663 AC_SUBST(RAW_CXX_FOR_TARGET)
3664
3665 # Certain tools may need extra flags.
3666 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3667 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3668 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3669
3670 # When building target libraries, except in a Canadian cross, we use
3671 # the same toolchain as the compiler we just built.
3672 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3673 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3674 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3675 if test $host = $build; then
3676   case " $configdirs " in
3677     *" gcc "*)
3678       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3679       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3680       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3681       ;;
3682   esac
3683 fi
3684
3685 AC_SUBST(COMPILER_AS_FOR_TARGET)
3686 AC_SUBST(COMPILER_LD_FOR_TARGET)
3687 AC_SUBST(COMPILER_NM_FOR_TARGET)
3688
3689 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3690 AC_ARG_ENABLE(maintainer-mode,
3691 [AS_HELP_STRING([--enable-maintainer-mode],
3692                 [enable make rules and dependencies not useful
3693                  (and sometimes confusing) to the casual installer])],
3694       USE_MAINTAINER_MODE=$enableval,
3695       USE_MAINTAINER_MODE=no)
3696 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3697 AC_SUBST(MAINTAINER_MODE_TRUE)
3698 AC_SUBST(MAINTAINER_MODE_FALSE)
3699 if test "$USE_MAINTAINER_MODE" = yes; then
3700   MAINTAINER_MODE_TRUE=
3701   MAINTAINER_MODE_FALSE='#'
3702 else
3703   MAINTAINER_MODE_TRUE='#'
3704   MAINTAINER_MODE_FALSE=
3705 fi
3706 MAINT=$MAINTAINER_MODE_TRUE
3707 AC_SUBST(MAINT)dnl
3708
3709 # ---------------------
3710 # GCC bootstrap support
3711 # ---------------------
3712
3713 # Stage specific cflags for build.
3714 stage1_cflags="-g"
3715 case $build in
3716   vax-*-*)
3717     case ${GCC} in
3718       yes) stage1_cflags="-g -Wa,-J" ;;
3719       *) stage1_cflags="-g -J" ;;
3720     esac ;;
3721 esac
3722
3723 AC_SUBST(stage1_cflags)
3724
3725 # Enable --enable-checking in stage1 of the compiler.
3726 AC_ARG_ENABLE(stage1-checking,
3727 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3728                 [choose additional checking for stage1 of the compiler])],
3729 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3730 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3731   # For --disable-checking or implicit --enable-checking=release, avoid
3732   # setting --enable-checking=gc in the default stage1 checking for LTO
3733   # bootstraps.  See PR62077.
3734   case $BUILD_CONFIG in
3735     *lto*)
3736       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3737     *)
3738       stage1_checking=--enable-checking=yes,types;;
3739   esac
3740   if test "x$enable_checking" = x && \
3741      test -d ${srcdir}/gcc && \
3742      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3743     stage1_checking=--enable-checking=yes,types,extra
3744   fi
3745 else
3746   stage1_checking=--enable-checking=$enable_checking,types
3747 fi])
3748 AC_SUBST(stage1_checking)
3749
3750 # Enable -Werror in bootstrap stage2 and later.
3751 AC_ARG_ENABLE(werror,
3752 [AS_HELP_STRING([--enable-werror],
3753                 [enable -Werror in bootstrap stage2 and later])],
3754 [
3755 case ${enable_werror} in
3756   yes) stage2_werror_flag="--enable-werror-always" ;;
3757   *) stage2_werror_flag="" ;;
3758 esac
3759 ],
3760 [
3761 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3762   case $BUILD_CONFIG in
3763   bootstrap-debug)
3764       stage2_werror_flag="--enable-werror-always" ;;
3765   "")
3766       stage2_werror_flag="--enable-werror-always" ;;
3767   esac
3768 fi
3769 ])
3770
3771 AC_SUBST(stage2_werror_flag)
3772
3773 # Specify what files to not compare during bootstrap.
3774
3775 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3776 case "$target" in
3777   hppa*64*-*-hpux*) ;;
3778   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3779   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3780 esac
3781 AC_SUBST(compare_exclusions)
3782
3783 AC_CONFIG_FILES([Makefile],
3784   [sed "$extrasub_build" Makefile |
3785    sed "$extrasub_host" |
3786    sed "$extrasub_target" > mf$$
3787    mv -f mf$$ Makefile],
3788   [extrasub_build="$extrasub_build"
3789    extrasub_host="$extrasub_host"
3790    extrasub_target="$extrasub_target"])
3791 AC_OUTPUT