configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [229],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 109
 110 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 111 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 112
 113 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 114
 115 M4_DEFINES=
 116
 117 AC_CHECK_TOOL(OBJCOPY, objcopy)
 118 AC_CHECK_TOOL(STRINGS, strings)
 119 AC_CHECK_TOOL(GPERF, gperf)
 120 if test -z "$GPERF" ; then
 121         AC_MSG_ERROR([*** gperf not found])
 122 fi
 123
 124 # ------------------------------------------------------------------------------
 125 address_sanitizer_cflags=
 126 address_sanitizer_cppflags=
 127 address_sanitizer_ldflags=
 128 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 129 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 131             AS_IF([test -z "$with_as_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 133             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             address_sanitizer_cppflags="-DVALGRIND=1"
 135             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 136       ])
 137
 138 undefined_sanitizer_cflags=
 139 undefined_sanitizer_cppflags=
 140 undefined_sanitizer_ldflags=
 141 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 142 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 143             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 144             AS_IF([test -z "$with_us_cflags"],
 145                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 146             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 147             undefined_sanitizer_cppflags="-DVALGRIND=1"
 148             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 149       ])
 150
 151 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 152 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 153 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 154
 155 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 156         -pipe \
 157         -Wall \
 158         -Wextra \
 159         -Wundef \
 160         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 161         -Wlogical-op \
 162         -Wmissing-include-dirs \
 163         -Wold-style-definition \
 164         -Wpointer-arith \
 165         -Winit-self \
 166         -Wdeclaration-after-statement \
 167         -Wfloat-equal \
 168         -Wsuggest-attribute=noreturn \
 169         -Werror=missing-prototypes \
 170         -Werror=implicit-function-declaration \
 171         -Werror=missing-declarations \
 172         -Werror=return-type \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 216                -flto])],
 217         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 218 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 222                -Wp,-D_FORTIFY_SOURCE=2])],
 223         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 224 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 225
 226 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 227         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 228                -Wl,--gc-sections])],
 229         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 230 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 231
 232 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 233         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 234                -ffunction-sections -fdata-sections])],
 235         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 236 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 237
 238 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 239         -Wl,--as-needed \
 240         -Wl,--no-undefined \
 241         -Wl,-z,relro \
 242         -Wl,-z,now \
 243         -pie \
 244         -Wl,-fuse-ld=gold])
 245 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 246
 247 AC_CHECK_SIZEOF(pid_t)
 248 AC_CHECK_SIZEOF(uid_t)
 249 AC_CHECK_SIZEOF(gid_t)
 250 AC_CHECK_SIZEOF(time_t)
 251 AC_CHECK_SIZEOF(dev_t)
 252 AC_CHECK_SIZEOF(rlim_t,,[
 253        #include <sys/time.h>
 254        #include <sys/resource.h>
 255 ])
 256
 257 # ------------------------------------------------------------------------------
 258 # we use python to build the man page index
 259 have_python=no
 260 AC_ARG_WITH([python],
 261         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 262
 263 have_lxml=no
 264 AS_IF([test "x$with_python" != "xno"], [
 265         AM_PATH_PYTHON(,, [:])
 266         AS_IF([test "x$PYTHON" != "x:"], [
 267                 AC_MSG_CHECKING([for python lxml module])
 268                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 269                 AC_MSG_RESULT([$have_lxml])
 270                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 271                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 272         ])
 273 ])
 274 AS_IF([test "$have_python" != "yes"], [
 275       AS_IF([test "$with_python" = "yes"],
 276             [AC_MSG_ERROR([*** python support requested but python support not found])])
 277       AS_IF([test "$with_python" != "no"],
 278             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 279 ])
 280 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 281
 282 # ------------------------------------------------------------------------------
 283
 284 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 285 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 286 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 287
 288 # unconditionally pull-in librt with old glibc versions
 289 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 290
 291 save_LIBS="$LIBS"
 292 LIBS=
 293 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 294 CAP_LIBS="$LIBS"
 295 LIBS="$save_LIBS"
 296 AC_SUBST(CAP_LIBS)
 297
 298 AC_CHECK_FUNCS([memfd_create])
 299 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 300 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2,
 301                 kcmp, keyctl, key_serial_t, char16_t, char32_t, LO_FLAGS_PARTSCAN],
 302                [], [], [[
 303 #include <sys/types.h>
 304 #include <unistd.h>
 305 #include <sys/mount.h>
 306 #include <fcntl.h>
 307 #include <sched.h>
 308 #include <linux/loop.h>
 309 #include <linux/random.h>
 310 ]])
 311
 312 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 313                 IFLA_MACVLAN_FLAGS,
 314                 IFLA_IPVLAN_MODE,
 315                 IFLA_VTI_REMOTE,
 316                 IFLA_PHYS_PORT_ID,
 317                 IFLA_BOND_AD_INFO,
 318                 IFLA_VLAN_PROTOCOL,
 319                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 320                 IFLA_IPTUN_ENCAP_DPORT,
 321                 IFLA_GRE_ENCAP_DPORT,
 322                 IFLA_BRIDGE_VLAN_INFO,
 323                 IFLA_BRPORT_LEARNING_SYNC,
 324                 IFLA_BR_PRIORITY,
 325                 NDA_IFINDEX,
 326                 IFA_FLAGS],
 327 [], [], [[
 328 #include <inttypes.h>
 329 #include <netinet/in.h>
 330 #include <netinet/ether.h>
 331 #include <linux/rtnetlink.h>
 332 #include <net/if.h>
 333 #include <linux/ip.h>
 334 #include <linux/if_tunnel.h>
 335 #include <linux/if_link.h>
 336 #include <linux/if_bridge.h>
 337 #include <linux/if_addr.h>
 338 #include <linux/neighbour.h>
 339 ]])
 340
 341 # This makes sure pkg.m4 is available.
 342 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 343
 344 # ------------------------------------------------------------------------------
 345 have_dbus=no
 346 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 347 AS_IF([test "x$enable_dbus" != "xno"], [
 348         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 349                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 350                 [have_dbus=no])
 351         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 352                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 353 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 354
 355 # ------------------------------------------------------------------------------
 356 have_utmp=yes
 357 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 358         AS_CASE("x${enableval}",
 359                 [xyes], [have_utmp=yes],
 360                 [xno],  [have_utmp=no],
 361                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 362 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 363 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 364
 365 # ------------------------------------------------------------------------------
 366 have_coverage=no
 367 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 368 if test "x$enable_coverage" = "xyes" ; then
 369         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 370         if test "x$lcov_found" = xno ; then
 371                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 372         else
 373                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 374                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 375                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 376                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 377                 else
 378                         have_coverage=yes
 379                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 380                         -fprofile-arcs \
 381                         -ftest-coverage])
 382                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 383                 fi
 384         fi
 385 fi
 386 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 387
 388 # ------------------------------------------------------------------------------
 389 have_kmod=no
 390 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 391 if test "x$enable_kmod" != "xno"; then
 392         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 393         if test "x$have_kmod" = "xyes"; then
 394                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 395                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 396                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 397         fi
 398         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 399                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 400         fi
 401 fi
 402 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 403
 404 # ------------------------------------------------------------------------------
 405 have_xkbcommon=no
 406 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 407 if test "x$enable_xkbcommon" != "xno"; then
 408         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 409                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 410         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 411                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 412         fi
 413 fi
 414 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 415
 416 # ------------------------------------------------------------------------------
 417 have_blkid=no
 418 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 419 if test "x$enable_blkid" != "xno"; then
 420         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 421                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 422         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 423                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 424         fi
 425 fi
 426 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 427
 428 # ------------------------------------------------------------------------------
 429 have_libmount=no
 430 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 431         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 432 if test "x$have_libmount" = xno; then
 433         AC_MSG_ERROR([*** libmount support required but libraries not found])
 434 fi
 435 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 436
 437 # ------------------------------------------------------------------------------
 438 have_seccomp=no
 439 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 440 if test "x$enable_seccomp" != "xno"; then
 441         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 442                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 443                 have_seccomp=yes
 444                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 445                [have_seccomp=no])
 446         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 447                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 448         fi
 449 fi
 450 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 451
 452 # ------------------------------------------------------------------------------
 453 have_ima=yes
 454 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 455                 [case "${enableval}" in
 456                         yes) have_ima=yes ;;
 457                         no) have_ima=no ;;
 458                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 459                 esac],
 460                 [have_ima=yes])
 461
 462 if test "x${have_ima}" != xno ; then
 463         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 464 fi
 465
 466 # ------------------------------------------------------------------------------
 467 have_selinux=no
 468 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 469 if test "x$enable_selinux" != "xno"; then
 470         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 471                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 472                  have_selinux=yes
 473                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 474                 [have_selinux=no])
 475         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 476                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 477         fi
 478 fi
 479 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 480
 481 have_apparmor=no
 482 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 483 if test "x$enable_apparmor" != "xno"; then
 484         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 485                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 486                  have_apparmor=yes
 487                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 488                 [have_apparmor=no])
 489         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 490                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 491         fi
 492 fi
 493 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 494
 495 have_wheel_group=no
 496 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 497 AS_IF([test "x$enable_wheel_group" != "xno"], [
 498         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 499         have_wheel_group=yes
 500         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 501 ])
 502
 503
 504 AC_ARG_WITH(debug-shell,
 505         AS_HELP_STRING([--with-debug-shell=PATH],
 506                 [Path to debug shell binary]),
 507         [SUSHELL="$withval"],[
 508         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 509
 510 AC_SUBST(SUSHELL)
 511
 512 AC_ARG_WITH([debug-tty],
 513         AS_HELP_STRING([--with-debug-tty=PATH],
 514                 [Specify the tty device for debug shell]),
 515         [DEBUGTTY="$withval"],
 516         [DEBUGTTY=/dev/tty9])
 517
 518 AC_SUBST(DEBUGTTY)
 519
 520 AC_ARG_WITH([certificate-root],
 521         AS_HELP_STRING([--with-certificate-root=PATH],
 522                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 523         [CERTIFICATEROOT="$withval"],
 524         [CERTIFICATEROOT="/etc/ssl"])
 525
 526 AC_SUBST(CERTIFICATEROOT)
 527
 528 # ------------------------------------------------------------------------------
 529 have_xz=no
 530 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 531 AS_IF([test "x$enable_xz" != "xno"], [
 532         PKG_CHECK_MODULES(XZ, [ liblzma ],
 533                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 534                  have_xz=yes],
 535                  have_xz=no)
 536         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 537               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 538 ])
 539 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 540
 541 # ------------------------------------------------------------------------------
 542 have_zlib=no
 543 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 544 AS_IF([test "x$enable_zlib" != "xno"], [
 545         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 546                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 547                  have_zlib=yes],
 548                  have_zlib=no)
 549         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 550               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 551 ])
 552 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 553
 554 # ------------------------------------------------------------------------------
 555 have_bzip2=no
 556 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Enable optional BZIP2 support]))
 557 AS_IF([test "x$enable_bzip2" != "xno"], [
 558         AC_CHECK_HEADERS(bzlib.h,
 559                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 560                  have_bzip2=yes],
 561                 [AS_IF([test "x$enable_bzip2" = xyes],
 562                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 563         )
 564 ])
 565 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 566
 567 # ------------------------------------------------------------------------------
 568 have_lz4=no
 569 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [Disable optional LZ4 support]))
 570 AS_IF([test "x$enable_lz4" != "xno"], [
 571         PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 572                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available])
 573                 have_lz4=yes],
 574                 have_lz4=no)
 575         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 576               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 577 ])
 578 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 579
 580 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 581
 582 # ------------------------------------------------------------------------------
 583 AC_ARG_ENABLE([pam],
 584         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 585                 [case "${enableval}" in
 586                         yes) have_pam=yes ;;
 587                         no) have_pam=no ;;
 588                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 589                 esac],
 590                 [have_pam=auto])
 591
 592 if test "x${have_pam}" != xno ; then
 593         AC_CHECK_HEADERS(
 594                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 595                 [have_pam=yes],
 596                 [if test "x$have_pam" = xyes ; then
 597                         AC_MSG_ERROR([*** PAM headers not found.])
 598                 fi])
 599
 600         AC_CHECK_LIB(
 601                 [pam],
 602                 [pam_syslog],
 603                 [have_pam=yes],
 604                 [if test "x$have_pam" = xyes ; then
 605                         AC_MSG_ERROR([*** libpam not found.])
 606                 fi])
 607
 608         if test "x$have_pam" = xyes ; then
 609                 PAM_LIBS="-lpam -lpam_misc"
 610                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 611                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 612         else
 613                 have_pam=no
 614         fi
 615 else
 616         PAM_LIBS=
 617 fi
 618 AC_SUBST(PAM_LIBS)
 619 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 620
 621 # ------------------------------------------------------------------------------
 622 AC_ARG_ENABLE([acl],
 623         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 624                 [case "${enableval}" in
 625                         yes) have_acl=yes ;;
 626                         no) have_acl=no ;;
 627                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 628                 esac],
 629                 [have_acl=auto])
 630
 631 if test "x${have_acl}" != xno ; then
 632         AC_CHECK_HEADERS(
 633                 [sys/acl.h acl/libacl.h],
 634                 [have_acl=yes],
 635                 [if test "x$have_acl" = xyes ; then
 636                         AC_MSG_ERROR([*** ACL headers not found.])
 637                 fi])
 638
 639         AC_CHECK_LIB(
 640                 [acl],
 641                 [acl_get_file],
 642                 [have_acl=yes],
 643                 [if test "x$have_acl" = xyes ; then
 644                         AC_MSG_ERROR([*** libacl not found.])
 645                 fi])
 646
 647         if test "x$have_acl" = xyes ; then
 648                 ACL_LIBS="-lacl"
 649                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 650                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 651         else
 652                 have_acl=no
 653         fi
 654 else
 655         ACL_LIBS=
 656 fi
 657 AC_SUBST(ACL_LIBS)
 658 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 659
 660 # ------------------------------------------------------------------------------
 661 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 662                 [case "${enableval}" in
 663                         yes) have_smack=yes ;;
 664                         no) have_smack=no ;;
 665                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 666                 esac],
 667                 [have_smack=auto])
 668
 669 if test "x${have_smack}" != xno; then
 670         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 671         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 672         have_smack=yes
 673 fi
 674
 675 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 676
 677 have_smack_run_label=no
 678 AC_ARG_WITH(smack-run-label,
 679 AS_HELP_STRING([--with-smack-run-label=STRING],
 680         [run systemd --system itself with a specific SMACK label]),
 681         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 682         [])
 683
 684 if test "x${have_smack_run_label}" = xyes; then
 685         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 686 fi
 687
 688 AC_ARG_WITH(smack-default-process-label,
 689 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 690         [default SMACK label for executed processes]),
 691         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 692         [])
 693
 694 # ------------------------------------------------------------------------------
 695 AC_ARG_ENABLE([gcrypt],
 696         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 697                 [case "${enableval}" in
 698                         yes) have_gcrypt=yes ;;
 699                         no) have_gcrypt=no ;;
 700                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 701                 esac],
 702                 [have_gcrypt=auto])
 703
 704 if test "x${have_gcrypt}" != xno ; then
 705         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 706                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 707         )
 708         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 709                         [1.4.5],
 710                         [have_gcrypt=yes],
 711                         dnl  If we have the gcrypt m4 macros, but don't have
 712                         dnl  gcrypt, throw an error if gcrypt is explicitly
 713                         dnl  requested.
 714                         [AM_PATH_LIBGCRYPT_FAIL]
 715                 )],
 716                 dnl  If we don't have the gcrypt m4 macros, but build with
 717                 dnl  gcrypt explicitly requested, throw an error.
 718                 [AM_PATH_LIBGCRYPT_FAIL]
 719         )
 720
 721         have_gpg_error=no
 722         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 723                         [1.12],
 724                         [have_gpg_error=yes],
 725                         [AM_PATH_LIBGCRYPT_FAIL]
 726                 )],
 727                 [AM_PATH_LIBGCRYPT_FAIL]
 728         )
 729
 730         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 731                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 732                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 733                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 734         else
 735                 have_gcrypt=no
 736                 have_gpg_error=no
 737         fi
 738 else
 739         GCRYPT_LIBS=
 740         GCRYPT_CFLAGS=
 741 fi
 742 AC_SUBST(GCRYPT_LIBS)
 743 AC_SUBST(GCRYPT_CFLAGS)
 744 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 745
 746 # ------------------------------------------------------------------------------
 747 AC_ARG_ENABLE([audit],
 748         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 749                 [case "${enableval}" in
 750                         yes) have_audit=yes ;;
 751                         no) have_audit=no ;;
 752                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 753                 esac],
 754                 [have_audit=auto])
 755
 756 if test "x${have_audit}" != xno ; then
 757         AC_CHECK_HEADERS(
 758                 [libaudit.h],
 759                 [have_audit=yes],
 760                 [if test "x$have_audit" = xyes ; then
 761                         AC_MSG_ERROR([*** AUDIT headers not found.])
 762                 fi])
 763
 764         AC_CHECK_LIB(
 765                 [audit],
 766                 [audit_open],
 767                 [have_audit=yes],
 768                 [if test "x$have_audit" = xyes ; then
 769                         AC_MSG_ERROR([*** libaudit not found.])
 770                 fi])
 771
 772         if test "x$have_audit" = xyes ; then
 773                 AUDIT_LIBS="-laudit"
 774                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 775         else
 776                 have_audit=no
 777         fi
 778 else
 779         AUDIT_LIBS=
 780 fi
 781 AC_SUBST(AUDIT_LIBS)
 782 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 783
 784 # ------------------------------------------------------------------------------
 785 AC_ARG_ENABLE([elfutils],
 786         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 787                 [case "${enableval}" in
 788                         yes) have_elfutils=yes ;;
 789                         no) have_elfutils=no ;;
 790                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 791                 esac],
 792                 [have_elfutils=auto])
 793
 794 if test "x${have_elfutils}" != xno ; then
 795         AC_CHECK_HEADERS(
 796                 [elfutils/libdwfl.h],
 797                 [],
 798                 [if test "x$have_elfutils" = xyes ; then
 799                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 800                 fi])
 801
 802         AC_CHECK_LIB(
 803                 [dw],
 804                 [dwfl_core_file_attach],
 805                 [have_elfutils=yes],
 806                 [if test "x$have_elfutils" = xyes ; then
 807                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 808                 fi])
 809
 810         if test "x$have_elfutils" = xyes ; then
 811                 ELFUTILS_LIBS="-lelf -ldw"
 812                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 813         else
 814                 have_elfutils=no
 815         fi
 816 else
 817         ELFUTILS_LIBS=
 818 fi
 819 AC_SUBST(ELFUTILS_LIBS)
 820 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 821
 822 # ------------------------------------------------------------------------------
 823 have_libcryptsetup=no
 824 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 825 if test "x$enable_libcryptsetup" != "xno"; then
 826         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 827                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 828         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 829                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 830         fi
 831 fi
 832 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 833
 834 # ------------------------------------------------------------------------------
 835 have_qrencode=no
 836 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 837 if test "x$enable_qrencode" != "xno"; then
 838         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 839                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 840         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 841                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 842         fi
 843 fi
 844 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 845
 846 # ------------------------------------------------------------------------------
 847 have_gnutls=no
 848 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 849 if test "x$enable_gnutls" != "xno"; then
 850         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 851                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 852         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 853                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 854         fi
 855 fi
 856 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 857
 858 # ------------------------------------------------------------------------------
 859 have_microhttpd=no
 860 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 861 if test "x$enable_microhttpd" != "xno"; then
 862         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 863                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 864                  have_microhttpd=yes
 865                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 866                 [have_microhttpd=no])
 867         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 868                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 869         fi
 870 fi
 871 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 872
 873 # ------------------------------------------------------------------------------
 874 have_libcurl=no
 875 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 876 if test "x$enable_libcurl" != "xno"; then
 877         PKG_CHECK_MODULES(LIBCURL, [libcurl],
 878                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 879                  have_libcurl=yes
 880                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 881                 [have_libcurl=no])
 882         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 883                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 884         fi
 885 fi
 886 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 887
 888 # ------------------------------------------------------------------------------
 889 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 890
 891 # ------------------------------------------------------------------------------
 892 have_libidn=no
 893 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 894 if test "x$enable_libidn" != "xno"; then
 895         PKG_CHECK_MODULES(LIBIDN, [libidn],
 896                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 897                 have_libidn=yes
 898                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 899                [have_libidn=no])
 900         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 901                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 902         fi
 903 fi
 904 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 905
 906 # ------------------------------------------------------------------------------
 907 have_libiptc=no
 908 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 909 if test "x$enable_libiptc" != "xno"; then
 910         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 911                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 912                 have_libiptc=yes
 913                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 914                [have_libiptc=no])
 915         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 916                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 917         fi
 918 fi
 919 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 920
 921 # ------------------------------------------------------------------------------
 922 have_binfmt=no
 923 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 924 if test "x$enable_binfmt" != "xno"; then
 925         have_binfmt=yes
 926 fi
 927 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 928
 929 # ------------------------------------------------------------------------------
 930 have_vconsole=no
 931 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 932 if test "x$enable_vconsole" != "xno"; then
 933         have_vconsole=yes
 934 fi
 935 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 936
 937 # ------------------------------------------------------------------------------
 938 have_bootchart=no
 939 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 940 if test "x$enable_bootchart" != "xno"; then
 941         have_bootchart=yes
 942 fi
 943 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 944
 945 # ------------------------------------------------------------------------------
 946 have_quotacheck=no
 947 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 948 if test "x$enable_quotacheck" != "xno"; then
 949         have_quotacheck=yes
 950 fi
 951 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 952
 953 # ------------------------------------------------------------------------------
 954 have_tmpfiles=no
 955 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 956 if test "x$enable_tmpfiles" != "xno"; then
 957         have_tmpfiles=yes
 958 fi
 959 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 960
 961 # ------------------------------------------------------------------------------
 962 have_sysusers=no
 963 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 964 if test "x$enable_sysusers" != "xno"; then
 965         have_sysusers=yes
 966 fi
 967 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 968
 969 # ------------------------------------------------------------------------------
 970 have_firstboot=no
 971 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 972 if test "x$enable_firstboot" != "xno"; then
 973         have_firstboot=yes
 974 fi
 975 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 976
 977 # ------------------------------------------------------------------------------
 978 have_randomseed=no
 979 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 980 if test "x$enable_randomseed" != "xno"; then
 981         have_randomseed=yes
 982 fi
 983 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 984
 985 # ------------------------------------------------------------------------------
 986 have_backlight=no
 987 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 988 if test "x$enable_backlight" != "xno"; then
 989         have_backlight=yes
 990 fi
 991 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 992
 993 # ------------------------------------------------------------------------------
 994 have_rfkill=no
 995 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
 996 if test "x$enable_rfkill" != "xno"; then
 997         have_rfkill=yes
 998 fi
 999 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1000
1001 # ------------------------------------------------------------------------------
1002 have_logind=no
1003 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1004 if test "x$enable_logind" != "xno"; then
1005         have_logind=yes
1006 fi
1007 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1008 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1009
1010 # ------------------------------------------------------------------------------
1011 have_machined=no
1012 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1013 if test "x$enable_machined" != "xno"; then
1014         have_machined=yes
1015 fi
1016 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1017 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
1018
1019 # ------------------------------------------------------------------------------
1020 have_importd=no
1021 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1022 if test "x$enable_importd" != "xno"; then
1023         have_importd=yes
1024 fi
1025 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1026 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1027
1028 # ------------------------------------------------------------------------------
1029 have_hostnamed=no
1030 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1031 if test "x$enable_hostnamed" != "xno"; then
1032         have_hostnamed=yes
1033 fi
1034 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1035
1036 # ------------------------------------------------------------------------------
1037 have_timedated=no
1038 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1039 if test "x$enable_timedated" != "xno"; then
1040         have_timedated=yes
1041 fi
1042 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1043
1044 # ------------------------------------------------------------------------------
1045 have_timesyncd=no
1046 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1047 if test "x$enable_timesyncd" != "xno"; then
1048         have_timesyncd=yes
1049         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1050 fi
1051 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1052
1053 AC_ARG_WITH(ntp-servers,
1054         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1055                 [Space-separated list of default NTP servers]),
1056         [NTP_SERVERS="$withval"],
1057         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1058         AC_MSG_WARN([*** Using Google NTP servers.
1059                         Do not ship OSes or devices with these default settings.
1060                         See DISTRO_PORTING for details!])])
1061
1062 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1063 AC_SUBST(NTP_SERVERS)
1064
1065 AC_ARG_WITH(time-epoch,
1066         AS_HELP_STRING([--with-time-epoch=SECONDS],
1067                 [Time epoch for time clients]),
1068         [TIME_EPOCH="$withval"],
1069         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1070
1071 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1072
1073 # ------------------------------------------------------------------------------
1074 AC_ARG_WITH(system-uid-max,
1075         AS_HELP_STRING([--with-system-uid-max=UID]
1076                 [Maximum UID for system users]),
1077         [SYSTEM_UID_MAX="$withval"],
1078         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1079
1080 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1081 AC_SUBST(SYSTEM_UID_MAX)
1082
1083 # ------------------------------------------------------------------------------
1084 AC_ARG_WITH(system-gid-max,
1085         AS_HELP_STRING([--with-system-gid-max=GID]
1086                 [Maximum GID for system groups]),
1087         [SYSTEM_GID_MAX="$withval"],
1088         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1089
1090 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1091 AC_SUBST(SYSTEM_GID_MAX)
1092
1093 # ------------------------------------------------------------------------------
1094 have_localed=no
1095 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1096 if test "x$enable_localed" != "xno"; then
1097         have_localed=yes
1098 fi
1099 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1100
1101 # ------------------------------------------------------------------------------
1102 have_coredump=no
1103 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1104 if test "x$enable_coredump" != "xno"; then
1105         have_coredump=yes
1106         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1107 fi
1108 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1109
1110 # ------------------------------------------------------------------------------
1111 have_polkit=no
1112 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1113 if test "x$enable_polkit" != "xno"; then
1114         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1115         have_polkit=yes
1116 fi
1117 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1118
1119 # ------------------------------------------------------------------------------
1120 have_resolved=no
1121 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1122 AS_IF([test "x$enable_resolved" != "xno"], [
1123         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1124
1125         have_resolved=yes
1126         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1127 ])
1128 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1129
1130 AC_ARG_WITH(dns-servers,
1131         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1132                 [Space-separated list of default DNS servers]),
1133         [DNS_SERVERS="$withval"],
1134         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1135
1136 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1137 AC_SUBST(DNS_SERVERS)
1138
1139 # ------------------------------------------------------------------------------
1140 have_networkd=no
1141 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1142 AS_IF([test "x$enable_networkd" != "xno"], [
1143         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1144         have_networkd=yes
1145         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1146 ])
1147 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1148
1149 # ------------------------------------------------------------------------------
1150 have_efi=no
1151 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1152 if test "x$enable_efi" != "xno"; then
1153         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1154         have_efi=yes
1155 fi
1156 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1157
1158 # ------------------------------------------------------------------------------
1159 AC_CHECK_TOOL(EFI_CC, gcc)
1160
1161 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1162
1163 AM_COND_IF(ARCH_IA32, [
1164         EFI_ARCH=ia32
1165         EFI_MACHINE_TYPE_NAME=ia32])
1166
1167 AM_COND_IF(ARCH_X86_64, [
1168         EFI_MACHINE_TYPE_NAME=x64])
1169
1170 AM_COND_IF(ARCH_AARCH64, [
1171         EFI_MACHINE_TYPE_NAME=aa64])
1172
1173 AC_SUBST([EFI_ARCH])
1174 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1175
1176 have_gnuefi=no
1177 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Enable optional gnuefi support]))
1178 AS_IF([test "x$enable_gnuefi" != "xno"], [
1179         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1180                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1181                  have_gnuefi=yes],
1182                 [AS_IF([test "x$enable_gnuefi" = xyes],
1183                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1184         ])
1185
1186         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1187
1188         EFI_LIB_DIR="$efiroot"
1189         AC_ARG_WITH(efi-libdir,
1190                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1191                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1192         )
1193         AC_SUBST([EFI_LIB_DIR])
1194
1195         have_efi_lds=no
1196         AC_ARG_WITH(efi-ldsdir,
1197                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1198                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1199                         [have_efi_lds=yes])],
1200                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1201                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1202                                        [have_efi_lds=yes && break])])])
1203         AS_IF([test "x$have_efi_lds" = xyes],
1204               [AC_SUBST([EFI_LDS_DIR])],
1205               [AS_IF([test "x$enable_gnuefi" = xyes],
1206                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1207                      [have_gnuefi=no])])
1208
1209         AC_ARG_WITH(efi-includedir,
1210                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1211                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1212         )
1213         AC_SUBST([EFI_INC_DIR])
1214 ])
1215 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1216
1217 # ------------------------------------------------------------------------------
1218 have_tpm=no
1219 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm],[Enable optional TPM support]),
1220                 [case "${enableval}" in
1221                         yes) have_tpm=yes ;;
1222                         no) have_tpm=no ;;
1223                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1224                 esac],
1225                 [have_tpm=no])
1226
1227 if test "x${have_tpm}" != xno ; then
1228         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1229 fi
1230
1231 AC_ARG_WITH(tpm-pcrindex,
1232         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1233                 [TPM PCR register number to use]),
1234         [SD_TPM_PCR="$withval"],
1235         [SD_TPM_PCR="8"])
1236
1237 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1238
1239 # ------------------------------------------------------------------------------
1240 have_kdbus=no
1241 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
1242 if test "x$enable_kdbus" != "xno"; then
1243         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
1244         have_kdbus=yes
1245         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
1246 fi
1247 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
1248
1249 # ------------------------------------------------------------------------------
1250 AC_ARG_WITH(rc-local-script-path-start,
1251         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1252                 [Path to /etc/rc.local]),
1253         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1254         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1255
1256 AC_ARG_WITH(rc-local-script-path-stop,
1257         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1258                 [Path to /usr/sbin/halt.local]),
1259         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1260         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1261
1262 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1263 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1264
1265 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1266 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1267
1268 # ------------------------------------------------------------------------------
1269 AC_ARG_WITH(kbd-loadkeys,
1270         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1271                 [Path to loadkeys]),
1272         [KBD_LOADKEYS="$withval"],
1273         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1274
1275 AC_ARG_WITH(kbd-setfont,
1276         AS_HELP_STRING([--with-kbd-setfont=PATH],
1277                 [Path to setfont]),
1278         [KBD_SETFONT="$withval"],
1279         [KBD_SETFONT="/usr/bin/setfont"])
1280
1281 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1282 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1283
1284 AC_SUBST(KBD_LOADKEYS)
1285 AC_SUBST(KBD_SETFONT)
1286
1287 AC_ARG_WITH(telinit,
1288         AS_HELP_STRING([--with-telinit=PATH],
1289                 [Path to telinit]),
1290         [TELINIT="$withval"],
1291         [TELINIT="/lib/sysvinit/telinit"])
1292
1293 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1294
1295 AC_SUBST(TELINIT)
1296
1297 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1298
1299 # ------------------------------------------------------------------------------
1300 have_myhostname=no
1301 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1302 if test "x$enable_myhostname" != "xno"; then
1303         AC_HEADER_STDC
1304         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1305
1306         AC_C_CONST
1307         AC_TYPE_SIZE_T
1308         AC_HEADER_TIME
1309
1310         AC_FUNC_SELECT_ARGTYPES
1311         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1312
1313         have_myhostname=yes
1314 fi
1315 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1316
1317 # ------------------------------------------------------------------------------
1318 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1319        enable_hwdb=$enableval, enable_hwdb=yes)
1320 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1321
1322 # ------------------------------------------------------------------------------
1323 have_manpages=no
1324 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1325 AC_PATH_PROG([XSLTPROC], [xsltproc])
1326 AS_IF([test "x$enable_manpages" != xno], [
1327        have_manpages=yes
1328        AS_IF([test -z "$XSLTPROC"],
1329              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1330 ])
1331 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1332
1333 # ------------------------------------------------------------------------------
1334 AC_ARG_ENABLE(hibernate,
1335        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1336        enable_hibernate=$enableval, enable_hibernate=yes)
1337 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1338
1339 # ------------------------------------------------------------------------------
1340 AC_ARG_ENABLE(ldconfig,
1341        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1342        enable_ldconfig=$enableval, enable_ldconfig=yes)
1343 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1344
1345 # ------------------------------------------------------------------------------
1346 # Location of the init scripts as mandated by LSB
1347 SYSTEM_SYSVINIT_PATH=/etc/init.d
1348 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1349
1350 AC_ARG_WITH([sysvinit-path],
1351         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1352                 [Specify the path to where the SysV init scripts are located])],
1353         [SYSTEM_SYSVINIT_PATH="$withval"],
1354         [])
1355
1356 AC_ARG_WITH([sysvrcnd-path],
1357         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1358                 [Specify the path to the base directory for the SysV rcN.d directories])],
1359         [SYSTEM_SYSVRCND_PATH="$withval"],
1360         [])
1361
1362 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1363         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1364         SYSTEM_SYSV_COMPAT="yes"
1365         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1366 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1367         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1368 else
1369         SYSTEM_SYSV_COMPAT="no"
1370 fi
1371
1372 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1373 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1374 AC_SUBST(M4_DEFINES)
1375
1376 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1377
1378 AC_ARG_WITH([tty-gid],
1379         [AS_HELP_STRING([--with-tty-gid=GID],
1380                 [Specify the numeric GID of the 'tty' group])],
1381         [TTY_GID="$withval"],
1382         [TTY_GID="5"])
1383
1384 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1385 AC_SUBST(TTY_GID)
1386
1387 AC_ARG_WITH([dbuspolicydir],
1388         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1389         [],
1390         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1391 AX_NORMALIZE_PATH([with_dbuspolicydir])
1392
1393 AC_ARG_WITH([dbussessionservicedir],
1394         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1395         [],
1396         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1397 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1398
1399 AC_ARG_WITH([dbussystemservicedir],
1400         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1401         [],
1402         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1403 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1404
1405 AC_ARG_WITH([bashcompletiondir],
1406         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1407         [],
1408         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1409                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1410         ] , [
1411                 with_bashcompletiondir=${datadir}/bash-completion/completions
1412         ])])
1413 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1414 AX_NORMALIZE_PATH([with_bashcompletiondir])
1415
1416 AC_ARG_WITH([zshcompletiondir],
1417         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1418         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1419 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1420 AX_NORMALIZE_PATH([with_zshcompletiondir])
1421
1422 AC_ARG_WITH([rootprefix],
1423         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1424         [], [with_rootprefix=${ac_default_prefix}])
1425 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1426 # defaults those to ".", solve that here for now until we can find a suitable
1427 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1428 # See: https://github.com/systemd/systemd/issues/54
1429 if test "x${with_rootprefix}" = "x"; then
1430         with_rootprefix="/"
1431 fi
1432 AX_NORMALIZE_PATH([with_rootprefix])
1433
1434 AC_ARG_WITH([rootlibdir],
1435         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1436         [],
1437         [with_rootlibdir=${libdir}])
1438 AX_NORMALIZE_PATH([with_rootlibdir])
1439
1440 AC_ARG_WITH([pamlibdir],
1441         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1442         [],
1443         [with_pamlibdir=${with_rootlibdir}/security])
1444 AX_NORMALIZE_PATH([with_pamlibdir])
1445
1446 AC_ARG_WITH([pamconfdir],
1447         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1448         [],
1449         [with_pamconfdir=${sysconfdir}/pam.d])
1450 AX_NORMALIZE_PATH([with_pamconfdir])
1451
1452 AC_ARG_ENABLE([split-usr],
1453         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1454         [],
1455         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1456                 enable_split_usr=yes
1457         ], [
1458                 enable_split_usr=no
1459         ])])
1460
1461 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1462         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1463 ])
1464 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1465
1466 # work around intltool-update issues during 'make distcheck'
1467 AS_IF([test "x$0" != "x./configure"], [
1468         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1469 ])
1470
1471 # QEMU and OVMF UEFI firmware
1472 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1473         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1474         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1475                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1476         AC_SUBST([QEMU_BIOS])
1477 ])
1478
1479 AC_ARG_ENABLE(tests,
1480         [AC_HELP_STRING([--disable-tests], [disable tests])],
1481         enable_tests=$enableval, enable_tests=yes)
1482 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1483
1484 AC_ARG_ENABLE(debug,
1485         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1486         [if test "x$enableval" = "xyes"; then
1487                 enableval="hashmap,mmap-cache"
1488         fi
1489         saved_ifs="$IFS"
1490         IFS="$IFS$PATH_SEPARATOR,"
1491         for name in $enableval; do
1492                 case $name in
1493                 hashmap)
1494                         enable_debug_hashmap=yes
1495                         ;;
1496                 mmap-cache)
1497                         enable_debug_mmap_cache=yes
1498                         ;;
1499                 esac
1500         done
1501         IFS="$saved_ifs"],[])
1502
1503 enable_debug=""
1504 AS_IF([test x$enable_debug_hashmap = xyes], [
1505         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1506         enable_debug="hashmap $enable_debug"
1507 ])
1508 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1509         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1510         enable_debug="mmap-cache $enable_debug"
1511 ])
1512 test -z "$enable_debug" && enable_debug="none"
1513
1514 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1515 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1516 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1517 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1518 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1519 AC_SUBST([pamlibdir], [$with_pamlibdir])
1520 AC_SUBST([pamconfdir], [$with_pamconfdir])
1521 AC_SUBST([rootprefix], [$with_rootprefix])
1522 AC_SUBST([rootlibdir], [$with_rootlibdir])
1523
1524 AC_CONFIG_FILES([
1525         Makefile
1526         po/Makefile.in
1527 ])
1528
1529 AC_OUTPUT
1530 AC_MSG_RESULT([
1531         $PACKAGE_NAME $VERSION
1532
1533         libcryptsetup:           ${have_libcryptsetup}
1534         PAM:                     ${have_pam}
1535         AUDIT:                   ${have_audit}
1536         IMA:                     ${have_ima}
1537         AppArmor:                ${have_apparmor}
1538         SELinux:                 ${have_selinux}
1539         SECCOMP:                 ${have_seccomp}
1540         SMACK:                   ${have_smack}
1541         ZLIB:                    ${have_zlib}
1542         XZ:                      ${have_xz}
1543         LZ4:                     ${have_lz4}
1544         BZIP2:                   ${have_bzip2}
1545         ACL:                     ${have_acl}
1546         GCRYPT:                  ${have_gcrypt}
1547         QRENCODE:                ${have_qrencode}
1548         MICROHTTPD:              ${have_microhttpd}
1549         GNUTLS:                  ${have_gnutls}
1550         libcurl:                 ${have_libcurl}
1551         libidn:                  ${have_libidn}
1552         libiptc:                 ${have_libiptc}
1553         ELFUTILS:                ${have_elfutils}
1554         binfmt:                  ${have_binfmt}
1555         vconsole:                ${have_vconsole}
1556         bootchart:               ${have_bootchart}
1557         quotacheck:              ${have_quotacheck}
1558         tmpfiles:                ${have_tmpfiles}
1559         sysusers:                ${have_sysusers}
1560         firstboot:               ${have_firstboot}
1561         randomseed:              ${have_randomseed}
1562         backlight:               ${have_backlight}
1563         rfkill:                  ${have_rfkill}
1564         logind:                  ${have_logind}
1565         machined:                ${have_machined}
1566         importd:                 ${have_importd}
1567         hostnamed:               ${have_hostnamed}
1568         timedated:               ${have_timedated}
1569         timesyncd:               ${have_timesyncd}
1570         default NTP servers:     ${NTP_SERVERS}
1571         time epoch:              ${TIME_EPOCH}
1572         localed:                 ${have_localed}
1573         networkd:                ${have_networkd}
1574         resolved:                ${have_resolved}
1575         default DNS servers:     ${DNS_SERVERS}
1576         coredump:                ${have_coredump}
1577         polkit:                  ${have_polkit}
1578         efi:                     ${have_efi}
1579         gnuefi:                  ${have_gnuefi}
1580         efi arch:                ${EFI_ARCH}
1581         EFI machine type:        ${EFI_MACHINE_TYPE_NAME}
1582         EFI CC                   ${EFI_CC}
1583         EFI libdir:              ${EFI_LIB_DIR}
1584         EFI ldsdir:              ${EFI_LDS_DIR}
1585         EFI includedir:          ${EFI_INC_DIR}
1586         kmod:                    ${have_kmod}
1587         xkbcommon:               ${have_xkbcommon}
1588         blkid:                   ${have_blkid}
1589         libmount:                ${have_libmount}
1590         dbus:                    ${have_dbus}
1591         nss-myhostname:          ${have_myhostname}
1592         hwdb:                    ${enable_hwdb}
1593         tpm:                     ${have_tpm}
1594         kdbus:                   ${have_kdbus}
1595         Python:                  ${have_python}
1596         man pages:               ${have_manpages}
1597         test coverage:           ${have_coverage}
1598         Split /usr:              ${enable_split_usr}
1599         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1600         utmp/wtmp support:       ${have_utmp}
1601         ldconfig support:        ${enable_ldconfig}
1602         hibernate support:       ${enable_hibernate}
1603         extra debugging:         ${enable_debug}
1604
1605         prefix:                  ${prefix}
1606         rootprefix:              ${with_rootprefix}
1607         sysconf dir:             ${sysconfdir}
1608         datarootdir:             ${datarootdir}
1609         includedir:              ${includedir}
1610         lib dir:                 ${libdir}
1611         rootlib dir:             ${with_rootlibdir}
1612         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1613         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1614         Build Python:            ${PYTHON}
1615         PAM modules dir:         ${with_pamlibdir}
1616         PAM configuration dir:   ${with_pamconfdir}
1617         D-Bus policy dir:        ${with_dbuspolicydir}
1618         D-Bus session dir:       ${with_dbussessionservicedir}
1619         D-Bus system dir:        ${with_dbussystemservicedir}
1620         Bash completions dir:    ${with_bashcompletiondir}
1621         Zsh completions dir:     ${with_zshcompletiondir}
1622         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1623         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1624         Wheel group:             ${have_wheel_group}
1625         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1626         TTY GID:                 ${TTY_GID}
1627         Maximum System UID:      ${SYSTEM_UID_MAX}
1628         Maximum System GID:      ${SYSTEM_GID_MAX}
1629         Certificate root:        ${CERTIFICATEROOT}
1630
1631         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1632         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1633         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1634 ])