configure.ac

   1 #
   2 # Copyright (C) 2007-2014 Tobias Brunner
   3 # Copyright (C) 2006-2014 Andreas Steffen
   4 # Copyright (C) 2006-2014 Martin Willi
   5 # Hochschule fuer Technik Rapperswil
   6 #
   7 # This program is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by the
   9 # Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 # for more details.
  16 #
  17
  18 # ============================
  19 #  initialize & set some vars
  20 # ============================
  21
  22 AC_INIT([strongSwan],[5.2.2])
  23 AM_INIT_AUTOMAKE(m4_esyscmd([
  24         echo tar-ustar
  25         echo subdir-objects
  26         case `automake --version | head -n 1` in
  27                 *" 1.9"*);;
  28                 *" 1.10"*);;
  29                 *" 1.11"*);;
  30                 # don't use parallel test harness in 1.12 and up
  31                 *) echo serial-tests;;
  32         esac
  33 ]))
  34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  35 AC_CONFIG_MACRO_DIR([m4/config])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
  38 PKG_PROG_PKG_CONFIG
  39
  40 m4_include(m4/macros/split-package-version.m4)
  41 SPLIT_PACKAGE_VERSION
  42
  43 # =================================
  44 #  check --enable-xxx & --with-xxx
  45 # =================================
  46
  47 m4_include(m4/macros/with.m4)
  48
  49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
  50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
  51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
  52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
  53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
  54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
  55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
  56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
  57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
  58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
  59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
  60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
  61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
  62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
  63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
  64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
  65
  66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
  67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
  68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
  69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
  70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
  71 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
  72
  73 if test -n "$PKG_CONFIG"; then
  74         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
  75 fi
  76 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
  77 AC_SUBST(systemdsystemunitdir)
  78
  79 AC_ARG_WITH(
  80         [user],
  81         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
  82         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
  83          AC_SUBST(ipsecuser, "$withval")],
  84         [AC_SUBST(ipsecuser, "root")]
  85 )
  86
  87 AC_ARG_WITH(
  88         [group],
  89         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
  90         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
  91          AC_SUBST(ipsecgroup, "$withval")],
  92         [AC_SUBST(ipsecgroup, "root")]
  93 )
  94
  95 AC_ARG_WITH(
  96         [charon-udp-port],
  97         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
  98         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
  99          AC_SUBST(charon_udp_port, [$withval])],
 100         [AC_SUBST(charon_udp_port, 500)]
 101 )
 102
 103 AC_ARG_WITH(
 104         [charon-natt-port],
 105         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
 106         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
 107          AC_SUBST(charon_natt_port, [$withval])],
 108         [AC_SUBST(charon_natt_port, 4500)]
 109 )
 110
 111 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
 112 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
 113         AC_MSG_ERROR(the ports have to be different)
 114 else
 115         AC_MSG_RESULT(ok)
 116 fi
 117
 118 # convert script name to uppercase
 119 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
 120
 121 m4_include(m4/macros/enable-disable.m4)
 122
 123 # crypto plugins
 124 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
 125 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
 126 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
 127 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
 128 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
 129 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
 130 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
 131 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
 132 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
 133 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
 134 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
 135 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
 136 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
 137 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
 138 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
 139 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
 140 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
 141 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
 142 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
 143 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
 144 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
 145 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
 146 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
 147 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
 148 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
 149 # encoding/decoding plugins
 150 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
 151 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
 152 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
 153 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
 154 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
 155 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
 156 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
 157 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
 158 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
 159 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
 160 # fetcher/resolver plugins
 161 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
 162 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
 163 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
 164 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
 165 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
 166 # database plugins
 167 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
 168 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
 169 # authentication/credential plugins
 170 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
 171 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
 172 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
 173 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
 174 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
 175 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
 176 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
 177 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
 178 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
 179 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
 180 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
 181 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
 182 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
 183 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
 184 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
 185 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
 186 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
 187 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
 188 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
 189 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
 190 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
 191 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
 192 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
 193 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
 194 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
 195 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
 196 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
 197 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
 198 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
 199 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
 200 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
 201 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
 202 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
 203 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
 204 # kernel interfaces / sockets
 205 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
 206 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
 207 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
 208 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
 209 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
 210 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
 211 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
 212 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
 213 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
 214 # configuration/control plugins
 215 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
 216 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
 217 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
 218 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
 219 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
 220 # attribute provider/consumer plugins
 221 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
 222 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
 223 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
 224 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
 225 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
 226 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
 227 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
 228 # TNC modules/plugins
 229 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
 230 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
 231 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
 232 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
 233 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
 234 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
 235 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
 236 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
 237 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
 238 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
 239 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
 240 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
 241 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
 242 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
 243 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
 244 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
 245 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
 246 # misc plugins
 247 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
 248 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
 249 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
 250 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
 251 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
 252 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
 253 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
 254 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
 255 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
 256 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
 257 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
 258 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
 259 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
 260 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
 261 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
 262 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
 263 # programs/components
 264 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
 265 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
 266 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
 267 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
 268 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
 269 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
 270 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
 271 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
 272 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
 273 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
 274 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
 275 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
 276 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
 277 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
 278 ARG_ENABL_SET([svc],            [enable charon Windows service.])
 279 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
 280 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
 281 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
 282 # optional features
 283 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
 284 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
 285 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
 286 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
 287 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
 288 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
 289 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
 290 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
 291 ARG_ENABL_SET([ruby-gems],      [enable installation of provided ruby gems.])
 292 # compile options
 293 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
 294 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
 295 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
 296 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
 297
 298 # ===================================
 299 #  option to disable default options
 300 # ===================================
 301
 302 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
 303
 304 if test x$defaults = xfalse; then
 305         for option in $enabled_by_default; do
 306                 eval test x\${${option}_given} = xtrue && continue
 307                 eval $option=false
 308         done
 309 fi
 310
 311 # ==============================
 312 #  option to enable all options
 313 # ==============================
 314
 315 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
 316
 317 if test x$all_given = xtrue; then
 318         for option in $disabled_by_default; do
 319                 eval test x\${${option}_given} = xtrue && continue
 320                 eval $option=true
 321         done
 322 fi
 323
 324 # ===========================
 325 #  set up compiler and flags
 326 # ===========================
 327
 328 if test -z "$CFLAGS"; then
 329         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
 330 fi
 331 AC_PROG_CC
 332 AM_PROG_CC_C_O
 333
 334 AC_LIB_PREFIX
 335 AC_C_BIGENDIAN
 336
 337 # =========================
 338 #  check required programs
 339 # =========================
 340
 341 LT_INIT
 342 AC_PROG_INSTALL
 343 AC_PROG_EGREP
 344 AC_PROG_AWK
 345 AC_PROG_LEX
 346 AC_PROG_YACC
 347 AM_PATH_PYTHON(,,[:])
 348 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 349 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 350
 351 # because gperf is not needed by end-users we just report it but do not abort on failure
 352 AC_MSG_CHECKING([gperf version >= 3.0.0])
 353 if test -x "$GPERF"; then
 354         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
 355                 AC_MSG_RESULT([yes])
 356         else
 357                 AC_MSG_RESULT([no])
 358         fi
 359 else
 360         AC_MSG_RESULT([not found])
 361 fi
 362
 363 # ========================
 364 #  dependency calculation
 365 # ========================
 366
 367 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
 368         xauth_generic=false;
 369 fi
 370
 371 if test x$kernel_libipsec = xtrue; then
 372         libipsec=true;
 373 fi
 374
 375 if test x$eap_aka_3gpp2 = xtrue; then
 376         gmp=true;
 377 fi
 378
 379 if test x$eap_aka = xtrue; then
 380         fips_prf=true;
 381         simaka=true;
 382 fi
 383
 384 if test x$eap_sim = xtrue; then
 385         fips_prf=true;
 386         simaka=true;
 387 fi
 388
 389 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
 390         radius=true;
 391 fi
 392
 393 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
 394         tnc_tnccs=true;
 395 fi
 396
 397 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
 398         tls=true;
 399 fi
 400
 401 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
 402         imcv=true;
 403 fi
 404
 405 if test x$fips_prf = xtrue; then
 406         if test x$openssl = xfalse; then
 407                 sha1=true;
 408         fi
 409 fi
 410
 411 if test x$swanctl = xtrue; then
 412         vici=true
 413 fi
 414
 415 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
 416         xml=true
 417 fi
 418
 419 if test x$manager = xtrue; then
 420         fast=true
 421 fi
 422
 423 if test x$medsrv = xtrue; then
 424         mediation=true
 425         fast=true
 426 fi
 427
 428 if test x$medcli = xtrue; then
 429         mediation=true
 430 fi
 431
 432 # ===========================================
 433 #  check required libraries and header files
 434 # ===========================================
 435
 436 AC_HEADER_STDBOOL
 437 AC_FUNC_ALLOCA
 438 AC_FUNC_STRERROR_R
 439
 440 #  libraries needed on some platforms but not on others
 441 # ------------------------------------------------------
 442 saved_LIBS=$LIBS
 443
 444 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
 445 LIBS=""
 446 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 447 AC_SUBST(DLLIB)
 448
 449 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
 450 LIBS=""
 451 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
 452 AC_CHECK_FUNCS(backtrace)
 453 AC_SUBST(BTLIB)
 454
 455 # OpenSolaris needs libsocket and libnsl for socket()
 456 LIBS=""
 457 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
 458         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
 459 )
 460 AC_SUBST(SOCKLIB)
 461
 462 # Android has pthread_* functions in bionic (libc), others need libpthread
 463 LIBS=""
 464 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
 465 AC_SUBST(PTHREADLIB)
 466
 467 LIBS=$saved_LIBS
 468 # ------------------------------------------------------
 469
 470 AC_MSG_CHECKING(for dladdr)
 471 AC_COMPILE_IFELSE(
 472         [AC_LANG_PROGRAM(
 473                 [[#define _GNU_SOURCE
 474                   #include <dlfcn.h>]],
 475                 [[Dl_info* info = 0;
 476                   dladdr(0, info);]])],
 477         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
 478         [AC_MSG_RESULT([no])]
 479 )
 480
 481 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
 482 saved_LIBS=$LIBS
 483 LIBS=$PTHREADLIB
 484 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
 485 AC_RUN_IFELSE(
 486         [AC_LANG_SOURCE(
 487                 [[#include <pthread.h>
 488                   int main() { pthread_condattr_t attr;
 489                         pthread_condattr_init(&attr);
 490                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
 491         [AC_MSG_RESULT([yes]);
 492          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 493                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
 494         [AC_MSG_RESULT([no])],
 495         # Check existence of pthread_condattr_setclock if cross-compiling
 496         [AC_MSG_RESULT([unknown]);
 497          AC_CHECK_FUNCS(pthread_condattr_setclock,
 498                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 499                                    [have pthread_condattr_setclock()])]
 500         )]
 501 )
 502 # check if we actually are able to configure attributes on cond vars
 503 AC_CHECK_FUNCS(pthread_condattr_init)
 504 # instead of pthread_condattr_setclock Android has this function
 505 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
 506 # check if we can cancel threads
 507 AC_CHECK_FUNCS(pthread_cancel)
 508 # check if native rwlocks are available
 509 AC_CHECK_FUNCS(pthread_rwlock_init)
 510 # check if pthread spinlocks are available
 511 AC_CHECK_FUNCS(pthread_spin_init)
 512 # check if we have POSIX semaphore functions, including timed-wait
 513 AC_CHECK_FUNCS(sem_timedwait)
 514 LIBS=$saved_LIBS
 515
 516 AC_CHECK_FUNC(
 517         [gettid],
 518         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
 519         [AC_MSG_CHECKING([for SYS_gettid])
 520          AC_COMPILE_IFELSE(
 521                 [AC_LANG_PROGRAM(
 522                         [[#define _GNU_SOURCE
 523                           #include <unistd.h>
 524                           #include <sys/syscall.h>]],
 525                         [[int main() {
 526                           return syscall(SYS_gettid);}]])],
 527                 [AC_MSG_RESULT([yes]);
 528                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
 529                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
 530                 [AC_MSG_RESULT([no])]
 531         )]
 532 )
 533
 534 AC_CHECK_FUNC(
 535         [qsort_r],
 536         [
 537                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
 538                 # set -Werror so that we get an error for "argument ... has
 539                 # incompatible pointer type" warnings
 540                 save_CFLAGS="$CFLAGS"
 541                 CFLAGS="$CFLAGS -Werror"
 542                 AC_MSG_CHECKING([for GNU-style qsort_r])
 543                 AC_COMPILE_IFELSE(
 544                         [AC_LANG_PROGRAM(
 545                                 [[#define _GNU_SOURCE
 546                                   #include <stdlib.h>
 547                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
 548                                 [[int arr[] = { 0, 1 };
 549                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
 550                 [AC_MSG_RESULT([yes]);
 551                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
 552                 [
 553                         AC_MSG_RESULT([no]);
 554                         AC_MSG_CHECKING([for BSD-style qsort_r])
 555                         AC_COMPILE_IFELSE(
 556                                 [AC_LANG_PROGRAM(
 557                                         [[#include <stdlib.h>
 558                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
 559                                         [[int arr[] = { 0, 1 };
 560                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
 561                         [AC_MSG_RESULT([yes]);
 562                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
 563                         [AC_MSG_RESULT([no]);
 564                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
 565                 ])
 566                 CFLAGS="$save_CFLAGS"
 567         ]
 568 )
 569
 570 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
 571 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime)
 572
 573 AC_CHECK_FUNC([syslog], [
 574         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
 575         syslog=true
 576 ])
 577 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
 578
 579 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h)
 580 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
 581 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
 582 [
 583         #include <sys/types.h>
 584         #include <netinet/in.h>
 585 ])
 586
 587 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 588 [
 589         #include <sys/types.h>
 590         #include <sys/socket.h>
 591 ])
 592
 593 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 594 [
 595         #include <sys/types.h>
 596         #ifdef HAVE_NET_PFKEYV2_H
 597         #include <net/pfkeyv2.h>
 598         #else
 599         #include <stdint.h>
 600         #include <linux/pfkeyv2.h>
 601         #endif
 602 ])
 603
 604 AC_MSG_CHECKING([for in6addr_any])
 605 AC_COMPILE_IFELSE(
 606         [AC_LANG_PROGRAM(
 607                 [[#include <sys/types.h>
 608                   #include <sys/socket.h>
 609                   #include <netinet/in.h>]],
 610                 [[struct in6_addr in6 __attribute__((unused));
 611                   in6 = in6addr_any;]])],
 612         [AC_MSG_RESULT([yes]);
 613          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
 614         [AC_MSG_RESULT([no])]
 615 )
 616
 617 AC_MSG_CHECKING([for in6_pktinfo])
 618 AC_COMPILE_IFELSE(
 619         [AC_LANG_PROGRAM(
 620                 [[#define _GNU_SOURCE
 621                   #include <sys/types.h>
 622                   #include <sys/socket.h>
 623                   #include <netinet/in.h>]],
 624                 [[struct in6_pktinfo pi;
 625                   if (pi.ipi6_ifindex)
 626                   {
 627                     return 0;
 628                   }]])],
 629         [AC_MSG_RESULT([yes]);
 630          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
 631         [AC_MSG_RESULT([no])]
 632 )
 633
 634 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
 635 AC_COMPILE_IFELSE(
 636         [AC_LANG_PROGRAM(
 637                 [[#include <sys/socket.h>
 638                   #include <net/if.h>
 639                   #include <net/route.h>]],
 640                 [[return RTM_IFANNOUNCE;]])],
 641         [AC_MSG_RESULT([yes]);
 642          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
 643         [AC_MSG_RESULT([no])]
 644 )
 645
 646 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 647 AC_COMPILE_IFELSE(
 648         [AC_LANG_PROGRAM(
 649                 [[#include <sys/types.h>
 650                   #ifdef HAVE_NETIPSEC_IPSEC_H
 651                   #include <netipsec/ipsec.h>
 652                   #elif defined(HAVE_NETINET6_IPSEC_H)
 653                   #include <netinet6/ipsec.h>
 654                   #else
 655                   #include <stdint.h>
 656                   #include <linux/ipsec.h>
 657                   #endif]],
 658                 [[int mode = IPSEC_MODE_BEET;
 659                   return mode;]])],
 660         [AC_MSG_RESULT([yes]);
 661          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
 662         [AC_MSG_RESULT([no])]
 663 )
 664
 665 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 666 AC_COMPILE_IFELSE(
 667         [AC_LANG_PROGRAM(
 668                 [[#include <sys/types.h>
 669                   #ifdef HAVE_NETIPSEC_IPSEC_H
 670                   #include <netipsec/ipsec.h>
 671                   #elif defined(HAVE_NETINET6_IPSEC_H)
 672                   #include <netinet6/ipsec.h>
 673                   #else
 674                   #include <stdint.h>
 675                   #include <linux/ipsec.h>
 676                   #endif]],
 677                 [[int dir = IPSEC_DIR_FWD;
 678                   return dir;]])],
 679         [AC_MSG_RESULT([yes]);
 680          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
 681         [AC_MSG_RESULT([no])]
 682 )
 683
 684 AC_MSG_CHECKING([for RTA_TABLE])
 685 AC_COMPILE_IFELSE(
 686         [AC_LANG_PROGRAM(
 687                 [[#include <sys/socket.h>
 688                   #include <linux/netlink.h>
 689                   #include <linux/rtnetlink.h>]],
 690                 [[int rta_type = RTA_TABLE;
 691                   return rta_type;]])],
 692         [AC_MSG_RESULT([yes]);
 693          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
 694         [AC_MSG_RESULT([no])]
 695 )
 696
 697 AC_MSG_CHECKING([for GCC __sync operations])
 698 AC_RUN_IFELSE([AC_LANG_SOURCE(
 699         [[
 700                         int main() {
 701                         int ref = 1;
 702                         __sync_fetch_and_add (&ref, 1);
 703                         __sync_sub_and_fetch (&ref, 1);
 704                         __sync_val_compare_and_swap(&ref, 1, 0);
 705                         return ref;
 706                 }
 707         ]])],
 708         [AC_MSG_RESULT([yes]);
 709          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
 710                    [have GCC __sync_* operations])],
 711         [AC_MSG_RESULT([no])],
 712         [AC_MSG_RESULT([no])]
 713 )
 714
 715 case "$printf_hooks" in
 716 auto|builtin|glibc|vstr)
 717         ;;
 718 *)
 719         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
 720         printf_hooks=auto
 721         ;;
 722 esac
 723
 724 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
 725         # check for the new register_printf_specifier function with len argument,
 726         # or the deprecated register_printf_function without
 727         AC_CHECK_FUNC(
 728                 [register_printf_specifier],
 729                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
 730                 [AC_CHECK_FUNC(
 731                         [register_printf_function],
 732                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
 733                         [
 734                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
 735                                 if test x$printf_hooks = xglibc; then
 736                                         AC_MSG_ERROR([please select a different printf hook implementation])
 737                                 else
 738                                         # fallback to builtin printf hook implementation
 739                                         printf_hooks=builtin
 740                                 fi
 741                         ]
 742                 )]
 743         )
 744 fi
 745
 746 AC_MSG_CHECKING([for Windows target])
 747 AC_COMPILE_IFELSE(
 748         [AC_LANG_PROGRAM(
 749                 [[#include <windows.h>]],
 750                 [[#ifndef WIN32
 751                   # error WIN32 undefined
 752                   #endif
 753                 ]])],
 754         [
 755                 AC_MSG_RESULT([yes])
 756                 windows=true
 757                 openssl_lib=eay32
 758                 AC_SUBST(PTHREADLIB, "")
 759                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
 760                 case "$CFLAGS" in
 761                         *ms-bitfields*) ;;
 762                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
 763                 esac
 764         ],
 765         [
 766                 AC_MSG_RESULT([no])
 767                 openssl_lib=crypto
 768
 769                 # check for clock_gettime() on non-Windows only. Otherwise this
 770                 # check might find clock_gettime() in libwinpthread, but we don't want
 771                 # to link against it.
 772                 saved_LIBS=$LIBS
 773                 # FreeBSD has clock_gettime in libc, Linux needs librt
 774                 LIBS=""
 775                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
 776                 AC_CHECK_FUNCS(clock_gettime)
 777                 AC_SUBST(RTLIB)
 778                 LIBS=$saved_LIBS
 779         ]
 780 )
 781 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
 782 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
 783
 784 AC_MSG_CHECKING([for working __attribute__((packed))])
 785 AC_COMPILE_IFELSE(
 786         [AC_LANG_PROGRAM([], [[
 787                 struct test { char a; short b; } __attribute__((packed));
 788                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
 789                         __attribute__((unused));
 790                 return 0;
 791         ]])],
 792         [AC_MSG_RESULT([yes])],
 793         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
 794 )
 795
 796 AC_MSG_CHECKING([clang])
 797 AC_COMPILE_IFELSE(
 798         [AC_LANG_PROGRAM(
 799                 [], [[
 800                  #ifndef __clang__
 801                  # error not using LLVM clang
 802                  #endif
 803                 ]])],
 804         [
 805                 AC_MSG_RESULT([yes])
 806         ],
 807         [
 808                 AC_MSG_RESULT([no])
 809                 # GCC, but not MinGW requires -rdynamic for plugins
 810                 if test x$windows != xtrue; then
 811                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
 812                 fi
 813         ]
 814 )
 815
 816 if test x$printf_hooks = xvstr; then
 817         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
 818         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
 819 fi
 820
 821 if test x$printf_hooks = xbuiltin; then
 822         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
 823 fi
 824
 825 if test x$gmp = xtrue; then
 826         saved_LIBS=$LIBS
 827         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
 828         AC_MSG_CHECKING([mpz_powm_sec])
 829         if test x$mpz_powm_sec = xyes; then
 830                 AC_COMPILE_IFELSE(
 831                         [AC_LANG_PROGRAM(
 832                                 [[#include "gmp.h"]],
 833                                 [[void *x = mpz_powm_sec;]])],
 834                         [AC_MSG_RESULT([yes]);
 835                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
 836                         [AC_MSG_RESULT([no])]
 837                 )
 838         else
 839                 AC_MSG_RESULT([disabled])
 840         fi
 841         LIBS=$saved_LIBS
 842         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 843         AC_COMPILE_IFELSE(
 844                 [AC_LANG_PROGRAM(
 845                         [[#include "gmp.h"]],
 846                         [[
 847                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 848                                         #error bad gmp
 849                                 #endif]])],
 850                 [AC_MSG_RESULT([yes])],
 851                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 852         )
 853 fi
 854
 855 if test x$ldap = xtrue; then
 856         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
 857         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
 858         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 859 fi
 860
 861 if test x$curl = xtrue; then
 862         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
 863         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 864 fi
 865
 866 if test x$unbound = xtrue; then
 867         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
 868         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
 869         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
 870         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
 871 fi
 872
 873 if test x$soup = xtrue; then
 874         PKG_CHECK_MODULES(soup, [libsoup-2.4])
 875         AC_SUBST(soup_CFLAGS)
 876         AC_SUBST(soup_LIBS)
 877 fi
 878
 879 if test x$xml = xtrue; then
 880         PKG_CHECK_MODULES(xml, [libxml-2.0])
 881         AC_SUBST(xml_CFLAGS)
 882         AC_SUBST(xml_LIBS)
 883 fi
 884
 885 if test x$systemd = xtrue; then
 886         AC_MSG_CHECKING([for systemd system unit directory])
 887         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 888                 AC_MSG_RESULT([$systemdsystemunitdir])
 889         else
 890                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 891         fi
 892
 893         PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
 894         AC_SUBST(systemd_daemon_CFLAGS)
 895         AC_SUBST(systemd_daemon_LIBS)
 896
 897         PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
 898         AC_SUBST(systemd_journal_CFLAGS)
 899         AC_SUBST(systemd_journal_LIBS)
 900 fi
 901
 902 if test x$tss = xtrousers; then
 903         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
 904         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
 905         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
 906 fi
 907
 908 if test x$imv_swid = xtrue; then
 909         PKG_CHECK_MODULES(json, [json-c], [],
 910                 [PKG_CHECK_MODULES(json, [json])])
 911         AC_SUBST(json_CFLAGS)
 912         AC_SUBST(json_LIBS)
 913 fi
 914
 915 if test x$dumm = xtrue; then
 916         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
 917         AC_SUBST(gtk_CFLAGS)
 918         AC_SUBST(gtk_LIBS)
 919         AC_CHECK_PROGS(RUBY, ruby)
 920         AC_MSG_CHECKING([for Ruby header files])
 921         if test -n "$RUBY"; then
 922                 RUBYINCLUDE=
 923                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
 924                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 925                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
 926                         if test -n "$RUBYARCH"; then
 927                                 AC_MSG_RESULT([$RUBYDIR])
 928                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
 929                         fi
 930                 else
 931                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
 932                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 933                                 AC_MSG_RESULT([$RUBYDIR])
 934                                 RUBYINCLUDE="-I$RUBYDIR"
 935                         fi
 936                 fi
 937                 if test -z "$RUBYINCLUDE"; then
 938                         AC_MSG_ERROR([ruby.h not found])
 939                 fi
 940                 AC_SUBST(RUBYINCLUDE)
 941         else
 942                 AC_MSG_ERROR([don't know how to run ruby])
 943         fi
 944         AC_MSG_CHECKING([for libruby])
 945         saved_LIBS=$LIBS
 946         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
 947         AC_TRY_LINK_FUNC(ruby_init,
 948                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
 949                 [AC_MSG_ERROR([not found])])
 950         AC_SUBST(RUBYLIB)
 951         AC_CHECK_FUNCS(rb_errinfo)
 952         LIBS=$saved_LIBS
 953 fi
 954
 955 if test x$fast = xtrue; then
 956         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
 957         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
 958         AC_MSG_CHECKING([ClearSilver requires zlib])
 959         saved_CFLAGS=$CFLAGS
 960         saved_LIBS=$LIBS
 961         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
 962         CFLAGS="-I/usr/include/ClearSilver"
 963         AC_LINK_IFELSE(
 964                 [AC_LANG_PROGRAM(
 965                         [[#include <ClearSilver.h>]],
 966                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
 967                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
 968                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
 969         )
 970         AC_SUBST(clearsilver_LIBS)
 971         LIBS=$saved_LIBS
 972         CFLAGS=$saved_CFLAGS
 973 # autoconf does not like CamelCase!? How to fix this?
 974 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
 975
 976         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
 977         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
 978 fi
 979
 980 if test x$mysql = xtrue; then
 981         if test "x$windows" = xtrue; then
 982                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
 983                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
 984                 AC_SUBST(MYSQLLIB, -lmysql)
 985         else
 986                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 987                 if test x$MYSQLCONFIG = x; then
 988                         AC_MSG_ERROR([mysql_config not found!])
 989                 fi
 990                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
 991                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
 992         fi
 993 fi
 994
 995 if test x$sqlite = xtrue; then
 996         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
 997         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
 998         AC_MSG_CHECKING([sqlite3_prepare_v2])
 999         AC_COMPILE_IFELSE(
1000                 [AC_LANG_PROGRAM(
1001                         [[#include <sqlite3.h>]],
1002                         [[void *test = sqlite3_prepare_v2;]])],
1003                 [AC_MSG_RESULT([yes]);
1004                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1005                 [AC_MSG_RESULT([no])]
1006         )
1007         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1008         AC_COMPILE_IFELSE(
1009                 [AC_LANG_PROGRAM(
1010                         [[#include <sqlite3.h>]],
1011                         [[
1012                                 #if SQLITE_VERSION_NUMBER < 3003001
1013                                         #error bad sqlite
1014                                 #endif]])],
1015                 [AC_MSG_RESULT([yes])],
1016                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1017         )
1018 fi
1019
1020 if test x$openssl = xtrue; then
1021         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
1022         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1023 fi
1024
1025 if test x$gcrypt = xtrue; then
1026         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1027         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1028         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1029         AC_COMPILE_IFELSE(
1030                 [AC_LANG_PROGRAM(
1031                         [[#include <gcrypt.h>]],
1032                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1033                 [AC_MSG_RESULT([yes]);
1034                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1035                 [AC_MSG_RESULT([no])]
1036         )
1037 fi
1038
1039 if test x$uci = xtrue; then
1040         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1041         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1042 fi
1043
1044 if test x$android_dns = xtrue; then
1045         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1046         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1047         # we have to force the use of libdl here because the autodetection
1048         # above does not work correctly when cross-compiling for android.
1049         DLLIB="-ldl"
1050         AC_SUBST(DLLIB)
1051 fi
1052
1053 if test x$maemo = xtrue; then
1054         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1055         AC_SUBST(maemo_CFLAGS)
1056         AC_SUBST(maemo_LIBS)
1057         dbusservicedir="/usr/share/dbus-1/system-services"
1058         AC_SUBST(dbusservicedir)
1059 fi
1060
1061 if test x$eap_sim_pcsc = xtrue; then
1062         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1063         AC_SUBST(pcsclite_CFLAGS)
1064         AC_SUBST(pcsclite_LIBS)
1065 fi
1066
1067 if test x$nm = xtrue; then
1068         PKG_CHECK_EXISTS([libnm-glib],
1069                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1070                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1071         )
1072         AC_SUBST(nm_CFLAGS)
1073         AC_SUBST(nm_LIBS)
1074 fi
1075
1076 if test x$xauth_pam = xtrue; then
1077         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1078         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1079 fi
1080
1081 if test x$capabilities = xnative; then
1082         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1083         # Linux requires the following for capset(), Android does not have it,
1084         # but defines capset() in unistd.h instead.
1085         AC_CHECK_HEADERS([sys/capability.h])
1086         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1087         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1088 fi
1089
1090 if test x$capabilities = xlibcap; then
1091         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1092         AC_CHECK_HEADER([sys/capability.h],
1093                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1094                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1095         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1096 fi
1097
1098 if test x$integrity_test = xtrue; then
1099         AC_MSG_CHECKING([for dladdr()])
1100         AC_COMPILE_IFELSE(
1101                 [AC_LANG_PROGRAM(
1102                         [[#define _GNU_SOURCE
1103                           #include <dlfcn.h>]],
1104                         [[Dl_info info; dladdr(main, &info);]])],
1105                 [AC_MSG_RESULT([yes])],
1106                 [AC_MSG_RESULT([no]);
1107                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1108         )
1109         AC_MSG_CHECKING([for dl_iterate_phdr()])
1110         AC_COMPILE_IFELSE(
1111                 [AC_LANG_PROGRAM(
1112                         [[#define _GNU_SOURCE
1113                           #include <link.h>]],
1114                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1115                 [AC_MSG_RESULT([yes])],
1116                 [AC_MSG_RESULT([no]);
1117                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1118         )
1119 fi
1120
1121 if test x$bfd_backtraces = xtrue; then
1122         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1123         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1124                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1125         BFDLIB="-lbfd"
1126         AC_SUBST(BFDLIB)
1127 fi
1128
1129 if test x$unwind_backtraces = xtrue; then
1130         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1131         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1132                 [AC_MSG_ERROR([libunwind.h header not found!])])
1133         UNWINDLIB="-lunwind"
1134         AC_SUBST(UNWINDLIB)
1135 fi
1136
1137 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1138 if test x$dev_headers = xyes; then
1139         dev_headers="$includedir/strongswan"
1140 fi
1141 AC_SUBST(dev_headers)
1142
1143 CFLAGS="$CFLAGS -include `pwd`/config.h"
1144
1145 if test x$tkm = xtrue; then
1146         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1147         if test x$GPRBUILD = x; then
1148                 AC_MSG_ERROR([gprbuild not found])
1149         fi
1150 fi
1151
1152 if test x$coverage = xtrue; then
1153         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1154         if test x$LCOV = x; then
1155                 AC_MSG_ERROR([lcov not found])
1156         fi
1157         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1158         if test x$GENHTML = x; then
1159                 AC_MSG_ERROR([genhtml not found])
1160         fi
1161
1162         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1163         COVERAGE_LDFLAGS="-fprofile-arcs"
1164         AC_SUBST(COVERAGE_CFLAGS)
1165         AC_SUBST(COVERAGE_LDFLAGS)
1166
1167         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1168         CFLAGS="${CFLAGS} -g -O0"
1169 fi
1170
1171 if test x$ruby_gems = xtrue; then
1172         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1173         if test x$GEM = x; then
1174                 AC_MSG_ERROR(RubyGems package manager not found)
1175         fi
1176         if test "x$rubygemdir" = "xgem environment gemdir"; then
1177                 rubygemdir=$($GEM environment gemdir)
1178         fi
1179         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1180 fi
1181
1182 # ===============================================
1183 #  collect plugin list for strongSwan components
1184 # ===============================================
1185
1186 m4_include(m4/macros/add-plugin.m4)
1187
1188 # plugin lists for all components
1189 charon_plugins=
1190 starter_plugins=
1191 pool_plugins=
1192 attest_plugins=
1193 scepclient_plugins=
1194 pki_plugins=
1195 scripts_plugins=
1196 manager_plugins=
1197 medsrv_plugins=
1198 nm_plugins=
1199 cmd_plugins=
1200 aikgen_plugins=
1201
1202 # location specific lists for checksumming,
1203 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1204 c_plugins=
1205 h_plugins=
1206 s_plugins=
1207 t_plugins=
1208
1209 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1210 ADD_PLUGIN([unbound],              [s charon scripts])
1211 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1212 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1213 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1214 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1215 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1216 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1217 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1218 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1219 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1220 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1221 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1222 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1223 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1224 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1225 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1226 ADD_PLUGIN([constraints],          [s charon nm cmd])
1227 ADD_PLUGIN([acert],                [s charon])
1228 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1229 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1230 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1231 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1232 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1233 ADD_PLUGIN([pgp],                  [s charon])
1234 ADD_PLUGIN([dnskey],               [s charon pki])
1235 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1236 ADD_PLUGIN([dnscert],              [c charon])
1237 ADD_PLUGIN([ipseckey],             [c charon])
1238 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1239 ADD_PLUGIN([padlock],              [s charon])
1240 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1241 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1242 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1243 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1244 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1245 ADD_PLUGIN([agent],                [s charon nm cmd])
1246 ADD_PLUGIN([keychain],             [s charon cmd])
1247 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1248 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1249 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1250 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1251 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1252 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1253 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1254 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1255 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1256 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1257 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1258 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1259 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1260 ADD_PLUGIN([attr],                 [c charon])
1261 ADD_PLUGIN([attr-sql],             [c charon])
1262 ADD_PLUGIN([load-tester],          [c charon])
1263 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1264 ADD_PLUGIN([kernel-wfp],           [c charon])
1265 ADD_PLUGIN([kernel-iph],           [c charon])
1266 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1267 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1268 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1269 ADD_PLUGIN([resolve],              [c charon cmd])
1270 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1271 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1272 ADD_PLUGIN([socket-win],           [c charon])
1273 ADD_PLUGIN([connmark],             [c charon])
1274 ADD_PLUGIN([forecast],             [c charon])
1275 ADD_PLUGIN([farp],                 [c charon])
1276 ADD_PLUGIN([stroke],               [c charon])
1277 ADD_PLUGIN([vici],                 [c charon])
1278 ADD_PLUGIN([smp],                  [c charon])
1279 ADD_PLUGIN([sql],                  [c charon])
1280 ADD_PLUGIN([updown],               [c charon])
1281 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1282 ADD_PLUGIN([eap-sim],              [c charon])
1283 ADD_PLUGIN([eap-sim-file],         [c charon])
1284 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1285 ADD_PLUGIN([eap-aka],              [c charon])
1286 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1287 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1288 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1289 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1290 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1291 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1292 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1293 ADD_PLUGIN([eap-dynamic],          [c charon])
1294 ADD_PLUGIN([eap-radius],           [c charon])
1295 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1296 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1297 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1298 ADD_PLUGIN([eap-tnc],              [c charon])
1299 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1300 ADD_PLUGIN([xauth-eap],            [c charon])
1301 ADD_PLUGIN([xauth-pam],            [c charon])
1302 ADD_PLUGIN([xauth-noauth],         [c charon])
1303 ADD_PLUGIN([tnc-ifmap],            [c charon])
1304 ADD_PLUGIN([tnc-pdp],              [c charon])
1305 ADD_PLUGIN([tnc-imc],              [t charon])
1306 ADD_PLUGIN([tnc-imv],              [t charon])
1307 ADD_PLUGIN([tnc-tnccs],            [t charon])
1308 ADD_PLUGIN([tnccs-20],             [t charon])
1309 ADD_PLUGIN([tnccs-11],             [t charon])
1310 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1311 ADD_PLUGIN([medsrv],               [c charon])
1312 ADD_PLUGIN([medcli],               [c charon])
1313 ADD_PLUGIN([dhcp],                 [c charon])
1314 ADD_PLUGIN([osx-attr],             [c charon cmd])
1315 ADD_PLUGIN([android-dns],          [c charon])
1316 ADD_PLUGIN([android-log],          [c charon])
1317 ADD_PLUGIN([ha],                   [c charon])
1318 ADD_PLUGIN([whitelist],            [c charon])
1319 ADD_PLUGIN([ext-auth],             [c charon])
1320 ADD_PLUGIN([lookip],               [c charon])
1321 ADD_PLUGIN([error-notify],         [c charon])
1322 ADD_PLUGIN([certexpire],           [c charon])
1323 ADD_PLUGIN([systime-fix],          [c charon])
1324 ADD_PLUGIN([led],                  [c charon])
1325 ADD_PLUGIN([duplicheck],           [c charon])
1326 ADD_PLUGIN([coupling],             [c charon])
1327 ADD_PLUGIN([radattr],              [c charon])
1328 ADD_PLUGIN([maemo],                [c charon])
1329 ADD_PLUGIN([uci],                  [c charon])
1330 ADD_PLUGIN([addrblock],            [c charon])
1331 ADD_PLUGIN([unity],                [c charon])
1332
1333 AC_SUBST(charon_plugins)
1334 AC_SUBST(starter_plugins)
1335 AC_SUBST(pool_plugins)
1336 AC_SUBST(attest_plugins)
1337 AC_SUBST(scepclient_plugins)
1338 AC_SUBST(pki_plugins)
1339 AC_SUBST(scripts_plugins)
1340 AC_SUBST(manager_plugins)
1341 AC_SUBST(medsrv_plugins)
1342 AC_SUBST(nm_plugins)
1343 AC_SUBST(cmd_plugins)
1344 AC_SUBST(aikgen_plugins)
1345
1346 AC_SUBST(c_plugins)
1347 AC_SUBST(h_plugins)
1348 AC_SUBST(s_plugins)
1349 AC_SUBST(t_plugins)
1350
1351 # ======================
1352 #  set Makefile.am vars
1353 # ======================
1354
1355 #  libstrongswan plugins
1356 # -----------------------
1357 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1358 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1359 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1360 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1361 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1362 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1363 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1364 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1365 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1366 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1367 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1368 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1369 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1370 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1371 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1372 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1373 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1374 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1375 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1376 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1377 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1378 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1379 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1380 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1381 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1382 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1383 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1384 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1385 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1386 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1387 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1388 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1389 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1390 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1391 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1392 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1393 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1394 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1395 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1396 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1397 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1398 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1399 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1400 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1401 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1402 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1403 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1404 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1405 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1406
1407 #  charon plugins
1408 # ----------------
1409 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1410 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1411 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1412 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1413 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1414 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1415 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1416 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1417 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1418 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1419 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1420 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1421 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1422 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1423 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1424 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1425 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1426 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1427 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1428 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1429 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1430 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1431 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1432 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1433 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1434 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1435 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1436 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1437 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1438 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1439 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1440 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1441 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1442 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1443 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1444 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1445 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1446 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1447 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1448 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1449 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1450 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1451 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1452 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1453 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1454 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1455 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1456 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1457 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1458 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1459 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1460 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1461 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1462 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1463 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1464 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1465 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1466 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1467 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1468 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1469 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1470 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1471 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1472 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1473 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1474 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1475 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1476 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1477 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1478 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1479 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1480 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1481 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1482 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1483 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1484 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1485 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1486 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1487 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1488 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1489 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1490
1491 #  hydra plugins
1492 # ---------------
1493 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1494 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1495 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1496
1497 #  other options
1498 # ---------------
1499 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1500 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1501 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1502 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1503 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1504 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1505 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1506 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1507 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1508 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1509 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1510 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1511 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1512 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1513 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1514 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1515 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1516 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1517 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1518 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1519 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1520 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1521 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1522 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1523 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1524 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1525 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1526 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1527 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1528 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1529 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1530 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1531 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1532 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1533 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1534 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1535 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1536 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1537 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1538 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1539 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1540 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1541 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1542 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1543 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1544 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1545 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1546
1547 # ========================
1548 #  set global definitions
1549 # ========================
1550
1551 if test x$mediation = xtrue; then
1552         AC_DEFINE([ME], [], [mediation extension support])
1553 fi
1554 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1555         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1556 fi
1557 if test x$monolithic = xtrue; then
1558         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1559 fi
1560 if test x$ikev1 = xtrue; then
1561         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1562 fi
1563 if test x$ikev2 = xtrue; then
1564         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1565 fi
1566
1567 # ====================================================
1568 #  options for enabled modules (see conf/Makefile.am)
1569 # ====================================================
1570
1571 strongswan_options=
1572
1573 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1574 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1575 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1576 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1577 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1578 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1579 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1580 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1581 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1582 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1583 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1584 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1585 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1586
1587 AC_SUBST(strongswan_options)
1588
1589 # =================
1590 #  build Makefiles
1591 # =================
1592
1593 AC_CONFIG_FILES([
1594         Makefile
1595         conf/Makefile
1596         man/Makefile
1597         init/Makefile
1598         init/systemd/Makefile
1599         init/systemd-swanctl/Makefile
1600         src/Makefile
1601         src/include/Makefile
1602         src/libstrongswan/Makefile
1603         src/libstrongswan/plugins/aes/Makefile
1604         src/libstrongswan/plugins/cmac/Makefile
1605         src/libstrongswan/plugins/des/Makefile
1606         src/libstrongswan/plugins/blowfish/Makefile
1607         src/libstrongswan/plugins/rc2/Makefile
1608         src/libstrongswan/plugins/md4/Makefile
1609         src/libstrongswan/plugins/md5/Makefile
1610         src/libstrongswan/plugins/sha1/Makefile
1611         src/libstrongswan/plugins/sha2/Makefile
1612         src/libstrongswan/plugins/fips_prf/Makefile
1613         src/libstrongswan/plugins/gmp/Makefile
1614         src/libstrongswan/plugins/rdrand/Makefile
1615         src/libstrongswan/plugins/random/Makefile
1616         src/libstrongswan/plugins/nonce/Makefile
1617         src/libstrongswan/plugins/hmac/Makefile
1618         src/libstrongswan/plugins/xcbc/Makefile
1619         src/libstrongswan/plugins/x509/Makefile
1620         src/libstrongswan/plugins/revocation/Makefile
1621         src/libstrongswan/plugins/constraints/Makefile
1622         src/libstrongswan/plugins/acert/Makefile
1623         src/libstrongswan/plugins/pubkey/Makefile
1624         src/libstrongswan/plugins/pkcs1/Makefile
1625         src/libstrongswan/plugins/pkcs7/Makefile
1626         src/libstrongswan/plugins/pkcs8/Makefile
1627         src/libstrongswan/plugins/pkcs12/Makefile
1628         src/libstrongswan/plugins/pgp/Makefile
1629         src/libstrongswan/plugins/dnskey/Makefile
1630         src/libstrongswan/plugins/sshkey/Makefile
1631         src/libstrongswan/plugins/pem/Makefile
1632         src/libstrongswan/plugins/curl/Makefile
1633         src/libstrongswan/plugins/winhttp/Makefile
1634         src/libstrongswan/plugins/unbound/Makefile
1635         src/libstrongswan/plugins/soup/Makefile
1636         src/libstrongswan/plugins/ldap/Makefile
1637         src/libstrongswan/plugins/mysql/Makefile
1638         src/libstrongswan/plugins/sqlite/Makefile
1639         src/libstrongswan/plugins/padlock/Makefile
1640         src/libstrongswan/plugins/openssl/Makefile
1641         src/libstrongswan/plugins/gcrypt/Makefile
1642         src/libstrongswan/plugins/agent/Makefile
1643         src/libstrongswan/plugins/keychain/Makefile
1644         src/libstrongswan/plugins/pkcs11/Makefile
1645         src/libstrongswan/plugins/ctr/Makefile
1646         src/libstrongswan/plugins/ccm/Makefile
1647         src/libstrongswan/plugins/gcm/Makefile
1648         src/libstrongswan/plugins/af_alg/Makefile
1649         src/libstrongswan/plugins/ntru/Makefile
1650         src/libstrongswan/plugins/bliss/Makefile
1651         src/libstrongswan/plugins/bliss/tests/Makefile
1652         src/libstrongswan/plugins/test_vectors/Makefile
1653         src/libstrongswan/tests/Makefile
1654         src/libhydra/Makefile
1655         src/libhydra/plugins/kernel_netlink/Makefile
1656         src/libhydra/plugins/kernel_pfkey/Makefile
1657         src/libhydra/plugins/kernel_pfroute/Makefile
1658         src/libhydra/tests/Makefile
1659         src/libipsec/Makefile
1660         src/libsimaka/Makefile
1661         src/libtls/Makefile
1662         src/libtls/tests/Makefile
1663         src/libradius/Makefile
1664         src/libtncif/Makefile
1665         src/libtnccs/Makefile
1666         src/libtnccs/plugins/tnc_tnccs/Makefile
1667         src/libtnccs/plugins/tnc_imc/Makefile
1668         src/libtnccs/plugins/tnc_imv/Makefile
1669         src/libtnccs/plugins/tnccs_11/Makefile
1670         src/libtnccs/plugins/tnccs_20/Makefile
1671         src/libtnccs/plugins/tnccs_dynamic/Makefile
1672         src/libpttls/Makefile
1673         src/libimcv/Makefile
1674         src/libimcv/plugins/imc_test/Makefile
1675         src/libimcv/plugins/imv_test/Makefile
1676         src/libimcv/plugins/imc_scanner/Makefile
1677         src/libimcv/plugins/imv_scanner/Makefile
1678         src/libimcv/plugins/imc_os/Makefile
1679         src/libimcv/plugins/imv_os/Makefile
1680         src/libimcv/plugins/imc_attestation/Makefile
1681         src/libimcv/plugins/imv_attestation/Makefile
1682         src/libimcv/plugins/imc_swid/Makefile
1683         src/libimcv/plugins/imv_swid/Makefile
1684         src/charon/Makefile
1685         src/charon-nm/Makefile
1686         src/charon-tkm/Makefile
1687         src/charon-cmd/Makefile
1688         src/charon-svc/Makefile
1689         src/charon-systemd/Makefile
1690         src/libcharon/Makefile
1691         src/libcharon/plugins/eap_aka/Makefile
1692         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1693         src/libcharon/plugins/eap_dynamic/Makefile
1694         src/libcharon/plugins/eap_identity/Makefile
1695         src/libcharon/plugins/eap_md5/Makefile
1696         src/libcharon/plugins/eap_gtc/Makefile
1697         src/libcharon/plugins/eap_sim/Makefile
1698         src/libcharon/plugins/eap_sim_file/Makefile
1699         src/libcharon/plugins/eap_sim_pcsc/Makefile
1700         src/libcharon/plugins/eap_simaka_sql/Makefile
1701         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1702         src/libcharon/plugins/eap_simaka_reauth/Makefile
1703         src/libcharon/plugins/eap_mschapv2/Makefile
1704         src/libcharon/plugins/eap_tls/Makefile
1705         src/libcharon/plugins/eap_ttls/Makefile
1706         src/libcharon/plugins/eap_peap/Makefile
1707         src/libcharon/plugins/eap_tnc/Makefile
1708         src/libcharon/plugins/eap_radius/Makefile
1709         src/libcharon/plugins/xauth_generic/Makefile
1710         src/libcharon/plugins/xauth_eap/Makefile
1711         src/libcharon/plugins/xauth_pam/Makefile
1712         src/libcharon/plugins/xauth_noauth/Makefile
1713         src/libcharon/plugins/tnc_ifmap/Makefile
1714         src/libcharon/plugins/tnc_pdp/Makefile
1715         src/libcharon/plugins/socket_default/Makefile
1716         src/libcharon/plugins/socket_dynamic/Makefile
1717         src/libcharon/plugins/socket_win/Makefile
1718         src/libcharon/plugins/connmark/Makefile
1719         src/libcharon/plugins/forecast/Makefile
1720         src/libcharon/plugins/farp/Makefile
1721         src/libcharon/plugins/smp/Makefile
1722         src/libcharon/plugins/sql/Makefile
1723         src/libcharon/plugins/dnscert/Makefile
1724         src/libcharon/plugins/ipseckey/Makefile
1725         src/libcharon/plugins/medsrv/Makefile
1726         src/libcharon/plugins/medcli/Makefile
1727         src/libcharon/plugins/addrblock/Makefile
1728         src/libcharon/plugins/unity/Makefile
1729         src/libcharon/plugins/uci/Makefile
1730         src/libcharon/plugins/ha/Makefile
1731         src/libcharon/plugins/kernel_libipsec/Makefile
1732         src/libcharon/plugins/kernel_wfp/Makefile
1733         src/libcharon/plugins/kernel_iph/Makefile
1734         src/libcharon/plugins/whitelist/Makefile
1735         src/libcharon/plugins/ext_auth/Makefile
1736         src/libcharon/plugins/lookip/Makefile
1737         src/libcharon/plugins/error_notify/Makefile
1738         src/libcharon/plugins/certexpire/Makefile
1739         src/libcharon/plugins/systime_fix/Makefile
1740         src/libcharon/plugins/led/Makefile
1741         src/libcharon/plugins/duplicheck/Makefile
1742         src/libcharon/plugins/coupling/Makefile
1743         src/libcharon/plugins/radattr/Makefile
1744         src/libcharon/plugins/osx_attr/Makefile
1745         src/libcharon/plugins/android_dns/Makefile
1746         src/libcharon/plugins/android_log/Makefile
1747         src/libcharon/plugins/maemo/Makefile
1748         src/libcharon/plugins/stroke/Makefile
1749         src/libcharon/plugins/vici/Makefile
1750         src/libcharon/plugins/vici/ruby/Makefile
1751         src/libcharon/plugins/updown/Makefile
1752         src/libcharon/plugins/dhcp/Makefile
1753         src/libcharon/plugins/load_tester/Makefile
1754         src/libcharon/plugins/resolve/Makefile
1755         src/libcharon/plugins/attr/Makefile
1756         src/libcharon/plugins/attr_sql/Makefile
1757         src/libcharon/tests/Makefile
1758         src/stroke/Makefile
1759         src/ipsec/Makefile
1760         src/starter/Makefile
1761         src/starter/tests/Makefile
1762         src/_updown/Makefile
1763         src/_updown_espmark/Makefile
1764         src/_copyright/Makefile
1765         src/scepclient/Makefile
1766         src/aikgen/Makefile
1767         src/pki/Makefile
1768         src/pki/man/Makefile
1769         src/pool/Makefile
1770         src/dumm/Makefile
1771         src/dumm/ext/extconf.rb
1772         src/libfast/Makefile
1773         src/manager/Makefile
1774         src/medsrv/Makefile
1775         src/checksum/Makefile
1776         src/conftest/Makefile
1777         src/pt-tls-client/Makefile
1778         src/swanctl/Makefile
1779         scripts/Makefile
1780         testing/Makefile
1781 ])
1782
1783 # =================
1784 #  build man pages
1785 # =================
1786
1787 AC_CONFIG_FILES([
1788         conf/strongswan.conf.5.head
1789         conf/strongswan.conf.5.tail
1790         man/ipsec.conf.5
1791         man/ipsec.secrets.5
1792         src/charon-cmd/charon-cmd.8
1793         src/pki/man/pki.1
1794         src/pki/man/pki---gen.1
1795         src/pki/man/pki---issue.1
1796         src/pki/man/pki---keyid.1
1797         src/pki/man/pki---pkcs7.1
1798         src/pki/man/pki---pkcs12.1
1799         src/pki/man/pki---print.1
1800         src/pki/man/pki---pub.1
1801         src/pki/man/pki---req.1
1802         src/pki/man/pki---self.1
1803         src/pki/man/pki---signcrl.1
1804         src/pki/man/pki---acert.1
1805         src/pki/man/pki---verify.1
1806         src/swanctl/swanctl.8
1807         src/swanctl/swanctl.conf.5.head
1808         src/swanctl/swanctl.conf.5.tail
1809 ])
1810
1811 AC_OUTPUT
1812
1813 # ========================
1814 #  report enabled plugins
1815 # ========================
1816
1817 AC_MSG_RESULT([])
1818 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1819 AC_MSG_RESULT([-----------------------------------------------------])
1820
1821 AC_MSG_RESULT([libstrongswan:$s_plugins])
1822 AC_MSG_RESULT([libcharon:    $c_plugins])
1823 AC_MSG_RESULT([libhydra:     $h_plugins])
1824 AC_MSG_RESULT([libtnccs:     $t_plugins])
1825 AC_MSG_RESULT([])