configure.ac

   1 #
   2 # Copyright (C) 2007-2014 Tobias Brunner
   3 # Copyright (C) 2006-2013 Andreas Steffen
   4 # Copyright (C) 2006-2013 Martin Willi
   5 # Hochschule fuer Technik Rapperswil
   6 #
   7 # This program is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by the
   9 # Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 # for more details.
  16 #
  17
  18 # ============================
  19 #  initialize & set some vars
  20 # ============================
  21
  22 AC_INIT([strongSwan],[5.2.0dr5])
  23 AM_INIT_AUTOMAKE(m4_esyscmd([
  24         echo tar-ustar
  25         echo subdir-objects
  26         case `automake --version | head -n 1` in
  27                 *" 1.9"*);;
  28                 *" 1.10"*);;
  29                 *" 1.11"*);;
  30                 # don't use parallel test harness in 1.12 and up
  31                 *) echo serial-tests;;
  32         esac
  33 ]))
  34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  35 AC_CONFIG_MACRO_DIR([m4/config])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
  38 PKG_PROG_PKG_CONFIG
  39
  40 m4_include(m4/macros/split-package-version.m4)
  41 SPLIT_PACKAGE_VERSION
  42
  43 # =================================
  44 #  check --enable-xxx & --with-xxx
  45 # =================================
  46
  47 m4_include(m4/macros/with.m4)
  48
  49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
  50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
  51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
  52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
  53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
  54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
  55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
  56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
  57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
  58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
  59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
  60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
  61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
  62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
  63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
  64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
  65
  66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
  67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
  68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
  69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
  70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
  71
  72 if test -n "$PKG_CONFIG"; then
  73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
  74 fi
  75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
  76 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
  77 AC_SUBST(systemdsystemunitdir)
  78
  79 AC_ARG_WITH(
  80         [user],
  81         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
  82         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
  83          AC_SUBST(ipsecuser, "$withval")],
  84         [AC_SUBST(ipsecuser, "root")]
  85 )
  86
  87 AC_ARG_WITH(
  88         [group],
  89         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
  90         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
  91          AC_SUBST(ipsecgroup, "$withval")],
  92         [AC_SUBST(ipsecgroup, "root")]
  93 )
  94
  95 AC_ARG_WITH(
  96         [charon-udp-port],
  97         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
  98         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
  99          AC_SUBST(charon_udp_port, [$withval])],
 100         [AC_SUBST(charon_udp_port, 500)]
 101 )
 102
 103 AC_ARG_WITH(
 104         [charon-natt-port],
 105         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
 106         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
 107          AC_SUBST(charon_natt_port, [$withval])],
 108         [AC_SUBST(charon_natt_port, 4500)]
 109 )
 110
 111 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
 112 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
 113         AC_MSG_ERROR(the ports have to be different)
 114 else
 115         AC_MSG_RESULT(ok)
 116 fi
 117
 118 # convert script name to uppercase
 119 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
 120
 121 m4_include(m4/macros/enable-disable.m4)
 122
 123 # crypto plugins
 124 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
 125 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
 126 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
 127 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
 128 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
 129 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
 130 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
 131 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
 132 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
 133 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
 134 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
 135 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
 136 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
 137 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
 138 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
 139 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
 140 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
 141 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
 142 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
 143 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
 144 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
 145 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
 146 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
 147 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
 148 # encoding/decoding plugins
 149 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
 150 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
 151 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
 152 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
 153 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
 154 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
 155 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
 156 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
 157 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
 158 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
 159 # fetcher/resolver plugins
 160 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
 161 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
 162 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
 163 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
 164 # database plugins
 165 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
 166 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
 167 # authentication/credential plugins
 168 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
 169 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
 170 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
 171 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
 172 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
 173 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
 174 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
 175 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
 176 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
 177 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
 178 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
 179 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
 180 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
 181 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
 182 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
 183 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
 184 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
 185 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
 186 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
 187 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
 188 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
 189 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
 190 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
 191 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
 192 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
 193 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
 194 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
 195 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
 196 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
 197 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
 198 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
 199 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
 200 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
 201 # kernel interfaces / sockets
 202 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
 203 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
 204 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
 205 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
 206 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
 207 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
 208 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
 209 # configuration/control plugins
 210 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
 211 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
 212 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
 213 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
 214 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
 215 # attribute provider/consumer plugins
 216 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
 217 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
 218 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
 219 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
 220 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
 221 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
 222 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
 223 # TNC modules/plugins
 224 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
 225 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
 226 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
 227 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
 228 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
 229 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
 230 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
 231 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
 232 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
 233 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
 234 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
 235 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
 236 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
 237 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
 238 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
 239 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
 240 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
 241 # misc plugins
 242 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
 243 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
 244 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
 245 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
 246 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
 247 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
 248 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
 249 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
 250 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
 251 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
 252 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
 253 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
 254 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
 255 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
 256 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
 257 # programs/components
 258 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
 259 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
 260 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
 261 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
 262 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
 263 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
 264 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
 265 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
 266 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
 267 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
 268 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
 269 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
 270 ARG_ENABL_SET([svc],            [enable charon Windows service.])
 271 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
 272 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
 273 ARG_DISBL_SET([tools],          [disable additional utilities (scepclient).])
 274 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
 275 # optional features
 276 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
 277 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
 278 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
 279 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
 280 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
 281 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
 282 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
 283 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
 284 # compile options
 285 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
 286 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
 287 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
 288 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
 289
 290 # ===================================
 291 #  option to disable default options
 292 # ===================================
 293
 294 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
 295
 296 if test x$defaults = xfalse; then
 297         for option in $enabled_by_default; do
 298                 eval test x\${${option}_given} = xtrue && continue
 299                 eval $option=false
 300         done
 301 fi
 302
 303 # ==============================
 304 #  option to enable all options
 305 # ==============================
 306
 307 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
 308
 309 if test x$all_given = xtrue; then
 310         for option in $disabled_by_default; do
 311                 eval test x\${${option}_given} = xtrue && continue
 312                 eval $option=true
 313         done
 314 fi
 315
 316 # ===========================
 317 #  set up compiler and flags
 318 # ===========================
 319
 320 if test -z "$CFLAGS"; then
 321         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
 322 fi
 323 AC_PROG_CC
 324 AM_PROG_CC_C_O
 325
 326 AC_LIB_PREFIX
 327 AC_C_BIGENDIAN
 328
 329 # =========================
 330 #  check required programs
 331 # =========================
 332
 333 LT_INIT
 334 AC_PROG_INSTALL
 335 AC_PROG_EGREP
 336 AC_PROG_AWK
 337 AC_PROG_LEX
 338 AC_PROG_YACC
 339 AM_PATH_PYTHON(,,[:])
 340 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 341 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 342
 343 # because gperf is not needed by end-users we just report it but do not abort on failure
 344 AC_MSG_CHECKING([gperf version >= 3.0.0])
 345 if test -x "$GPERF"; then
 346         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
 347                 AC_MSG_RESULT([yes])
 348         else
 349                 AC_MSG_RESULT([no])
 350         fi
 351 else
 352         AC_MSG_RESULT([not found])
 353 fi
 354
 355 # ========================
 356 #  dependency calculation
 357 # ========================
 358
 359 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
 360         xauth_generic=false;
 361 fi
 362
 363 if test x$kernel_libipsec = xtrue; then
 364         libipsec=true;
 365 fi
 366
 367 if test x$eap_aka_3gpp2 = xtrue; then
 368         gmp=true;
 369 fi
 370
 371 if test x$eap_aka = xtrue; then
 372         fips_prf=true;
 373         simaka=true;
 374 fi
 375
 376 if test x$eap_sim = xtrue; then
 377         fips_prf=true;
 378         simaka=true;
 379 fi
 380
 381 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
 382         radius=true;
 383 fi
 384
 385 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
 386         tnc_tnccs=true;
 387 fi
 388
 389 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
 390         tls=true;
 391 fi
 392
 393 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
 394         imcv=true;
 395 fi
 396
 397 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
 398         pts=true;
 399 fi
 400
 401 if test x$fips_prf = xtrue; then
 402         if test x$openssl = xfalse; then
 403                 sha1=true;
 404         fi
 405 fi
 406
 407 if test x$swanctl = xtrue; then
 408         vici=true
 409 fi
 410
 411 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
 412         xml=true
 413 fi
 414
 415 if test x$manager = xtrue; then
 416         fast=true
 417 fi
 418
 419 if test x$medsrv = xtrue; then
 420         mediation=true
 421         fast=true
 422 fi
 423
 424 if test x$medcli = xtrue; then
 425         mediation=true
 426 fi
 427
 428 # ===========================================
 429 #  check required libraries and header files
 430 # ===========================================
 431
 432 AC_HEADER_STDBOOL
 433 AC_FUNC_ALLOCA
 434 AC_FUNC_STRERROR_R
 435
 436 #  libraries needed on some platforms but not on others
 437 # ------------------------------------------------------
 438 saved_LIBS=$LIBS
 439
 440 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
 441 LIBS=""
 442 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 443 AC_SUBST(DLLIB)
 444
 445 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
 446 LIBS=""
 447 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
 448 AC_CHECK_FUNCS(backtrace)
 449 AC_SUBST(BTLIB)
 450
 451 # OpenSolaris needs libsocket and libnsl for socket()
 452 LIBS=""
 453 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
 454         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
 455 )
 456 AC_SUBST(SOCKLIB)
 457
 458 # FreeBSD has clock_gettime in libc, Linux needs librt
 459 LIBS=""
 460 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
 461 AC_CHECK_FUNCS(clock_gettime)
 462 AC_SUBST(RTLIB)
 463
 464 # Android has pthread_* functions in bionic (libc), others need libpthread
 465 LIBS=""
 466 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
 467 AC_SUBST(PTHREADLIB)
 468
 469 LIBS=$saved_LIBS
 470 # ------------------------------------------------------
 471
 472 AC_MSG_CHECKING(for dladdr)
 473 AC_COMPILE_IFELSE(
 474         [AC_LANG_PROGRAM(
 475                 [[#define _GNU_SOURCE
 476                   #include <dlfcn.h>]],
 477                 [[Dl_info* info = 0;
 478                   dladdr(0, info);]])],
 479         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
 480         [AC_MSG_RESULT([no])]
 481 )
 482
 483 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
 484 saved_LIBS=$LIBS
 485 LIBS=$PTHREADLIB
 486 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
 487 AC_RUN_IFELSE(
 488         [AC_LANG_SOURCE(
 489                 [[#include <pthread.h>
 490                   int main() { pthread_condattr_t attr;
 491                         pthread_condattr_init(&attr);
 492                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
 493         [AC_MSG_RESULT([yes]);
 494          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 495                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
 496         [AC_MSG_RESULT([no])],
 497         # Check existence of pthread_condattr_setclock if cross-compiling
 498         [AC_MSG_RESULT([unknown]);
 499          AC_CHECK_FUNCS(pthread_condattr_setclock,
 500                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 501                                    [have pthread_condattr_setclock()])]
 502         )]
 503 )
 504 # check if we actually are able to configure attributes on cond vars
 505 AC_CHECK_FUNCS(pthread_condattr_init)
 506 # instead of pthread_condattr_setclock Android has this function
 507 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
 508 # check if we can cancel threads
 509 AC_CHECK_FUNCS(pthread_cancel)
 510 # check if native rwlocks are available
 511 AC_CHECK_FUNCS(pthread_rwlock_init)
 512 # check if pthread spinlocks are available
 513 AC_CHECK_FUNCS(pthread_spin_init)
 514 # check if we have POSIX semaphore functions, including timed-wait
 515 AC_CHECK_FUNCS(sem_timedwait)
 516 LIBS=$saved_LIBS
 517
 518 AC_CHECK_FUNC(
 519         [gettid],
 520         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
 521         [AC_MSG_CHECKING([for SYS_gettid])
 522          AC_COMPILE_IFELSE(
 523                 [AC_LANG_PROGRAM(
 524                         [[#define _GNU_SOURCE
 525                           #include <unistd.h>
 526                           #include <sys/syscall.h>]],
 527                         [[int main() {
 528                           return syscall(SYS_gettid);}]])],
 529                 [AC_MSG_RESULT([yes]);
 530                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
 531                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
 532                 [AC_MSG_RESULT([no])]
 533         )]
 534 )
 535
 536 AC_CHECK_FUNC(
 537         [qsort_r],
 538         [
 539                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
 540                 # set -Werror so that we get an error for "argument ... has
 541                 # incompatible pointer type" warnings
 542                 save_CFLAGS="$CFLAGS"
 543                 CFLAGS="$CFLAGS -Werror"
 544                 AC_MSG_CHECKING([for GNU-style qsort_r])
 545                 AC_COMPILE_IFELSE(
 546                         [AC_LANG_PROGRAM(
 547                                 [[#define _GNU_SOURCE
 548                                   #include <stdlib.h>
 549                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
 550                                 [[int arr[] = { 0, 1 };
 551                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
 552                 [AC_MSG_RESULT([yes]);
 553                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
 554                 [
 555                         AC_MSG_RESULT([no]);
 556                         AC_MSG_CHECKING([for BSD-style qsort_r])
 557                         AC_COMPILE_IFELSE(
 558                                 [AC_LANG_PROGRAM(
 559                                         [[#include <stdlib.h>
 560                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
 561                                         [[int arr[] = { 0, 1 };
 562                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
 563                         [AC_MSG_RESULT([yes]);
 564                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
 565                         [AC_MSG_RESULT([no]);
 566                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
 567                 ])
 568                 CFLAGS="$save_CFLAGS"
 569         ]
 570 )
 571
 572 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
 573 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime)
 574
 575 AC_CHECK_FUNC([syslog], [
 576         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
 577         syslog=true
 578 ])
 579 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
 580
 581 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h linux/fib_rules.h)
 582 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
 583 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
 584 [
 585         #include <sys/types.h>
 586         #include <netinet/in.h>
 587 ])
 588
 589 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 590 [
 591         #include <sys/types.h>
 592         #include <sys/socket.h>
 593 ])
 594
 595 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 596 [
 597         #include <sys/types.h>
 598         #ifdef HAVE_NET_PFKEYV2_H
 599         #include <net/pfkeyv2.h>
 600         #else
 601         #include <stdint.h>
 602         #include <linux/pfkeyv2.h>
 603         #endif
 604 ])
 605
 606 AC_MSG_CHECKING([for in6addr_any])
 607 AC_COMPILE_IFELSE(
 608         [AC_LANG_PROGRAM(
 609                 [[#include <sys/types.h>
 610                   #include <sys/socket.h>
 611                   #include <netinet/in.h>]],
 612                 [[struct in6_addr in6 __attribute__((unused));
 613                   in6 = in6addr_any;]])],
 614         [AC_MSG_RESULT([yes]);
 615          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
 616         [AC_MSG_RESULT([no])]
 617 )
 618
 619 AC_MSG_CHECKING([for in6_pktinfo])
 620 AC_COMPILE_IFELSE(
 621         [AC_LANG_PROGRAM(
 622                 [[#define _GNU_SOURCE
 623                   #include <sys/types.h>
 624                   #include <sys/socket.h>
 625                   #include <netinet/in.h>]],
 626                 [[struct in6_pktinfo pi;
 627                   if (pi.ipi6_ifindex)
 628                   {
 629                     return 0;
 630                   }]])],
 631         [AC_MSG_RESULT([yes]);
 632          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
 633         [AC_MSG_RESULT([no])]
 634 )
 635
 636 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 637 AC_COMPILE_IFELSE(
 638         [AC_LANG_PROGRAM(
 639                 [[#include <sys/types.h>
 640                   #ifdef HAVE_NETIPSEC_IPSEC_H
 641                   #include <netipsec/ipsec.h>
 642                   #elif defined(HAVE_NETINET6_IPSEC_H)
 643                   #include <netinet6/ipsec.h>
 644                   #else
 645                   #include <stdint.h>
 646                   #include <linux/ipsec.h>
 647                   #endif]],
 648                 [[int mode = IPSEC_MODE_BEET;
 649                   return mode;]])],
 650         [AC_MSG_RESULT([yes]);
 651          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
 652         [AC_MSG_RESULT([no])]
 653 )
 654
 655 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 656 AC_COMPILE_IFELSE(
 657         [AC_LANG_PROGRAM(
 658                 [[#include <sys/types.h>
 659                   #ifdef HAVE_NETIPSEC_IPSEC_H
 660                   #include <netipsec/ipsec.h>
 661                   #elif defined(HAVE_NETINET6_IPSEC_H)
 662                   #include <netinet6/ipsec.h>
 663                   #else
 664                   #include <stdint.h>
 665                   #include <linux/ipsec.h>
 666                   #endif]],
 667                 [[int dir = IPSEC_DIR_FWD;
 668                   return dir;]])],
 669         [AC_MSG_RESULT([yes]);
 670          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
 671         [AC_MSG_RESULT([no])]
 672 )
 673
 674 AC_MSG_CHECKING([for RTA_TABLE])
 675 AC_COMPILE_IFELSE(
 676         [AC_LANG_PROGRAM(
 677                 [[#include <sys/socket.h>
 678                   #include <linux/netlink.h>
 679                   #include <linux/rtnetlink.h>]],
 680                 [[int rta_type = RTA_TABLE;
 681                   return rta_type;]])],
 682         [AC_MSG_RESULT([yes]);
 683          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
 684         [AC_MSG_RESULT([no])]
 685 )
 686
 687 AC_MSG_CHECKING([for GCC __sync operations])
 688 AC_RUN_IFELSE([AC_LANG_SOURCE(
 689         [[
 690                         int main() {
 691                         int ref = 1;
 692                         __sync_fetch_and_add (&ref, 1);
 693                         __sync_sub_and_fetch (&ref, 1);
 694                         __sync_val_compare_and_swap(&ref, 1, 0);
 695                         return ref;
 696                 }
 697         ]])],
 698         [AC_MSG_RESULT([yes]);
 699          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
 700                    [have GCC __sync_* operations])],
 701         [AC_MSG_RESULT([no])],
 702         [AC_MSG_RESULT([no])]
 703 )
 704
 705 case "$printf_hooks" in
 706 auto|builtin|glibc|vstr)
 707         ;;
 708 *)
 709         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
 710         printf_hooks=auto
 711         ;;
 712 esac
 713
 714 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
 715         # check for the new register_printf_specifier function with len argument,
 716         # or the deprecated register_printf_function without
 717         AC_CHECK_FUNC(
 718                 [register_printf_specifier],
 719                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
 720                 [AC_CHECK_FUNC(
 721                         [register_printf_function],
 722                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
 723                         [
 724                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
 725                                 if test x$printf_hooks = xglibc; then
 726                                         AC_MSG_ERROR([please select a different printf hook implementation])
 727                                 else
 728                                         # fallback to builtin printf hook implementation
 729                                         printf_hooks=builtin
 730                                 fi
 731                         ]
 732                 )]
 733         )
 734 fi
 735
 736 AC_MSG_CHECKING([for Windows target])
 737 AC_COMPILE_IFELSE(
 738         [AC_LANG_PROGRAM(
 739                 [[#include <windows.h>]],
 740                 [[#ifndef WIN32
 741                   # error WIN32 undefined
 742                   #endif
 743                 ]])],
 744         [
 745                 AC_MSG_RESULT([yes])
 746                 windows=true
 747                 openssl_lib=eay32
 748                 AC_SUBST(PTHREADLIB, "")
 749                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
 750                 case "$CFLAGS" in
 751                         *ms-bitfields*) ;;
 752                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
 753                 esac
 754         ],
 755         [
 756                 AC_MSG_RESULT([no])
 757                 openssl_lib=crypto
 758         ]
 759 )
 760 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
 761 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
 762
 763 AC_MSG_CHECKING([for working __attribute__((packed))])
 764 AC_COMPILE_IFELSE(
 765         [AC_LANG_PROGRAM([], [[
 766                 struct test { char a; short b; } __attribute__((packed));
 767                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
 768                         __attribute__((unused));
 769                 return 0;
 770         ]])],
 771         [AC_MSG_RESULT([yes])],
 772         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
 773 )
 774
 775 AC_MSG_CHECKING([clang])
 776 AC_COMPILE_IFELSE(
 777         [AC_LANG_PROGRAM(
 778                 [], [[
 779                  #ifndef __clang__
 780                  # error not using LLVM clang
 781                  #endif
 782                 ]])],
 783         [
 784                 AC_MSG_RESULT([yes])
 785         ],
 786         [
 787                 AC_MSG_RESULT([no])
 788                 # GCC, but not MinGW requires -rdynamic for plugins
 789                 if test x$windows != xtrue; then
 790                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
 791                 fi
 792         ]
 793 )
 794
 795 if test x$printf_hooks = xvstr; then
 796         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
 797         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
 798 fi
 799
 800 if test x$printf_hooks = xbuiltin; then
 801         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
 802 fi
 803
 804 if test x$gmp = xtrue; then
 805         saved_LIBS=$LIBS
 806         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
 807         AC_MSG_CHECKING([mpz_powm_sec])
 808         if test x$mpz_powm_sec = xyes; then
 809                 AC_COMPILE_IFELSE(
 810                         [AC_LANG_PROGRAM(
 811                                 [[#include "gmp.h"]],
 812                                 [[void *x = mpz_powm_sec;]])],
 813                         [AC_MSG_RESULT([yes]);
 814                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
 815                         [AC_MSG_RESULT([no])]
 816                 )
 817         else
 818                 AC_MSG_RESULT([disabled])
 819         fi
 820         LIBS=$saved_LIBS
 821         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 822         AC_COMPILE_IFELSE(
 823                 [AC_LANG_PROGRAM(
 824                         [[#include "gmp.h"]],
 825                         [[
 826                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 827                                         #error bad gmp
 828                                 #endif]])],
 829                 [AC_MSG_RESULT([yes])],
 830                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 831         )
 832 fi
 833
 834 if test x$ldap = xtrue; then
 835         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
 836         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
 837         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 838 fi
 839
 840 if test x$curl = xtrue; then
 841         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
 842         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 843 fi
 844
 845 if test x$unbound = xtrue; then
 846         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
 847         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
 848         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
 849         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
 850 fi
 851
 852 if test x$soup = xtrue; then
 853         PKG_CHECK_MODULES(soup, [libsoup-2.4])
 854         AC_SUBST(soup_CFLAGS)
 855         AC_SUBST(soup_LIBS)
 856 fi
 857
 858 if test x$xml = xtrue; then
 859         PKG_CHECK_MODULES(xml, [libxml-2.0])
 860         AC_SUBST(xml_CFLAGS)
 861         AC_SUBST(xml_LIBS)
 862 fi
 863
 864 if test x$tss = xtrousers; then
 865         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
 866         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
 867         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
 868 fi
 869
 870 if test x$imv_swid = xtrue; then
 871         AC_CHECK_LIB([json],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([JSON library libjson not found])],[])
 872         AC_CHECK_HEADER([json/json.h],,[AC_MSG_ERROR([JSON header json/json.h not found!])])
 873 fi
 874
 875 if test x$dumm = xtrue; then
 876         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
 877         AC_SUBST(gtk_CFLAGS)
 878         AC_SUBST(gtk_LIBS)
 879         AC_CHECK_PROGS(RUBY, ruby)
 880         AC_MSG_CHECKING([for Ruby header files])
 881         if test -n "$RUBY"; then
 882                 RUBYINCLUDE=
 883                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
 884                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 885                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
 886                         if test -n "$RUBYARCH"; then
 887                                 AC_MSG_RESULT([$RUBYDIR])
 888                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
 889                         fi
 890                 else
 891                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
 892                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 893                                 AC_MSG_RESULT([$RUBYDIR])
 894                                 RUBYINCLUDE="-I$RUBYDIR"
 895                         fi
 896                 fi
 897                 if test -z "$RUBYINCLUDE"; then
 898                         AC_MSG_ERROR([ruby.h not found])
 899                 fi
 900                 AC_SUBST(RUBYINCLUDE)
 901         else
 902                 AC_MSG_ERROR([don't know how to run ruby])
 903         fi
 904         AC_MSG_CHECKING([for libruby])
 905         saved_LIBS=$LIBS
 906         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
 907         AC_TRY_LINK_FUNC(ruby_init,
 908                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
 909                 [AC_MSG_ERROR([not found])])
 910         AC_SUBST(RUBYLIB)
 911         AC_CHECK_FUNCS(rb_errinfo)
 912         LIBS=$saved_LIBS
 913 fi
 914
 915 if test x$fast = xtrue; then
 916         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
 917         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
 918         AC_MSG_CHECKING([ClearSilver requires zlib])
 919         saved_CFLAGS=$CFLAGS
 920         saved_LIBS=$LIBS
 921         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
 922         CFLAGS="-I/usr/include/ClearSilver"
 923         AC_LINK_IFELSE(
 924                 [AC_LANG_PROGRAM(
 925                         [[#include <ClearSilver.h>]],
 926                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
 927                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
 928                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
 929         )
 930         AC_SUBST(clearsilver_LIBS)
 931         LIBS=$saved_LIBS
 932         CFLAGS=$saved_CFLAGS
 933 # autoconf does not like CamelCase!? How to fix this?
 934 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
 935
 936         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
 937         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
 938 fi
 939
 940 if test x$mysql = xtrue; then
 941         if test "x$windows" = xtrue; then
 942                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
 943                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
 944                 AC_SUBST(MYSQLLIB, -lmysql)
 945         else
 946                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 947                 if test x$MYSQLCONFIG = x; then
 948                         AC_MSG_ERROR([mysql_config not found!])
 949                 fi
 950                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
 951                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
 952         fi
 953 fi
 954
 955 if test x$sqlite = xtrue; then
 956         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
 957         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
 958         AC_MSG_CHECKING([sqlite3_prepare_v2])
 959         AC_COMPILE_IFELSE(
 960                 [AC_LANG_PROGRAM(
 961                         [[#include <sqlite3.h>]],
 962                         [[void *test = sqlite3_prepare_v2;]])],
 963                 [AC_MSG_RESULT([yes]);
 964                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
 965                 [AC_MSG_RESULT([no])]
 966         )
 967         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
 968         AC_COMPILE_IFELSE(
 969                 [AC_LANG_PROGRAM(
 970                         [[#include <sqlite3.h>]],
 971                         [[
 972                                 #if SQLITE_VERSION_NUMBER < 3003001
 973                                         #error bad sqlite
 974                                 #endif]])],
 975                 [AC_MSG_RESULT([yes])],
 976                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
 977         )
 978 fi
 979
 980 if test x$openssl = xtrue; then
 981         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
 982         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
 983 fi
 984
 985 if test x$gcrypt = xtrue; then
 986         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
 987         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
 988         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
 989         AC_COMPILE_IFELSE(
 990                 [AC_LANG_PROGRAM(
 991                         [[#include <gcrypt.h>]],
 992                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
 993                 [AC_MSG_RESULT([yes]);
 994                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
 995                 [AC_MSG_RESULT([no])]
 996         )
 997 fi
 998
 999 if test x$uci = xtrue; then
1000         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1001         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1002 fi
1003
1004 if test x$android_dns = xtrue; then
1005         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1006         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1007         # we have to force the use of libdl here because the autodetection
1008         # above does not work correctly when cross-compiling for android.
1009         DLLIB="-ldl"
1010         AC_SUBST(DLLIB)
1011 fi
1012
1013 if test x$maemo = xtrue; then
1014         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1015         AC_SUBST(maemo_CFLAGS)
1016         AC_SUBST(maemo_LIBS)
1017         dbusservicedir="/usr/share/dbus-1/system-services"
1018         AC_SUBST(dbusservicedir)
1019 fi
1020
1021 if test x$eap_sim_pcsc = xtrue; then
1022         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1023         AC_SUBST(pcsclite_CFLAGS)
1024         AC_SUBST(pcsclite_LIBS)
1025 fi
1026
1027 if test x$nm = xtrue; then
1028         PKG_CHECK_EXISTS([libnm-glib],
1029                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1030                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1031         )
1032         AC_SUBST(nm_CFLAGS)
1033         AC_SUBST(nm_LIBS)
1034 fi
1035
1036 if test x$xauth_pam = xtrue; then
1037         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1038         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1039 fi
1040
1041 if test x$capabilities = xnative; then
1042         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1043         # Linux requires the following for capset(), Android does not have it,
1044         # but defines capset() in unistd.h instead.
1045         AC_CHECK_HEADERS([sys/capability.h])
1046         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1047         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1048 fi
1049
1050 if test x$capabilities = xlibcap; then
1051         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1052         AC_CHECK_HEADER([sys/capability.h],
1053                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1054                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1055         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1056 fi
1057
1058 if test x$integrity_test = xtrue; then
1059         AC_MSG_CHECKING([for dladdr()])
1060         AC_COMPILE_IFELSE(
1061                 [AC_LANG_PROGRAM(
1062                         [[#define _GNU_SOURCE
1063                           #include <dlfcn.h>]],
1064                         [[Dl_info info; dladdr(main, &info);]])],
1065                 [AC_MSG_RESULT([yes])],
1066                 [AC_MSG_RESULT([no]);
1067                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1068         )
1069         AC_MSG_CHECKING([for dl_iterate_phdr()])
1070         AC_COMPILE_IFELSE(
1071                 [AC_LANG_PROGRAM(
1072                         [[#define _GNU_SOURCE
1073                           #include <link.h>]],
1074                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1075                 [AC_MSG_RESULT([yes])],
1076                 [AC_MSG_RESULT([no]);
1077                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1078         )
1079 fi
1080
1081 if test x$bfd_backtraces = xtrue; then
1082         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1083         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1084                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1085         BFDLIB="-lbfd"
1086         AC_SUBST(BFDLIB)
1087 fi
1088
1089 if test x$unwind_backtraces = xtrue; then
1090         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1091         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1092                 [AC_MSG_ERROR([libunwind.h header not found!])])
1093         UNWINDLIB="-lunwind"
1094         AC_SUBST(UNWINDLIB)
1095 fi
1096
1097 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1098 if test x$dev_headers = xyes; then
1099         dev_headers="$includedir/strongswan"
1100 fi
1101 AC_SUBST(dev_headers)
1102
1103 CFLAGS="$CFLAGS -include `pwd`/config.h"
1104
1105 if test x$tkm = xtrue; then
1106         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1107         if test x$GPRBUILD = x; then
1108                 AC_MSG_ERROR([gprbuild not found])
1109         fi
1110 fi
1111
1112 if test x$coverage = xtrue; then
1113         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1114         if test x$LCOV = x; then
1115                 AC_MSG_ERROR([lcov not found])
1116         fi
1117         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1118         if test x$GENHTML = x; then
1119                 AC_MSG_ERROR([genhtml not found])
1120         fi
1121
1122         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1123         COVERAGE_LDFLAGS="-fprofile-arcs"
1124         AC_SUBST(COVERAGE_CFLAGS)
1125         AC_SUBST(COVERAGE_LDFLAGS)
1126
1127         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1128         CFLAGS="${CFLAGS} -g -O0"
1129 fi
1130
1131 # ===============================================
1132 #  collect plugin list for strongSwan components
1133 # ===============================================
1134
1135 m4_include(m4/macros/add-plugin.m4)
1136
1137 # plugin lists for all components
1138 charon_plugins=
1139 starter_plugins=
1140 pool_plugins=
1141 attest_plugins=
1142 scepclient_plugins=
1143 pki_plugins=
1144 scripts_plugins=
1145 manager_plugins=
1146 medsrv_plugins=
1147 nm_plugins=
1148 cmd_plugins=
1149 aikgen_plugins=
1150
1151 # location specific lists for checksumming,
1152 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1153 c_plugins=
1154 h_plugins=
1155 s_plugins=
1156 t_plugins=
1157
1158 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1159 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm cmd])
1160 ADD_PLUGIN([soup],                 [s charon scripts nm cmd])
1161 ADD_PLUGIN([unbound],              [s charon scripts])
1162 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1163 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1164 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1165 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1166 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1167 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1168 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1169 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1170 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1171 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1172 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1173 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1174 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1175 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1176 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1177 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1178 ADD_PLUGIN([revocation],           [s charon nm cmd])
1179 ADD_PLUGIN([constraints],          [s charon nm cmd])
1180 ADD_PLUGIN([acert],                [s charon])
1181 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1182 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1183 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1184 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1185 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1186 ADD_PLUGIN([pgp],                  [s charon])
1187 ADD_PLUGIN([dnskey],               [s charon pki])
1188 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1189 ADD_PLUGIN([dnscert],              [c charon])
1190 ADD_PLUGIN([ipseckey],             [c charon])
1191 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1192 ADD_PLUGIN([padlock],              [s charon])
1193 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1194 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1195 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1196 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1197 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1198 ADD_PLUGIN([agent],                [s charon nm cmd])
1199 ADD_PLUGIN([keychain],             [s charon cmd])
1200 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1201 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1202 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1203 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1204 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1205 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1206 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1207 ADD_PLUGIN([attr],                 [h charon])
1208 ADD_PLUGIN([attr-sql],             [h charon])
1209 ADD_PLUGIN([load-tester],          [c charon])
1210 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1211 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1212 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1213 ADD_PLUGIN([kernel-klips],         [h charon starter])
1214 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1215 ADD_PLUGIN([resolve],              [h charon cmd])
1216 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1217 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1218 ADD_PLUGIN([farp],                 [c charon])
1219 ADD_PLUGIN([stroke],               [c charon])
1220 ADD_PLUGIN([vici],                 [c charon])
1221 ADD_PLUGIN([smp],                  [c charon])
1222 ADD_PLUGIN([sql],                  [c charon])
1223 ADD_PLUGIN([updown],               [c charon])
1224 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1225 ADD_PLUGIN([eap-sim],              [c charon])
1226 ADD_PLUGIN([eap-sim-file],         [c charon])
1227 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1228 ADD_PLUGIN([eap-aka],              [c charon])
1229 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1230 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1231 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1232 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1233 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1234 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1235 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1236 ADD_PLUGIN([eap-dynamic],          [c charon])
1237 ADD_PLUGIN([eap-radius],           [c charon])
1238 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1239 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1240 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1241 ADD_PLUGIN([eap-tnc],              [c charon])
1242 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1243 ADD_PLUGIN([xauth-eap],            [c charon])
1244 ADD_PLUGIN([xauth-pam],            [c charon])
1245 ADD_PLUGIN([xauth-noauth],         [c charon])
1246 ADD_PLUGIN([tnc-ifmap],            [c charon])
1247 ADD_PLUGIN([tnc-pdp],              [c charon])
1248 ADD_PLUGIN([tnc-imc],              [t charon])
1249 ADD_PLUGIN([tnc-imv],              [t charon])
1250 ADD_PLUGIN([tnc-tnccs],            [t charon])
1251 ADD_PLUGIN([tnccs-20],             [t charon])
1252 ADD_PLUGIN([tnccs-11],             [t charon])
1253 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1254 ADD_PLUGIN([medsrv],               [c charon])
1255 ADD_PLUGIN([medcli],               [c charon])
1256 ADD_PLUGIN([dhcp],                 [c charon])
1257 ADD_PLUGIN([osx-attr],             [c charon cmd])
1258 ADD_PLUGIN([android-dns],          [c charon])
1259 ADD_PLUGIN([android-log],          [c charon])
1260 ADD_PLUGIN([ha],                   [c charon])
1261 ADD_PLUGIN([whitelist],            [c charon])
1262 ADD_PLUGIN([lookip],               [c charon])
1263 ADD_PLUGIN([error-notify],         [c charon])
1264 ADD_PLUGIN([certexpire],           [c charon])
1265 ADD_PLUGIN([systime-fix],          [c charon])
1266 ADD_PLUGIN([led],                  [c charon])
1267 ADD_PLUGIN([duplicheck],           [c charon])
1268 ADD_PLUGIN([coupling],             [c charon])
1269 ADD_PLUGIN([radattr],              [c charon])
1270 ADD_PLUGIN([maemo],                [c charon])
1271 ADD_PLUGIN([uci],                  [c charon])
1272 ADD_PLUGIN([addrblock],            [c charon])
1273 ADD_PLUGIN([unity],                [c charon])
1274 ADD_PLUGIN([unit-tester],          [c charon])
1275
1276 AC_SUBST(charon_plugins)
1277 AC_SUBST(starter_plugins)
1278 AC_SUBST(pool_plugins)
1279 AC_SUBST(attest_plugins)
1280 AC_SUBST(scepclient_plugins)
1281 AC_SUBST(pki_plugins)
1282 AC_SUBST(scripts_plugins)
1283 AC_SUBST(manager_plugins)
1284 AC_SUBST(medsrv_plugins)
1285 AC_SUBST(nm_plugins)
1286 AC_SUBST(cmd_plugins)
1287 AC_SUBST(aikgen_plugins)
1288
1289 AC_SUBST(c_plugins)
1290 AC_SUBST(h_plugins)
1291 AC_SUBST(s_plugins)
1292 AC_SUBST(t_plugins)
1293
1294 # ======================
1295 #  set Makefile.am vars
1296 # ======================
1297
1298 #  libstrongswan plugins
1299 # -----------------------
1300 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1301 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1302 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1303 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1304 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1305 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1306 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1307 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1308 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1309 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1310 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1311 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1312 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1313 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1314 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1315 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1316 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1317 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1318 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1319 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1320 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1321 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1322 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1323 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1324 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1325 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1326 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1327 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1328 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1329 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1330 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1331 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1332 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1333 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1334 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1335 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1336 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1337 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1338 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1339 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1340 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1341 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1342 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1343 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1344 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1345 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1346 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1347
1348 #  charon plugins
1349 # ----------------
1350 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1351 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1352 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1353 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1354 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1355 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1356 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1357 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1358 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1359 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1360 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1361 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1362 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1363 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1364 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1365 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1366 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1367 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1368 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1369 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1370 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1371 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1372 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1373 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1374 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1375 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1376 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1377 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1378 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1379 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1380 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1381 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1382 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1383 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1384 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1385 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1386 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1387 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1388 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1389 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1390 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1391 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1392 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1393 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1394 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1395 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1396 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1397 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1398 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1399 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1400 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1401 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1402 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1403 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1404 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1405 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1406 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1407 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1408 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1409 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1410 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1411 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1412 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1413 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1414 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1415 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1416 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1417 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1418 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1419 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1420 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1421 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1422 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1423
1424 #  hydra plugins
1425 # ---------------
1426 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1427 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1428 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1429 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1430 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1431 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1432 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1433
1434 #  other options
1435 # ---------------
1436 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1437 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1438 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1439 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1440 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1441 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1442 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1443 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1444 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1445 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1446 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1447 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1448 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1449 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1450 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1451 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1452 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1453 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1454 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue)
1455 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue)
1456 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue)
1457 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1458 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1459 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1460 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1461 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1462 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1463 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1464 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1465 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1466 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1467 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1468 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1469 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1470 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1471 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1472 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1473 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1474 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1475 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1476 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1477 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1478 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1479 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1480 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1481
1482 # ========================
1483 #  set global definitions
1484 # ========================
1485
1486 if test x$mediation = xtrue; then
1487         AC_DEFINE([ME], [], [mediation extension support])
1488 fi
1489 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1490         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1491 fi
1492 if test x$monolithic = xtrue; then
1493         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1494 fi
1495 if test x$ikev1 = xtrue; then
1496         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1497 fi
1498 if test x$ikev2 = xtrue; then
1499         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1500 fi
1501
1502 # ====================================================
1503 #  options for enabled modules (see conf/Makefile.am)
1504 # ====================================================
1505
1506 strongswan_options=
1507
1508 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1509 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1510 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1511 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1512 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1513 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1514 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1515 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1516 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1517 AM_COND_IF([USE_TOOLS], [strongswan_options=${strongswan_options}" tools"])
1518 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1519
1520 AC_SUBST(strongswan_options)
1521
1522 # =================
1523 #  build Makefiles
1524 # =================
1525
1526 AC_CONFIG_FILES([
1527         Makefile
1528         conf/Makefile
1529         man/Makefile
1530         init/Makefile
1531         init/systemd/Makefile
1532         src/Makefile
1533         src/include/Makefile
1534         src/libstrongswan/Makefile
1535         src/libstrongswan/plugins/aes/Makefile
1536         src/libstrongswan/plugins/cmac/Makefile
1537         src/libstrongswan/plugins/des/Makefile
1538         src/libstrongswan/plugins/blowfish/Makefile
1539         src/libstrongswan/plugins/rc2/Makefile
1540         src/libstrongswan/plugins/md4/Makefile
1541         src/libstrongswan/plugins/md5/Makefile
1542         src/libstrongswan/plugins/sha1/Makefile
1543         src/libstrongswan/plugins/sha2/Makefile
1544         src/libstrongswan/plugins/fips_prf/Makefile
1545         src/libstrongswan/plugins/gmp/Makefile
1546         src/libstrongswan/plugins/rdrand/Makefile
1547         src/libstrongswan/plugins/random/Makefile
1548         src/libstrongswan/plugins/nonce/Makefile
1549         src/libstrongswan/plugins/hmac/Makefile
1550         src/libstrongswan/plugins/xcbc/Makefile
1551         src/libstrongswan/plugins/x509/Makefile
1552         src/libstrongswan/plugins/revocation/Makefile
1553         src/libstrongswan/plugins/constraints/Makefile
1554         src/libstrongswan/plugins/acert/Makefile
1555         src/libstrongswan/plugins/pubkey/Makefile
1556         src/libstrongswan/plugins/pkcs1/Makefile
1557         src/libstrongswan/plugins/pkcs7/Makefile
1558         src/libstrongswan/plugins/pkcs8/Makefile
1559         src/libstrongswan/plugins/pkcs12/Makefile
1560         src/libstrongswan/plugins/pgp/Makefile
1561         src/libstrongswan/plugins/dnskey/Makefile
1562         src/libstrongswan/plugins/sshkey/Makefile
1563         src/libstrongswan/plugins/pem/Makefile
1564         src/libstrongswan/plugins/curl/Makefile
1565         src/libstrongswan/plugins/unbound/Makefile
1566         src/libstrongswan/plugins/soup/Makefile
1567         src/libstrongswan/plugins/ldap/Makefile
1568         src/libstrongswan/plugins/mysql/Makefile
1569         src/libstrongswan/plugins/sqlite/Makefile
1570         src/libstrongswan/plugins/padlock/Makefile
1571         src/libstrongswan/plugins/openssl/Makefile
1572         src/libstrongswan/plugins/gcrypt/Makefile
1573         src/libstrongswan/plugins/agent/Makefile
1574         src/libstrongswan/plugins/keychain/Makefile
1575         src/libstrongswan/plugins/pkcs11/Makefile
1576         src/libstrongswan/plugins/ctr/Makefile
1577         src/libstrongswan/plugins/ccm/Makefile
1578         src/libstrongswan/plugins/gcm/Makefile
1579         src/libstrongswan/plugins/af_alg/Makefile
1580         src/libstrongswan/plugins/ntru/Makefile
1581         src/libstrongswan/plugins/test_vectors/Makefile
1582         src/libstrongswan/tests/Makefile
1583         src/libhydra/Makefile
1584         src/libhydra/plugins/attr/Makefile
1585         src/libhydra/plugins/attr_sql/Makefile
1586         src/libhydra/plugins/kernel_klips/Makefile
1587         src/libhydra/plugins/kernel_netlink/Makefile
1588         src/libhydra/plugins/kernel_pfkey/Makefile
1589         src/libhydra/plugins/kernel_pfroute/Makefile
1590         src/libhydra/plugins/resolve/Makefile
1591         src/libipsec/Makefile
1592         src/libsimaka/Makefile
1593         src/libtls/Makefile
1594         src/libtls/tests/Makefile
1595         src/libradius/Makefile
1596         src/libtncif/Makefile
1597         src/libtnccs/Makefile
1598         src/libtnccs/plugins/tnc_tnccs/Makefile
1599         src/libtnccs/plugins/tnc_imc/Makefile
1600         src/libtnccs/plugins/tnc_imv/Makefile
1601         src/libtnccs/plugins/tnccs_11/Makefile
1602         src/libtnccs/plugins/tnccs_20/Makefile
1603         src/libtnccs/plugins/tnccs_dynamic/Makefile
1604         src/libpttls/Makefile
1605         src/libpts/Makefile
1606         src/libpts/plugins/imc_attestation/Makefile
1607         src/libpts/plugins/imv_attestation/Makefile
1608         src/libpts/plugins/imc_swid/Makefile
1609         src/libpts/plugins/imv_swid/Makefile
1610         src/libimcv/Makefile
1611         src/libimcv/plugins/imc_test/Makefile
1612         src/libimcv/plugins/imv_test/Makefile
1613         src/libimcv/plugins/imc_scanner/Makefile
1614         src/libimcv/plugins/imv_scanner/Makefile
1615         src/libimcv/plugins/imc_os/Makefile
1616         src/libimcv/plugins/imv_os/Makefile
1617         src/charon/Makefile
1618         src/charon-nm/Makefile
1619         src/charon-tkm/Makefile
1620         src/charon-cmd/Makefile
1621         src/charon-svc/Makefile
1622         src/libcharon/Makefile
1623         src/libcharon/plugins/eap_aka/Makefile
1624         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1625         src/libcharon/plugins/eap_dynamic/Makefile
1626         src/libcharon/plugins/eap_identity/Makefile
1627         src/libcharon/plugins/eap_md5/Makefile
1628         src/libcharon/plugins/eap_gtc/Makefile
1629         src/libcharon/plugins/eap_sim/Makefile
1630         src/libcharon/plugins/eap_sim_file/Makefile
1631         src/libcharon/plugins/eap_sim_pcsc/Makefile
1632         src/libcharon/plugins/eap_simaka_sql/Makefile
1633         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1634         src/libcharon/plugins/eap_simaka_reauth/Makefile
1635         src/libcharon/plugins/eap_mschapv2/Makefile
1636         src/libcharon/plugins/eap_tls/Makefile
1637         src/libcharon/plugins/eap_ttls/Makefile
1638         src/libcharon/plugins/eap_peap/Makefile
1639         src/libcharon/plugins/eap_tnc/Makefile
1640         src/libcharon/plugins/eap_radius/Makefile
1641         src/libcharon/plugins/xauth_generic/Makefile
1642         src/libcharon/plugins/xauth_eap/Makefile
1643         src/libcharon/plugins/xauth_pam/Makefile
1644         src/libcharon/plugins/xauth_noauth/Makefile
1645         src/libcharon/plugins/tnc_ifmap/Makefile
1646         src/libcharon/plugins/tnc_pdp/Makefile
1647         src/libcharon/plugins/socket_default/Makefile
1648         src/libcharon/plugins/socket_dynamic/Makefile
1649         src/libcharon/plugins/farp/Makefile
1650         src/libcharon/plugins/smp/Makefile
1651         src/libcharon/plugins/sql/Makefile
1652         src/libcharon/plugins/dnscert/Makefile
1653         src/libcharon/plugins/ipseckey/Makefile
1654         src/libcharon/plugins/medsrv/Makefile
1655         src/libcharon/plugins/medcli/Makefile
1656         src/libcharon/plugins/addrblock/Makefile
1657         src/libcharon/plugins/unity/Makefile
1658         src/libcharon/plugins/uci/Makefile
1659         src/libcharon/plugins/ha/Makefile
1660         src/libcharon/plugins/kernel_libipsec/Makefile
1661         src/libcharon/plugins/whitelist/Makefile
1662         src/libcharon/plugins/lookip/Makefile
1663         src/libcharon/plugins/error_notify/Makefile
1664         src/libcharon/plugins/certexpire/Makefile
1665         src/libcharon/plugins/systime_fix/Makefile
1666         src/libcharon/plugins/led/Makefile
1667         src/libcharon/plugins/duplicheck/Makefile
1668         src/libcharon/plugins/coupling/Makefile
1669         src/libcharon/plugins/radattr/Makefile
1670         src/libcharon/plugins/osx_attr/Makefile
1671         src/libcharon/plugins/android_dns/Makefile
1672         src/libcharon/plugins/android_log/Makefile
1673         src/libcharon/plugins/maemo/Makefile
1674         src/libcharon/plugins/stroke/Makefile
1675         src/libcharon/plugins/vici/Makefile
1676         src/libcharon/plugins/updown/Makefile
1677         src/libcharon/plugins/dhcp/Makefile
1678         src/libcharon/plugins/unit_tester/Makefile
1679         src/libcharon/plugins/load_tester/Makefile
1680         src/stroke/Makefile
1681         src/ipsec/Makefile
1682         src/starter/Makefile
1683         src/_updown/Makefile
1684         src/_updown_espmark/Makefile
1685         src/_copyright/Makefile
1686         src/scepclient/Makefile
1687         src/aikgen/Makefile
1688         src/pki/Makefile
1689         src/pki/man/Makefile
1690         src/pool/Makefile
1691         src/dumm/Makefile
1692         src/dumm/ext/extconf.rb
1693         src/libfast/Makefile
1694         src/manager/Makefile
1695         src/medsrv/Makefile
1696         src/checksum/Makefile
1697         src/conftest/Makefile
1698         src/pt-tls-client/Makefile
1699         src/swanctl/Makefile
1700         scripts/Makefile
1701         testing/Makefile
1702 ])
1703
1704 # =================
1705 #  build man pages
1706 # =================
1707
1708 AC_CONFIG_FILES([
1709         conf/strongswan.conf.5.head
1710         conf/strongswan.conf.5.tail
1711         man/ipsec.conf.5
1712         man/ipsec.secrets.5
1713         src/charon-cmd/charon-cmd.8
1714         src/pki/man/pki.1
1715         src/pki/man/pki---gen.1
1716         src/pki/man/pki---issue.1
1717         src/pki/man/pki---keyid.1
1718         src/pki/man/pki---pkcs7.1
1719         src/pki/man/pki---print.1
1720         src/pki/man/pki---pub.1
1721         src/pki/man/pki---req.1
1722         src/pki/man/pki---self.1
1723         src/pki/man/pki---signcrl.1
1724         src/pki/man/pki---acert.1
1725         src/pki/man/pki---verify.1
1726         src/swanctl/swanctl.8
1727         src/swanctl/swanctl.conf.5.head
1728         src/swanctl/swanctl.conf.5.tail
1729 ])
1730
1731 AC_OUTPUT
1732
1733 # ========================
1734 #  report enabled plugins
1735 # ========================
1736
1737 AC_MSG_RESULT([])
1738 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1739 AC_MSG_RESULT([-----------------------------------------------------])
1740
1741 AC_MSG_RESULT([libstrongswan:$s_plugins])
1742 AC_MSG_RESULT([libcharon:    $c_plugins])
1743 AC_MSG_RESULT([libhydra:     $h_plugins])
1744 AC_MSG_RESULT([libtnccs:     $t_plugins])
1745 AC_MSG_RESULT([])