configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [209],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  42        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  43       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  44
  45 LT_PREREQ(2.2)
  46 LT_INIT([disable-static])
  47
  48 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  49 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  50
  51 # i18n stuff for the PolicyKit policy files
  52 IT_PROG_INTLTOOL([0.40.0])
  53
  54 GETTEXT_PACKAGE=systemd
  55 AC_SUBST(GETTEXT_PACKAGE)
  56
  57 AC_PROG_MKDIR_P
  58 AC_PROG_LN_S
  59 AC_PROG_SED
  60 AC_PROG_GREP
  61 AC_PROG_AWK
  62
  63 AC_PROG_CC_C99
  64
  65 AC_PATH_PROG([M4], [m4])
  66 AC_PATH_PROG([XSLTPROC], [xsltproc])
  67
  68 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  69 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  70
  71 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  72
  73 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  74
  75 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  76
  77 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  78
  79 M4_DEFINES=
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(STRINGS, strings)
  98 AC_CHECK_TOOL(GPERF, gperf)
  99 if test -z "$GPERF" ; then
 100         AC_MSG_ERROR([*** gperf not found])
 101 fi
 102
 103 # ------------------------------------------------------------------------------
 104 address_sanitizer_cflags=
 105 address_sanitizer_cppflags=
 106 address_sanitizer_ldflags=
 107 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 108 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 109             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 110             AS_IF([test -z "$with_as_cflags"],
 111                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 112             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 113             address_sanitizer_cppflags="-DVALGRIND=1"
 114             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 115       ])
 116
 117 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 118         -pipe \
 119         -Wall \
 120         -Wextra \
 121         -Wno-inline \
 122         -Wundef \
 123         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 124         -Wlogical-op \
 125         -Wsign-compare \
 126         -Wmissing-include-dirs \
 127         -Wold-style-definition \
 128         -Wpointer-arith \
 129         -Winit-self \
 130         -Wdeclaration-after-statement \
 131         -Wfloat-equal \
 132         -Wsuggest-attribute=noreturn \
 133         -Wmissing-prototypes \
 134         -Wstrict-prototypes \
 135         -Wredundant-decls \
 136         -Wmissing-declarations \
 137         -Wmissing-noreturn \
 138         -Wshadow \
 139         -Wendif-labels \
 140         -Wcast-align \
 141         -Wstrict-aliasing=2 \
 142         -Wwrite-strings \
 143         -Wno-long-long \
 144         -Wno-overlength-strings \
 145         -Wno-unused-parameter \
 146         -Wno-missing-field-initializers \
 147         -Wno-unused-result \
 148         -Werror=overflow \
 149         -Wdate-time \
 150         -Wnested-externs \
 151         -ffast-math \
 152         -fno-common \
 153         -fdiagnostics-show-option \
 154         -fdiagnostics-color \
 155         -fno-strict-aliasing \
 156         -fvisibility=hidden \
 157         -ffunction-sections \
 158         -fdata-sections \
 159         -fstack-protector \
 160         --param=ssp-buffer-size=4])
 161 AS_CASE([$CFLAGS], [*-O[[12345\ ]]*],
 162         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 163                -flto])],
 164         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 165 AC_SUBST([OUR_CFLAGS], "$with_cflags $address_sanitizer_cflags")
 166
 167 AS_CASE([$CFLAGS], [*-O[[12345\ ]]*],
 168         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 169                -Wp,-D_FORTIFY_SOURCE=2])],
 170         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 171 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $address_sanitizer_cppflags")
 172
 173 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 174         -Wl,--as-needed \
 175         -Wl,--no-undefined \
 176         -Wl,--gc-sections \
 177         -Wl,-z,relro \
 178         -Wl,-z,now \
 179         -Wl,-fuse-ld=gold])
 180 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $address_sanitizer_ldflags")
 181
 182 AC_CHECK_SIZEOF(pid_t)
 183 AC_CHECK_SIZEOF(uid_t)
 184
 185 # ------------------------------------------------------------------------------
 186 # we use python to build the man page index, and for systemd-python
 187 have_python=no
 188 AC_ARG_WITH([python],
 189         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 190
 191 have_lxml=no
 192 AS_IF([test "x$with_python" != "xno"], [
 193         AM_PATH_PYTHON(,, [:])
 194         AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes], [have_lxml=no])
 195         AS_IF([test "$PYTHON" != : -a $have_lxml = yes], [have_python=yes])
 196 ])
 197 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 198 AS_IF([test "x$PYTHON_BINARY" = "x"],
 199       [AS_IF([test "x$have_python" = "xyes"],
 200              [PYTHON_BINARY="$(which "$PYTHON")"],
 201              [PYTHON_BINARY=/usr/bin/python])])
 202 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 203
 204 AS_IF([test "x$have_python" != "xyes" -a "x$enable_python_devel" = "xyes"],
 205       [AC_MSG_ERROR([*** python-devel support requires --with-python])])
 206
 207 have_python_devel=no
 208 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 209 AS_IF([test "x$have_python" = "xyes" -a "x$enable_python_devel" != "xno"], [
 210       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 211             [have_python_devel=yes],
 212             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 213                   [have_python_devel=yes],
 214                   [have_python_devel=no])])
 215       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 216             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 217       AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 218 ])
 219 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 220
 221 # ------------------------------------------------------------------------------
 222
 223 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 224 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 225 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 226
 227 # unconditionally pull-in librt with old glibc versions
 228 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 229
 230 save_LIBS="$LIBS"
 231 LIBS=
 232 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 233 CAP_LIBS="$LIBS"
 234 AC_SUBST(CAP_LIBS)
 235
 236 LIBS=
 237 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 238 RT_LIBS="$LIBS"
 239 AC_SUBST(RT_LIBS)
 240 LIBS="$save_LIBS"
 241
 242 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 243 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 244 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns], [], [], [[#include <sys/types.h>
 245 #include <unistd.h>
 246 #include <sys/mount.h>
 247 #include <fcntl.h>
 248 #include <sched.h>]])
 249
 250 # This makes sure pkg.m4 is available.
 251 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 252
 253 # ------------------------------------------------------------------------------
 254 have_dbus=no
 255 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 256 AS_IF([test "x$enable_dbus" != "xno"], [
 257         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 258                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 259                 [have_dbus=no])
 260         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 261                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 262 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 263
 264 # ------------------------------------------------------------------------------
 265 have_compat_libs=no
 266 AC_ARG_ENABLE([compat_libs], AS_HELP_STRING([--enable-compat-libs],[Enable creation of compatibility libraries]),
 267                 [case "${enableval}" in
 268                         yes) have_compat_libs=yes ;;
 269                         no) have_compat_libs=no ;;
 270                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libs) ;;
 271                 esac],
 272                 [have_compat_libs=no])
 273 AM_CONDITIONAL([ENABLE_COMPAT_LIBS], [test "$have_compat_libs" = "yes"])
 274
 275 # ------------------------------------------------------------------------------
 276 have_coverage=no
 277 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 278 if test "x$enable_coverage" = "xyes" ; then
 279         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 280         if test "x$lcov_found" = xno ; then
 281                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 282         else
 283                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 284                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 285                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 286                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 287                 else
 288                         have_coverage=yes
 289                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 290                         -fprofile-arcs \
 291                         -ftest-coverage])
 292                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 293                 fi
 294         fi
 295 fi
 296 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 297
 298 # ------------------------------------------------------------------------------
 299 have_kmod=no
 300 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 301 if test "x$enable_kmod" != "xno"; then
 302         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 303         if test "x$have_kmod" = "xyes"; then
 304                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 305                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 306                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 307         fi
 308         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 309                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 310         fi
 311 fi
 312 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 313
 314 # ------------------------------------------------------------------------------
 315 have_blkid=no
 316 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 317 if test "x$enable_blkid" != "xno"; then
 318         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 319                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 320         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 321                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 322         fi
 323 fi
 324 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 325
 326 # ------------------------------------------------------------------------------
 327 have_seccomp=no
 328 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 329 if test "x$enable_seccomp" != "xno"; then
 330         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 331                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 332                 have_seccomp=yes
 333                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 334                [have_seccomp=no])
 335         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 336                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 337         fi
 338 fi
 339 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 340
 341 # ------------------------------------------------------------------------------
 342 have_ima=yes
 343 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 344                 [case "${enableval}" in
 345                         yes) have_ima=yes ;;
 346                         no) have_ima=no ;;
 347                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 348                 esac],
 349                 [have_ima=yes])
 350
 351 if test "x${have_ima}" != xno ; then
 352         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 353 fi
 354
 355 # ------------------------------------------------------------------------------
 356 have_chkconfig=yes
 357 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 358                 [case "${enableval}" in
 359                         yes) have_chkconfig=yes ;;
 360                         no) have_chkconfig=no ;;
 361                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 362                 esac],
 363                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 364                 if test -z "$CHKCONFIG"; then
 365                         have_chkconfig=no
 366                 else
 367                         have_chkconfig=yes
 368                 fi])
 369
 370 if test "x${have_chkconfig}" != xno ; then
 371         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 372 fi
 373
 374 # ------------------------------------------------------------------------------
 375 have_selinux=no
 376 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 377 if test "x$enable_selinux" != "xno"; then
 378         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 379                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 380                  have_selinux=yes
 381                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 382                 [have_selinux=no])
 383         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 384                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 385         fi
 386 fi
 387 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 388
 389 AC_ARG_WITH(debug-shell,
 390         AS_HELP_STRING([--with-debug-shell=PATH],
 391                 [Path to debug shell binary]),
 392         [SUSHELL="$withval"],[
 393         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 394
 395 AC_SUBST(SUSHELL)
 396
 397 AC_ARG_WITH([debug-tty],
 398         AS_HELP_STRING([--with-debug-tty=PATH],
 399                 [Specify the tty device for debug shell]),
 400         [DEBUGTTY="$withval"],
 401         [DEBUGTTY=/dev/tty9])
 402
 403 AC_SUBST(DEBUGTTY)
 404
 405 # ------------------------------------------------------------------------------
 406 have_xz=no
 407 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 408 if test "x$enable_xz" != "xno"; then
 409         PKG_CHECK_MODULES(XZ, [ liblzma ],
 410                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 411         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 412                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 413         fi
 414 fi
 415 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 416
 417 # ------------------------------------------------------------------------------
 418 AC_ARG_ENABLE([tcpwrap],
 419         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 420                 [case "${enableval}" in
 421                         yes) have_tcpwrap=yes ;;
 422                         no) have_tcpwrap=no ;;
 423                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 424                 esac],
 425                 [have_tcpwrap=auto])
 426
 427 if test "x${have_tcpwrap}" != xno ; then
 428         ACX_LIBWRAP
 429         if test "x${LIBWRAP_LIBS}" = x ; then
 430                 if test "x$have_tcpwrap" = xyes ; then
 431                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 432                 fi
 433                 have_tcpwrap=no
 434         else
 435                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBWRAP"
 436                 have_tcpwrap=yes
 437         fi
 438 else
 439         LIBWRAP_LIBS=
 440 fi
 441 AC_SUBST(LIBWRAP_LIBS)
 442
 443 # ------------------------------------------------------------------------------
 444 AC_ARG_ENABLE([pam],
 445         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 446                 [case "${enableval}" in
 447                         yes) have_pam=yes ;;
 448                         no) have_pam=no ;;
 449                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 450                 esac],
 451                 [have_pam=auto])
 452
 453 if test "x${have_pam}" != xno ; then
 454         AC_CHECK_HEADERS(
 455                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 456                 [have_pam=yes],
 457                 [if test "x$have_pam" = xyes ; then
 458                         AC_MSG_ERROR([*** PAM headers not found.])
 459                 fi])
 460
 461         AC_CHECK_LIB(
 462                 [pam],
 463                 [pam_syslog],
 464                 [have_pam=yes],
 465                 [if test "x$have_pam" = xyes ; then
 466                         AC_MSG_ERROR([*** libpam not found.])
 467                 fi])
 468
 469         if test "x$have_pam" = xyes ; then
 470                 PAM_LIBS="-lpam -lpam_misc"
 471                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 472                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 473         else
 474                 have_pam=no
 475         fi
 476 else
 477         PAM_LIBS=
 478 fi
 479 AC_SUBST(PAM_LIBS)
 480 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 481
 482 # ------------------------------------------------------------------------------
 483 AC_ARG_ENABLE([acl],
 484         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 485                 [case "${enableval}" in
 486                         yes) have_acl=yes ;;
 487                         no) have_acl=no ;;
 488                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 489                 esac],
 490                 [have_acl=auto])
 491
 492 if test "x${have_acl}" != xno ; then
 493         AC_CHECK_HEADERS(
 494                 [sys/acl.h acl/libacl.h],
 495                 [have_acl=yes],
 496                 [if test "x$have_acl" = xyes ; then
 497                         AC_MSG_ERROR([*** ACL headers not found.])
 498                 fi])
 499
 500         AC_CHECK_LIB(
 501                 [acl],
 502                 [acl_get_file],
 503                 [have_acl=yes],
 504                 [if test "x$have_acl" = xyes ; then
 505                         AC_MSG_ERROR([*** libacl not found.])
 506                 fi])
 507
 508         if test "x$have_acl" = xyes ; then
 509                 ACL_LIBS="-lacl"
 510                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 511         else
 512                 have_acl=no
 513         fi
 514 else
 515         ACL_LIBS=
 516 fi
 517 AC_SUBST(ACL_LIBS)
 518 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 519
 520 # ------------------------------------------------------------------------------
 521 AC_ARG_ENABLE([xattr],
 522         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 523                 [case "${enableval}" in
 524                         yes) have_xattr=yes ;;
 525                         no) have_xattr=no ;;
 526                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 527                 esac],
 528                 [have_xattr=auto])
 529
 530 if test "x${have_xattr}" != xno ; then
 531         AC_CHECK_HEADERS(
 532                 [attr/xattr.h],
 533                 [have_xattr=yes],
 534                 [if test "x$have_xattr" = xyes ; then
 535                         AC_MSG_ERROR([*** XATTR headers not found.])
 536                 fi])
 537
 538         AC_CHECK_LIB(
 539                 [attr],
 540                 [fsetxattr],
 541                 [have_xattr=yes],
 542                 [if test "x$have_xattr" = xyes ; then
 543                         AC_MSG_ERROR([*** libattr not found.])
 544                 fi])
 545
 546         if test "x$have_xattr" = xyes ; then
 547                 XATTR_LIBS="-lattr"
 548                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 549         else
 550                 have_xattr=no
 551         fi
 552 else
 553         XATTR_LIBS=
 554 fi
 555 AC_SUBST(XATTR_LIBS)
 556 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 557
 558 # ------------------------------------------------------------------------------
 559 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 560                 [case "${enableval}" in
 561                         yes) have_smack=yes ;;
 562                         no) have_smack=no ;;
 563                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 564                 esac],
 565                 [have_smack=auto])
 566
 567 if test "x${have_xattr}" = xno; then
 568         if test "x${have_smack}" = xyes; then
 569                 AC_MSG_ERROR(SMACK requires xattr support)
 570         else
 571                 have_smack=no
 572         fi
 573 else
 574         if test "x${have_smack}" = xauto; then
 575                 M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 576                 have_smack=yes
 577         fi
 578 fi
 579
 580 AC_ARG_WITH(smack-run-label,
 581 AS_HELP_STRING([--with-smack-run-label=STRING],
 582         [run systemd --system with a specific SMACK label]),
 583         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 584         [])
 585
 586 if test "x${have_smack}" = xyes ; then
 587         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 588 fi
 589
 590 # ------------------------------------------------------------------------------
 591 AC_ARG_ENABLE([gcrypt],
 592         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 593                 [case "${enableval}" in
 594                         yes) have_gcrypt=yes ;;
 595                         no) have_gcrypt=no ;;
 596                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 597                 esac],
 598                 [have_gcrypt=auto])
 599
 600 if test "x${have_gcrypt}" != xno ; then
 601         AM_PATH_LIBGCRYPT(
 602                 [1.4.5],
 603                 [have_gcrypt=yes],
 604                 [if test "x$have_gcrypt" = xyes ; then
 605                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 606                 fi])
 607
 608         if test "x$have_gcrypt" = xyes ; then
 609                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 610                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 611                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 612         else
 613                 have_gcrypt=no
 614         fi
 615 else
 616         GCRYPT_LIBS=
 617         GCRYPT_CFLAGS=
 618 fi
 619 AC_SUBST(GCRYPT_LIBS)
 620 AC_SUBST(GCRYPT_CFLAGS)
 621 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 622
 623 # ------------------------------------------------------------------------------
 624 AC_ARG_ENABLE([audit],
 625         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 626                 [case "${enableval}" in
 627                         yes) have_audit=yes ;;
 628                         no) have_audit=no ;;
 629                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 630                 esac],
 631                 [have_audit=auto])
 632
 633 if test "x${have_audit}" != xno ; then
 634         AC_CHECK_HEADERS(
 635                 [libaudit.h],
 636                 [have_audit=yes],
 637                 [if test "x$have_audit" = xyes ; then
 638                         AC_MSG_ERROR([*** AUDIT headers not found.])
 639                 fi])
 640
 641         AC_CHECK_LIB(
 642                 [audit],
 643                 [audit_open],
 644                 [have_audit=yes],
 645                 [if test "x$have_audit" = xyes ; then
 646                         AC_MSG_ERROR([*** libaudit not found.])
 647                 fi])
 648
 649         if test "x$have_audit" = xyes ; then
 650                 AUDIT_LIBS="-laudit"
 651                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 652         else
 653                 have_audit=no
 654         fi
 655 else
 656         AUDIT_LIBS=
 657 fi
 658 AC_SUBST(AUDIT_LIBS)
 659
 660 # ------------------------------------------------------------------------------
 661 have_libcryptsetup=no
 662 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 663 if test "x$enable_libcryptsetup" != "xno"; then
 664         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 665                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 666         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 667                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 668         fi
 669 fi
 670 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 671
 672 # ------------------------------------------------------------------------------
 673 have_qrencode=no
 674 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 675 if test "x$enable_qrencode" != "xno"; then
 676         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 677                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 678         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 679                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 680         fi
 681 fi
 682 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 683
 684 # ------------------------------------------------------------------------------
 685 have_microhttpd=no
 686 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 687 if test "x$enable_microhttpd" != "xno"; then
 688         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 689                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 690         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 691                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 692         fi
 693 fi
 694 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 695
 696 # ------------------------------------------------------------------------------
 697 have_binfmt=no
 698 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 699 if test "x$enable_binfmt" != "xno"; then
 700         have_binfmt=yes
 701 fi
 702 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 703
 704 # ------------------------------------------------------------------------------
 705 have_vconsole=no
 706 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 707 if test "x$enable_vconsole" != "xno"; then
 708         have_vconsole=yes
 709 fi
 710 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 711
 712 # ------------------------------------------------------------------------------
 713 have_readahead=no
 714 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 715 if test "x$enable_readahead" != "xno"; then
 716         have_readahead=yes
 717 fi
 718 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 719
 720 # ------------------------------------------------------------------------------
 721 have_bootchart=no
 722 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 723 if test "x$enable_bootchart" != "xno"; then
 724         have_bootchart=yes
 725 fi
 726 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 727
 728 # ------------------------------------------------------------------------------
 729 have_quotacheck=no
 730 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 731 if test "x$enable_quotacheck" != "xno"; then
 732         have_quotacheck=yes
 733 fi
 734 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 735
 736 # ------------------------------------------------------------------------------
 737 have_tmpfiles=no
 738 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 739 if test "x$enable_tmpfiles" != "xno"; then
 740         have_tmpfiles=yes
 741 fi
 742 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 743
 744 # ------------------------------------------------------------------------------
 745 have_randomseed=no
 746 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 747 if test "x$enable_randomseed" != "xno"; then
 748         have_randomseed=yes
 749 fi
 750 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 751
 752 # ------------------------------------------------------------------------------
 753 have_backlight=no
 754 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 755 if test "x$enable_backlight" != "xno"; then
 756         have_backlight=yes
 757 fi
 758 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 759
 760 # ------------------------------------------------------------------------------
 761 have_rfkill=no
 762 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
 763 if test "x$enable_rfkill" != "xno"; then
 764         have_rfkill=yes
 765 fi
 766 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
 767
 768 # ------------------------------------------------------------------------------
 769 have_logind=no
 770 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 771 if test "x$enable_logind" != "xno"; then
 772         have_logind=yes
 773 fi
 774 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 775 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 776
 777 # ------------------------------------------------------------------------------
 778 have_machined=no
 779 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 780 if test "x$enable_machined" != "xno"; then
 781         have_machined=yes
 782 fi
 783 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 784 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 785
 786 # ------------------------------------------------------------------------------
 787 have_hostnamed=no
 788 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 789 if test "x$enable_hostnamed" != "xno"; then
 790         have_hostnamed=yes
 791 fi
 792 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 793
 794 # ------------------------------------------------------------------------------
 795 have_timedated=no
 796 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 797 if test "x$enable_timedated" != "xno"; then
 798         have_timedated=yes
 799 fi
 800 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 801
 802 # ------------------------------------------------------------------------------
 803 have_localed=no
 804 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 805 if test "x$enable_localed" != "xno"; then
 806         have_localed=yes
 807 fi
 808 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 809
 810 # ------------------------------------------------------------------------------
 811 have_coredump=no
 812 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 813 if test "x$enable_coredump" != "xno"; then
 814         have_coredump=yes
 815 fi
 816 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 817
 818 # ------------------------------------------------------------------------------
 819 have_polkit=no
 820 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 821 if test "x$enable_polkit" != "xno"; then
 822         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 823         have_polkit=yes
 824 fi
 825 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 826
 827 # ------------------------------------------------------------------------------
 828 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
 829 if test "x$enable_networkd" != "xno"; then
 830         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
 831         have_networkd=yes
 832 fi
 833 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
 834
 835 # ------------------------------------------------------------------------------
 836 have_efi=no
 837 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 838 if test "x$enable_efi" != "xno"; then
 839         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 840         have_efi=yes
 841 fi
 842 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 843
 844 # ------------------------------------------------------------------------------
 845 have_multi_seat_x=no
 846 AC_ARG_ENABLE(multi_seat_x, AS_HELP_STRING([--disable-multi-seat-x], [do not build multi-seat-x]))
 847 if test "x$enable_multi_seat_x" != "xno"; then
 848         have_multi_seat_x=yes
 849 fi
 850 AM_CONDITIONAL(ENABLE_MULTI_SEAT_X, [test "$have_multi_seat_x" = "yes"])
 851
 852 # ------------------------------------------------------------------------------
 853 have_kdbus=no
 854 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
 855 if test "x$enable_kdbus" = "xyes"; then
 856         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
 857         have_kdbus=yes
 858         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 859 fi
 860 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 861
 862 # ------------------------------------------------------------------------------
 863 AC_ARG_WITH(rc-local-script-path-start,
 864         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 865                 [Path to /etc/rc.local]),
 866         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 867         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 868
 869 AC_ARG_WITH(rc-local-script-path-stop,
 870         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 871                 [Path to /usr/sbin/halt.local]),
 872         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 873         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 874
 875 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 876 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 877
 878 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 879 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 880
 881 # ------------------------------------------------------------------------------
 882 AC_ARG_WITH(kbd-loadkeys,
 883         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 884                 [Path to loadkeys]),
 885         [KBD_LOADKEYS="$withval"],
 886         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 887
 888 AC_ARG_WITH(kbd-setfont,
 889         AS_HELP_STRING([--with-kbd-setfont=PATH],
 890                 [Path to setfont]),
 891         [KBD_SETFONT="$withval"],
 892         [KBD_SETFONT="/usr/bin/setfont"])
 893
 894 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 895 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 896
 897 AC_SUBST(KBD_LOADKEYS)
 898 AC_SUBST(KBD_SETFONT)
 899
 900 AC_ARG_WITH(telinit,
 901         AS_HELP_STRING([--with-telinit=PATH],
 902                 [Path to telinit]),
 903         [TELINIT="$withval"],
 904         [TELINIT="/lib/sysvinit/telinit"])
 905
 906 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 907
 908 AC_SUBST(TELINIT)
 909
 910 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 911
 912 # ------------------------------------------------------------------------------
 913 have_myhostname=no
 914 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 915 if test "x$enable_myhostname" != "xno"; then
 916         AC_HEADER_STDC
 917         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
 918
 919         AC_C_CONST
 920         AC_TYPE_SIZE_T
 921         AC_HEADER_TIME
 922
 923         AC_FUNC_MALLOC
 924         AC_FUNC_SELECT_ARGTYPES
 925         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 926
 927         have_myhostname=yes
 928 fi
 929 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 930
 931 # ------------------------------------------------------------------------------
 932 AC_ARG_WITH(firmware-path,
 933        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 934           [Firmware search path (default="")]),
 935        [], [with_firmware_path=""])
 936 OLD_IFS=$IFS
 937 IFS=:
 938 for i in $with_firmware_path; do
 939        if test "x${FIRMWARE_PATH}" = "x"; then
 940               FIRMWARE_PATH="\\\"${i}/\\\""
 941        else
 942               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 943        fi
 944 done
 945 IFS=$OLD_IFS
 946 AC_SUBST(FIRMWARE_PATH)
 947 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 948 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 949
 950 # ------------------------------------------------------------------------------
 951 AC_ARG_ENABLE([gudev],
 952        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 953        [], [enable_gudev=yes])
 954 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 955 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 956 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 957
 958 # ------------------------------------------------------------------------------
 959 have_manpages=no
 960 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 961 AS_IF([test "x$enable_manpages" != xno], [
 962         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 963                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 964         ])
 965         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 966 ])
 967 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 968
 969 # ------------------------------------------------------------------------------
 970
 971 # Location of the init scripts as mandated by LSB
 972 SYSTEM_SYSVINIT_PATH=/etc/init.d
 973 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 974
 975 AC_ARG_WITH([sysvinit-path],
 976         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 977                 [Specify the path to where the SysV init scripts are located])],
 978         [SYSTEM_SYSVINIT_PATH="$withval"],
 979         [])
 980
 981 AC_ARG_WITH([sysvrcnd-path],
 982         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 983                 [Specify the path to the base directory for the SysV rcN.d directories])],
 984         [SYSTEM_SYSVRCND_PATH="$withval"],
 985         [])
 986
 987 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 988         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 989         SYSTEM_SYSV_COMPAT="yes"
 990         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 991 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 992         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 993 else
 994         SYSTEM_SYSV_COMPAT="no"
 995 fi
 996
 997 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 998 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 999 AC_SUBST(M4_DEFINES)
1000
1001 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1002
1003 AC_ARG_WITH([tty-gid],
1004         [AS_HELP_STRING([--with-tty-gid=GID],
1005                 [Specify the numeric GID of the 'tty' group])],
1006         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
1007         [])
1008
1009 AC_ARG_WITH([dbuspolicydir],
1010         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1011         [],
1012         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
1013
1014 AC_ARG_WITH([dbussessionservicedir],
1015         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1016         [],
1017         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
1018
1019 AC_ARG_WITH([dbussystemservicedir],
1020         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1021         [],
1022         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
1023
1024 AC_ARG_WITH([dbusinterfacedir],
1025         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
1026         [],
1027         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
1028
1029 AC_ARG_WITH([bashcompletiondir],
1030         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1031         [],
1032         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1033                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1034         ] , [
1035                 with_bashcompletiondir=${datadir}/bash-completion/completions
1036         ])])
1037
1038 AC_ARG_WITH([zshcompletiondir],
1039         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1040         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1041
1042 AC_ARG_WITH([rootprefix],
1043         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1044         [], [with_rootprefix=${ac_default_prefix}])
1045
1046 AC_ARG_WITH([rootlibdir],
1047         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1048         [],
1049         [with_rootlibdir=${libdir}])
1050
1051 AC_ARG_WITH([pamlibdir],
1052         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1053         [],
1054         [with_pamlibdir=${with_rootlibdir}/security])
1055
1056 AC_ARG_WITH([pamconfdir],
1057         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1058         [],
1059         [with_pamconfdir=${sysconfdir}/pam.d])
1060
1061 AC_ARG_ENABLE([split-usr],
1062         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1063         [],
1064         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1065                 enable_split_usr=yes
1066         ], [
1067                 enable_split_usr=no
1068         ])])
1069
1070 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1071         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1072 ])
1073
1074 # Work around intltoolize and gtk-doc problems in VPATH builds
1075 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
1076                                        [Define to do gtk-doc tests])
1077 AS_IF([test "x$0" != "x./configure"], [
1078         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1079 ])
1080
1081 AC_ARG_ENABLE(tests,
1082        [AC_HELP_STRING([--disable-tests], [disable tests])],
1083        enable_tests=$enableval, enable_tests=yes)
1084 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1085
1086 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1087 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1088 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1089 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
1090 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1091 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1092 AC_SUBST([pamlibdir], [$with_pamlibdir])
1093 AC_SUBST([pamconfdir], [$with_pamconfdir])
1094 AC_SUBST([rootprefix], [$with_rootprefix])
1095 AC_SUBST([rootlibdir], [$with_rootlibdir])
1096
1097 AC_CONFIG_FILES([
1098         Makefile po/Makefile.in
1099         docs/libudev/Makefile
1100         docs/libudev/version.xml
1101         docs/gudev/Makefile
1102         docs/gudev/version.xml
1103 ])
1104
1105 AC_OUTPUT
1106 AC_MSG_RESULT([
1107         $PACKAGE_NAME $VERSION
1108
1109         libcryptsetup:           ${have_libcryptsetup}
1110         tcpwrap:                 ${have_tcpwrap}
1111         PAM:                     ${have_pam}
1112         AUDIT:                   ${have_audit}
1113         IMA:                     ${have_ima}
1114         SELinux:                 ${have_selinux}
1115         SECCOMP:                 ${have_seccomp}
1116         SMACK:                   ${have_smack}
1117         XZ:                      ${have_xz}
1118         ACL:                     ${have_acl}
1119         XATTR:                   ${have_xattr}
1120         GCRYPT:                  ${have_gcrypt}
1121         QRENCODE:                ${have_qrencode}
1122         MICROHTTPD:              ${have_microhttpd}
1123         CHKCONFIG:               ${have_chkconfig}
1124         binfmt:                  ${have_binfmt}
1125         vconsole:                ${have_vconsole}
1126         readahead:               ${have_readahead}
1127         bootchart:               ${have_bootchart}
1128         quotacheck:              ${have_quotacheck}
1129         tmpfiles:                ${have_tmpfiles}
1130         randomseed:              ${have_randomseed}
1131         backlight:               ${have_backlight}
1132         rfkill:                  ${have_rfkill}
1133         logind:                  ${have_logind}
1134         machined:                ${have_machined}
1135         hostnamed:               ${have_hostnamed}
1136         timedated:               ${have_timedated}
1137         localed:                 ${have_localed}
1138         coredump:                ${have_coredump}
1139         polkit:                  ${have_polkit}
1140         efi:                     ${have_efi}
1141         kmod:                    ${have_kmod}
1142         blkid:                   ${have_blkid}
1143         dbus:                    ${have_dbus}
1144         nss-myhostname:          ${have_myhostname}
1145         gudev:                   ${enable_gudev}
1146         gintrospection:          ${enable_introspection}
1147         multi-seat-x:            ${have_multi_seat_x}
1148         kdbus:                   ${have_kdbus}
1149         Python:                  ${have_python}
1150         Python Headers:          ${have_python_devel}
1151         man pages:               ${have_manpages}
1152         gtk-doc:                 ${enable_gtk_doc}
1153         test coverage:           ${have_coverage}
1154         Split /usr:              ${enable_split_usr}
1155         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1156         compatibility libraries: ${have_compat_libs}
1157
1158         prefix:                  ${prefix}
1159         rootprefix:              ${with_rootprefix}
1160         sysconf dir:             ${sysconfdir}
1161         datarootdir:             ${datarootdir}
1162         includedir:              ${includedir}
1163         include_prefix:          ${INCLUDE_PREFIX}
1164         lib dir:                 ${libdir}
1165         rootlib dir:             ${with_rootlibdir}
1166         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1167         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1168         Build Python:            ${PYTHON}
1169         Installation Python:     ${PYTHON_BINARY}
1170         sphinx binary:           ${SPHINX_BUILD}
1171         firmware path:           ${FIRMWARE_PATH}
1172         PAM modules dir:         ${with_pamlibdir}
1173         PAM configuration dir:   ${with_pamconfdir}
1174         D-Bus policy dir:        ${with_dbuspolicydir}
1175         D-Bus session dir:       ${with_dbussessionservicedir}
1176         D-Bus system dir:        ${with_dbussystemservicedir}
1177         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1178         Bash completions dir:    ${with_bashcompletiondir}
1179         Zsh completions dir:     ${with_zshcompletiondir}
1180         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1181         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1182         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1183
1184         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1185         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1186         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1187         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1188         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1189 ])