configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[31],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26
  27 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  30
  31 AC_CANONICAL_HOST
  32 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  33 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  34        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  35       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  36
  37 AM_SILENT_RULES([yes])
  38
  39 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  40
  41 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  42         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 ])
  45
  46 # i18n stuff for the PolicyKit policy files
  47 IT_PROG_INTLTOOL([0.40.0])
  48
  49 GETTEXT_PACKAGE=systemd
  50 AC_SUBST(GETTEXT_PACKAGE)
  51
  52 AC_PROG_MKDIR_P
  53 AC_PROG_LN_S
  54 AC_PROG_SED
  55
  56 AC_PROG_CC
  57 AC_PROG_CC_C99
  58 AM_PROG_CC_C_O
  59 AC_PROG_GCC_TRADITIONAL
  60
  61 AC_CHECK_TOOL(OBJCOPY, objcopy)
  62 AC_CHECK_TOOL(STRINGS, strings)
  63
  64 CC_CHECK_CFLAGS_APPEND([ \
  65         -pipe \
  66         -Wall \
  67         -W \
  68         -Wextra \
  69         -Wno-inline \
  70         -Wvla \
  71         -Wundef \
  72         -Wformat=2 \
  73         -Wlogical-op \
  74         -Wsign-compare \
  75         -Wformat-security \
  76         -Wmissing-include-dirs \
  77         -Wformat-nonliteral \
  78         -Wold-style-definition \
  79         -Wpointer-arith \
  80         -Winit-self \
  81         -Wdeclaration-after-statement \
  82         -Wfloat-equal \
  83         -Wmissing-prototypes \
  84         -Wstrict-prototypes \
  85         -Wredundant-decls \
  86         -Wmissing-declarations \
  87         -Wmissing-noreturn \
  88         -Wshadow \
  89         -Wendif-labels \
  90         -Wcast-align \
  91         -Wstrict-aliasing=2 \
  92         -Wwrite-strings \
  93         -Wno-long-long \
  94         -Wno-overlength-strings \
  95         -Wno-unused-parameter \
  96         -Wno-missing-field-initializers \
  97         -Wno-unused-result \
  98         -Wp,-D_FORTIFY_SOURCE=2 \
  99         -ffast-math \
 100         -fno-common \
 101         -fdiagnostics-show-option \
 102         -fno-strict-aliasing \
 103         -fvisibility=hidden \
 104         -ffunction-sections \
 105         -fdata-sections \
 106         -Wl,--as-needed \
 107         -Wl,--gc-sections])
 108
 109 LT_PREREQ(2.2)
 110 LT_INIT
 111
 112 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 113 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 114
 115 save_LIBS="$LIBS"
 116 LIBS=
 117 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 118 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 119 CAP_LIBS="$LIBS"
 120 LIBS="$save_LIBS"
 121 AC_SUBST(CAP_LIBS)
 122
 123 # This makes sure pkg.m4 is available.
 124 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 125
 126 PKG_CHECK_MODULES(UDEV, [ libudev >= 172 ])
 127 AC_SUBST(UDEV_CFLAGS)
 128 AC_SUBST(UDEV_LIBS)
 129
 130 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 131 AC_SUBST(DBUS_CFLAGS)
 132 AC_SUBST(DBUS_LIBS)
 133
 134 have_selinux=no
 135 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 136 if test "x$enable_selinux" != "xno"; then
 137         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 138                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 139         AC_SUBST(SELINUX_CFLAGS)
 140         AC_SUBST(SELINUX_LIBS)
 141         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 142                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 143         fi
 144 fi
 145 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 146
 147 AC_ARG_ENABLE([tcpwrap],
 148         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 149                 [case "${enableval}" in
 150                         yes) have_tcpwrap=yes ;;
 151                         no) have_tcpwrap=no ;;
 152                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 153                 esac],
 154                 [have_tcpwrap=auto])
 155
 156 if test "x${have_tcpwrap}" != xno ; then
 157         ACX_LIBWRAP
 158         if test "x${LIBWRAP_LIBS}" = x ; then
 159                 if test "x$have_tcpwrap" = xyes ; then
 160                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 161                 fi
 162                 have_tcpwrap=no
 163         else
 164                 have_tcpwrap=yes
 165         fi
 166 else
 167         LIBWRAP_LIBS=
 168 fi
 169 AC_SUBST(LIBWRAP_LIBS)
 170
 171 AC_ARG_ENABLE([pam],
 172         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 173                 [case "${enableval}" in
 174                         yes) have_pam=yes ;;
 175                         no) have_pam=no ;;
 176                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 177                 esac],
 178                 [have_pam=auto])
 179
 180 if test "x${have_pam}" != xno ; then
 181         AC_CHECK_HEADERS(
 182                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 183                 [have_pam=yes],
 184                 [if test "x$have_pam" = xyes ; then
 185                         AC_MSG_ERROR([*** PAM headers not found.])
 186                 fi])
 187
 188         AC_CHECK_LIB(
 189                 [pam],
 190                 [pam_syslog],
 191                 [have_pam=yes],
 192                 [if test "x$have_pam" = xyes ; then
 193                         AC_MSG_ERROR([*** libpam not found.])
 194                 fi])
 195
 196         if test "x$have_pam" = xyes ; then
 197                 PAM_LIBS="-lpam -lpam_misc"
 198                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 199         else
 200                 have_pam=no
 201         fi
 202 else
 203         PAM_LIBS=
 204 fi
 205 AC_SUBST(PAM_LIBS)
 206 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 207
 208 AC_ARG_ENABLE([acl],
 209         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 210                 [case "${enableval}" in
 211                         yes) have_acl=yes ;;
 212                         no) have_acl=no ;;
 213                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 214                 esac],
 215                 [have_acl=auto])
 216
 217 if test "x${have_acl}" != xno ; then
 218         AC_CHECK_HEADERS(
 219                 [sys/acl.h acl/libacl.h],
 220                 [have_acl=yes],
 221                 [if test "x$have_acl" = xyes ; then
 222                         AC_MSG_ERROR([*** ACL headers not found.])
 223                 fi])
 224
 225         AC_CHECK_LIB(
 226                 [acl],
 227                 [acl_get_file],
 228                 [have_acl=yes],
 229                 [if test "x$have_acl" = xyes ; then
 230                         AC_MSG_ERROR([*** libacl not found.])
 231                 fi])
 232
 233         if test "x$have_acl" = xyes ; then
 234                 ACL_LIBS="-lacl"
 235                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 236         else
 237                 have_acl=no
 238         fi
 239 else
 240         ACL_LIBS=
 241 fi
 242 AC_SUBST(ACL_LIBS)
 243 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 244
 245 AC_ARG_ENABLE([audit],
 246         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 247                 [case "${enableval}" in
 248                         yes) have_audit=yes ;;
 249                         no) have_audit=no ;;
 250                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 251                 esac],
 252                 [have_audit=auto])
 253
 254 if test "x${have_audit}" != xno ; then
 255         AC_CHECK_HEADERS(
 256                 [libaudit.h],
 257                 [have_audit=yes],
 258                 [if test "x$have_audit" = xyes ; then
 259                         AC_MSG_ERROR([*** AUDIT headers not found.])
 260                 fi])
 261
 262         AC_CHECK_LIB(
 263                 [audit],
 264                 [audit_open],
 265                 [have_audit=yes],
 266                 [if test "x$have_audit" = xyes ; then
 267                         AC_MSG_ERROR([*** libaudit not found.])
 268                 fi])
 269
 270         if test "x$have_audit" = xyes ; then
 271                 AUDIT_LIBS="-laudit"
 272                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 273         else
 274                 have_audit=no
 275         fi
 276 else
 277         AUDIT_LIBS=
 278 fi
 279 AC_SUBST(AUDIT_LIBS)
 280
 281 have_libcryptsetup=no
 282 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 283 if test "x$enable_libcryptsetup" != "xno"; then
 284         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 285                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 286         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
 287         AC_SUBST(LIBCRYPTSETUP_LIBS)
 288         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 289                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 290         fi
 291 fi
 292 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 293
 294 have_binfmt=no
 295 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 296 if test "x$enable_binfmt" != "xno"; then
 297         have_binfmt=yes
 298 fi
 299 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 300
 301 have_gtk=no
 302 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 303 if test "x$enable_gtk" != "xno"; then
 304         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
 305                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 306         AC_SUBST(GTK_CFLAGS)
 307         AC_SUBST(GTK_LIBS)
 308         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 309                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
 310         fi
 311 fi
 312 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 313
 314 if test "$have_gtk" = "yes"; then
 315         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 316         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
 317
 318         AC_SUBST(LIBNOTIFY_CFLAGS)
 319         AC_SUBST(LIBNOTIFY_LIBS)
 320 fi
 321 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
 322
 323 AM_PROG_VALAC([0.10])
 324 AC_SUBST(VAPIDIR)
 325 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 326
 327 AC_PATH_PROG([XSLTPROC], [xsltproc])
 328 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 329
 330 AC_PATH_PROG([M4], [m4])
 331
 332 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux or other]))
 333 if test "z$with_distro" = "z"; then
 334         if test "$cross_compiling" = yes; then
 335                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 336         else
 337                 test -f "/etc/redhat-release" && with_distro="fedora"
 338                 test -f "/etc/SuSE-release" && with_distro="suse"
 339                 test -f "/etc/debian_version" &&  with_distro="debian"
 340                 test -f "/etc/arch-release" && with_distro="arch"
 341                 test -f "/etc/gentoo-release" && with_distro="gentoo"
 342                 test -f "/etc/slackware-version" && with_distro="slackware"
 343                 test -f "/etc/frugalware-release" && with_distro="frugalware"
 344                 test -f "/etc/altlinux-release" && with_distro="altlinux"
 345                 test -f "/etc/mandriva-release" && with_distro="mandriva"
 346                 test -f "/etc/meego-release" && with_distro="meego"
 347                 test -f "/etc/angstrom-version" && with_distro="angstrom"
 348                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 349                         with_distro="ubuntu"
 350                 fi
 351         fi
 352         if test "z$with_distro" = "z"; then
 353                 with_distro=`uname -s`
 354         fi
 355 fi
 356 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 357 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 358
 359 # Location of the init scripts as mandated by LSB
 360 SYSTEM_SYSVINIT_PATH=/etc/init.d
 361 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 362
 363 M4_DISTRO_FLAG=
 364 have_plymouth=no
 365
 366 case $with_distro in
 367         fedora)
 368                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 369                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 370                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 371                 have_plymouth=yes
 372                 ;;
 373         suse)
 374                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 375                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 376                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 377                 have_plymouth=yes
 378                 ;;
 379         debian)
 380                 SYSTEM_SYSVRCND_PATH=/etc
 381                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 382                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 383                 ;;
 384         ubuntu)
 385                 SYSTEM_SYSVRCND_PATH=/etc
 386                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 387                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
 388                 ;;
 389         arch)
 390                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 391                 SYSTEM_SYSVRCND_PATH=/etc
 392                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 393                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 394                 ;;
 395         gentoo)
 396                 SYSTEM_SYSVINIT_PATH=
 397                 SYSTEM_SYSVRCND_PATH=
 398                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 399                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 400                 ;;
 401         slackware)
 402                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 403                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 404                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 405                 ;;
 406         frugalware)
 407                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 408                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 409                 M4_DISTRO_FLAG=-DTARGET_FRUGALWARE=1
 410                 have_plymouth=yes
 411                 ;;
 412         altlinux)
 413                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 414                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 415                 M4_DISTRO_FLAG=-DTARGET_ALTLINUX=1
 416                 have_plymouth=yes
 417                 ;;
 418         mandriva)
 419                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 420                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 421                 M4_DISTRO_FLAG=-DTARGET_MANDRIVA=1
 422                 have_plymouth=yes
 423                 ;;
 424         meego)
 425                 SYSTEM_SYSVINIT_PATH=
 426                 SYSTEM_SYSVRCND_PATH=
 427                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
 428                 M4_DISTRO_FLAG=-DTARGET_MEEGO=1
 429                 ;;
 430         angstrom)
 431                 SYSTEM_SYSVRCND_PATH=/etc
 432                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 433                 M4_DISTRO_FLAG=-DTARGET_ANGSTROM=1
 434                 ;;
 435         other)
 436                 ;;
 437         *)
 438                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 439                 ;;
 440 esac
 441
 442 AC_ARG_WITH([sysvinit-path],
 443         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 444                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 445         [SYSTEM_SYSVINIT_PATH="$withval"],
 446         [])
 447
 448 AC_ARG_WITH([sysvrcd-path],
 449         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 450                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 451         [SYSTEM_SYSVRCND_PATH="$withval"],
 452         [])
 453
 454 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 455 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 456 AC_SUBST(M4_DISTRO_FLAG)
 457
 458 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 459         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 460         SYSTEM_SYSV_COMPAT="yes"
 461 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 462         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 463 else
 464         SYSTEM_SYSV_COMPAT="no"
 465 fi
 466
 467 AC_ARG_WITH([tty-gid],
 468         [AS_HELP_STRING([--with-tty-gid=GID],
 469                 [Specify the numeric GID of the 'tty' group])],
 470         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 471         [])
 472
 473 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
 474 if test -n "$enable_plymouth"; then
 475         have_plymouth="$enable_plymouth"
 476 fi
 477
 478 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 479 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 480 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 481 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 482 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 483 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 484 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 485 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 486 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 487 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 488 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 489 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
 490 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 491
 492 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
 493 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 494
 495 AC_ARG_WITH([dbuspolicydir],
 496         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 497         [],
 498         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 499
 500 AC_ARG_WITH([dbussessionservicedir],
 501         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 502         [],
 503         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 504
 505 AC_ARG_WITH([dbussystemservicedir],
 506         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 507         [],
 508         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 509
 510 AC_ARG_WITH([dbusinterfacedir],
 511         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 512         [],
 513         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 514
 515 AC_ARG_WITH([udevrulesdir],
 516         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 517         [],
 518         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 519
 520 AC_ARG_WITH([pamlibdir],
 521         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 522         [],
 523         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 524
 525 AC_ARG_WITH([rootdir],
 526         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 527         [],
 528         [with_rootdir=${ac_default_prefix}])
 529
 530 AC_ARG_WITH([rootlibdir],
 531         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 532         [],
 533         [with_rootlibdir=${libdir}])
 534
 535 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 536 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 537 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 538 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 539 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 540 AC_SUBST([pamlibdir], [$with_pamlibdir])
 541 AC_SUBST([rootdir], [$with_rootdir])
 542 AC_SUBST([rootlibdir], [$with_rootlibdir])
 543
 544 AC_CONFIG_FILES([Makefile po/Makefile.in])
 545 AC_OUTPUT
 546 AC_MSG_RESULT([
 547         $PACKAGE_NAME $VERSION
 548
 549         Distribution:            ${with_distro}
 550         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 551         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 552         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 553         Gtk:                     ${have_gtk}
 554         libcryptsetup:           ${have_libcryptsetup}
 555         tcpwrap:                 ${have_tcpwrap}
 556         PAM:                     ${have_pam}
 557         AUDIT:                   ${have_audit}
 558         SELinux:                 ${have_selinux}
 559         ACL:                     ${have_acl}
 560         binfmt:                  ${have_binfmt}
 561         plymouth:                ${have_plymouth}
 562         prefix:                  ${prefix}
 563         root dir:                ${with_rootdir}
 564         lib dir:                 ${libdir}
 565         rootlib dir:             ${with_rootlibdir}
 566         pam modules dir:         ${with_pamlibdir}
 567         udev rules dir:          ${with_udevrulesdir}
 568         dbus policy dir:         ${with_dbuspolicydir}
 569         dbus session dir:        ${with_dbussessionservicedir}
 570         dbus system dir:         ${with_dbussystemservicedir}
 571         dbus interfaces dir:     ${with_dbusinterfacedir}
 572 ])