configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Must change all of the below together
   5 # For a release, set revision for that tagged release as well and uncomment
   6 AC_INIT([freeswitch], [1.10.4-dev], bugs@freeswitch.org)
   7 AC_SUBST(SWITCH_VERSION_MAJOR, [1])
   8 AC_SUBST(SWITCH_VERSION_MINOR, [10])
   9 AC_SUBST(SWITCH_VERSION_MICRO, [4-dev])
  10 AC_SUBST(SWITCH_VERSION_REVISION, [])
  11 AC_SUBST(SWITCH_VERSION_REVISION_HUMAN, [])
  12
  13 AC_CONFIG_FILES([src/include/switch_version.h.in:src/include/switch_version.h.template])
  14
  15 AC_CONFIG_AUX_DIR(build/config)
  16 AM_INIT_AUTOMAKE
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([src/switch.c])
  19 AC_CONFIG_HEADER([src/include/switch_private.h])
  20 AC_CONFIG_HEADER([libs/esl/src/include/esl_config_auto.h])
  21 AC_CONFIG_HEADER([libs/xmlrpc-c/xmlrpc_amconfig.h])
  22
  23 AC_CANONICAL_HOST
  24
  25 # Absolute source/build directory
  26 switch_srcdir=`(cd $srcdir && pwd)`
  27 switch_builddir=`pwd`
  28 AC_SUBST(switch_srcdir)
  29 AC_SUBST(switch_builddir)
  30
  31 #
  32 # --enable-64 has been moved up higher prior to AC_PROG_CC so that we can tuck in the -m64 flag
  33 # so devs on with Solaris wanting to build 64bit can not bother with adding any additional
  34 # flags on the ./configure line.  User friendly.
  35 #
  36
  37 #  Enable 64 bit build
  38 AC_ARG_ENABLE(64,
  39 [AC_HELP_STRING([--enable-64],[build with 64 bit support])],[enable_64="$enable_64"],[enable_64="no"])
  40
  41 if test "${enable_64}" = "yes"; then
  42    case "$host" in
  43         *-solaris2*)
  44             # All three have to have -m64 for AC_PROG_CC to pick the right libtool
  45             CFLAGS="$CFLAGS -m64"
  46             LDFLAGS="$LDFLAGS -m64"
  47             CXXFLAGS="$CXXFLAGS -m64"
  48         ;;
  49         *)
  50         ;;
  51    esac
  52 fi
  53
  54 # use mtmalloc on Solaris SPARC if available
  55 AS_CASE([$host], [sparc-*-solaris2*], [AC_CHECK_LIB(mtmalloc, malloc)])
  56
  57 # Whether to follow FHS
  58 AC_ARG_ENABLE([fhs],[AS_HELP_STRING([--disable-fhs],
  59         [Do Not follow the FHS when placing files and directories (default only when not specifying prefix])],[enable_fhs="$enableval"],[enable_fhs="yes"])
  60
  61 AC_PREFIX_DEFAULT(/usr/local/freeswitch)
  62 # AC_PREFIX_DEFAULT does not get expanded until too late so we need to do this to use prefix in this script
  63
  64 if test "x$prefix" = "xNONE" ; then
  65     enable_fhs=no
  66     prefix='/usr/local/freeswitch'
  67 fi
  68
  69 if test "x${exec_prefix}" = "xNONE" ; then
  70     exec_prefix="$prefix"
  71 fi
  72
  73 default_scriptdir="$prefix/scripts"
  74 default_grammardir="$prefix/grammar"
  75 default_soundsdir="$prefix/sounds"
  76 default_htdocsdir="$prefix/htdocs"
  77 default_modulesdir="$prefix/mod"
  78 default_dbdir="$prefix/db"
  79 default_storagedir="$prefix/storage"
  80 default_cachedir="$prefix/cache"
  81 default_recordingsdir="$prefix/recordings"
  82 rundir="$prefix/run"
  83 logdir="${prefix}/log"
  84 confdir="$prefix/conf"
  85 default_certsdir="$prefix/certs"
  86 default_fontsdir="$prefix/fonts"
  87 default_imagesdir="$prefix/images"
  88
  89 if test "${enable_fhs}" = "yes"; then
  90     eval full_datadir="${datadir}/freeswitch"
  91     eval datadir=$full_datadir
  92     eval full_localstatedir="${localstatedir}"
  93     eval localstatedir=$full_localstatedir
  94     eval libdir=$libdir
  95     default_cachedir="${localstatedir}/cache/freeswitch"
  96     rundir="${localstatedir}/run/freeswitch"
  97     logdir="${localstatedir}/log/freeswitch"
  98     localstatedir="${localstatedir}/lib/freeswitch"
  99     default_scriptdir="${datadir}/scripts"
 100     default_grammardir="${datadir}/grammar"
 101     default_soundsdir="${datadir}/sounds"
 102     default_htdocsdir="${datadir}/htdocs"
 103     default_fontsdir="${datadir}/fonts"
 104     default_modulesdir="${libdir}/freeswitch/mod"
 105     default_dbdir="${localstatedir}/db"
 106     default_storagedir="${localstatedir}/storage"
 107     default_recordingsdir="${localstatedir}/recordings"
 108     default_imagesdir="${localstatedir}/images"
 109     eval confdir="${sysconfdir}/freeswitch"
 110     eval default_certsdir="${confdir}/tls"
 111 else
 112     if test "$datadir" = "\${datarootdir}" ; then
 113         datadir="${prefix}"
 114     fi
 115     if test "$localstatedir" = "\${prefix}/var" ; then
 116         localstatedir="${prefix}"
 117     fi
 118 fi
 119
 120 if test "$includedir" = "\${prefix}/include" ; then
 121    includedir="${prefix}/include/freeswitch"
 122 fi
 123
 124 default_pkgconfigdir="$libdir/pkgconfig"
 125 default_runtimedir="$rundir"
 126 default_logfiledir="$logdir"
 127
 128 AC_SUBST(libdir)
 129
 130 # Where to install the modules
 131 AC_ARG_WITH([modinstdir],
 132         [AS_HELP_STRING([--with-modinstdir=DIR], [Install modules into this location (default: $prefix/mod)])], [modulesdir="$withval"], [modulesdir="${default_modulesdir}"])
 133 eval modulesdir="${modulesdir}"
 134 AC_SUBST(modulesdir)
 135 AC_DEFINE_UNQUOTED([SWITCH_MOD_DIR],"${modulesdir}",[where to install the modules to])
 136
 137 # Where to put pidfile
 138 AC_ARG_WITH([rundir],
 139         [AS_HELP_STRING([--with-rundir=DIR], [Put pidfile into this location (default: $prefix/run)])], [runtimedir="$withval"], [runtimedir="${default_runtimedir}"])
 140 AC_SUBST(runtimedir)
 141 AC_DEFINE_UNQUOTED([SWITCH_RUN_DIR],"${runtimedir}",[where to put pidfile to])
 142
 143 AC_ARG_WITH([logfiledir],
 144         [AS_HELP_STRING([--with-logfiledir=DIR], [Put logfiles into this location (default: $localstatedir/log)])], [logfiledir="$withval"], [logfiledir="${default_logfiledir}"])
 145 AC_SUBST(logfiledir)
 146 AC_DEFINE_UNQUOTED([SWITCH_LOG_DIR],"${logfiledir}",[where to put log files])
 147
 148 AC_ARG_WITH([dbdir],
 149         [AS_HELP_STRING([--with-dbdir=DIR], [Put database files into this location (default: $prefix/db)])], [dbdir="$withval"], [dbdir="${default_dbdir}"])
 150 AC_SUBST(dbdir)
 151 AC_DEFINE_UNQUOTED([SWITCH_DB_DIR],"${dbdir}",[where to put db files])
 152
 153 AC_ARG_WITH([htdocsdir],
 154         [AS_HELP_STRING([--with-htdocsdir=DIR], [Put html files into this location (default: $prefix/htdocs)])], [htdocsdir="$withval"], [htdocsdir="${default_htdocsdir}"])
 155 AC_SUBST(htdocsdir)
 156 AC_DEFINE_UNQUOTED([SWITCH_HTDOCS_DIR],"${htdocsdir}",[where to put htdocs files])
 157
 158 AC_ARG_WITH([fontsdir],
 159         [AS_HELP_STRING([--with-fontsdir=DIR], [Put font files into this location (default: $prefix/fonts)])], [fontsdir="$withval"], [fontsdir="${default_fontsdir}"])
 160 AC_SUBST(fontsdir)
 161 AC_DEFINE_UNQUOTED([SWITCH_FONTS_DIR],"${fontsdir}",[where to put font files])
 162
 163 AC_ARG_WITH([soundsdir],
 164         [AS_HELP_STRING([--with-soundsdir=DIR], [Put sound files into this location (default: $prefix/sounds)])], [soundsdir="$withval"], [soundsdir="${default_soundsdir}"])
 165 AC_SUBST(soundsdir)
 166 AC_DEFINE_UNQUOTED([SWITCH_SOUNDS_DIR],"${soundsdir}",[where to put sounds files])
 167
 168 AC_ARG_WITH([grammardir],
 169         [AS_HELP_STRING([--with-grammardir=DIR], [Put grammar files into this location (default: $prefix/grammar)])], [grammardir="$withval"], [grammardir="${default_grammardir}"])
 170 AC_SUBST(grammardir)
 171 AC_DEFINE_UNQUOTED([SWITCH_GRAMMAR_DIR],"${grammardir}",[where to put grammar files])
 172
 173 AC_ARG_WITH([certsdir],
 174         [AS_HELP_STRING([--with-certsdir=DIR], [Put certs files into this location (default: $prefix/certs)])], [certsdir="$withval"], [certsdir="${default_certsdir}"])
 175 AC_SUBST(certsdir)
 176 AC_DEFINE_UNQUOTED([SWITCH_CERTS_DIR],"${certsdir}",[where to put certs files])
 177
 178 AC_ARG_WITH([scriptdir],
 179         [AS_HELP_STRING([--with-scriptdir=DIR], [Put script files into this location (default: $prefix/scripts)])], [scriptdir="$withval"], [scriptdir="${default_scriptdir}"])
 180 AC_SUBST(scriptdir)
 181 AC_DEFINE_UNQUOTED([SWITCH_SCRIPT_DIR],"${scriptdir}",[where to put script files])
 182
 183 AC_ARG_WITH([recordingsdir],
 184         [AS_HELP_STRING([--with-recordingsdir=DIR], [Put recordings files into this location (default: $prefix/recordings)])], [recordingsdir="$withval"], [recordingsdir="${default_recordingsdir}"])
 185 AC_SUBST(recordingsdir)
 186 AC_DEFINE_UNQUOTED([SWITCH_RECORDINGS_DIR],"${recordingsdir}",[where to put recording files])
 187
 188 AC_ARG_WITH([imagesdir],
 189         [AS_HELP_STRING([--with-imagesdir=DIR], [Put images files into this location (default: $prefix/images)])], [imagesdir="$withval"], [imagesdir="${default_imagesdir}"])
 190 AC_SUBST(imagesdir)
 191 AC_DEFINE_UNQUOTED([SWITCH_IMAGES_DIR],"${imagesdir}",[where to put image files])
 192
 193 AC_ARG_WITH([storagedir],
 194         [AS_HELP_STRING([--with-storagedir=DIR], [Put storage files into this location (default: $prefix/storage)])], [storagedir="$withval"], [storagedir="${default_storagedir}"])
 195 AC_SUBST(storagedir)
 196 AC_DEFINE_UNQUOTED([SWITCH_STORAGE_DIR],"${storagedir}",[where to put storage files])
 197
 198 AC_ARG_WITH([cachedir],
 199         [AS_HELP_STRING([--with-cachedir=DIR], [Put cache files into this location (default: $prefix/cache)])], [cachedir="$withval"], [cachedir="${default_cachedir}"])
 200 AC_SUBST(cachedir)
 201 AC_DEFINE_UNQUOTED([SWITCH_CACHE_DIR],"${cachedir}",[where to put cache files])
 202
 203 AC_SUBST(confdir)
 204 AC_DEFINE_UNQUOTED([SWITCH_CONF_DIR],"${confdir}",[directory for configuration files])
 205
 206 AC_SUBST(datadir)
 207 AC_DEFINE_UNQUOTED([SWITCH_DATA_DIR],"${datadir}",[directory for data files])
 208
 209 AC_SUBST(localstatedir)
 210 AC_DEFINE_UNQUOTED([SWITCH_LOCALSTATE_DIR],"${localstatedir}",[directory for local state files])
 211 AC_SUBST(bindir)
 212 AC_SUBST(includedir)
 213
 214 AC_ARG_WITH([pkgconfigdir],
 215         [AS_HELP_STRING([--with-pkgconfigdir=DIR], [Installation directory for pkgconfig file (default: ${libdir}/pkgconfig)])],
 216         [case "${withval}" in
 217          yes|no) AC_MSG_ERROR([Invalid value ${withval} for option --with-pkgconfigdir]) ;;
 218          *) pkgconfigdir="${withval}" ;;
 219          esac
 220         ],
 221         [pkgconfigdir="${default_pkgconfigdir}"]
 222 )
 223 AC_SUBST([pkgconfigdir])
 224
 225 #Set default language
 226 AC_LANG_C
 227 # Checks for programs.
 228 AC_PROG_CC
 229 AC_PROG_CXX
 230
 231 #check if the g++ compiler works
 232 AC_CACHE_CHECK([whether the C++ compiler works], [ac_cv_sys_cxx_works], [
 233     AC_LANG_PUSH([C++])
 234     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int main() { }])], [ac_cv_sys_cxx_works=yes],
 235         [ac_cv_sys_cxx_works=no])
 236     AC_LANG_POP([C++])
 237     ])
 238 [ if [ "x$ac_cv_sys_cxx_works" = "xno" ]; then ]
 239     AC_MSG_FAILURE([The C++ compiler does not work. Please (re)install the C++ compiler])
 240 [ fi ]
 241
 242 AC_PROG_AWK
 243 AC_PROG_MAKE_SET
 244 AC_PROG_INSTALL
 245
 246 #override some default libtool behavior and invoke AC_PROG_LIBTOOL (see http://lists.gnu.org/archive/html/libtool/2007-03/msg00000.html)
 247 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
 248 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
 249 m4_defun([_LT_AC_LANG_RC_CONFIG], [:])
 250 AM_PROG_CC_C_O
 251 AC_PROG_LIBTOOL
 252
 253 #Check for compiler vendor
 254 AX_COMPILER_VENDOR
 255
 256 # Set CC_FOR_BUILD
 257 if test "x${cross_compiling}" = "xyes"; then
 258     CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 259     case "$host" in
 260          arm*-linux-gnueabi*|arm*-*-linux-gnueabi*)
 261                 # spandsp modem
 262                 ac_cv_file__dev_ptmx=yes
 263                 # libjs
 264                 export ac_cv_va_copy=yes
 265                 # srtp
 266                 export ac_cv_file__dev_urandom=yes
 267                 # rpl_malloc
 268                 export ac_cv_func_realloc_0_nonnull=yes
 269                 export ac_cv_func_malloc_0_nonnull=yes
 270                 # apr
 271                 export ac_cv_func_setpgrp_void=yes
 272                 export ac_cv_file__dev_zero=yes
 273                 export apr_cv_tcp_nodelay_with_cork=yes
 274                 export ac_cv_file_dbd_apr_dbd_mysql_c=no
 275                 export ac_cv_sizeof_ssize_t=4
 276                 export apr_cv_mutex_recursive=yes
 277                 export ac_cv_func_pthread_rwlock_init=yes
 278                 export apr_cv_type_rwlock_t=yes
 279                 export apr_cv_process_shared_works=yes
 280                 export apr_cv_mutex_robust_shared=yes
 281          ;;
 282     esac
 283 else
 284     CC_FOR_BUILD='$(CC)'
 285 fi
 286 AC_SUBST(CC_FOR_BUILD)
 287
 288 if test -n "$lt_sysroot" ; then
 289    APR_ADDTO(CFLAGS, --sysroot=$lt_sysroot)
 290    APR_ADDTO(CXXFLAGS, --sysroot=$lt_sysroot)
 291    APR_ADDTO(CPPFLAGS, --sysroot=$lt_sysroot)
 292    APR_ADDTO(LDFLAGS, --sysroot=$lt_sysroot)
 293    PKG_CONFIG_SYSROOT_DIR=$lt_sysroot
 294 fi
 295
 296 #  Optimize
 297 AC_ARG_ENABLE(optimization,
 298 [AC_HELP_STRING([--enable-optimization],[Set if you want us to add max optimising compiler flags])],[enable_optimizer="$enableval"],[enable_optimizer="no"])
 299
 300 if test "${enable_optimizer}" = "yes" ; then
 301         AC_DEFINE([OPTIMZER],[],[Enable Optimization.])
 302         AX_CC_MAXOPT
 303 fi
 304
 305 # set defaults for use on all platforms
 306 SWITCH_AM_CFLAGS="-I${switch_srcdir}/src/include -I${switch_builddir}/src/include -I${switch_srcdir}/libs/libteletone/src"
 307 SWITCH_AM_CXXFLAGS="-I${switch_srcdir}/src/include -I${switch_builddir}/src/include -I${switch_srcdir}/libs/libteletone/src"
 308 SWITCH_AM_CPPFLAGS="-I${switch_srcdir}/src/include -I${switch_builddir}/src/include -I${switch_srcdir}/libs/libteletone/src"
 309 SWITCH_AM_LDFLAGS="-lm"
 310
 311 #set SOLINK variable based on compiler and host
 312 if test "x${ax_cv_c_compiler_vendor}"  =  "xsun" ; then
 313     SOLINK="-Bdynamic -dy -G"
 314 elif test "x${ax_cv_c_compiler_vendor}" = "xclang" ; then
 315     case "$host" in
 316         *darwin*)
 317             SOLINK="-dynamic -force-flat-namespace"
 318         ;;
 319         *)
 320             SOLINK="-shared -Xlinker -x"
 321         ;;
 322
 323     esac
 324 elif test "x${ax_cv_c_compiler_vendor}" = "xgnu" ; then
 325     case "$host" in
 326 # older Xcode test for darwin, Xcode 4/5 use clang above
 327         *darwin*)
 328             SOLINK="-dynamic -bundle -force-flat-namespace"
 329         ;;
 330         *-solaris2*)
 331             SOLINK="-shared -Xlinker"
 332         ;;
 333         *)
 334             SOLINK="-shared -Xlinker -x"
 335         ;;
 336     esac
 337 elif test "x${ax_cv_c_compiler_vendor}" = "xintel" ; then
 338     case "$host" in
 339         *)
 340             SOLINK="-shared -Xlinker -x"
 341         ;;
 342     esac
 343 else
 344     AC_ERROR([Please update configure.in with SOLINK values for your compiler])
 345 fi
 346
 347 ##
 348 # detect libtool major version,
 349 # set libtool library extension based on this
 350 # to work around some brokeness when using 'la' with libtool-1.5
 351 #
 352 AC_MSG_CHECKING([libtool major version])
 353 libtool="${switch_builddir}/libtool"
 354 LIBTOOL_MAJOR_VERSION="`$libtool --version 2>/dev/null| sed -e 's/([[^)]]*)//g;s/^[[^0-9]]*//;s/[[- ]].*//g;q'| awk  'BEGIN { FS = "." } { print $1 }' `"
 355 if test -z "$LIBTOOL_MAJOR_VERSION" ; then
 356         LIBTOOL_MAJOR_VERSION="`sed -n -e '/^VERSION/{s/^.*=\"\{0,1\}\([[0-9]]\{1,\}\)\..*/\1/;p;}' ${switch_srcdir}/build/config/ltmain.sh`"
 357 fi
 358 if test -z "$LIBTOOL_MAJOR_VERSION" ; then
 359         AC_MSG_ERROR([Failed to detect your libtool version, please open a bug report on https://freeswitch.org/jira])
 360 fi
 361 AC_MSG_RESULT([${LIBTOOL_MAJOR_VERSION}])
 362
 363 LIBTOOL_LIB_EXTEN=so
 364
 365 if test "${LIBTOOL_MAJOR_VERSION}" = "2" ; then
 366    LIBTOOL_LIB_EXTEN="la"
 367 fi
 368 AC_MSG_RESULT([using libtool library extension... ${LIBTOOL_LIB_EXTEN}])
 369
 370 if test "$ax_cv_c_compiler_vendor" = "gnu"; then
 371   saved_CFLAGS="$CFLAGS"
 372   AC_CACHE_CHECK([whether compiler supports -Wno-unused-result],
 373     [ac_cv_gcc_supports_w_no_unused_result], [
 374       CFLAGS="$CFLAGS -Wno-unused-result -Wno-error=unused-result"
 375       AC_TRY_COMPILE([],[return 0;],
 376         [ac_cv_gcc_supports_w_no_unused_result=yes],
 377         [ac_cv_gcc_supports_w_no_unused_result=no])])
 378   CFLAGS="$saved_CFLAGS"
 379   AC_MSG_RESULT($ac_cv_gcc_supports_w_no_unused_result)
 380
 381   saved_CFLAGS="$CFLAGS"
 382   AC_CACHE_CHECK([whether compiler supports -Wno-misleading-indentation],
 383     [ac_cv_gcc_supports_w_no_misleading_indentation], [
 384       CFLAGS="$CFLAGS -Wno-misleading-indentation -Wno-error=misleading-indentation"
 385       AC_TRY_COMPILE([],[return 0;],
 386         [ac_cv_gcc_supports_w_no_misleading_indentation=yes],
 387         [ac_cv_gcc_supports_w_no_misleading_indentation=no])])
 388   CFLAGS="$saved_CFLAGS"
 389   AC_MSG_RESULT($ac_cv_gcc_supports_w_no_misleading_indentation)
 390 fi
 391
 392 # tweak compiler specific flags
 393 if test "x${ax_cv_c_compiler_vendor}"  =  "xsun" ; then
 394     APR_ADDTO(SWITCH_AM_CFLAGS, -KPIC)
 395     APR_ADDTO(SWITCH_AM_CFLAGS, -DPIC)
 396     APR_ADDTO(SWITCH_AM_CFLAGS, -erroff=E_END_OF_LOOP_CODE_NOT_REACHED)
 397     APR_ADDTO(SWITCH_AM_CFLAGS, -errtags=yes)
 398     APR_ADDTO(SWITCH_AM_CFLAGS, -D__FUNCTION__=__func__ )
 399     APR_ADDTO(SWITCH_AM_CFLAGS, -mt)
 400     APR_ADDTO(SWITCH_AM_CXXFLAGS, -errtags=yes)
 401     APR_ADDTO(SWITCH_AM_CXXFLAGS, -KPIC)
 402     APR_ADDTO(SWITCH_AM_CXXFLAGS, -DPIC)
 403     APR_ADDTO(SWITCH_AM_CXXFLAGS, "-features=extensions")
 404     APR_ADDTO(SWITCH_AM_CXXFLAGS, -D__FUNCTION__=__func__)
 405     APR_ADDTO(SWITCH_AM_CXXFLAGS, -mt)
 406
 407     APR_ADDTO(SWITCH_AM_LDFLAGS, -R${prefix}/lib)
 408     if test "${enable_64}" = "yes"; then
 409         APR_ADDTO(SWITCH_AM_CFLAGS, -m64)
 410         APR_ADDTO(SWITCH_AM_CXXFLAGS, -m64)
 411         APR_ADDTO(SWITCH_AM_LDFLAGS, -m64)
 412         LIBS="$LIBS -m64"
 413     fi
 414 elif test "x${ax_cv_c_compiler_vendor}" = "xclang" ; then
 415     APR_ADDTO(SWITCH_AM_CFLAGS, -fPIC -ffast-math)
 416     APR_ADDTO(SWITCH_AM_CXXFLAGS, -fPIC -ffast-math)
 417     APR_ADDTO(SWITCH_AM_CFLAGS, -Werror)
 418 elif test "x${ax_cv_c_compiler_vendor}" = "xgnu" ; then
 419     APR_ADDTO(SWITCH_AM_CFLAGS, -fPIC -ffast-math)
 420     APR_ADDTO(SWITCH_AM_CXXFLAGS, -fPIC -ffast-math)
 421     AC_SUBST([AM_MOD_AVMD_CXXFLAGS], [-std=gnu99])      # FS-8809, needed for MAP_POPULATE
 422     if test "$ac_cv_gcc_supports_w_no_unused_result" = yes; then
 423       APR_ADDTO(SWITCH_AM_CFLAGS, -Werror)
 424       APR_ADDTO(SWITCH_AM_CFLAGS, -Wno-unused-result)
 425     fi
 426     if test "$ac_cv_gcc_supports_w_no_misleading_indentation" = yes; then
 427       APR_ADDTO(SWITCH_AM_CFLAGS, -Wno-misleading-indentation)
 428     fi
 429     if test "${enable_64}" = "yes"; then
 430         case "$host" in
 431              *darwin*)
 432                 osxvrm=`sw_vers -productVersion`          # Get version.release.modlevel
 433                 osxrel=`echo $osxvrm | cut -d. -f2`       # Get release only
 434                 if test "$osxrel" -ge 4; then             # 10.4 and up are x64
 435                    APR_ADDTO(CFLAGS, -arch x86_64)
 436                    APR_ADDTO(LDFLAGS, -arch x86_64)
 437                    APR_ADDTO(CXXFLAGS, -arch x86_64)
 438                 fi
 439                 ;;
 440              *-solaris2*)
 441                 APR_ADDTO(CFLAGS, -m64)
 442                 APR_ADDTO(LDFLAGS, -m64)
 443                 APR_ADDTO(CXXFLAGS, -m64)
 444                 ;;
 445              *)
 446                 LIBS="$LIBS -m64"
 447              ;;
 448          esac
 449     fi
 450 fi
 451
 452 case "${ax_cv_c_compiler_vendor}" in
 453 sun)
 454         VISIBILITY_FLAG=-xldscope=hidden
 455 ;;
 456 *)
 457         VISIBILITY_FLAG=-fvisibility=hidden
 458 ;;
 459 esac
 460 AC_SUBST(VISIBILITY_FLAG)
 461
 462 #
 463 # gcc visibility cflag checks
 464 #
 465 AC_ARG_ENABLE([visibility],
 466         [AS_HELP_STRING([--disable-visibility], [Disable or enable API visibility support (default: use if available)])],
 467         [enable_visibility="${enableval}"],
 468         [enable_visibility="detect"]
 469 )
 470 HAVE_VISIBILITY="no"
 471
 472 if test "x${enable_visibility}" != "xno" ; then
 473
 474         case "${ax_cv_c_compiler_vendor}" in
 475         gnu)
 476                 save_CFLAGS="${CFLAGS}"
 477                 CFLAGS="${CFLAGS} -fvisibility=hidden"
 478                 AC_MSG_CHECKING([whether the compiler supports -fvisibility=hidden])
 479                 AC_COMPILE_IFELSE(
 480                         [AC_LANG_PROGRAM(
 481                                 [int foo __attribute__ ((visibility("default")));],
 482                                 [;]
 483                         )],
 484
 485                         [AC_MSG_RESULT([yes])
 486                          APR_ADDTO([SWITCH_AM_CFLAGS],   [-fvisibility=hidden -DSWITCH_API_VISIBILITY=1 -DCJSON_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 487                          APR_ADDTO([SWITCH_AM_CXXFLAGS], [-fvisibility=hidden -DSWITCH_API_VISIBILITY=1 -DCJSON_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 488                          HAVE_VISIBILITY="yes"],
 489
 490                         [AC_MSG_RESULT([no])]
 491                 )
 492                 CFLAGS="${save_CFLAGS}"
 493                 ;;
 494
 495         sun)
 496         #       save_CFLAGS="${CFLAGS}"
 497         #       CFLAGS="${CFLAGS} -xldscope=hidden"
 498         #       AC_MSG_CHECKING([whether the compiler supports -xldscope=hidden])
 499         #       AC_COMPILE_IFELSE(
 500         #               [AC_LANG_PROGRAM(
 501         #                       [int foo __attribute__ ((visibility("default")));],
 502         #                       [;]
 503         #               )],
 504         #
 505         #               [AC_MSG_RESULT([yes])
 506         #                APR_ADDTO([SWITCH_AM_CFLAGS],   [-xldscope=hidden -DSWITCH_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 507         #                APR_ADDTO([SWITCH_AM_CXXFLAGS], [-xldscope=hidden -DSWITCH_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 508         #                HAVE_VISIBILITY="yes"],
 509         #
 510         #               [AC_MSG_RESULT([no])]
 511         #       )
 512         #       CFLAGS="${save_CFLAGS}"
 513                 ;;
 514
 515         *)
 516                 if test "x${enable_visibility}" = "xyes" ; then
 517                         AC_MSG_ERROR([Non-GNU / SUN compilers are currently unsupported])
 518                 else
 519                         AC_MSG_WARN([Non-GNU / SUN compilers are currently unsupported])
 520                 fi
 521                 ;;
 522         esac
 523
 524         #
 525         # visibility explicitly requested but not supported by this compiler => error
 526         #
 527         if test "x${enable_visibility}" = "xyes" -a "x${HAVE_VISIBILITY}" = "xno" ; then
 528                 AC_MSG_ERROR([API visibility not supported by this compiler])
 529         fi
 530 fi
 531
 532 # Enable debugging (default: on)
 533 # (rename option if the default is changed)
 534 AC_ARG_ENABLE(debug,
 535 [AC_HELP_STRING([--disable-debug],[build without debug information])],[enable_debug="$enableval"],[enable_debug="yes"])
 536
 537 if test "${enable_debug}" = "yes"; then
 538         AC_DEFINE([DEBUG],[],[Enable extra debugging.])
 539         saved_CFLAGS="$CFLAGS"
 540         CFLAGS=
 541         AX_CFLAGS_WARN_ALL_ANSI
 542         SWITCH_ANSI_CFLAGS=$CFLAGS
 543         CFLAGS="$saved_CFLAGS"
 544
 545         if test "x${ax_cv_c_compiler_vendor}" = "xgnu" ; then
 546             if test "$ac_cv_gcc_supports_w_no_unused_result" = yes; then
 547               APR_ADDTO(SWITCH_AM_CFLAGS, -Wno-unused-result)
 548             fi
 549             APR_ADDTO(SWITCH_AM_CFLAGS, -g -ggdb)
 550             export DEBUG_CFLAGS="-g -ggdb"
 551         fi
 552
 553 fi
 554
 555 AC_ARG_ENABLE(libyuv,
 556 [AC_HELP_STRING([--disable-libyuv],[build without libyuv])],[enable_libyuv="$enableval"],[enable_libyuv="yes"])
 557
 558 AM_CONDITIONAL([ENABLE_LIBYUV],[test "${enable_libyuv}" = "yes"])
 559
 560 AC_ARG_ENABLE(libvpx,
 561 [AC_HELP_STRING([--disable-libvpx],[build without libvpx])],[enable_libvpx="$enableval"],[enable_libvpx="yes"])
 562
 563 AM_CONDITIONAL([ENABLE_LIBVPX],[test "${enable_libvpx}" = "yes"])
 564
 565 AC_ARG_ENABLE(cpp,
 566 [AC_HELP_STRING([--disable-cpp],[build without cpp code])],[enable_cpp="$enableval"],[enable_cpp="yes"])
 567
 568 AM_CONDITIONAL([ENABLE_CPP],[test "${enable_cpp}" = "yes"])
 569
 570 AM_CONDITIONAL([DISABLE_CC],[test "${disable_cc}" = "yes"])
 571
 572 AC_ARG_ENABLE([system-xmlrpc-c],
 573   [AS_HELP_STRING([--enable-system-xmlrpc-c],
 574     [use system lib for xmlrpc-c])],,
 575   [enable_xmlrpcc="no"])
 576
 577 if test "${enable_xmlrpcc}" = "yes" ; then
 578 SYS_XMLRPC_CFLAGS=`xmlrpc-c-config --cflags`
 579 SYS_XMLRPC_LDFLAGS=`xmlrpc-c-config --libs`
 580 fi
 581 AC_SUBST(SYS_XMLRPC_CFLAGS)
 582 AC_SUBST(SYS_XMLRPC_LDFLAGS)
 583 AM_CONDITIONAL([SYSTEM_XMLRPCC],[test "${enable_xmlrpcc}" = "yes"])
 584
 585 for luaversion in luajit lua5.2 lua-5.2 lua52 lua5.1 lua-5.1 lua; do
 586   PKG_CHECK_MODULES([LUA],[${luaversion}],[have_lua=yes],[have_lua=no])
 587   if test ${have_lua} = yes; then
 588     break
 589   fi
 590 done
 591 if test x"${LUA_LIBS}" = x"" ; then
 592    LUA_LIBS="-llua"
 593 fi
 594
 595 AC_ARG_ENABLE(srtp,
 596 [AC_HELP_STRING([--disable-srtp],[build without srtp support])],[enable_srtp="$enableval"],[enable_srtp="yes"])
 597
 598 AM_CONDITIONAL([ENABLE_SRTP],[test "${enable_srtp}" = "yes"])
 599
 600 have_openal=no
 601 AC_CHECK_LIB(openal, alMidiGainSOFT, [have_openal="yes"])
 602 AM_CONDITIONAL([HAVE_OPENAL],[test "${have_openal}" = "yes"])
 603
 604 AC_ARG_ENABLE(zrtp,
 605         [AS_HELP_STRING([--enable-zrtp], [Compile with zrtp Support])],,[enable_zrtp="no"])
 606 if test "x$enable_zrtp" = "xyes" ; then
 607    LIBS="-lpthread $LIBS"
 608    APR_ADDTO(SWITCH_AM_CFLAGS, -DENABLE_ZRTP)
 609 fi
 610
 611 PA_LIBS=
 612
 613 PKG_CHECK_MODULES(JACK, jack, have_jack=yes, have_jack=no)
 614 if test "x$have_jack" = "xyes" ; then
 615 PA_LIBS+=$JACK_LIBS
 616 fi
 617
 618 AC_CHECK_LIB(asound, snd_pcm_open, have_alsa=yes, have_alsa=no)
 619 if test "x$have_alsa" = "xyes"  ; then
 620 PA_LIBS+=-lasound
 621 fi
 622
 623 AC_SUBST(PA_LIBS)
 624
 625 AM_CONDITIONAL([ENABLE_ZRTP],[test "x$enable_zrtp" != "xno"])
 626
 627 AM_CONDITIONAL([WANT_DEBUG],[test "${enable_debug}" = "yes"])
 628
 629 AC_ARG_ENABLE(core-odbc-support,
 630   [AS_HELP_STRING([--enable-core-odbc-support], [Compile with ODBC Support (default is optional)])],,[enable_core_odbc_support="optional"])
 631 if ! test "$enable_core_odbc_support" = "no"; then
 632   AX_LIB_ODBC
 633   if test "$ac_cv_found_odbc" = "yes" ; then
 634     enable_core_odbc_support="yes"
 635   elif test "$enable_core_odbc_support" = "yes"; then
 636     AC_MSG_ERROR([no usable libodbc; please install unixodbc devel package or equivalent])
 637   else
 638     enable_core_odbc_support="no"
 639   fi
 640 fi
 641
 642 CHECK_LIBUUID
 643 SWITCH_AM_LDFLAGS="$LIBUUID_LIBS $SWITCH_AM_LDFLAGS"
 644 SWITCH_AM_CFLAGS="$LIBUUID_CFLAGS $SWITCH_AM_CFLAGS"
 645
 646 AC_ARG_ENABLE(core-pgsql-pkgconfig,
 647         [AS_HELP_STRING([--disable-core-pgsql-pkgconfig], [Use pg_config to get PGQSL build options])],[enable_core_pgsql_pkgconfig="$enableval"],[enable_core_pgsql_pkgconfig="yes"])
 648
 649 path_remove () {
 650   echo "$1" | tr ':' '\n' | grep -Fxv "$2" | tr '\n' ':' | sed 's/:$//'
 651 }
 652 path_push_unique () {
 653   x="$(eval echo \$$1)"
 654   x="$(path_remove "$x" "$2")"
 655   if test -z "$x"; then
 656     eval export $1="$2"
 657   else
 658     eval export $1="$2:$x"
 659   fi
 660 }
 661
 662 AC_PATH_PROG([PG_CONFIG], [pg_config], [no])
 663 AC_PATH_PROG([PKG_CONFIG], [pkg-config], [no])
 664
 665 case $host in
 666      *-darwin*)
 667         path_push_unique PKG_CONFIG_PATH /usr/local/opt/libpq/lib/pkgconfig
 668      ;;
 669 esac
 670
 671 if test "$PKG_CONFIG" = "no" \
 672         || test x"$enable_core_pgsql_pkgconfig" = x"no" \
 673         || ! pkg-config libpq; then
 674         if test "$PG_CONFIG" != "no"; then
 675                 AC_MSG_CHECKING([for PostgreSQL libraries via pg_config])
 676                 POSTGRESQL_CFLAGS="-I`$PG_CONFIG --includedir`"
 677                 POSTGRESQL_LIBDIR="-L`$PG_CONFIG --libdir`"
 678                 POSTGRESQL_LDFLAGS="-L`$PG_CONFIG --libdir` -lpq"
 679                 POSTGRESQL_VERSION=`$PG_CONFIG --version | awk '{ print $NF }'`
 680                 POSTGRESQL_MAJOR_VERSION=`$PG_CONFIG --version | awk '{ print $NF }' | awk -F. '{ print $1 }'`
 681                 POSTGRESQL_MINOR_VERSION=`$PG_CONFIG --version | awk '{ print $NF }' | awk -F. '{ print $2 }'`
 682                 POSTGRESQL_PATCH_VERSION=`$PG_CONFIG --version | awk '{ print $NF }' | awk -F. '{ print $3 }'`
 683         fi
 684 else
 685
 686         AC_MSG_CHECKING([for PostgreSQL libraries via pkg_config])
 687         POSTGRESQL_CFLAGS="`$PKG_CONFIG --cflags libpq`"
 688         POSTGRESQL_LIBDIR="`$PKG_CONFIG libpq --libs-only-L`"
 689         POSTGRESQL_LDFLAGS="`$PKG_CONFIG --libs libpq`"
 690         POSTGRESQL_VERSION="`$PKG_CONFIG --modversion libpq`"
 691         POSTGRESQL_MAJOR_VERSION="`echo $POSTGRESQL_VERSION | cut -d. -f1 | sed 's/^\([[0-9]]*\)[[^0-9]].*/\1/'`"
 692         POSTGRESQL_MINOR_VERSION="`echo $POSTGRESQL_VERSION | cut -d. -f2 | sed 's/^\([[0-9]]*\)[[^0-9]].*/\1/'`"
 693         POSTGRESQL_PATCH_VERSION="`echo $POSTGRESQL_VERSION | cut -d. -f3 | sed 's/^\([[0-9]]*\)[[^0-9]].*/\1/'`"
 694         test -n "$POSTGRESQL_PATCH_VERSION" || POSTGRESQL_PATCH_VERSION=0
 695 fi
 696 AC_MSG_RESULT([$POSTGRESQL_LIBDIR])
 697 AC_DEFINE_UNQUOTED([POSTGRESQL_VERSION], "${POSTGRESQL_VERSION}", [Specifies the version of PostgreSQL we are linking against])
 698 AC_DEFINE_UNQUOTED([POSTGRESQL_MAJOR_VERSION], ${POSTGRESQL_MAJOR_VERSION}, [Specifies the version of PostgreSQL we are linking against])
 699 AC_DEFINE_UNQUOTED([POSTGRESQL_MINOR_VERSION], ${POSTGRESQL_MINOR_VERSION}, [Specifies the version of PostgreSQL we are linking against])
 700 AC_DEFINE_UNQUOTED([POSTGRESQL_PATCH_VERSION], ${POSTGRESQL_PATCH_VERSION}, [Specifies the version of PostgreSQL we are linking against])
 701 have_libpq=no
 702 AC_CHECK_LIB([pq], [PQgetvalue], [have_libpq="yes"])
 703 AM_CONDITIONAL([HAVE_PGSQL],[test "${have_libpq}" = "yes"])
 704 AC_SUBST([POSTGRESQL_CFLAGS], [$POSTGRESQL_CFLAGS])
 705 AC_SUBST([POSTGRESQL_LDFLAGS], [$POSTGRESQL_LDFLAGS])
 706 AC_SUBST([POSTGRESQL_LIBDIR], [$POSTGRESQL_LIBDIR])
 707
 708
 709 PKG_CHECK_MODULES([MARIADB], [libmariadb >= 3.0.9],[
 710   AM_CONDITIONAL([HAVE_MARIADB],[true])],[
 711   PKG_CHECK_MODULES([MARIADB], [mariadb >= 3.0.9],[
 712     AM_CONDITIONAL([HAVE_MARIADB],[true])],[
 713     AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MARIADB],[false])
 714   ])
 715 ])
 716
 717 PKG_CHECK_MODULES([SPANDSP], [spandsp >= 1.99],[
 718   AM_CONDITIONAL([HAVE_SPANDSP],[true])],[
 719     AC_MSG_ERROR([no usable spandsp; please install spandsp devel package or equivalent])
 720 ])
 721
 722 PKG_CHECK_MODULES([SOFIA_SIP], [sofia-sip-ua >= 1.12.12],[
 723   AM_CONDITIONAL([HAVE_SOFIA_SIP],[true])],[
 724     AC_MSG_ERROR([no usable sofia-sip; please install sofia-sip-ua devel package or equivalent])
 725 ])
 726
 727 AC_ARG_ENABLE(deprecated-core-db-events,
 728         [AS_HELP_STRING([--enable-deprecated-core-db-events], [Keep deprecated core db events])],,[enable_deprecated_core_db_events="no"])
 729
 730 if test x"$enable_deprecated_core_db_events" = x"yes" ; then
 731         AC_DEFINE([SWITCH_DEPRECATED_CORE_DB], [1], [Define to 1 to enable deprecated core db events])
 732 fi
 733
 734 ESL_LDFLAGS=
 735 PLATFORM_CORE_LDFLAGS=
 736 PLATFORM_CORE_LIBS=
 737
 738 # tweak platform specific flags
 739 case "$host" in
 740     *darwin*)
 741         # Common Apple Darwin settings
 742         APR_ADDTO(SWITCH_AM_CFLAGS, -DMACOSX)
 743         APR_REMOVEFROM(SWITCH_AM_CFLAGS, -fPIC)
 744         APR_ADDTO(CPPFLAGS, -I/usr/local/opt/openssl/include)
 745         APR_ADDTO(LDFLAGS, -L/usr/local/opt/openssl/lib)
 746         if test "x$enable_core_odbc_support" != "xno"; then
 747            APR_ADDTO([PLATFORM_CORE_LDFLAGS], [--framework CoreFoundation])
 748         fi
 749         APR_ADDTO([PLATFORM_CORE_LIBS], [-ldl])
 750     # Get OSX and clang version
 751         osxvrm=`sw_vers -productVersion`          # Get version.release.modlevel
 752         osxrel=`echo $osxvrm | cut -d. -f2`       # Get release only
 753         clangvers="`clang -v 2>&1  >/dev/null | grep version | sed -e 's/.*version \([[0-9]]*\).*$/\1/'`"
 754         if test "$clangvers" -ge 6; then          # Xcode 6 drops std lib search, add it to clang
 755            APR_ADDTO(LDFLAGS, -L/usr/local/lib)
 756            APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 757         fi
 758         if test "$clangvers" -ge 4; then          # Xcode 4 / 10.7 and up
 759            APR_ADDTO(CFLAGS, -Wno-deprecated-declarations)
 760         fi
 761         if test "$osxrel" -ge 6; then             # 10.6 and up
 762            APR_ADDTO(CFLAGS, -pipe -no-cpp-precomp)
 763            APR_ADDTO(LDFLAGS, -pipe -bind_at_load)
 764            APR_ADDTO(CXXFLAGS, -pipe)
 765         fi
 766     ;;
 767     *-solaris2*)
 768         if test "${enable_64}" = "yes"; then
 769            APR_ADDTO(CPPFLAGS, [-I/opt/64/include])
 770            APR_ADDTO(LDFLAGS, [-L/opt/64/lib -Wl,-rpath,/opt/64/lib])
 771            APR_ADDTO(SWITCH_AM_CFLAGS, [-I/opt/64/include])
 772            APR_ADDTO(SWITCH_AM_LDFLAGS, [-L/opt/64/lib -Wl,-rpath,/opt/64/lib])
 773         else
 774            APR_ADDTO(CPPFLAGS, [-I/opt/include])
 775            APR_ADDTO(LDFLAGS, [-L/opt/lib -Wl,-rpath,/opt/lib])
 776            APR_ADDTO(SWITCH_AM_CFLAGS, [-I/opt/include])
 777            APR_ADDTO(SWITCH_AM_LDFLAGS, [-L/opt/lib -Wl,-rpath,/opt/lib])
 778         fi
 779         APR_ADDTO(SWITCH_AM_CFLAGS, -DPATH_MAX=2048 -D__EXTENSIONS__)
 780         APR_ADDTO(SWITCH_AM_LDFLAGS, -lsendfile -lresolv -lsocket -lnsl -luuid)
 781         APR_ADDTO(ESL_LDFLAGS, -lnsl -lsocket)
 782         APR_ADDTO([PLATFORM_CORE_LIBS], [-ldl -lcrypt -lrt -lsendfile -lresolv -lsocket -lnsl -luuid])
 783     ;;
 784     *dragonfly*)
 785         APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 786         APR_ADDTO(LDFLAGS, -L/usr/local/lib)
 787         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/local/include)
 788     ;;
 789     *openbsd*)
 790         APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 791         APR_ADDTO(LDFLAGS, -L/usr/local/lib -ltermcap)
 792         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/local/include)
 793     ;;
 794     *netbsd*)
 795         APR_ADDTO(CPPFLAGS, -I/usr/pkg/include)
 796         APR_ADDTO(LDFLAGS, [-L/usr/pkg/lib -Wl,-rpath,/usr/pkg/lib])
 797         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/pkg/include)
 798     ;;
 799     *bsd*)
 800         APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 801         APR_ADDTO(LDFLAGS, -L/usr/local/lib)
 802         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/local/include)
 803         APR_ADDTO([PLATFORM_CORE_LIBS], [-lcrypt -lrt])
 804     ;;
 805     *linux*)
 806         APR_ADDTO([PLATFORM_CORE_LIBS], [-ldl -lcrypt -lrt])
 807     ;;
 808 esac
 809
 810 APR_REMOVEFROM(SWITCH_AM_CXXFLAGS, -std=c99)
 811
 812 # check for usable system MD5 library
 813 AS_CASE([$host],
 814   [*-solaris2*], [AC_CHECK_LIB(md5, MD5Init)],
 815   [*-freebsd*], [AC_CHECK_LIB(md, MD5Init)],
 816   [*-openbsd*|*-netbsd*], [AC_CHECK_FUNCS([MD5Init])])
 817
 818 AC_CHECK_LIB(z, inflateReset, have_libz=yes, AC_MSG_ERROR([no usable zlib; please install zlib devel package or equivalent]))
 819 if test "x$have_libz" = "xyes"  ; then
 820 APR_ADDTO([PLATFORM_CORE_LIBS], [-lz])
 821 fi
 822
 823 PKG_CHECK_MODULES([MPG123], [libmpg123 >= 1.16.0],[
 824   AM_CONDITIONAL([HAVE_MPG123],[true])],[
 825   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MPG123],[false])])
 826
 827 PKG_CHECK_MODULES([AMR], [opencore-amrnb >= 0.1.0],[
 828                 AM_CONDITIONAL([HAVE_AMR],[true])],[
 829                 AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AMR],[false])])
 830
 831 PKG_CHECK_MODULES([AMRWB], [opencore-amrwb >= 0.1.0 vo-amrwbenc >= 0.1.0],[
 832                 AM_CONDITIONAL([HAVE_AMRWB],[true])],[
 833                 AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AMRWB],[false])])
 834
 835 AC_CHECK_LIB(apr-1, apr_pool_mutex_set, use_system_apr=yes, use_system_apr=no)
 836 AM_CONDITIONAL([SYSTEM_APR],[test "${use_system_apr}" = "yes"])
 837 AC_CHECK_LIB(aprutil-1, apr_queue_pop_timeout, use_system_aprutil=yes, use_system_aprutil=no)
 838 AM_CONDITIONAL([SYSTEM_APRUTIL],[test "${use_system_aprutil}" = "yes"])
 839
 840 save_LIBS="$LIBS"
 841 LIBS=
 842 AC_CHECK_LIB(jpeg, jpeg_std_error,, AC_MSG_ERROR([no usable libjpeg; please install libjpeg devel package or equivalent]))
 843
 844 AC_CHECK_LIB(jbig, jbg_enc_out, have_libjbig=yes, have_libjbig=no)
 845 if test "x$have_libjbig" = "xyes"  ; then
 846 SPANDSP_LA_JBIG="-ljbig $LIBS"
 847 AC_SUBST(SPANDSP_LA_JBIG)
 848 fi
 849 LIBS="$save_LIBS"
 850
 851 AC_CHECK_LIB(lzma, lzma_code, have_liblzma=yes, have_liblzma=no)
 852 if test "x$have_liblzma" = "xyes" ; then
 853 SPANDSP_LA_LZMA="-llzma"
 854 AC_SUBST(SPANDSP_LA_LZMA)
 855 fi
 856
 857 AC_CHECK_LIB(resolv, res_init, have_libresolv=yes, have_libresolv=no)
 858 if test "x$have_libresolv" = "xyes"  ; then
 859 APR_ADDTO(SWITCH_AM_LDFLAGS, -lresolv)
 860 fi
 861
 862 AC_SUBST(SWITCH_AM_CFLAGS)
 863 AC_SUBST(SWITCH_ANSI_CFLAGS)
 864 AC_SUBST(SWITCH_AM_CXXFLAGS)
 865 AC_SUBST(SWITCH_AM_CPPFLAGS)
 866 AC_SUBST(SWITCH_AM_LDFLAGS)
 867 AC_SUBST(ESL_LDFLAGS)
 868 AC_SUBST(PLATFORM_CORE_LDFLAGS)
 869 AC_SUBST(PLATFORM_CORE_LIBS)
 870 AC_SUBST(SOLINK)
 871 AC_SUBST(LIBTOOL_LIB_EXTEN)
 872
 873 # Checks for header files.
 874 AC_HEADER_DIRENT
 875 AC_HEADER_STDC
 876 AC_CHECK_HEADERS([sys/types.h sys/resource.h sched.h wchar.h sys/filio.h sys/ioctl.h sys/prctl.h sys/select.h netdb.h execinfo.h sys/time.h])
 877
 878 # Solaris 11 privilege management
 879 AS_CASE([$host],
 880   [*-*-solaris2.11], [AC_CHECK_HEADER([priv.h], [AC_DEFINE([SOLARIS_PRIVILEGES],[1],[Solaris 11 privilege management])])]
 881 )
 882
 883
 884 if test x"$ac_cv_header_wchar_h" = xyes; then
 885   HAVE_WCHAR_H_DEFINE=1
 886 else
 887   HAVE_WCHAR_H_DEFINE=0
 888 fi
 889 AC_SUBST(HAVE_WCHAR_H_DEFINE)
 890
 891 # Needed by Abyss on Solaris:
 892
 893 if test x"$ac_cv_header_sys_filio_h" = xyes; then
 894   HAVE_SYS_FILIO_H_DEFINE=1
 895 else
 896   HAVE_SYS_FILIO_H_DEFINE=0
 897 fi
 898 AC_SUBST(HAVE_SYS_FILIO_H_DEFINE)
 899
 900 # Needed by Abyss on Solaris:
 901
 902 if test x"$ac_cv_header_sys_ioctl_h" = xyes; then
 903   HAVE_SYS_IOCTL_H_DEFINE=1
 904 else
 905   HAVE_SYS_IOCTL_H_DEFINE=0
 906 fi
 907 AC_SUBST(HAVE_SYS_IOCTL_H_DEFINE)
 908
 909 if test x"$ac_cv_header_sys_select_h" = xyes; then
 910   HAVE_SYS_SELECT_H_DEFINE=1
 911 else
 912   HAVE_SYS_SELECT_H_DEFINE=0
 913 fi
 914 AC_SUBST(HAVE_SYS_SELECT_H_DEFINE)
 915
 916 # Checks for typedefs, structures, and compiler characteristics.
 917 AC_C_CONST
 918 AC_C_INLINE
 919 AC_TYPE_SIZE_T
 920 AC_HEADER_TIME
 921 AC_STRUCT_TM
 922
 923 # Checks for library functions.
 924 AC_PROG_GCC_TRADITIONAL
 925 AC_FUNC_MALLOC
 926 AC_TYPE_SIGNAL
 927 AC_FUNC_STRFTIME
 928 AC_CHECK_FUNCS([gethostname vasprintf mmap mlock mlockall usleep getifaddrs timerfd_create getdtablesize posix_openpt poll])
 929 AC_CHECK_FUNCS([sched_setscheduler setpriority setrlimit setgroups initgroups getrusage])
 930 AC_CHECK_FUNCS([wcsncmp setgroups asprintf setenv pselect gettimeofday localtime_r gmtime_r strcasecmp stricmp _stricmp])
 931
 932 # Check availability and return type of strerror_r
 933 # (NOTE: apr-1-config sets -D_GNU_SOURCE at build-time, need to run the check with it too)
 934 save_CPPFLAGS="$CPPFLAGS"
 935 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 936 AC_FUNC_STRERROR_R
 937 CPPFLAGS="$save_CPPFLAGS"
 938
 939 AX_HAVE_CPU_SET
 940
 941 AC_CHECK_LIB(rt, clock_gettime, [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])])
 942 AC_CHECK_LIB(rt, clock_getres, [AC_DEFINE(HAVE_CLOCK_GETRES, 1, [Define if you have clock_getres()])])
 943 AC_CHECK_LIB(rt, clock_nanosleep, [AC_DEFINE(HAVE_CLOCK_NANOSLEEP, 1, [Define if you have clock_nanosleep()])])
 944 AC_CHECK_LIB(pthread, pthread_setschedparam, [AC_DEFINE(HAVE_PTHREAD_SETSCHEDPARAM, 1, [Define if you have pthread_setschedparam()])])
 945
 946 AC_CHECK_FUNC(socket, , AC_CHECK_LIB(socket, socket))
 947
 948 AC_CHECK_FILE(/dev/ptmx, [AC_DEFINE(HAVE_DEV_PTMX, 1, [Define if you have /dev/ptmx])])
 949 AC_CHECK_LIB(util, openpty, [AC_DEFINE(HAVE_OPENPTY, 1, [Define if you have openpty()])])
 950
 951 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[
 952 #include <sys/types.h>
 953 #include <time.h>])
 954
 955 AC_CHECK_MEMBERS([struct tm.tm_zone],,,[
 956 #include <sys/types.h>
 957 #include <time.h>])
 958
 959 AC_CHECK_DECL([RLIMIT_MEMLOCK],
 960         [AC_DEFINE([HAVE_RLIMIT_MEMLOCK],[1],[RLIMIT_MEMLOCK constant for setrlimit])],,
 961         [#ifdef HAVE_SYS_RESOURCE_H
 962          #include <sys/resource.h>
 963          #endif])
 964
 965 AC_CHECK_DECL([SCHED_RR],
 966         [AC_DEFINE([HAVE_SCHED_RR],[1],[SCHED_RR constant for sched_setscheduler])],,
 967         [#ifdef HAVE_SCHED_H
 968          #include <sched.h>
 969          #endif])
 970
 971 AC_CHECK_DECL([SCHED_FIFO],
 972         [AC_DEFINE([HAVE_SCHED_FIFO],[1],[SCHED_FIFO constant for sched_setscheduler])],,
 973         [#ifdef HAVE_SCHED_H
 974          #include <sched.h>
 975          #endif])
 976
 977 #
 978 # use mlockall only on linux (for now; if available)
 979 #
 980 if test "x${ac_cv_func_mlockall}" = "xyes"; then
 981         AC_MSG_CHECKING([whether to use mlockall])
 982         case "$host" in
 983         *-linux-*)
 984                 AC_DEFINE([USE_MLOCKALL],[1],[Enable mlockall support])
 985                 AC_MSG_RESULT([yes])
 986                 USE_MLOCKALL=yes
 987                 ;;
 988         *-freebsd*)
 989                 APR_ADDTO(SWITCH_AM_CFLAGS, -fPIC)
 990                 APR_ADDTO(SWITCH_AM_CXXFLAGS, -fPIC)
 991                 AC_MSG_RESULT([no, broken for non-root users])
 992                 ;;
 993         *)
 994                 AC_MSG_RESULT([no])
 995                 ;;
 996         esac
 997
 998         #
 999         # setrlimit prerequisites
1000         #
1001         if test "x${USE_MLOCKALL}" = "xyes" -a \
1002                 "x${ac_cv_func_setrlimit}" = "xyes" -a \
1003                 "x${ac_cv_have_decl_RLIMIT_MEMLOCK}" = "xyes"
1004         then
1005                 AC_DEFINE([USE_SETRLIMIT],[1],[Use setrlimit to disable mlock limit for non-root users])
1006         fi
1007 fi
1008
1009 #
1010 # sched_setcheduler + round-robin scheduler prerequisites
1011 #
1012 if test "x${ac_cv_func_sched_setscheduler}" = "xyes" -a \
1013         "x${ac_cv_have_decl_SCHED_RR}" = "xyes"
1014 then
1015         AC_DEFINE([USE_SCHED_SETSCHEDULER],[1],[Enable round-robin scheduler using sched_setscheduler])
1016 fi
1017 #
1018 # xmlrpc-c checks
1019 #
1020
1021 AC_CHECK_FUNCS(setenv strtoll strtoull strtoq strtouq __strtoll __strtoull)
1022
1023 HAVE_LIBWWW_SSL_DEFINE=0
1024 AC_SUBST(HAVE_LIBWWW_SSL_DEFINE)
1025
1026 DIRECTORY_SEPARATOR="/"
1027 AC_SUBST(DIRECTORY_SEPARATOR)
1028
1029 va_list_is_array=no
1030 AC_MSG_CHECKING(whether va_list is an array)
1031 AC_TRY_COMPILE([
1032 #include <stdarg.h>
1033 ], [va_list list1, list2; list1 = list2;], ,
1034 va_list_is_array=yes)
1035 AC_MSG_RESULT($va_list_is_array)
1036 if test x"$va_list_is_array" = xyes; then
1037   VA_LIST_IS_ARRAY_DEFINE=1
1038 else
1039   VA_LIST_IS_ARRAY_DEFINE=0
1040 fi
1041 AC_SUBST(VA_LIST_IS_ARRAY_DEFINE)
1042
1043
1044 AC_MSG_CHECKING(whether compiler has __attribute__)
1045 AC_TRY_COMPILE(, [int x __attribute__((__unused__));],
1046 compiler_has_attribute=yes,
1047 compiler_has_attribute=no)
1048 AC_MSG_RESULT($compiler_has_attribute)
1049 if test x"$compiler_has_attribute" = xyes; then
1050     ATTR_UNUSED="__attribute__((__unused__))"
1051 else
1052     ATTR_UNUSED=
1053 fi
1054 AC_SUBST(ATTR_UNUSED)
1055
1056
1057 saved_CFLAGS="$CFLAGS"
1058 AC_CACHE_CHECK([whether compiler supports -Wdeclaration-after-statement], [ac_cv_gcc_declaration_after_statement], [
1059 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1060 AC_TRY_COMPILE([],[return 0;],[ac_cv_gcc_declaration_after_statement=yes],[ac_cv_gcc_declaration_after_statement=no])
1061 ])
1062 AC_MSG_RESULT($ac_cv_gcc_declaration_after_statement)
1063 if test x"$ac_cv_gcc_declaration_after_statement" = xyes; then
1064     APR_ADDTO(SWITCH_ANSI_CFLAGS, -Wdeclaration-after-statement)
1065 fi
1066 CFLAGS="$saved_CFLAGS"
1067
1068 if test "x${ax_cv_c_compiler_vendor}" = "xclang" ; then
1069      saved_CFLAGS="$CFLAGS"
1070      # Next check added for Xcode 5 and systems with clang 5 llvm 3.3 or above, extended offset must be off
1071      AC_CACHE_CHECK([whether compiler supports -Wextended-offsetof], [ac_cv_clang_extended_offsetof], [
1072        CFLAGS="$CFLAGS -Wno-extended-offsetof"
1073        AC_TRY_COMPILE([],[return 0;],[ac_cv_clang_extended_offsetof=yes],[ac_cv_clang_extended_offsetof=no])
1074      ])
1075      AC_MSG_RESULT($ac_cv_clang_extended_offsetof)
1076      if test x"$ac_cv_clang_extended_offsetof" = xyes; then
1077          APR_ADDTO(CFLAGS, -Wno-extended-offsetof)
1078      fi
1079      CFLAGS="$saved_CFLAGS"
1080 fi
1081
1082 # Tested and fixed lot of modules, but some are untested.  Will be added back when the core team decide it ready
1083 # Untested modules : mod_osp mod_soundtouch mod_sangoma_codec mod_dingaling mod_opal mod_h323 mod_khomp
1084 #                    mod_unimrcp mod_cepstral mod_erlang_event mod_snmp mod_perl mod_java mod_managed
1085 #
1086 #saved_CFLAGS="$CFLAGS"
1087 #AC_CACHE_CHECK([whether compiler supports -Wunused-but-set-variable], [ac_cv_gcc_unused_but_set_variable], [
1088 #CFLAGS="$CFLAGS -Wunused-but-set-variable"
1089 #AC_TRY_COMPILE([],[return 0;],[ac_cv_gcc_unused_but_set_variable=yes],[ac_cv_gcc_unused_but_set_variable=no])
1090 #])
1091 #AC_MSG_RESULT($ac_cv_gcc_unused_but_set_variable)
1092 #if test x"$ac_cv_gcc_unused_but_set_variable" = xyes; then
1093 #    APR_ADDTO(SWITCH_ANSI_CFLAGS, -Wunused-but-set-variable)
1094 #fi
1095 #CFLAGS="$saved_CFLAGS"
1096
1097 AC_C_BIGENDIAN(AC_DEFINE([SWITCH_BYTE_ORDER],__BIG_ENDIAN,[Big Endian]),AC_DEFINE([SWITCH_BYTE_ORDER],__LITTLE_ENDIAN,[Little Endian]))
1098
1099 # Checks for integer size
1100 AC_CHECK_SIZEOF(char, 1)
1101 AC_CHECK_SIZEOF(int, 4)
1102 AC_CHECK_SIZEOF(long, 4)
1103 AC_CHECK_SIZEOF(short, 2)
1104 AC_CHECK_SIZEOF(long long, 8)
1105 AC_TYPE_SIZE_T
1106 AC_CHECK_TYPE(ssize_t, int)
1107
1108 # Checks for pointer size
1109 AC_CHECK_SIZEOF(void*, 4)
1110
1111 if test "x$ac_cv_sizeof_voidp" != "x"; then
1112     voidp_size=$ac_cv_sizeof_voidp
1113 else
1114     AC_ERROR([Cannot determine size of void*])
1115 fi
1116
1117 if test "$ac_cv_sizeof_short" = "2"; then
1118     short_value=short
1119 fi
1120 if test "$ac_cv_sizeof_int" = "4"; then
1121     int_value=int
1122 fi
1123
1124 if test "$ac_cv_sizeof_int" = "8"; then
1125     int64_t_fmt='#define SWITCH_INT64_T_FMT "d"'
1126     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "u"'
1127     int64_value="int"
1128     long_value=int
1129 elif test "$ac_cv_sizeof_long" = "8"; then
1130     int64_t_fmt='#define SWITCH_INT64_T_FMT "ld"'
1131     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "lu"'
1132     int64_value="long"
1133     long_value=long
1134     case "$host" in
1135         *pc-solaris2*)
1136         ;;
1137         sparc-*-solaris2*)
1138         ;;
1139         *-solaris2*|*apple-darwin*|*-openbsd*)
1140             if test "$ac_cv_sizeof_long_long" = "8"; then
1141                 int64_t_fmt='#define SWITCH_INT64_T_FMT "lld"'
1142                 uint64_t_fmt='#define SWITCH_UINT64_T_FMT "llu"'
1143                 int64_value="long long"
1144                 long_value="long long"
1145             fi
1146         ;;
1147     esac
1148 elif test "$ac_cv_sizeof_long_long" = "8"; then
1149     int64_t_fmt='#define SWITCH_INT64_T_FMT "lld"'
1150     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "llu"'
1151     int64_value="long long"
1152     long_value="long long"
1153 elif test "$ac_cv_sizeof_longlong" = "8"; then
1154     int64_t_fmt='#define SWITCH_INT64_T_FMT "qd"'
1155     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "qu"'
1156     int64_value="__int64"
1157     long_value="__int64"
1158 else
1159     AC_ERROR([could not detect a 64-bit integer type])
1160 fi
1161
1162 if test "$ac_cv_type_size_t" = "yes"; then
1163     size_t_value="size_t"
1164 else
1165     size_t_value="switch_int32_t"
1166 fi
1167
1168 if test "$ac_cv_type_ssize_t" = "yes"; then
1169     ssize_t_value="ssize_t"
1170 else
1171     ssize_t_value="switch_int32_t"
1172 fi
1173
1174 APR_CHECK_SIZEOF_EXTENDED([#include <sys/types.h>], ssize_t, 8)
1175
1176 if test "$ac_cv_sizeof_ssize_t" = "$ac_cv_sizeof_int"; then
1177     ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "d"'
1178 elif test "$ac_cv_sizeof_ssize_t" = "$ac_cv_sizeof_long"; then
1179     ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1180 else
1181     ssize_t_fmt='#error Can not determine the proper size for ssize_t'
1182 fi
1183
1184 APR_CHECK_SIZEOF_EXTENDED([#include <stddef.h>], size_t, 8)
1185
1186 if test "$ac_cv_sizeof_size_t" = "$ac_cv_sizeof_int"; then
1187     size_t_fmt='#define SWITCH_SIZE_T_FMT "d"'
1188 elif test "$ac_cv_sizeof_size_t" = "$ac_cv_sizeof_long"; then
1189     size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1190 else
1191     size_t_fmt='#define SWITCH_SIZE_T_FMT "zu"'
1192 fi
1193
1194 # Basically, we have tried to figure out the correct format strings
1195 # for SWITCH types which vary between platforms, but we don't always get
1196 # it right.  If you find that we don't get it right for your platform,
1197 # you can override our decision below.
1198 # NOTE: borrowed much of this logic from apr.
1199 case $host in
1200    s390*linux*)
1201        # uniquely, the 31-bit Linux/s390 uses "unsigned long int"
1202        # for size_t rather than "unsigned int":
1203        size_t_fmt='#define SWITCH_SIZE_T_FMT "lu"'
1204        ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1205        ;;
1206    *-os2*)
1207        size_t_fmt='#define SWITCH_SIZE_T_FMT "lu"'
1208        ;;
1209    *-openbsd*)
1210        size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1211        ;;
1212    *aix4*|*aix5*)
1213        ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1214        size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1215        ;;
1216     *beos*)
1217         ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1218         size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1219         ;;
1220     *apple-darwin*)
1221          ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1222          size_t_fmt='#define SWITCH_SIZE_T_FMT "lu"'
1223         ;;
1224 esac
1225
1226 AC_SUBST(voidp_size)
1227 AC_SUBST(short_value)
1228 AC_SUBST(int_value)
1229 AC_SUBST(long_value)
1230 AC_SUBST(int64_value)
1231 AC_SUBST(size_t_value)
1232 AC_SUBST(ssize_t_value)
1233 AC_SUBST(int64_t_fmt)
1234 AC_SUBST(uint64_t_fmt)
1235 AC_SUBST(ssize_t_fmt)
1236 AC_SUBST(size_t_fmt)
1237
1238 case $host in
1239    *-openbsd*)
1240        # OpenBSD's gunzip and friends don't like -d because its redundant, only gzip does
1241        AC_PATH_PROGS(ZCAT, gzip)
1242        ;;
1243     *)
1244        AC_PATH_PROGS(ZCAT, gunzip gzcat gzip zcat)
1245        ;;
1246 esac
1247
1248 AC_PATH_PROGS(BZIP, bzip2)
1249 AC_PATH_PROGS(XZ, xz)
1250 AC_PATH_PROGS(TAR, gtar tar)
1251 AC_PATH_PROGS(WGET, wget)
1252 AC_PATH_PROGS(CURL, curl)
1253 GETLIB="cd $switch_srcdir/libs && ${SHELL} $switch_builddir/build/getlib.sh"
1254 AC_SUBST(GETLIB)
1255 GETG729="cd $switch_srcdir/libs && ${SHELL} $switch_builddir/build/getg729.sh"
1256 AC_SUBST(GETG729)
1257 GETSOUNDS="${SHELL} $switch_builddir/build/getsounds.sh"
1258 AC_SUBST(GETSOUNDS)
1259
1260 case $host in
1261    *-darwin*)
1262         path_push_unique PKG_CONFIG_PATH /usr/local/opt/curl/lib/pkgconfig
1263         path_push_unique PKG_CONFIG_PATH /usr/local/opt/sqlite/lib/pkgconfig/
1264         path_push_unique PKG_CONFIG_PATH /usr/local/opt/ldns/lib/pkgconfig/
1265         path_push_unique PKG_CONFIG_PATH /usr/local/opt/portaudio/lib/pkgconfig/
1266         path_push_unique PKG_CONFIG_PATH /usr/local/opt/ffmpeg/lib/pkgconfig/
1267        ;;
1268 esac
1269
1270 if ! (test -x "$PKG_CONFIG" || test -x "$(which pkg-config)"); then
1271   AC_MSG_ERROR([You need to install pkg-config to configure FreeSWITCH.])
1272 fi
1273
1274 # temporary workaround for Debian libldns-dev package bug
1275 if test "$cross_compiling" != "yes" && test -f /usr/lib/pkg-config/libldns.pc; then
1276   path_push_unique PKG_CONFIG_PATH /usr/lib/pkg-config
1277 fi
1278
1279 module_enabled() {
1280   grep -v -e "\#" -e "^\$" modules.conf | sed 's/|.*//' | sed -e "s|^.*/||" | grep "^${1}\$" >/dev/null
1281 }
1282
1283 AC_ARG_WITH(png,
1284   [AS_HELP_STRING([--without-png],
1285     [disable support for libpng])],
1286   [with_png="$withval"],
1287   [with_png="yes"])
1288 if test "$with_png" = "yes"; then
1289   PKG_CHECK_MODULES([LIBPNG], [libpng >= 1.6.16],[
1290     AM_CONDITIONAL([HAVE_PNG],[true])],[
1291       PKG_CHECK_MODULES([LIBPNG], [libpng16 >= 1.6.16],[
1292         AM_CONDITIONAL([HAVE_PNG],[true])],[
1293           PKG_CHECK_MODULES([LIBPNG], [libpng >= 1.2.49],[
1294             AM_CONDITIONAL([HAVE_PNG],[true])],[
1295             AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_PNG],[false])])])])
1296 else
1297   AM_CONDITIONAL([HAVE_PNG],[false])
1298 fi
1299
1300 AC_ARG_WITH(freetype,
1301   [AS_HELP_STRING([--without-freetype],
1302     [disable support for freetype])],
1303   [with_freetype="$withval"],
1304   [with_freetype="yes"])
1305 if test "$with_freetype" = "yes"; then
1306   PKG_CHECK_MODULES([FREETYPE], [freetype2 >= 2.4.9],[
1307     AM_CONDITIONAL([HAVE_FREETYPE],[true])],[
1308     AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_FREETYPE],[false])])
1309 else
1310   AM_CONDITIONAL([HAVE_FREETYPE],[false])
1311 fi
1312
1313 PKG_CHECK_MODULES([GUMBO], [gumbo >= 0.10.1],[
1314   AM_CONDITIONAL([HAVE_GUMBO],[true])],[
1315   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_GUMBO],[false])])
1316
1317 PKG_CHECK_MODULES([FVAD], [libfvad >= 1.0],[
1318   AM_CONDITIONAL([HAVE_FVAD],[true])],[
1319   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_FVAD],[false])])
1320
1321 PKG_CHECK_MODULES([TPL], [libtpl >= 1.5],[
1322   AC_DEFINE([HAVE_LIBTPL],[1],[Define to 1 if you have libtpl])],[
1323   AC_MSG_RESULT([no])])
1324
1325 PKG_CHECK_MODULES([SQLITE], [sqlite3 >= 3.6.20])
1326 PKG_CHECK_MODULES([CURL], [libcurl >= 7.19])
1327 PKG_CHECK_MODULES([PCRE], [libpcre >= 7.8])
1328 PKG_CHECK_MODULES([SPEEX], [speex >= 1.2rc1 speexdsp >= 1.2rc1])
1329 PKG_CHECK_MODULES([YAML], [yaml-0.1 >= 0.1.4],[
1330   AM_CONDITIONAL([HAVE_YAML],[true])],[
1331   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_YAML],[false])])
1332 PKG_CHECK_MODULES([PORTAUDIO], [portaudio-2.0 >= 19],[
1333   AM_CONDITIONAL([HAVE_PORTAUDIO],[true])],[
1334   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_PORTAUDIO],[false])])
1335 PKG_CHECK_MODULES([LDNS], [libldns-fs >= 1.6.6],[
1336   AM_CONDITIONAL([HAVE_LDNS],[true])],[
1337 PKG_CHECK_MODULES([LDNS], [libldns >= 1.6.6],[
1338   AM_CONDITIONAL([HAVE_LDNS],[true])],[
1339   AC_CHECK_LIB([ldns], [ldns_str2rdf_a], [LDNS_LIBS=-lldns])
1340   AS_IF([test -z "$LDNS_LIBS"],[
1341     if module_enabled mod_enum; then
1342       AC_MSG_ERROR([You need to either install libldns-dev or disable mod_enum in modules.conf])
1343     else
1344       AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_LDNS],[false])
1345     fi],[
1346     AM_CONDITIONAL([HAVE_LDNS],[true])])])])
1347 PKG_CHECK_MODULES([SNDFILE], [sndfile >= 1.0.20],[
1348   AM_CONDITIONAL([HAVE_SNDFILE],[true])],[
1349   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SNDFILE],[false])])
1350
1351 PKG_CHECK_MODULES([MPG123], [libmpg123 >= 1.16.0],[
1352   AM_CONDITIONAL([HAVE_MPG123],[true])],[
1353   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MPG123],[false])])
1354
1355 PKG_CHECK_MODULES([SHOUT], [shout >= 2.2.2],[
1356   AM_CONDITIONAL([HAVE_SHOUT],[true])],[
1357   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SHOUT],[false])])
1358
1359 mp3lame=false
1360 AC_CHECK_LIB([mp3lame], [lame_init],[
1361   AC_CHECK_HEADER([lame/lame.h],[
1362     mp3lame=true
1363     AC_SUBST([MP3LAME_LIBS], [-lmp3lame])
1364     AC_SUBST([MP3LAME_CFLAGS], [$CPPFLAGS])])])
1365 AM_CONDITIONAL([HAVE_MP3LAME],[$mp3lame])
1366
1367 PKG_CHECK_MODULES([AVCODEC], [libavcodec >= 53.35.0],[
1368   AM_CONDITIONAL([HAVE_AVCODEC],[true])],[
1369   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVCODEC],[false])])
1370
1371 PKG_CHECK_MODULES([X264], [x264 >= 0.142.2431],[
1372   AM_CONDITIONAL([HAVE_X264],[true])],[
1373   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_X264],[false])])
1374
1375 PKG_CHECK_MODULES([AVFORMAT], [libavformat >= 53.21.1],[
1376   AM_CONDITIONAL([HAVE_AVFORMAT],[true])],[
1377   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVFORMAT],[false])])
1378
1379 PKG_CHECK_MODULES([AVUTIL], [libavutil >= 54.3.0],[
1380   AM_CONDITIONAL([HAVE_AVUTIL],[true])],[
1381   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVUTIL],[false])])
1382
1383 PKG_CHECK_MODULES([AVRESAMPLE], [libavresample >= 2.1.0],[
1384   AM_CONDITIONAL([HAVE_AVRESAMPLE],[true])],[
1385   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVRESAMPLE],[false])])
1386
1387 PKG_CHECK_MODULES([SWRESAMPLE], [libswresample >= 2.1.0],[
1388   AM_CONDITIONAL([HAVE_SWRESAMPLE],[true])],[
1389   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SWRESAMPLE],[false])])
1390
1391 PKG_CHECK_MODULES([SWSCALE], [libswscale >= 3.0.0],[
1392   AM_CONDITIONAL([HAVE_SWSCALE],[true])],[
1393   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SWSCALE],[false])])
1394
1395 PKG_CHECK_MODULES([VLC], [libvlc >= 2.1.0],[
1396   AM_CONDITIONAL([HAVE_VLC],[true])],[
1397   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_VLC],[false])])
1398
1399 PKG_CHECK_MODULES([OPENCV], [opencv >= 2.4.5],[
1400   AM_CONDITIONAL([HAVE_OPENCV],[true])],[
1401   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPENCV],[false])])
1402
1403 PKG_CHECK_MODULES([OPUSFILE_DECODE], [opusfile >= 0.5],[
1404    AM_CONDITIONAL([HAVE_OPUSFILE_DECODE],[true])],[
1405    AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPUSFILE_DECODE],[false])])
1406 PKG_CHECK_MODULES([OPUSFILE_ENCODE], [libopusenc >= 0.1],[
1407    AM_CONDITIONAL([HAVE_OPUSFILE_ENCODE],[true])],[
1408    AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPUSFILE_ENCODE],[false])])
1409
1410
1411 PKG_CHECK_MODULES([MAGICK], [ImageMagick >= 6.0.0],[
1412   AM_CONDITIONAL([HAVE_MAGICK],[true])],[
1413   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MAGICK],[false])])
1414
1415 PKG_CHECK_MODULES([MAGICK7], [ImageMagick >= 7.0.0],[
1416   AM_CONDITIONAL([HAVE_MAGICK7],[true])],[
1417   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MAGICK7],[false])])
1418
1419 PKG_CHECK_MODULES([SILK], [silk >= 1.0.8],[
1420   AM_CONDITIONAL([HAVE_SILK],[true])],[
1421   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SILK],[false])])
1422
1423 PKG_CHECK_MODULES([BROADVOICE], [broadvoice >= 0.1.0],[
1424   AM_CONDITIONAL([HAVE_BROADVOICE],[true])],[
1425   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_BROADVOICE],[false])])
1426
1427 PKG_CHECK_MODULES([ILBC], [ilbc2 >= 0.0.1],[
1428   AM_CONDITIONAL([HAVE_ILBC],[true])],[
1429     PKG_CHECK_MODULES([ILBC], [ilbc >= 0.0.1],[
1430       AM_CONDITIONAL([HAVE_ILBC],[true])],[
1431       AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_ILBC],[false])])])
1432
1433 PKG_CHECK_MODULES([G7221], [g722_1 >= 0.2.0],[
1434   AM_CONDITIONAL([HAVE_G7221],[true])],[
1435   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_G7221],[false])])
1436
1437 codec2="true"
1438 PKG_CHECK_MODULES([CODEC2], [codec2 >= 0.5],[],[
1439   AC_CHECK_LIB([codec2], [codec2_create],[
1440     AC_CHECK_HEADERS([codec2/codec2.h],[
1441       CODEC2_LIBS="-lcodec2"
1442       CODEC2_CFLAGS=""
1443     ], [
1444     codec2="false"
1445     if module_enabled mod_codec2; then
1446         AC_MSG_ERROR([You must install libcodec2-dev to build mod_codec2])
1447       else
1448         AC_MSG_RESULT([no])
1449       fi
1450     ])
1451   ])
1452 ])
1453
1454 AM_CONDITIONAL([HAVE_CODEC2],[$codec2])
1455
1456
1457 PKG_CHECK_MODULES([OPUS], [opus >= 1.1],[
1458   AM_CONDITIONAL([HAVE_OPUS],[true])],[
1459   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPUS],[false])])
1460
1461 PKG_CHECK_MODULES([SOUNDTOUCH], [soundtouch >= 1.7.0],[
1462   AM_CONDITIONAL([HAVE_SOUNDTOUCH],[true])],[
1463   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SOUNDTOUCH],[false])])
1464
1465 flite="true"
1466 PKG_CHECK_MODULES([FLITE], [flite >= 2],[],[
1467   AC_CHECK_LIB([flite], [flite_init],[
1468     AC_CHECK_HEADERS([flite/flite.h],[
1469       FLITE_LIBS="-lflite -lflite_cmu_grapheme_lang -lflite_cmu_grapheme_lex -lflite_cmu_indic_lang -lflite_cmu_indic_lex -lflite_cmulex -lflite_cmu_time_awb -lflite_cmu_us_awb -lflite_cmu_us_kal16 -lflite_cmu_us_kal -lflite_cmu_us_rms -lflite_cmu_us_slt -lflite_usenglish"
1470       FLITE_CFLAGS=""
1471     ], [
1472     flite="false"
1473     if module_enabled mod_flite; then
1474         AC_MSG_ERROR([You must install libflite-dev to build mod_flite])
1475       else
1476         AC_MSG_RESULT([no])
1477       fi
1478     ])
1479   ])
1480 ])
1481
1482 AM_CONDITIONAL([HAVE_FLITE],[$flite])
1483
1484 PKG_CHECK_MODULES([MONGOC], [libmongoc-1.0 >= 1.0.8],[
1485   AM_CONDITIONAL([HAVE_MONGOC],[true])],[
1486   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MONGOC],[false])])
1487
1488 PKG_CHECK_MODULES([MEMCACHED], [libmemcached >= 0.31],[
1489   AM_CONDITIONAL([HAVE_MEMCACHED],[true])
1490   MEMCACHED_LIBS="${MEMCACHED_LIBS} -lpthread"
1491   save_LIBS="${LIBS}"
1492   save_CPPFLAGS="${CPPFLAGS}"
1493   LIBS="${MEMCACHED_LIBS}"
1494   CPPFLAGS="${MEMCACHED_CFLAGS}"
1495   AC_CHECK_FUNCS([memcached_server_name memcached_stat_execute])
1496   AC_CHECK_TYPES([memcached_instance_st*],,, [[#include <libmemcached/memcached.h>]])
1497   LIBS="${save_LIBS}"
1498   CPPFLAGS="${save_CPPFLAGS}"
1499 ],[
1500   AC_MSG_RESULT([no])
1501   AM_CONDITIONAL([HAVE_MEMCACHED],[false])
1502 ])
1503
1504 PKG_CHECK_MODULES([V8FS_STATIC], [v8-6.1_static >= 6.1.298],[
1505   AM_CONDITIONAL([HAVE_V8FS],[true])],[
1506   PKG_CHECK_MODULES([V8FS_STATIC], [v8fs_static >= 6.1.298],[
1507     AM_CONDITIONAL([HAVE_V8FS],[true])],[
1508     PKG_CHECK_MODULES([V8FS_STATIC], [v8 >= 6.1.298],[
1509       AM_CONDITIONAL([HAVE_V8FS],[true])],[
1510       if module_enabled mod_v8; then
1511         AC_MSG_ERROR([You need to either install libv8-6.1-dev (>= 6.1.298), libv8fs-dev (>= 6.1.298) or disable mod_v8 in modules.conf])
1512       else
1513         AC_MSG_RESULT([no])
1514         AM_CONDITIONAL([HAVE_V8FS],[false])
1515       fi
1516     ])
1517   ])
1518 ])
1519
1520 PKG_CHECK_MODULES([KS], [libks >= 1.1.0],[
1521   AM_CONDITIONAL([HAVE_KS],[true])],[
1522   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_KS],[false])])
1523
1524 PKG_CHECK_MODULES([SIGNALWIRE_CLIENT], [signalwire_client >= 1.0.0],[
1525   AM_CONDITIONAL([HAVE_SIGNALWIRE_CLIENT],[true])],[
1526   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SIGNALWIRE_CLIENT],[false])])
1527
1528 PKG_CHECK_MODULES([AMQP], [librabbitmq >= 0.5.2],[
1529   AM_CONDITIONAL([HAVE_AMQP],[true])],[
1530   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AMQP],[false])])
1531
1532 PKG_CHECK_MODULES([H2O], [libh2o-evloop >= 0.11.0],[
1533   AM_CONDITIONAL([HAVE_H2O],[true])],[
1534   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_H2O],[false])])
1535
1536 PKG_CHECK_MODULES([BROTLIENC], [libbrotlienc >= 0.1.0],[
1537   AM_CONDITIONAL([HAVE_BROTLIENC],[true])],[
1538   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_BROTLIENC],[false])])
1539
1540 PKG_CHECK_MODULES([BROTLIDEC], [libbrotlidec >= 0.1.0],[
1541   AM_CONDITIONAL([HAVE_BROTLIDEC],[true])],[
1542   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_BROTLIDEC],[false])])
1543
1544 PKG_CHECK_MODULES([TAP], [tap >= 0.1.0],[
1545   AM_CONDITIONAL([HAVE_TAP],[true])],[
1546   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_TAP],[false])])
1547
1548 PKG_CHECK_MODULES([SMPP34], [libsmpp34 >= 1.10],[
1549   AM_CONDITIONAL([HAVE_SMPP34],[true])],[
1550   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SMPP34],[false])])
1551
1552 PKG_CHECK_MODULES([HIREDIS], [hiredis >= 0.10.0],[
1553   AM_CONDITIONAL([HAVE_HIREDIS],[true])],[
1554   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_HIREDIS],[false])])
1555
1556 AC_ARG_ENABLE(core-libedit-support,
1557   [AS_HELP_STRING([--disable-core-libedit-support], [Compile without libedit Support])])
1558
1559 AS_IF([test "x$enable_core_libedit_support" != "xno"],[
1560   PKG_CHECK_MODULES([LIBEDIT], [libedit >= 2.11],,[
1561     AC_MSG_RESULT([no])
1562     AC_CHECK_LIB([edit], [el_line], [LIBEDIT_LIBS=-ledit])
1563     AC_CHECK_LIB([edit], [el_cursor], [ac_cv_has_el_cursor=yes])
1564     AC_CHECK_HEADER([histedit.h], [], [unset LIBEDIT_LIBS])
1565     AS_IF([test "x$LIBEDIT_LIBS" = "x"], [
1566       AC_MSG_ERROR([You need to either install libedit-dev (>= 2.11) or configure with --disable-core-libedit-support])
1567       ])])])
1568
1569 dnl ---------------------------------------------------------------------------
1570 dnl - OpenLDAP SDK
1571 dnl ---------------------------------------------------------------------------
1572
1573 AC_CHECK_LIB(ldap, ldap_search, with_ldap=yes)
1574 dnl Check for other libraries we need to link with to get the main routines.
1575 test "$with_ldap" != "yes" && { AC_CHECK_LIB(ldap, ldap_open, [with_ldap=yes with_ldap_lber=yes], , -llber) }
1576 test "$with_ldap" != "yes" && { AC_CHECK_LIB(ldap, ldap_open, [with_ldap=yes with_ldap_lber=yes with_ldap_krb=yes], , -llber -lkrb) }
1577 test "$with_ldap" != "yes" && { AC_CHECK_LIB(ldap, ldap_open, [with_ldap=yes with_ldap_lber=yes with_ldap_krb=yes with_ldap_des=yes], , -llber -lkrb -ldes) }
1578 test "$with_ldap_lber" != "yes" && { AC_CHECK_LIB(lber, ber_pvt_opt_on, with_ldap_lber=yes) }
1579
1580 if test "$with_ldap" = "yes"; then
1581    if test "$with_ldap_des" = "yes" ; then
1582       OPENLDAP_LIBS="${OPENLDAP_LIBS} -ldes"
1583    fi
1584    if test "$with_ldap_krb" = "yes" ; then
1585       OPENLDAP_LIBS="${OPENLDAP_LIBS} -lkrb"
1586    fi
1587    if test "$with_ldap_lber" = "yes" ; then
1588       OPENLDAP_LIBS="${OPENLDAP_LIBS} -llber"
1589    fi
1590    OPENLDAP_LIBS="${OPENLDAP_LIBS} -lldap"
1591 fi
1592
1593 AM_CONDITIONAL([HAVE_LDAP],[test "x$with_ldap" = "xyes"])
1594
1595 AC_SUBST(OPENLDAP_LIBS)
1596
1597 AS_IF([test "x$enable_core_libedit_support" != "xno"], [
1598   # If making changes here, don't forget to run autoheader and
1599   # update libs/esl/src/include/esl_config_auto.h.in manually.
1600   AC_DEFINE([HAVE_LIBEDIT], [1], [Define to 1 if you have libedit is available])
1601 if test x$ac_cv_has_el_cursor = xyes; then
1602   AC_DEFINE([HAVE_EL_CURSOR], [1], [Define to 1 if you have libedit el_cursor support])
1603 fi
1604   save_LIBS="${LIBS}"
1605   save_CPPFLAGS="${CPPFLAGS}"
1606   LIBS="${LIBEDIT_LIBS}"
1607   CPPFLAGS="${LIBEDIT_CFLAGS}"
1608   AC_CHECK_DECLS([EL_PROMPT_ESC, EL_REFRESH],,, [[#include <histedit.h>]])
1609   AC_CHECK_FUNCS([el_wset])
1610   LIBS="${save_LIBS}"
1611   CPPFLAGS="${save_CPPFLAGS}"
1612 ])
1613
1614 SAC_OPENSSL
1615
1616 if test x$HAVE_OPENSSL = x1; then
1617         openssl_CFLAGS="$openssl_CFLAGS -DHAVE_OPENSSL";
1618         APR_ADDTO(SWITCH_AM_CFLAGS, -DHAVE_OPENSSL)
1619         AC_CHECK_LIB(ssl, SSL_CTX_set_tlsext_use_srtp, AC_DEFINE_UNQUOTED(HAVE_OPENSSL_DTLS_SRTP, 1, HAVE_OPENSSL_DTLS_SRTP), AC_MSG_ERROR([OpenSSL >= 1.0.1e and associated developement headers required]))
1620         AC_CHECK_LIB(ssl, DTLSv1_method, AC_DEFINE_UNQUOTED(HAVE_OPENSSL_DTLS, 1, HAVE_OPENSSL_DTLS), AC_MSG_ERROR([OpenSSL >= 1.0.1e and associaed developement headers required]))
1621         AC_CHECK_LIB(ssl, DTLSv1_2_method, AC_DEFINE_UNQUOTED(HAVE_OPENSSL_DTLSv1_2_method, 1, [DTLS version 1.2 is available]))
1622 else
1623         AC_MSG_ERROR([OpenSSL >= 1.0.1e and associated developement headers required])
1624 fi
1625
1626 AX_CHECK_JAVA
1627
1628 AM_CONDITIONAL([HAVE_ODBC],[test "x$enable_core_odbc_support" != "xno"])
1629 AM_CONDITIONAL([HAVE_MYSQL],[test "$found_mysql" = "yes"])
1630
1631 #
1632 # perl checks
1633 #
1634
1635 AC_CHECK_PROG(PERL,perl,[ac_cv_have_perl=yes],[ac_cv_have_perl=no])
1636
1637 # -a "x$ac_cv_have_EXTERN_h" != "xno"
1638
1639 if test "x$ac_cv_have_perl" != "xno"; then
1640    PERL=perl
1641    PERL_SITEDIR="`$PERL -MConfig -e 'print $Config{archlib}'`"
1642    PERL_LIBDIR="-L`$PERL -MConfig -e 'print $Config{archlib}'`/CORE"
1643    PERL_LIBS="`$PERL -MConfig -e 'print $Config{libs}'`"
1644    PERL_CFLAGS="-w -DMULTIPLICITY `$PERL -MExtUtils::Embed -e ccopts | sed -e 's|-arch x86_64 -arch i386||'` -DEMBED_PERL"
1645    PERL_LDFLAGS="`$PERL -MExtUtils::Embed -e ldopts| sed -e 's|-arch x86_64 -arch i386||'`"
1646    PERL_INC="`$PERL -MExtUtils::Embed -e perl_inc`"
1647
1648    save_CFLAGS="$CFLAGS"
1649    CFLAGS="$PERL_CFLAGS"
1650    AC_CHECK_HEADER([EXTERN.h], [ac_cv_have_EXTERN_h=yes], [ac_cv_have_EXTERN_h=no], [[#include <EXTERN.h>
1651 # include <perl.h>]])
1652    CFLAGS="$save_CFLAGS"
1653
1654    save_LDFLAGS="$LDFLAGS"
1655    LDFLAGS="$PERL_LDFLAGS"
1656    AC_CHECK_LIB([perl], [perl_alloc], ac_cv_use_libperl=yes, ac_cv_use_libperl=no)
1657    LDFLAGS="$save_LDFLAGS"
1658
1659    AC_SUBST(PERL_SITEDIR)
1660    AC_SUBST(PERL_LIBDIR)
1661    AC_SUBST(PERL_LIBS)
1662    AC_SUBST(PERL_CFLAGS)
1663    AC_SUBST(PERL_LDFLAGS)
1664    AC_SUBST(PERL_INC)
1665 fi
1666
1667 AM_CONDITIONAL([HAVE_PERL],[test "x$ac_cv_have_perl" != "xno" -a "x$ac_cv_have_EXTERN_h" != "xno" -a "x$ac_cv_use_libperl" != "xno"])
1668
1669 #
1670 # php checks
1671 #
1672
1673 AC_CHECK_PROG(PHP,php,[ac_cv_have_php=yes],[ac_cv_have_php=no])
1674 AC_CHECK_PROG(PHP_CONFIG,php-config,[ac_cv_have_php_config=yes],[ac_cv_have_php_config=no])
1675 AM_CONDITIONAL([HAVE_PHP],[test "x$ac_cv_have_php" != "xno" -a "x$ac_cv_have_php_config" != "xno"])
1676
1677 if test "x$ac_cv_have_php" != "xno" -a "x$ac_cv_have_php_config" != "xno"; then
1678    PHP=php
1679    PHP_CONFIG=php-config
1680    PHP_LDFLAGS="`$PHP_CONFIG --ldflags`"
1681    PHP_LIBS="`$PHP_CONFIG --libs | sed -r 's/ ?-l(bz2|pcre2-8|xml2|gssapi_krb5|krb5|k5crypto|com_err|history|z|readline|gmp|ssl|crypto|argon2|sodium)//g'`"
1682    PHP_EXT_DIR="`$PHP_CONFIG --extension-dir`"
1683    PHP_INC_DIR="`$PHP -r 'echo ini_get("include_path");' | cut -d: -f2`"
1684    PHP_INI_DIR="`$PHP_CONFIG --configure-options | tr " " "\n" | grep -- --with-config-file-scan-dir | cut -f2 -d=`"
1685    PHP_CFLAGS="`$PHP_CONFIG --includes`"
1686    AC_SUBST(PHP_LDFLAGS)
1687    AC_SUBST(PHP_LIBS)
1688    AC_SUBST(PHP_EXT_DIR)
1689    AC_SUBST(PHP_INC_DIR)
1690    AC_SUBST(PHP_INI_DIR)
1691    AC_SUBST(PHP_CFLAGS)
1692 fi
1693
1694 #
1695 # Python checks for mod_python
1696 #
1697 AC_ARG_WITH(
1698         [python],
1699         [AS_HELP_STRING([--with-python], [Use system provided version of python (default: try)])],
1700         [with_python="$withval"],
1701         [with_python="try"]
1702 )
1703
1704 if test "$with_python" != "no"
1705 then
1706         save_CFLAGS="$CFLAGS"
1707         save_LIBS="$LIBS"
1708
1709         if test "$with_python" != "yes" -a "$with_python" != "try" ; then
1710                 AC_MSG_CHECKING([for python])
1711                 if test ! -x "$with_python" ; then
1712                         AC_MSG_ERROR([Specified python does not exist or is not executable: $with_python])
1713                 fi
1714                 AC_MSG_RESULT([$with_python])
1715                 AC_SUBST([PYTHON], ["$with_python"])
1716         else
1717                 AC_PATH_PROG([PYTHON], ["python"], ["no"], ["$PATH:/usr/bin:/usr/local/bin"])
1718         fi
1719
1720         if test "$PYTHON" != "no" ; then
1721                 AC_MSG_CHECKING([python version])
1722                 PYTHON_VER="`$PYTHON -V 2>&1 | cut -d' ' -f2`"
1723
1724                 if test -z "$PYTHON_VER" ; then
1725                         AC_MSG_ERROR([Unable to detect python version])
1726                 fi
1727                 AC_MSG_RESULT([$PYTHON_VER])
1728
1729                 AC_MSG_CHECKING([for python distutils])
1730                 python_result="`$PYTHON -c 'import distutils;' 2>&1`"
1731                 if test -z "$python_result" ; then
1732                         python_has_distutils="yes"
1733                 else
1734                         python_has_distutils="no"
1735                 fi
1736                 AC_MSG_RESULT([$python_has_distutils])
1737
1738                 if test "$python_has_distutils" != "no" ; then
1739                         AC_MSG_CHECKING([location of site-packages])
1740
1741                         PYTHON_SITE_DIR="`$PYTHON -c 'from distutils import sysconfig; print(sysconfig.get_python_lib(0));'`"
1742
1743                         if test -z "$PYTHON_SITE_DIR" ; then
1744                                 AC_MSG_ERROR([Unable to detect python site-packages path])
1745                         elif test ! -d "$PYTHON_SITE_DIR" ; then
1746                                 AC_MSG_ERROR([Path $PYTHON_SITE_DIR returned by python does not exist!])
1747                         fi
1748                         AC_MSG_RESULT([$PYTHON_SITE_DIR])
1749                         AC_SUBST([PYTHON_SITE_DIR], [$PYTHON_SITE_DIR])
1750
1751                         #
1752                         # python distutils found, get settings from python directly
1753                         #
1754                         PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; flags = [[\"-I\" + sysconfig.get_python_inc(0), \"-I\" + sysconfig.get_python_inc(1), \" \".join(sysconfig.get_config_var(\"CFLAGS\").split())]]; print(\" \".join(flags));' | sed -e 's/-arch i386//g;s/-arch x86_64//g'`"
1755                         PYTHON_LDFLAGS="`$PYTHON -c 'from distutils import sysconfig; libs = sysconfig.get_config_var(\"LIBS\").split() + sysconfig.get_config_var(\"SYSLIBS\").split(); libs.append(\"-lpython\"+sysconfig.get_config_var(\"VERSION\")); print(\" \".join(libs));'`"
1756                         PYTHON_LIB="`$PYTHON -c 'from distutils import sysconfig; print(\"python\" + sysconfig.get_config_var(\"VERSION\"));'`"
1757                         PYTHON_LIBDIR="`$PYTHON -c 'from distutils import sysconfig; print(sysconfig.get_config_var(\"LIBDIR\"));'`"
1758
1759                         # handle python being installed into /usr/local
1760                         AC_MSG_CHECKING([python libdir])
1761                         if test -z "`echo $PYTHON_LIBDIR | grep "/usr/lib"`" ; then
1762                                 PYTHON_LDFLAGS="-L$PYTHON_LIBDIR $PYTHON_LDFLAGS"
1763                                 LIBS="-L$PYTHON_LIBDIR $LIBS"
1764                         fi
1765                         AC_MSG_RESULT([$PYTHON_LIBDIR])
1766
1767                         # check libpython
1768                         AC_CHECK_LIB([$PYTHON_LIB], [main], [has_libpython="yes"], [has_libpython="no"])
1769
1770                         if test "$has_libpython" = "no" ; then
1771                                 AS_IF([test "$with_python" = "try"],
1772                                         [AC_MSG_WARN([$PYTHON_LIB is unusable])],
1773                                         [AC_MSG_ERROR([$PYTHON_LIB is unusable])]
1774                                 )
1775                         fi
1776
1777                         # check whether system libpython is usable and has threads support
1778                         CFLAGS="$PYTHON_CFLAGS"
1779                         LIBS="$PYTHON_LDFLAGS"
1780                         AC_CHECK_FUNC([PyThread_init_thread], [python_has_threads="yes"], [python_has_threads="no"])
1781
1782                         if test "$python_has_threads" = "no"; then
1783                                 AS_IF([test "$with_python" = "try"],
1784                                         [AC_MSG_WARN([Your python lacks threads support, can not build mod_python])],
1785                                         [AC_MSG_ERROR([Your python lacks threads support, can not build mod_python])]
1786                                 )
1787                         else
1788                                 AC_MSG_NOTICE([Your python seems OK, do not forget to enable mod_python in modules.conf])
1789                                 AC_SUBST([PYTHON_CFLAGS],  [$PYTHON_CFLAGS])
1790                                 AC_SUBST([PYTHON_LDFLAGS], [$PYTHON_LDFLAGS])
1791                         fi
1792                 else
1793                         AS_IF([test "$with_python" = "try"],
1794                                 [AC_MSG_WARN([Could not find or use python distutils module: $python_result])],
1795                                 [AC_MSG_ERROR([Could not find or use python distutils module: $python_result])]
1796                         )
1797                 fi
1798
1799                 LIBS="$save_LIBS"
1800                 CFLAGS="$save_CFLAGS"
1801
1802                 unset python_has_threads
1803                 unset python_has_distutils
1804                 unset python_result
1805         else
1806                 AS_IF([test "$with_python" = "try"],
1807                         [AC_MSG_WARN([Could not find python, mod_python will not build, use --with-python to specify the location])],
1808                         [AC_MSG_ERROR([Could not find python, use --with-python to specify the location])]
1809                 )
1810         fi
1811 else
1812         AC_MSG_WARN([python support disabled, building mod_python will fail!])
1813 fi
1814
1815 #
1816 # SNMP checks for mod_snmp
1817 #
1818 AC_PATH_PROG([NET_SNMP_CONFIG], [net-snmp-config], [no])
1819 if test "$NET_SNMP_CONFIG" != "no"; then
1820         AC_MSG_CHECKING([for Net-SNMP libraries via net-snmp-config])
1821         SNMP_LIBS="`$NET_SNMP_CONFIG --base-agent-libs`"
1822 else
1823         # net-snmp-config not in path, fallback to sensible defaults
1824         SNMP_LIBS="-lnetsnmpmibs -lnetsnmpagent -lnetsnmp"
1825 fi
1826
1827 # fix linking error on Solaris patched Net-SNMP
1828 AS_CASE([$host], [*-solaris2*], [AC_CHECK_LIB([dladm], [dladm_open], [SNMP_LIBS="$SNMP_LIBS -ldladm"])])
1829 AC_SUBST(SNMP_LIBS)
1830
1831 CHECK_ERLANG
1832
1833 #  Enable clang address sanitizer bit build
1834 AC_ARG_ENABLE(address_sanitizer,
1835   [AC_HELP_STRING([--enable-address-sanitizer],[build with address sanitizer])],
1836   [enable_address_sanitizer="$enable_address_sanitizer"],
1837   [enable_address_sanitizer="no"])
1838
1839 if test "${enable_address_sanitizer}" = "yes"; then
1840   APR_ADDTO(CFLAGS, -fsanitize=address -fno-omit-frame-pointer -fstack-protector-strong)
1841   APR_ADDTO(CXXFLAGS, -fsanitize=address -fno-omit-frame-pointer -fstack-protector-strong)
1842   APR_ADDTO(LDFLAGS, -fsanitize=address)
1843 fi
1844
1845 AC_ARG_ENABLE(,
1846   [AC_HELP_STRING([--enable-pool-sanitizer],[build with sanitizer friendly pool behavior])],
1847   [enable_pool_sanitizer="$enable_pool_sanitizer"],
1848   [enable_pool_sanitizer="no"])
1849
1850 if test "${enable_pool_sanitizer}" = "yes"; then
1851   APR_ADDTO(CFLAGS, -DDESTROY_POOLS)
1852   ac_configure_args="$ac_configure_args --enable-pool-debug=yes"
1853 fi
1854
1855 # we never use this, and hard setting it will make cross compile work better
1856 ac_cv_file_dbd_apr_dbd_mysql_c=no
1857
1858 AC_CONFIG_FILES([Makefile
1859                 build/Makefile
1860                 tests/unit/Makefile
1861                 src/Makefile
1862                 src/mod/Makefile
1863                 src/mod/applications/mod_abstraction/Makefile
1864                 src/mod/applications/mod_avmd/Makefile
1865                 src/mod/applications/mod_bert/Makefile
1866                 src/mod/applications/mod_blacklist/Makefile
1867                 src/mod/applications/mod_callcenter/Makefile
1868                 src/mod/applications/mod_cidlookup/Makefile
1869                 src/mod/applications/mod_cluechoo/Makefile
1870                 src/mod/applications/mod_commands/Makefile
1871                 src/mod/applications/mod_conference/Makefile
1872                 src/mod/applications/mod_curl/Makefile
1873                 src/mod/applications/mod_cv/Makefile
1874                 src/mod/applications/mod_db/Makefile
1875                 src/mod/applications/mod_directory/Makefile
1876                 src/mod/applications/mod_distributor/Makefile
1877                 src/mod/applications/mod_dptools/Makefile
1878                 src/mod/applications/mod_easyroute/Makefile
1879                 src/mod/applications/mod_enum/Makefile
1880                 src/mod/applications/mod_esf/Makefile
1881                 src/mod/applications/mod_esl/Makefile
1882                 src/mod/applications/mod_expr/Makefile
1883                 src/mod/applications/mod_fifo/Makefile
1884                 src/mod/applications/mod_fsk/Makefile
1885                 src/mod/applications/mod_fsv/Makefile
1886                 src/mod/applications/mod_hash/Makefile
1887                 src/mod/applications/mod_hiredis/Makefile
1888                 src/mod/applications/mod_httapi/Makefile
1889                 src/mod/applications/mod_http_cache/Makefile
1890                 src/mod/applications/mod_ladspa/Makefile
1891                 src/mod/applications/mod_lcr/Makefile
1892                 src/mod/applications/mod_limit/Makefile
1893                 src/mod/applications/mod_memcache/Makefile
1894                 src/mod/applications/mod_mongo/Makefile
1895                 src/mod/applications/mod_mp4/Makefile
1896                 src/mod/applications/mod_mp4v2/Makefile
1897                 src/mod/applications/mod_nibblebill/Makefile
1898                 src/mod/applications/mod_oreka/Makefile
1899                 src/mod/applications/mod_osp/Makefile
1900                 src/mod/applications/mod_prefix/Makefile
1901                 src/mod/applications/mod_rad_auth/Makefile
1902                 src/mod/applications/mod_random/Makefile
1903                 src/mod/applications/mod_redis/Makefile
1904                 src/mod/applications/mod_rss/Makefile
1905                 src/mod/applications/mod_skel/Makefile
1906                 src/mod/applications/mod_signalwire/Makefile
1907                 src/mod/applications/mod_sms/Makefile
1908                 src/mod/applications/mod_sms_flowroute/Makefile
1909                 src/mod/applications/mod_snapshot/Makefile
1910                 src/mod/applications/mod_snom/Makefile
1911                 src/mod/applications/mod_sonar/Makefile
1912                 src/mod/applications/mod_soundtouch/Makefile
1913                 src/mod/applications/mod_spandsp/Makefile
1914                 src/mod/applications/mod_spy/Makefile
1915                 src/mod/applications/mod_stress/Makefile
1916                 src/mod/applications/mod_test/Makefile
1917                 src/mod/applications/mod_translate/Makefile
1918                 src/mod/applications/mod_valet_parking/Makefile
1919                 src/mod/applications/mod_vmd/Makefile
1920                 src/mod/applications/mod_voicemail/Makefile
1921                 src/mod/applications/mod_voicemail_ivr/Makefile
1922                 src/mod/asr_tts/mod_cepstral/Makefile
1923                 src/mod/asr_tts/mod_flite/Makefile
1924                 src/mod/asr_tts/mod_pocketsphinx/Makefile
1925                 src/mod/asr_tts/mod_tts_commandline/Makefile
1926                 src/mod/asr_tts/mod_unimrcp/Makefile
1927                 src/mod/codecs/mod_amr/Makefile
1928                 src/mod/codecs/mod_amrwb/Makefile
1929                 src/mod/codecs/mod_b64/Makefile
1930                 src/mod/codecs/mod_bv/Makefile
1931                 src/mod/codecs/mod_clearmode/Makefile
1932                 src/mod/codecs/mod_codec2/Makefile
1933                 src/mod/codecs/mod_com_g729/Makefile
1934                 src/mod/codecs/mod_dahdi_codec/Makefile
1935                 src/mod/codecs/mod_g723_1/Makefile
1936                 src/mod/codecs/mod_g729/Makefile
1937                 src/mod/codecs/mod_h26x/Makefile
1938                 src/mod/codecs/mod_ilbc/Makefile
1939                 src/mod/codecs/mod_isac/Makefile
1940                 src/mod/codecs/mod_mp4v/Makefile
1941                 src/mod/codecs/mod_opus/Makefile
1942                 src/mod/codecs/mod_openh264/Makefile
1943                 src/mod/codecs/mod_sangoma_codec/Makefile
1944                 src/mod/codecs/mod_silk/Makefile
1945                 src/mod/codecs/mod_siren/Makefile
1946                 src/mod/codecs/mod_skel_codec/Makefile
1947                 src/mod/codecs/mod_theora/Makefile
1948                 src/mod/databases/mod_mariadb/Makefile
1949                 src/mod/databases/mod_pgsql/Makefile
1950                 src/mod/dialplans/mod_dialplan_asterisk/Makefile
1951                 src/mod/dialplans/mod_dialplan_directory/Makefile
1952                 src/mod/dialplans/mod_dialplan_xml/Makefile
1953                 src/mod/directories/mod_ldap/Makefile
1954                 src/mod/endpoints/mod_alsa/Makefile
1955                 src/mod/endpoints/mod_dingaling/Makefile
1956                 src/mod/endpoints/mod_gsmopen/Makefile
1957                 src/mod/endpoints/mod_h323/Makefile
1958                 src/mod/endpoints/mod_khomp/Makefile
1959                 src/mod/endpoints/mod_loopback/Makefile
1960                 src/mod/endpoints/mod_opal/Makefile
1961                 src/mod/endpoints/mod_portaudio/Makefile
1962                 src/mod/endpoints/mod_reference/Makefile
1963                 src/mod/endpoints/mod_rtmp/Makefile
1964                 src/mod/endpoints/mod_skinny/Makefile
1965                 src/mod/endpoints/mod_sofia/Makefile
1966                 src/mod/endpoints/mod_unicall/Makefile
1967                 src/mod/endpoints/mod_rtc/Makefile
1968                 src/mod/endpoints/mod_verto/Makefile
1969                 src/mod/event_handlers/mod_amqp/Makefile
1970                 src/mod/event_handlers/mod_cdr_csv/Makefile
1971                 src/mod/event_handlers/mod_cdr_mongodb/Makefile
1972                 src/mod/event_handlers/mod_cdr_pg_csv/Makefile
1973                 src/mod/event_handlers/mod_cdr_sqlite/Makefile
1974                 src/mod/event_handlers/mod_erlang_event/Makefile
1975                 src/mod/event_handlers/mod_event_multicast/Makefile
1976                 src/mod/event_handlers/mod_event_socket/Makefile
1977                 src/mod/event_handlers/mod_event_test/Makefile
1978                 src/mod/event_handlers/mod_fail2ban/Makefile
1979                 src/mod/event_handlers/mod_format_cdr/Makefile
1980                 src/mod/event_handlers/mod_json_cdr/Makefile
1981                 src/mod/event_handlers/mod_kazoo/Makefile
1982                 src/mod/event_handlers/mod_radius_cdr/Makefile
1983                 src/mod/event_handlers/mod_odbc_cdr/Makefile
1984                 src/mod/event_handlers/mod_rayo/Makefile
1985                 src/mod/event_handlers/mod_smpp/Makefile
1986                 src/mod/event_handlers/mod_snmp/Makefile
1987                 src/mod/event_handlers/mod_event_zmq/Makefile
1988                 src/mod/formats/mod_imagick/Makefile
1989                 src/mod/formats/mod_local_stream/Makefile
1990                 src/mod/formats/mod_native_file/Makefile
1991                 src/mod/formats/mod_opusfile/Makefile
1992                 src/mod/formats/mod_png/Makefile
1993                 src/mod/formats/mod_shell_stream/Makefile
1994                 src/mod/formats/mod_shout/Makefile
1995                 src/mod/formats/mod_sndfile/Makefile
1996                 src/mod/formats/mod_ssml/Makefile
1997                 src/mod/formats/mod_tone_stream/Makefile
1998                 src/mod/formats/mod_vlc/Makefile
1999                 src/mod/formats/mod_portaudio_stream/Makefile
2000                 src/mod/languages/mod_java/Makefile
2001                 src/mod/languages/mod_lua/Makefile
2002                 src/mod/languages/mod_managed/Makefile
2003                 src/mod/languages/mod_perl/Makefile
2004                 src/mod/languages/mod_python/Makefile
2005                 src/mod/languages/mod_v8/Makefile
2006                 src/mod/languages/mod_yaml/Makefile
2007                 src/mod/languages/mod_basic/Makefile
2008                 src/mod/loggers/mod_console/Makefile
2009                 src/mod/loggers/mod_graylog2/Makefile
2010                 src/mod/loggers/mod_logfile/Makefile
2011                 src/mod/loggers/mod_syslog/Makefile
2012                 src/mod/loggers/mod_raven/Makefile
2013                 src/mod/say/mod_say_de/Makefile
2014                 src/mod/say/mod_say_en/Makefile
2015                 src/mod/say/mod_say_es/Makefile
2016                 src/mod/say/mod_say_es_ar/Makefile
2017                 src/mod/say/mod_say_fa/Makefile
2018                 src/mod/say/mod_say_fr/Makefile
2019                 src/mod/say/mod_say_he/Makefile
2020                 src/mod/say/mod_say_hr/Makefile
2021                 src/mod/say/mod_say_hu/Makefile
2022                 src/mod/say/mod_say_it/Makefile
2023                 src/mod/say/mod_say_ja/Makefile
2024                 src/mod/say/mod_say_nl/Makefile
2025                 src/mod/say/mod_say_pl/Makefile
2026                 src/mod/say/mod_say_pt/Makefile
2027                 src/mod/say/mod_say_ru/Makefile
2028                 src/mod/say/mod_say_sv/Makefile
2029                 src/mod/say/mod_say_th/Makefile
2030                 src/mod/say/mod_say_zh/Makefile
2031                 src/mod/timers/mod_posix_timer/Makefile
2032                 src/mod/timers/mod_timerfd/Makefile
2033                 src/mod/xml_int/mod_xml_cdr/Makefile
2034                 src/mod/xml_int/mod_xml_curl/Makefile
2035                 src/mod/xml_int/mod_xml_ldap/Makefile
2036                 src/mod/xml_int/mod_xml_radius/Makefile
2037                 src/mod/xml_int/mod_xml_rpc/Makefile
2038                 src/mod/xml_int/mod_xml_scgi/Makefile
2039                 src/mod/applications/mod_av/Makefile
2040                 src/mod/applications/mod_video_filter/Makefile
2041                 src/include/switch_am_config.h
2042                 build/getsounds.sh
2043                 build/getlib.sh
2044                 build/getg729.sh
2045                 build/freeswitch.pc
2046                 build/standalone_module/freeswitch.pc
2047                 build/modmake.rules
2048                 libs/esl/Makefile
2049                 libs/esl/perl/Makefile
2050                 libs/esl/php/Makefile
2051                 libs/xmlrpc-c/include/xmlrpc-c/config.h
2052                 libs/xmlrpc-c/xmlrpc_config.h
2053                 libs/xmlrpc-c/config.mk
2054                 libs/xmlrpc-c/srcdir.mk
2055                 libs/xmlrpc-c/stamp-h
2056                 scripts/gentls_cert])
2057
2058 AM_CONDITIONAL(ISLINUX, [test `uname -s` = Linux])
2059 AM_CONDITIONAL(ISMAC, [test `uname -s` = Darwin])
2060 AM_CONDITIONAL(ISFREEBSD, [test `uname -s` = FreeBSD])
2061 AM_CONDITIONAL(IS64BITLINUX, [test `uname -m` = x86_64])
2062
2063 AM_CONDITIONAL(HAVE_G723_1, [ test -d ${switch_srcdir}/libs/libg723_1 ])
2064 AM_CONDITIONAL(HAVE_G729, [ test -d ${switch_srcdir}/libs/libg729 ])
2065
2066 #some vars to sub into the Makefile.am's
2067 #LIBS+=> core.log || error="yes";if test -n "$(VERBOSE)" -o "$$error" = "yes";then cat core.log;fi;if test "$$error" = "yes";then exit 1;fi
2068 LIBTOOL='$(SHELL) $(switch_builddir)/libtool'
2069 TOUCH_TARGET='if test -f "$@";then touch "$@";fi;'
2070 CONF_MODULES='$$(grep -v "\#" $(switch_builddir)/modules.conf | sed "s/|.*//" | sed -e "s|^.*/||" | sort | uniq )'
2071 CONF_DISABLED_MODULES='$$(grep "\#" $(switch_builddir)/modules.conf | grep -v "\#\#" | sed "s/|.*//" | sed -e "s|^.*/||" | sort | uniq )'
2072 OUR_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-all ; done )"; echo $$mods )'
2073 OUR_CLEAN_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-clean ; done )"; echo $$mods )'
2074 OUR_INSTALL_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-install ; done)"; echo $$mods )'
2075 OUR_UNINSTALL_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-uninstall ; done)"; echo $$mods )'
2076 OUR_TEST_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-print_tests ; done )"; echo $$mods )'
2077 OUR_CHECK_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-check ; done )"; echo $$mods )'
2078 OUR_DISABLED_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)"; mods="$$(for i in $$tmp_mods ; do echo $$i-all ; done )"; echo $$mods )'
2079 OUR_DISABLED_CLEAN_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)";  mods="$$(for i in $$tmp_mods ; do echo $$i-clean ; done )"; echo $$mods )'
2080 OUR_DISABLED_INSTALL_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)"; mods="$$(for i in $$tmp_mods ; do echo $$i-install ; done)"; echo $$mods )'
2081 OUR_DISABLED_UNINSTALL_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)"; mods="$$(for i in $$tmp_mods ; do echo $$i-uninstall ; done)"; echo $$mods )'
2082
2083 #AM_MAKEFLAGS='"OUR_MODULES=$(OUR_MODS)" "OUR_CLEAN_MODULES=$(OUR_CLEAN_MODS)" "OUR_INSTALL_MODULES=$(OUR_INSTALL_MODS)" "OUR_UNINSTALL_MODULES=$(OUR_UNINSTALL_MODS)" "OUR_DISABLED_MODULES=$(OUR_DISABLED_MODS)" "OUR_DISABLED_CLEAN_MODULES=$(OUR_DISABLED_CLEAN_MODS)" "OUR_DISABLED_INSTALL_MODULES=$(OUR_DISABLED_INSTALL_MODS)" "OUR_DISABLED_UNINSTALL_MODULES=$(OUR_DISABLED_UNINSTALL_MODS)" `test -n "$(VERBOSE)" || echo -s`'
2084 #AM_MAKEFLAGS='`test -n "$(VERBOSE)" || echo -s`'
2085 AC_SUBST(LIBTOOL)
2086 AC_SUBST(TOUCH_TARGET)
2087 AC_SUBST(CONF_DISABLED_MODULES)
2088 AC_SUBST(CONF_MODULES)
2089
2090 AC_SUBST(OUR_MODS)
2091 AC_SUBST(OUR_CLEAN_MODS)
2092 AC_SUBST(OUR_TEST_MODS)
2093 AC_SUBST(OUR_CHECK_MODS)
2094 AC_SUBST(OUR_INSTALL_MODS)
2095 AC_SUBST(OUR_UNINSTALL_MODS)
2096 AC_SUBST(OUR_DISABLED_MODS)
2097 AC_SUBST(OUR_DISABLED_CLEAN_MODS)
2098 AC_SUBST(OUR_DISABLED_INSTALL_MODS)
2099 AC_SUBST(OUR_DISABLED_UNINSTALL_MODS)
2100 AC_SUBST(AM_MAKEFLAGS)
2101
2102 ac_configure_args="$ac_configure_args --with-modinstdir=${modulesdir} CONFIGURE_CFLAGS='$CFLAGS $CPPFLAGS' CONFIGURE_CXXFLAGS='$CXXFLAGS $CPPFLAGS' CONFIGURE_LDFLAGS='$LDFLAGS' "
2103
2104 #       --prefix='$prefix' --exec_prefix='$exec_prefix' --libdir='$libdir' --libexecdir='$libexecdir' --bindir='$bindir' --sbindir='$sbindir' \
2105 #       --localstatedir='$localstatedir' --datadir='$datadir'"
2106
2107 # Run configure in all the subdirs
2108 AC_CONFIG_SUBDIRS([libs/srtp])
2109 if test "$use_system_apr" != "yes"; then
2110    AC_CONFIG_SUBDIRS([libs/apr])
2111 fi
2112 if test "$use_system_aprutil" != "yes"; then
2113    AC_CONFIG_SUBDIRS([libs/apr-util])
2114 fi
2115 AC_CONFIG_SUBDIRS([libs/iksemel])
2116 AC_CONFIG_SUBDIRS([libs/libdingaling])
2117 AC_CONFIG_SUBDIRS([libs/freetdm])
2118 AC_CONFIG_SUBDIRS([libs/unimrcp])
2119 if test "x${enable_zrtp}" = "xyes"; then
2120    AC_CONFIG_SUBDIRS([libs/libzrtp])
2121 fi
2122
2123 case $host in
2124    *-openbsd*|*-netbsd*)
2125        # libtool won't link static libs against shared ones on NetBSD/OpenBSD unless we tell it not to be stupid
2126        AC_CONFIG_COMMANDS([hacklibtool], [cp libtool libtool.orig  && sed -e "s/deplibs_check_method=.*/deplibs_check_method=pass_all/g" libtool.orig > libtool])
2127        ;;
2128 esac
2129
2130
2131 AC_OUTPUT
2132
2133 ##
2134 ## Configuration summary
2135 ##
2136
2137 echo
2138 echo "-------------------------- FreeSWITCH configuration --------------------------"
2139 echo ""
2140 echo "  Locations:"
2141 echo ""
2142 echo "      prefix:          ${prefix}"
2143 echo "      exec_prefix:     ${exec_prefix}"
2144 echo "      bindir:          ${bindir}"
2145 echo "      confdir:         ${confdir}"
2146 echo "      libdir:          ${libdir}"
2147 echo "      datadir:         ${datadir}"
2148 echo "      localstatedir:   ${localstatedir}"
2149 echo "      includedir:      ${includedir}"
2150 echo ""
2151 echo "      certsdir:        ${certsdir}"
2152 echo "      dbdir:           ${dbdir}"
2153 echo "      grammardir:      ${grammardir}"
2154 echo "      htdocsdir:       ${htdocsdir}"
2155 echo "      fontsdir:        ${fontsdir}"
2156 echo "      logfiledir:      ${logfiledir}"
2157 echo "      modulesdir:      ${modulesdir}"
2158 echo "      pkgconfigdir:    ${pkgconfigdir}"
2159 echo "      recordingsdir:   ${recordingsdir}"
2160 echo "      imagesdir:       ${imagesdir}"
2161 echo "      runtimedir:      ${runtimedir}"
2162 echo "      scriptdir:       ${scriptdir}"
2163 echo "      soundsdir:       ${soundsdir}"
2164 echo "      storagedir:      ${storagedir}"
2165 echo "      cachedir:        ${cachedir}"
2166 echo ""
2167 echo "------------------------------------------------------------------------------"