configure.ac

   1
   2 AC_INIT([iptables], [1.4.21])
   3
   4 # See libtool.info "Libtool's versioning system"
   5 libxtables_vcurrent=10
   6 libxtables_vage=0
   7
   8 AC_CONFIG_AUX_DIR([build-aux])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_PROG_INSTALL
  12 AM_INIT_AUTOMAKE([-Wall])
  13 AC_PROG_CC
  14 AM_PROG_CC_C_O
  15 AC_DISABLE_STATIC
  16 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  17 AM_PROG_LIBTOOL
  18
  19 AC_ARG_WITH([kernel],
  20         AS_HELP_STRING([--with-kernel=PATH],
  21         [Path to kernel source/build directory]),
  22         [kbuilddir="$withval"; ksourcedir="$withval";])
  23 AC_ARG_WITH([kbuild],
  24         AS_HELP_STRING([--with-kbuild=PATH],
  25         [Path to kernel build directory [[/lib/modules/CURRENT/build]]]),
  26         [kbuilddir="$withval"])
  27 AC_ARG_WITH([ksource],
  28         AS_HELP_STRING([--with-ksource=PATH],
  29         [Path to kernel source directory [[/lib/modules/CURRENT/source]]]),
  30         [ksourcedir="$withval"])
  31 AC_ARG_WITH([xtlibdir],
  32         AS_HELP_STRING([--with-xtlibdir=PATH],
  33         [Path where to install Xtables extensions [[LIBEXECDIR/xtables]]]),
  34         [xtlibdir="$withval"],
  35         [xtlibdir="${libdir}/xtables"])
  36 AC_ARG_ENABLE([ipv4],
  37         AS_HELP_STRING([--disable-ipv4], [Do not build iptables]),
  38         [enable_ipv4="$enableval"], [enable_ipv4="yes"])
  39 AC_ARG_ENABLE([ipv6],
  40         AS_HELP_STRING([--disable-ipv6], [Do not build ip6tables]),
  41         [enable_ipv6="$enableval"], [enable_ipv6="yes"])
  42 AC_ARG_ENABLE([largefile],
  43         AS_HELP_STRING([--disable-largefile], [Do not build largefile support]),
  44         [enable_largefile="$enableval"],
  45         [enable_largefile="yes";
  46         largefile_cppflags='-D_LARGEFILE_SOURCE=1 -D_LARGE_FILES -D_FILE_OFFSET_BITS=64'])
  47 AC_ARG_ENABLE([devel],
  48         AS_HELP_STRING([--enable-devel],
  49         [Install Xtables development headers]),
  50         [enable_devel="$enableval"], [enable_devel="yes"])
  51 AC_ARG_ENABLE([libipq],
  52         AS_HELP_STRING([--enable-libipq], [Build and install libipq]),
  53         [enable_libipq="$enableval"], [enable_libipq="no"])
  54 AC_ARG_ENABLE([bpf-compiler],
  55         AS_HELP_STRING([--enable-bpf-compiler], [Build bpf compiler]),
  56         [enable_bpfc="yes"], [enable_bpfc="no"])
  57 AC_ARG_ENABLE([nfsynproxy],
  58         AS_HELP_STRING([--enable-nfsynproxy], [Build SYNPROXY configuration tool]),
  59         [enable_nfsynproxy="yes"], [enable_nfsynproxy="no"])
  60 AC_ARG_WITH([pkgconfigdir], AS_HELP_STRING([--with-pkgconfigdir=PATH],
  61         [Path to the pkgconfig directory [[LIBDIR/pkgconfig]]]),
  62         [pkgconfigdir="$withval"], [pkgconfigdir='${libdir}/pkgconfig'])
  63
  64 libiptc_LDFLAGS2="";
  65 AX_CHECK_LINKER_FLAGS([-Wl,--no-as-needed],
  66         [libiptc_LDFLAGS2="-Wl,--no-as-needed"])
  67 AC_SUBST([libiptc_LDFLAGS2])
  68
  69 AC_MSG_CHECKING([whether $LD knows -Wl,--no-undefined])
  70 saved_LDFLAGS="$LDFLAGS";
  71 LDFLAGS="-Wl,--no-undefined";
  72 AC_LINK_IFELSE([AC_LANG_SOURCE([int main(void) {}])],
  73         [noundef_LDFLAGS="$LDFLAGS"; AC_MSG_RESULT([yes])],
  74         [AC_MSG_RESULT([no])]
  75 )
  76 LDFLAGS="$saved_LDFLAGS";
  77
  78 blacklist_modules="";
  79
  80 AC_CHECK_HEADERS([linux/dccp.h linux/ip_vs.h linux/magic.h linux/proc_fs.h])
  81 if test "$ac_cv_header_linux_dccp_h" != "yes"; then
  82         blacklist_modules="$blacklist_modules dccp";
  83 fi;
  84 if test "$ac_cv_header_linux_ip_vs_h" != "yes"; then
  85         blacklist_modules="$blacklist_modules ipvs";
  86 fi;
  87
  88 PKG_CHECK_MODULES([libnetfilter_conntrack], [libnetfilter_conntrack >= 1.0.4],
  89         [nfconntrack=1], [nfconntrack=0])
  90 AM_CONDITIONAL([HAVE_LIBNETFILTER_CONNTRACK], [test "$nfconntrack" = 1])
  91
  92 if test "$nfconntrack" -ne 1; then
  93         blacklist_modules="$blacklist_modules connlabel";
  94         echo "WARNING: libnetfilter_conntrack not found, connlabel match will not be built";
  95 fi;
  96
  97 AC_SUBST([blacklist_modules])
  98 AC_CHECK_SIZEOF([struct ip6_hdr], [], [#include <netinet/ip6.h>])
  99
 100 AM_CONDITIONAL([ENABLE_STATIC], [test "$enable_static" = "yes"])
 101 AM_CONDITIONAL([ENABLE_SHARED], [test "$enable_shared" = "yes"])
 102 AM_CONDITIONAL([ENABLE_IPV4], [test "$enable_ipv4" = "yes"])
 103 AM_CONDITIONAL([ENABLE_IPV6], [test "$enable_ipv6" = "yes"])
 104 AM_CONDITIONAL([ENABLE_LARGEFILE], [test "$enable_largefile" = "yes"])
 105 AM_CONDITIONAL([ENABLE_DEVEL], [test "$enable_devel" = "yes"])
 106 AM_CONDITIONAL([ENABLE_LIBIPQ], [test "$enable_libipq" = "yes"])
 107 AM_CONDITIONAL([ENABLE_BPFC], [test "$enable_bpfc" = "yes"])
 108 AM_CONDITIONAL([ENABLE_SYNCONF], [test "$enable_nfsynproxy" = "yes"])
 109
 110 if test "x$enable_bpfc" = "xyes" || test "x$enable_nfsynproxy" = "xyes"; then
 111         AC_CHECK_LIB(pcap, pcap_compile,, AC_MSG_ERROR(missing libpcap library required by bpf compiler or nfsynproxy tool))
 112 fi
 113
 114 PKG_CHECK_MODULES([libnfnetlink], [libnfnetlink >= 1.0],
 115         [nfnetlink=1], [nfnetlink=0])
 116 AM_CONDITIONAL([HAVE_LIBNFNETLINK], [test "$nfnetlink" = 1])
 117
 118 regular_CFLAGS="-Wall -Waggregate-return -Wmissing-declarations \
 119         -Wmissing-prototypes -Wredundant-decls -Wshadow -Wstrict-prototypes \
 120         -Winline -pipe";
 121 regular_CPPFLAGS="${largefile_cppflags} -D_REENTRANT \
 122         -DXTABLES_LIBDIR=\\\"\${xtlibdir}\\\" -DXTABLES_INTERNAL";
 123 kinclude_CPPFLAGS="";
 124 if [[ -n "$kbuilddir" ]]; then
 125         kinclude_CPPFLAGS="$kinclude_CPPFLAGS -I$kbuilddir/include/uapi -I$kbuilddir/include";
 126 fi;
 127 if [[ -n "$ksourcedir" ]]; then
 128         kinclude_CPPFLAGS="$kinclude_CPPFLAGS -I$ksourcedir/include/uapi -I$ksourcedir/include";
 129 fi;
 130 pkgdatadir='${datadir}/xtables';
 131
 132 define([EXPAND_VARIABLE],
 133 [$2=[$]$1
 134 if test $prefix = 'NONE'; then
 135         prefix="/usr/local"
 136 fi
 137 while true; do
 138   case "[$]$2" in
 139     *\[$]* ) eval "$2=[$]$2" ;;
 140     *) break ;;
 141   esac
 142 done
 143 eval "$2=[$]$2"
 144 ])dnl EXPAND_VARIABLE
 145
 146 AC_SUBST([regular_CFLAGS])
 147 AC_SUBST([regular_CPPFLAGS])
 148 AC_SUBST([noundef_LDFLAGS])
 149 AC_SUBST([kinclude_CPPFLAGS])
 150 AC_SUBST([kbuilddir])
 151 AC_SUBST([ksourcedir])
 152 AC_SUBST([xtlibdir])
 153 AC_SUBST([pkgconfigdir])
 154 AC_SUBST([pkgdatadir])
 155 AC_SUBST([libxtables_vcurrent])
 156 AC_SUBST([libxtables_vage])
 157 libxtables_vmajor=$(($libxtables_vcurrent - $libxtables_vage));
 158 AC_SUBST([libxtables_vmajor])
 159
 160 AC_CONFIG_FILES([Makefile extensions/GNUmakefile include/Makefile
 161         iptables/Makefile iptables/xtables.pc
 162         iptables/iptables.8 iptables/iptables-extensions.8.tmpl
 163         iptables/iptables-save.8 iptables/iptables-restore.8
 164         iptables/iptables-apply.8 iptables/iptables-xml.1
 165         libipq/Makefile libipq/libipq.pc
 166         libiptc/Makefile libiptc/libiptc.pc
 167         libiptc/libip4tc.pc libiptc/libip6tc.pc
 168         libxtables/Makefile utils/Makefile
 169         include/xtables-version.h include/iptables/internal.h])
 170 AC_OUTPUT
 171
 172
 173 EXPAND_VARIABLE(xtlibdir, e_xtlibdir)
 174 EXPAND_VARIABLE(pkgconfigdir, e_pkgconfigdir)
 175
 176 echo "
 177 Iptables Configuration:
 178   IPv4 support:                         ${enable_ipv4}
 179   IPv6 support:                         ${enable_ipv6}
 180   Devel support:                        ${enable_devel}
 181   IPQ support:                          ${enable_libipq}
 182   Large file support:                   ${enable_largefile}
 183   BPF utils support:                    ${enable_bpfc}
 184   nfsynproxy util support:              ${enable_nfsynproxy}
 185
 186 Build parameters:
 187   Put plugins into executable (static): ${enable_static}
 188   Support plugins via dlopen (shared):  ${enable_shared}
 189   Installation prefix (--prefix):       ${prefix}
 190   Xtables extension directory:          ${e_xtlibdir}
 191   Pkg-config directory:                 ${e_pkgconfigdir}"
 192
 193 if [[ -n "$ksourcedir" ]]; then
 194         echo "  Kernel source directory:                ${ksourcedir}"
 195 fi;
 196 if [[ -n "$kbuilddir" ]]; then
 197         echo "  Kernel build directory:         ${kbuilddir}"
 198 fi;
 199
 200 echo "  Host:                                   ${host}
 201   GCC binary:                           ${CC}"
 202
 203 test x"$blacklist_modules" = "x" || echo "
 204 Iptables modules that will not be built: $blacklist_modules"