configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [204],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  71
  72 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  73
  74 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  75 m4_ifdef([GTK_DOC_CHECK], [
  76 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  77          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  78           enable_gtk_doc=no])
  79
  80 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  81         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  82 ])
  83
  84 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  85 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  86 ], [
  87    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  88    enable_introspection=no])
  89
  90 AC_CHECK_TOOL(OBJCOPY, objcopy)
  91 AC_CHECK_TOOL(STRINGS, strings)
  92 AC_CHECK_TOOL(GPERF, gperf)
  93 if test -z "$GPERF" ; then
  94         AC_MSG_ERROR([*** gperf not found])
  95 fi
  96
  97 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  98         -pipe \
  99         -Wall \
 100         -Wextra \
 101         -Wno-inline \
 102         -Wundef \
 103         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 104         -Wlogical-op \
 105         -Wsign-compare \
 106         -Wmissing-include-dirs \
 107         -Wold-style-definition \
 108         -Wpointer-arith \
 109         -Winit-self \
 110         -Wdeclaration-after-statement \
 111         -Wfloat-equal \
 112         -Wmissing-prototypes \
 113         -Wstrict-prototypes \
 114         -Wredundant-decls \
 115         -Wmissing-declarations \
 116         -Wmissing-noreturn \
 117         -Wshadow \
 118         -Wendif-labels \
 119         -Wcast-align \
 120         -Wstrict-aliasing=2 \
 121         -Wwrite-strings \
 122         -Wno-long-long \
 123         -Wno-overlength-strings \
 124         -Wno-unused-parameter \
 125         -Wno-missing-field-initializers \
 126         -Wno-unused-result \
 127         -Werror=overflow \
 128         -ffast-math \
 129         -fno-common \
 130         -fdiagnostics-show-option \
 131         -fdiagnostics-color \
 132         -fno-strict-aliasing \
 133         -fvisibility=hidden \
 134         -ffunction-sections \
 135         -fdata-sections \
 136         -fstack-protector \
 137         --param=ssp-buffer-size=4])
 138 AC_SUBST([OUR_CFLAGS], $with_cflags)
 139
 140 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
 141         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 142                -Wp,-D_FORTIFY_SOURCE=2])], [
 143         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 144         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 145 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 146
 147 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 148         -Wl,--as-needed \
 149         -Wl,--no-undefined \
 150         -Wl,--gc-sections \
 151         -Wl,-z,relro \
 152         -Wl,-z,now])
 153 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 154
 155 # ------------------------------------------------------------------------------
 156 # we use python to build the man page index, and for systemd-python
 157 have_python=no
 158 have_python_devel=no
 159
 160 AC_ARG_WITH([python],
 161         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 162
 163 AS_IF([test "x$with_python" != "xno"], [
 164         AM_PATH_PYTHON(,, [:])
 165         AS_IF([test "$PYTHON" != :], [have_python=yes])
 166 ])
 167 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 168 AS_IF([test "x$PYTHON_BINARY" = "x"],
 169       [AS_IF([test "x$have_python" = "xyes"],
 170              [PYTHON_BINARY="$(which "$PYTHON")"],
 171              [PYTHON_BINARY=/usr/bin/python])])
 172 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 173
 174 AS_IF([test "x$with_python" != "xno"], [
 175         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 176         AS_IF([test -n "$PYTHON_CONFIG"], [
 177               have_python_devel=yes
 178               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
 179               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
 180               AC_SUBST(PYTHON_CFLAGS)
 181               AC_SUBST(PYTHON_LIBS)
 182               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 183         ])
 184 ])
 185 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 186
 187 # ------------------------------------------------------------------------------
 188
 189 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 190 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 191
 192 save_LIBS="$LIBS"
 193 LIBS=
 194 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 195 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 196 CAP_LIBS="$LIBS"
 197 LIBS="$save_LIBS"
 198 AC_SUBST(CAP_LIBS)
 199
 200 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 201 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 202 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 203 #include <unistd.h>
 204 #include <sys/mount.h>
 205 #include <fcntl.h>]])
 206
 207 # This makes sure pkg.m4 is available.
 208 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 209
 210 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 211
 212 # ------------------------------------------------------------------------------
 213 have_kmod=no
 214 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 215 if test "x$enable_kmod" != "xno"; then
 216         PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ],
 217                 [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available]) have_kmod=yes], have_kmod=no)
 218         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 219                 AC_MSG_ERROR([*** kmod support requested but libraries not found])
 220         fi
 221 fi
 222 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 223
 224 # ------------------------------------------------------------------------------
 225 have_blkid=no
 226 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 227 if test "x$enable_blkid" != "xno"; then
 228         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 229                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 230         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 231                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 232         fi
 233 fi
 234 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 235
 236 # ------------------------------------------------------------------------------
 237 have_ima=yes
 238 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 239                 [case "${enableval}" in
 240                         yes) have_ima=yes ;;
 241                         no) have_ima=no ;;
 242                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 243                 esac],
 244                 [have_ima=yes])
 245
 246 if test "x${have_ima}" != xno ; then
 247         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 248 fi
 249
 250 # ------------------------------------------------------------------------------
 251 have_chkconfig=yes
 252 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 253                 [case "${enableval}" in
 254                         yes) have_chkconfig=yes ;;
 255                         no) have_chkconfig=no ;;
 256                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 257                 esac],
 258                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 259                 if test -z "$CHKCONFIG"; then
 260                         have_chkconfig=no
 261                 else
 262                         have_chkconfig=yes
 263                 fi])
 264
 265 if test "x${have_chkconfig}" != xno ; then
 266         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 267 fi
 268
 269 # ------------------------------------------------------------------------------
 270 have_selinux=no
 271 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 272 if test "x$enable_selinux" != "xno"; then
 273         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 274                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 275         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 276                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 277         fi
 278 fi
 279 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 280
 281 AC_ARG_WITH(debug-shell,
 282         AS_HELP_STRING([--with-debug-shell=PATH],
 283                 [Path to debug shell binary]),
 284         [SUSHELL="$withval"],[
 285         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 286
 287 AC_SUBST(SUSHELL)
 288
 289 AC_ARG_WITH([debug-tty],
 290         AS_HELP_STRING([--with-debug-tty=PATH],
 291                 [Specify the tty device for debug shell]),
 292         [DEBUGTTY="$withval"],
 293         [DEBUGTTY=/dev/tty9])
 294
 295 AC_SUBST(DEBUGTTY)
 296
 297 # ------------------------------------------------------------------------------
 298 have_xz=no
 299 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 300 if test "x$enable_xz" != "xno"; then
 301         PKG_CHECK_MODULES(XZ, [ liblzma ],
 302                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 303         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 304                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 305         fi
 306 fi
 307 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 308
 309 # ------------------------------------------------------------------------------
 310 AC_ARG_ENABLE([tcpwrap],
 311         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 312                 [case "${enableval}" in
 313                         yes) have_tcpwrap=yes ;;
 314                         no) have_tcpwrap=no ;;
 315                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 316                 esac],
 317                 [have_tcpwrap=auto])
 318
 319 if test "x${have_tcpwrap}" != xno ; then
 320         ACX_LIBWRAP
 321         if test "x${LIBWRAP_LIBS}" = x ; then
 322                 if test "x$have_tcpwrap" = xyes ; then
 323                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 324                 fi
 325                 have_tcpwrap=no
 326         else
 327                 have_tcpwrap=yes
 328         fi
 329 else
 330         LIBWRAP_LIBS=
 331 fi
 332 AC_SUBST(LIBWRAP_LIBS)
 333
 334 # ------------------------------------------------------------------------------
 335 AC_ARG_ENABLE([pam],
 336         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 337                 [case "${enableval}" in
 338                         yes) have_pam=yes ;;
 339                         no) have_pam=no ;;
 340                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 341                 esac],
 342                 [have_pam=auto])
 343
 344 if test "x${have_pam}" != xno ; then
 345         AC_CHECK_HEADERS(
 346                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 347                 [have_pam=yes],
 348                 [if test "x$have_pam" = xyes ; then
 349                         AC_MSG_ERROR([*** PAM headers not found.])
 350                 fi])
 351
 352         AC_CHECK_LIB(
 353                 [pam],
 354                 [pam_syslog],
 355                 [have_pam=yes],
 356                 [if test "x$have_pam" = xyes ; then
 357                         AC_MSG_ERROR([*** libpam not found.])
 358                 fi])
 359
 360         if test "x$have_pam" = xyes ; then
 361                 PAM_LIBS="-lpam -lpam_misc"
 362                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 363         else
 364                 have_pam=no
 365         fi
 366 else
 367         PAM_LIBS=
 368 fi
 369 AC_SUBST(PAM_LIBS)
 370 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 371
 372 # ------------------------------------------------------------------------------
 373 AC_ARG_ENABLE([acl],
 374         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 375                 [case "${enableval}" in
 376                         yes) have_acl=yes ;;
 377                         no) have_acl=no ;;
 378                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 379                 esac],
 380                 [have_acl=auto])
 381
 382 if test "x${have_acl}" != xno ; then
 383         AC_CHECK_HEADERS(
 384                 [sys/acl.h acl/libacl.h],
 385                 [have_acl=yes],
 386                 [if test "x$have_acl" = xyes ; then
 387                         AC_MSG_ERROR([*** ACL headers not found.])
 388                 fi])
 389
 390         AC_CHECK_LIB(
 391                 [acl],
 392                 [acl_get_file],
 393                 [have_acl=yes],
 394                 [if test "x$have_acl" = xyes ; then
 395                         AC_MSG_ERROR([*** libacl not found.])
 396                 fi])
 397
 398         if test "x$have_acl" = xyes ; then
 399                 ACL_LIBS="-lacl"
 400                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 401         else
 402                 have_acl=no
 403         fi
 404 else
 405         ACL_LIBS=
 406 fi
 407 AC_SUBST(ACL_LIBS)
 408 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 409
 410 # ------------------------------------------------------------------------------
 411 AC_ARG_ENABLE([xattr],
 412         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 413                 [case "${enableval}" in
 414                         yes) have_xattr=yes ;;
 415                         no) have_xattr=no ;;
 416                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 417                 esac],
 418                 [have_xattr=auto])
 419
 420 if test "x${have_xattr}" != xno ; then
 421         AC_CHECK_HEADERS(
 422                 [attr/xattr.h],
 423                 [have_xattr=yes],
 424                 [if test "x$have_xattr" = xyes ; then
 425                         AC_MSG_ERROR([*** XATTR headers not found.])
 426                 fi])
 427
 428         AC_CHECK_LIB(
 429                 [attr],
 430                 [fsetxattr],
 431                 [have_xattr=yes],
 432                 [if test "x$have_xattr" = xyes ; then
 433                         AC_MSG_ERROR([*** libattr not found.])
 434                 fi])
 435
 436         if test "x$have_xattr" = xyes ; then
 437                 XATTR_LIBS="-lattr"
 438                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 439         else
 440                 have_xattr=no
 441         fi
 442 else
 443         XATTR_LIBS=
 444 fi
 445 AC_SUBST(XATTR_LIBS)
 446 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 447
 448 # ------------------------------------------------------------------------------
 449 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 450                 [case "${enableval}" in
 451                         yes) have_smack=yes ;;
 452                         no) have_smack=no ;;
 453                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 454                 esac],
 455                 [have_smack=auto])
 456
 457 if test "x${have_xattr}" = xno; then
 458         if test "x${have_smack}" = xyes; then
 459                 AC_MSG_ERROR(SMACK requires xattr support)
 460         else
 461                 have_smack=no
 462         fi
 463 else
 464         if test "x${have_smack}" = xauto; then
 465                 have_smack=yes
 466         fi
 467 fi
 468
 469 if test "x${have_smack}" = xyes ; then
 470         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 471 fi
 472
 473 # ------------------------------------------------------------------------------
 474 AC_ARG_ENABLE([gcrypt],
 475         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 476                 [case "${enableval}" in
 477                         yes) have_gcrypt=yes ;;
 478                         no) have_gcrypt=no ;;
 479                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 480                 esac],
 481                 [have_gcrypt=auto])
 482
 483 if test "x${have_gcrypt}" != xno ; then
 484         AM_PATH_LIBGCRYPT(
 485                 [1.4.5],
 486                 [have_gcrypt=yes],
 487                 [if test "x$have_gcrypt" = xyes ; then
 488                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 489                 fi])
 490
 491         if test "x$have_gcrypt" = xyes ; then
 492                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 493                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 494                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 495         else
 496                 have_gcrypt=no
 497         fi
 498 else
 499         GCRYPT_LIBS=
 500         GCRYPT_CFLAGS=
 501 fi
 502 AC_SUBST(GCRYPT_LIBS)
 503 AC_SUBST(GCRYPT_CFLAGS)
 504 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 505
 506 # ------------------------------------------------------------------------------
 507 AC_ARG_ENABLE([audit],
 508         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 509                 [case "${enableval}" in
 510                         yes) have_audit=yes ;;
 511                         no) have_audit=no ;;
 512                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 513                 esac],
 514                 [have_audit=auto])
 515
 516 if test "x${have_audit}" != xno ; then
 517         AC_CHECK_HEADERS(
 518                 [libaudit.h],
 519                 [have_audit=yes],
 520                 [if test "x$have_audit" = xyes ; then
 521                         AC_MSG_ERROR([*** AUDIT headers not found.])
 522                 fi])
 523
 524         AC_CHECK_LIB(
 525                 [audit],
 526                 [audit_open],
 527                 [have_audit=yes],
 528                 [if test "x$have_audit" = xyes ; then
 529                         AC_MSG_ERROR([*** libaudit not found.])
 530                 fi])
 531
 532         if test "x$have_audit" = xyes ; then
 533                 AUDIT_LIBS="-laudit"
 534                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 535         else
 536                 have_audit=no
 537         fi
 538 else
 539         AUDIT_LIBS=
 540 fi
 541 AC_SUBST(AUDIT_LIBS)
 542
 543 # ------------------------------------------------------------------------------
 544 have_libcryptsetup=no
 545 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 546 if test "x$enable_libcryptsetup" != "xno"; then
 547         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 548                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 549         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 550                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 551         fi
 552 fi
 553 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 554
 555 # ------------------------------------------------------------------------------
 556 have_qrencode=no
 557 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 558 if test "x$enable_qrencode" != "xno"; then
 559         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 560                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 561         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 562                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 563         fi
 564 fi
 565 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 566
 567 # ------------------------------------------------------------------------------
 568 have_microhttpd=no
 569 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 570 if test "x$enable_microhttpd" != "xno"; then
 571         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 572                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 573         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 574                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 575         fi
 576 fi
 577 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 578
 579 # ------------------------------------------------------------------------------
 580 have_binfmt=no
 581 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 582 if test "x$enable_binfmt" != "xno"; then
 583         have_binfmt=yes
 584 fi
 585 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 586
 587 # ------------------------------------------------------------------------------
 588 have_vconsole=no
 589 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 590 if test "x$enable_vconsole" != "xno"; then
 591         have_vconsole=yes
 592 fi
 593 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 594
 595 # ------------------------------------------------------------------------------
 596 have_readahead=no
 597 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 598 if test "x$enable_readahead" != "xno"; then
 599         have_readahead=yes
 600 fi
 601 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 602
 603 # ------------------------------------------------------------------------------
 604 have_bootchart=no
 605 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 606 if test "x$enable_bootchart" != "xno"; then
 607         have_bootchart=yes
 608 fi
 609 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 610
 611 # ------------------------------------------------------------------------------
 612 have_quotacheck=no
 613 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 614 if test "x$enable_quotacheck" != "xno"; then
 615         have_quotacheck=yes
 616 fi
 617 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 618
 619 # ------------------------------------------------------------------------------
 620 have_tmpfiles=no
 621 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 622 if test "x$enable_tmpfiles" != "xno"; then
 623         have_tmpfiles=yes
 624 fi
 625 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 626
 627 # ------------------------------------------------------------------------------
 628 have_randomseed=no
 629 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 630 if test "x$enable_randomseed" != "xno"; then
 631         have_randomseed=yes
 632 fi
 633 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 634
 635 # ------------------------------------------------------------------------------
 636 have_logind=no
 637 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 638 if test "x$enable_logind" != "xno"; then
 639         have_logind=yes
 640 fi
 641 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 642 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 643
 644 # ------------------------------------------------------------------------------
 645 have_hostnamed=no
 646 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 647 if test "x$enable_hostnamed" != "xno"; then
 648         have_hostnamed=yes
 649 fi
 650 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 651
 652 # ------------------------------------------------------------------------------
 653 have_timedated=no
 654 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 655 if test "x$enable_timedated" != "xno"; then
 656         have_timedated=yes
 657 fi
 658 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 659
 660 # ------------------------------------------------------------------------------
 661 have_localed=no
 662 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 663 if test "x$enable_localed" != "xno"; then
 664         have_localed=yes
 665 fi
 666 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 667
 668 # ------------------------------------------------------------------------------
 669 have_coredump=no
 670 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 671 if test "x$enable_coredump" != "xno"; then
 672         have_coredump=yes
 673 fi
 674 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 675
 676 # ------------------------------------------------------------------------------
 677 have_polkit=no
 678 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 679 if test "x$enable_polkit" != "xno"; then
 680         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 681         have_polkit=yes
 682 fi
 683 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 684
 685 # ------------------------------------------------------------------------------
 686 have_efi=no
 687 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 688 if test "x$enable_efi" != "xno"; then
 689         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 690         have_efi=yes
 691 fi
 692 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 693
 694 # ------------------------------------------------------------------------------
 695 AC_ARG_WITH(rc-local-script-path-start,
 696         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 697                 [Path to /etc/rc.local]),
 698         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 699         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 700
 701 AC_ARG_WITH(rc-local-script-path-stop,
 702         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 703                 [Path to /usr/sbin/halt.local]),
 704         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 705         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 706
 707 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 708 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 709
 710 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 711 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 712
 713 # ------------------------------------------------------------------------------
 714 AC_ARG_WITH(kbd-loadkeys,
 715         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 716                 [Path to loadkeys]),
 717         [KBD_LOADKEYS="$withval"],
 718         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 719
 720 AC_ARG_WITH(kbd-setfont,
 721         AS_HELP_STRING([--with-kbd-setfont=PATH],
 722                 [Path to setfont]),
 723         [KBD_SETFONT="$withval"],
 724         [KBD_SETFONT="/usr/bin/setfont"])
 725
 726 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 727 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 728
 729 AC_SUBST(KBD_LOADKEYS)
 730 AC_SUBST(KBD_SETFONT)
 731
 732 AC_ARG_WITH(telinit,
 733         AS_HELP_STRING([--with-telinit=PATH],
 734                 [Path to telinit]),
 735         [TELINIT="$withval"],
 736         [TELINIT="/lib/upstart/telinit"])
 737
 738 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 739
 740 AC_SUBST(TELINIT)
 741
 742 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 743
 744 # ------------------------------------------------------------------------------
 745 have_myhostname=no
 746 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 747 if test "x$enable_myhostname" != "xno"; then
 748         AC_HEADER_STDC
 749         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 750
 751         AC_C_CONST
 752         AC_TYPE_SIZE_T
 753         AC_HEADER_TIME
 754
 755         AC_FUNC_MALLOC
 756         AC_FUNC_SELECT_ARGTYPES
 757         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 758
 759         have_myhostname=yes
 760 fi
 761 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 762
 763 # ------------------------------------------------------------------------------
 764 AC_ARG_WITH(firmware-path,
 765        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 766           [Firmware search path (default="")]),
 767        [], [with_firmware_path=""])
 768 OLD_IFS=$IFS
 769 IFS=:
 770 for i in $with_firmware_path; do
 771        if test "x${FIRMWARE_PATH}" = "x"; then
 772               FIRMWARE_PATH="\\\"${i}/\\\""
 773        else
 774               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 775        fi
 776 done
 777 IFS=$OLD_IFS
 778 AC_SUBST(FIRMWARE_PATH)
 779 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 780 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 781
 782 # ------------------------------------------------------------------------------
 783 AC_ARG_ENABLE([gudev],
 784        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 785        [], [enable_gudev=yes])
 786 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 787 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 788 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 789
 790 # ------------------------------------------------------------------------------
 791 AC_ARG_ENABLE([keymap],
 792        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 793        [], [enable_keymap=yes])
 794 AS_IF([test "x$enable_keymap" = "xyes"], [
 795        AC_PATH_PROG([GPERF], [gperf])
 796        if test -z "$GPERF"; then
 797               AC_MSG_ERROR([gperf is needed])
 798        fi
 799
 800        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 801        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 802 ])
 803 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 804
 805 # ------------------------------------------------------------------------------
 806 have_manpages=no
 807 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 808 AS_IF([test "x$enable_manpages" != xno], [
 809         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 810                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 811         ])
 812         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 813 ])
 814 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 815
 816 # ------------------------------------------------------------------------------
 817
 818 # Location of the init scripts as mandated by LSB
 819 SYSTEM_SYSVINIT_PATH=/etc/init.d
 820 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 821 M4_DEFINES=
 822
 823 AC_ARG_WITH([sysvinit-path],
 824         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 825                 [Specify the path to where the SysV init scripts are located])],
 826         [SYSTEM_SYSVINIT_PATH="$withval"],
 827         [])
 828
 829 AC_ARG_WITH([sysvrcnd-path],
 830         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 831                 [Specify the path to the base directory for the SysV rcN.d directories])],
 832         [SYSTEM_SYSVRCND_PATH="$withval"],
 833         [])
 834
 835 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 836         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 837         SYSTEM_SYSV_COMPAT="yes"
 838         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 839 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 840         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 841 else
 842         SYSTEM_SYSV_COMPAT="no"
 843 fi
 844
 845 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 846 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 847 AC_SUBST(M4_DEFINES)
 848
 849 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 850
 851 AC_ARG_WITH([tty-gid],
 852         [AS_HELP_STRING([--with-tty-gid=GID],
 853                 [Specify the numeric GID of the 'tty' group])],
 854         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 855         [])
 856
 857 AC_ARG_WITH([dbuspolicydir],
 858         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 859         [],
 860         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 861
 862 AC_ARG_WITH([dbussessionservicedir],
 863         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 864         [],
 865         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 866
 867 AC_ARG_WITH([dbussystemservicedir],
 868         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 869         [],
 870         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 871
 872 AC_ARG_WITH([dbusinterfacedir],
 873         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 874         [],
 875         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 876
 877 AC_ARG_WITH([bashcompletiondir],
 878         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 879         [],
 880         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 881                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 882         ] , [
 883                 with_bashcompletiondir=${datadir}/bash-completion/completions
 884         ])])
 885
 886 AC_ARG_WITH([rootprefix],
 887         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 888         [], [with_rootprefix=${ac_default_prefix}])
 889
 890 AC_ARG_WITH([rootlibdir],
 891         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 892         [],
 893         [with_rootlibdir=${libdir}])
 894
 895 AC_ARG_WITH([pamlibdir],
 896         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 897         [],
 898         [with_pamlibdir=${with_rootlibdir}/security])
 899
 900 AC_ARG_ENABLE([split-usr],
 901         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 902         [],
 903         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 904                 enable_split_usr=yes
 905         ], [
 906                 enable_split_usr=no
 907         ])])
 908
 909 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 910         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 911 ])
 912
 913 # Work around intltoolize and gtk-doc problems in VPATH builds
 914 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 915                                        [Define to do gtk-doc tests])
 916 AS_IF([test "x$0" != "x./configure"], [
 917         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 918 ])
 919
 920 AC_ARG_ENABLE(tests,
 921        [AC_HELP_STRING([--disable-tests], [disable tests])],
 922        enable_tests=$enableval, enable_tests=yes)
 923 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 924
 925 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 926 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 927 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 928 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 929 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 930 AC_SUBST([pamlibdir], [$with_pamlibdir])
 931 AC_SUBST([rootprefix], [$with_rootprefix])
 932 AC_SUBST([rootlibdir], [$with_rootlibdir])
 933
 934 AC_CONFIG_FILES([
 935         Makefile po/Makefile.in
 936         docs/libudev/Makefile
 937         docs/libudev/version.xml
 938         docs/gudev/Makefile
 939         docs/gudev/version.xml
 940 ])
 941
 942 AC_OUTPUT
 943 AC_MSG_RESULT([
 944         $PACKAGE_NAME $VERSION
 945
 946         libcryptsetup:           ${have_libcryptsetup}
 947         tcpwrap:                 ${have_tcpwrap}
 948         PAM:                     ${have_pam}
 949         AUDIT:                   ${have_audit}
 950         IMA:                     ${have_ima}
 951         SELinux:                 ${have_selinux}
 952         SMACK:                   ${have_smack}
 953         XZ:                      ${have_xz}
 954         ACL:                     ${have_acl}
 955         XATTR:                   ${have_xattr}
 956         GCRYPT:                  ${have_gcrypt}
 957         QRENCODE:                ${have_qrencode}
 958         MICROHTTPD:              ${have_microhttpd}
 959         CHKCONFIG:               ${have_chkconfig}
 960         binfmt:                  ${have_binfmt}
 961         vconsole:                ${have_vconsole}
 962         readahead:               ${have_readahead}
 963         bootchart:               ${have_bootchart}
 964         quotacheck:              ${have_quotacheck}
 965         tmpfiles:                ${have_tmpfiles}
 966         randomseed:              ${have_randomseed}
 967         logind:                  ${have_logind}
 968         hostnamed:               ${have_hostnamed}
 969         timedated:               ${have_timedated}
 970         localed:                 ${have_localed}
 971         coredump:                ${have_coredump}
 972         polkit:                  ${have_polkit}
 973         efi:                     ${have_efi}
 974         kmod:                    ${have_kmod}
 975         blkid:                   ${have_blkid}
 976         nss-myhostname:          ${have_myhostname}
 977         gudev:                   ${enable_gudev}
 978         gintrospection:          ${enable_introspection}
 979         keymap:                  ${enable_keymap}
 980         Python:                  ${have_python}
 981         Python Headers:          ${have_python_devel}
 982         man pages:               ${have_manpages}
 983         gtk-doc:                 ${enable_gtk_doc}
 984         Split /usr:              ${enable_split_usr}
 985         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 986
 987         prefix:                  ${prefix}
 988         rootprefix:              ${with_rootprefix}
 989         sysconf dir:             ${sysconfdir}
 990         datarootdir:             ${datarootdir}
 991         includedir:              ${includedir}
 992         include_prefix:          ${INCLUDE_PREFIX}
 993         lib dir:                 ${libdir}
 994         rootlib dir:             ${with_rootlibdir}
 995         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 996         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 997         Build Python:            ${PYTHON}
 998         Installation Python:     ${PYTHON_BINARY}
 999         firmware path:           ${FIRMWARE_PATH}
1000         PAM modules dir:         ${with_pamlibdir}
1001         D-Bus policy dir:        ${with_dbuspolicydir}
1002         D-Bus session dir:       ${with_dbussessionservicedir}
1003         D-Bus system dir:        ${with_dbussystemservicedir}
1004         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1005         Bash completions dir:    ${with_bashcompletiondir}
1006         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1007         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1008         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1009
1010         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1011         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1012         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1013         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
1014         PYTHON_LIBS:             ${PYTHON_LIBS}
1015 ])