configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[33],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26
  27 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  30
  31 AC_CANONICAL_HOST
  32 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  33 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  34        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  35       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  36
  37 AM_SILENT_RULES([yes])
  38
  39 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  40
  41 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  42         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 ])
  45
  46 # i18n stuff for the PolicyKit policy files
  47 IT_PROG_INTLTOOL([0.40.0])
  48
  49 GETTEXT_PACKAGE=systemd
  50 AC_SUBST(GETTEXT_PACKAGE)
  51
  52 AC_PROG_MKDIR_P
  53 AC_PROG_LN_S
  54 AC_PROG_SED
  55 AC_PROG_AWK
  56
  57 AC_PROG_CC
  58 AC_PROG_CC_C99
  59 AM_PROG_CC_C_O
  60 AC_PROG_GCC_TRADITIONAL
  61
  62 AC_CHECK_TOOL(OBJCOPY, objcopy)
  63 AC_CHECK_TOOL(STRINGS, strings)
  64 AC_CHECK_TOOL(GPERF, gperf)
  65 if test -z "$GPERF" ; then
  66         AC_MSG_ERROR([*** gperf not found])
  67 fi
  68
  69 CC_CHECK_CFLAGS_APPEND([ \
  70         -pipe \
  71         -Wall \
  72         -W \
  73         -Wextra \
  74         -Wno-inline \
  75         -Wvla \
  76         -Wundef \
  77         -Wformat=2 \
  78         -Wlogical-op \
  79         -Wsign-compare \
  80         -Wformat-security \
  81         -Wmissing-include-dirs \
  82         -Wformat-nonliteral \
  83         -Wold-style-definition \
  84         -Wpointer-arith \
  85         -Winit-self \
  86         -Wdeclaration-after-statement \
  87         -Wfloat-equal \
  88         -Wmissing-prototypes \
  89         -Wstrict-prototypes \
  90         -Wredundant-decls \
  91         -Wmissing-declarations \
  92         -Wmissing-noreturn \
  93         -Wshadow \
  94         -Wendif-labels \
  95         -Wcast-align \
  96         -Wstrict-aliasing=2 \
  97         -Wwrite-strings \
  98         -Wno-long-long \
  99         -Wno-overlength-strings \
 100         -Wno-unused-parameter \
 101         -Wno-missing-field-initializers \
 102         -Wno-unused-result \
 103         -Wp,-D_FORTIFY_SOURCE=2 \
 104         -ffast-math \
 105         -fno-common \
 106         -fdiagnostics-show-option \
 107         -fno-strict-aliasing \
 108         -fvisibility=hidden \
 109         -ffunction-sections \
 110         -fdata-sections \
 111         -Wl,--as-needed \
 112         -Wl,--gc-sections])
 113
 114 LT_PREREQ(2.2)
 115 LT_INIT
 116
 117 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 118 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 119
 120 save_LIBS="$LIBS"
 121 LIBS=
 122 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 123 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 124 CAP_LIBS="$LIBS"
 125 LIBS="$save_LIBS"
 126 AC_SUBST(CAP_LIBS)
 127
 128 # This makes sure pkg.m4 is available.
 129 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 130
 131 PKG_CHECK_MODULES(UDEV, [ libudev >= 172 ])
 132 AC_SUBST(UDEV_CFLAGS)
 133 AC_SUBST(UDEV_LIBS)
 134
 135 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 136 AC_SUBST(DBUS_CFLAGS)
 137 AC_SUBST(DBUS_LIBS)
 138
 139 have_selinux=no
 140 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 141 if test "x$enable_selinux" != "xno"; then
 142         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 143                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 144         AC_SUBST(SELINUX_CFLAGS)
 145         AC_SUBST(SELINUX_LIBS)
 146         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 147                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 148         fi
 149 fi
 150 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 151
 152 AC_ARG_ENABLE([tcpwrap],
 153         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 154                 [case "${enableval}" in
 155                         yes) have_tcpwrap=yes ;;
 156                         no) have_tcpwrap=no ;;
 157                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 158                 esac],
 159                 [have_tcpwrap=auto])
 160
 161 if test "x${have_tcpwrap}" != xno ; then
 162         ACX_LIBWRAP
 163         if test "x${LIBWRAP_LIBS}" = x ; then
 164                 if test "x$have_tcpwrap" = xyes ; then
 165                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 166                 fi
 167                 have_tcpwrap=no
 168         else
 169                 have_tcpwrap=yes
 170         fi
 171 else
 172         LIBWRAP_LIBS=
 173 fi
 174 AC_SUBST(LIBWRAP_LIBS)
 175
 176 AC_ARG_ENABLE([pam],
 177         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 178                 [case "${enableval}" in
 179                         yes) have_pam=yes ;;
 180                         no) have_pam=no ;;
 181                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 182                 esac],
 183                 [have_pam=auto])
 184
 185 if test "x${have_pam}" != xno ; then
 186         AC_CHECK_HEADERS(
 187                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 188                 [have_pam=yes],
 189                 [if test "x$have_pam" = xyes ; then
 190                         AC_MSG_ERROR([*** PAM headers not found.])
 191                 fi])
 192
 193         AC_CHECK_LIB(
 194                 [pam],
 195                 [pam_syslog],
 196                 [have_pam=yes],
 197                 [if test "x$have_pam" = xyes ; then
 198                         AC_MSG_ERROR([*** libpam not found.])
 199                 fi])
 200
 201         if test "x$have_pam" = xyes ; then
 202                 PAM_LIBS="-lpam -lpam_misc"
 203                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 204         else
 205                 have_pam=no
 206         fi
 207 else
 208         PAM_LIBS=
 209 fi
 210 AC_SUBST(PAM_LIBS)
 211 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 212
 213 AC_ARG_ENABLE([acl],
 214         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 215                 [case "${enableval}" in
 216                         yes) have_acl=yes ;;
 217                         no) have_acl=no ;;
 218                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 219                 esac],
 220                 [have_acl=auto])
 221
 222 if test "x${have_acl}" != xno ; then
 223         AC_CHECK_HEADERS(
 224                 [sys/acl.h acl/libacl.h],
 225                 [have_acl=yes],
 226                 [if test "x$have_acl" = xyes ; then
 227                         AC_MSG_ERROR([*** ACL headers not found.])
 228                 fi])
 229
 230         AC_CHECK_LIB(
 231                 [acl],
 232                 [acl_get_file],
 233                 [have_acl=yes],
 234                 [if test "x$have_acl" = xyes ; then
 235                         AC_MSG_ERROR([*** libacl not found.])
 236                 fi])
 237
 238         if test "x$have_acl" = xyes ; then
 239                 ACL_LIBS="-lacl"
 240                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 241         else
 242                 have_acl=no
 243         fi
 244 else
 245         ACL_LIBS=
 246 fi
 247 AC_SUBST(ACL_LIBS)
 248 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 249
 250 AC_ARG_ENABLE([audit],
 251         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 252                 [case "${enableval}" in
 253                         yes) have_audit=yes ;;
 254                         no) have_audit=no ;;
 255                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 256                 esac],
 257                 [have_audit=auto])
 258
 259 if test "x${have_audit}" != xno ; then
 260         AC_CHECK_HEADERS(
 261                 [libaudit.h],
 262                 [have_audit=yes],
 263                 [if test "x$have_audit" = xyes ; then
 264                         AC_MSG_ERROR([*** AUDIT headers not found.])
 265                 fi])
 266
 267         AC_CHECK_LIB(
 268                 [audit],
 269                 [audit_open],
 270                 [have_audit=yes],
 271                 [if test "x$have_audit" = xyes ; then
 272                         AC_MSG_ERROR([*** libaudit not found.])
 273                 fi])
 274
 275         if test "x$have_audit" = xyes ; then
 276                 AUDIT_LIBS="-laudit"
 277                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 278         else
 279                 have_audit=no
 280         fi
 281 else
 282         AUDIT_LIBS=
 283 fi
 284 AC_SUBST(AUDIT_LIBS)
 285
 286 have_libcryptsetup=no
 287 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 288 if test "x$enable_libcryptsetup" != "xno"; then
 289         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 290                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 291         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
 292         AC_SUBST(LIBCRYPTSETUP_LIBS)
 293         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 294                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 295         fi
 296 fi
 297 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 298
 299 have_binfmt=no
 300 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 301 if test "x$enable_binfmt" != "xno"; then
 302         have_binfmt=yes
 303 fi
 304 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 305
 306 have_hostnamed=no
 307 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 308 if test "x$enable_hostnamed" != "xno"; then
 309         have_hostnamed=yes
 310 fi
 311 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 312
 313 have_gtk=no
 314 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 315 if test "x$enable_gtk" != "xno"; then
 316         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
 317                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 318         AC_SUBST(GTK_CFLAGS)
 319         AC_SUBST(GTK_LIBS)
 320         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 321                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
 322         fi
 323 fi
 324 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 325
 326 if test "$have_gtk" = "yes"; then
 327         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 328         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
 329
 330         AC_SUBST(LIBNOTIFY_CFLAGS)
 331         AC_SUBST(LIBNOTIFY_LIBS)
 332 fi
 333 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
 334
 335 AM_PROG_VALAC([0.10])
 336 AC_SUBST(VAPIDIR)
 337 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 338
 339 AC_PATH_PROG([XSLTPROC], [xsltproc])
 340 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 341
 342 AC_PATH_PROG([M4], [m4])
 343
 344 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux or other]))
 345 if test "z$with_distro" = "z"; then
 346         if test "$cross_compiling" = yes; then
 347                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 348         else
 349                 test -f "/etc/redhat-release" && with_distro="fedora"
 350                 test -f "/etc/SuSE-release" && with_distro="suse"
 351                 test -f "/etc/debian_version" &&  with_distro="debian"
 352                 test -f "/etc/arch-release" && with_distro="arch"
 353                 test -f "/etc/gentoo-release" && with_distro="gentoo"
 354                 test -f "/etc/slackware-version" && with_distro="slackware"
 355                 test -f "/etc/frugalware-release" && with_distro="frugalware"
 356                 test -f "/etc/altlinux-release" && with_distro="altlinux"
 357                 test -f "/etc/mandriva-release" && with_distro="mandriva"
 358                 test -f "/etc/meego-release" && with_distro="meego"
 359                 test -f "/etc/angstrom-version" && with_distro="angstrom"
 360                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 361                         with_distro="ubuntu"
 362                 fi
 363         fi
 364         if test "z$with_distro" = "z"; then
 365                 with_distro=`uname -s`
 366         fi
 367 fi
 368 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 369 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 370
 371 # Location of the init scripts as mandated by LSB
 372 SYSTEM_SYSVINIT_PATH=/etc/init.d
 373 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 374
 375 M4_DEFINES=
 376 have_plymouth=no
 377
 378 case $with_distro in
 379         fedora)
 380                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 381                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 382                 M4_DEFINES=-DTARGET_FEDORA=1
 383                 have_plymouth=yes
 384                 ;;
 385         suse)
 386                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 387                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 388                 M4_DEFINES=-DTARGET_SUSE=1
 389                 have_plymouth=yes
 390                 ;;
 391         debian)
 392                 SYSTEM_SYSVRCND_PATH=/etc
 393                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 394                 M4_DEFINES=-DTARGET_DEBIAN=1
 395                 ;;
 396         ubuntu)
 397                 SYSTEM_SYSVRCND_PATH=/etc
 398                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 399                 M4_DEFINES=-DTARGET_UBUNTU=1
 400                 ;;
 401         arch)
 402                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 403                 SYSTEM_SYSVRCND_PATH=/etc
 404                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 405                 M4_DEFINES=-DTARGET_ARCH=1
 406                 ;;
 407         gentoo)
 408                 SYSTEM_SYSVINIT_PATH=
 409                 SYSTEM_SYSVRCND_PATH=
 410                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 411                 M4_DEFINES=-DTARGET_GENTOO=1
 412                 ;;
 413         slackware)
 414                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 415                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 416                 M4_DEFINES=-DTARGET_SLACKWARE=1
 417                 ;;
 418         frugalware)
 419                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 420                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 421                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 422                 have_plymouth=yes
 423                 ;;
 424         altlinux)
 425                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 426                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 427                 M4_DEFINES=-DTARGET_ALTLINUX=1
 428                 have_plymouth=yes
 429                 ;;
 430         mandriva)
 431                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 432                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 433                 M4_DEFINES=-DTARGET_MANDRIVA=1
 434                 have_plymouth=yes
 435                 ;;
 436         meego)
 437                 SYSTEM_SYSVINIT_PATH=
 438                 SYSTEM_SYSVRCND_PATH=
 439                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
 440                 M4_DEFINES=-DTARGET_MEEGO=1
 441                 ;;
 442         angstrom)
 443                 SYSTEM_SYSVRCND_PATH=/etc
 444                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 445                 M4_DEFINES=-DTARGET_ANGSTROM=1
 446                 ;;
 447         other)
 448                 ;;
 449         *)
 450                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 451                 ;;
 452 esac
 453
 454 AC_ARG_WITH([sysvinit-path],
 455         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 456                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 457         [SYSTEM_SYSVINIT_PATH="$withval"],
 458         [])
 459
 460 AC_ARG_WITH([sysvrcd-path],
 461         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 462                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 463         [SYSTEM_SYSVRCND_PATH="$withval"],
 464         [])
 465
 466 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 467 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 468 AC_SUBST(M4_DEFINES)
 469
 470 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 471         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 472         SYSTEM_SYSV_COMPAT="yes"
 473         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 474 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 475         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 476 else
 477         SYSTEM_SYSV_COMPAT="no"
 478 fi
 479
 480 AC_ARG_WITH([tty-gid],
 481         [AS_HELP_STRING([--with-tty-gid=GID],
 482                 [Specify the numeric GID of the 'tty' group])],
 483         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 484         [])
 485
 486 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
 487 if test -n "$enable_plymouth"; then
 488         have_plymouth="$enable_plymouth"
 489 fi
 490
 491 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 492 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 493 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 494 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 495 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 496 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 497 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 498 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 499 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 500 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 501 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 502 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
 503 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 504
 505 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
 506 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 507
 508 AC_ARG_WITH([dbuspolicydir],
 509         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 510         [],
 511         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 512
 513 AC_ARG_WITH([dbussessionservicedir],
 514         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 515         [],
 516         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 517
 518 AC_ARG_WITH([dbussystemservicedir],
 519         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 520         [],
 521         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 522
 523 AC_ARG_WITH([dbusinterfacedir],
 524         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 525         [],
 526         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 527
 528 AC_ARG_WITH([udevrulesdir],
 529         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 530         [],
 531         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 532
 533 AC_ARG_WITH([pamlibdir],
 534         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 535         [],
 536         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 537
 538 AC_ARG_WITH([rootdir],
 539         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 540         [],
 541         [with_rootdir=${ac_default_prefix}])
 542
 543 AC_ARG_WITH([rootlibdir],
 544         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 545         [],
 546         [with_rootlibdir=${libdir}])
 547
 548 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 549 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 550 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 551 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 552 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 553 AC_SUBST([pamlibdir], [$with_pamlibdir])
 554 AC_SUBST([rootdir], [$with_rootdir])
 555 AC_SUBST([rootlibdir], [$with_rootlibdir])
 556
 557 AC_CONFIG_FILES([Makefile po/Makefile.in])
 558 AC_OUTPUT
 559 AC_MSG_RESULT([
 560         $PACKAGE_NAME $VERSION
 561
 562         Distribution:            ${with_distro}
 563         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 564         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 565         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 566         Gtk:                     ${have_gtk}
 567         libcryptsetup:           ${have_libcryptsetup}
 568         tcpwrap:                 ${have_tcpwrap}
 569         PAM:                     ${have_pam}
 570         AUDIT:                   ${have_audit}
 571         SELinux:                 ${have_selinux}
 572         ACL:                     ${have_acl}
 573         binfmt:                  ${have_binfmt}
 574         hostnamed:               ${have_hostnamed}
 575         plymouth:                ${have_plymouth}
 576         prefix:                  ${prefix}
 577         root dir:                ${with_rootdir}
 578         lib dir:                 ${libdir}
 579         rootlib dir:             ${with_rootlibdir}
 580         pam modules dir:         ${with_pamlibdir}
 581         udev rules dir:          ${with_udevrulesdir}
 582         dbus policy dir:         ${with_dbuspolicydir}
 583         dbus session dir:        ${with_dbussessionservicedir}
 584         dbus system dir:         ${with_dbussystemservicedir}
 585         dbus interfaces dir:     ${with_dbusinterfacedir}
 586 ])