configure.ac

   1 #
   2 # Copyright (C) 2007-2014 Tobias Brunner
   3 # Copyright (C) 2006-2014 Andreas Steffen
   4 # Copyright (C) 2006-2014 Martin Willi
   5 # Hochschule fuer Technik Rapperswil
   6 #
   7 # This program is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by the
   9 # Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 # for more details.
  16 #
  17
  18 # ============================
  19 #  initialize & set some vars
  20 # ============================
  21
  22 AC_INIT([strongSwan],[5.2.1])
  23 AM_INIT_AUTOMAKE(m4_esyscmd([
  24         echo tar-ustar
  25         echo subdir-objects
  26         case `automake --version | head -n 1` in
  27                 *" 1.9"*);;
  28                 *" 1.10"*);;
  29                 *" 1.11"*);;
  30                 # don't use parallel test harness in 1.12 and up
  31                 *) echo serial-tests;;
  32         esac
  33 ]))
  34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  35 AC_CONFIG_MACRO_DIR([m4/config])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
  38 PKG_PROG_PKG_CONFIG
  39
  40 m4_include(m4/macros/split-package-version.m4)
  41 SPLIT_PACKAGE_VERSION
  42
  43 # =================================
  44 #  check --enable-xxx & --with-xxx
  45 # =================================
  46
  47 m4_include(m4/macros/with.m4)
  48
  49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
  50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
  51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
  52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
  53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
  54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
  55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
  56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
  57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
  58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
  59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
  60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
  61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
  62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
  63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
  64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
  65
  66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
  67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
  68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
  69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
  70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
  71 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
  72
  73 if test -n "$PKG_CONFIG"; then
  74         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
  75 fi
  76 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
  77 AC_SUBST(systemdsystemunitdir)
  78
  79 AC_ARG_WITH(
  80         [user],
  81         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
  82         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
  83          AC_SUBST(ipsecuser, "$withval")],
  84         [AC_SUBST(ipsecuser, "root")]
  85 )
  86
  87 AC_ARG_WITH(
  88         [group],
  89         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
  90         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
  91          AC_SUBST(ipsecgroup, "$withval")],
  92         [AC_SUBST(ipsecgroup, "root")]
  93 )
  94
  95 AC_ARG_WITH(
  96         [charon-udp-port],
  97         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
  98         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
  99          AC_SUBST(charon_udp_port, [$withval])],
 100         [AC_SUBST(charon_udp_port, 500)]
 101 )
 102
 103 AC_ARG_WITH(
 104         [charon-natt-port],
 105         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
 106         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
 107          AC_SUBST(charon_natt_port, [$withval])],
 108         [AC_SUBST(charon_natt_port, 4500)]
 109 )
 110
 111 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
 112 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
 113         AC_MSG_ERROR(the ports have to be different)
 114 else
 115         AC_MSG_RESULT(ok)
 116 fi
 117
 118 # convert script name to uppercase
 119 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
 120
 121 m4_include(m4/macros/enable-disable.m4)
 122
 123 # crypto plugins
 124 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
 125 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
 126 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
 127 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
 128 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
 129 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
 130 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
 131 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
 132 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
 133 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
 134 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
 135 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
 136 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
 137 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
 138 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
 139 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
 140 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
 141 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
 142 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
 143 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
 144 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
 145 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
 146 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
 147 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
 148 # encoding/decoding plugins
 149 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
 150 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
 151 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
 152 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
 153 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
 154 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
 155 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
 156 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
 157 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
 158 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
 159 # fetcher/resolver plugins
 160 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
 161 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
 162 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
 163 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
 164 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
 165 # database plugins
 166 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
 167 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
 168 # authentication/credential plugins
 169 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
 170 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
 171 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
 172 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
 173 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
 174 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
 175 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
 176 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
 177 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
 178 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
 179 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
 180 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
 181 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
 182 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
 183 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
 184 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
 185 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
 186 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
 187 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
 188 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
 189 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
 190 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
 191 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
 192 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
 193 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
 194 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
 195 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
 196 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
 197 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
 198 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
 199 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
 200 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
 201 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
 202 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
 203 # kernel interfaces / sockets
 204 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
 205 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
 206 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
 207 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
 208 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
 209 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
 210 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
 211 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
 212 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
 213 # configuration/control plugins
 214 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
 215 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
 216 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
 217 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
 218 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
 219 # attribute provider/consumer plugins
 220 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
 221 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
 222 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
 223 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
 224 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
 225 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
 226 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
 227 # TNC modules/plugins
 228 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
 229 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
 230 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
 231 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
 232 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
 233 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
 234 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
 235 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
 236 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
 237 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
 238 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
 239 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
 240 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
 241 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
 242 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
 243 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
 244 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
 245 # misc plugins
 246 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
 247 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
 248 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
 249 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
 250 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
 251 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
 252 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
 253 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
 254 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
 255 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
 256 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
 257 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
 258 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
 259 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
 260 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
 261 # programs/components
 262 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
 263 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
 264 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
 265 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
 266 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
 267 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
 268 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
 269 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
 270 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
 271 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
 272 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
 273 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
 274 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
 275 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
 276 ARG_ENABL_SET([svc],            [enable charon Windows service.])
 277 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
 278 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
 279 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
 280 # optional features
 281 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
 282 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
 283 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
 284 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
 285 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
 286 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
 287 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
 288 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
 289 ARG_ENABL_SET([ruby-gems],      [enable installation of provided ruby gems.])
 290 # compile options
 291 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
 292 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
 293 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
 294 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
 295
 296 # ===================================
 297 #  option to disable default options
 298 # ===================================
 299
 300 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
 301
 302 if test x$defaults = xfalse; then
 303         for option in $enabled_by_default; do
 304                 eval test x\${${option}_given} = xtrue && continue
 305                 eval $option=false
 306         done
 307 fi
 308
 309 # ==============================
 310 #  option to enable all options
 311 # ==============================
 312
 313 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
 314
 315 if test x$all_given = xtrue; then
 316         for option in $disabled_by_default; do
 317                 eval test x\${${option}_given} = xtrue && continue
 318                 eval $option=true
 319         done
 320 fi
 321
 322 # ===========================
 323 #  set up compiler and flags
 324 # ===========================
 325
 326 if test -z "$CFLAGS"; then
 327         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
 328 fi
 329 AC_PROG_CC
 330 AM_PROG_CC_C_O
 331
 332 AC_LIB_PREFIX
 333 AC_C_BIGENDIAN
 334
 335 # =========================
 336 #  check required programs
 337 # =========================
 338
 339 LT_INIT
 340 AC_PROG_INSTALL
 341 AC_PROG_EGREP
 342 AC_PROG_AWK
 343 AC_PROG_LEX
 344 AC_PROG_YACC
 345 AM_PATH_PYTHON(,,[:])
 346 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 347 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 348
 349 # because gperf is not needed by end-users we just report it but do not abort on failure
 350 AC_MSG_CHECKING([gperf version >= 3.0.0])
 351 if test -x "$GPERF"; then
 352         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
 353                 AC_MSG_RESULT([yes])
 354         else
 355                 AC_MSG_RESULT([no])
 356         fi
 357 else
 358         AC_MSG_RESULT([not found])
 359 fi
 360
 361 # ========================
 362 #  dependency calculation
 363 # ========================
 364
 365 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
 366         xauth_generic=false;
 367 fi
 368
 369 if test x$kernel_libipsec = xtrue; then
 370         libipsec=true;
 371 fi
 372
 373 if test x$eap_aka_3gpp2 = xtrue; then
 374         gmp=true;
 375 fi
 376
 377 if test x$eap_aka = xtrue; then
 378         fips_prf=true;
 379         simaka=true;
 380 fi
 381
 382 if test x$eap_sim = xtrue; then
 383         fips_prf=true;
 384         simaka=true;
 385 fi
 386
 387 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
 388         radius=true;
 389 fi
 390
 391 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
 392         tnc_tnccs=true;
 393 fi
 394
 395 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
 396         tls=true;
 397 fi
 398
 399 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
 400         imcv=true;
 401 fi
 402
 403 if test x$fips_prf = xtrue; then
 404         if test x$openssl = xfalse; then
 405                 sha1=true;
 406         fi
 407 fi
 408
 409 if test x$swanctl = xtrue; then
 410         vici=true
 411 fi
 412
 413 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
 414         xml=true
 415 fi
 416
 417 if test x$manager = xtrue; then
 418         fast=true
 419 fi
 420
 421 if test x$medsrv = xtrue; then
 422         mediation=true
 423         fast=true
 424 fi
 425
 426 if test x$medcli = xtrue; then
 427         mediation=true
 428 fi
 429
 430 # ===========================================
 431 #  check required libraries and header files
 432 # ===========================================
 433
 434 AC_HEADER_STDBOOL
 435 AC_FUNC_ALLOCA
 436 AC_FUNC_STRERROR_R
 437
 438 #  libraries needed on some platforms but not on others
 439 # ------------------------------------------------------
 440 saved_LIBS=$LIBS
 441
 442 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
 443 LIBS=""
 444 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 445 AC_SUBST(DLLIB)
 446
 447 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
 448 LIBS=""
 449 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
 450 AC_CHECK_FUNCS(backtrace)
 451 AC_SUBST(BTLIB)
 452
 453 # OpenSolaris needs libsocket and libnsl for socket()
 454 LIBS=""
 455 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
 456         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
 457 )
 458 AC_SUBST(SOCKLIB)
 459
 460 # Android has pthread_* functions in bionic (libc), others need libpthread
 461 LIBS=""
 462 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
 463 AC_SUBST(PTHREADLIB)
 464
 465 LIBS=$saved_LIBS
 466 # ------------------------------------------------------
 467
 468 AC_MSG_CHECKING(for dladdr)
 469 AC_COMPILE_IFELSE(
 470         [AC_LANG_PROGRAM(
 471                 [[#define _GNU_SOURCE
 472                   #include <dlfcn.h>]],
 473                 [[Dl_info* info = 0;
 474                   dladdr(0, info);]])],
 475         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
 476         [AC_MSG_RESULT([no])]
 477 )
 478
 479 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
 480 saved_LIBS=$LIBS
 481 LIBS=$PTHREADLIB
 482 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
 483 AC_RUN_IFELSE(
 484         [AC_LANG_SOURCE(
 485                 [[#include <pthread.h>
 486                   int main() { pthread_condattr_t attr;
 487                         pthread_condattr_init(&attr);
 488                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
 489         [AC_MSG_RESULT([yes]);
 490          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 491                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
 492         [AC_MSG_RESULT([no])],
 493         # Check existence of pthread_condattr_setclock if cross-compiling
 494         [AC_MSG_RESULT([unknown]);
 495          AC_CHECK_FUNCS(pthread_condattr_setclock,
 496                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 497                                    [have pthread_condattr_setclock()])]
 498         )]
 499 )
 500 # check if we actually are able to configure attributes on cond vars
 501 AC_CHECK_FUNCS(pthread_condattr_init)
 502 # instead of pthread_condattr_setclock Android has this function
 503 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
 504 # check if we can cancel threads
 505 AC_CHECK_FUNCS(pthread_cancel)
 506 # check if native rwlocks are available
 507 AC_CHECK_FUNCS(pthread_rwlock_init)
 508 # check if pthread spinlocks are available
 509 AC_CHECK_FUNCS(pthread_spin_init)
 510 # check if we have POSIX semaphore functions, including timed-wait
 511 AC_CHECK_FUNCS(sem_timedwait)
 512 LIBS=$saved_LIBS
 513
 514 AC_CHECK_FUNC(
 515         [gettid],
 516         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
 517         [AC_MSG_CHECKING([for SYS_gettid])
 518          AC_COMPILE_IFELSE(
 519                 [AC_LANG_PROGRAM(
 520                         [[#define _GNU_SOURCE
 521                           #include <unistd.h>
 522                           #include <sys/syscall.h>]],
 523                         [[int main() {
 524                           return syscall(SYS_gettid);}]])],
 525                 [AC_MSG_RESULT([yes]);
 526                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
 527                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
 528                 [AC_MSG_RESULT([no])]
 529         )]
 530 )
 531
 532 AC_CHECK_FUNC(
 533         [qsort_r],
 534         [
 535                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
 536                 # set -Werror so that we get an error for "argument ... has
 537                 # incompatible pointer type" warnings
 538                 save_CFLAGS="$CFLAGS"
 539                 CFLAGS="$CFLAGS -Werror"
 540                 AC_MSG_CHECKING([for GNU-style qsort_r])
 541                 AC_COMPILE_IFELSE(
 542                         [AC_LANG_PROGRAM(
 543                                 [[#define _GNU_SOURCE
 544                                   #include <stdlib.h>
 545                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
 546                                 [[int arr[] = { 0, 1 };
 547                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
 548                 [AC_MSG_RESULT([yes]);
 549                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
 550                 [
 551                         AC_MSG_RESULT([no]);
 552                         AC_MSG_CHECKING([for BSD-style qsort_r])
 553                         AC_COMPILE_IFELSE(
 554                                 [AC_LANG_PROGRAM(
 555                                         [[#include <stdlib.h>
 556                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
 557                                         [[int arr[] = { 0, 1 };
 558                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
 559                         [AC_MSG_RESULT([yes]);
 560                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
 561                         [AC_MSG_RESULT([no]);
 562                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
 563                 ])
 564                 CFLAGS="$save_CFLAGS"
 565         ]
 566 )
 567
 568 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
 569 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime)
 570
 571 AC_CHECK_FUNC([syslog], [
 572         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
 573         syslog=true
 574 ])
 575 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
 576
 577 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h)
 578 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
 579 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
 580 [
 581         #include <sys/types.h>
 582         #include <netinet/in.h>
 583 ])
 584
 585 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 586 [
 587         #include <sys/types.h>
 588         #include <sys/socket.h>
 589 ])
 590
 591 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 592 [
 593         #include <sys/types.h>
 594         #ifdef HAVE_NET_PFKEYV2_H
 595         #include <net/pfkeyv2.h>
 596         #else
 597         #include <stdint.h>
 598         #include <linux/pfkeyv2.h>
 599         #endif
 600 ])
 601
 602 AC_MSG_CHECKING([for in6addr_any])
 603 AC_COMPILE_IFELSE(
 604         [AC_LANG_PROGRAM(
 605                 [[#include <sys/types.h>
 606                   #include <sys/socket.h>
 607                   #include <netinet/in.h>]],
 608                 [[struct in6_addr in6 __attribute__((unused));
 609                   in6 = in6addr_any;]])],
 610         [AC_MSG_RESULT([yes]);
 611          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
 612         [AC_MSG_RESULT([no])]
 613 )
 614
 615 AC_MSG_CHECKING([for in6_pktinfo])
 616 AC_COMPILE_IFELSE(
 617         [AC_LANG_PROGRAM(
 618                 [[#define _GNU_SOURCE
 619                   #include <sys/types.h>
 620                   #include <sys/socket.h>
 621                   #include <netinet/in.h>]],
 622                 [[struct in6_pktinfo pi;
 623                   if (pi.ipi6_ifindex)
 624                   {
 625                     return 0;
 626                   }]])],
 627         [AC_MSG_RESULT([yes]);
 628          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
 629         [AC_MSG_RESULT([no])]
 630 )
 631
 632 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
 633 AC_COMPILE_IFELSE(
 634         [AC_LANG_PROGRAM(
 635                 [[#include <sys/socket.h>
 636                   #include <net/if.h>
 637                   #include <net/route.h>]],
 638                 [[return RTM_IFANNOUNCE;]])],
 639         [AC_MSG_RESULT([yes]);
 640          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
 641         [AC_MSG_RESULT([no])]
 642 )
 643
 644 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 645 AC_COMPILE_IFELSE(
 646         [AC_LANG_PROGRAM(
 647                 [[#include <sys/types.h>
 648                   #ifdef HAVE_NETIPSEC_IPSEC_H
 649                   #include <netipsec/ipsec.h>
 650                   #elif defined(HAVE_NETINET6_IPSEC_H)
 651                   #include <netinet6/ipsec.h>
 652                   #else
 653                   #include <stdint.h>
 654                   #include <linux/ipsec.h>
 655                   #endif]],
 656                 [[int mode = IPSEC_MODE_BEET;
 657                   return mode;]])],
 658         [AC_MSG_RESULT([yes]);
 659          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
 660         [AC_MSG_RESULT([no])]
 661 )
 662
 663 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 664 AC_COMPILE_IFELSE(
 665         [AC_LANG_PROGRAM(
 666                 [[#include <sys/types.h>
 667                   #ifdef HAVE_NETIPSEC_IPSEC_H
 668                   #include <netipsec/ipsec.h>
 669                   #elif defined(HAVE_NETINET6_IPSEC_H)
 670                   #include <netinet6/ipsec.h>
 671                   #else
 672                   #include <stdint.h>
 673                   #include <linux/ipsec.h>
 674                   #endif]],
 675                 [[int dir = IPSEC_DIR_FWD;
 676                   return dir;]])],
 677         [AC_MSG_RESULT([yes]);
 678          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
 679         [AC_MSG_RESULT([no])]
 680 )
 681
 682 AC_MSG_CHECKING([for RTA_TABLE])
 683 AC_COMPILE_IFELSE(
 684         [AC_LANG_PROGRAM(
 685                 [[#include <sys/socket.h>
 686                   #include <linux/netlink.h>
 687                   #include <linux/rtnetlink.h>]],
 688                 [[int rta_type = RTA_TABLE;
 689                   return rta_type;]])],
 690         [AC_MSG_RESULT([yes]);
 691          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
 692         [AC_MSG_RESULT([no])]
 693 )
 694
 695 AC_MSG_CHECKING([for GCC __sync operations])
 696 AC_RUN_IFELSE([AC_LANG_SOURCE(
 697         [[
 698                         int main() {
 699                         int ref = 1;
 700                         __sync_fetch_and_add (&ref, 1);
 701                         __sync_sub_and_fetch (&ref, 1);
 702                         __sync_val_compare_and_swap(&ref, 1, 0);
 703                         return ref;
 704                 }
 705         ]])],
 706         [AC_MSG_RESULT([yes]);
 707          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
 708                    [have GCC __sync_* operations])],
 709         [AC_MSG_RESULT([no])],
 710         [AC_MSG_RESULT([no])]
 711 )
 712
 713 case "$printf_hooks" in
 714 auto|builtin|glibc|vstr)
 715         ;;
 716 *)
 717         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
 718         printf_hooks=auto
 719         ;;
 720 esac
 721
 722 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
 723         # check for the new register_printf_specifier function with len argument,
 724         # or the deprecated register_printf_function without
 725         AC_CHECK_FUNC(
 726                 [register_printf_specifier],
 727                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
 728                 [AC_CHECK_FUNC(
 729                         [register_printf_function],
 730                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
 731                         [
 732                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
 733                                 if test x$printf_hooks = xglibc; then
 734                                         AC_MSG_ERROR([please select a different printf hook implementation])
 735                                 else
 736                                         # fallback to builtin printf hook implementation
 737                                         printf_hooks=builtin
 738                                 fi
 739                         ]
 740                 )]
 741         )
 742 fi
 743
 744 AC_MSG_CHECKING([for Windows target])
 745 AC_COMPILE_IFELSE(
 746         [AC_LANG_PROGRAM(
 747                 [[#include <windows.h>]],
 748                 [[#ifndef WIN32
 749                   # error WIN32 undefined
 750                   #endif
 751                 ]])],
 752         [
 753                 AC_MSG_RESULT([yes])
 754                 windows=true
 755                 openssl_lib=eay32
 756                 AC_SUBST(PTHREADLIB, "")
 757                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
 758                 case "$CFLAGS" in
 759                         *ms-bitfields*) ;;
 760                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
 761                 esac
 762         ],
 763         [
 764                 AC_MSG_RESULT([no])
 765                 openssl_lib=crypto
 766
 767                 # check for clock_gettime() on non-Windows only. Otherwise this
 768                 # check might find clock_gettime() in libwinpthread, but we don't want
 769                 # to link against it.
 770                 saved_LIBS=$LIBS
 771                 # FreeBSD has clock_gettime in libc, Linux needs librt
 772                 LIBS=""
 773                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
 774                 AC_CHECK_FUNCS(clock_gettime)
 775                 AC_SUBST(RTLIB)
 776                 LIBS=$saved_LIBS
 777         ]
 778 )
 779 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
 780 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
 781
 782 AC_MSG_CHECKING([for working __attribute__((packed))])
 783 AC_COMPILE_IFELSE(
 784         [AC_LANG_PROGRAM([], [[
 785                 struct test { char a; short b; } __attribute__((packed));
 786                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
 787                         __attribute__((unused));
 788                 return 0;
 789         ]])],
 790         [AC_MSG_RESULT([yes])],
 791         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
 792 )
 793
 794 AC_MSG_CHECKING([clang])
 795 AC_COMPILE_IFELSE(
 796         [AC_LANG_PROGRAM(
 797                 [], [[
 798                  #ifndef __clang__
 799                  # error not using LLVM clang
 800                  #endif
 801                 ]])],
 802         [
 803                 AC_MSG_RESULT([yes])
 804         ],
 805         [
 806                 AC_MSG_RESULT([no])
 807                 # GCC, but not MinGW requires -rdynamic for plugins
 808                 if test x$windows != xtrue; then
 809                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
 810                 fi
 811         ]
 812 )
 813
 814 if test x$printf_hooks = xvstr; then
 815         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
 816         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
 817 fi
 818
 819 if test x$printf_hooks = xbuiltin; then
 820         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
 821 fi
 822
 823 if test x$gmp = xtrue; then
 824         saved_LIBS=$LIBS
 825         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
 826         AC_MSG_CHECKING([mpz_powm_sec])
 827         if test x$mpz_powm_sec = xyes; then
 828                 AC_COMPILE_IFELSE(
 829                         [AC_LANG_PROGRAM(
 830                                 [[#include "gmp.h"]],
 831                                 [[void *x = mpz_powm_sec;]])],
 832                         [AC_MSG_RESULT([yes]);
 833                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
 834                         [AC_MSG_RESULT([no])]
 835                 )
 836         else
 837                 AC_MSG_RESULT([disabled])
 838         fi
 839         LIBS=$saved_LIBS
 840         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 841         AC_COMPILE_IFELSE(
 842                 [AC_LANG_PROGRAM(
 843                         [[#include "gmp.h"]],
 844                         [[
 845                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 846                                         #error bad gmp
 847                                 #endif]])],
 848                 [AC_MSG_RESULT([yes])],
 849                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 850         )
 851 fi
 852
 853 if test x$ldap = xtrue; then
 854         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
 855         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
 856         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 857 fi
 858
 859 if test x$curl = xtrue; then
 860         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
 861         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 862 fi
 863
 864 if test x$unbound = xtrue; then
 865         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
 866         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
 867         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
 868         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
 869 fi
 870
 871 if test x$soup = xtrue; then
 872         PKG_CHECK_MODULES(soup, [libsoup-2.4])
 873         AC_SUBST(soup_CFLAGS)
 874         AC_SUBST(soup_LIBS)
 875 fi
 876
 877 if test x$xml = xtrue; then
 878         PKG_CHECK_MODULES(xml, [libxml-2.0])
 879         AC_SUBST(xml_CFLAGS)
 880         AC_SUBST(xml_LIBS)
 881 fi
 882
 883 if test x$systemd = xtrue; then
 884         AC_MSG_CHECKING([for systemd system unit directory])
 885         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 886                 AC_MSG_RESULT([$systemdsystemunitdir])
 887         else
 888                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 889         fi
 890
 891         PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
 892         AC_SUBST(systemd_daemon_CFLAGS)
 893         AC_SUBST(systemd_daemon_LIBS)
 894
 895         PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
 896         AC_SUBST(systemd_journal_CFLAGS)
 897         AC_SUBST(systemd_journal_LIBS)
 898 fi
 899
 900 if test x$tss = xtrousers; then
 901         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
 902         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
 903         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
 904 fi
 905
 906 if test x$imv_swid = xtrue; then
 907         PKG_CHECK_MODULES(json, [json-c], [],
 908                 [PKG_CHECK_MODULES(json, [json])])
 909         AC_SUBST(json_CFLAGS)
 910         AC_SUBST(json_LIBS)
 911 fi
 912
 913 if test x$dumm = xtrue; then
 914         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
 915         AC_SUBST(gtk_CFLAGS)
 916         AC_SUBST(gtk_LIBS)
 917         AC_CHECK_PROGS(RUBY, ruby)
 918         AC_MSG_CHECKING([for Ruby header files])
 919         if test -n "$RUBY"; then
 920                 RUBYINCLUDE=
 921                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
 922                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 923                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
 924                         if test -n "$RUBYARCH"; then
 925                                 AC_MSG_RESULT([$RUBYDIR])
 926                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
 927                         fi
 928                 else
 929                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
 930                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 931                                 AC_MSG_RESULT([$RUBYDIR])
 932                                 RUBYINCLUDE="-I$RUBYDIR"
 933                         fi
 934                 fi
 935                 if test -z "$RUBYINCLUDE"; then
 936                         AC_MSG_ERROR([ruby.h not found])
 937                 fi
 938                 AC_SUBST(RUBYINCLUDE)
 939         else
 940                 AC_MSG_ERROR([don't know how to run ruby])
 941         fi
 942         AC_MSG_CHECKING([for libruby])
 943         saved_LIBS=$LIBS
 944         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
 945         AC_TRY_LINK_FUNC(ruby_init,
 946                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
 947                 [AC_MSG_ERROR([not found])])
 948         AC_SUBST(RUBYLIB)
 949         AC_CHECK_FUNCS(rb_errinfo)
 950         LIBS=$saved_LIBS
 951 fi
 952
 953 if test x$fast = xtrue; then
 954         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
 955         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
 956         AC_MSG_CHECKING([ClearSilver requires zlib])
 957         saved_CFLAGS=$CFLAGS
 958         saved_LIBS=$LIBS
 959         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
 960         CFLAGS="-I/usr/include/ClearSilver"
 961         AC_LINK_IFELSE(
 962                 [AC_LANG_PROGRAM(
 963                         [[#include <ClearSilver.h>]],
 964                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
 965                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
 966                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
 967         )
 968         AC_SUBST(clearsilver_LIBS)
 969         LIBS=$saved_LIBS
 970         CFLAGS=$saved_CFLAGS
 971 # autoconf does not like CamelCase!? How to fix this?
 972 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
 973
 974         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
 975         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
 976 fi
 977
 978 if test x$mysql = xtrue; then
 979         if test "x$windows" = xtrue; then
 980                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
 981                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
 982                 AC_SUBST(MYSQLLIB, -lmysql)
 983         else
 984                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 985                 if test x$MYSQLCONFIG = x; then
 986                         AC_MSG_ERROR([mysql_config not found!])
 987                 fi
 988                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
 989                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
 990         fi
 991 fi
 992
 993 if test x$sqlite = xtrue; then
 994         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
 995         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
 996         AC_MSG_CHECKING([sqlite3_prepare_v2])
 997         AC_COMPILE_IFELSE(
 998                 [AC_LANG_PROGRAM(
 999                         [[#include <sqlite3.h>]],
1000                         [[void *test = sqlite3_prepare_v2;]])],
1001                 [AC_MSG_RESULT([yes]);
1002                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1003                 [AC_MSG_RESULT([no])]
1004         )
1005         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1006         AC_COMPILE_IFELSE(
1007                 [AC_LANG_PROGRAM(
1008                         [[#include <sqlite3.h>]],
1009                         [[
1010                                 #if SQLITE_VERSION_NUMBER < 3003001
1011                                         #error bad sqlite
1012                                 #endif]])],
1013                 [AC_MSG_RESULT([yes])],
1014                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1015         )
1016 fi
1017
1018 if test x$openssl = xtrue; then
1019         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
1020         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1021 fi
1022
1023 if test x$gcrypt = xtrue; then
1024         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1025         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1026         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1027         AC_COMPILE_IFELSE(
1028                 [AC_LANG_PROGRAM(
1029                         [[#include <gcrypt.h>]],
1030                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1031                 [AC_MSG_RESULT([yes]);
1032                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1033                 [AC_MSG_RESULT([no])]
1034         )
1035 fi
1036
1037 if test x$uci = xtrue; then
1038         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1039         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1040 fi
1041
1042 if test x$android_dns = xtrue; then
1043         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1044         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1045         # we have to force the use of libdl here because the autodetection
1046         # above does not work correctly when cross-compiling for android.
1047         DLLIB="-ldl"
1048         AC_SUBST(DLLIB)
1049 fi
1050
1051 if test x$maemo = xtrue; then
1052         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1053         AC_SUBST(maemo_CFLAGS)
1054         AC_SUBST(maemo_LIBS)
1055         dbusservicedir="/usr/share/dbus-1/system-services"
1056         AC_SUBST(dbusservicedir)
1057 fi
1058
1059 if test x$eap_sim_pcsc = xtrue; then
1060         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1061         AC_SUBST(pcsclite_CFLAGS)
1062         AC_SUBST(pcsclite_LIBS)
1063 fi
1064
1065 if test x$nm = xtrue; then
1066         PKG_CHECK_EXISTS([libnm-glib],
1067                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1068                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1069         )
1070         AC_SUBST(nm_CFLAGS)
1071         AC_SUBST(nm_LIBS)
1072 fi
1073
1074 if test x$xauth_pam = xtrue; then
1075         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1076         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1077 fi
1078
1079 if test x$capabilities = xnative; then
1080         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1081         # Linux requires the following for capset(), Android does not have it,
1082         # but defines capset() in unistd.h instead.
1083         AC_CHECK_HEADERS([sys/capability.h])
1084         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1085         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1086 fi
1087
1088 if test x$capabilities = xlibcap; then
1089         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1090         AC_CHECK_HEADER([sys/capability.h],
1091                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1092                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1093         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1094 fi
1095
1096 if test x$integrity_test = xtrue; then
1097         AC_MSG_CHECKING([for dladdr()])
1098         AC_COMPILE_IFELSE(
1099                 [AC_LANG_PROGRAM(
1100                         [[#define _GNU_SOURCE
1101                           #include <dlfcn.h>]],
1102                         [[Dl_info info; dladdr(main, &info);]])],
1103                 [AC_MSG_RESULT([yes])],
1104                 [AC_MSG_RESULT([no]);
1105                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1106         )
1107         AC_MSG_CHECKING([for dl_iterate_phdr()])
1108         AC_COMPILE_IFELSE(
1109                 [AC_LANG_PROGRAM(
1110                         [[#define _GNU_SOURCE
1111                           #include <link.h>]],
1112                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1113                 [AC_MSG_RESULT([yes])],
1114                 [AC_MSG_RESULT([no]);
1115                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1116         )
1117 fi
1118
1119 if test x$bfd_backtraces = xtrue; then
1120         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1121         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1122                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1123         BFDLIB="-lbfd"
1124         AC_SUBST(BFDLIB)
1125 fi
1126
1127 if test x$unwind_backtraces = xtrue; then
1128         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1129         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1130                 [AC_MSG_ERROR([libunwind.h header not found!])])
1131         UNWINDLIB="-lunwind"
1132         AC_SUBST(UNWINDLIB)
1133 fi
1134
1135 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1136 if test x$dev_headers = xyes; then
1137         dev_headers="$includedir/strongswan"
1138 fi
1139 AC_SUBST(dev_headers)
1140
1141 CFLAGS="$CFLAGS -include `pwd`/config.h"
1142
1143 if test x$tkm = xtrue; then
1144         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1145         if test x$GPRBUILD = x; then
1146                 AC_MSG_ERROR([gprbuild not found])
1147         fi
1148 fi
1149
1150 if test x$coverage = xtrue; then
1151         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1152         if test x$LCOV = x; then
1153                 AC_MSG_ERROR([lcov not found])
1154         fi
1155         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1156         if test x$GENHTML = x; then
1157                 AC_MSG_ERROR([genhtml not found])
1158         fi
1159
1160         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1161         COVERAGE_LDFLAGS="-fprofile-arcs"
1162         AC_SUBST(COVERAGE_CFLAGS)
1163         AC_SUBST(COVERAGE_LDFLAGS)
1164
1165         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1166         CFLAGS="${CFLAGS} -g -O0"
1167 fi
1168
1169 if test x$ruby_gems = xtrue; then
1170         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1171         if test x$GEM = x; then
1172                 AC_MSG_ERROR(RubyGems package manager not found)
1173         fi
1174         if test "x$rubygemdir" = "xgem environment gemdir"; then
1175                 rubygemdir=$($GEM environment gemdir)
1176         fi
1177         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1178 fi
1179
1180 # ===============================================
1181 #  collect plugin list for strongSwan components
1182 # ===============================================
1183
1184 m4_include(m4/macros/add-plugin.m4)
1185
1186 # plugin lists for all components
1187 charon_plugins=
1188 starter_plugins=
1189 pool_plugins=
1190 attest_plugins=
1191 scepclient_plugins=
1192 pki_plugins=
1193 scripts_plugins=
1194 manager_plugins=
1195 medsrv_plugins=
1196 nm_plugins=
1197 cmd_plugins=
1198 aikgen_plugins=
1199
1200 # location specific lists for checksumming,
1201 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1202 c_plugins=
1203 h_plugins=
1204 s_plugins=
1205 t_plugins=
1206
1207 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1208 ADD_PLUGIN([unbound],              [s charon scripts])
1209 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1210 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1211 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1212 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1213 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1214 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1215 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1216 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1217 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1218 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1219 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1220 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1221 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1222 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1223 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1224 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1225 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1226 ADD_PLUGIN([constraints],          [s charon nm cmd])
1227 ADD_PLUGIN([acert],                [s charon])
1228 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1229 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1230 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1231 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1232 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1233 ADD_PLUGIN([pgp],                  [s charon])
1234 ADD_PLUGIN([dnskey],               [s charon pki])
1235 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1236 ADD_PLUGIN([dnscert],              [c charon])
1237 ADD_PLUGIN([ipseckey],             [c charon])
1238 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1239 ADD_PLUGIN([padlock],              [s charon])
1240 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1241 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1242 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1243 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1244 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1245 ADD_PLUGIN([agent],                [s charon nm cmd])
1246 ADD_PLUGIN([keychain],             [s charon cmd])
1247 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1248 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1249 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1250 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1251 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1252 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1253 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1254 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1255 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1256 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1257 ADD_PLUGIN([attr],                 [h charon])
1258 ADD_PLUGIN([attr-sql],             [h charon])
1259 ADD_PLUGIN([load-tester],          [c charon])
1260 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1261 ADD_PLUGIN([kernel-wfp],           [c charon])
1262 ADD_PLUGIN([kernel-iph],           [c charon])
1263 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1264 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1265 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1266 ADD_PLUGIN([resolve],              [h charon cmd])
1267 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1268 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1269 ADD_PLUGIN([socket-win],           [c charon])
1270 ADD_PLUGIN([farp],                 [c charon])
1271 ADD_PLUGIN([stroke],               [c charon])
1272 ADD_PLUGIN([vici],                 [c charon])
1273 ADD_PLUGIN([smp],                  [c charon])
1274 ADD_PLUGIN([sql],                  [c charon])
1275 ADD_PLUGIN([updown],               [c charon])
1276 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1277 ADD_PLUGIN([eap-sim],              [c charon])
1278 ADD_PLUGIN([eap-sim-file],         [c charon])
1279 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1280 ADD_PLUGIN([eap-aka],              [c charon])
1281 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1282 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1283 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1284 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1285 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1286 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1287 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1288 ADD_PLUGIN([eap-dynamic],          [c charon])
1289 ADD_PLUGIN([eap-radius],           [c charon])
1290 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1291 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1292 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1293 ADD_PLUGIN([eap-tnc],              [c charon])
1294 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1295 ADD_PLUGIN([xauth-eap],            [c charon])
1296 ADD_PLUGIN([xauth-pam],            [c charon])
1297 ADD_PLUGIN([xauth-noauth],         [c charon])
1298 ADD_PLUGIN([tnc-ifmap],            [c charon])
1299 ADD_PLUGIN([tnc-pdp],              [c charon])
1300 ADD_PLUGIN([tnc-imc],              [t charon])
1301 ADD_PLUGIN([tnc-imv],              [t charon])
1302 ADD_PLUGIN([tnc-tnccs],            [t charon])
1303 ADD_PLUGIN([tnccs-20],             [t charon])
1304 ADD_PLUGIN([tnccs-11],             [t charon])
1305 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1306 ADD_PLUGIN([medsrv],               [c charon])
1307 ADD_PLUGIN([medcli],               [c charon])
1308 ADD_PLUGIN([dhcp],                 [c charon])
1309 ADD_PLUGIN([osx-attr],             [c charon cmd])
1310 ADD_PLUGIN([android-dns],          [c charon])
1311 ADD_PLUGIN([android-log],          [c charon])
1312 ADD_PLUGIN([ha],                   [c charon])
1313 ADD_PLUGIN([whitelist],            [c charon])
1314 ADD_PLUGIN([ext-auth],             [c charon])
1315 ADD_PLUGIN([lookip],               [c charon])
1316 ADD_PLUGIN([error-notify],         [c charon])
1317 ADD_PLUGIN([certexpire],           [c charon])
1318 ADD_PLUGIN([systime-fix],          [c charon])
1319 ADD_PLUGIN([led],                  [c charon])
1320 ADD_PLUGIN([duplicheck],           [c charon])
1321 ADD_PLUGIN([coupling],             [c charon])
1322 ADD_PLUGIN([radattr],              [c charon])
1323 ADD_PLUGIN([maemo],                [c charon])
1324 ADD_PLUGIN([uci],                  [c charon])
1325 ADD_PLUGIN([addrblock],            [c charon])
1326 ADD_PLUGIN([unity],                [c charon])
1327 ADD_PLUGIN([unit-tester],          [c charon])
1328
1329 AC_SUBST(charon_plugins)
1330 AC_SUBST(starter_plugins)
1331 AC_SUBST(pool_plugins)
1332 AC_SUBST(attest_plugins)
1333 AC_SUBST(scepclient_plugins)
1334 AC_SUBST(pki_plugins)
1335 AC_SUBST(scripts_plugins)
1336 AC_SUBST(manager_plugins)
1337 AC_SUBST(medsrv_plugins)
1338 AC_SUBST(nm_plugins)
1339 AC_SUBST(cmd_plugins)
1340 AC_SUBST(aikgen_plugins)
1341
1342 AC_SUBST(c_plugins)
1343 AC_SUBST(h_plugins)
1344 AC_SUBST(s_plugins)
1345 AC_SUBST(t_plugins)
1346
1347 # ======================
1348 #  set Makefile.am vars
1349 # ======================
1350
1351 #  libstrongswan plugins
1352 # -----------------------
1353 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1354 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1355 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1356 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1357 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1358 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1359 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1360 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1361 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1362 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1363 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1364 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1365 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1366 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1367 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1368 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1369 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1370 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1371 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1372 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1373 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1374 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1375 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1376 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1377 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1378 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1379 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1380 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1381 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1382 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1383 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1384 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1385 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1386 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1387 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1388 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1389 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1390 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1391 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1392 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1393 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1394 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1395 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1396 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1397 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1398 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1399 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1400 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1401
1402 #  charon plugins
1403 # ----------------
1404 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1405 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1406 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1407 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1408 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1409 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1410 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1411 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1412 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1413 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1414 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1415 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1416 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1417 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1418 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1419 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1420 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1421 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1422 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1423 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1424 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1425 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1426 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1427 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1428 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1429 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1430 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1431 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1432 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1433 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1434 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1435 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1436 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1437 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1438 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1439 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1440 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1441 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1442 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1443 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1444 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1445 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1446 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1447 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1448 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1449 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1450 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1451 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1452 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1453 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1454 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1455 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1456 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1457 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1458 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1459 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1460 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1461 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1462 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1463 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1464 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1465 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1466 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1467 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1468 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1469 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1470 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1471 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1472 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1473 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1474 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1475 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1476 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1477 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1478 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1479 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1480 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1481
1482 #  hydra plugins
1483 # ---------------
1484 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1485 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1486 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1487 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1488 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1489 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1490
1491 #  other options
1492 # ---------------
1493 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1494 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1495 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1496 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1497 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1498 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1499 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1500 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1501 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1502 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1503 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1504 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1505 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1506 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1507 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1508 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1509 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1510 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1511 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1512 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1513 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1514 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1515 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1516 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1517 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1518 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1519 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1520 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1521 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1522 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1523 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1524 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1525 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1526 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1527 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1528 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1529 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1530 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1531 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1532 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1533 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1534 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1535 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1536 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1537 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1538 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1539 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1540
1541 # ========================
1542 #  set global definitions
1543 # ========================
1544
1545 if test x$mediation = xtrue; then
1546         AC_DEFINE([ME], [], [mediation extension support])
1547 fi
1548 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1549         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1550 fi
1551 if test x$monolithic = xtrue; then
1552         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1553 fi
1554 if test x$ikev1 = xtrue; then
1555         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1556 fi
1557 if test x$ikev2 = xtrue; then
1558         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1559 fi
1560
1561 # ====================================================
1562 #  options for enabled modules (see conf/Makefile.am)
1563 # ====================================================
1564
1565 strongswan_options=
1566
1567 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1568 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1569 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1570 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1571 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1572 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1573 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1574 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1575 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1576 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1577 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1578 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1579 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1580
1581 AC_SUBST(strongswan_options)
1582
1583 # =================
1584 #  build Makefiles
1585 # =================
1586
1587 AC_CONFIG_FILES([
1588         Makefile
1589         conf/Makefile
1590         man/Makefile
1591         init/Makefile
1592         init/systemd/Makefile
1593         init/systemd-swanctl/Makefile
1594         src/Makefile
1595         src/include/Makefile
1596         src/libstrongswan/Makefile
1597         src/libstrongswan/plugins/aes/Makefile
1598         src/libstrongswan/plugins/cmac/Makefile
1599         src/libstrongswan/plugins/des/Makefile
1600         src/libstrongswan/plugins/blowfish/Makefile
1601         src/libstrongswan/plugins/rc2/Makefile
1602         src/libstrongswan/plugins/md4/Makefile
1603         src/libstrongswan/plugins/md5/Makefile
1604         src/libstrongswan/plugins/sha1/Makefile
1605         src/libstrongswan/plugins/sha2/Makefile
1606         src/libstrongswan/plugins/fips_prf/Makefile
1607         src/libstrongswan/plugins/gmp/Makefile
1608         src/libstrongswan/plugins/rdrand/Makefile
1609         src/libstrongswan/plugins/random/Makefile
1610         src/libstrongswan/plugins/nonce/Makefile
1611         src/libstrongswan/plugins/hmac/Makefile
1612         src/libstrongswan/plugins/xcbc/Makefile
1613         src/libstrongswan/plugins/x509/Makefile
1614         src/libstrongswan/plugins/revocation/Makefile
1615         src/libstrongswan/plugins/constraints/Makefile
1616         src/libstrongswan/plugins/acert/Makefile
1617         src/libstrongswan/plugins/pubkey/Makefile
1618         src/libstrongswan/plugins/pkcs1/Makefile
1619         src/libstrongswan/plugins/pkcs7/Makefile
1620         src/libstrongswan/plugins/pkcs8/Makefile
1621         src/libstrongswan/plugins/pkcs12/Makefile
1622         src/libstrongswan/plugins/pgp/Makefile
1623         src/libstrongswan/plugins/dnskey/Makefile
1624         src/libstrongswan/plugins/sshkey/Makefile
1625         src/libstrongswan/plugins/pem/Makefile
1626         src/libstrongswan/plugins/curl/Makefile
1627         src/libstrongswan/plugins/winhttp/Makefile
1628         src/libstrongswan/plugins/unbound/Makefile
1629         src/libstrongswan/plugins/soup/Makefile
1630         src/libstrongswan/plugins/ldap/Makefile
1631         src/libstrongswan/plugins/mysql/Makefile
1632         src/libstrongswan/plugins/sqlite/Makefile
1633         src/libstrongswan/plugins/padlock/Makefile
1634         src/libstrongswan/plugins/openssl/Makefile
1635         src/libstrongswan/plugins/gcrypt/Makefile
1636         src/libstrongswan/plugins/agent/Makefile
1637         src/libstrongswan/plugins/keychain/Makefile
1638         src/libstrongswan/plugins/pkcs11/Makefile
1639         src/libstrongswan/plugins/ctr/Makefile
1640         src/libstrongswan/plugins/ccm/Makefile
1641         src/libstrongswan/plugins/gcm/Makefile
1642         src/libstrongswan/plugins/af_alg/Makefile
1643         src/libstrongswan/plugins/ntru/Makefile
1644         src/libstrongswan/plugins/test_vectors/Makefile
1645         src/libstrongswan/tests/Makefile
1646         src/libhydra/Makefile
1647         src/libhydra/plugins/attr/Makefile
1648         src/libhydra/plugins/attr_sql/Makefile
1649         src/libhydra/plugins/kernel_netlink/Makefile
1650         src/libhydra/plugins/kernel_pfkey/Makefile
1651         src/libhydra/plugins/kernel_pfroute/Makefile
1652         src/libhydra/plugins/resolve/Makefile
1653         src/libhydra/tests/Makefile
1654         src/libipsec/Makefile
1655         src/libsimaka/Makefile
1656         src/libtls/Makefile
1657         src/libtls/tests/Makefile
1658         src/libradius/Makefile
1659         src/libtncif/Makefile
1660         src/libtnccs/Makefile
1661         src/libtnccs/plugins/tnc_tnccs/Makefile
1662         src/libtnccs/plugins/tnc_imc/Makefile
1663         src/libtnccs/plugins/tnc_imv/Makefile
1664         src/libtnccs/plugins/tnccs_11/Makefile
1665         src/libtnccs/plugins/tnccs_20/Makefile
1666         src/libtnccs/plugins/tnccs_dynamic/Makefile
1667         src/libpttls/Makefile
1668         src/libimcv/Makefile
1669         src/libimcv/plugins/imc_test/Makefile
1670         src/libimcv/plugins/imv_test/Makefile
1671         src/libimcv/plugins/imc_scanner/Makefile
1672         src/libimcv/plugins/imv_scanner/Makefile
1673         src/libimcv/plugins/imc_os/Makefile
1674         src/libimcv/plugins/imv_os/Makefile
1675         src/libimcv/plugins/imc_attestation/Makefile
1676         src/libimcv/plugins/imv_attestation/Makefile
1677         src/libimcv/plugins/imc_swid/Makefile
1678         src/libimcv/plugins/imv_swid/Makefile
1679         src/charon/Makefile
1680         src/charon-nm/Makefile
1681         src/charon-tkm/Makefile
1682         src/charon-cmd/Makefile
1683         src/charon-svc/Makefile
1684         src/charon-systemd/Makefile
1685         src/libcharon/Makefile
1686         src/libcharon/plugins/eap_aka/Makefile
1687         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1688         src/libcharon/plugins/eap_dynamic/Makefile
1689         src/libcharon/plugins/eap_identity/Makefile
1690         src/libcharon/plugins/eap_md5/Makefile
1691         src/libcharon/plugins/eap_gtc/Makefile
1692         src/libcharon/plugins/eap_sim/Makefile
1693         src/libcharon/plugins/eap_sim_file/Makefile
1694         src/libcharon/plugins/eap_sim_pcsc/Makefile
1695         src/libcharon/plugins/eap_simaka_sql/Makefile
1696         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1697         src/libcharon/plugins/eap_simaka_reauth/Makefile
1698         src/libcharon/plugins/eap_mschapv2/Makefile
1699         src/libcharon/plugins/eap_tls/Makefile
1700         src/libcharon/plugins/eap_ttls/Makefile
1701         src/libcharon/plugins/eap_peap/Makefile
1702         src/libcharon/plugins/eap_tnc/Makefile
1703         src/libcharon/plugins/eap_radius/Makefile
1704         src/libcharon/plugins/xauth_generic/Makefile
1705         src/libcharon/plugins/xauth_eap/Makefile
1706         src/libcharon/plugins/xauth_pam/Makefile
1707         src/libcharon/plugins/xauth_noauth/Makefile
1708         src/libcharon/plugins/tnc_ifmap/Makefile
1709         src/libcharon/plugins/tnc_pdp/Makefile
1710         src/libcharon/plugins/socket_default/Makefile
1711         src/libcharon/plugins/socket_dynamic/Makefile
1712         src/libcharon/plugins/socket_win/Makefile
1713         src/libcharon/plugins/farp/Makefile
1714         src/libcharon/plugins/smp/Makefile
1715         src/libcharon/plugins/sql/Makefile
1716         src/libcharon/plugins/dnscert/Makefile
1717         src/libcharon/plugins/ipseckey/Makefile
1718         src/libcharon/plugins/medsrv/Makefile
1719         src/libcharon/plugins/medcli/Makefile
1720         src/libcharon/plugins/addrblock/Makefile
1721         src/libcharon/plugins/unity/Makefile
1722         src/libcharon/plugins/uci/Makefile
1723         src/libcharon/plugins/ha/Makefile
1724         src/libcharon/plugins/kernel_libipsec/Makefile
1725         src/libcharon/plugins/kernel_wfp/Makefile
1726         src/libcharon/plugins/kernel_iph/Makefile
1727         src/libcharon/plugins/whitelist/Makefile
1728         src/libcharon/plugins/ext_auth/Makefile
1729         src/libcharon/plugins/lookip/Makefile
1730         src/libcharon/plugins/error_notify/Makefile
1731         src/libcharon/plugins/certexpire/Makefile
1732         src/libcharon/plugins/systime_fix/Makefile
1733         src/libcharon/plugins/led/Makefile
1734         src/libcharon/plugins/duplicheck/Makefile
1735         src/libcharon/plugins/coupling/Makefile
1736         src/libcharon/plugins/radattr/Makefile
1737         src/libcharon/plugins/osx_attr/Makefile
1738         src/libcharon/plugins/android_dns/Makefile
1739         src/libcharon/plugins/android_log/Makefile
1740         src/libcharon/plugins/maemo/Makefile
1741         src/libcharon/plugins/stroke/Makefile
1742         src/libcharon/plugins/vici/Makefile
1743         src/libcharon/plugins/vici/ruby/Makefile
1744         src/libcharon/plugins/updown/Makefile
1745         src/libcharon/plugins/dhcp/Makefile
1746         src/libcharon/plugins/unit_tester/Makefile
1747         src/libcharon/plugins/load_tester/Makefile
1748         src/stroke/Makefile
1749         src/ipsec/Makefile
1750         src/starter/Makefile
1751         src/starter/tests/Makefile
1752         src/_updown/Makefile
1753         src/_updown_espmark/Makefile
1754         src/_copyright/Makefile
1755         src/scepclient/Makefile
1756         src/aikgen/Makefile
1757         src/pki/Makefile
1758         src/pki/man/Makefile
1759         src/pool/Makefile
1760         src/dumm/Makefile
1761         src/dumm/ext/extconf.rb
1762         src/libfast/Makefile
1763         src/manager/Makefile
1764         src/medsrv/Makefile
1765         src/checksum/Makefile
1766         src/conftest/Makefile
1767         src/pt-tls-client/Makefile
1768         src/swanctl/Makefile
1769         scripts/Makefile
1770         testing/Makefile
1771 ])
1772
1773 # =================
1774 #  build man pages
1775 # =================
1776
1777 AC_CONFIG_FILES([
1778         conf/strongswan.conf.5.head
1779         conf/strongswan.conf.5.tail
1780         man/ipsec.conf.5
1781         man/ipsec.secrets.5
1782         src/charon-cmd/charon-cmd.8
1783         src/pki/man/pki.1
1784         src/pki/man/pki---gen.1
1785         src/pki/man/pki---issue.1
1786         src/pki/man/pki---keyid.1
1787         src/pki/man/pki---pkcs7.1
1788         src/pki/man/pki---print.1
1789         src/pki/man/pki---pub.1
1790         src/pki/man/pki---req.1
1791         src/pki/man/pki---self.1
1792         src/pki/man/pki---signcrl.1
1793         src/pki/man/pki---acert.1
1794         src/pki/man/pki---verify.1
1795         src/swanctl/swanctl.8
1796         src/swanctl/swanctl.conf.5.head
1797         src/swanctl/swanctl.conf.5.tail
1798 ])
1799
1800 AC_OUTPUT
1801
1802 # ========================
1803 #  report enabled plugins
1804 # ========================
1805
1806 AC_MSG_RESULT([])
1807 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1808 AC_MSG_RESULT([-----------------------------------------------------])
1809
1810 AC_MSG_RESULT([libstrongswan:$s_plugins])
1811 AC_MSG_RESULT([libcharon:    $c_plugins])
1812 AC_MSG_RESULT([libhydra:     $h_plugins])
1813 AC_MSG_RESULT([libtnccs:     $t_plugins])
1814 AC_MSG_RESULT([])