configure.ac

   1 AC_INIT([DHCP],[4.4.0b1],[dhcp-users@isc.org])
   2
   3
   4 # we specify "foreign" to avoid having to have the GNU mandated files,
   5 # like AUTHORS, COPYING, and such
   6 AM_INIT_AUTOMAKE([foreign])
   7
   8 # we specify AM_MAINTAINER_MODE to avoid problems with rebuilding
   9 # the configure and makefiles.  Without it users doing things that
  10 # change the timestamps on the code, like checking it into a cvs
  11 # tree, could trigger a rebuild of the infrastructure files which
  12 # might fail if they don't have the correct tools.
  13 AM_MAINTAINER_MODE
  14
  15 AC_CANONICAL_HOST
  16
  17 # We want to turn on warnings if we are using gcc and the user did
  18 # not specify CFLAGS. The autoconf check for the C compiler sets the
  19 # CFLAGS if gcc is used, so we will save it before we run that check.
  20 SAVE_CFLAGS="$CFLAGS"
  21
  22 # Now find our C compiler.
  23 AC_PROG_CC
  24
  25 # Suppress warnings about --datarootdir
  26 AC_DEFUN([AC_DATAROOTDIR_CHECKED])
  27
  28 # If we have gcc, and AC_PROG_CC changed the flags, then we know the
  29 # user did not specify any flags. Add warnings in this case.
  30 if test "$GCC" = "yes"; then
  31         if test "$CFLAGS" != "$SAVE_CFLAGS"; then
  32                 STD_CWARNINGS="$STD_CWARNINGS -Wall -Werror -fno-strict-aliasing"
  33         fi
  34 fi
  35
  36 # We can have some flags to pass to bind configure
  37 BINDCONFIG=
  38 if test "$cross_compiling" = "yes"; then
  39         BINDCONFIG="--host=$host"
  40 fi
  41 # Pass CFLAGS and co. $ac_configure_args looks like "'arg1' 'arg2' ..."
  42 # and as there can be a space inside an argument some magic is required.
  43 # This sets $1 ... $N to my_configure_args, arg1 ... argN
  44 eval "set my_configure_args $ac_configure_args"
  45 # remove my_configure_args, i.e., the guard against empty $ac_configure_args
  46 shift
  47 # iterate on arguments and copying 'arg' when it begins by an upper case
  48 for a
  49 do
  50         case $a in
  51                 [[A-Z]]*) BINDCONFIG="$BINDCONFIG '$a'" ;;
  52         esac
  53 done
  54 AC_SUBST(BINDCONFIG)
  55
  56 # POSIX doesn't include the IPv6 Advanced Socket API and glibc hides
  57 # parts of the IPv6 Advanced Socket API as a result.  This is stupid
  58 # as it breaks how the two halves (Basic and Advanced) of the IPv6
  59 # Socket API were designed to be used but we have to live with it.
  60 # Use this to define _GNU_SOURCE to pull in the IPv6 Advanced Socket API.
  61 AC_USE_SYSTEM_EXTENSIONS
  62
  63 AC_PROG_RANLIB
  64
  65 AC_PATH_PROG(AR, ar)
  66 AC_SUBST(AR)
  67
  68 if test "X$AR" = "X"; then
  69         AC_MSG_ERROR([
  70 ar program not found.  Please fix your PATH to include the directory in
  71 which ar resides, or set AR in the environment with the full path to ar.])
  72 fi
  73
  74 AC_CONFIG_HEADERS([includes/config.h])
  75
  76 # we sometimes need to know byte order for building packets
  77 AC_C_BIGENDIAN(AC_SUBST(byte_order, BIG_ENDIAN),
  78                AC_SUBST(byte_order, LITTLE_ENDIAN))
  79 AC_DEFINE_UNQUOTED([DHCP_BYTE_ORDER], [$byte_order],
  80                    [Define to BIG_ENDIAN for MSB (Motorola or SPARC CPUs)
  81                     or LITTLE_ENDIAN for LSB (Intel CPUs).])
  82
  83 # Optional compile-time DEBUGging.
  84 AC_ARG_ENABLE(debug,
  85         AS_HELP_STRING([--enable-debug],[create a debug-only version of the software (default is no).]),
  86   [case "${enableval}" in
  87     yes) enable_debug=yes
  88         AC_DEFINE([DEBUG], [1],
  89             [Define to compile debug-only DHCP software.])
  90         # Just override CFLAGS totally to remove optimization.
  91         CFLAGS="-g";;
  92     no)  enable_debug=no ;;
  93     *)   AC_MSG_ERROR([bad value ${enableval} for --enable-debug]) ;;
  94   esac],[enable_debug=no])
  95
  96 # XXX: there are actually quite a lot more DEBUG_ features we could enable,
  97 # but I don't want to pollute the --help space.
  98 #
  99 #/* #define DEBUG_TOKENS */
 100 #/* #define DEBUG_PACKET */
 101 #/* #define DEBUG_EXPRESSIONS */
 102 #/* #define DEBUG_FIND_LEASE */
 103 #/* #define DEBUG_EXPRESSION_PARSE */
 104 #/* #define DEBUG_CLASS_MATCHING */
 105 #/* #define DEBUG_MEMORY_LEAKAGE */
 106 #/* #define DEBUG_MALLOC_POOL */
 107 #/* #define DEBUG_LEASE_STATE_TRANSITIONS */
 108 #/* #define DEBUG_RC_HISTORY */
 109 #/* #define DEBUG_RC_HISTORY_EXHAUSTIVELY */
 110 #/* #define RC_HISTORY_MAX 10240 */
 111 #/* #define POINTER_DEBUG */
 112 #/* #define DEBUG_FAILOVER_MESSAGES */
 113 #/* #define DEBUG_FAILOVER_TIMING */
 114 #/* #define DEBUG_DUMP_ALL_LEASES */
 115
 116 # Failover optional compile-time feature.
 117 AC_ARG_ENABLE(failover,
 118         AS_HELP_STRING([--enable-failover],[enable support for failover (default is yes)]))
 119 # Failover is on by default, so define if it is not explicitly disabled.
 120 if test "$enable_failover" != "no"; then
 121     enable_failover="yes"
 122         AC_DEFINE([FAILOVER_PROTOCOL], [1],
 123                   [Define to include Failover Protocol support.])
 124 fi
 125
 126 # execute() support.
 127 AC_ARG_ENABLE(execute,
 128         AS_HELP_STRING([--enable-execute],[enable support for execute() in config (default is yes)]))
 129 # execute() is on by default, so define if it is not explicitly disabled.
 130 if test "$enable_execute" != "no" ; then
 131     enable_execute="yes"
 132         AC_DEFINE([ENABLE_EXECUTE], [1],
 133                   [Define to include execute() config language support.])
 134 fi
 135
 136 # Server tracing support.
 137 AC_ARG_ENABLE(tracing,
 138         AS_HELP_STRING([--enable-tracing],[enable support for server activity tracing (default is yes)]))
 139 # tracing is on by default, so define if it is not explicitly disabled.
 140 if test "$enable_tracing" != "no" ; then
 141         AC_DEFINE([TRACING], [1],
 142                   [Define to include server activity tracing support.])
 143 fi
 144
 145 # Delayed-ack feature support.
 146 AC_ARG_ENABLE(delayed_ack,
 147         AS_HELP_STRING([--enable-delayed-ack],[queues multiple DHCPACK replies (default is yes)]))
 148 if test "$enable_delayed_ack" != "no"; then
 149     enable_delayed_ack="yes"
 150         AC_DEFINE([DELAYED_ACK], [1],
 151                   [Define to queue multiple DHCPACK replies per fsync.])
 152 fi
 153
 154 # DHCPv6 optional compile-time feature.
 155 AC_ARG_ENABLE(dhcpv6,
 156         AS_HELP_STRING([--enable-dhcpv6],[enable support for DHCPv6 (default is yes)]))
 157 # DHCPv6 is on by default, so define if it is not explicitly disabled.
 158 if test "$enable_dhcpv6" != "no"; then
 159     enable_dhcpv6="yes"
 160         AC_DEFINE([DHCPv6], [1],
 161                   [Define to 1 to include DHCPv6 support.])
 162 fi
 163
 164 # DHCPv4o6 optional compile-time feature.
 165 AC_ARG_ENABLE(dhcpv4o6,
 166         AS_HELP_STRING([--enable-dhcpv4o6],[enable support for DHCPv4-over-DHCPv6 (default is no)]))
 167 # DHCPv4o6 is off by default, so define if it is explicitly enabled.
 168 if test "$enable_dhcpv4o6" = "yes"; then
 169         # DHCPv4o6 requires DHCPv6
 170         if test "$enable_dhcpv6" = "no"; then
 171                 AC_MSG_ERROR([dhcpv4o6 requires dhcpv6])
 172         fi
 173         AC_DEFINE([DHCP4o6], [1],
 174                   [Define to 1 to include DHCPv4 over DHCPv6 support.])
 175 else
 176     # so we can report below
 177     enable_dhcpv4o6="no"
 178 fi
 179
 180 # Relay port (draft-ietf-dhc-relay-port-10.txt) optional compile-time feature.
 181 AC_ARG_ENABLE(relay-port,
 182         AS_HELP_STRING([--enable-relay-port],[enable support for relay port (default is no)]))
 183 # Relay port is off by default (for now)
 184 if test "$enable_relay_port" = "yes"; then
 185         AC_DEFINE([RELAY_PORT], [1],
 186                   [Define to 1 to include relay port support.])
 187 fi
 188
 189 # PARANOIA is off by default (until we can test it with all features)
 190 AC_ARG_ENABLE(paranoia,
 191         AS_HELP_STRING([--enable-paranoia],[enable support for chroot/setuid (default is no)]))
 192 AC_ARG_ENABLE(early_chroot,
 193         AS_HELP_STRING([--enable-early-chroot],[enable chrooting prior to configuration (default is no)]))
 194 # If someone enables early chroot, but does not enable paranoia, do so for
 195 # them.
 196 if test "$enable_paranoia" != "yes" && \
 197    test "$enable_early_chroot" = "yes" ; then
 198         enable_paranoia="yes"
 199 fi
 200
 201 if test "$enable_paranoia" = "yes" ; then
 202         AC_DEFINE([PARANOIA], [1],
 203                   [Define to any value to include Ari's PARANOIA patch.])
 204 fi
 205 if test "$enable_early_chroot" = "yes" ; then
 206         AC_DEFINE([EARLY_CHROOT], [1],
 207                   [Define to any value to chroot() prior to loading config.])
 208 fi
 209
 210 AC_ARG_ENABLE(ipv4_pktinfo,
 211         AS_HELP_STRING([--enable-ipv4-pktinfo],[enable use of pktinfo on IPv4 sockets (default is no)]))
 212
 213 if test "$enable_ipv4_pktinfo" = "yes"; then
 214         AC_DEFINE([USE_V4_PKTINFO], [1],
 215                 [Define to 1 to enable IPv4 packet info support.])
 216 fi
 217
 218 AC_ARG_ENABLE(use_sockets,
 219         AS_HELP_STRING([--enable-use-sockets],[use the standard BSD socket API (default is no)]))
 220
 221 if test "$enable_use_sockets" = "yes"; then
 222         AC_DEFINE([USE_SOCKETS], [1],
 223                 [Define to 1 to use the standard BSD socket API.])
 224 fi
 225
 226 # Include the PID in the log messages.  This is useful when there may
 227 # be multiple instances of a program.
 228 # This is off by default
 229 AC_ARG_ENABLE(log_pid,
 230         AS_HELP_STRING([--enable-log-pid],[Include PIDs in syslog messages (default is no).]))
 231 if test "$enable_log_pid" = "yes" ; then
 232         AC_DEFINE([USE_LOG_PID], [1],
 233                 [Define to include PIDs in syslog messages.])
 234 fi
 235
 236 # Allow for binary search when inserting v4 leases into queues
 237 AC_ARG_ENABLE(binary_leases,
 238         AS_HELP_STRING([--enable-binary-leases],[enable support for binary insertion of leases (default is no)]))
 239 # binary_leases is off by default.
 240 if test "$enable_binary_leases" = "yes"; then
 241         AC_DEFINE([BINARY_LEASES], [1],
 242                   [Define to support binary insertion of leases into queues.])
 243 else
 244     enable_binary_leases="no"
 245 fi
 246
 247 # Testing section
 248
 249 DISTCHECK_ATF_CONFIGURE_FLAG=
 250 atf_path="no"
 251 AC_ARG_WITH([atf],
 252     AS_HELP_STRING([--with-atf=PATH],[specify location where atf was installed (or "bind")]),
 253     [atf_path="$withval"])
 254 AM_CONDITIONAL(BIND_ATF, test "$atf_path" = "bind")
 255 if test "$atf_path" = "bind" ; then
 256     DISTCHECK_ATF_CONFIGURE_FLAG="--with-atf=bind"
 257     atf_pcp="bind"
 258     atf_path="\${top_srcdir}/bind/atf"
 259     ATF_CFLAGS="-I$atf_path/include -DUNIT_TEST"
 260     ATF_LDFLAGS="-L$atf_path/lib -latf-c"
 261     ATF_BIN=`cd $srcdir; pwd`/bind/atf/bin
 262     AC_SUBST(ATF_CFLAGS)
 263     AC_SUBST(ATF_LDFLAGS)
 264     AC_SUBST(ATF_BIN)
 265     BINDCONFIG="$BINDCONFIG --with-atf"
 266 elif test "$atf_path" != "no" ; then
 267     DISTCHECK_ATF_CONFIGURE_FLAG="--with-atf=$atf_path"
 268     # Config path for pkg-config
 269     atf_pcp=""
 270     if test "$atf_path" != "yes" ; then
 271         if test -f $atf_path/lib/pkgconfig/atf-c.pc ; then
 272             atf_pcp=$atf_path/lib/pkgconfig
 273         elif test -f $atf_path/lib64/pkgconfig/atf-c.pc ; then
 274             atf_pcp=$atf_path/lib64/pkgconfig
 275         fi
 276     else
 277         # Not specified, try some common paths
 278         atf_dirs="/usr /usr/local /usr/pkg /opt /opt/local"
 279         for d in $atf_dirs
 280         do
 281             if test -f $d/lib/pkgconfig/atf-c.pc ; then
 282                 atf_pcp=$d/lib/pkgconfig
 283                 atf_path=$d
 284             elif test -f $d/lib64/pkgconfig/atf-c.pc ; then
 285                 atf_pcp=$d/lib64/pkgconfig
 286                 atf_path=$d
 287             fi
 288         done
 289     fi
 290
 291     if test "$atf_pcp" = "" ; then
 292         AC_MSG_ERROR([Unable to find atf files in location specified])
 293     else
 294         AC_CHECK_PROG([pkgcfg_found],[pkg-config],[pkg-config],[])
 295         if test "$pkgcfg_found" = ""; then
 296             AC_MSG_ERROR([Could not locate ATF, pkg-config not installed])
 297         fi
 298         ATF_CFLAGS="`PKG_CONFIG_PATH=$atf_pcp pkg-config --cflags atf-c` -DUNIT_TEST"
 299         ATF_LDFLAGS="`PKG_CONFIG_PATH=$atf_pcp pkg-config --libs atf-c`"
 300         if  test -f $atf_pcp/atf-sh.pc ; then
 301                 ATF_BIN="`PKG_CONFIG_PATH=$atf_pcp pkg-config --variable=exec_prefix atf-sh`/bin"
 302         else
 303                 # older versions don't have atf-sh, try usual place
 304                 ATF_BIN=$atf_path/bin
 305         fi
 306
 307         if test ! -x $ATF_BIN/atf-run  -o  ! -x $ATF_BIN/atf-report ; then
 308             AC_MSG_WARN([atf-run/atf-report not found, assuming they are in your path])
 309         fi
 310
 311         AC_SUBST(ATF_CFLAGS)
 312         AC_SUBST(ATF_LDFLAGS)
 313         AC_SUBST(ATF_BIN)
 314     fi
 315 fi
 316
 317 AM_CONDITIONAL(HAVE_ATF, test "$atf_pcp" != "")
 318 AM_COND_IF([HAVE_ATF], [AC_DEFINE([HAVE_ATF], [1], [ATF framework specified?])])
 319 AC_SUBST(DISTCHECK_ATF_CONFIGURE_FLAG)
 320
 321 ###
 322 ### Path fun.  Older versions of DHCP were installed in /usr/sbin, so we
 323 ### need to look there and potentially overwrite by default (but not if
 324 ### the user configures an alternate value).  LOCALSTATEDIR is totally
 325 ### braindead.  No one uses /usr/local/var/db/ nor /usr/local/var/run, and
 326 ### they would be insane for suggesting it.  We need to look in /var/for
 327 ### 'db' and 'state/dhcp' for db files, and /var/run for pid files by
 328 ### default.
 329 ###
 330 AC_PREFIX_PROGRAM(dhcpd)
 331
 332 # XXX - isn't there SOME WAY to default autoconf to /var instead of
 333 # /usr/local/var/no/one/has/this/please/stop/trying?
 334 case "$localstatedir" in
 335         '${prefix}/var')
 336                 localstatedir=/var
 337                 ;;
 338 esac
 339
 340 # Default server configuration file.
 341 AC_ARG_WITH(srv-conf-file,
 342         AS_HELP_STRING([--with-srv-conf-file=PATH],[Default file containing dhcpd configuration
 343                         (default is typically /etc/dhcpd.conf)]),
 344         AC_DEFINE_UNQUOTED([_PATH_DHCPD_CONF], ["$withval"],
 345                            [Default file containing dhcpd configuration.]))
 346
 347 # Allow specification of alternate state files
 348 AC_ARG_WITH(srv-lease-file,
 349         AS_HELP_STRING([--with-srv-lease-file=PATH],[File for dhcpd leases
 350                         (default is LOCALSTATEDIR/db/dhcpd.leases)]),
 351         AC_DEFINE_UNQUOTED([_PATH_DHCPD_DB], ["$withval"],
 352                            [File for dhcpd leases.]))
 353
 354 AC_MSG_CHECKING([for dhcpd.leases location])
 355 if [[ "x$with_srv_lease_file" = "x" ]] ; then
 356         if [[ -d "${localstatedir}/db" ]] ; then
 357                 with_srv_lease_file="${localstatedir}/db/dhcpd.leases"
 358         elif [[ -d "${localstatedir}/state" ]] ; then
 359                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 360                         with_srv_lease_file="${localstatedir}/state/dhcp/dhcpd.leases"
 361                 else
 362                         with_srv_lease_file="${localstatedir}/state/dhcpd.leases"
 363                 fi
 364         elif [[ -d "${localstatedir}/lib" ]] ; then
 365                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 366                         with_srv_lease_file="${localstatedir}/lib/dhcp/dhcpd.leases"
 367                 else
 368                         with_srv_lease_file="${localstatedir}/lib/dhcpd.leases"
 369                 fi
 370         elif [[ -d "${localstatedir}/etc" ]] ; then
 371                 with_srv_lease_file="${localstatedir}/etc/dhcpd.leases"
 372         else
 373                 with_srv_lease_file="/etc/dhcpd.leases"
 374         fi
 375 fi
 376 AC_MSG_RESULT($with_srv_lease_file)
 377
 378 AC_ARG_WITH(srv6-lease-file,
 379         AS_HELP_STRING([--with-srv6-lease-file=PATH],[File for dhcpd6 leases
 380                         (default is LOCALSTATEDIR/db/dhcpd6.leases)]),
 381         AC_DEFINE_UNQUOTED([_PATH_DHCPD6_DB], ["$withval"],
 382                            [File for dhcpd6 leases.]))
 383
 384 AC_MSG_CHECKING([for dhcpd6.leases location])
 385 if [[ "x$with_srv6_lease_file" = "x" ]] ; then
 386         if [[ -d "${localstatedir}/db" ]] ; then
 387                 with_srv6_lease_file="${localstatedir}/db/dhcpd6.leases"
 388         elif [[ -d "${localstatedir}/state" ]] ; then
 389                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 390                         with_srv6_lease_file="${localstatedir}/state/dhcp/dhcpd6.leases"
 391                 else
 392                         with_srv6_lease_file="${localstatedir}/state/dhcpd6.leases"
 393                 fi
 394         elif [[ -d "${localstatedir}/lib" ]] ; then
 395                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 396                         with_srv6_lease_file="${localstatedir}/lib/dhcp/dhcpd6.leases"
 397                 else
 398                         with_srv6_lease_file="${localstatedir}/lib/dhcpd6.leases"
 399                 fi
 400         elif [[ -d "${localstatedir}/etc" ]] ; then
 401                 with_srv6_lease_file="${localstatedir}/etc/dhcpd6.leases"
 402         else
 403                 with_srv6_lease_file="/etc/dhcpd6.leases"
 404         fi
 405 fi
 406 AC_MSG_RESULT($with_srv6_lease_file)
 407
 408 AC_ARG_WITH(cli-lease-file,
 409         AS_HELP_STRING([--with-cli-lease-file=PATH],[File for dhclient leases
 410                         (default is LOCALSTATEDIR/db/dhclient.leases)]),
 411         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT_DB], ["$withval"],
 412                            [File for dhclient leases.]))
 413
 414 AC_MSG_CHECKING([for dhclient.leases location])
 415 if [[ "x$with_cli_lease_file" = "x" ]] ; then
 416         if [[ -d "${localstatedir}/db" ]] ; then
 417                 with_cli_lease_file="${localstatedir}/db/dhclient.leases"
 418         elif [[ -d "${localstatedir}/state" ]] ; then
 419                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 420                         with_cli_lease_file="${localstatedir}/state/dhcp/dhclient.leases"
 421                 else
 422                         with_cli_lease_file="${localstatedir}/state/dhclient.leases"
 423                 fi
 424         elif [[ -d "${localstatedir}/lib" ]] ; then
 425                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 426                         with_cli_lease_file="${localstatedir}/lib/dhcp/dhclient.leases"
 427                 else
 428                         with_cli_lease_file="${localstatedir}/lib/dhclient.leases"
 429                 fi
 430         elif [[ -d "${localstatedir}/etc" ]] ; then
 431                 with_cli_lease_file="${localstatedir}/etc/dhclient.leases"
 432         else
 433                 with_cli_lease_file="/etc/dhclient.leases"
 434         fi
 435 fi
 436 AC_MSG_RESULT($with_cli_lease_file)
 437
 438 AC_ARG_WITH(cli6-lease-file,
 439         AS_HELP_STRING([--with-cli6-lease-file=PATH],[File for dhclient6 leases
 440                         (default is LOCALSTATEDIR/db/dhclient6.leases)]),
 441         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT6_DB], ["$withval"],
 442                            [File for dhclient6 leases.]))
 443
 444 AC_MSG_CHECKING([for dhclient6.leases location])
 445 if [[ "x$with_cli6_lease_file" = "x" ]] ; then
 446         if [[ -d "${localstatedir}/db" ]] ; then
 447                 with_cli6_lease_file="${localstatedir}/db/dhclient6.leases"
 448         elif [[ -d "${localstatedir}/state" ]] ; then
 449                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 450                         with_cli6_lease_file="${localstatedir}/state/dhcp/dhclient6.leases"
 451                 else
 452                         with_cli6_lease_file="${localstatedir}/state/dhclient6.leases"
 453                 fi
 454         elif [[ -d "${localstatedir}/lib" ]] ; then
 455                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 456                         with_cli6_lease_file="${localstatedir}/lib/dhcp/dhclient6.leases"
 457                 else
 458                         with_cli6_lease_file="${localstatedir}/lib/dhclient6.leases"
 459                 fi
 460         elif [[ -d "${localstatedir}/etc" ]] ; then
 461                 with_cli6_lease_file="${localstatedir}/etc/dhclient6.leases"
 462         else
 463                 with_cli6_lease_file="/etc/dhclient6.leases"
 464         fi
 465 fi
 466 AC_MSG_RESULT($with_cli6_lease_file)
 467
 468 AC_ARG_WITH(srv-pid-file,
 469         AS_HELP_STRING([--with-srv-pid-file=PATH],[File for dhcpd process information
 470                         (default is LOCALSTATEDIR/run/dhcpd.pid)]),
 471         AC_DEFINE_UNQUOTED([_PATH_DHCPD_PID], ["$withval"],
 472                            [File for dhcpd process information.]))
 473 AC_ARG_WITH(srv6-pid-file,
 474         AS_HELP_STRING([--with-srv6-pid-file=PATH],[File for dhcpd6 process information
 475                         (default is LOCALSTATEDIR/run/dhcpd6.pid)]),
 476         AC_DEFINE_UNQUOTED([_PATH_DHCPD6_PID], ["$withval"],
 477                            [File for dhcpd6 process information.]))
 478 AC_ARG_WITH(cli-pid-file,
 479         AS_HELP_STRING([--with-cli-pid-file=PATH],[File for dhclient process information
 480                         (default is LOCALSTATEDIR/run/dhclient.pid)]),
 481         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT_PID], ["$withval"],
 482                            [File for dhclient process information.]))
 483 AC_ARG_WITH(cli6-pid-file,
 484         AS_HELP_STRING([--with-cli6-pid-file=PATH],[File for dhclient6 process information
 485                         (default is LOCALSTATEDIR/run/dhclient6.pid)]),
 486         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT6_PID], ["$withval"],
 487                            [File for dhclient6 process information.]))
 488 AC_ARG_WITH(relay-pid-file,
 489         AS_HELP_STRING([--with-relay-pid-file=PATH],[File for dhcrelay process information
 490                         (default is LOCALSTATEDIR/run/dhcrelay.pid)]),
 491         AC_DEFINE_UNQUOTED([_PATH_DHCRELAY_PID], ["$withval"],
 492                            [File for dhcrelay process information.]))
 493 AC_ARG_WITH(relay6-pid-file,
 494         AS_HELP_STRING([--with-relay6-pid-file=PATH],[File for dhcrelay6 process information
 495                         (default is LOCALSTATEDIR/run/dhcrelay6.pid)]),
 496         AC_DEFINE_UNQUOTED([_PATH_DHCRELAY6_PID], ["$withval"],
 497                            [File for dhcrelay6 process information.]))
 498
 499 # Check basic types.
 500 AC_TYPE_INT8_T
 501 AC_TYPE_INT16_T
 502 AC_TYPE_INT32_T
 503 AC_TYPE_INT64_T
 504
 505 # Some systems need the u_intX_t types defined across.
 506 AC_CHECK_TYPE([u_int8_t], [], [
 507   AC_TYPE_UINT8_T
 508   AC_DEFINE(u_int8_t, [uint8_t], [Define a type for 8-bit unsigned
 509                                   integers.])
 510 ])
 511 AC_CHECK_TYPE([u_int16_t], [], [
 512   AC_TYPE_UINT16_T
 513   AC_DEFINE(u_int16_t, [uint16_t], [Define a type for 16-bit unsigned
 514                                     integers.])
 515 ])
 516 AC_CHECK_TYPE([u_int32_t], [], [
 517   AC_TYPE_UINT32_T
 518   AC_DEFINE(u_int32_t, [uint32_t], [Define a type for 32-bit unsigned
 519                                     integers.])
 520 ])
 521 AC_CHECK_TYPE([u_int64_t], [], [
 522   AC_TYPE_UINT64_T
 523   AC_DEFINE(u_int64_t, [uint64_t], [Define a type for 64-bit unsigned
 524                                     integers.])
 525 ])
 526
 527 # see if ifaddrs.h is available
 528 AC_CHECK_HEADERS(ifaddrs.h)
 529
 530 # figure out what IPv4 interface code to use
 531 AC_CHECK_HEADERS(linux/types.h)  # needed for linux/filter.h on old systems
 532
 533 relay_port_supported="no"
 534 AC_CHECK_HEADER(linux/filter.h, DO_LPF=1, ,
 535 [
 536 #ifdef HAVE_LINUX_TYPES_H
 537 #include <linux/types.h>
 538 #endif
 539 ])
 540 if test -n "$DO_LPF"
 541 then
 542         AC_DEFINE([HAVE_LPF], [1],
 543                   [Define to 1 to use the Linux Packet Filter interface code.])
 544         relay_port_supported="yes"
 545 else
 546         AC_CHECK_HEADER(sys/dlpi.h, DO_DLPI=1)
 547         if test -n "$DO_DLPI"
 548         then
 549                 AC_DEFINE([HAVE_DLPI], [1],
 550                           [Define to 1 to use DLPI interface code.])
 551         else
 552                 AC_CHECK_HEADER(net/bpf.h, DO_BPF=1)
 553                 if test -n "$DO_BPF"
 554                 then
 555                         AC_DEFINE([HAVE_BPF], [1],
 556                                    [Define to 1 to use the
 557                                    Berkeley Packet Filter interface code.])
 558                         relay_port_supported="yes"
 559                 fi
 560         fi
 561 fi
 562
 563 if test "$enable_relay_port" = "yes"; then
 564         if test "$relay_port_supported" != "yes"; then
 565                 AC_MSG_ERROR([--enable-relay-port requires BPF or LPF])
 566         fi
 567 fi
 568
 569 # SIOCGLIFCONF uses some transport structures.  Trick is not all platforms
 570 # use the same structures.  We like to use 'struct lifconf' and 'struct
 571 # lifreq', but we'll use these other structures if they're present.  HPUX
 572 # does not define 'struct lifnum', but does use SIOCGLIFNUM - they use an
 573 # int value.
 574 #
 575 AC_MSG_CHECKING([for struct lifnum])
 576 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ #include <sys/types.h>
 577   #include <sys/socket.h>
 578   #include <net/if.h>
 579 ]], [[ struct lifnum a;
 580 ]])],[AC_MSG_RESULT(yes)
 581          AC_DEFINE([ISC_PLATFORM_HAVELIFNUM], [1],
 582                    [Define to 1 if the system has 'struct lifnum'.])],[AC_MSG_RESULT(no)])
 583
 584 AC_MSG_CHECKING([for struct if_laddrconf])
 585 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ #include <sys/types.h>
 586   #include <net/if6.h>
 587 ]], [[ struct if_laddrconf a;
 588 ]])],[AC_MSG_RESULT(yes)
 589          AC_DEFINE([ISC_PLATFORM_HAVEIF_LADDRCONF], [1],
 590                    [Define to 1 if the system has 'struct if_laddrconf'.])],[AC_MSG_RESULT(no)])
 591
 592 AC_MSG_CHECKING([for struct if_laddrreq])
 593 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 594  #include <net/if6.h>
 595 ]], [[ struct if_laddrreq a;
 596 ]])],[AC_MSG_RESULT(yes)
 597          AC_DEFINE([ISC_PLATFORM_HAVEIF_LADDRREQ], [1],
 598                    [Define to 1 if the system has 'struct if_laddrreq'.])],[AC_MSG_RESULT(no)])
 599
 600 #
 601 # check for GCC noreturn attribute
 602 #
 603 AC_MSG_CHECKING(for GCC noreturn attribute)
 604 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[void foo() __attribute__((noreturn));]])],[AC_MSG_RESULT(yes)
 605          AC_DEFINE([ISC_DHCP_NORETURN], [__attribute__((noreturn))],
 606                    [Define to the string for a noreturn attribute.])],[AC_MSG_RESULT(no)
 607          AC_DEFINE([ISC_DHCP_NORETURN], [],
 608                    [Define to the string for a noreturn attribute.])])
 609
 610 # Look for optional headers.
 611 AC_CHECK_HEADERS(sys/socket.h net/if_dl.h net/if6.h regex.h)
 612
 613 # Solaris needs some libraries for functions
 614 AC_SEARCH_LIBS(socket, [socket])
 615 AC_SEARCH_LIBS(inet_ntoa, [nsl])
 616
 617 AC_SEARCH_LIBS(inet_aton, [socket nsl], ,
 618         AC_DEFINE([NEED_INET_ATON], [1],
 619                   [Define to 1 if the inet_aton() function is missing.]))
 620
 621 # Check for a standalone regex library.
 622 AC_SEARCH_LIBS(regcomp, [regex])
 623
 624 AC_CHECK_FUNCS(strlcat)
 625
 626 # For HP/UX we need -lipv6 for if_nametoindex, perhaps others.
 627 AC_SEARCH_LIBS(if_nametoindex, [ipv6])
 628
 629 # For some Solaris nanosleep is found by BIND in librt
 630 have_nanosleep="no"
 631 AC_CHECK_FUNC(nanosleep, have_nanosleep="yes")
 632 if test "$have_nanosleep" = "no"; then
 633         AC_CHECK_LIB(rt, nanosleep, have_nanosleep="rt")
 634 fi
 635 if test "$have_nanosleep" = "rt"; then
 636         LIBS="-lrt $LIBS"
 637 fi
 638
 639 # check for /dev/random (declares HAVE_DEV_RANDOM)
 640 AC_MSG_CHECKING(for random device)
 641 AC_ARG_WITH(randomdev,
 642         AS_HELP_STRING([--with-randomdev=PATH],[Path for random device
 643                        (default is /dev/random)]),
 644         use_randomdev="$withval", use_randomdev="unspec")
 645 if test "$use_randomdev" = "unspec"; then
 646         if test "$cross_compiling" = "yes"; then
 647                 AC_MSG_RESULT(unspecified)
 648                 AC_MSG_ERROR([ need --with-randomdev=PATH or --with-randomdev=no])
 649         fi
 650         use_randomdev="/dev/random"
 651 elif test "$use_randomdev" = "yes"; then
 652         use_randomdev="/dev/random"
 653 fi
 654 if test "$use_randomdev" = "no"; then
 655         AC_MSG_RESULT(disabled)
 656         BINDCONFIG="$BINDCONFIG --with-randomdev=no"
 657 else
 658         if test "$cross_compiling" = "yes"; then
 659                 AC_MSG_RESULT($use_randomdev (unchecked))
 660         else
 661                 AC_MSG_RESULT($use_randomdev)
 662                 AC_CHECK_FILE($use_randomdev,
 663                     AC_DEFINE([HAVE_DEV_RANDOM], [1],
 664                         [Define to 1 if you have the /dev/random or other configured file.]),
 665                     AC_MSG_ERROR(cannot find $use_randomdev))
 666         fi
 667         BINDCONFIG="$BINDCONFIG --with-randomdev=$use_randomdev"
 668 fi
 669
 670 BINDIOMUX="--disable-kqueue --disable-epoll --disable-devpoll"
 671 # check kqueue/epoll/devpoll alternative to select
 672 AC_ARG_ENABLE(kqueue,
 673         AS_HELP_STRING([--enable-kqueue],[use BSD kqueue (default is no)]),
 674         want_kqueue="$enableval", want_kqueue="no")
 675 if test "$want_kqueue" = "yes"; then
 676         BINDIOMUX="--enable-kqueue"
 677         AC_MSG_WARN([--enable-kqueue is not supported: it may lead to issues such as server looping])
 678 fi
 679 AC_ARG_ENABLE(epoll,
 680         AS_HELP_STRING([--enable-epoll],[use Linux epoll (default is no)]),
 681         want_epoll="$enableval", want_epoll="no")
 682 if test "$want_epoll" = "yes"; then
 683         BINDIOMUX="--enable-epoll"
 684         AC_MSG_WARN([--enable-epoll is not supported: it may lead to issues such as server looping])
 685 fi
 686 AC_ARG_ENABLE(devpoll,
 687         AS_HELP_STRING([--enable-devpoll],[use /dev/poll (default is no)]),
 688         want_devpoll="$enableval", want_devpoll="no")
 689 if test "$want_devpoll" = "yes"; then
 690         BINDIOMUX="--enable-devpoll"
 691         AC_MSG_WARN([--enable-devpoll is not supported: it may lead to issues such as server looping])
 692 fi
 693 AC_SUBST(BINDIOMUX)
 694
 695 # general extra bind configure arguments
 696 AC_ARG_WITH(bind-extra-config,
 697         AS_HELP_STRING([--with-bind-extra-config],[configure bind librairies
 698                        with some extra options (default is none)]),
 699         use_xbindconfig="$withval", use_xbindconfig="")
 700 case "$use_xbindconfig" in
 701 yes|no|'')
 702         ;;
 703 *)
 704         BINDCONFIG="$BINDCONFIG $use_xbindconfig"
 705         AC_MSG_WARN([Most options to bind configure are not supported when used by ISC DHCP])
 706         ;;
 707 esac
 708
 709 # see if there is a "sa_len" field in our interface information structure
 710 AC_CHECK_MEMBER(struct sockaddr.sa_len,
 711         AC_DEFINE([HAVE_SA_LEN], [],
 712                   [Define to 1 if the sockaddr structure has a length field.]),
 713         ,
 714         [#include <sys/socket.h>])
 715
 716 # figure out pointer size
 717 SAVE_CFLAGS="$CFLAGS"
 718 CFLAGS="$CFLAGS -I$srcdir"
 719 AC_CHECK_SIZEOF(struct iaddr *, , [
 720 #include "includes/inet.h"
 721 #include <stdio.h>
 722 ])
 723 CFLAGS="$SAVE_CFLAGS"
 724
 725 # Solaris does not have the msg_control or msg_controlen members
 726 # in the msghdr structure unless you define:
 727 #
 728 #   _XOPEN_SOURCE, _XOPEN_SOURCE_EXTENDED, and __EXTENSIONS__
 729 #
 730 # See the "standards" man page for details.
 731 #
 732 # We check for the msg_control member, and if it is not found, we check
 733 # again with the appropriate defines added to the CFLAGS. (In order to
 734 # do this we have to remove the check from the cache, which is what the
 735 # "unset" is for.)
 736 AC_CHECK_MEMBER(struct msghdr.msg_control,,
 737         [CFLAGS="$CFLAGS -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 738          CFLAGS="$CFLAGS -D__EXTENSIONS__"
 739          unset ac_cv_member_struct_msghdr_msg_control
 740          AC_CHECK_MEMBER(struct msghdr.msg_control,,
 741                 [AC_MSG_ERROR([Missing msg_control member in
 742                                msg_control structure.])],
 743                 [
 744 #include <sys/types.h>
 745 #include <sys/socket.h>
 746                 ])
 747         ],
 748         [
 749 #include <sys/types.h>
 750 #include <sys/socket.h>
 751         ])
 752
 753 AC_CHECK_MEMBER(struct tpacket_auxdata.tp_vlan_tci,
 754     [AC_DEFINE([VLAN_TCI_PRESENT], [1], [tpacket_auxdata.tp_vlan_tci present])]
 755     ,, [#include <linux/if_packet.h>])
 756
 757 # bind/Makefile.in is not from automake so we need 2 variables for bind dir
 758 BINDSUBDIR=
 759 BINDDIR=
 760 BINDSRCDIR=
 761 BINDLIBIRSDIR=
 762 BINDLIBDNSDIR=
 763 BINDLIBISCCFGDIR=
 764 BINDLIBISCDIR=
 765 DISTCHECK_LIBBIND_CONFIGURE_FLAG=
 766 AC_ARG_WITH(libbind,
 767         AS_HELP_STRING([--with-libbind=PATH],[bind includes and libraries are in PATH]),
 768         use_libbind="$withval", use_libbind="no")
 769 case "$use_libbind" in
 770 yes)
 771         AC_MSG_ERROR([PATH is required in --with-libbind=PATH])
 772         ;;
 773 no)
 774         BINDSUBDIR="\${top_srcdir}/bind"
 775         my_abs_srcdir=`cd $srcdir && pwd`
 776         BINDDIR="${my_abs_srcdir}/bind"
 777         if test ! -d "$srcdir/bind"; then
 778                 AC_MSG_ERROR([Where to find or build bind includes and libraries must be specified])
 779         fi
 780         if test -d "$srcdir/bind/bind9"; then
 781                 BINDSRCDIR="${my_abs_srcdir}/bind/bind9"
 782         else
 783                 if test ! -f "$srcdir/bind/version.tmp"; then
 784                         AC_MSG_ERROR([Cannot find $srcdir/bind/version.tmp])
 785                 fi
 786                 . "$srcdir/bind/version.tmp"
 787                 bindversion=${MAJORVER}.${MINORVER}.${PATCHVER}${RELEASETYPE}${RELEASEVER}
 788                 BINDSRCDIR="${my_abs_srcdir}/bind/bind-$bindversion"
 789         fi
 790         AC_CONFIG_FILES([$srcdir/bind/Makefile])
 791
 792         BINDLIBIRSDIR="$BINDSRCDIR/lib/irs"
 793         BINDLIBDNSDIR="$BINDSRCDIR/lib/dns"
 794         BINDLIBISCCFGDIR="$BINDSRCDIR/lib/isccfg"
 795         BINDLIBISCDIR="$BINDSRCDIR/lib/isc"
 796         ;;
 797 *)
 798         if test ! -d "$use_libbind"; then
 799                 AC_MSG_ERROR([Cannot find bind directory at $use_libbind])
 800         fi
 801         if test ! -d "$use_libbind/include" -o \
 802                 ! -f "$use_libbind/include/isc/buffer.h"
 803         then
 804                 AC_MSG_ERROR([Cannot find bind includes at $use_libbind/include])
 805         fi
 806         if test ! -d "$use_libbind/lib" -o \
 807                 \( ! -f "$use_libbind/lib/libisc.a" -a \
 808                    ! -f "$use_libbind/lib/libisc.la" \)
 809         then
 810                 AC_MSG_ERROR([Cannot find bind libraries at $use_libbind/lib])
 811         fi
 812         BINDDIR="$use_libbind"
 813         BINDLIBIRSDIR="$BINDDIR/lib"
 814         BINDLIBDNSDIR="$BINDDIR/lib"
 815         BINDLIBISCCFGDIR="$BINDDIR/lib"
 816         BINDLIBISCDIR="$BINDDIR/lib"
 817         DISTCHECK_LIBBIND_CONFIGURE_FLAG="--with-libbind=$use_libbind"
 818         ;;
 819 esac
 820 AC_SUBST(BINDSUBDIR)
 821 AC_SUBST(BINDDIR)
 822 AC_SUBST(BINDSRCDIR)
 823 AC_SUBST(BINDLIBIRSDIR)
 824 AC_SUBST(BINDLIBDNSDIR)
 825 AC_SUBST(BINDLIBISCCFGDIR)
 826 AC_SUBST(BINDLIBISCDIR)
 827 AC_SUBST(DISTCHECK_LIBBIND_CONFIGURE_FLAG)
 828 AM_CONDITIONAL(HAVE_BINDDIR, test "$use_libbind" = "no")
 829
 830 #
 831 # GNU libtool support
 832 #
 833 case "$build_os" in
 834         sunos*)
 835                 # Just set the maximum command line length for sunos
 836                 # as it otherwise takes a exceptionally long time to
 837                 # work it out. Required for libtool.
 838
 839                 lt_cv_sys_max_cmd_len=4096
 840                 ;;
 841 esac
 842
 843 want_libtool="no"
 844
 845 BINDLT=
 846 DISTCHECK_LIBTOOL_CONFIGURE_FLAG=
 847 AC_ARG_ENABLE(libtool,
 848         AS_HELP_STRING([--enable-libtool],
 849 [use GNU libtool for dynamic shared libraries (default is no).]),
 850         want_libtool="$enableval")
 851
 852 if test "$use_libbind" != "no"; then
 853         if test "$want_libtool" = "yes" -a \
 854                 ! -f "$use_libbind/lib/libisc.la"
 855         then
 856                 AC_MSG_ERROR([Cannot find dynamic libraries at $use_libbind/lib])
 857         fi
 858         if test "$want_libtool" = "no" -a \
 859                 ! -f "$use_libbind/lib/libisc.a"
 860         then
 861                 AC_MSG_ERROR([Cannot find static libraries at $use_libbind/lib])
 862         fi
 863 fi
 864
 865
 866 if test "$want_libtool" = "yes"; then
 867         AC_MSG_WARN([legacy configure is used but libtool is enabled. Trying to recover...])
 868         # expand $ac_configure_args
 869         eval "set my_configure_args $ac_configure_args"
 870         shift
 871         cd $srcdir; exec ./config+lt "$@"
 872         AC_MSG_ERROR([Recovering failed])
 873 fi
 874
 875 DHLIBS=LIBRARIES
 876 A=a
 877
 878 AC_SUBST(DHLIBS)
 879 AC_SUBST(A)
 880 AC_SUBST(BINDLT)
 881 AC_SUBST(DISTCHECK_LIBTOOL_CONFIGURE_FLAG)
 882
 883 # quoting in Makefile.am.in
 884 Q=@
 885 AC_SUBST(Q)
 886
 887 # install bind includes and libraries
 888
 889 want_install_bind="no"
 890 if test "$want_libtool" = "yes"; then
 891         want_install_bind="yes"
 892 fi
 893 if test "$use_libbind" != "no"; then
 894         want_install_bind="no"
 895 fi
 896 AC_ARG_ENABLE(bind_install,
 897         AS_HELP_STRING([--enable-bind-install],
 898 [install bind includes and libraries (default is no).]),
 899         want_install_bind="$enableval")
 900 if test "$want_install_bind" = "yes"; then
 901         if test "$use_libbind" != "no"; then
 902                 AC_MSG_WARN([--enable-bind-install does nothing when --with-libbind is set])
 903         fi
 904 elif test "$want_libtool" = "yes" -a "$use_libbind" = "no"; then
 905         AC_MSG_WARN([embedded dynamic bind libraries must be installed])
 906 fi
 907 AM_CONDITIONAL(INSTALL_BIND, test "$want_install_bind" = "yes")
 908
 909 # OpenLDAP support.
 910 AC_ARG_WITH(ldap,
 911     AS_HELP_STRING([--with-ldap],[enable OpenLDAP support in dhcpd (default is no)]),
 912     [ldap=$withval],
 913     [ldap=no])
 914
 915 # OpenLDAP with SSL support.
 916 AC_ARG_WITH(ldapcrypto,
 917     AS_HELP_STRING([--with-ldapcrypto],[enable OpenLDAP crypto support in dhcpd (default is no)]),
 918     [ldapcrypto=$withval],
 919     [ldapcrypto=no])
 920
 921 # Gssapi to allow LDAP to authenticate with a keytab
 922 AC_ARG_WITH(ldap-gssapi,
 923     AC_HELP_STRING([--with-ldap-gssapi],
 924                    [enable krb5/gssapi authentication for OpenLDAP in dhcpd (default is no)]),
 925     [ldap_gssapi=$withval],
 926     [ldap_gssapi=no])
 927
 928
 929 # LDAP CASA auth support.
 930 AC_ARG_WITH(ldapcasa,
 931     AC_HELP_STRING([--with-ldapcasa],
 932                    [enable LDAP CASA auth support in dhcpd (default is no)]),
 933     [ldapcasa=$withval],
 934     [ldapcasa=no])
 935
 936 # OpenLDAP support is disabled by default, if enabled then SSL support is an
 937 # extra optional that is also disabled by default.  Enabling LDAP SSL support
 938 # implies enabling LDAP support. Similarly, KRB5 support implies LDAP support,
 939 # but doesn't include SSL. The two are not dependant.
 940 if test x$ldap = xyes || test x$ldapcrypto = xyes || test x$ldap_gssapi = xyes; then
 941     saved_LIBS="$LIBS"
 942     LIBS=""
 943     AC_SEARCH_LIBS(ldap_initialize, [ldap], ,
 944                    AC_MSG_FAILURE([*** Cannot find ldap_initialize with -lldap - do you need to install an OpenLDAP2 Devel package?]))
 945     AC_SEARCH_LIBS(ber_pvt_opt_on, [lber], ,
 946                    AC_MSG_FAILURE([*** Cannot find ber_pvt_opt_on with -llber - do you need to install an OpenLDAP2 Devel package?]))
 947     if test x$ldap_gssapi = xyes ; then
 948     AC_SEARCH_LIBS(krb5_init_context, [krb5], ,
 949           AC_MSG_FAILURE([*** Cannot find krb5_init_context with -lkrb5 - do you need to install a Kerberos Devel package?]))
 950     fi
 951
 952     # Create LDAP_LIBS which we specify them explicitly rather than lumping them in with LIBS
 953     AC_SUBST(LDAP_LIBS, [$LIBS])
 954     LIBS="$saved_LIBS"
 955
 956
 957     AC_CHECK_HEADERS([ldap.h])
 958     AC_CHECK_FUNCS([inet_pton inet_ntop])
 959
 960
 961     LDAP_CFLAGS="-DLDAP_CONFIGURATION"
 962
 963     if test x$ldapcasa = xyes ; then
 964     AC_CHECK_HEADERS([micasa_mgmd.h],[
 965            LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_CASA_AUTH"
 966     ], AC_MSG_FAILURE([*** Cannot find micasa_mgmd.h for ldap casa auth support]))
 967     fi
 968
 969     if test x$ldapcrypto = xyes ; then
 970     LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_USE_SSL"
 971     fi
 972
 973     if test x$ldap_gssapi = xyes; then
 974     LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_USE_GSSAPI"
 975     fi
 976
 977     AC_SUBST(LDAP_CFLAGS, [$LDAP_CFLAGS])
 978 fi
 979
 980 # Append selected warning levels to CFLAGS before substitution (but after
 981 # AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[],[]) & etc).
 982 CFLAGS="$CFLAGS $STD_CWARNINGS"
 983
 984 # Try to add the bind and dhcp include directories
 985 CFLAGS="$CFLAGS -I\$(top_srcdir)/includes -I$BINDDIR/include"
 986
 987 case "$host" in
 988 *-darwin*)
 989     CFLAGS="$CFLAGS -D__APPLE_USE_RFC_3542";;
 990 *-solaris*)
 991     # As of Solaris 11, ethernet dev files are in /dev/net
 992     AC_CHECK_FILE(/dev/net,
 993                     [AC_DEFINE([USE_DEV_NET], [1],
 994                         [Define to 1 if ethernet devices are in /dev/net])])
 995     ;;
 996 esac
 997
 998 AC_C_FLEXIBLE_ARRAY_MEMBER
 999
1000 AC_CONFIG_FILES([
1001   Makefile
1002   client/Makefile
1003   client/tests/Makefile
1004   common/Makefile.am
1005   common/Makefile
1006   common/tests/Makefile
1007   dhcpctl/Makefile.am
1008   dhcpctl/Makefile
1009   includes/Makefile
1010   omapip/Makefile.am
1011   omapip/Makefile
1012   relay/Makefile
1013   server/Makefile
1014   tests/Makefile.am
1015   tests/Makefile
1016   tests/unittest.sh
1017   server/tests/Makefile
1018   doc/devel/doxyfile
1019 ])
1020 AC_OUTPUT
1021
1022
1023 if test "$enable_dhcpv4o6" = "yes"; then
1024         DHCP_VERSIONS="DHCPv4, DHCPv6 and DHCPv4-over-DHCPv6"
1025 elif test "$enable_dhcpv6" != "no"; then
1026         DHCP_VERSIONS="DHCPv4 and DHCPv6"
1027 else
1028         DHCP_VERSIONS="DHCPv4"
1029 fi
1030
1031 cat > config.report << END
1032
1033      ISC DHCP source configure results:
1034     -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
1035
1036 Package:
1037   Name:          $PACKAGE_NAME
1038   Version:       $PACKAGE_VERSION
1039
1040 C Compiler:      $CC
1041
1042 Flags:
1043   DEFS:          $DEFS
1044   CFLAGS:        $CFLAGS
1045
1046 DHCP versions:   $DHCP_VERSIONS
1047
1048 Features:
1049   debug:         $enable_debug
1050   failover:      $enable_failover
1051   execute:       $enable_execute
1052   binary-leases: $enable_binary_leases
1053   dhcpv6:        $enable_dhcpv6
1054   delayed-ack:   $enable_delayed_ack
1055   dhcpv4o6:      $enable_dhcpv4o6
1056   relay-port:    $enable_relay_port
1057
1058 Developer:
1059   ATF unittests : $atf_path
1060
1061 END
1062 # TODO: Add Perl system tests
1063
1064 if test "$atf_path" != "no"
1065 then
1066 echo "ATF_CFLAGS  : $ATF_CFLAGS" >> config.report
1067 echo "ATF_LDFLAGS : $ATF_LDFLAGS" >> config.report
1068 echo "ATF_BIN : $ATF_BIN" >> config.report
1069 echo
1070 fi
1071
1072 cat config.report
1073
1074 echo
1075 echo Now you can type "make" to build ISC DHCP
1076 echo