configure.ac

   1 #
   2 # Copyright (C) 2007-2015 Tobias Brunner
   3 # Copyright (C) 2006-2014 Andreas Steffen
   4 # Copyright (C) 2006-2014 Martin Willi
   5 # Hochschule fuer Technik Rapperswil
   6 #
   7 # This program is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by the
   9 # Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 # for more details.
  16 #
  17
  18 # ============================
  19 #  initialize & set some vars
  20 # ============================
  21
  22 AC_INIT([strongSwan],[5.3.3dr5])
  23 AM_INIT_AUTOMAKE(m4_esyscmd([
  24         echo tar-ustar
  25         echo subdir-objects
  26         case `automake --version | head -n 1` in
  27                 *" 1.9"*);;
  28                 *" 1.10"*);;
  29                 *" 1.11"*);;
  30                 # don't use parallel test harness in 1.12 and up
  31                 *) echo serial-tests;;
  32         esac
  33 ]))
  34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  35 AC_CONFIG_MACRO_DIR([m4/config])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
  38 PKG_PROG_PKG_CONFIG
  39
  40 m4_include(m4/macros/split-package-version.m4)
  41 SPLIT_PACKAGE_VERSION
  42
  43 # =================================
  44 #  check --enable-xxx & --with-xxx
  45 # =================================
  46
  47 m4_include(m4/macros/with.m4)
  48
  49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
  50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
  51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
  52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
  53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
  54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
  55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
  56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
  57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
  58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
  59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
  60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
  61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
  62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
  63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
  64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
  65
  66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
  67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
  68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
  69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
  70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
  71 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
  72 ARG_WITH_SET([pythoneggdir],         ["main site-packages directory"], [path to install python eggs to to])
  73
  74 if test -n "$PKG_CONFIG"; then
  75         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
  76 fi
  77 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
  78 AC_SUBST(systemdsystemunitdir)
  79
  80 AC_ARG_WITH(
  81         [user],
  82         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
  83         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
  84          AC_SUBST(ipsecuser, "$withval")],
  85         [AC_SUBST(ipsecuser, "root")]
  86 )
  87
  88 AC_ARG_WITH(
  89         [group],
  90         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
  91         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
  92          AC_SUBST(ipsecgroup, "$withval")],
  93         [AC_SUBST(ipsecgroup, "root")]
  94 )
  95
  96 AC_ARG_WITH(
  97         [charon-udp-port],
  98         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
  99         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
 100          AC_SUBST(charon_udp_port, [$withval])],
 101         [AC_SUBST(charon_udp_port, 500)]
 102 )
 103
 104 AC_ARG_WITH(
 105         [charon-natt-port],
 106         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
 107         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
 108          AC_SUBST(charon_natt_port, [$withval])],
 109         [AC_SUBST(charon_natt_port, 4500)]
 110 )
 111
 112 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
 113 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
 114         AC_MSG_ERROR(the ports have to be different)
 115 else
 116         AC_MSG_RESULT(ok)
 117 fi
 118
 119 # convert script name to uppercase
 120 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
 121
 122 m4_include(m4/macros/enable-disable.m4)
 123
 124 # crypto plugins
 125 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
 126 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
 127 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
 128 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
 129 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
 130 ARG_ENABL_SET([chapoly],        [enables the ChaCha20/Poly1305 AEAD plugin.])
 131 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
 132 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
 133 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
 134 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
 135 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
 136 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
 137 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
 138 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
 139 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
 140 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
 141 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
 142 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
 143 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
 144 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
 145 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
 146 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
 147 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
 148 ARG_ENABL_SET([aesni],          [enable Intel AES-NI crypto plugin.])
 149 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
 150 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
 151 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
 152 # encoding/decoding plugins
 153 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
 154 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
 155 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
 156 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
 157 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
 158 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
 159 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
 160 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
 161 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
 162 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
 163 # fetcher/resolver plugins
 164 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
 165 ARG_ENABL_SET([files],          [enable simple file:// URI fetcher.])
 166 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
 167 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
 168 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
 169 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
 170 # database plugins
 171 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
 172 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
 173 # authentication/credential plugins
 174 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
 175 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
 176 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
 177 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
 178 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
 179 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
 180 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
 181 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
 182 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
 183 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
 184 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
 185 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
 186 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
 187 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
 188 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
 189 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
 190 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
 191 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
 192 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
 193 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
 194 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
 195 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
 196 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
 197 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
 198 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
 199 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
 200 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
 201 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
 202 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
 203 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
 204 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
 205 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
 206 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
 207 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
 208 # kernel interfaces / sockets
 209 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
 210 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
 211 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
 212 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
 213 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
 214 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
 215 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
 216 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
 217 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
 218 # configuration/control plugins
 219 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
 220 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
 221 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
 222 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
 223 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
 224 # attribute provider/consumer plugins
 225 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
 226 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
 227 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
 228 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
 229 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
 230 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
 231 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
 232 # TNC modules/plugins
 233 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
 234 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
 235 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
 236 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
 237 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
 238 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
 239 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
 240 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
 241 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
 242 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
 243 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
 244 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
 245 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
 246 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
 247 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
 248 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
 249 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
 250 # misc plugins
 251 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
 252 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
 253 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
 254 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
 255 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
 256 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
 257 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
 258 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
 259 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
 260 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
 261 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
 262 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
 263 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
 264 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
 265 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
 266 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
 267 # programs/components
 268 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
 269 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
 270 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
 271 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
 272 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
 273 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
 274 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
 275 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
 276 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
 277 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
 278 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
 279 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
 280 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
 281 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
 282 ARG_ENABL_SET([svc],            [enable charon Windows service.])
 283 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
 284 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
 285 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
 286 # optional features
 287 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
 288 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
 289 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
 290 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
 291 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
 292 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
 293 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
 294 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
 295 ARG_ENABL_SET([ruby-gems],      [enable build of provided ruby gems.])
 296 ARG_ENABL_SET([ruby-gems-install],[enable installation of provided ruby gems.])
 297 ARG_ENABL_SET([python-eggs],    [enable build of provided python eggs.])
 298 ARG_ENABL_SET([python-eggs-install],[enable installation of provided python eggs.])
 299 # compile options
 300 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
 301 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
 302 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
 303 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
 304
 305 # ===================================
 306 #  option to disable default options
 307 # ===================================
 308
 309 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
 310
 311 if test x$defaults = xfalse; then
 312         for option in $enabled_by_default; do
 313                 eval test x\${${option}_given} = xtrue && continue
 314                 eval $option=false
 315         done
 316 fi
 317
 318 # ==============================
 319 #  option to enable all options
 320 # ==============================
 321
 322 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
 323
 324 if test x$all_given = xtrue; then
 325         for option in $disabled_by_default; do
 326                 eval test x\${${option}_given} = xtrue && continue
 327                 eval $option=true
 328         done
 329 fi
 330
 331 # ===========================
 332 #  set up compiler and flags
 333 # ===========================
 334
 335 if test -z "$CFLAGS"; then
 336         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
 337 fi
 338 AC_PROG_CC
 339 AM_PROG_CC_C_O
 340
 341 AC_LIB_PREFIX
 342 AC_C_BIGENDIAN
 343
 344 # =========================
 345 #  check required programs
 346 # =========================
 347
 348 LT_INIT
 349 AC_PROG_INSTALL
 350 AC_PROG_EGREP
 351 AC_PROG_AWK
 352 AC_PROG_LEX
 353 AC_PROG_YACC
 354 AM_PATH_PYTHON(,,[:])
 355 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 356 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 357
 358 # because gperf is not needed by end-users we just report it but do not abort on failure
 359 AC_MSG_CHECKING([gperf version >= 3.0.0])
 360 if test -x "$GPERF"; then
 361         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
 362                 AC_MSG_RESULT([yes])
 363         else
 364                 AC_MSG_RESULT([no])
 365         fi
 366 else
 367         AC_MSG_RESULT([not found])
 368 fi
 369
 370 # ========================
 371 #  dependency calculation
 372 # ========================
 373
 374 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
 375         xauth_generic=false;
 376 fi
 377
 378 if test x$kernel_libipsec = xtrue; then
 379         libipsec=true;
 380 fi
 381
 382 if test x$eap_aka_3gpp2 = xtrue; then
 383         gmp=true;
 384 fi
 385
 386 if test x$eap_aka = xtrue; then
 387         fips_prf=true;
 388         simaka=true;
 389 fi
 390
 391 if test x$eap_sim = xtrue; then
 392         fips_prf=true;
 393         simaka=true;
 394 fi
 395
 396 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
 397         radius=true;
 398 fi
 399
 400 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
 401         tnc_tnccs=true;
 402 fi
 403
 404 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
 405         tls=true;
 406 fi
 407
 408 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
 409         imcv=true;
 410 fi
 411
 412 if test x$fips_prf = xtrue; then
 413         if test x$openssl = xfalse; then
 414                 sha1=true;
 415         fi
 416 fi
 417
 418 if test x$swanctl = xtrue; then
 419         vici=true
 420 fi
 421
 422 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
 423         xml=true
 424 fi
 425
 426 if test x$manager = xtrue; then
 427         fast=true
 428 fi
 429
 430 if test x$medsrv = xtrue; then
 431         mediation=true
 432         fast=true
 433 fi
 434
 435 if test x$medcli = xtrue; then
 436         mediation=true
 437 fi
 438
 439 if test x$ruby_gems_install = xtrue; then
 440         ruby_gems=true
 441 fi
 442
 443 if test x$python_eggs_install = xtrue; then
 444         python_eggs=true
 445 fi
 446
 447 # ===========================================
 448 #  check required libraries and header files
 449 # ===========================================
 450
 451 AC_HEADER_STDBOOL
 452 AC_FUNC_ALLOCA
 453 AC_FUNC_STRERROR_R
 454
 455 #  libraries needed on some platforms but not on others
 456 # ------------------------------------------------------
 457 saved_LIBS=$LIBS
 458
 459 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
 460 LIBS=""
 461 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 462 AC_SUBST(DLLIB)
 463
 464 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
 465 LIBS=""
 466 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
 467 AC_CHECK_FUNCS(backtrace)
 468 AC_SUBST(BTLIB)
 469
 470 # OpenSolaris needs libsocket and libnsl for socket()
 471 LIBS=""
 472 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
 473         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
 474 )
 475 AC_SUBST(SOCKLIB)
 476
 477 # Android has pthread_* functions in bionic (libc), others need libpthread
 478 LIBS=""
 479 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
 480 AC_SUBST(PTHREADLIB)
 481
 482 LIBS=$saved_LIBS
 483 # ------------------------------------------------------
 484
 485 AC_MSG_CHECKING(for dladdr)
 486 AC_COMPILE_IFELSE(
 487         [AC_LANG_PROGRAM(
 488                 [[#define _GNU_SOURCE
 489                   #include <dlfcn.h>]],
 490                 [[Dl_info* info = 0;
 491                   dladdr(0, info);]])],
 492         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
 493         [AC_MSG_RESULT([no])]
 494 )
 495
 496 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
 497 saved_LIBS=$LIBS
 498 LIBS=$PTHREADLIB
 499 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
 500 AC_RUN_IFELSE(
 501         [AC_LANG_SOURCE(
 502                 [[#include <pthread.h>
 503                   int main() { pthread_condattr_t attr;
 504                         pthread_condattr_init(&attr);
 505                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
 506         [AC_MSG_RESULT([yes]);
 507          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 508                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
 509         [AC_MSG_RESULT([no])],
 510         # Check existence of pthread_condattr_setclock if cross-compiling
 511         [AC_MSG_RESULT([unknown]);
 512          AC_CHECK_FUNCS(pthread_condattr_setclock,
 513                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 514                                    [have pthread_condattr_setclock()])]
 515         )]
 516 )
 517 # check if we actually are able to configure attributes on cond vars
 518 AC_CHECK_FUNCS(pthread_condattr_init)
 519 # instead of pthread_condattr_setclock Android has this function
 520 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
 521 # check if we can cancel threads
 522 AC_CHECK_FUNCS(pthread_cancel)
 523 # check if native rwlocks are available
 524 AC_CHECK_FUNCS(pthread_rwlock_init)
 525 # check if pthread spinlocks are available
 526 AC_CHECK_FUNCS(pthread_spin_init)
 527 # check if we have POSIX semaphore functions, including timed-wait
 528 AC_CHECK_FUNCS(sem_timedwait)
 529 LIBS=$saved_LIBS
 530
 531 AC_CHECK_FUNC(
 532         [gettid],
 533         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
 534         [AC_MSG_CHECKING([for SYS_gettid])
 535          AC_COMPILE_IFELSE(
 536                 [AC_LANG_PROGRAM(
 537                         [[#define _GNU_SOURCE
 538                           #include <unistd.h>
 539                           #include <sys/syscall.h>]],
 540                         [[int main() {
 541                           return syscall(SYS_gettid);}]])],
 542                 [AC_MSG_RESULT([yes]);
 543                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
 544                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
 545                 [AC_MSG_RESULT([no])]
 546         )]
 547 )
 548
 549 AC_CHECK_FUNC(
 550         [qsort_r],
 551         [
 552                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
 553                 # set -Werror so that we get an error for "argument ... has
 554                 # incompatible pointer type" warnings
 555                 save_CFLAGS="$CFLAGS"
 556                 CFLAGS="$CFLAGS -Werror -Wno-unused-parameter"
 557                 AC_MSG_CHECKING([for GNU-style qsort_r])
 558                 AC_COMPILE_IFELSE(
 559                         [AC_LANG_PROGRAM(
 560                                 [[#define _GNU_SOURCE
 561                                   #include <stdlib.h>
 562                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
 563                                 [[int arr[] = { 0, 1 };
 564                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
 565                 [AC_MSG_RESULT([yes]);
 566                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
 567                 [
 568                         AC_MSG_RESULT([no]);
 569                         AC_MSG_CHECKING([for BSD-style qsort_r])
 570                         AC_COMPILE_IFELSE(
 571                                 [AC_LANG_PROGRAM(
 572                                         [[#include <stdlib.h>
 573                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
 574                                         [[int arr[] = { 0, 1 };
 575                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
 576                         [AC_MSG_RESULT([yes]);
 577                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
 578                         [AC_MSG_RESULT([no]);
 579                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
 580                 ])
 581                 CFLAGS="$save_CFLAGS"
 582         ]
 583 )
 584
 585 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
 586 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime dirfd)
 587
 588 AC_CHECK_FUNC([syslog], [
 589         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
 590         syslog=true
 591 ])
 592 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
 593
 594 AC_CHECK_HEADERS(sys/sockio.h sys/syscall.h glob.h net/if_tun.h)
 595 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
 596 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
 597 [
 598         #include <sys/types.h>
 599         #include <netinet/in.h>
 600 ])
 601
 602 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 603 [
 604         #include <sys/types.h>
 605         #include <sys/socket.h>
 606 ])
 607
 608 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 609 [
 610         #include <sys/types.h>
 611         #ifdef HAVE_NET_PFKEYV2_H
 612         #include <net/pfkeyv2.h>
 613         #else
 614         #include <stdint.h>
 615         #include <linux/pfkeyv2.h>
 616         #endif
 617 ])
 618
 619 AC_MSG_CHECKING([for in6addr_any])
 620 AC_COMPILE_IFELSE(
 621         [AC_LANG_PROGRAM(
 622                 [[#include <sys/types.h>
 623                   #include <sys/socket.h>
 624                   #include <netinet/in.h>]],
 625                 [[struct in6_addr in6 __attribute__((unused));
 626                   in6 = in6addr_any;]])],
 627         [AC_MSG_RESULT([yes]);
 628          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
 629         [AC_MSG_RESULT([no])]
 630 )
 631
 632 AC_MSG_CHECKING([for in6_pktinfo])
 633 AC_COMPILE_IFELSE(
 634         [AC_LANG_PROGRAM(
 635                 [[#define _GNU_SOURCE
 636                   #include <sys/types.h>
 637                   #include <sys/socket.h>
 638                   #include <netinet/in.h>]],
 639                 [[struct in6_pktinfo pi;
 640                   if (pi.ipi6_ifindex)
 641                   {
 642                     return 0;
 643                   }]])],
 644         [AC_MSG_RESULT([yes]);
 645          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
 646         [AC_MSG_RESULT([no])]
 647 )
 648
 649 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
 650 AC_COMPILE_IFELSE(
 651         [AC_LANG_PROGRAM(
 652                 [[#include <sys/socket.h>
 653                   #include <net/if.h>
 654                   #include <net/route.h>]],
 655                 [[return RTM_IFANNOUNCE;]])],
 656         [AC_MSG_RESULT([yes]);
 657          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
 658         [AC_MSG_RESULT([no])]
 659 )
 660
 661 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 662 AC_COMPILE_IFELSE(
 663         [AC_LANG_PROGRAM(
 664                 [[#include <sys/types.h>
 665                   #ifdef HAVE_NETIPSEC_IPSEC_H
 666                   #include <netipsec/ipsec.h>
 667                   #elif defined(HAVE_NETINET6_IPSEC_H)
 668                   #include <netinet6/ipsec.h>
 669                   #else
 670                   #include <stdint.h>
 671                   #include <linux/ipsec.h>
 672                   #endif]],
 673                 [[int mode = IPSEC_MODE_BEET;
 674                   return mode;]])],
 675         [AC_MSG_RESULT([yes]);
 676          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
 677         [AC_MSG_RESULT([no])]
 678 )
 679
 680 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 681 AC_COMPILE_IFELSE(
 682         [AC_LANG_PROGRAM(
 683                 [[#include <sys/types.h>
 684                   #ifdef HAVE_NETIPSEC_IPSEC_H
 685                   #include <netipsec/ipsec.h>
 686                   #elif defined(HAVE_NETINET6_IPSEC_H)
 687                   #include <netinet6/ipsec.h>
 688                   #else
 689                   #include <stdint.h>
 690                   #include <linux/ipsec.h>
 691                   #endif]],
 692                 [[int dir = IPSEC_DIR_FWD;
 693                   return dir;]])],
 694         [AC_MSG_RESULT([yes]);
 695          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
 696         [AC_MSG_RESULT([no])]
 697 )
 698
 699 AC_MSG_CHECKING([for RTA_TABLE])
 700 AC_COMPILE_IFELSE(
 701         [AC_LANG_PROGRAM(
 702                 [[#include <sys/socket.h>
 703                   #include <linux/netlink.h>
 704                   #include <linux/rtnetlink.h>]],
 705                 [[int rta_type = RTA_TABLE;
 706                   return rta_type;]])],
 707         [AC_MSG_RESULT([yes]);
 708          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
 709         [AC_MSG_RESULT([no])]
 710 )
 711
 712 AC_MSG_CHECKING([for __int128])
 713 AC_COMPILE_IFELSE(
 714         [AC_LANG_PROGRAM(
 715                 [[#include <sys/types.h>]],
 716                 [[__int128 x = 0;
 717                   return x;]])],
 718         [AC_MSG_RESULT([yes]);
 719          AC_DEFINE([HAVE_INT128], [], [have __int128 type support])],
 720         [AC_MSG_RESULT([no])]
 721 )
 722
 723 AC_MSG_CHECKING([for GCC __sync operations])
 724 AC_RUN_IFELSE([AC_LANG_SOURCE(
 725         [[
 726                         int main() {
 727                         int ref = 1;
 728                         __sync_fetch_and_add (&ref, 1);
 729                         __sync_sub_and_fetch (&ref, 1);
 730                         __sync_val_compare_and_swap(&ref, 1, 0);
 731                         return ref;
 732                 }
 733         ]])],
 734         [AC_MSG_RESULT([yes]);
 735          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
 736                    [have GCC __sync_* operations])],
 737         [AC_MSG_RESULT([no])],
 738         [AC_MSG_RESULT([no])]
 739 )
 740
 741 case "$printf_hooks" in
 742 auto|builtin|glibc|vstr)
 743         ;;
 744 *)
 745         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
 746         printf_hooks=auto
 747         ;;
 748 esac
 749
 750 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
 751         # check for the new register_printf_specifier function with len argument,
 752         # or the deprecated register_printf_function without
 753         AC_CHECK_FUNC(
 754                 [register_printf_specifier],
 755                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
 756                 [AC_CHECK_FUNC(
 757                         [register_printf_function],
 758                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
 759                         [
 760                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
 761                                 if test x$printf_hooks = xglibc; then
 762                                         AC_MSG_ERROR([please select a different printf hook implementation])
 763                                 else
 764                                         # fallback to builtin printf hook implementation
 765                                         printf_hooks=builtin
 766                                 fi
 767                         ]
 768                 )]
 769         )
 770 fi
 771
 772 AC_MSG_CHECKING([for Windows target])
 773 AC_COMPILE_IFELSE(
 774         [AC_LANG_PROGRAM(
 775                 [[#include <windows.h>]],
 776                 [[#ifndef WIN32
 777                   # error WIN32 undefined
 778                   #endif
 779                 ]])],
 780         [
 781                 AC_MSG_RESULT([yes])
 782                 windows=true
 783                 openssl_lib=eay32
 784                 AC_SUBST(PTHREADLIB, "")
 785                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
 786                 case "$CFLAGS" in
 787                         *ms-bitfields*) ;;
 788                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
 789                 esac
 790         ],
 791         [
 792                 AC_MSG_RESULT([no])
 793                 openssl_lib=crypto
 794
 795                 # check for clock_gettime() on non-Windows only. Otherwise this
 796                 # check might find clock_gettime() in libwinpthread, but we don't want
 797                 # to link against it.
 798                 saved_LIBS=$LIBS
 799                 # FreeBSD has clock_gettime in libc, Linux needs librt
 800                 LIBS=""
 801                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
 802                 AC_CHECK_FUNCS(clock_gettime)
 803                 AC_SUBST(RTLIB)
 804                 LIBS=$saved_LIBS
 805         ]
 806 )
 807 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
 808 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
 809
 810 AC_MSG_CHECKING([for working __attribute__((packed))])
 811 AC_COMPILE_IFELSE(
 812         [AC_LANG_PROGRAM([], [[
 813                 struct test { char a; short b; } __attribute__((packed));
 814                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
 815                         __attribute__((unused));
 816                 return 0;
 817         ]])],
 818         [AC_MSG_RESULT([yes])],
 819         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
 820 )
 821
 822 AC_MSG_CHECKING([clang])
 823 AC_COMPILE_IFELSE(
 824         [AC_LANG_PROGRAM(
 825                 [], [[
 826                  #ifndef __clang__
 827                  # error not using LLVM clang
 828                  #endif
 829                 ]])],
 830         [
 831                 AC_MSG_RESULT([yes])
 832         ],
 833         [
 834                 AC_MSG_RESULT([no])
 835                 # GCC, but not MinGW requires -rdynamic for plugins
 836                 if test x$windows != xtrue; then
 837                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
 838                 fi
 839         ]
 840 )
 841
 842 AC_MSG_CHECKING([x86/x64 target])
 843 AC_COMPILE_IFELSE(
 844         [AC_LANG_PROGRAM(
 845                 [], [[
 846                  #if !defined(__i386__) && !defined(__x86_64__)
 847                  # error not on x86/x64
 848                  #endif
 849                 ]])],
 850         [
 851                 x86x64=true
 852                 AC_MSG_RESULT([yes])
 853         ],
 854         [AC_MSG_RESULT([no])]
 855 )
 856 AM_CONDITIONAL(USE_X86X64, [test "x$x86x64" = xtrue])
 857
 858 if test x$printf_hooks = xvstr; then
 859         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
 860         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
 861 fi
 862
 863 if test x$printf_hooks = xbuiltin; then
 864         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
 865 fi
 866
 867 if test x$gmp = xtrue; then
 868         saved_LIBS=$LIBS
 869         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
 870         AC_MSG_CHECKING([mpz_powm_sec])
 871         if test x$mpz_powm_sec = xyes; then
 872                 AC_COMPILE_IFELSE(
 873                         [AC_LANG_PROGRAM(
 874                                 [[#include "gmp.h"]],
 875                                 [[void *x = mpz_powm_sec;]])],
 876                         [AC_MSG_RESULT([yes]);
 877                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
 878                         [AC_MSG_RESULT([no])]
 879                 )
 880         else
 881                 AC_MSG_RESULT([disabled])
 882         fi
 883         LIBS=$saved_LIBS
 884         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 885         AC_COMPILE_IFELSE(
 886                 [AC_LANG_PROGRAM(
 887                         [[#include "gmp.h"]],
 888                         [[
 889                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 890                                         #error bad gmp
 891                                 #endif]])],
 892                 [AC_MSG_RESULT([yes])],
 893                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 894         )
 895 fi
 896
 897 if test x$ldap = xtrue; then
 898         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
 899         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
 900         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 901 fi
 902
 903 if test x$curl = xtrue; then
 904         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
 905         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 906 fi
 907
 908 if test x$unbound = xtrue; then
 909         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
 910         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
 911         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
 912         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
 913 fi
 914
 915 if test x$soup = xtrue; then
 916         PKG_CHECK_MODULES(soup, [libsoup-2.4])
 917         AC_SUBST(soup_CFLAGS)
 918         AC_SUBST(soup_LIBS)
 919 fi
 920
 921 if test x$xml = xtrue; then
 922         PKG_CHECK_MODULES(xml, [libxml-2.0])
 923         AC_SUBST(xml_CFLAGS)
 924         AC_SUBST(xml_LIBS)
 925 fi
 926
 927 if test x$systemd = xtrue; then
 928         AC_MSG_CHECKING([for systemd system unit directory])
 929         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 930                 AC_MSG_RESULT([$systemdsystemunitdir])
 931         else
 932                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 933         fi
 934
 935         PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
 936         AC_SUBST(systemd_daemon_CFLAGS)
 937         AC_SUBST(systemd_daemon_LIBS)
 938
 939         PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
 940         AC_SUBST(systemd_journal_CFLAGS)
 941         AC_SUBST(systemd_journal_LIBS)
 942 fi
 943
 944 if test x$tss = xtrousers; then
 945         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
 946         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
 947         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
 948 fi
 949
 950 if test x$imv_swid = xtrue; then
 951         PKG_CHECK_MODULES(json, [json-c], [],
 952                 [PKG_CHECK_MODULES(json, [json])])
 953         AC_SUBST(json_CFLAGS)
 954         AC_SUBST(json_LIBS)
 955 fi
 956
 957 if test x$dumm = xtrue; then
 958         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
 959         AC_SUBST(gtk_CFLAGS)
 960         AC_SUBST(gtk_LIBS)
 961         AC_CHECK_PROGS(RUBY, ruby)
 962         AC_MSG_CHECKING([for Ruby header files])
 963         if test -n "$RUBY"; then
 964                 RUBYINCLUDE=
 965                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
 966                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 967                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
 968                         if test -n "$RUBYARCH"; then
 969                                 AC_MSG_RESULT([$RUBYDIR])
 970                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
 971                         fi
 972                 else
 973                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
 974                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 975                                 AC_MSG_RESULT([$RUBYDIR])
 976                                 RUBYINCLUDE="-I$RUBYDIR"
 977                         fi
 978                 fi
 979                 if test -z "$RUBYINCLUDE"; then
 980                         AC_MSG_ERROR([ruby.h not found])
 981                 fi
 982                 AC_SUBST(RUBYINCLUDE)
 983         else
 984                 AC_MSG_ERROR([don't know how to run ruby])
 985         fi
 986         AC_MSG_CHECKING([for libruby])
 987         saved_LIBS=$LIBS
 988         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
 989         AC_TRY_LINK_FUNC(ruby_init,
 990                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
 991                 [AC_MSG_ERROR([not found])])
 992         AC_SUBST(RUBYLIB)
 993         AC_CHECK_FUNCS(rb_errinfo)
 994         LIBS=$saved_LIBS
 995 fi
 996
 997 if test x$fast = xtrue; then
 998         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
 999         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
1000         AC_MSG_CHECKING([ClearSilver requires zlib])
1001         saved_CFLAGS=$CFLAGS
1002         saved_LIBS=$LIBS
1003         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
1004         CFLAGS="-I/usr/include/ClearSilver"
1005         AC_LINK_IFELSE(
1006                 [AC_LANG_PROGRAM(
1007                         [[#include <ClearSilver.h>]],
1008                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
1009                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
1010                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
1011         )
1012         AC_SUBST(clearsilver_LIBS)
1013         LIBS=$saved_LIBS
1014         CFLAGS=$saved_CFLAGS
1015 # autoconf does not like CamelCase!? How to fix this?
1016 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
1017
1018         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
1019         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
1020 fi
1021
1022 if test x$mysql = xtrue; then
1023         if test "x$windows" = xtrue; then
1024                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
1025                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
1026                 AC_SUBST(MYSQLLIB, -lmysql)
1027         else
1028                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1029                 if test x$MYSQLCONFIG = x; then
1030                         AC_MSG_ERROR([mysql_config not found!])
1031                 fi
1032                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
1033                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
1034         fi
1035 fi
1036
1037 if test x$sqlite = xtrue; then
1038         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
1039         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
1040         AC_MSG_CHECKING([sqlite3_prepare_v2])
1041         AC_COMPILE_IFELSE(
1042                 [AC_LANG_PROGRAM(
1043                         [[#include <sqlite3.h>]],
1044                         [[void *test = sqlite3_prepare_v2;]])],
1045                 [AC_MSG_RESULT([yes]);
1046                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1047                 [AC_MSG_RESULT([no])]
1048         )
1049         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1050         AC_COMPILE_IFELSE(
1051                 [AC_LANG_PROGRAM(
1052                         [[#include <sqlite3.h>]],
1053                         [[
1054                                 #if SQLITE_VERSION_NUMBER < 3003001
1055                                         #error bad sqlite
1056                                 #endif]])],
1057                 [AC_MSG_RESULT([yes])],
1058                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1059         )
1060 fi
1061
1062 if test x$openssl = xtrue; then
1063         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
1064         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1065 fi
1066
1067 if test x$gcrypt = xtrue; then
1068         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1069         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1070         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1071         AC_COMPILE_IFELSE(
1072                 [AC_LANG_PROGRAM(
1073                         [[#include <gcrypt.h>]],
1074                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1075                 [AC_MSG_RESULT([yes]);
1076                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1077                 [AC_MSG_RESULT([no])]
1078         )
1079 fi
1080
1081 if test x$uci = xtrue; then
1082         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1083         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1084 fi
1085
1086 if test x$android_dns = xtrue; then
1087         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1088         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1089         # we have to force the use of libdl here because the autodetection
1090         # above does not work correctly when cross-compiling for android.
1091         DLLIB="-ldl"
1092         AC_SUBST(DLLIB)
1093 fi
1094
1095 if test x$maemo = xtrue; then
1096         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1097         AC_SUBST(maemo_CFLAGS)
1098         AC_SUBST(maemo_LIBS)
1099         dbusservicedir="/usr/share/dbus-1/system-services"
1100         AC_SUBST(dbusservicedir)
1101 fi
1102
1103 if test x$eap_sim_pcsc = xtrue; then
1104         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1105         AC_SUBST(pcsclite_CFLAGS)
1106         AC_SUBST(pcsclite_LIBS)
1107 fi
1108
1109 if test x$nm = xtrue; then
1110         PKG_CHECK_EXISTS([libnm-glib],
1111                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1112                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1113         )
1114         AC_SUBST(nm_CFLAGS)
1115         AC_SUBST(nm_LIBS)
1116 fi
1117
1118 if test x$xauth_pam = xtrue; then
1119         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1120         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1121 fi
1122
1123 if test x$connmark = xtrue -o x$forecast = xtrue; then
1124         PKG_CHECK_MODULES(libiptc, [libiptc])
1125         AC_SUBST(libiptc_CFLAGS)
1126         AC_SUBST(libiptc_LIBS)
1127 fi
1128
1129 if test x$capabilities = xnative; then
1130         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1131         # Linux requires the following for capset(), Android does not have it,
1132         # but defines capset() in unistd.h instead.
1133         AC_CHECK_HEADERS([sys/capability.h])
1134         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1135         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1136 fi
1137
1138 if test x$capabilities = xlibcap; then
1139         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1140         AC_CHECK_HEADER([sys/capability.h],
1141                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1142                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1143         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1144 fi
1145
1146 if test x$integrity_test = xtrue; then
1147         AC_MSG_CHECKING([for dladdr()])
1148         AC_COMPILE_IFELSE(
1149                 [AC_LANG_PROGRAM(
1150                         [[#define _GNU_SOURCE
1151                           #include <dlfcn.h>]],
1152                         [[Dl_info info; dladdr(main, &info);]])],
1153                 [AC_MSG_RESULT([yes])],
1154                 [AC_MSG_RESULT([no]);
1155                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1156         )
1157         AC_MSG_CHECKING([for dl_iterate_phdr()])
1158         AC_COMPILE_IFELSE(
1159                 [AC_LANG_PROGRAM(
1160                         [[#define _GNU_SOURCE
1161                           #include <link.h>]],
1162                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1163                 [AC_MSG_RESULT([yes])],
1164                 [AC_MSG_RESULT([no]);
1165                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1166         )
1167 fi
1168
1169 if test x$bfd_backtraces = xtrue; then
1170         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1171         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1172                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1173         BFDLIB="-lbfd"
1174         AC_SUBST(BFDLIB)
1175 fi
1176
1177 if test x$unwind_backtraces = xtrue; then
1178         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1179         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1180                 [AC_MSG_ERROR([libunwind.h header not found!])])
1181         UNWINDLIB="-lunwind"
1182         AC_SUBST(UNWINDLIB)
1183 fi
1184
1185 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1186 if test x$dev_headers = xyes; then
1187         dev_headers="$includedir/strongswan"
1188 fi
1189 AC_SUBST(dev_headers)
1190
1191 CFLAGS="$CFLAGS -include `pwd`/config.h"
1192
1193 if test x$tkm = xtrue; then
1194         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1195         if test x$GPRBUILD = x; then
1196                 AC_MSG_ERROR([gprbuild not found])
1197         fi
1198 fi
1199
1200 if test x$coverage = xtrue; then
1201         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1202         if test x$LCOV = x; then
1203                 AC_MSG_ERROR([lcov not found])
1204         fi
1205         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1206         if test x$GENHTML = x; then
1207                 AC_MSG_ERROR([genhtml not found])
1208         fi
1209
1210         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1211         COVERAGE_LDFLAGS="-fprofile-arcs"
1212         AC_SUBST(COVERAGE_CFLAGS)
1213         AC_SUBST(COVERAGE_LDFLAGS)
1214
1215         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1216         CFLAGS="${CFLAGS} -g -O0"
1217 fi
1218
1219 if test x$ruby_gems = xtrue; then
1220         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1221         if test x$GEM = x; then
1222                 AC_MSG_ERROR(RubyGems package manager not found)
1223         fi
1224         if test "x$rubygemdir" = "xgem environment gemdir"; then
1225                 rubygemdir=$($GEM environment gemdir)
1226         fi
1227         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1228 fi
1229 AM_CONDITIONAL(RUBY_GEMS_INSTALL, [test "x$ruby_gems_install" = xtrue])
1230
1231 if test x$python_eggs = xtrue; then
1232         if test x$python_eggs_install = xtrue; then
1233                 AC_PATH_PROG([EASY_INSTALL], [easy_install], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1234                 if test x$EASY_INSTALL = x; then
1235                         AC_MSG_ERROR(Python easy_install not found)
1236                 fi
1237         fi
1238         if test "x$pythoneggdir" = "xmain site-packages directory"; then
1239                 AC_SUBST(PYTHONEGGINSTALLDIR, "")
1240         else
1241                 AC_SUBST(PYTHONEGGINSTALLDIR, "--install-dir $pythoneggdir")
1242         fi
1243         AC_PATH_PROG([PY_TEST], [py.test], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1244 fi
1245 AM_CONDITIONAL(PYTHON_EGGS_INSTALL, [test "x$python_eggs_install" = xtrue])
1246
1247 # ===============================================
1248 #  collect plugin list for strongSwan components
1249 # ===============================================
1250
1251 m4_include(m4/macros/add-plugin.m4)
1252
1253 # plugin lists for all components
1254 charon_plugins=
1255 starter_plugins=
1256 pool_plugins=
1257 attest_plugins=
1258 scepclient_plugins=
1259 pki_plugins=
1260 scripts_plugins=
1261 manager_plugins=
1262 medsrv_plugins=
1263 nm_plugins=
1264 cmd_plugins=
1265 aikgen_plugins=
1266
1267 # location specific lists for checksumming,
1268 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1269 c_plugins=
1270 h_plugins=
1271 s_plugins=
1272 t_plugins=
1273
1274 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1275 ADD_PLUGIN([unbound],              [s charon scripts])
1276 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1277 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1278 ADD_PLUGIN([aesni],                [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1279 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1280 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1281 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1282 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1283 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1284 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1285 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1286 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1287 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1288 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1289 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1290 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1291 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1292 ADD_PLUGIN([constraints],          [s charon nm cmd])
1293 ADD_PLUGIN([acert],                [s charon])
1294 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1295 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1296 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1297 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1298 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1299 ADD_PLUGIN([pgp],                  [s charon])
1300 ADD_PLUGIN([dnskey],               [s charon pki])
1301 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1302 ADD_PLUGIN([dnscert],              [c charon])
1303 ADD_PLUGIN([ipseckey],             [c charon])
1304 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1305 ADD_PLUGIN([padlock],              [s charon])
1306 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1307 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1308 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1309 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1310 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1311 ADD_PLUGIN([agent],                [s charon nm cmd])
1312 ADD_PLUGIN([keychain],             [s charon cmd])
1313 ADD_PLUGIN([chapoly],              [s charon scripts nm cmd])
1314 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1315 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1316 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1317 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1318 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1319 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1320 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1321 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1322 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1323 ADD_PLUGIN([files],                [s charon scepclient pki scripts nm cmd])
1324 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1325 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1326 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1327 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1328 ADD_PLUGIN([attr],                 [c charon])
1329 ADD_PLUGIN([attr-sql],             [c charon])
1330 ADD_PLUGIN([load-tester],          [c charon])
1331 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1332 ADD_PLUGIN([kernel-wfp],           [c charon])
1333 ADD_PLUGIN([kernel-iph],           [c charon])
1334 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1335 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1336 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1337 ADD_PLUGIN([resolve],              [c charon cmd])
1338 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1339 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1340 ADD_PLUGIN([socket-win],           [c charon])
1341 ADD_PLUGIN([connmark],             [c charon])
1342 ADD_PLUGIN([forecast],             [c charon])
1343 ADD_PLUGIN([farp],                 [c charon])
1344 ADD_PLUGIN([stroke],               [c charon])
1345 ADD_PLUGIN([vici],                 [c charon])
1346 ADD_PLUGIN([smp],                  [c charon])
1347 ADD_PLUGIN([sql],                  [c charon])
1348 ADD_PLUGIN([updown],               [c charon])
1349 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1350 ADD_PLUGIN([eap-sim],              [c charon])
1351 ADD_PLUGIN([eap-sim-file],         [c charon])
1352 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1353 ADD_PLUGIN([eap-aka],              [c charon])
1354 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1355 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1356 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1357 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1358 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1359 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1360 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1361 ADD_PLUGIN([eap-dynamic],          [c charon])
1362 ADD_PLUGIN([eap-radius],           [c charon])
1363 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1364 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1365 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1366 ADD_PLUGIN([eap-tnc],              [c charon])
1367 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1368 ADD_PLUGIN([xauth-eap],            [c charon])
1369 ADD_PLUGIN([xauth-pam],            [c charon])
1370 ADD_PLUGIN([xauth-noauth],         [c charon])
1371 ADD_PLUGIN([tnc-ifmap],            [c charon])
1372 ADD_PLUGIN([tnc-pdp],              [c charon])
1373 ADD_PLUGIN([tnc-imc],              [t charon])
1374 ADD_PLUGIN([tnc-imv],              [t charon])
1375 ADD_PLUGIN([tnc-tnccs],            [t charon])
1376 ADD_PLUGIN([tnccs-20],             [t charon])
1377 ADD_PLUGIN([tnccs-11],             [t charon])
1378 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1379 ADD_PLUGIN([medsrv],               [c charon])
1380 ADD_PLUGIN([medcli],               [c charon])
1381 ADD_PLUGIN([dhcp],                 [c charon])
1382 ADD_PLUGIN([osx-attr],             [c charon cmd])
1383 ADD_PLUGIN([android-dns],          [c charon])
1384 ADD_PLUGIN([android-log],          [c charon])
1385 ADD_PLUGIN([ha],                   [c charon])
1386 ADD_PLUGIN([whitelist],            [c charon])
1387 ADD_PLUGIN([ext-auth],             [c charon])
1388 ADD_PLUGIN([lookip],               [c charon])
1389 ADD_PLUGIN([error-notify],         [c charon])
1390 ADD_PLUGIN([certexpire],           [c charon])
1391 ADD_PLUGIN([systime-fix],          [c charon])
1392 ADD_PLUGIN([led],                  [c charon])
1393 ADD_PLUGIN([duplicheck],           [c charon])
1394 ADD_PLUGIN([coupling],             [c charon])
1395 ADD_PLUGIN([radattr],              [c charon])
1396 ADD_PLUGIN([maemo],                [c charon])
1397 ADD_PLUGIN([uci],                  [c charon])
1398 ADD_PLUGIN([addrblock],            [c charon])
1399 ADD_PLUGIN([unity],                [c charon])
1400
1401 AC_SUBST(charon_plugins)
1402 AC_SUBST(starter_plugins)
1403 AC_SUBST(pool_plugins)
1404 AC_SUBST(attest_plugins)
1405 AC_SUBST(scepclient_plugins)
1406 AC_SUBST(pki_plugins)
1407 AC_SUBST(scripts_plugins)
1408 AC_SUBST(manager_plugins)
1409 AC_SUBST(medsrv_plugins)
1410 AC_SUBST(nm_plugins)
1411 AC_SUBST(cmd_plugins)
1412 AC_SUBST(aikgen_plugins)
1413
1414 AC_SUBST(c_plugins)
1415 AC_SUBST(h_plugins)
1416 AC_SUBST(s_plugins)
1417 AC_SUBST(t_plugins)
1418
1419 # ======================
1420 #  set Makefile.am vars
1421 # ======================
1422
1423 #  libstrongswan plugins
1424 # -----------------------
1425 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1426 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1427 AM_CONDITIONAL(USE_FILES, test x$files = xtrue)
1428 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1429 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1430 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1431 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1432 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1433 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1434 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1435 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1436 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1437 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1438 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1439 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1440 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1441 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1442 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1443 AM_CONDITIONAL(USE_AESNI, test x$aesni = xtrue)
1444 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1445 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1446 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1447 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1448 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1449 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1450 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1451 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1452 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1453 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1454 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1455 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1456 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1457 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1458 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1459 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1460 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1461 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1462 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1463 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1464 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1465 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1466 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1467 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1468 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1469 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1470 AM_CONDITIONAL(USE_CHAPOLY, test x$chapoly = xtrue)
1471 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1472 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1473 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1474 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1475 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1476 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1477
1478 #  charon plugins
1479 # ----------------
1480 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1481 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1482 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1483 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1484 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1485 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1486 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1487 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1488 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1489 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1490 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1491 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1492 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1493 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1494 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1495 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1496 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1497 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1498 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1499 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1500 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1501 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1502 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1503 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1504 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1505 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1506 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1507 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1508 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1509 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1510 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1511 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1512 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1513 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1514 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1515 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1516 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1517 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1518 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1519 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1520 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1521 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1522 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1523 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1524 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1525 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1526 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1527 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1528 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1529 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1530 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1531 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1532 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1533 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1534 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1535 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1536 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1537 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1538 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1539 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1540 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1541 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1542 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1543 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1544 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1545 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1546 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1547 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1548 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1549 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1550 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1551 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1552 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1553 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1554 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1555 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1556 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1557 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1558 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1559 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1560 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1561
1562 #  hydra plugins
1563 # ---------------
1564 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1565 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1566 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1567
1568 #  other options
1569 # ---------------
1570 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1571 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1572 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1573 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1574 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1575 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1576 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1577 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1578 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1579 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1580 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1581 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1582 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1583 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1584 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1585 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1586 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1587 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1588 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1589 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1590 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1591 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1592 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1593 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1594 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1595 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1596 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1597 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1598 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1599 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1600 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1601 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1602 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1603 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1604 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1605 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1606 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1607 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1608 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1609 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1610 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1611 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1612 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1613 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1614 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1615 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1616 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1617 AM_CONDITIONAL(USE_PYTHON_EGGS, test x$python_eggs = xtrue)
1618 AM_CONDITIONAL(USE_PY_TEST, test "x$PY_TEST" != x)
1619
1620 # ========================
1621 #  set global definitions
1622 # ========================
1623
1624 if test x$mediation = xtrue; then
1625         AC_DEFINE([ME], [], [mediation extension support])
1626 fi
1627 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1628         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1629 fi
1630 if test x$monolithic = xtrue; then
1631         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1632 fi
1633 if test x$ikev1 = xtrue; then
1634         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1635 fi
1636 if test x$ikev2 = xtrue; then
1637         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1638 fi
1639
1640 # ====================================================
1641 #  options for enabled modules (see conf/Makefile.am)
1642 # ====================================================
1643
1644 strongswan_options=
1645
1646 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1647 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1648 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1649 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1650 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1651 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1652 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1653 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1654 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1655 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1656 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1657 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1658 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1659
1660 AC_SUBST(strongswan_options)
1661
1662 # =================
1663 #  build Makefiles
1664 # =================
1665
1666 AC_CONFIG_FILES([
1667         Makefile
1668         conf/Makefile
1669         man/Makefile
1670         init/Makefile
1671         init/systemd/Makefile
1672         init/systemd-swanctl/Makefile
1673         src/Makefile
1674         src/include/Makefile
1675         src/libstrongswan/Makefile
1676         src/libstrongswan/plugins/aes/Makefile
1677         src/libstrongswan/plugins/cmac/Makefile
1678         src/libstrongswan/plugins/des/Makefile
1679         src/libstrongswan/plugins/blowfish/Makefile
1680         src/libstrongswan/plugins/rc2/Makefile
1681         src/libstrongswan/plugins/md4/Makefile
1682         src/libstrongswan/plugins/md5/Makefile
1683         src/libstrongswan/plugins/sha1/Makefile
1684         src/libstrongswan/plugins/sha2/Makefile
1685         src/libstrongswan/plugins/fips_prf/Makefile
1686         src/libstrongswan/plugins/gmp/Makefile
1687         src/libstrongswan/plugins/rdrand/Makefile
1688         src/libstrongswan/plugins/aesni/Makefile
1689         src/libstrongswan/plugins/random/Makefile
1690         src/libstrongswan/plugins/nonce/Makefile
1691         src/libstrongswan/plugins/hmac/Makefile
1692         src/libstrongswan/plugins/xcbc/Makefile
1693         src/libstrongswan/plugins/x509/Makefile
1694         src/libstrongswan/plugins/revocation/Makefile
1695         src/libstrongswan/plugins/constraints/Makefile
1696         src/libstrongswan/plugins/acert/Makefile
1697         src/libstrongswan/plugins/pubkey/Makefile
1698         src/libstrongswan/plugins/pkcs1/Makefile
1699         src/libstrongswan/plugins/pkcs7/Makefile
1700         src/libstrongswan/plugins/pkcs8/Makefile
1701         src/libstrongswan/plugins/pkcs12/Makefile
1702         src/libstrongswan/plugins/pgp/Makefile
1703         src/libstrongswan/plugins/dnskey/Makefile
1704         src/libstrongswan/plugins/sshkey/Makefile
1705         src/libstrongswan/plugins/pem/Makefile
1706         src/libstrongswan/plugins/curl/Makefile
1707         src/libstrongswan/plugins/files/Makefile
1708         src/libstrongswan/plugins/winhttp/Makefile
1709         src/libstrongswan/plugins/unbound/Makefile
1710         src/libstrongswan/plugins/soup/Makefile
1711         src/libstrongswan/plugins/ldap/Makefile
1712         src/libstrongswan/plugins/mysql/Makefile
1713         src/libstrongswan/plugins/sqlite/Makefile
1714         src/libstrongswan/plugins/padlock/Makefile
1715         src/libstrongswan/plugins/openssl/Makefile
1716         src/libstrongswan/plugins/gcrypt/Makefile
1717         src/libstrongswan/plugins/agent/Makefile
1718         src/libstrongswan/plugins/keychain/Makefile
1719         src/libstrongswan/plugins/pkcs11/Makefile
1720         src/libstrongswan/plugins/chapoly/Makefile
1721         src/libstrongswan/plugins/ctr/Makefile
1722         src/libstrongswan/plugins/ccm/Makefile
1723         src/libstrongswan/plugins/gcm/Makefile
1724         src/libstrongswan/plugins/af_alg/Makefile
1725         src/libstrongswan/plugins/ntru/Makefile
1726         src/libstrongswan/plugins/bliss/Makefile
1727         src/libstrongswan/plugins/bliss/tests/Makefile
1728         src/libstrongswan/plugins/test_vectors/Makefile
1729         src/libstrongswan/tests/Makefile
1730         src/libhydra/Makefile
1731         src/libhydra/plugins/kernel_netlink/Makefile
1732         src/libhydra/plugins/kernel_pfkey/Makefile
1733         src/libhydra/plugins/kernel_pfroute/Makefile
1734         src/libhydra/tests/Makefile
1735         src/libipsec/Makefile
1736         src/libipsec/tests/Makefile
1737         src/libsimaka/Makefile
1738         src/libtls/Makefile
1739         src/libtls/tests/Makefile
1740         src/libradius/Makefile
1741         src/libtncif/Makefile
1742         src/libtnccs/Makefile
1743         src/libtnccs/plugins/tnc_tnccs/Makefile
1744         src/libtnccs/plugins/tnc_imc/Makefile
1745         src/libtnccs/plugins/tnc_imv/Makefile
1746         src/libtnccs/plugins/tnccs_11/Makefile
1747         src/libtnccs/plugins/tnccs_20/Makefile
1748         src/libtnccs/plugins/tnccs_dynamic/Makefile
1749         src/libpttls/Makefile
1750         src/libimcv/Makefile
1751         src/libimcv/plugins/imc_test/Makefile
1752         src/libimcv/plugins/imv_test/Makefile
1753         src/libimcv/plugins/imc_scanner/Makefile
1754         src/libimcv/plugins/imv_scanner/Makefile
1755         src/libimcv/plugins/imc_os/Makefile
1756         src/libimcv/plugins/imv_os/Makefile
1757         src/libimcv/plugins/imc_attestation/Makefile
1758         src/libimcv/plugins/imv_attestation/Makefile
1759         src/libimcv/plugins/imc_swid/Makefile
1760         src/libimcv/plugins/imv_swid/Makefile
1761         src/charon/Makefile
1762         src/charon-nm/Makefile
1763         src/charon-tkm/Makefile
1764         src/charon-cmd/Makefile
1765         src/charon-svc/Makefile
1766         src/charon-systemd/Makefile
1767         src/libcharon/Makefile
1768         src/libcharon/plugins/eap_aka/Makefile
1769         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1770         src/libcharon/plugins/eap_dynamic/Makefile
1771         src/libcharon/plugins/eap_identity/Makefile
1772         src/libcharon/plugins/eap_md5/Makefile
1773         src/libcharon/plugins/eap_gtc/Makefile
1774         src/libcharon/plugins/eap_sim/Makefile
1775         src/libcharon/plugins/eap_sim_file/Makefile
1776         src/libcharon/plugins/eap_sim_pcsc/Makefile
1777         src/libcharon/plugins/eap_simaka_sql/Makefile
1778         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1779         src/libcharon/plugins/eap_simaka_reauth/Makefile
1780         src/libcharon/plugins/eap_mschapv2/Makefile
1781         src/libcharon/plugins/eap_tls/Makefile
1782         src/libcharon/plugins/eap_ttls/Makefile
1783         src/libcharon/plugins/eap_peap/Makefile
1784         src/libcharon/plugins/eap_tnc/Makefile
1785         src/libcharon/plugins/eap_radius/Makefile
1786         src/libcharon/plugins/xauth_generic/Makefile
1787         src/libcharon/plugins/xauth_eap/Makefile
1788         src/libcharon/plugins/xauth_pam/Makefile
1789         src/libcharon/plugins/xauth_noauth/Makefile
1790         src/libcharon/plugins/tnc_ifmap/Makefile
1791         src/libcharon/plugins/tnc_pdp/Makefile
1792         src/libcharon/plugins/socket_default/Makefile
1793         src/libcharon/plugins/socket_dynamic/Makefile
1794         src/libcharon/plugins/socket_win/Makefile
1795         src/libcharon/plugins/connmark/Makefile
1796         src/libcharon/plugins/forecast/Makefile
1797         src/libcharon/plugins/farp/Makefile
1798         src/libcharon/plugins/smp/Makefile
1799         src/libcharon/plugins/sql/Makefile
1800         src/libcharon/plugins/dnscert/Makefile
1801         src/libcharon/plugins/ipseckey/Makefile
1802         src/libcharon/plugins/medsrv/Makefile
1803         src/libcharon/plugins/medcli/Makefile
1804         src/libcharon/plugins/addrblock/Makefile
1805         src/libcharon/plugins/unity/Makefile
1806         src/libcharon/plugins/uci/Makefile
1807         src/libcharon/plugins/ha/Makefile
1808         src/libcharon/plugins/kernel_libipsec/Makefile
1809         src/libcharon/plugins/kernel_wfp/Makefile
1810         src/libcharon/plugins/kernel_iph/Makefile
1811         src/libcharon/plugins/whitelist/Makefile
1812         src/libcharon/plugins/ext_auth/Makefile
1813         src/libcharon/plugins/lookip/Makefile
1814         src/libcharon/plugins/error_notify/Makefile
1815         src/libcharon/plugins/certexpire/Makefile
1816         src/libcharon/plugins/systime_fix/Makefile
1817         src/libcharon/plugins/led/Makefile
1818         src/libcharon/plugins/duplicheck/Makefile
1819         src/libcharon/plugins/coupling/Makefile
1820         src/libcharon/plugins/radattr/Makefile
1821         src/libcharon/plugins/osx_attr/Makefile
1822         src/libcharon/plugins/android_dns/Makefile
1823         src/libcharon/plugins/android_log/Makefile
1824         src/libcharon/plugins/maemo/Makefile
1825         src/libcharon/plugins/stroke/Makefile
1826         src/libcharon/plugins/vici/Makefile
1827         src/libcharon/plugins/vici/ruby/Makefile
1828         src/libcharon/plugins/vici/python/Makefile
1829         src/libcharon/plugins/updown/Makefile
1830         src/libcharon/plugins/dhcp/Makefile
1831         src/libcharon/plugins/load_tester/Makefile
1832         src/libcharon/plugins/resolve/Makefile
1833         src/libcharon/plugins/attr/Makefile
1834         src/libcharon/plugins/attr_sql/Makefile
1835         src/libcharon/tests/Makefile
1836         src/stroke/Makefile
1837         src/ipsec/Makefile
1838         src/starter/Makefile
1839         src/starter/tests/Makefile
1840         src/_updown/Makefile
1841         src/_copyright/Makefile
1842         src/scepclient/Makefile
1843         src/aikgen/Makefile
1844         src/pki/Makefile
1845         src/pki/man/Makefile
1846         src/pool/Makefile
1847         src/dumm/Makefile
1848         src/dumm/ext/extconf.rb
1849         src/libfast/Makefile
1850         src/manager/Makefile
1851         src/medsrv/Makefile
1852         src/checksum/Makefile
1853         src/conftest/Makefile
1854         src/pt-tls-client/Makefile
1855         src/swanctl/Makefile
1856         scripts/Makefile
1857         testing/Makefile
1858 ])
1859
1860 # =================
1861 #  build man pages
1862 # =================
1863
1864 AC_CONFIG_FILES([
1865         conf/strongswan.conf.5.head
1866         conf/strongswan.conf.5.tail
1867         man/ipsec.conf.5
1868         man/ipsec.secrets.5
1869         src/charon-cmd/charon-cmd.8
1870         src/pki/man/pki.1
1871         src/pki/man/pki---gen.1
1872         src/pki/man/pki---issue.1
1873         src/pki/man/pki---keyid.1
1874         src/pki/man/pki---pkcs7.1
1875         src/pki/man/pki---pkcs12.1
1876         src/pki/man/pki---print.1
1877         src/pki/man/pki---pub.1
1878         src/pki/man/pki---req.1
1879         src/pki/man/pki---self.1
1880         src/pki/man/pki---signcrl.1
1881         src/pki/man/pki---acert.1
1882         src/pki/man/pki---verify.1
1883         src/swanctl/swanctl.8
1884         src/swanctl/swanctl.conf.5.head
1885         src/swanctl/swanctl.conf.5.tail
1886 ])
1887
1888 AC_OUTPUT
1889
1890 # ========================
1891 #  report enabled plugins
1892 # ========================
1893
1894 AC_MSG_RESULT([])
1895 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1896 AC_MSG_RESULT([-----------------------------------------------------])
1897
1898 AC_MSG_RESULT([libstrongswan:$s_plugins])
1899 AC_MSG_RESULT([libcharon:    $c_plugins])
1900 AC_MSG_RESULT([libhydra:     $h_plugins])
1901 AC_MSG_RESULT([libtnccs:     $t_plugins])
1902 AC_MSG_RESULT([])