configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [233],
  24         [https://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [https://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(ARM, arm*)
  61 SET_ARCH(AARCH64, aarch64*)
  62
  63 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  64 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  65 AS_IF([test x"$intltool_found" != xyes],
  66       [AS_IF([test x"$enable_nls" = xyes],
  67              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  68              [AS_IF([test x"$enable_nls" != xno],
  69                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  70                      enable_nls=no])
  71              ])
  72       ])
  73
  74 AM_NLS
  75 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  76     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  77 IT_PROG_INTLTOOL([0.40.0])
  78 ])
  79
  80 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  81     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  82     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  83     AC_SUBST(INTLTOOL_POLICY_RULE)
  84 ])
  85
  86 GETTEXT_PACKAGE=systemd
  87 AC_SUBST(GETTEXT_PACKAGE)
  88 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  89
  90 AC_PROG_MKDIR_P
  91 AC_PROG_LN_S
  92 AC_PROG_SED
  93 AC_PROG_GREP
  94 AC_PROG_AWK
  95
  96 AC_PATH_PROG([M4], [m4])
  97
  98 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  99 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
 100
 101 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 102
 103 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 104
 105 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 106
 107 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 108
 109 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 110 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 111
 112 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 113
 114 M4_DEFINES=
 115
 116 AC_CHECK_TOOL(OBJCOPY, objcopy)
 117 AC_CHECK_TOOL(STRINGS, strings)
 118 AC_CHECK_TOOL(GPERF, gperf)
 119 if test -z "$GPERF" ; then
 120         AC_MSG_ERROR([*** gperf not found])
 121 fi
 122
 123 # ------------------------------------------------------------------------------
 124 address_sanitizer_cflags=
 125 address_sanitizer_cppflags=
 126 address_sanitizer_ldflags=
 127 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 128 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 129             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 130             AS_IF([test -z "$with_as_cflags"],
 131                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 132             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 133             address_sanitizer_cppflags="-DVALGRIND=1"
 134             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 135       ])
 136
 137 undefined_sanitizer_cflags=
 138 undefined_sanitizer_cppflags=
 139 undefined_sanitizer_ldflags=
 140 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 141 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 142             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 143             AS_IF([test -z "$with_us_cflags"],
 144                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 145             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 146             undefined_sanitizer_cppflags="-DVALGRIND=1"
 147             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 148       ])
 149
 150 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 151 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 152 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 153
 154 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 155         -pipe \
 156         -Wall \
 157         -Wextra \
 158         -Wundef \
 159         -Wlogical-op \
 160         -Wmissing-include-dirs \
 161         -Wold-style-definition \
 162         -Wpointer-arith \
 163         -Winit-self \
 164         -Wdeclaration-after-statement \
 165         -Wfloat-equal \
 166         -Wsuggest-attribute=noreturn \
 167         -Werror=missing-prototypes \
 168         -Werror=implicit-function-declaration \
 169         -Werror=missing-declarations \
 170         -Werror=return-type \
 171         -Werror=incompatible-pointer-types \
 172         -Werror=format=2 \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AC_ARG_ENABLE([lto], [AS_HELP_STRING([--disable-lto], [disable -flto])],
 215                      [], [enable_lto=yes])
 216 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 217         [AS_IF([test "x$enable_lto" = "xyes"],
 218                [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-flto])],
 219                [AC_MSG_RESULT([disabling -flto as requested])])],
 220         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 221
 222 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 223         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 224                -Wp,-D_FORTIFY_SOURCE=2])],
 225         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 226
 227 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 228         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 229                -Wl,--gc-sections])],
 230         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 231
 232 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 233         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 234                -ffunction-sections -fdata-sections])],
 235         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 236
 237 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 238         -Wl,--as-needed \
 239         -Wl,--no-undefined \
 240         -Wl,-z,relro \
 241         -Wl,-z,now \
 242         -pie \
 243         -Wl,-fuse-ld=gold])
 244
 245 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 246 AC_SUBST([OUR_CFLAGS], "-D__SANE_USERSPACE_TYPES__ $with_cflags $sanitizer_cflags")
 247 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 248
 249 AC_CHECK_SIZEOF(pid_t)
 250 AC_CHECK_SIZEOF(uid_t)
 251 AC_CHECK_SIZEOF(gid_t)
 252 AC_CHECK_SIZEOF(time_t)
 253 AC_CHECK_SIZEOF(dev_t)
 254 AC_CHECK_SIZEOF(ino_t)
 255 AC_CHECK_SIZEOF(rlim_t,,[
 256        #include <sys/time.h>
 257        #include <sys/resource.h>
 258 ])
 259
 260 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
 261
 262 AC_COMPILE_IFELSE(
 263         [AC_LANG_PROGRAM([
 264                 #include <string.h>
 265                 const char * in_word_set(const char *, size_t);
 266                 $GPERF_TEST]
 267         )],
 268         [GPERF_LEN_TYPE=size_t],
 269         [AC_COMPILE_IFELSE(
 270                 [AC_LANG_PROGRAM([
 271                         #include <string.h>
 272                         const char * in_word_set(const char *, unsigned);
 273                         $GPERF_TEST]
 274                 )],
 275                 [GPERF_LEN_TYPE=unsigned],
 276                 [AC_MSG_ERROR([** unable to determine gperf len type])]
 277         )]
 278 )
 279
 280 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
 281
 282 # ------------------------------------------------------------------------------
 283 # we use python to build the man page index
 284 have_python=no
 285 AC_ARG_WITH([python],
 286         [AS_HELP_STRING([--without-python], [disable building the man page index and systemd-python (default: test)])])
 287
 288 have_lxml=no
 289 AS_IF([test "x$with_python" != "xno"], [
 290         AM_PATH_PYTHON([3],, [:])
 291         AS_IF([test "x$PYTHON" != "x:"], [
 292                 AC_MSG_CHECKING([for python lxml module])
 293                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 294                 AC_MSG_RESULT([$have_lxml])
 295                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 296                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 297         ])
 298 ])
 299 AS_IF([test "$have_python" != "yes"], [
 300       AS_IF([test "$with_python" = "yes"],
 301             [AC_MSG_ERROR([*** python support requested but python support not found])])
 302       AS_IF([test "$with_python" != "no"],
 303             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 304 ])
 305 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 306
 307 # ------------------------------------------------------------------------------
 308
 309 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 310 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 311 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 312 AC_CHECK_HEADERS([linux/vm_sockets.h], [], [], [#include <sys/socket.h>])
 313
 314 # unconditionally pull-in librt with old glibc versions
 315 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 316
 317 save_LIBS="$LIBS"
 318 LIBS=
 319 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 320 CAP_LIBS="$LIBS"
 321 LIBS="$save_LIBS"
 322 AC_SUBST(CAP_LIBS)
 323
 324 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 325 AC_CHECK_DECLS([
 326         memfd_create,
 327         gettid,
 328         pivot_root,
 329         name_to_handle_at,
 330         setns,
 331         renameat2,
 332         kcmp,
 333         keyctl,
 334         LO_FLAGS_PARTSCAN,
 335         copy_file_range,
 336         explicit_bzero],
 337         [], [], [[
 338 #include <sys/types.h>
 339 #include <unistd.h>
 340 #include <sys/mount.h>
 341 #include <fcntl.h>
 342 #include <sched.h>
 343 #include <string.h>
 344 #include <linux/loop.h>
 345 ]])
 346
 347 AC_CHECK_DECLS([getrandom],
 348                [AC_DEFINE([USE_SYS_RANDOM_H], [], [sys/random.h is usable])],
 349                [AC_CHECK_DECLS([getrandom], [], [], [[
 350 #include <sys/random.h>
 351 ]])], [[
 352 #include <linux/random.h>
 353 ]])
 354
 355 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t, struct ethtool_link_settings],
 356                [], [], [[
 357 #include <uchar.h>
 358 #include <linux/ethtool.h>
 359 ]])
 360
 361 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 362                 IN6_ADDR_GEN_MODE_STABLE_PRIVACY,
 363                 IFLA_VRF_TABLE,
 364                 IFLA_MACVLAN_FLAGS,
 365                 IFLA_IPVLAN_MODE,
 366                 IFLA_VTI_REMOTE,
 367                 IFLA_PHYS_PORT_ID,
 368                 IFLA_BOND_AD_INFO,
 369                 IFLA_VLAN_PROTOCOL,
 370                 IFLA_VXLAN_GPE,
 371                 IFLA_GENEVE_LABEL,
 372                 IFLA_IPTUN_ENCAP_DPORT,
 373                 IFLA_GRE_ENCAP_DPORT,
 374                 IFLA_BRIDGE_VLAN_INFO,
 375                 IFLA_BRPORT_PROXYARP,
 376                 IFLA_BRPORT_LEARNING_SYNC,
 377                 IFLA_BR_VLAN_DEFAULT_PVID,
 378                 NDA_IFINDEX,
 379                 IFA_FLAGS],
 380 [], [], [[
 381 #include <inttypes.h>
 382 #include <netinet/in.h>
 383 #include <netinet/ether.h>
 384 #include <linux/rtnetlink.h>
 385 #include <net/if.h>
 386 #include <linux/ip.h>
 387 #include <linux/if_tunnel.h>
 388 #include <linux/if_link.h>
 389 #include <linux/if_bridge.h>
 390 #include <linux/if_addr.h>
 391 #include <linux/neighbour.h>
 392 ]])
 393
 394 # This makes sure pkg.m4 is available.
 395 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 396
 397 # ------------------------------------------------------------------------------
 398 have_dbus=no
 399 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 400 AS_IF([test "x$enable_dbus" != "xno"], [
 401         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 402                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 403                 [have_dbus=no])
 404         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 405                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 406 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 407
 408 # ------------------------------------------------------------------------------
 409 have_glib=no
 410 AC_ARG_ENABLE(glib, AS_HELP_STRING([--disable-glib], [disable usage of glib,gobject,gio in tests]))
 411 AS_IF([test "x$enable_glib" != "xno"], [
 412         PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 413                 [AC_DEFINE(HAVE_GLIB, 1, [Define if glib,gobject,gio are available]) have_glib=yes],
 414                 [have_glib=no])
 415         AS_IF([test "x$have_glib" = "xno" -a "x$enable_glib" = "xyes"],
 416                 [AC_MSG_ERROR([*** glib support requested but libraries not found])])])
 417
 418 # ------------------------------------------------------------------------------
 419 have_utmp=yes
 420 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 421         AS_CASE("x${enableval}",
 422                 [xyes], [have_utmp=yes],
 423                 [xno],  [have_utmp=no],
 424                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 425 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 426 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 427
 428 # ------------------------------------------------------------------------------
 429 have_coverage=no
 430 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 431 if test "x$enable_coverage" = "xyes" ; then
 432         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 433         if test "x$lcov_found" = xno ; then
 434                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 435         else
 436                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 437                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 438                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 439                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 440                 else
 441                         have_coverage=yes
 442                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 443                         -fprofile-arcs \
 444                         -ftest-coverage])
 445                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 446                 fi
 447         fi
 448 fi
 449 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 450
 451 # ------------------------------------------------------------------------------
 452 have_kmod=no
 453 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 454 if test "x$enable_kmod" != "xno"; then
 455         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 456         if test "x$have_kmod" = "xyes"; then
 457                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 458                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 459                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 460         fi
 461         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 462                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 463         fi
 464 fi
 465 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 466
 467 # ------------------------------------------------------------------------------
 468 have_xkbcommon=no
 469 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 470 if test "x$enable_xkbcommon" != "xno"; then
 471         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 472                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 473         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 474                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 475         fi
 476 fi
 477 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 478
 479 # ------------------------------------------------------------------------------
 480 have_blkid=no
 481 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 482 if test "x$enable_blkid" != "xno"; then
 483         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 484                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 485         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 486                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 487         fi
 488 fi
 489 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 490
 491 # ------------------------------------------------------------------------------
 492 have_libmount=no
 493 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 494         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 495 if test "x$have_libmount" = xno; then
 496         AC_MSG_ERROR([*** libmount support required but libraries not found])
 497 fi
 498 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 499
 500 # ------------------------------------------------------------------------------
 501 have_seccomp=no
 502 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [disable optional SECCOMP support]))
 503 if test "x$enable_seccomp" != "xno"; then
 504         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 2.3.1],
 505                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 506                 have_seccomp=yes
 507                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 508                [have_seccomp=no])
 509         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 510                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 511         fi
 512 fi
 513 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 514
 515 # ------------------------------------------------------------------------------
 516 have_ima=yes
 517 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima], [disable optional IMA support]),
 518                 [case "${enableval}" in
 519                         yes) have_ima=yes ;;
 520                         no) have_ima=no ;;
 521                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 522                 esac],
 523                 [have_ima=yes])
 524
 525 if test "x${have_ima}" != xno ; then
 526         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 527 fi
 528
 529 # ------------------------------------------------------------------------------
 530 have_selinux=no
 531 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [disable optional SELINUX support]))
 532 if test "x$enable_selinux" != "xno"; then
 533         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 534                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 535                  have_selinux=yes
 536                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 537                 [have_selinux=no])
 538         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 539                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 540         fi
 541 fi
 542 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 543
 544 have_apparmor=no
 545 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [disable optional AppArmor support]))
 546 if test "x$enable_apparmor" != "xno"; then
 547         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 548                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 549                  have_apparmor=yes
 550                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 551                 [have_apparmor=no])
 552         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 553                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 554         fi
 555 fi
 556 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 557
 558 have_adm_group=no
 559 AC_ARG_ENABLE(adm-group, AS_HELP_STRING([--disable-adm-group], [disable adm group]))
 560 AS_IF([test "x$enable_adm_group" != "xno"], [
 561         AC_DEFINE(ENABLE_ADM_GROUP, 1, [Define if the ACL for adm group should be enabled])
 562         have_adm_group=yes
 563         M4_DEFINES="$M4_DEFINES -DENABLE_ADM_GROUP"
 564 ])
 565
 566 have_wheel_group=no
 567 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 568 AS_IF([test "x$enable_wheel_group" != "xno"], [
 569         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 570         have_wheel_group=yes
 571         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 572 ])
 573
 574
 575 AC_ARG_WITH(debug-shell,
 576         AS_HELP_STRING([--with-debug-shell=PATH],
 577                 [path to debug shell binary]),
 578         [SUSHELL="$withval"],
 579         [SUSHELL="/bin/sh"])
 580
 581 AC_SUBST(SUSHELL)
 582
 583 AC_ARG_WITH([debug-tty],
 584         AS_HELP_STRING([--with-debug-tty=PATH],
 585                 [specify the tty device for debug shell]),
 586         [DEBUGTTY="$withval"],
 587         [DEBUGTTY=/dev/tty9])
 588
 589 AC_SUBST(DEBUGTTY)
 590
 591 AC_ARG_WITH([certificate-root],
 592         AS_HELP_STRING([--with-certificate-root=PATH],
 593                 [specify the prefix for TLS certificates [/etc/ssl]]),
 594         [CERTIFICATEROOT="$withval"],
 595         [CERTIFICATEROOT="/etc/ssl"])
 596
 597 AC_SUBST(CERTIFICATEROOT)
 598
 599 AC_ARG_WITH([support-url],
 600         AS_HELP_STRING([--with-support-url=URL],
 601                 [specify the support URL to show in catalog entries included in systemd]),
 602         [SUPPORT_URL="$withval"],
 603         [SUPPORT_URL=https://lists.freedesktop.org/mailman/listinfo/systemd-devel])
 604
 605 AC_SUBST(SUPPORT_URL)
 606
 607 AC_ARG_WITH([nobody-user],
 608         AS_HELP_STRING([--with-nobody-user=NAME],
 609                 [specify the name of the nobody user (the one with UID 65534)]),
 610         [NOBODY_USER_NAME="$withval"],
 611         [NOBODY_USER_NAME=nobody])
 612
 613 AC_SUBST(NOBODY_USER_NAME)
 614 AC_DEFINE_UNQUOTED(NOBODY_USER_NAME, ["$NOBODY_USER_NAME"], [The name of the nobody user (the one with UID 65534)])
 615
 616 AC_ARG_WITH([nobody-group],
 617         AS_HELP_STRING([--with-nobody-group=NAME],
 618                 [specify the name of the nobody group (the one with GID 65534)]),
 619         [NOBODY_GROUP_NAME="$withval"],
 620         [NOBODY_GROUP_NAME=nobody])
 621
 622 AC_SUBST(NOBODY_GROUP_NAME)
 623 AC_DEFINE_UNQUOTED(NOBODY_GROUP_NAME, ["$NOBODY_GROUP_NAME"], [The name of the nobody group (the one with GID 65534)])
 624
 625 AC_ARG_WITH([fallback-hostname],
 626         AS_HELP_STRING([--with-fallback-hostname=NAME],
 627                 [specify the hostname used if none configured]),
 628         [FALLBACK_HOSTNAME="$withval"],
 629         [FALLBACK_HOSTNAME=localhost])
 630
 631 AC_SUBST(FALLBACK_HOSTNAME)
 632 AC_DEFINE_UNQUOTED(FALLBACK_HOSTNAME, ["$FALLBACK_HOSTNAME"], [The hostname used if none configured])
 633
 634 # ------------------------------------------------------------------------------
 635
 636 AC_ARG_WITH(default-hierarchy,
 637         AS_HELP_STRING([--with-default-hierarchy=MODE],
 638                 [default cgroup hierarchy, defaults to "hybrid"]),
 639         [DEFAULT_HIERARCHY="$withval"],
 640         [DEFAULT_HIERARCHY="hybrid"])
 641
 642 AS_CASE("$DEFAULT_HIERARCHY",
 643         [legacy], [mode=CGROUP_UNIFIED_NONE],
 644         [hybrid], [mode=CGROUP_UNIFIED_SYSTEMD],
 645         [unified], [mode=CGROUP_UNIFIED_ALL],
 646         AC_MSG_ERROR(Bad default hierarchy mode ${DEFAULT_HIERARCHY}))
 647 AC_DEFINE_UNQUOTED(DEFAULT_HIERARCHY, [$mode], [Default cgroup hierarchy])
 648 AC_DEFINE_UNQUOTED(DEFAULT_HIERARCHY_NAME, ["$DEFAULT_HIERARCHY"],
 649                                            [Default cgroup hierarchy as string])
 650
 651 # ------------------------------------------------------------------------------
 652 have_xz=no
 653 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [disable optional XZ support]))
 654 AS_IF([test "x$enable_xz" != "xno"], [
 655         PKG_CHECK_MODULES(XZ, [ liblzma ],
 656                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 657                  have_xz=yes],
 658                  have_xz=no)
 659         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 660               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 661 ])
 662 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 663
 664 # ------------------------------------------------------------------------------
 665 have_zlib=no
 666 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [disable optional ZLIB support]))
 667 AS_IF([test "x$enable_zlib" != "xno"], [
 668         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 669                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 670                  have_zlib=yes],
 671                  have_zlib=no)
 672         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 673               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 674 ])
 675 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 676
 677 # ------------------------------------------------------------------------------
 678 have_bzip2=no
 679 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--disable-bzip2], [disable optional BZIP2 support]))
 680 AS_IF([test "x$enable_bzip2" != "xno"], [
 681         AC_CHECK_HEADERS(bzlib.h,
 682                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 683                  have_bzip2=yes],
 684                 [AS_IF([test "x$enable_bzip2" = xyes],
 685                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 686         )
 687 ])
 688 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 689
 690 # ------------------------------------------------------------------------------
 691 have_lz4=no
 692 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [disable optional LZ4 support]))
 693 AS_IF([test "x$enable_lz4" != "xno"], [
 694         PKG_CHECK_MODULES(LZ4, [ liblz4 < 10 ],
 695                [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 696                 have_lz4=yes],
 697                 [PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 698                       [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 699                       have_lz4=yes],
 700                       have_lz4=no)])
 701         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 702               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 703 ])
 704 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 705
 706 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 707
 708 # ------------------------------------------------------------------------------
 709 AC_ARG_ENABLE([pam],
 710         AS_HELP_STRING([--disable-pam], [disable optional PAM support]),
 711                 [case "${enableval}" in
 712                         yes) have_pam=yes ;;
 713                         no) have_pam=no ;;
 714                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 715                 esac],
 716                 [have_pam=auto])
 717
 718 if test "x${have_pam}" != xno ; then
 719         AC_CHECK_HEADERS(
 720                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 721                 [have_pam=yes],
 722                 [if test "x$have_pam" = xyes ; then
 723                         AC_MSG_ERROR([*** PAM headers not found.])
 724                 fi])
 725
 726         AC_CHECK_LIB(
 727                 [pam],
 728                 [pam_syslog],
 729                 [have_pam=yes],
 730                 [if test "x$have_pam" = xyes ; then
 731                         AC_MSG_ERROR([*** libpam not found.])
 732                 fi])
 733
 734         if test "x$have_pam" = xyes ; then
 735                 PAM_LIBS="-lpam -lpam_misc"
 736                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 737                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 738         else
 739                 have_pam=no
 740         fi
 741 else
 742         PAM_LIBS=
 743 fi
 744 AC_SUBST(PAM_LIBS)
 745 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 746
 747 # ------------------------------------------------------------------------------
 748 AC_ARG_ENABLE([acl],
 749         AS_HELP_STRING([--disable-acl], [disable optional ACL support]),
 750                 [case "${enableval}" in
 751                         yes) have_acl=yes ;;
 752                         no) have_acl=no ;;
 753                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 754                 esac],
 755                 [have_acl=auto])
 756
 757 if test "x${have_acl}" != xno ; then
 758         AC_CHECK_HEADERS(
 759                 [sys/acl.h acl/libacl.h],
 760                 [have_acl=yes],
 761                 [if test "x$have_acl" = xyes ; then
 762                         AC_MSG_ERROR([*** ACL headers not found.])
 763                 fi])
 764
 765         AC_CHECK_LIB(
 766                 [acl],
 767                 [acl_get_file],
 768                 [have_acl=yes],
 769                 [if test "x$have_acl" = xyes ; then
 770                         AC_MSG_ERROR([*** libacl not found.])
 771                 fi])
 772
 773         if test "x$have_acl" = xyes ; then
 774                 ACL_LIBS="-lacl"
 775                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 776                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 777         else
 778                 have_acl=no
 779         fi
 780 else
 781         ACL_LIBS=
 782 fi
 783 AC_SUBST(ACL_LIBS)
 784 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 785
 786 # ------------------------------------------------------------------------------
 787 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack], [disable optional SMACK support]),
 788                 [case "${enableval}" in
 789                         yes) have_smack=yes ;;
 790                         no) have_smack=no ;;
 791                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 792                 esac],
 793                 [have_smack=auto])
 794
 795 if test "x${have_smack}" != xno; then
 796         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 797         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 798         have_smack=yes
 799 fi
 800
 801 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 802
 803 have_smack_run_label=no
 804 AC_ARG_WITH(smack-run-label,
 805 AS_HELP_STRING([--with-smack-run-label=STRING],
 806         [run systemd --system itself with a specific SMACK label]),
 807         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 808         [])
 809
 810 if test "x${have_smack_run_label}" = xyes; then
 811         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 812 fi
 813
 814 AC_ARG_WITH(smack-default-process-label,
 815 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 816         [default SMACK label for executed processes]),
 817         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 818         [])
 819
 820 # ------------------------------------------------------------------------------
 821 AC_ARG_ENABLE([gcrypt],
 822         AS_HELP_STRING([--disable-gcrypt], [disable optional GCRYPT support]),
 823                 [case "${enableval}" in
 824                         yes) have_gcrypt=yes ;;
 825                         no) have_gcrypt=no ;;
 826                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 827                 esac],
 828                 [have_gcrypt=auto])
 829
 830 if test "x${have_gcrypt}" != xno ; then
 831         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 832                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 833         )
 834         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 835                         [1.4.5],
 836                         [have_gcrypt=yes],
 837                         dnl  If we have the gcrypt m4 macros, but don't have
 838                         dnl  gcrypt, throw an error if gcrypt is explicitly
 839                         dnl  requested.
 840                         [AM_PATH_LIBGCRYPT_FAIL]
 841                 )],
 842                 dnl  If we don't have the gcrypt m4 macros, but build with
 843                 dnl  gcrypt explicitly requested, throw an error.
 844                 [AM_PATH_LIBGCRYPT_FAIL]
 845         )
 846
 847         have_gpg_error=no
 848         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 849                         [1.12],
 850                         [have_gpg_error=yes],
 851                         [AM_PATH_LIBGCRYPT_FAIL]
 852                 )],
 853                 [AM_PATH_LIBGCRYPT_FAIL]
 854         )
 855
 856         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 857                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 858                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 859                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 860         else
 861                 have_gcrypt=no
 862                 have_gpg_error=no
 863         fi
 864 else
 865         GCRYPT_LIBS=
 866         GCRYPT_CFLAGS=
 867 fi
 868 AC_SUBST(GCRYPT_LIBS)
 869 AC_SUBST(GCRYPT_CFLAGS)
 870 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 871
 872 # ------------------------------------------------------------------------------
 873 AC_ARG_ENABLE([audit],
 874         AS_HELP_STRING([--disable-audit], [disable optional AUDIT support]),
 875                 [case "${enableval}" in
 876                         yes) have_audit=yes ;;
 877                         no) have_audit=no ;;
 878                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 879                 esac],
 880                 [have_audit=auto])
 881
 882 if test "x${have_audit}" != xno ; then
 883         AC_CHECK_HEADERS(
 884                 [libaudit.h],
 885                 [have_audit=yes],
 886                 [if test "x$have_audit" = xyes ; then
 887                         AC_MSG_ERROR([*** AUDIT headers not found.])
 888                 fi])
 889
 890         AC_CHECK_LIB(
 891                 [audit],
 892                 [audit_open],
 893                 [have_audit=yes],
 894                 [if test "x$have_audit" = xyes ; then
 895                         AC_MSG_ERROR([*** libaudit not found.])
 896                 fi])
 897
 898         if test "x$have_audit" = xyes ; then
 899                 AUDIT_LIBS="-laudit"
 900                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 901         else
 902                 have_audit=no
 903         fi
 904 else
 905         AUDIT_LIBS=
 906 fi
 907 AC_SUBST(AUDIT_LIBS)
 908 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 909
 910 # ------------------------------------------------------------------------------
 911 AC_ARG_ENABLE([elfutils],
 912         AS_HELP_STRING([--disable-elfutils], [disable optional ELFUTILS support]),
 913                 [case "${enableval}" in
 914                         yes) have_elfutils=yes ;;
 915                         no) have_elfutils=no ;;
 916                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 917                 esac],
 918                 [have_elfutils=auto])
 919
 920 if test "x${have_elfutils}" != xno ; then
 921         AC_CHECK_HEADERS(
 922                 [elfutils/libdwfl.h],
 923                 [],
 924                 [if test "x$have_elfutils" = xyes ; then
 925                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 926                 fi])
 927
 928         AC_CHECK_LIB(
 929                 [dw],
 930                 [dwfl_core_file_attach],
 931                 [have_elfutils=yes],
 932                 [if test "x$have_elfutils" = xyes ; then
 933                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 934                 fi])
 935
 936         if test "x$have_elfutils" = xyes ; then
 937                 ELFUTILS_LIBS="-lelf -ldw"
 938                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 939         else
 940                 have_elfutils=no
 941         fi
 942 else
 943         ELFUTILS_LIBS=
 944 fi
 945 AC_SUBST(ELFUTILS_LIBS)
 946 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 947
 948 # ------------------------------------------------------------------------------
 949 have_libcryptsetup=no
 950 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 951 if test "x$enable_libcryptsetup" != "xno"; then
 952         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 953                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 954         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 955                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 956         fi
 957 fi
 958 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 959
 960 # ------------------------------------------------------------------------------
 961 have_qrencode=no
 962 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 963 if test "x$enable_qrencode" != "xno"; then
 964         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 965                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 966         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 967                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 968         fi
 969 fi
 970 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 971
 972 # ------------------------------------------------------------------------------
 973 have_gnutls=no
 974 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 975 if test "x$enable_gnutls" != "xno"; then
 976         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 977                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 978         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 979                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 980         fi
 981 fi
 982 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 983
 984 # ------------------------------------------------------------------------------
 985 have_microhttpd=no
 986 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 987 if test "x$enable_microhttpd" != "xno"; then
 988         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 989                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 990                  have_microhttpd=yes
 991                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 992                 [have_microhttpd=no])
 993         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 994                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 995         fi
 996 fi
 997 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 998
 999 # ------------------------------------------------------------------------------
1000 have_libcurl=no
1001 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
1002 if test "x$enable_libcurl" != "xno"; then
1003         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
1004                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
1005                  have_libcurl=yes
1006                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
1007                 [have_libcurl=no])
1008         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
1009                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
1010         fi
1011 fi
1012 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
1013
1014 # ------------------------------------------------------------------------------
1015 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
1016
1017 # ------------------------------------------------------------------------------
1018 have_libidn=no
1019 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [disable optional LIBIDN support]))
1020 if test "x$enable_libidn" != "xno"; then
1021         PKG_CHECK_MODULES(LIBIDN, [libidn],
1022                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
1023                 have_libidn=yes
1024                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
1025                [have_libidn=no])
1026         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
1027                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
1028         fi
1029 fi
1030 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
1031
1032 # ------------------------------------------------------------------------------
1033 have_libiptc=no
1034 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [disable optional LIBIPTC support]))
1035 if test "x$enable_libiptc" != "xno"; then
1036         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
1037                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
1038                 have_libiptc=yes
1039                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
1040                [have_libiptc=no])
1041         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
1042                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
1043         fi
1044 fi
1045 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
1046
1047 # ------------------------------------------------------------------------------
1048 have_binfmt=no
1049 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
1050 if test "x$enable_binfmt" != "xno"; then
1051         have_binfmt=yes
1052 fi
1053 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
1054
1055 # ------------------------------------------------------------------------------
1056 have_vconsole=no
1057 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
1058 if test "x$enable_vconsole" != "xno"; then
1059         have_vconsole=yes
1060 fi
1061 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
1062
1063 # ------------------------------------------------------------------------------
1064 have_quotacheck=no
1065 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
1066 if test "x$enable_quotacheck" != "xno"; then
1067         have_quotacheck=yes
1068 fi
1069 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
1070
1071 # ------------------------------------------------------------------------------
1072 have_tmpfiles=no
1073 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
1074 if test "x$enable_tmpfiles" != "xno"; then
1075         have_tmpfiles=yes
1076 fi
1077 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
1078
1079 # ------------------------------------------------------------------------------
1080 have_environment_d=no
1081 AC_ARG_ENABLE(environment-d, AS_HELP_STRING([--disable-environment-d], [disable environment.d support]))
1082 if test "x$enable_environment_d" != "xno"; then
1083         have_environment_d=yes
1084 fi
1085 AM_CONDITIONAL(ENABLE_ENVIRONMENT_D, [test "$have_environment_d" = "yes"])
1086
1087 # ------------------------------------------------------------------------------
1088 have_sysusers=no
1089 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
1090 if test "x$enable_sysusers" != "xno"; then
1091         have_sysusers=yes
1092 fi
1093 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
1094
1095 # ------------------------------------------------------------------------------
1096 have_firstboot=no
1097 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
1098 if test "x$enable_firstboot" != "xno"; then
1099         have_firstboot=yes
1100 fi
1101 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
1102
1103 # ------------------------------------------------------------------------------
1104 have_randomseed=no
1105 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
1106 if test "x$enable_randomseed" != "xno"; then
1107         have_randomseed=yes
1108 fi
1109 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
1110
1111 # ------------------------------------------------------------------------------
1112 have_backlight=no
1113 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
1114 if test "x$enable_backlight" != "xno"; then
1115         have_backlight=yes
1116 fi
1117 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
1118
1119 # ------------------------------------------------------------------------------
1120 have_rfkill=no
1121 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1122 if test "x$enable_rfkill" != "xno"; then
1123         have_rfkill=yes
1124 fi
1125 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1126
1127 # ------------------------------------------------------------------------------
1128 have_logind=no
1129 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1130 if test "x$enable_logind" != "xno"; then
1131         have_logind=yes
1132 fi
1133 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1134 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(ENABLE_LOGIND, [1], [Logind support available]) ])
1135
1136 AC_ARG_WITH([kill-user-processes],
1137         [AS_HELP_STRING([--without-kill-user-processes], [set logind's KillUserProcesses=no by default])])
1138 AS_IF([test "$with_kill_user_processes" != "no"],
1139        [kill_user_processes=true
1140         KILL_USER_PROCESSES=yes],
1141        [kill_user_processes=false
1142         KILL_USER_PROCESSES=no])
1143 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
1144 AC_SUBST(KILL_USER_PROCESSES)
1145
1146 # ------------------------------------------------------------------------------
1147 have_machined=no
1148 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1149 if test "x$enable_machined" != "xno"; then
1150         have_machined=yes
1151         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1152 fi
1153 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1154
1155 # ------------------------------------------------------------------------------
1156 have_importd=no
1157 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1158 if test "x$enable_importd" != "xno"; then
1159         have_importd=yes
1160 fi
1161 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1162 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1163
1164 # ------------------------------------------------------------------------------
1165 have_hostnamed=no
1166 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1167 if test "x$enable_hostnamed" != "xno"; then
1168         have_hostnamed=yes
1169 fi
1170 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1171
1172 # ------------------------------------------------------------------------------
1173 have_timedated=no
1174 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1175 if test "x$enable_timedated" != "xno"; then
1176         have_timedated=yes
1177 fi
1178 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1179
1180 # ------------------------------------------------------------------------------
1181 have_timesyncd=no
1182 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1183 if test "x$enable_timesyncd" != "xno"; then
1184         have_timesyncd=yes
1185         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1186 fi
1187 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1188
1189 AC_ARG_WITH(ntp-servers,
1190         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1191                 [space-separated list of default NTP servers]),
1192         [NTP_SERVERS="$withval"],
1193         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"])
1194
1195 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1196 AC_SUBST(NTP_SERVERS)
1197
1198 AC_ARG_WITH(time-epoch,
1199         AS_HELP_STRING([--with-time-epoch=SECONDS],
1200                 [time epoch for time clients]),
1201         [TIME_EPOCH="$withval"],
1202         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1203
1204 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1205
1206 # ------------------------------------------------------------------------------
1207 AC_ARG_WITH(system-uid-max,
1208         AS_HELP_STRING([--with-system-uid-max=UID]
1209                 [maximum UID for system users]),
1210         [SYSTEM_UID_MAX="$withval"],
1211         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1212
1213 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1214 AC_SUBST(SYSTEM_UID_MAX)
1215
1216 # ------------------------------------------------------------------------------
1217 AC_ARG_WITH(system-gid-max,
1218         AS_HELP_STRING([--with-system-gid-max=GID]
1219                 [maximum GID for system groups]),
1220         [SYSTEM_GID_MAX="$withval"],
1221         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1222
1223 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1224 AC_SUBST(SYSTEM_GID_MAX)
1225
1226 # ------------------------------------------------------------------------------
1227
1228 AC_ARG_WITH(dev-kvm-mode,
1229         AS_HELP_STRING([--with-dev-kvm-mode=MODE],
1230                 [/dev/kvm access mode, defaults to "0660"]),
1231         [DEV_KVM_MODE="$withval"],
1232         [DEV_KVM_MODE="0660"])
1233
1234 AC_SUBST(DEV_KVM_MODE, [$DEV_KVM_MODE], [/dev/kvm access mode])
1235
1236 # ------------------------------------------------------------------------------
1237 have_localed=no
1238 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1239 if test "x$enable_localed" != "xno"; then
1240         have_localed=yes
1241 fi
1242 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1243
1244 # ------------------------------------------------------------------------------
1245 have_coredump=no
1246 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1247 if test "x$enable_coredump" != "xno"; then
1248         have_coredump=yes
1249         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1250 fi
1251 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1252
1253 # ------------------------------------------------------------------------------
1254 have_polkit=no
1255 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1256 if test "x$enable_polkit" != "xno"; then
1257         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1258         have_polkit=yes
1259
1260         # also enable support for *.pkla files on old polkit
1261         PKG_CHECK_MODULES(POLKIT, [ polkit-gobject-1 < 0.106 ],
1262                            [polkit_pkla=yes],
1263                            [polkit_pkla=no])
1264 fi
1265 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1266 AM_CONDITIONAL(ENABLE_POLKIT_PKLA, [test "x$polkit_pkla" = "xyes"])
1267
1268 # ------------------------------------------------------------------------------
1269 have_resolved=no
1270 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1271 AS_IF([test "x$enable_resolved" != "xno"], [
1272         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1273
1274         have_resolved=yes
1275         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1276         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1277 ])
1278 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1279
1280 AC_ARG_WITH(dns-servers,
1281         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1282                 [space-separated list of default DNS servers]),
1283         [DNS_SERVERS="$withval"],
1284         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1285
1286 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1287 AC_SUBST(DNS_SERVERS)
1288
1289 AC_ARG_WITH(default-dnssec,
1290         AS_HELP_STRING([--with-default-dnssec=MODE],
1291                [default DNSSEC mode, defaults to "allow-downgrade"]),
1292         [DEFAULT_DNSSEC_MODE="$withval"],
1293         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1294
1295 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1296         [xno], [mode=DNSSEC_NO],
1297         [xyes], [mode=DNSSEC_YES],
1298         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1299         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1300 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1301 AC_SUBST(DEFAULT_DNSSEC_MODE)
1302
1303 # ------------------------------------------------------------------------------
1304 have_networkd=no
1305 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1306 AS_IF([test "x$enable_networkd" != "xno"], [
1307         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1308         have_networkd=yes
1309         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1310 ])
1311 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1312
1313 # ------------------------------------------------------------------------------
1314 have_efi=no
1315 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable systemd-boot and bootctl (EFI support)]))
1316 if test "x$enable_efi" != "xno"; then
1317         AC_DEFINE(ENABLE_EFI, 1, [Define if systemd-boot and bootctl are to be enabled])
1318         have_efi=yes
1319 fi
1320 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1321
1322 # ------------------------------------------------------------------------------
1323 AC_CHECK_TOOL(EFI_CC, gcc)
1324
1325 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1326
1327 AM_COND_IF(ARCH_IA32, [
1328         EFI_ARCH=ia32
1329         EFI_MACHINE_TYPE_NAME=ia32])
1330
1331 AM_COND_IF(ARCH_X86_64, [
1332         EFI_MACHINE_TYPE_NAME=x64])
1333
1334 AM_COND_IF(ARCH_ARM, [
1335         EFI_MACHINE_TYPE_NAME=arm])
1336
1337 AM_COND_IF(ARCH_AARCH64, [
1338         EFI_MACHINE_TYPE_NAME=aa64])
1339
1340 AC_SUBST([EFI_ARCH])
1341 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1342
1343 have_gnuefi=no
1344 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [enable optional gnuefi support]))
1345 AS_IF([test "x$enable_gnuefi" != "xno"], [
1346         AC_ARG_WITH(efi-includedir,
1347                 AS_HELP_STRING([--with-efi-includedir=PATH], [path to EFI include directory]),
1348                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1349         )
1350         AC_SUBST([EFI_INC_DIR])
1351
1352         AC_CHECK_HEADERS(${EFI_INC_DIR}/efi/${EFI_ARCH}/efibind.h,
1353                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1354                  have_gnuefi=yes],
1355                 [AS_IF([test "x$enable_gnuefi" = xyes],
1356                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1357         ])
1358
1359         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1360
1361         EFI_LIB_DIR="$efiroot"
1362         AC_ARG_WITH(efi-libdir,
1363                 AS_HELP_STRING([--with-efi-libdir=PATH], [path to EFI lib directory]),
1364                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1365         )
1366         AC_SUBST([EFI_LIB_DIR])
1367
1368         have_efi_lds=no
1369         AC_ARG_WITH(efi-ldsdir,
1370                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [path to EFI lds directory]),
1371                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1372                         [have_efi_lds=yes])],
1373                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1374                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1375                                        [have_efi_lds=yes && break])])])
1376         AS_IF([test "x$have_efi_lds" = xyes],
1377               [AC_SUBST([EFI_LDS_DIR])],
1378               [AS_IF([test "x$enable_gnuefi" = xyes],
1379                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1380                      [have_gnuefi=no])])
1381 ])
1382 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1383
1384 # ------------------------------------------------------------------------------
1385 have_tpm=no
1386 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm], [enable optional TPM support]),
1387                 [case "${enableval}" in
1388                         yes) have_tpm=yes ;;
1389                         no) have_tpm=no ;;
1390                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1391                 esac],
1392                 [have_tpm=no])
1393
1394 if test "x${have_tpm}" != xno ; then
1395         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1396 fi
1397
1398 AC_ARG_WITH(tpm-pcrindex,
1399         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1400                 [TPM PCR register number to use]),
1401         [SD_TPM_PCR="$withval"],
1402         [SD_TPM_PCR="8"])
1403
1404 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1405
1406 # ------------------------------------------------------------------------------
1407 AC_ARG_WITH(rc-local-script-path-start,
1408         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1409                 [path to /etc/rc.local]),
1410         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1411         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1412
1413 AC_ARG_WITH(rc-local-script-path-stop,
1414         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1415                 [path to /usr/sbin/halt.local]),
1416         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1417         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1418
1419 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1420 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1421
1422 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1423 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1424
1425 # ------------------------------------------------------------------------------
1426 AC_ARG_WITH(kbd-loadkeys,
1427         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1428                 [path to loadkeys]),
1429         [KBD_LOADKEYS="$withval"],
1430         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1431
1432 AC_ARG_WITH(kbd-setfont,
1433         AS_HELP_STRING([--with-kbd-setfont=PATH],
1434                 [path to setfont]),
1435         [KBD_SETFONT="$withval"],
1436         [KBD_SETFONT="/usr/bin/setfont"])
1437
1438 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1439 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1440
1441 AC_SUBST(KBD_LOADKEYS)
1442 AC_SUBST(KBD_SETFONT)
1443
1444 AC_ARG_WITH(telinit,
1445         AS_HELP_STRING([--with-telinit=PATH],
1446                 [path to telinit]),
1447         [TELINIT="$withval"],
1448         [TELINIT="/lib/sysvinit/telinit"])
1449
1450 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1451
1452 AC_SUBST(TELINIT)
1453
1454 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1455
1456 # ------------------------------------------------------------------------------
1457 have_myhostname=no
1458 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1459 if test "x$enable_myhostname" != "xno"; then
1460         AC_HEADER_STDC
1461         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1462
1463         AC_C_CONST
1464         AC_TYPE_SIZE_T
1465         AC_HEADER_TIME
1466
1467         AC_FUNC_SELECT_ARGTYPES
1468         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1469
1470         have_myhostname=yes
1471         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1472 fi
1473 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1474
1475 # ------------------------------------------------------------------------------
1476 AC_ARG_ENABLE(hwdb, [AS_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1477        enable_hwdb=$enableval, enable_hwdb=yes)
1478 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1479
1480 # ------------------------------------------------------------------------------
1481 have_manpages=no
1482 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1483 AC_PATH_PROG([XSLTPROC], [xsltproc])
1484 AS_IF([test "x$enable_manpages" != xno], [
1485        have_manpages=yes
1486        AS_IF([test -z "$XSLTPROC"],
1487              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1488 ])
1489 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1490
1491 # ------------------------------------------------------------------------------
1492 AC_ARG_ENABLE(hibernate,
1493        [AS_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1494        enable_hibernate=$enableval, enable_hibernate=yes)
1495 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1496
1497 # ------------------------------------------------------------------------------
1498 AC_ARG_ENABLE(ldconfig,
1499        [AS_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1500        enable_ldconfig=$enableval, enable_ldconfig=yes)
1501 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1502
1503 # ------------------------------------------------------------------------------
1504 # Location of the init scripts as mandated by LSB
1505 SYSTEM_SYSVINIT_PATH=/etc/init.d
1506 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1507
1508 AC_ARG_WITH([sysvinit-path],
1509         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1510                 [specify the path to where the SysV init scripts are located])],
1511         [SYSTEM_SYSVINIT_PATH="$withval"],
1512         [])
1513
1514 AC_ARG_WITH([sysvrcnd-path],
1515         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1516                 [specify the path to the base directory for the SysV rcN.d directories])],
1517         [SYSTEM_SYSVRCND_PATH="$withval"],
1518         [])
1519
1520 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1521         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1522         SYSTEM_SYSV_COMPAT="yes"
1523         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1524 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1525         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1526 else
1527         SYSTEM_SYSV_COMPAT="no"
1528 fi
1529
1530 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1531 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1532 AC_SUBST(M4_DEFINES)
1533
1534 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1535
1536 AC_ARG_WITH([tty-gid],
1537         [AS_HELP_STRING([--with-tty-gid=GID],
1538                 [specify the numeric GID of the 'tty' group])],
1539         [TTY_GID="$withval"],
1540         [TTY_GID="5"])
1541
1542 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1543 AC_SUBST(TTY_GID)
1544
1545 AC_ARG_WITH([dbuspolicydir],
1546         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1547         [],
1548         [with_dbuspolicydir=${datadir}/dbus-1/system.d])
1549 AX_NORMALIZE_PATH([with_dbuspolicydir])
1550
1551 AC_ARG_WITH([dbussessionservicedir],
1552         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1553         [],
1554         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1555 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1556
1557 AC_ARG_WITH([dbussystemservicedir],
1558         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1559         [],
1560         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1561 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1562
1563 AC_ARG_WITH([bashcompletiondir],
1564         AS_HELP_STRING([--with-bashcompletiondir=DIR], [bash completions directory]),
1565         [],
1566         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1567                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1568         ] , [
1569                 with_bashcompletiondir=${datadir}/bash-completion/completions
1570         ])])
1571 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1572 AX_NORMALIZE_PATH([with_bashcompletiondir])
1573
1574 AC_ARG_WITH([zshcompletiondir],
1575         AS_HELP_STRING([--with-zshcompletiondir=DIR], [zsh completions directory]),
1576         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1577 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1578 AX_NORMALIZE_PATH([with_zshcompletiondir])
1579
1580 AC_ARG_WITH([rootprefix],
1581         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1582         [], [with_rootprefix=${ac_default_prefix}])
1583 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1584 # defaults those to ".", solve that here for now until we can find a suitable
1585 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1586 # See: https://github.com/systemd/systemd/issues/54
1587 if test "x${with_rootprefix}" = "x"; then
1588         with_rootprefix="/"
1589 fi
1590 AX_NORMALIZE_PATH([with_rootprefix])
1591
1592 AC_ARG_WITH([rootlibdir],
1593         AS_HELP_STRING([--with-rootlibdir=DIR], [root directory for libraries necessary for boot]),
1594         [],
1595         [with_rootlibdir=${libdir}])
1596 AX_NORMALIZE_PATH([with_rootlibdir])
1597
1598 AC_ARG_WITH([pamlibdir],
1599         AS_HELP_STRING([--with-pamlibdir=DIR], [directory for PAM modules]),
1600         [],
1601         [with_pamlibdir=${with_rootlibdir}/security])
1602 AX_NORMALIZE_PATH([with_pamlibdir])
1603
1604 AC_ARG_WITH([pamconfdir],
1605         AS_HELP_STRING([--with-pamconfdir=DIR], [directory for PAM configuration (pass no to disable installing)]),
1606         [],
1607         [with_pamconfdir=${sysconfdir}/pam.d])
1608 AM_CONDITIONAL(ENABLE_PAM_CONFIG, [test "$with_pamconfdir" != "no"])
1609 AX_NORMALIZE_PATH([with_pamconfdir])
1610
1611 AC_ARG_WITH([rpmmacrosdir],
1612         AS_HELP_STRING([--with-rpmmacrosdir=DIR], [directory to store macros for RPM]),
1613         [], [with_rpmmacrosdir=\${prefix}/lib/rpm/macros.d])
1614 AM_CONDITIONAL(ENABLE_RPM_MACROS, [test "$with_rpmmacrosdir" != "no"])
1615 AX_NORMALIZE_PATH([with_rpmmacrosdir])
1616
1617 AC_ARG_ENABLE([split-usr],
1618         AS_HELP_STRING([--enable-split-usr], [assume that /bin, /sbin aren't symlinks into /usr]),
1619         [],
1620         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1621                 enable_split_usr=yes
1622         ], [
1623                 enable_split_usr=no
1624         ])])
1625
1626 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1627         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1628 ])
1629 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1630
1631 # work around intltool-update issues during 'make distcheck'
1632 AS_IF([test "x$0" != "x./configure"], [
1633         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1634 ])
1635
1636 # QEMU and OVMF UEFI firmware
1637 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1638         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1639         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1640                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1641         AC_SUBST([QEMU_BIOS])
1642 ])
1643
1644 AC_ARG_ENABLE(tests,
1645         [AS_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1646         enable_tests=$enableval, enable_tests=yes)
1647 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1648 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1649
1650 AC_ARG_ENABLE(debug,
1651         [AS_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1652         [if test "x$enableval" = "xyes"; then
1653                 enableval="hashmap,mmap-cache"
1654         fi
1655         saved_ifs="$IFS"
1656         IFS="$IFS$PATH_SEPARATOR,"
1657         for name in $enableval; do
1658                 case $name in
1659                 hashmap)
1660                         enable_debug_hashmap=yes
1661                         ;;
1662                 mmap-cache)
1663                         enable_debug_mmap_cache=yes
1664                         ;;
1665                 esac
1666         done
1667         IFS="$saved_ifs"],[])
1668
1669 enable_debug=""
1670 AS_IF([test x$enable_debug_hashmap = xyes], [
1671         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1672         enable_debug="hashmap $enable_debug"
1673 ])
1674 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1675         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1676         enable_debug="mmap-cache $enable_debug"
1677 ])
1678 test -z "$enable_debug" && enable_debug="none"
1679
1680 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1681 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1682 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1683 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1684 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1685 AC_SUBST([pamlibdir], [$with_pamlibdir])
1686 AC_SUBST([pamconfdir], [$with_pamconfdir])
1687 AC_SUBST([rpmmacrosdir], [$with_rpmmacrosdir])
1688 AC_SUBST([rootprefix], [$with_rootprefix])
1689 AC_SUBST([rootlibdir], [$with_rootlibdir])
1690
1691 AC_CONFIG_FILES([
1692         Makefile
1693         po/Makefile.in
1694 ])
1695
1696 AC_OUTPUT
1697 AC_MSG_RESULT([
1698         $PACKAGE_NAME $PACKAGE_VERSION
1699
1700         libcryptsetup:                     ${have_libcryptsetup}
1701         PAM:                               ${have_pam}
1702         AUDIT:                             ${have_audit}
1703         IMA:                               ${have_ima}
1704         AppArmor:                          ${have_apparmor}
1705         SELinux:                           ${have_selinux}
1706         SECCOMP:                           ${have_seccomp}
1707         SMACK:                             ${have_smack}
1708         ZLIB:                              ${have_zlib}
1709         XZ:                                ${have_xz}
1710         LZ4:                               ${have_lz4}
1711         BZIP2:                             ${have_bzip2}
1712         ACL:                               ${have_acl}
1713         GCRYPT:                            ${have_gcrypt}
1714         QRENCODE:                          ${have_qrencode}
1715         MICROHTTPD:                        ${have_microhttpd}
1716         GNUTLS:                            ${have_gnutls}
1717         libcurl:                           ${have_libcurl}
1718         libidn:                            ${have_libidn}
1719         libiptc:                           ${have_libiptc}
1720         ELFUTILS:                          ${have_elfutils}
1721         binfmt:                            ${have_binfmt}
1722         vconsole:                          ${have_vconsole}
1723         quotacheck:                        ${have_quotacheck}
1724         tmpfiles:                          ${have_tmpfiles}
1725         environment.d:                     ${have_environment_d}
1726         sysusers:                          ${have_sysusers}
1727         firstboot:                         ${have_firstboot}
1728         randomseed:                        ${have_randomseed}
1729         backlight:                         ${have_backlight}
1730         rfkill:                            ${have_rfkill}
1731         logind:                            ${have_logind}
1732         default cgroup hierarchy:          ${DEFAULT_HIERARCHY}
1733         default KillUserProcesses setting: ${KILL_USER_PROCESSES}
1734         machined:                          ${have_machined}
1735         importd:                           ${have_importd}
1736         hostnamed:                         ${have_hostnamed}
1737         timedated:                         ${have_timedated}
1738         timesyncd:                         ${have_timesyncd}
1739         default NTP servers:               ${NTP_SERVERS}
1740         time epoch:                        ${TIME_EPOCH}
1741         localed:                           ${have_localed}
1742         networkd:                          ${have_networkd}
1743         resolved:                          ${have_resolved}
1744         default DNS servers:               ${DNS_SERVERS}
1745         default DNSSEC mode:               ${DEFAULT_DNSSEC_MODE}
1746         coredump:                          ${have_coredump}
1747         polkit:                            ${have_polkit} (legacy pkla support: ${polkit_pkla})
1748         efi:                               ${have_efi}
1749         gnuefi:                            ${have_gnuefi}
1750         efi arch:                          ${EFI_ARCH}
1751         EFI machine type:                  ${EFI_MACHINE_TYPE_NAME}
1752         EFI CC                             ${EFI_CC}
1753         EFI libdir:                        ${EFI_LIB_DIR}
1754         EFI ldsdir:                        ${EFI_LDS_DIR}
1755         EFI includedir:                    ${EFI_INC_DIR}
1756         kmod:                              ${have_kmod}
1757         xkbcommon:                         ${have_xkbcommon}
1758         blkid:                             ${have_blkid}
1759         libmount:                          ${have_libmount}
1760         dbus:                              ${have_dbus}
1761         glib:                              ${have_glib}
1762         nss-myhostname:                    ${have_myhostname}
1763         hwdb:                              ${enable_hwdb}
1764         tpm:                               ${have_tpm}
1765         Python:                            ${have_python}
1766         man pages:                         ${have_manpages}
1767         test coverage:                     ${have_coverage}
1768         Split /usr:                        ${enable_split_usr}
1769         SysV compatibility:                ${SYSTEM_SYSV_COMPAT}
1770         utmp/wtmp support:                 ${have_utmp}
1771         ldconfig support:                  ${enable_ldconfig}
1772         hibernate support:                 ${enable_hibernate}
1773         extra debugging:                   ${enable_debug}
1774         tests:                             ${enable_tests}
1775
1776         prefix:                            ${prefix}
1777         rootprefix:                        ${with_rootprefix}
1778         sysconf dir:                       ${sysconfdir}
1779         datarootdir:                       ${datarootdir}
1780         includedir:                        ${includedir}
1781         lib dir:                           ${libdir}
1782         rootlib dir:                       ${with_rootlibdir}
1783         SysV init scripts:                 ${SYSTEM_SYSVINIT_PATH}
1784         SysV rc?.d directories:            ${SYSTEM_SYSVRCND_PATH}
1785         build Python:                      ${PYTHON}
1786         PAM modules dir:                   ${with_pamlibdir}
1787         PAM configuration dir:             ${with_pamconfdir}
1788         RPM macros dir:                    ${with_rpmmacrosdir}
1789         D-Bus policy dir:                  ${with_dbuspolicydir}
1790         D-Bus session dir:                 ${with_dbussessionservicedir}
1791         D-Bus system dir:                  ${with_dbussystemservicedir}
1792         bash completions dir:              ${with_bashcompletiondir}
1793         zsh completions dir:               ${with_zshcompletiondir}
1794         extra start script:                ${RC_LOCAL_SCRIPT_PATH_START}
1795         extra stop script:                 ${RC_LOCAL_SCRIPT_PATH_STOP}
1796         adm group:                         ${have_adm_group}
1797         wheel group:                       ${have_wheel_group}
1798         debug shell:                       ${SUSHELL} @ ${DEBUGTTY}
1799         TTY GID:                           ${TTY_GID}
1800         maximum system UID:                ${SYSTEM_UID_MAX}
1801         maximum system GID:                ${SYSTEM_GID_MAX}
1802         /dev/kvm access mode:              ${DEV_KVM_MODE}
1803         certificate root:                  ${CERTIFICATEROOT}
1804         support URL:                       ${SUPPORT_URL}
1805         nobody user name:                  ${NOBODY_USER_NAME}
1806         nobody group name:                 ${NOBODY_GROUP_NAME}
1807         fallback hostname:                 ${FALLBACK_HOSTNAME}
1808
1809         CFLAGS:   ${OUR_CFLAGS} ${CFLAGS}
1810         CPPFLAGS: ${OUR_CPPFLAGS} ${CPPFLAGS}
1811         LDFLAGS:  ${OUR_LDFLAGS} ${LDFLAGS}
1812 ])