configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[0],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30
  31 AM_SILENT_RULES([yes])
  32
  33 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  34
  35 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  36         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  37         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  38 ])
  39
  40 AC_PROG_MKDIR_P
  41 AC_PROG_LN_S
  42 AC_PROG_SED
  43
  44 AC_PROG_CC
  45 AC_PROG_CC_C99
  46 AM_PROG_CC_C_O
  47 AC_PROG_GCC_TRADITIONAL
  48 AC_USE_SYSTEM_EXTENSIONS
  49
  50 CC_CHECK_CFLAGS_APPEND([ \
  51         -Wall \
  52         -W \
  53         -Wextra \
  54         -pipe \
  55         -Wno-long-long \
  56         -Winline \
  57         -Wvla \
  58         -Wno-overlength-strings \
  59         -Wundef \
  60         -Wformat=2 \
  61         -Wlogical-op \
  62         -Wsign-compare \
  63         -Wformat-security \
  64         -Wmissing-include-dirs \
  65         -Wformat-nonliteral \
  66         -Wold-style-definition \
  67         -Wpointer-arith \
  68         -Winit-self \
  69         -Wdeclaration-after-statement \
  70         -Wfloat-equal \
  71         -Wmissing-prototypes \
  72         -Wstrict-prototypes \
  73         -Wredundant-decls \
  74         -Wmissing-declarations \
  75         -Wmissing-noreturn \
  76         -Wshadow \
  77         -Wendif-labels \
  78         -Wcast-align \
  79         -Wstrict-aliasing=2 \
  80         -Wwrite-strings \
  81         -Wno-unused-parameter \
  82         -ffast-math \
  83         -Wp,-D_FORTIFY_SOURCE=2 \
  84         -fno-common \
  85         -fdiagnostics-show-option \
  86         -Wno-missing-field-initializers])
  87
  88 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
  89 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
  90 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
  91
  92 # This makes sure pkg.m4 is available.
  93 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  94
  95 PKG_CHECK_MODULES(UDEV, [ libudev >= 154 ])
  96 AC_SUBST(UDEV_CFLAGS)
  97 AC_SUBST(UDEV_LIBS)
  98
  99 PKG_CHECK_MODULES(DBUS, [ dbus-1 ])
 100 AC_SUBST(DBUS_CFLAGS)
 101 AC_SUBST(DBUS_LIBS)
 102
 103 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
 104 AC_SUBST(DBUSGLIB_CFLAGS)
 105 AC_SUBST(DBUSGLIB_LIBS)
 106
 107 PKG_CHECK_MODULES(CGROUP, [ libcgroup >= 0.36 ])
 108 AC_SUBST(CGROUP_CFLAGS)
 109 AC_SUBST(CGROUP_LIBS)
 110
 111 AC_ARG_ENABLE([tcpwrap],
 112         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 113                 [case "${enableval}" in
 114                         yes) tcpwrap=yes ;;
 115                         no) tcpwrap=no ;;
 116                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 117                 esac],
 118                 [tcpwrap=auto])
 119
 120 if test "x${tcpwrap}" != xno ; then
 121         ACX_LIBWRAP
 122         if test "x${LIBWRAP_LIBS}" = x ; then
 123                 if test "x$tcpwrap" = xyes ; then
 124                         AC_MSG_ERROR([*** TCP wrappers support not found])
 125                 fi
 126         else
 127                 tcpwrap=yes
 128         fi
 129 else
 130     LIBWRAP_LIBS=
 131 fi
 132
 133 AC_SUBST(LIBWRAP_LIBS)
 134
 135 have_gtk=no
 136 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 137 if test "x$enable_gtk" != "xno"; then
 138         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 ],
 139                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 140         AC_SUBST(GTK_CFLAGS)
 141         AC_SUBST(GTK_LIBS)
 142         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 143              AC_MSG_ERROR([*** gtk support requested but libraries not found])
 144         fi
 145 fi
 146 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 147
 148 AM_PROG_VALAC([0.8])
 149 AC_SUBST(VAPIDIR)
 150 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 151
 152 AC_PATH_PROG([XSLTPROC], [xsltproc])
 153 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 154
 155 AC_PATH_PROG([M4], [m4])
 156
 157 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, arch, gentoo, slackware or other]))
 158 if test "z$with_distro" = "z"; then
 159         if test "$cross_compiling" = yes; then
 160                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 161         else
 162                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 163                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 164                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 165                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 166                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 167                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 168         fi
 169         if test "z$with_distro" = "z"; then
 170                 with_distro=`uname -s`
 171         fi
 172 fi
 173 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 174
 175 # Default generic names
 176 SPECIAL_DBUS_SERVICE=dbus.service
 177 SPECIAL_SYSLOG_SERVICE=syslog.service
 178
 179 # Location of the init scripts as mandated by LSB
 180 SYSTEM_SYSVINIT_PATH=/etc/init.d
 181
 182 M4_DISTRO_FLAG=
 183
 184 case $with_distro in
 185         fedora)
 186                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 187                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 188
 189                 # A little background why we define these special unit
 190                 # names here in configure.ac: SysV services currently
 191                 # cannot have aliases. As long as syslog is started
 192                 # via a SysV init script we hence define these names
 193                 # to the actual SysV name here. Later on when SysV
 194                 # init scripts are not used anymore it is advisable to
 195                 # use the generic names instead and use symlinks in
 196                 # the unit directories to point to the right native
 197                 # unit file.
 198
 199                 SPECIAL_DBUS_SERVICE=messagebus.service
 200                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 201                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 202                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 203                 ;;
 204         suse)
 205                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 206                 AC_DEFINE(TARGET_SUSE, [], [Target is OpenSUSE/SLE])
 207                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 208                 ;;
 209         debian)
 210                 SYSTEM_SYSVRCND_PATH=/etc
 211                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 212                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
 213                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 214                 ;;
 215         arch)
 216                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 217                 SYSTEM_SYSVRCND_PATH=/etc
 218                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 219                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 220                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 221                 ;;
 222         gentoo)
 223                 SYSTEM_SYSVRCND_PATH=/etc
 224                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 225                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 226                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 227                 ;;
 228         slackware)
 229                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 230                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 231                 SPECIAL_DBUS_SERVICE=messagebus.service
 232                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 233                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 234                 ;;
 235         other)
 236                 AS_IF([test "x$with_sysvinit_path" = "x"],
 237                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvinit-path= to configure])])
 238                 AS_IF([test "x$with_sysvrcd_path" = "x"],
 239                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvrcd-path= to configure])])
 240                 AS_IF([test "x$with_dbus_service" = "x"],
 241                         [AC_MSG_ERROR([With --distro=other, you must pass --with-dbus-service= to configure])])
 242                 AS_IF([test "x$with_syslog_service" = "x"],
 243                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 244                 ;;
 245         *)
 246                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 247                 ;;
 248 esac
 249
 250 AC_ARG_WITH([sysvinit-path],
 251         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 252                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 253         [SYSTEM_SYSVINIT_PATH="$withval"],
 254         [])
 255
 256 AC_ARG_WITH([sysvrcd-path],
 257         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 258                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 259         [SYSTEM_SYSVRCND_PATH="$withval"],
 260         [])
 261
 262 AC_ARG_WITH([dbus-service],
 263         [AS_HELP_STRING([--with-dbus-service=UNIT],
 264                 [Specify the name of the special DBus service @<:@default=based on distro@:>@])],
 265         [SPECIAL_DBUS_SERVICE="$withval"],
 266         [])
 267
 268 AC_ARG_WITH([syslog-service],
 269         [AS_HELP_STRING([--with-syslog-service=UNIT],
 270                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 271         [SPECIAL_SYSLOG_SERVICE="$withval"],
 272         [])
 273
 274 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 275 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 276 AC_SUBST(SPECIAL_DBUS_SERVICE)
 277 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 278 AC_SUBST(M4_DISTRO_FLAG)
 279
 280 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 281 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 282 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 283 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 284 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 285 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 286
 287 AC_DEFINE_UNQUOTED(SPECIAL_DBUS_SERVICE, ["$SPECIAL_DBUS_SERVICE"], [D-Bus service name])
 288 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 289
 290 AC_ARG_WITH([dbuspolicydir],
 291         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 292         [],
 293         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 294
 295 AC_ARG_WITH([dbussessionservicedir],
 296         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 297         [],
 298         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 299
 300 AC_ARG_WITH([dbussystemservicedir],
 301         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 302         [],
 303         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 304
 305 AC_ARG_WITH([dbusinterfacedir],
 306         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 307         [],
 308         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 309
 310 AC_ARG_WITH([udevrulesdir],
 311         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 312         [],
 313         [with_udevrulesdir=/lib/udev/rules.d])
 314
 315 AC_ARG_WITH([rootdir],
 316         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 317         [],
 318         [with_rootdir=${ac_default_prefix}])
 319
 320 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 321 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 322 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 323 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 324 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 325 AC_SUBST([rootdir], [$with_rootdir])
 326
 327 AC_CONFIG_FILES([Makefile])
 328 AC_OUTPUT
 329
 330 echo "
 331         $PACKAGE_NAME $VERSION
 332
 333         Distribution:            ${with_distro}
 334         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 335         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 336         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 337         D-Bus service:           ${SPECIAL_DBUS_SERVICE}
 338         Gtk:                     ${have_gtk}
 339         tcpwrap:                 ${tcpwrap}
 340         prefix:                  ${prefix}
 341         root dir:                ${with_rootdir}
 342         udev rules dir:          ${with_udevrulesdir}
 343         dbus policy dir:         ${with_dbuspolicydir}
 344         dbus session dir:        ${with_dbussessionservicedir}
 345         dbus system dir:         ${with_dbussystemservicedir}
 346         dbus interfaces dir:     ${with_dbusinterfacedir}
 347 "