configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [207],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(OBJCOPY, objcopy)
  98 AC_CHECK_TOOL(STRINGS, strings)
  99 AC_CHECK_TOOL(GPERF, gperf)
 100 if test -z "$GPERF" ; then
 101         AC_MSG_ERROR([*** gperf not found])
 102 fi
 103
 104 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 105         -pipe \
 106         -Wall \
 107         -Wextra \
 108         -Wno-inline \
 109         -Wundef \
 110         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 111         -Wlogical-op \
 112         -Wsign-compare \
 113         -Wmissing-include-dirs \
 114         -Wold-style-definition \
 115         -Wpointer-arith \
 116         -Winit-self \
 117         -Wdeclaration-after-statement \
 118         -Wfloat-equal \
 119         -Wmissing-prototypes \
 120         -Wstrict-prototypes \
 121         -Wredundant-decls \
 122         -Wmissing-declarations \
 123         -Wmissing-noreturn \
 124         -Wshadow \
 125         -Wendif-labels \
 126         -Wcast-align \
 127         -Wstrict-aliasing=2 \
 128         -Wwrite-strings \
 129         -Wno-long-long \
 130         -Wno-overlength-strings \
 131         -Wno-unused-parameter \
 132         -Wno-missing-field-initializers \
 133         -Wno-unused-result \
 134         -Werror=overflow \
 135         -ffast-math \
 136         -fno-common \
 137         -fdiagnostics-show-option \
 138         -fdiagnostics-color \
 139         -fno-strict-aliasing \
 140         -fvisibility=hidden \
 141         -ffunction-sections \
 142         -fdata-sections \
 143         -fstack-protector \
 144         --param=ssp-buffer-size=4])
 145 AC_SUBST([OUR_CFLAGS], $with_cflags)
 146
 147 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 148         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 149                -Wp,-D_FORTIFY_SOURCE=2])],
 150         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 151 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 152
 153 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 154         -Wl,--as-needed \
 155         -Wl,--no-undefined \
 156         -Wl,--gc-sections \
 157         -Wl,-z,relro \
 158         -Wl,-z,now])
 159 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 160
 161 # ------------------------------------------------------------------------------
 162 # we use python to build the man page index, and for systemd-python
 163 have_python=no
 164 AC_ARG_WITH([python],
 165         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 166
 167 AS_IF([test "x$with_python" != "xno"], [
 168         AM_PATH_PYTHON(,, [:])
 169         AS_IF([test "$PYTHON" != :], [have_python=yes])
 170 ])
 171 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 172 AS_IF([test "x$PYTHON_BINARY" = "x"],
 173       [AS_IF([test "x$have_python" = "xyes"],
 174              [PYTHON_BINARY="$(which "$PYTHON")"],
 175              [PYTHON_BINARY=/usr/bin/python])])
 176 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 177
 178 have_python_devel=no
 179 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 180 AS_IF([test "x$enable_python_devel" != "xno"], [
 181       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 182             [have_python_devel=yes],
 183             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 184                   [have_python_devel=yes],
 185                   [have_python_devel=no])])
 186       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 187             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 188 ])
 189 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 190
 191 # ------------------------------------------------------------------------------
 192
 193 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 194 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 195 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 196
 197 # unconditionally pull-in librt with old glibc versions
 198 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 199
 200 save_LIBS="$LIBS"
 201 LIBS=
 202 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 203 CAP_LIBS="$LIBS"
 204 AC_SUBST(CAP_LIBS)
 205
 206 LIBS=
 207 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 208 RT_LIBS="$LIBS"
 209 AC_SUBST(RT_LIBS)
 210 LIBS="$save_LIBS"
 211
 212 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 213 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 214 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 215 #include <unistd.h>
 216 #include <sys/mount.h>
 217 #include <fcntl.h>]])
 218
 219 # This makes sure pkg.m4 is available.
 220 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 221
 222 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 223
 224
 225 # ------------------------------------------------------------------------------
 226 have_coverage=no
 227 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 228 if test "x$enable_coverage" = "xyes" ; then
 229         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 230         if test "x$lcov_found" = xno ; then
 231                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 232         else
 233                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 234                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 235                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 236                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 237                 else
 238                         have_coverage=yes
 239                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 240                         -fprofile-arcs \
 241                         -ftest-coverage])
 242                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 243                 fi
 244         fi
 245 fi
 246 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 247
 248 # ------------------------------------------------------------------------------
 249 have_kmod=no
 250 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 251 if test "x$enable_kmod" != "xno"; then
 252         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 253         if test "x$have_kmod" = "xyes"; then
 254                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 255                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 256                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 257         fi
 258         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 259                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 260         fi
 261 fi
 262 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 263
 264 # ------------------------------------------------------------------------------
 265 have_blkid=no
 266 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 267 if test "x$enable_blkid" != "xno"; then
 268         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 269                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 270         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 271                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 272         fi
 273 fi
 274 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 275
 276 # ------------------------------------------------------------------------------
 277 have_ima=yes
 278 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 279                 [case "${enableval}" in
 280                         yes) have_ima=yes ;;
 281                         no) have_ima=no ;;
 282                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 283                 esac],
 284                 [have_ima=yes])
 285
 286 if test "x${have_ima}" != xno ; then
 287         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 288 fi
 289
 290 # ------------------------------------------------------------------------------
 291 have_chkconfig=yes
 292 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 293                 [case "${enableval}" in
 294                         yes) have_chkconfig=yes ;;
 295                         no) have_chkconfig=no ;;
 296                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 297                 esac],
 298                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 299                 if test -z "$CHKCONFIG"; then
 300                         have_chkconfig=no
 301                 else
 302                         have_chkconfig=yes
 303                 fi])
 304
 305 if test "x${have_chkconfig}" != xno ; then
 306         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 307 fi
 308
 309 # ------------------------------------------------------------------------------
 310 have_selinux=no
 311 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 312 if test "x$enable_selinux" != "xno"; then
 313         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 314                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 315         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 316                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 317         fi
 318 fi
 319 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 320
 321 AC_ARG_WITH(debug-shell,
 322         AS_HELP_STRING([--with-debug-shell=PATH],
 323                 [Path to debug shell binary]),
 324         [SUSHELL="$withval"],[
 325         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 326
 327 AC_SUBST(SUSHELL)
 328
 329 AC_ARG_WITH([debug-tty],
 330         AS_HELP_STRING([--with-debug-tty=PATH],
 331                 [Specify the tty device for debug shell]),
 332         [DEBUGTTY="$withval"],
 333         [DEBUGTTY=/dev/tty9])
 334
 335 AC_SUBST(DEBUGTTY)
 336
 337 # ------------------------------------------------------------------------------
 338 have_xz=no
 339 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 340 if test "x$enable_xz" != "xno"; then
 341         PKG_CHECK_MODULES(XZ, [ liblzma ],
 342                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 343         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 344                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 345         fi
 346 fi
 347 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 348
 349 # ------------------------------------------------------------------------------
 350 AC_ARG_ENABLE([tcpwrap],
 351         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 352                 [case "${enableval}" in
 353                         yes) have_tcpwrap=yes ;;
 354                         no) have_tcpwrap=no ;;
 355                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 356                 esac],
 357                 [have_tcpwrap=auto])
 358
 359 if test "x${have_tcpwrap}" != xno ; then
 360         ACX_LIBWRAP
 361         if test "x${LIBWRAP_LIBS}" = x ; then
 362                 if test "x$have_tcpwrap" = xyes ; then
 363                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 364                 fi
 365                 have_tcpwrap=no
 366         else
 367                 have_tcpwrap=yes
 368         fi
 369 else
 370         LIBWRAP_LIBS=
 371 fi
 372 AC_SUBST(LIBWRAP_LIBS)
 373
 374 # ------------------------------------------------------------------------------
 375 AC_ARG_ENABLE([pam],
 376         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 377                 [case "${enableval}" in
 378                         yes) have_pam=yes ;;
 379                         no) have_pam=no ;;
 380                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 381                 esac],
 382                 [have_pam=auto])
 383
 384 if test "x${have_pam}" != xno ; then
 385         AC_CHECK_HEADERS(
 386                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 387                 [have_pam=yes],
 388                 [if test "x$have_pam" = xyes ; then
 389                         AC_MSG_ERROR([*** PAM headers not found.])
 390                 fi])
 391
 392         AC_CHECK_LIB(
 393                 [pam],
 394                 [pam_syslog],
 395                 [have_pam=yes],
 396                 [if test "x$have_pam" = xyes ; then
 397                         AC_MSG_ERROR([*** libpam not found.])
 398                 fi])
 399
 400         if test "x$have_pam" = xyes ; then
 401                 PAM_LIBS="-lpam -lpam_misc"
 402                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 403         else
 404                 have_pam=no
 405         fi
 406 else
 407         PAM_LIBS=
 408 fi
 409 AC_SUBST(PAM_LIBS)
 410 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 411
 412 # ------------------------------------------------------------------------------
 413 AC_ARG_ENABLE([acl],
 414         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 415                 [case "${enableval}" in
 416                         yes) have_acl=yes ;;
 417                         no) have_acl=no ;;
 418                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 419                 esac],
 420                 [have_acl=auto])
 421
 422 if test "x${have_acl}" != xno ; then
 423         AC_CHECK_HEADERS(
 424                 [sys/acl.h acl/libacl.h],
 425                 [have_acl=yes],
 426                 [if test "x$have_acl" = xyes ; then
 427                         AC_MSG_ERROR([*** ACL headers not found.])
 428                 fi])
 429
 430         AC_CHECK_LIB(
 431                 [acl],
 432                 [acl_get_file],
 433                 [have_acl=yes],
 434                 [if test "x$have_acl" = xyes ; then
 435                         AC_MSG_ERROR([*** libacl not found.])
 436                 fi])
 437
 438         if test "x$have_acl" = xyes ; then
 439                 ACL_LIBS="-lacl"
 440                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 441         else
 442                 have_acl=no
 443         fi
 444 else
 445         ACL_LIBS=
 446 fi
 447 AC_SUBST(ACL_LIBS)
 448 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 449
 450 # ------------------------------------------------------------------------------
 451 AC_ARG_ENABLE([xattr],
 452         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 453                 [case "${enableval}" in
 454                         yes) have_xattr=yes ;;
 455                         no) have_xattr=no ;;
 456                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 457                 esac],
 458                 [have_xattr=auto])
 459
 460 if test "x${have_xattr}" != xno ; then
 461         AC_CHECK_HEADERS(
 462                 [attr/xattr.h],
 463                 [have_xattr=yes],
 464                 [if test "x$have_xattr" = xyes ; then
 465                         AC_MSG_ERROR([*** XATTR headers not found.])
 466                 fi])
 467
 468         AC_CHECK_LIB(
 469                 [attr],
 470                 [fsetxattr],
 471                 [have_xattr=yes],
 472                 [if test "x$have_xattr" = xyes ; then
 473                         AC_MSG_ERROR([*** libattr not found.])
 474                 fi])
 475
 476         if test "x$have_xattr" = xyes ; then
 477                 XATTR_LIBS="-lattr"
 478                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 479         else
 480                 have_xattr=no
 481         fi
 482 else
 483         XATTR_LIBS=
 484 fi
 485 AC_SUBST(XATTR_LIBS)
 486 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 487
 488 # ------------------------------------------------------------------------------
 489 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 490                 [case "${enableval}" in
 491                         yes) have_smack=yes ;;
 492                         no) have_smack=no ;;
 493                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 494                 esac],
 495                 [have_smack=auto])
 496
 497 if test "x${have_xattr}" = xno; then
 498         if test "x${have_smack}" = xyes; then
 499                 AC_MSG_ERROR(SMACK requires xattr support)
 500         else
 501                 have_smack=no
 502         fi
 503 else
 504         if test "x${have_smack}" = xauto; then
 505                 have_smack=yes
 506         fi
 507 fi
 508
 509 if test "x${have_smack}" = xyes ; then
 510         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 511 fi
 512
 513 # ------------------------------------------------------------------------------
 514 AC_ARG_ENABLE([gcrypt],
 515         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 516                 [case "${enableval}" in
 517                         yes) have_gcrypt=yes ;;
 518                         no) have_gcrypt=no ;;
 519                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 520                 esac],
 521                 [have_gcrypt=auto])
 522
 523 if test "x${have_gcrypt}" != xno ; then
 524         AM_PATH_LIBGCRYPT(
 525                 [1.4.5],
 526                 [have_gcrypt=yes],
 527                 [if test "x$have_gcrypt" = xyes ; then
 528                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 529                 fi])
 530
 531         if test "x$have_gcrypt" = xyes ; then
 532                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 533                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 534                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 535         else
 536                 have_gcrypt=no
 537         fi
 538 else
 539         GCRYPT_LIBS=
 540         GCRYPT_CFLAGS=
 541 fi
 542 AC_SUBST(GCRYPT_LIBS)
 543 AC_SUBST(GCRYPT_CFLAGS)
 544 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 545
 546 # ------------------------------------------------------------------------------
 547 AC_ARG_ENABLE([audit],
 548         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 549                 [case "${enableval}" in
 550                         yes) have_audit=yes ;;
 551                         no) have_audit=no ;;
 552                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 553                 esac],
 554                 [have_audit=auto])
 555
 556 if test "x${have_audit}" != xno ; then
 557         AC_CHECK_HEADERS(
 558                 [libaudit.h],
 559                 [have_audit=yes],
 560                 [if test "x$have_audit" = xyes ; then
 561                         AC_MSG_ERROR([*** AUDIT headers not found.])
 562                 fi])
 563
 564         AC_CHECK_LIB(
 565                 [audit],
 566                 [audit_open],
 567                 [have_audit=yes],
 568                 [if test "x$have_audit" = xyes ; then
 569                         AC_MSG_ERROR([*** libaudit not found.])
 570                 fi])
 571
 572         if test "x$have_audit" = xyes ; then
 573                 AUDIT_LIBS="-laudit"
 574                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 575         else
 576                 have_audit=no
 577         fi
 578 else
 579         AUDIT_LIBS=
 580 fi
 581 AC_SUBST(AUDIT_LIBS)
 582
 583 # ------------------------------------------------------------------------------
 584 have_libcryptsetup=no
 585 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 586 if test "x$enable_libcryptsetup" != "xno"; then
 587         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 588                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 589         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 590                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 591         fi
 592 fi
 593 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 594
 595 # ------------------------------------------------------------------------------
 596 have_qrencode=no
 597 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 598 if test "x$enable_qrencode" != "xno"; then
 599         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 600                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 601         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 602                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 603         fi
 604 fi
 605 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 606
 607 # ------------------------------------------------------------------------------
 608 have_microhttpd=no
 609 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 610 if test "x$enable_microhttpd" != "xno"; then
 611         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 612                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 613         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 614                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 615         fi
 616 fi
 617 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 618
 619 # ------------------------------------------------------------------------------
 620 have_binfmt=no
 621 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 622 if test "x$enable_binfmt" != "xno"; then
 623         have_binfmt=yes
 624 fi
 625 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 626
 627 # ------------------------------------------------------------------------------
 628 have_vconsole=no
 629 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 630 if test "x$enable_vconsole" != "xno"; then
 631         have_vconsole=yes
 632 fi
 633 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 634
 635 # ------------------------------------------------------------------------------
 636 have_readahead=no
 637 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 638 if test "x$enable_readahead" != "xno"; then
 639         have_readahead=yes
 640 fi
 641 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 642
 643 # ------------------------------------------------------------------------------
 644 have_bootchart=no
 645 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 646 if test "x$enable_bootchart" != "xno"; then
 647         have_bootchart=yes
 648 fi
 649 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 650
 651 # ------------------------------------------------------------------------------
 652 have_quotacheck=no
 653 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 654 if test "x$enable_quotacheck" != "xno"; then
 655         have_quotacheck=yes
 656 fi
 657 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 658
 659 # ------------------------------------------------------------------------------
 660 have_tmpfiles=no
 661 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 662 if test "x$enable_tmpfiles" != "xno"; then
 663         have_tmpfiles=yes
 664 fi
 665 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 666
 667 # ------------------------------------------------------------------------------
 668 have_randomseed=no
 669 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 670 if test "x$enable_randomseed" != "xno"; then
 671         have_randomseed=yes
 672 fi
 673 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 674
 675 # ------------------------------------------------------------------------------
 676 have_backlight=no
 677 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 678 if test "x$enable_backlight" != "xno"; then
 679         have_backlight=yes
 680 fi
 681 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 682
 683 # ------------------------------------------------------------------------------
 684 have_logind=no
 685 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 686 if test "x$enable_logind" != "xno"; then
 687         have_logind=yes
 688 fi
 689 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 690 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 691
 692 # ------------------------------------------------------------------------------
 693 have_machined=no
 694 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 695 if test "x$enable_machined" != "xno"; then
 696         have_machined=yes
 697 fi
 698 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 699 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 700
 701 # ------------------------------------------------------------------------------
 702 have_hostnamed=no
 703 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 704 if test "x$enable_hostnamed" != "xno"; then
 705         have_hostnamed=yes
 706 fi
 707 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 708
 709 # ------------------------------------------------------------------------------
 710 have_timedated=no
 711 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 712 if test "x$enable_timedated" != "xno"; then
 713         have_timedated=yes
 714 fi
 715 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 716
 717 # ------------------------------------------------------------------------------
 718 have_localed=no
 719 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 720 if test "x$enable_localed" != "xno"; then
 721         have_localed=yes
 722 fi
 723 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 724
 725 # ------------------------------------------------------------------------------
 726 have_coredump=no
 727 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 728 if test "x$enable_coredump" != "xno"; then
 729         have_coredump=yes
 730 fi
 731 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 732
 733 # ------------------------------------------------------------------------------
 734 have_polkit=no
 735 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 736 if test "x$enable_polkit" != "xno"; then
 737         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 738         have_polkit=yes
 739 fi
 740 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 741
 742 # ------------------------------------------------------------------------------
 743 have_efi=no
 744 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 745 if test "x$enable_efi" != "xno"; then
 746         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 747         have_efi=yes
 748 fi
 749 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 750
 751 # ------------------------------------------------------------------------------
 752 AC_ARG_WITH(rc-local-script-path-start,
 753         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 754                 [Path to /etc/rc.local]),
 755         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 756         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 757
 758 AC_ARG_WITH(rc-local-script-path-stop,
 759         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 760                 [Path to /usr/sbin/halt.local]),
 761         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 762         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 763
 764 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 765 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 766
 767 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 768 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 769
 770 # ------------------------------------------------------------------------------
 771 AC_ARG_WITH(kbd-loadkeys,
 772         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 773                 [Path to loadkeys]),
 774         [KBD_LOADKEYS="$withval"],
 775         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 776
 777 AC_ARG_WITH(kbd-setfont,
 778         AS_HELP_STRING([--with-kbd-setfont=PATH],
 779                 [Path to setfont]),
 780         [KBD_SETFONT="$withval"],
 781         [KBD_SETFONT="/usr/bin/setfont"])
 782
 783 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 784 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 785
 786 AC_SUBST(KBD_LOADKEYS)
 787 AC_SUBST(KBD_SETFONT)
 788
 789 AC_ARG_WITH(telinit,
 790         AS_HELP_STRING([--with-telinit=PATH],
 791                 [Path to telinit]),
 792         [TELINIT="$withval"],
 793         [TELINIT="/lib/upstart/telinit"])
 794
 795 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 796
 797 AC_SUBST(TELINIT)
 798
 799 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 800
 801 # ------------------------------------------------------------------------------
 802 have_myhostname=no
 803 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 804 if test "x$enable_myhostname" != "xno"; then
 805         AC_HEADER_STDC
 806         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 807
 808         AC_C_CONST
 809         AC_TYPE_SIZE_T
 810         AC_HEADER_TIME
 811
 812         AC_FUNC_MALLOC
 813         AC_FUNC_SELECT_ARGTYPES
 814         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 815
 816         have_myhostname=yes
 817 fi
 818 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 819
 820 # ------------------------------------------------------------------------------
 821 AC_ARG_WITH(firmware-path,
 822        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 823           [Firmware search path (default="")]),
 824        [], [with_firmware_path=""])
 825 OLD_IFS=$IFS
 826 IFS=:
 827 for i in $with_firmware_path; do
 828        if test "x${FIRMWARE_PATH}" = "x"; then
 829               FIRMWARE_PATH="\\\"${i}/\\\""
 830        else
 831               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 832        fi
 833 done
 834 IFS=$OLD_IFS
 835 AC_SUBST(FIRMWARE_PATH)
 836 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 837 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 838
 839 # ------------------------------------------------------------------------------
 840 AC_ARG_ENABLE([gudev],
 841        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 842        [], [enable_gudev=yes])
 843 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 844 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 845 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 846
 847 # ------------------------------------------------------------------------------
 848 have_manpages=no
 849 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 850 AS_IF([test "x$enable_manpages" != xno], [
 851         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 852                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 853         ])
 854         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 855 ])
 856 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 857
 858 # ------------------------------------------------------------------------------
 859
 860 # Location of the init scripts as mandated by LSB
 861 SYSTEM_SYSVINIT_PATH=/etc/init.d
 862 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 863 M4_DEFINES=
 864
 865 AC_ARG_WITH([sysvinit-path],
 866         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 867                 [Specify the path to where the SysV init scripts are located])],
 868         [SYSTEM_SYSVINIT_PATH="$withval"],
 869         [])
 870
 871 AC_ARG_WITH([sysvrcnd-path],
 872         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 873                 [Specify the path to the base directory for the SysV rcN.d directories])],
 874         [SYSTEM_SYSVRCND_PATH="$withval"],
 875         [])
 876
 877 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 878         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 879         SYSTEM_SYSV_COMPAT="yes"
 880         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 881 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 882         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 883 else
 884         SYSTEM_SYSV_COMPAT="no"
 885 fi
 886
 887 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 888 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 889 AC_SUBST(M4_DEFINES)
 890
 891 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 892
 893 AC_ARG_WITH([tty-gid],
 894         [AS_HELP_STRING([--with-tty-gid=GID],
 895                 [Specify the numeric GID of the 'tty' group])],
 896         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 897         [])
 898
 899 AC_ARG_WITH([dbuspolicydir],
 900         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 901         [],
 902         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 903
 904 AC_ARG_WITH([dbussessionservicedir],
 905         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 906         [],
 907         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 908
 909 AC_ARG_WITH([dbussystemservicedir],
 910         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 911         [],
 912         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 913
 914 AC_ARG_WITH([dbusinterfacedir],
 915         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 916         [],
 917         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 918
 919 AC_ARG_WITH([bashcompletiondir],
 920         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 921         [],
 922         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 923                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 924         ] , [
 925                 with_bashcompletiondir=${datadir}/bash-completion/completions
 926         ])])
 927
 928 AC_ARG_WITH([zshcompletiondir],
 929         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 930         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 931
 932 AC_ARG_WITH([rootprefix],
 933         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 934         [], [with_rootprefix=${ac_default_prefix}])
 935
 936 AC_ARG_WITH([rootlibdir],
 937         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 938         [],
 939         [with_rootlibdir=${libdir}])
 940
 941 AC_ARG_WITH([pamlibdir],
 942         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 943         [],
 944         [with_pamlibdir=${with_rootlibdir}/security])
 945
 946 AC_ARG_WITH([pamconfdir],
 947         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 948         [],
 949         [with_pamconfdir=${sysconfdir}/pam.d])
 950
 951 AC_ARG_ENABLE([split-usr],
 952         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 953         [],
 954         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 955                 enable_split_usr=yes
 956         ], [
 957                 enable_split_usr=no
 958         ])])
 959
 960 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 961         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 962 ])
 963
 964 # Work around intltoolize and gtk-doc problems in VPATH builds
 965 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 966                                        [Define to do gtk-doc tests])
 967 AS_IF([test "x$0" != "x./configure"], [
 968         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 969 ])
 970
 971 AC_ARG_ENABLE(tests,
 972        [AC_HELP_STRING([--disable-tests], [disable tests])],
 973        enable_tests=$enableval, enable_tests=yes)
 974 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 975
 976 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 977 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 978 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 979 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 980 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 981 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 982 AC_SUBST([pamlibdir], [$with_pamlibdir])
 983 AC_SUBST([pamconfdir], [$with_pamconfdir])
 984 AC_SUBST([rootprefix], [$with_rootprefix])
 985 AC_SUBST([rootlibdir], [$with_rootlibdir])
 986
 987 AC_CONFIG_FILES([
 988         Makefile po/Makefile.in
 989         docs/libudev/Makefile
 990         docs/libudev/version.xml
 991         docs/gudev/Makefile
 992         docs/gudev/version.xml
 993 ])
 994
 995 AC_OUTPUT
 996 AC_MSG_RESULT([
 997         $PACKAGE_NAME $VERSION
 998
 999         libcryptsetup:           ${have_libcryptsetup}
1000         tcpwrap:                 ${have_tcpwrap}
1001         PAM:                     ${have_pam}
1002         AUDIT:                   ${have_audit}
1003         IMA:                     ${have_ima}
1004         SELinux:                 ${have_selinux}
1005         SMACK:                   ${have_smack}
1006         XZ:                      ${have_xz}
1007         ACL:                     ${have_acl}
1008         XATTR:                   ${have_xattr}
1009         GCRYPT:                  ${have_gcrypt}
1010         QRENCODE:                ${have_qrencode}
1011         MICROHTTPD:              ${have_microhttpd}
1012         CHKCONFIG:               ${have_chkconfig}
1013         binfmt:                  ${have_binfmt}
1014         vconsole:                ${have_vconsole}
1015         readahead:               ${have_readahead}
1016         bootchart:               ${have_bootchart}
1017         quotacheck:              ${have_quotacheck}
1018         tmpfiles:                ${have_tmpfiles}
1019         randomseed:              ${have_randomseed}
1020         backlight:               ${have_backlight}
1021         logind:                  ${have_logind}
1022         machined:                ${have_machined}
1023         hostnamed:               ${have_hostnamed}
1024         timedated:               ${have_timedated}
1025         localed:                 ${have_localed}
1026         coredump:                ${have_coredump}
1027         polkit:                  ${have_polkit}
1028         efi:                     ${have_efi}
1029         kmod:                    ${have_kmod}
1030         blkid:                   ${have_blkid}
1031         nss-myhostname:          ${have_myhostname}
1032         gudev:                   ${enable_gudev}
1033         gintrospection:          ${enable_introspection}
1034         Python:                  ${have_python}
1035         Python Headers:          ${have_python_devel}
1036         man pages:               ${have_manpages}
1037         gtk-doc:                 ${enable_gtk_doc}
1038         test coverage:           ${have_coverage}
1039         Split /usr:              ${enable_split_usr}
1040         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1041
1042         prefix:                  ${prefix}
1043         rootprefix:              ${with_rootprefix}
1044         sysconf dir:             ${sysconfdir}
1045         datarootdir:             ${datarootdir}
1046         includedir:              ${includedir}
1047         include_prefix:          ${INCLUDE_PREFIX}
1048         lib dir:                 ${libdir}
1049         rootlib dir:             ${with_rootlibdir}
1050         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1051         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1052         Build Python:            ${PYTHON}
1053         Installation Python:     ${PYTHON_BINARY}
1054         firmware path:           ${FIRMWARE_PATH}
1055         PAM modules dir:         ${with_pamlibdir}
1056         PAM configuration dir:   ${with_pamconfdir}
1057         D-Bus policy dir:        ${with_dbuspolicydir}
1058         D-Bus session dir:       ${with_dbussessionservicedir}
1059         D-Bus system dir:        ${with_dbussystemservicedir}
1060         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1061         Bash completions dir:    ${with_bashcompletiondir}
1062         Zsh completions dir:     ${with_zshcompletiondir}
1063         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1064         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1065         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1066
1067         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1068         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1069         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1070         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1071         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1072 ])