configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Must change all of the below together
   5 # For a release, set revision for that tagged release as well and uncomment
   6 AC_INIT([freeswitch], [1.10.7-dev], bugs@freeswitch.org)
   7 AC_SUBST(SWITCH_VERSION_MAJOR, [1])
   8 AC_SUBST(SWITCH_VERSION_MINOR, [10])
   9 AC_SUBST(SWITCH_VERSION_MICRO, [7-dev])
  10 AC_SUBST(SWITCH_VERSION_REVISION, [])
  11 AC_SUBST(SWITCH_VERSION_REVISION_HUMAN, [])
  12
  13 AC_CONFIG_FILES([src/include/switch_version.h.in:src/include/switch_version.h.template])
  14
  15 AC_CONFIG_AUX_DIR(build/config)
  16 AM_INIT_AUTOMAKE
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([src/switch.c])
  19 AC_CONFIG_HEADER([src/include/switch_private.h])
  20 AC_CONFIG_HEADER([libs/esl/src/include/esl_config_auto.h])
  21 AC_CONFIG_HEADER([libs/xmlrpc-c/xmlrpc_amconfig.h])
  22
  23 AC_CANONICAL_HOST
  24
  25 # Absolute source/build directory
  26 switch_srcdir=`(cd $srcdir && pwd)`
  27 switch_builddir=`pwd`
  28 AC_SUBST(switch_srcdir)
  29 AC_SUBST(switch_builddir)
  30
  31 #
  32 # --enable-64 has been moved up higher prior to AC_PROG_CC so that we can tuck in the -m64 flag
  33 # so devs on with Solaris wanting to build 64bit can not bother with adding any additional
  34 # flags on the ./configure line.  User friendly.
  35 #
  36
  37 #  Enable 64 bit build
  38 AC_ARG_ENABLE(64,
  39 [AC_HELP_STRING([--enable-64],[build with 64 bit support])],[enable_64="$enable_64"],[enable_64="no"])
  40
  41 if test "${enable_64}" = "yes"; then
  42    case "$host" in
  43         *-solaris2*)
  44             # All three have to have -m64 for AC_PROG_CC to pick the right libtool
  45             CFLAGS="$CFLAGS -m64"
  46             LDFLAGS="$LDFLAGS -m64"
  47             CXXFLAGS="$CXXFLAGS -m64"
  48         ;;
  49         *)
  50         ;;
  51    esac
  52 fi
  53
  54 # use mtmalloc on Solaris SPARC if available
  55 AS_CASE([$host], [sparc-*-solaris2*], [AC_CHECK_LIB(mtmalloc, malloc)])
  56
  57 # Whether to follow FHS
  58 AC_ARG_ENABLE([fhs],[AS_HELP_STRING([--disable-fhs],
  59         [Do Not follow the FHS when placing files and directories (default only when not specifying prefix])],[enable_fhs="$enableval"],[enable_fhs="yes"])
  60
  61 AC_PREFIX_DEFAULT(/usr/local/freeswitch)
  62 # AC_PREFIX_DEFAULT does not get expanded until too late so we need to do this to use prefix in this script
  63
  64 if test "x$prefix" = "xNONE" ; then
  65     enable_fhs=no
  66     prefix='/usr/local/freeswitch'
  67 fi
  68
  69 if test "x${exec_prefix}" = "xNONE" ; then
  70     exec_prefix="$prefix"
  71 fi
  72
  73 default_scriptdir="$prefix/scripts"
  74 default_grammardir="$prefix/grammar"
  75 default_soundsdir="$prefix/sounds"
  76 default_htdocsdir="$prefix/htdocs"
  77 default_modulesdir="$prefix/mod"
  78 default_dbdir="$prefix/db"
  79 default_storagedir="$prefix/storage"
  80 default_cachedir="$prefix/cache"
  81 default_recordingsdir="$prefix/recordings"
  82 rundir="$prefix/run"
  83 logdir="${prefix}/log"
  84 confdir="$prefix/conf"
  85 default_certsdir="$prefix/certs"
  86 default_fontsdir="$prefix/fonts"
  87 default_imagesdir="$prefix/images"
  88
  89 if test "${enable_fhs}" = "yes"; then
  90     eval full_datadir="${datadir}/freeswitch"
  91     eval datadir=$full_datadir
  92     eval full_localstatedir="${localstatedir}"
  93     eval localstatedir=$full_localstatedir
  94     eval libdir=$libdir
  95     default_cachedir="${localstatedir}/cache/freeswitch"
  96     rundir="${localstatedir}/run/freeswitch"
  97     logdir="${localstatedir}/log/freeswitch"
  98     localstatedir="${localstatedir}/lib/freeswitch"
  99     default_scriptdir="${datadir}/scripts"
 100     default_grammardir="${datadir}/grammar"
 101     default_soundsdir="${datadir}/sounds"
 102     default_htdocsdir="${datadir}/htdocs"
 103     default_fontsdir="${datadir}/fonts"
 104     default_modulesdir="${libdir}/freeswitch/mod"
 105     default_dbdir="${localstatedir}/db"
 106     default_storagedir="${localstatedir}/storage"
 107     default_recordingsdir="${localstatedir}/recordings"
 108     default_imagesdir="${localstatedir}/images"
 109     eval confdir="${sysconfdir}/freeswitch"
 110     eval default_certsdir="${confdir}/tls"
 111 else
 112     if test "$datadir" = "\${datarootdir}" ; then
 113         datadir="${prefix}"
 114     fi
 115     if test "$localstatedir" = "\${prefix}/var" ; then
 116         localstatedir="${prefix}"
 117     fi
 118 fi
 119
 120 if test "$includedir" = "\${prefix}/include" ; then
 121    includedir="${prefix}/include/freeswitch"
 122 fi
 123
 124 default_pkgconfigdir="$libdir/pkgconfig"
 125 default_runtimedir="$rundir"
 126 default_logfiledir="$logdir"
 127
 128 AC_SUBST(libdir)
 129
 130 # Where to install the modules
 131 AC_ARG_WITH([modinstdir],
 132         [AS_HELP_STRING([--with-modinstdir=DIR], [Install modules into this location (default: $prefix/mod)])], [modulesdir="$withval"], [modulesdir="${default_modulesdir}"])
 133 eval modulesdir="${modulesdir}"
 134 AC_SUBST(modulesdir)
 135 AC_DEFINE_UNQUOTED([SWITCH_MOD_DIR],"${modulesdir}",[where to install the modules to])
 136
 137 # Where to put pidfile
 138 AC_ARG_WITH([rundir],
 139         [AS_HELP_STRING([--with-rundir=DIR], [Put pidfile into this location (default: $prefix/run)])], [runtimedir="$withval"], [runtimedir="${default_runtimedir}"])
 140 AC_SUBST(runtimedir)
 141 AC_DEFINE_UNQUOTED([SWITCH_RUN_DIR],"${runtimedir}",[where to put pidfile to])
 142
 143 AC_ARG_WITH([logfiledir],
 144         [AS_HELP_STRING([--with-logfiledir=DIR], [Put logfiles into this location (default: $localstatedir/log)])], [logfiledir="$withval"], [logfiledir="${default_logfiledir}"])
 145 AC_SUBST(logfiledir)
 146 AC_DEFINE_UNQUOTED([SWITCH_LOG_DIR],"${logfiledir}",[where to put log files])
 147
 148 AC_ARG_WITH([dbdir],
 149         [AS_HELP_STRING([--with-dbdir=DIR], [Put database files into this location (default: $prefix/db)])], [dbdir="$withval"], [dbdir="${default_dbdir}"])
 150 AC_SUBST(dbdir)
 151 AC_DEFINE_UNQUOTED([SWITCH_DB_DIR],"${dbdir}",[where to put db files])
 152
 153 AC_ARG_WITH([htdocsdir],
 154         [AS_HELP_STRING([--with-htdocsdir=DIR], [Put html files into this location (default: $prefix/htdocs)])], [htdocsdir="$withval"], [htdocsdir="${default_htdocsdir}"])
 155 AC_SUBST(htdocsdir)
 156 AC_DEFINE_UNQUOTED([SWITCH_HTDOCS_DIR],"${htdocsdir}",[where to put htdocs files])
 157
 158 AC_ARG_WITH([fontsdir],
 159         [AS_HELP_STRING([--with-fontsdir=DIR], [Put font files into this location (default: $prefix/fonts)])], [fontsdir="$withval"], [fontsdir="${default_fontsdir}"])
 160 AC_SUBST(fontsdir)
 161 AC_DEFINE_UNQUOTED([SWITCH_FONTS_DIR],"${fontsdir}",[where to put font files])
 162
 163 AC_ARG_WITH([soundsdir],
 164         [AS_HELP_STRING([--with-soundsdir=DIR], [Put sound files into this location (default: $prefix/sounds)])], [soundsdir="$withval"], [soundsdir="${default_soundsdir}"])
 165 AC_SUBST(soundsdir)
 166 AC_DEFINE_UNQUOTED([SWITCH_SOUNDS_DIR],"${soundsdir}",[where to put sounds files])
 167
 168 AC_ARG_WITH([grammardir],
 169         [AS_HELP_STRING([--with-grammardir=DIR], [Put grammar files into this location (default: $prefix/grammar)])], [grammardir="$withval"], [grammardir="${default_grammardir}"])
 170 AC_SUBST(grammardir)
 171 AC_DEFINE_UNQUOTED([SWITCH_GRAMMAR_DIR],"${grammardir}",[where to put grammar files])
 172
 173 AC_ARG_WITH([certsdir],
 174         [AS_HELP_STRING([--with-certsdir=DIR], [Put certs files into this location (default: $prefix/certs)])], [certsdir="$withval"], [certsdir="${default_certsdir}"])
 175 AC_SUBST(certsdir)
 176 AC_DEFINE_UNQUOTED([SWITCH_CERTS_DIR],"${certsdir}",[where to put certs files])
 177
 178 AC_ARG_WITH([scriptdir],
 179         [AS_HELP_STRING([--with-scriptdir=DIR], [Put script files into this location (default: $prefix/scripts)])], [scriptdir="$withval"], [scriptdir="${default_scriptdir}"])
 180 AC_SUBST(scriptdir)
 181 AC_DEFINE_UNQUOTED([SWITCH_SCRIPT_DIR],"${scriptdir}",[where to put script files])
 182
 183 AC_ARG_WITH([recordingsdir],
 184         [AS_HELP_STRING([--with-recordingsdir=DIR], [Put recordings files into this location (default: $prefix/recordings)])], [recordingsdir="$withval"], [recordingsdir="${default_recordingsdir}"])
 185 AC_SUBST(recordingsdir)
 186 AC_DEFINE_UNQUOTED([SWITCH_RECORDINGS_DIR],"${recordingsdir}",[where to put recording files])
 187
 188 AC_ARG_WITH([imagesdir],
 189         [AS_HELP_STRING([--with-imagesdir=DIR], [Put images files into this location (default: $prefix/images)])], [imagesdir="$withval"], [imagesdir="${default_imagesdir}"])
 190 AC_SUBST(imagesdir)
 191 AC_DEFINE_UNQUOTED([SWITCH_IMAGES_DIR],"${imagesdir}",[where to put image files])
 192
 193 AC_ARG_WITH([storagedir],
 194         [AS_HELP_STRING([--with-storagedir=DIR], [Put storage files into this location (default: $prefix/storage)])], [storagedir="$withval"], [storagedir="${default_storagedir}"])
 195 AC_SUBST(storagedir)
 196 AC_DEFINE_UNQUOTED([SWITCH_STORAGE_DIR],"${storagedir}",[where to put storage files])
 197
 198 AC_ARG_WITH([cachedir],
 199         [AS_HELP_STRING([--with-cachedir=DIR], [Put cache files into this location (default: $prefix/cache)])], [cachedir="$withval"], [cachedir="${default_cachedir}"])
 200 AC_SUBST(cachedir)
 201 AC_DEFINE_UNQUOTED([SWITCH_CACHE_DIR],"${cachedir}",[where to put cache files])
 202
 203 AC_SUBST(confdir)
 204 AC_DEFINE_UNQUOTED([SWITCH_CONF_DIR],"${confdir}",[directory for configuration files])
 205
 206 AC_SUBST(datadir)
 207 AC_DEFINE_UNQUOTED([SWITCH_DATA_DIR],"${datadir}",[directory for data files])
 208
 209 AC_SUBST(localstatedir)
 210 AC_DEFINE_UNQUOTED([SWITCH_LOCALSTATE_DIR],"${localstatedir}",[directory for local state files])
 211 AC_SUBST(bindir)
 212 AC_SUBST(includedir)
 213
 214 AC_ARG_WITH([pkgconfigdir],
 215         [AS_HELP_STRING([--with-pkgconfigdir=DIR], [Installation directory for pkgconfig file (default: ${libdir}/pkgconfig)])],
 216         [case "${withval}" in
 217          yes|no) AC_MSG_ERROR([Invalid value ${withval} for option --with-pkgconfigdir]) ;;
 218          *) pkgconfigdir="${withval}" ;;
 219          esac
 220         ],
 221         [pkgconfigdir="${default_pkgconfigdir}"]
 222 )
 223 AC_SUBST([pkgconfigdir])
 224
 225 #Set default language
 226 AC_LANG_C
 227 # Checks for programs.
 228 AC_PROG_CC
 229 AC_PROG_CXX
 230
 231 #check if the g++ compiler works
 232 AC_CACHE_CHECK([whether the C++ compiler works], [ac_cv_sys_cxx_works], [
 233     AC_LANG_PUSH([C++])
 234     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int main() { }])], [ac_cv_sys_cxx_works=yes],
 235         [ac_cv_sys_cxx_works=no])
 236     AC_LANG_POP([C++])
 237     ])
 238 [ if [ "x$ac_cv_sys_cxx_works" = "xno" ]; then ]
 239     AC_MSG_FAILURE([The C++ compiler does not work. Please (re)install the C++ compiler])
 240 [ fi ]
 241
 242 AC_PROG_AWK
 243 AC_PROG_MAKE_SET
 244 AC_PROG_INSTALL
 245
 246 #override some default libtool behavior and invoke AC_PROG_LIBTOOL (see http://lists.gnu.org/archive/html/libtool/2007-03/msg00000.html)
 247 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
 248 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
 249 m4_defun([_LT_AC_LANG_RC_CONFIG], [:])
 250 AM_PROG_CC_C_O
 251 AC_PROG_LIBTOOL
 252
 253 #Check for compiler vendor
 254 AX_COMPILER_VENDOR
 255
 256 # Set CC_FOR_BUILD
 257 if test "x${cross_compiling}" = "xyes"; then
 258     CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
 259     case "$host" in
 260          arm*-linux-gnueabi*|arm*-*-linux-gnueabi*)
 261                 # spandsp modem
 262                 ac_cv_file__dev_ptmx=yes
 263                 # libjs
 264                 export ac_cv_va_copy=yes
 265                 # srtp
 266                 export ac_cv_file__dev_urandom=yes
 267                 # rpl_malloc
 268                 export ac_cv_func_realloc_0_nonnull=yes
 269                 export ac_cv_func_malloc_0_nonnull=yes
 270                 # apr
 271                 export ac_cv_func_setpgrp_void=yes
 272                 export ac_cv_file__dev_zero=yes
 273                 export apr_cv_tcp_nodelay_with_cork=yes
 274                 export ac_cv_file_dbd_apr_dbd_mysql_c=no
 275                 export ac_cv_sizeof_ssize_t=4
 276                 export apr_cv_mutex_recursive=yes
 277                 export ac_cv_func_pthread_rwlock_init=yes
 278                 export apr_cv_type_rwlock_t=yes
 279                 export apr_cv_process_shared_works=yes
 280                 export apr_cv_mutex_robust_shared=yes
 281          ;;
 282     esac
 283 else
 284     CC_FOR_BUILD='$(CC)'
 285 fi
 286 AC_SUBST(CC_FOR_BUILD)
 287
 288 if test -n "$lt_sysroot" ; then
 289    APR_ADDTO(CFLAGS, --sysroot=$lt_sysroot)
 290    APR_ADDTO(CXXFLAGS, --sysroot=$lt_sysroot)
 291    APR_ADDTO(CPPFLAGS, --sysroot=$lt_sysroot)
 292    APR_ADDTO(LDFLAGS, --sysroot=$lt_sysroot)
 293    PKG_CONFIG_SYSROOT_DIR=$lt_sysroot
 294 fi
 295
 296 #  Optimize
 297 AC_ARG_ENABLE(optimization,
 298 [AC_HELP_STRING([--enable-optimization],[Set if you want us to add max optimising compiler flags])],[enable_optimizer="$enableval"],[enable_optimizer="no"])
 299
 300 if test "${enable_optimizer}" = "yes" ; then
 301         AC_DEFINE([OPTIMZER],[],[Enable Optimization.])
 302         AX_CC_MAXOPT
 303 fi
 304
 305 # set defaults for use on all platforms
 306 SWITCH_AM_CFLAGS="-I${switch_srcdir}/src/include -I${switch_builddir}/src/include -I${switch_srcdir}/libs/libteletone/src"
 307 SWITCH_AM_CXXFLAGS="-I${switch_srcdir}/src/include -I${switch_builddir}/src/include -I${switch_srcdir}/libs/libteletone/src"
 308 SWITCH_AM_CPPFLAGS="-I${switch_srcdir}/src/include -I${switch_builddir}/src/include -I${switch_srcdir}/libs/libteletone/src"
 309 SWITCH_AM_LDFLAGS="-lm"
 310
 311 #set SOLINK variable based on compiler and host
 312 if test "x${ax_cv_c_compiler_vendor}"  =  "xsun" ; then
 313     SOLINK="-Bdynamic -dy -G"
 314 elif test "x${ax_cv_c_compiler_vendor}" = "xclang" ; then
 315     case "$host" in
 316         *darwin*)
 317             SOLINK="-dynamic -force-flat-namespace"
 318         ;;
 319         *)
 320             SOLINK="-shared -Xlinker -x"
 321         ;;
 322
 323     esac
 324 elif test "x${ax_cv_c_compiler_vendor}" = "xgnu" ; then
 325     case "$host" in
 326 # older Xcode test for darwin, Xcode 4/5 use clang above
 327         *darwin*)
 328             SOLINK="-dynamic -bundle -force-flat-namespace"
 329         ;;
 330         *-solaris2*)
 331             SOLINK="-shared -Xlinker"
 332         ;;
 333         *)
 334             SOLINK="-shared -Xlinker -x"
 335         ;;
 336     esac
 337 elif test "x${ax_cv_c_compiler_vendor}" = "xintel" ; then
 338     case "$host" in
 339         *)
 340             SOLINK="-shared -Xlinker -x"
 341         ;;
 342     esac
 343 else
 344     AC_ERROR([Please update configure.in with SOLINK values for your compiler])
 345 fi
 346
 347 ##
 348 # detect libtool major version,
 349 # set libtool library extension based on this
 350 # to work around some brokeness when using 'la' with libtool-1.5
 351 #
 352 AC_MSG_CHECKING([libtool major version])
 353 libtool="${switch_builddir}/libtool"
 354 LIBTOOL_MAJOR_VERSION="`$libtool --version 2>/dev/null| sed -e 's/([[^)]]*)//g;s/^[[^0-9]]*//;s/[[- ]].*//g;q'| awk  'BEGIN { FS = "." } { print $1 }' `"
 355 if test -z "$LIBTOOL_MAJOR_VERSION" ; then
 356         LIBTOOL_MAJOR_VERSION="`sed -n -e '/^VERSION/{s/^.*=\"\{0,1\}\([[0-9]]\{1,\}\)\..*/\1/;p;}' ${switch_srcdir}/build/config/ltmain.sh`"
 357 fi
 358 if test -z "$LIBTOOL_MAJOR_VERSION" ; then
 359         AC_MSG_ERROR([Failed to detect your libtool version, please open a bug report on https://freeswitch.org/jira])
 360 fi
 361 AC_MSG_RESULT([${LIBTOOL_MAJOR_VERSION}])
 362
 363 LIBTOOL_LIB_EXTEN=so
 364
 365 if test "${LIBTOOL_MAJOR_VERSION}" = "2" ; then
 366    LIBTOOL_LIB_EXTEN="la"
 367 fi
 368 AC_MSG_RESULT([using libtool library extension... ${LIBTOOL_LIB_EXTEN}])
 369
 370 if test "$ax_cv_c_compiler_vendor" = "gnu"; then
 371   saved_CFLAGS="$CFLAGS"
 372   AC_CACHE_CHECK([whether compiler supports -Wno-unused-result],
 373     [ac_cv_gcc_supports_w_no_unused_result], [
 374       CFLAGS="$CFLAGS -Wno-unused-result -Wno-error=unused-result"
 375       AC_TRY_COMPILE([],[return 0;],
 376         [ac_cv_gcc_supports_w_no_unused_result=yes],
 377         [ac_cv_gcc_supports_w_no_unused_result=no])])
 378   CFLAGS="$saved_CFLAGS"
 379   AC_MSG_RESULT($ac_cv_gcc_supports_w_no_unused_result)
 380
 381   saved_CFLAGS="$CFLAGS"
 382   AC_CACHE_CHECK([whether compiler supports -Wno-misleading-indentation],
 383     [ac_cv_gcc_supports_w_no_misleading_indentation], [
 384       CFLAGS="$CFLAGS -Wno-misleading-indentation -Wno-error=misleading-indentation"
 385       AC_TRY_COMPILE([],[return 0;],
 386         [ac_cv_gcc_supports_w_no_misleading_indentation=yes],
 387         [ac_cv_gcc_supports_w_no_misleading_indentation=no])])
 388   CFLAGS="$saved_CFLAGS"
 389   AC_MSG_RESULT($ac_cv_gcc_supports_w_no_misleading_indentation)
 390 fi
 391
 392 # tweak compiler specific flags
 393 if test "x${ax_cv_c_compiler_vendor}"  =  "xsun" ; then
 394     APR_ADDTO(SWITCH_AM_CFLAGS, -KPIC)
 395     APR_ADDTO(SWITCH_AM_CFLAGS, -DPIC)
 396     APR_ADDTO(SWITCH_AM_CFLAGS, -erroff=E_END_OF_LOOP_CODE_NOT_REACHED)
 397     APR_ADDTO(SWITCH_AM_CFLAGS, -errtags=yes)
 398     APR_ADDTO(SWITCH_AM_CFLAGS, -D__FUNCTION__=__func__ )
 399     APR_ADDTO(SWITCH_AM_CFLAGS, -mt)
 400     APR_ADDTO(SWITCH_AM_CXXFLAGS, -errtags=yes)
 401     APR_ADDTO(SWITCH_AM_CXXFLAGS, -KPIC)
 402     APR_ADDTO(SWITCH_AM_CXXFLAGS, -DPIC)
 403     APR_ADDTO(SWITCH_AM_CXXFLAGS, "-features=extensions")
 404     APR_ADDTO(SWITCH_AM_CXXFLAGS, -D__FUNCTION__=__func__)
 405     APR_ADDTO(SWITCH_AM_CXXFLAGS, -mt)
 406
 407     APR_ADDTO(SWITCH_AM_LDFLAGS, -R${prefix}/lib)
 408     if test "${enable_64}" = "yes"; then
 409         APR_ADDTO(SWITCH_AM_CFLAGS, -m64)
 410         APR_ADDTO(SWITCH_AM_CXXFLAGS, -m64)
 411         APR_ADDTO(SWITCH_AM_LDFLAGS, -m64)
 412         LIBS="$LIBS -m64"
 413     fi
 414 elif test "x${ax_cv_c_compiler_vendor}" = "xclang" ; then
 415     APR_ADDTO(SWITCH_AM_CFLAGS, -fPIC -ffast-math)
 416     APR_ADDTO(SWITCH_AM_CXXFLAGS, -fPIC -ffast-math)
 417     APR_ADDTO(SWITCH_AM_CFLAGS, -Werror)
 418 elif test "x${ax_cv_c_compiler_vendor}" = "xgnu" ; then
 419     APR_ADDTO(SWITCH_AM_CFLAGS, -fPIC -ffast-math)
 420     APR_ADDTO(SWITCH_AM_CXXFLAGS, -fPIC -ffast-math)
 421     AC_SUBST([AM_MOD_AVMD_CXXFLAGS], [-std=gnu99])      # FS-8809, needed for MAP_POPULATE
 422     if test "$ac_cv_gcc_supports_w_no_unused_result" = yes; then
 423       APR_ADDTO(SWITCH_AM_CFLAGS, -Werror)
 424       APR_ADDTO(SWITCH_AM_CFLAGS, -Wno-unused-result)
 425     fi
 426     if test "$ac_cv_gcc_supports_w_no_misleading_indentation" = yes; then
 427       APR_ADDTO(SWITCH_AM_CFLAGS, -Wno-misleading-indentation)
 428     fi
 429     if test "${enable_64}" = "yes"; then
 430         case "$host" in
 431              *darwin*)
 432                 osxvrm=`sw_vers -productVersion`          # Get version.release.modlevel
 433                 osxrel=`echo $osxvrm | cut -d. -f2`       # Get release only
 434                 if test "$osxrel" -ge 4; then             # 10.4 and up are x64
 435                    APR_ADDTO(CFLAGS, -arch x86_64)
 436                    APR_ADDTO(LDFLAGS, -arch x86_64)
 437                    APR_ADDTO(CXXFLAGS, -arch x86_64)
 438                 fi
 439                 ;;
 440              *-solaris2*)
 441                 APR_ADDTO(CFLAGS, -m64)
 442                 APR_ADDTO(LDFLAGS, -m64)
 443                 APR_ADDTO(CXXFLAGS, -m64)
 444                 ;;
 445              *)
 446                 LIBS="$LIBS -m64"
 447              ;;
 448          esac
 449     fi
 450 fi
 451
 452 case "${ax_cv_c_compiler_vendor}" in
 453 sun)
 454         VISIBILITY_FLAG=-xldscope=hidden
 455 ;;
 456 *)
 457         VISIBILITY_FLAG=-fvisibility=hidden
 458 ;;
 459 esac
 460 AC_SUBST(VISIBILITY_FLAG)
 461
 462 #
 463 # gcc visibility cflag checks
 464 #
 465 AC_ARG_ENABLE([visibility],
 466         [AS_HELP_STRING([--disable-visibility], [Disable or enable API visibility support (default: use if available)])],
 467         [enable_visibility="${enableval}"],
 468         [enable_visibility="detect"]
 469 )
 470 HAVE_VISIBILITY="no"
 471
 472 if test "x${enable_visibility}" != "xno" ; then
 473
 474         case "${ax_cv_c_compiler_vendor}" in
 475         gnu)
 476                 save_CFLAGS="${CFLAGS}"
 477                 CFLAGS="${CFLAGS} -fvisibility=hidden"
 478                 AC_MSG_CHECKING([whether the compiler supports -fvisibility=hidden])
 479                 AC_COMPILE_IFELSE(
 480                         [AC_LANG_PROGRAM(
 481                                 [int foo __attribute__ ((visibility("default")));],
 482                                 [;]
 483                         )],
 484
 485                         [AC_MSG_RESULT([yes])
 486                          APR_ADDTO([SWITCH_AM_CFLAGS],   [-fvisibility=hidden -DSWITCH_API_VISIBILITY=1 -DCJSON_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 487                          APR_ADDTO([SWITCH_AM_CXXFLAGS], [-fvisibility=hidden -DSWITCH_API_VISIBILITY=1 -DCJSON_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 488                          HAVE_VISIBILITY="yes"],
 489
 490                         [AC_MSG_RESULT([no])]
 491                 )
 492                 CFLAGS="${save_CFLAGS}"
 493                 ;;
 494
 495         sun)
 496         #       save_CFLAGS="${CFLAGS}"
 497         #       CFLAGS="${CFLAGS} -xldscope=hidden"
 498         #       AC_MSG_CHECKING([whether the compiler supports -xldscope=hidden])
 499         #       AC_COMPILE_IFELSE(
 500         #               [AC_LANG_PROGRAM(
 501         #                       [int foo __attribute__ ((visibility("default")));],
 502         #                       [;]
 503         #               )],
 504         #
 505         #               [AC_MSG_RESULT([yes])
 506         #                APR_ADDTO([SWITCH_AM_CFLAGS],   [-xldscope=hidden -DSWITCH_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 507         #                APR_ADDTO([SWITCH_AM_CXXFLAGS], [-xldscope=hidden -DSWITCH_API_VISIBILITY=1 -DHAVE_VISIBILITY=1])
 508         #                HAVE_VISIBILITY="yes"],
 509         #
 510         #               [AC_MSG_RESULT([no])]
 511         #       )
 512         #       CFLAGS="${save_CFLAGS}"
 513                 ;;
 514
 515         *)
 516                 if test "x${enable_visibility}" = "xyes" ; then
 517                         AC_MSG_ERROR([Non-GNU / SUN compilers are currently unsupported])
 518                 else
 519                         AC_MSG_WARN([Non-GNU / SUN compilers are currently unsupported])
 520                 fi
 521                 ;;
 522         esac
 523
 524         #
 525         # visibility explicitly requested but not supported by this compiler => error
 526         #
 527         if test "x${enable_visibility}" = "xyes" -a "x${HAVE_VISIBILITY}" = "xno" ; then
 528                 AC_MSG_ERROR([API visibility not supported by this compiler])
 529         fi
 530 fi
 531
 532 # Enable debugging (default: on)
 533 # (rename option if the default is changed)
 534 AC_ARG_ENABLE(debug,
 535 [AC_HELP_STRING([--disable-debug],[build without debug information])],[enable_debug="$enableval"],[enable_debug="yes"])
 536
 537 if test "${enable_debug}" = "yes"; then
 538         AC_DEFINE([DEBUG],[],[Enable extra debugging.])
 539         saved_CFLAGS="$CFLAGS"
 540         CFLAGS=
 541         AX_CFLAGS_WARN_ALL_ANSI
 542         SWITCH_ANSI_CFLAGS=$CFLAGS
 543         CFLAGS="$saved_CFLAGS"
 544
 545         if test "x${ax_cv_c_compiler_vendor}" = "xgnu" ; then
 546             if test "$ac_cv_gcc_supports_w_no_unused_result" = yes; then
 547               APR_ADDTO(SWITCH_AM_CFLAGS, -Wno-unused-result)
 548             fi
 549             APR_ADDTO(SWITCH_AM_CFLAGS, -g -ggdb)
 550             export DEBUG_CFLAGS="-g -ggdb"
 551         fi
 552
 553 fi
 554
 555 AC_ARG_ENABLE(libyuv,
 556 [AC_HELP_STRING([--disable-libyuv],[build without libyuv])],[enable_libyuv="$enableval"],[enable_libyuv="yes"])
 557
 558 AM_CONDITIONAL([ENABLE_LIBYUV],[test "${enable_libyuv}" = "yes"])
 559
 560 AC_ARG_ENABLE(libvpx,
 561 [AC_HELP_STRING([--disable-libvpx],[build without libvpx])],[enable_libvpx="$enableval"],[enable_libvpx="yes"])
 562
 563 AM_CONDITIONAL([ENABLE_LIBVPX],[test "${enable_libvpx}" = "yes"])
 564
 565 AC_ARG_ENABLE(cpp,
 566 [AC_HELP_STRING([--disable-cpp],[build without cpp code])],[enable_cpp="$enableval"],[enable_cpp="yes"])
 567
 568 AM_CONDITIONAL([ENABLE_CPP],[test "${enable_cpp}" = "yes"])
 569
 570 AM_CONDITIONAL([DISABLE_CC],[test "${disable_cc}" = "yes"])
 571
 572 AC_ARG_ENABLE([system-xmlrpc-c],
 573   [AS_HELP_STRING([--enable-system-xmlrpc-c],
 574     [use system lib for xmlrpc-c])],,
 575   [enable_xmlrpcc="no"])
 576
 577 if test "${enable_xmlrpcc}" = "yes" ; then
 578 SYS_XMLRPC_CFLAGS=`xmlrpc-c-config --cflags`
 579 SYS_XMLRPC_LDFLAGS=`xmlrpc-c-config --libs`
 580 fi
 581 AC_SUBST(SYS_XMLRPC_CFLAGS)
 582 AC_SUBST(SYS_XMLRPC_LDFLAGS)
 583 AM_CONDITIONAL([SYSTEM_XMLRPCC],[test "${enable_xmlrpcc}" = "yes"])
 584
 585 for luaversion in luajit lua5.2 lua-5.2 lua52 lua5.1 lua-5.1 lua; do
 586   PKG_CHECK_MODULES([LUA],[${luaversion}],[have_lua=yes],[have_lua=no])
 587   if test ${have_lua} = yes; then
 588     break
 589   fi
 590 done
 591 if test x"${LUA_LIBS}" = x"" ; then
 592    LUA_LIBS="-llua"
 593 fi
 594
 595 AC_ARG_ENABLE(srtp,
 596 [AC_HELP_STRING([--disable-srtp],[build without srtp support])],[enable_srtp="$enableval"],[enable_srtp="yes"])
 597
 598 AM_CONDITIONAL([ENABLE_SRTP],[test "${enable_srtp}" = "yes"])
 599
 600 have_openal=no
 601 AC_CHECK_LIB(openal, alMidiGainSOFT, [have_openal="yes"])
 602 AM_CONDITIONAL([HAVE_OPENAL],[test "${have_openal}" = "yes"])
 603
 604 AC_ARG_ENABLE(zrtp,
 605         [AS_HELP_STRING([--enable-zrtp], [Compile with zrtp Support])],,[enable_zrtp="no"])
 606 if test "x$enable_zrtp" = "xyes" ; then
 607    LIBS="-lpthread $LIBS"
 608    APR_ADDTO(SWITCH_AM_CFLAGS, -DENABLE_ZRTP)
 609 fi
 610
 611 PA_LIBS=
 612
 613 PKG_CHECK_MODULES(JACK, jack, have_jack=yes, have_jack=no)
 614 if test "x$have_jack" = "xyes" ; then
 615 PA_LIBS+=$JACK_LIBS
 616 fi
 617
 618 AC_CHECK_LIB(asound, snd_pcm_open, have_alsa=yes, have_alsa=no)
 619 if test "x$have_alsa" = "xyes"  ; then
 620 PA_LIBS+=-lasound
 621 fi
 622
 623 AC_SUBST(PA_LIBS)
 624
 625 AM_CONDITIONAL([ENABLE_ZRTP],[test "x$enable_zrtp" != "xno"])
 626
 627 AM_CONDITIONAL([WANT_DEBUG],[test "${enable_debug}" = "yes"])
 628
 629 AC_ARG_ENABLE(core-odbc-support,
 630   [AS_HELP_STRING([--enable-core-odbc-support], [Compile with ODBC Support (default is optional)])],,[enable_core_odbc_support="optional"])
 631 if ! test "$enable_core_odbc_support" = "no"; then
 632   AX_LIB_ODBC
 633   if test "$ac_cv_found_odbc" = "yes" ; then
 634     enable_core_odbc_support="yes"
 635   elif test "$enable_core_odbc_support" = "yes"; then
 636     AC_MSG_ERROR([no usable libodbc; please install unixodbc devel package or equivalent])
 637   else
 638     enable_core_odbc_support="no"
 639   fi
 640 fi
 641
 642 CHECK_LIBUUID
 643 SWITCH_AM_LDFLAGS="$LIBUUID_LIBS $SWITCH_AM_LDFLAGS"
 644 SWITCH_AM_CFLAGS="$LIBUUID_CFLAGS $SWITCH_AM_CFLAGS"
 645
 646 AC_ARG_ENABLE(core-pgsql-pkgconfig,
 647         [AS_HELP_STRING([--disable-core-pgsql-pkgconfig], [Use pg_config to get PGQSL build options])],[enable_core_pgsql_pkgconfig="$enableval"],[enable_core_pgsql_pkgconfig="yes"])
 648
 649 path_remove () {
 650   echo "$1" | tr ':' '\n' | grep -Fxv "$2" | tr '\n' ':' | sed 's/:$//'
 651 }
 652 path_push_unique () {
 653   x="$(eval echo \$$1)"
 654   x="$(path_remove "$x" "$2")"
 655   if test -z "$x"; then
 656     eval export $1="$2"
 657   else
 658     eval export $1="$2:$x"
 659   fi
 660 }
 661
 662 AC_PATH_PROG([PG_CONFIG], [pg_config], [no])
 663 AC_PATH_PROG([PKG_CONFIG], [pkg-config], [no])
 664
 665 case $host in
 666      *-darwin*)
 667         path_push_unique PKG_CONFIG_PATH /usr/local/opt/libpq/lib/pkgconfig
 668      ;;
 669 esac
 670
 671 if test "$PKG_CONFIG" = "no" \
 672         || test x"$enable_core_pgsql_pkgconfig" = x"no" \
 673         || ! pkg-config libpq; then
 674         if test "$PG_CONFIG" != "no"; then
 675                 AC_MSG_CHECKING([for PostgreSQL libraries via pg_config])
 676                 POSTGRESQL_CFLAGS="-I`$PG_CONFIG --includedir`"
 677                 POSTGRESQL_LIBDIR="-L`$PG_CONFIG --libdir`"
 678                 POSTGRESQL_LDFLAGS="-L`$PG_CONFIG --libdir` -lpq"
 679                 POSTGRESQL_VERSION=`$PG_CONFIG --version | awk '{ print $NF }'`
 680                 POSTGRESQL_MAJOR_VERSION=`$PG_CONFIG --version | awk '{ print $NF }' | awk -F. '{ print $1 }'`
 681                 POSTGRESQL_MINOR_VERSION=`$PG_CONFIG --version | awk '{ print $NF }' | awk -F. '{ print $2 }'`
 682                 POSTGRESQL_PATCH_VERSION=`$PG_CONFIG --version | awk '{ print $NF }' | awk -F. '{ print $3 }'`
 683         fi
 684 else
 685
 686         AC_MSG_CHECKING([for PostgreSQL libraries via pkg_config])
 687         POSTGRESQL_CFLAGS="`$PKG_CONFIG --cflags libpq`"
 688         POSTGRESQL_LIBDIR="`$PKG_CONFIG libpq --libs-only-L`"
 689         POSTGRESQL_LDFLAGS="`$PKG_CONFIG --libs libpq`"
 690         POSTGRESQL_VERSION="`$PKG_CONFIG --modversion libpq`"
 691         POSTGRESQL_MAJOR_VERSION="`echo $POSTGRESQL_VERSION | cut -d. -f1 | sed 's/^\([[0-9]]*\)[[^0-9]].*/\1/'`"
 692         POSTGRESQL_MINOR_VERSION="`echo $POSTGRESQL_VERSION | cut -d. -f2 | sed 's/^\([[0-9]]*\)[[^0-9]].*/\1/'`"
 693         POSTGRESQL_PATCH_VERSION="`echo $POSTGRESQL_VERSION | cut -d. -f3 | sed 's/^\([[0-9]]*\)[[^0-9]].*/\1/'`"
 694         test -n "$POSTGRESQL_PATCH_VERSION" || POSTGRESQL_PATCH_VERSION=0
 695 fi
 696 AC_MSG_RESULT([$POSTGRESQL_LIBDIR])
 697 AC_DEFINE_UNQUOTED([POSTGRESQL_VERSION], "${POSTGRESQL_VERSION}", [Specifies the version of PostgreSQL we are linking against])
 698 AC_DEFINE_UNQUOTED([POSTGRESQL_MAJOR_VERSION], ${POSTGRESQL_MAJOR_VERSION}, [Specifies the version of PostgreSQL we are linking against])
 699 AC_DEFINE_UNQUOTED([POSTGRESQL_MINOR_VERSION], ${POSTGRESQL_MINOR_VERSION}, [Specifies the version of PostgreSQL we are linking against])
 700 AC_DEFINE_UNQUOTED([POSTGRESQL_PATCH_VERSION], ${POSTGRESQL_PATCH_VERSION}, [Specifies the version of PostgreSQL we are linking against])
 701 have_libpq=no
 702 save_LIBS="${LIBS}"
 703 save_CPPFLAGS="${CPPFLAGS}"
 704 LIBS="${POSTGRESQL_LDFLAGS}"
 705 CPPFLAGS="${POSTGRESQL_CFLAGS}"
 706 AC_CHECK_LIB([pq], [PQgetvalue], [have_libpq="yes"])
 707 LIBS="${save_LIBS}"
 708 CPPFLAGS="${save_CPPFLAGS}"
 709 AM_CONDITIONAL([HAVE_PGSQL],[test "${have_libpq}" = "yes"])
 710 AC_SUBST([POSTGRESQL_CFLAGS], [$POSTGRESQL_CFLAGS])
 711 AC_SUBST([POSTGRESQL_LDFLAGS], [$POSTGRESQL_LDFLAGS])
 712 AC_SUBST([POSTGRESQL_LIBDIR], [$POSTGRESQL_LIBDIR])
 713
 714
 715 PKG_CHECK_MODULES([MARIADB], [libmariadb >= 3.0.9],[
 716   AM_CONDITIONAL([HAVE_MARIADB],[true])],[
 717   PKG_CHECK_MODULES([MARIADB], [mariadb >= 3.0.9],[
 718     AM_CONDITIONAL([HAVE_MARIADB],[true])],[
 719     AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MARIADB],[false])
 720   ])
 721 ])
 722
 723 PKG_CHECK_MODULES([SPANDSP], [spandsp >= 3.0],[
 724   AM_CONDITIONAL([HAVE_SPANDSP],[true])],[
 725     AC_MSG_ERROR([no usable spandsp; please install spandsp3 devel package or equivalent])
 726 ])
 727
 728 PKG_CHECK_MODULES([SOFIA_SIP], [sofia-sip-ua >= 1.13.4],[
 729   AM_CONDITIONAL([HAVE_SOFIA_SIP],[true])],[
 730     AC_MSG_ERROR([no usable sofia-sip; please install sofia-sip-ua devel package or equivalent])
 731 ])
 732
 733 AC_ARG_ENABLE(deprecated-core-db-events,
 734         [AS_HELP_STRING([--enable-deprecated-core-db-events], [Keep deprecated core db events])],,[enable_deprecated_core_db_events="no"])
 735
 736 if test x"$enable_deprecated_core_db_events" = x"yes" ; then
 737         AC_DEFINE([SWITCH_DEPRECATED_CORE_DB], [1], [Define to 1 to enable deprecated core db events])
 738 fi
 739
 740 ESL_LDFLAGS=
 741 PLATFORM_CORE_LDFLAGS=
 742 PLATFORM_CORE_LIBS=
 743
 744 # tweak platform specific flags
 745 case "$host" in
 746     *darwin*)
 747         # Common Apple Darwin settings
 748         APR_ADDTO(SWITCH_AM_CFLAGS, -DMACOSX)
 749         APR_REMOVEFROM(SWITCH_AM_CFLAGS, -fPIC)
 750         APR_ADDTO(CPPFLAGS, -I/usr/local/opt/openssl/include)
 751         APR_ADDTO(LDFLAGS, -L/usr/local/opt/openssl/lib)
 752         if test "x$enable_core_odbc_support" != "xno"; then
 753            APR_ADDTO([PLATFORM_CORE_LDFLAGS], [--framework CoreFoundation])
 754         fi
 755         APR_ADDTO([PLATFORM_CORE_LIBS], [-ldl])
 756     # Get OSX and clang version
 757         osxvrm=`sw_vers -productVersion`          # Get version.release.modlevel
 758         osxrel=`echo $osxvrm | cut -d. -f2`       # Get release only
 759         clangvers="`clang -v 2>&1  >/dev/null | grep version | sed -e 's/.*version \([[0-9]]*\).*$/\1/'`"
 760         if test "$clangvers" -ge 6; then          # Xcode 6 drops std lib search, add it to clang
 761            APR_ADDTO(LDFLAGS, -L/usr/local/lib)
 762            APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 763         fi
 764         if test "$clangvers" -ge 4; then          # Xcode 4 / 10.7 and up
 765            APR_ADDTO(CFLAGS, -Wno-deprecated-declarations)
 766         fi
 767         if test "$osxrel" -ge 6; then             # 10.6 and up
 768            APR_ADDTO(CFLAGS, -pipe -no-cpp-precomp)
 769            APR_ADDTO(LDFLAGS, -pipe -bind_at_load)
 770            APR_ADDTO(CXXFLAGS, -pipe)
 771         fi
 772     ;;
 773     *-solaris2*)
 774         if test "${enable_64}" = "yes"; then
 775            APR_ADDTO(CPPFLAGS, [-I/opt/64/include])
 776            APR_ADDTO(LDFLAGS, [-L/opt/64/lib -Wl,-rpath,/opt/64/lib])
 777            APR_ADDTO(SWITCH_AM_CFLAGS, [-I/opt/64/include])
 778            APR_ADDTO(SWITCH_AM_LDFLAGS, [-L/opt/64/lib -Wl,-rpath,/opt/64/lib])
 779         else
 780            APR_ADDTO(CPPFLAGS, [-I/opt/include])
 781            APR_ADDTO(LDFLAGS, [-L/opt/lib -Wl,-rpath,/opt/lib])
 782            APR_ADDTO(SWITCH_AM_CFLAGS, [-I/opt/include])
 783            APR_ADDTO(SWITCH_AM_LDFLAGS, [-L/opt/lib -Wl,-rpath,/opt/lib])
 784         fi
 785         APR_ADDTO(SWITCH_AM_CFLAGS, -DPATH_MAX=2048 -D__EXTENSIONS__)
 786         APR_ADDTO(SWITCH_AM_LDFLAGS, -lsendfile -lresolv -lsocket -lnsl -luuid)
 787         APR_ADDTO(ESL_LDFLAGS, -lnsl -lsocket)
 788         APR_ADDTO([PLATFORM_CORE_LIBS], [-ldl -lcrypt -lrt -lsendfile -lresolv -lsocket -lnsl -luuid])
 789     ;;
 790     *dragonfly*)
 791         APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 792         APR_ADDTO(LDFLAGS, -L/usr/local/lib)
 793         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/local/include)
 794     ;;
 795     *openbsd*)
 796         APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 797         APR_ADDTO(LDFLAGS, -L/usr/local/lib -ltermcap)
 798         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/local/include)
 799     ;;
 800     *netbsd*)
 801         APR_ADDTO(CPPFLAGS, -I/usr/pkg/include)
 802         APR_ADDTO(LDFLAGS, [-L/usr/pkg/lib -Wl,-rpath,/usr/pkg/lib])
 803         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/pkg/include)
 804     ;;
 805     *bsd*)
 806         APR_ADDTO(CPPFLAGS, -I/usr/local/include)
 807         APR_ADDTO(LDFLAGS, -L/usr/local/lib)
 808         APR_ADDTO(SWITCH_AM_CFLAGS, -I/usr/local/include)
 809         APR_ADDTO([PLATFORM_CORE_LIBS], [-lcrypt -lrt])
 810     ;;
 811     *linux*)
 812         APR_ADDTO([PLATFORM_CORE_LIBS], [-ldl -lcrypt -lrt])
 813     ;;
 814 esac
 815
 816 APR_REMOVEFROM(SWITCH_AM_CXXFLAGS, -std=c99)
 817
 818 # check for usable system MD5 library
 819 AS_CASE([$host],
 820   [*-solaris2*], [AC_CHECK_LIB(md5, MD5Init)],
 821   [*-freebsd*], [AC_CHECK_LIB(md, MD5Init)],
 822   [*-openbsd*|*-netbsd*], [AC_CHECK_FUNCS([MD5Init])])
 823
 824 AC_CHECK_LIB(z, inflateReset, have_libz=yes, AC_MSG_ERROR([no usable zlib; please install zlib devel package or equivalent]))
 825 if test "x$have_libz" = "xyes"  ; then
 826 APR_ADDTO([PLATFORM_CORE_LIBS], [-lz])
 827 fi
 828
 829 PKG_CHECK_MODULES([MPG123], [libmpg123 >= 1.16.0],[
 830   AM_CONDITIONAL([HAVE_MPG123],[true])],[
 831   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MPG123],[false])])
 832
 833 PKG_CHECK_MODULES([AMR], [opencore-amrnb >= 0.1.0],[
 834                 AM_CONDITIONAL([HAVE_AMR],[true])],[
 835                 AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AMR],[false])])
 836
 837 PKG_CHECK_MODULES([AMRWB], [opencore-amrwb >= 0.1.0 vo-amrwbenc >= 0.1.0],[
 838                 AM_CONDITIONAL([HAVE_AMRWB],[true])],[
 839                 AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AMRWB],[false])])
 840
 841 PKG_CHECK_MODULES([STIRSHAKEN], [stirshaken],[
 842                 AM_CONDITIONAL([HAVE_STIRSHAKEN],[true])],[
 843                 AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_STIRSHAKEN],[false])])
 844
 845 AC_CHECK_LIB(apr-1, apr_pool_mutex_set, use_system_apr=yes, use_system_apr=no)
 846 AM_CONDITIONAL([SYSTEM_APR],[test "${use_system_apr}" = "yes"])
 847 AC_CHECK_LIB(aprutil-1, apr_queue_pop_timeout, use_system_aprutil=yes, use_system_aprutil=no)
 848 AM_CONDITIONAL([SYSTEM_APRUTIL],[test "${use_system_aprutil}" = "yes"])
 849
 850 save_LIBS="$LIBS"
 851 LIBS=
 852 AC_CHECK_LIB(jpeg, jpeg_std_error,, AC_MSG_ERROR([no usable libjpeg; please install libjpeg devel package or equivalent]))
 853
 854 AC_CHECK_LIB(jbig, jbg_enc_out, have_libjbig=yes, have_libjbig=no)
 855 if test "x$have_libjbig" = "xyes"  ; then
 856 SPANDSP_LA_JBIG="-ljbig $LIBS"
 857 AC_SUBST(SPANDSP_LA_JBIG)
 858 fi
 859 LIBS="$save_LIBS"
 860
 861 AC_CHECK_LIB(lzma, lzma_code, have_liblzma=yes, have_liblzma=no)
 862 if test "x$have_liblzma" = "xyes" ; then
 863 SPANDSP_LA_LZMA="-llzma"
 864 AC_SUBST(SPANDSP_LA_LZMA)
 865 fi
 866
 867 AC_CHECK_LIB(resolv, res_init, have_libresolv=yes, have_libresolv=no)
 868 if test "x$have_libresolv" = "xyes"  ; then
 869 APR_ADDTO(SWITCH_AM_LDFLAGS, -lresolv)
 870 fi
 871
 872 AC_SUBST(SWITCH_AM_CFLAGS)
 873 AC_SUBST(SWITCH_ANSI_CFLAGS)
 874 AC_SUBST(SWITCH_AM_CXXFLAGS)
 875 AC_SUBST(SWITCH_AM_CPPFLAGS)
 876 AC_SUBST(SWITCH_AM_LDFLAGS)
 877 AC_SUBST(ESL_LDFLAGS)
 878 AC_SUBST(PLATFORM_CORE_LDFLAGS)
 879 AC_SUBST(PLATFORM_CORE_LIBS)
 880 AC_SUBST(SOLINK)
 881 AC_SUBST(LIBTOOL_LIB_EXTEN)
 882
 883 # Checks for header files.
 884 AC_HEADER_DIRENT
 885 AC_HEADER_STDC
 886 AC_CHECK_HEADERS([sys/types.h sys/resource.h sched.h wchar.h sys/filio.h sys/ioctl.h sys/prctl.h sys/select.h netdb.h execinfo.h sys/time.h])
 887
 888 # Solaris 11 privilege management
 889 AS_CASE([$host],
 890   [*-*-solaris2.11], [AC_CHECK_HEADER([priv.h], [AC_DEFINE([SOLARIS_PRIVILEGES],[1],[Solaris 11 privilege management])])]
 891 )
 892
 893
 894 if test x"$ac_cv_header_wchar_h" = xyes; then
 895   HAVE_WCHAR_H_DEFINE=1
 896 else
 897   HAVE_WCHAR_H_DEFINE=0
 898 fi
 899 AC_SUBST(HAVE_WCHAR_H_DEFINE)
 900
 901 # Needed by Abyss on Solaris:
 902
 903 if test x"$ac_cv_header_sys_filio_h" = xyes; then
 904   HAVE_SYS_FILIO_H_DEFINE=1
 905 else
 906   HAVE_SYS_FILIO_H_DEFINE=0
 907 fi
 908 AC_SUBST(HAVE_SYS_FILIO_H_DEFINE)
 909
 910 # Needed by Abyss on Solaris:
 911
 912 if test x"$ac_cv_header_sys_ioctl_h" = xyes; then
 913   HAVE_SYS_IOCTL_H_DEFINE=1
 914 else
 915   HAVE_SYS_IOCTL_H_DEFINE=0
 916 fi
 917 AC_SUBST(HAVE_SYS_IOCTL_H_DEFINE)
 918
 919 if test x"$ac_cv_header_sys_select_h" = xyes; then
 920   HAVE_SYS_SELECT_H_DEFINE=1
 921 else
 922   HAVE_SYS_SELECT_H_DEFINE=0
 923 fi
 924 AC_SUBST(HAVE_SYS_SELECT_H_DEFINE)
 925
 926 # Checks for typedefs, structures, and compiler characteristics.
 927 AC_C_CONST
 928 AC_C_INLINE
 929 AC_TYPE_SIZE_T
 930 AC_HEADER_TIME
 931 AC_STRUCT_TM
 932
 933 # Checks for library functions.
 934 AC_PROG_GCC_TRADITIONAL
 935 AC_FUNC_MALLOC
 936 AC_TYPE_SIGNAL
 937 AC_FUNC_STRFTIME
 938 AC_CHECK_FUNCS([gethostname vasprintf mmap mlock mlockall usleep getifaddrs timerfd_create getdtablesize posix_openpt poll])
 939 AC_CHECK_FUNCS([sched_setscheduler setpriority setrlimit setgroups initgroups getrusage])
 940 AC_CHECK_FUNCS([wcsncmp setgroups asprintf setenv pselect gettimeofday localtime_r gmtime_r strcasecmp stricmp _stricmp])
 941
 942 # Check availability and return type of strerror_r
 943 # (NOTE: apr-1-config sets -D_GNU_SOURCE at build-time, need to run the check with it too)
 944 save_CPPFLAGS="$CPPFLAGS"
 945 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 946 AC_FUNC_STRERROR_R
 947 CPPFLAGS="$save_CPPFLAGS"
 948
 949 AX_HAVE_CPU_SET
 950
 951 AC_CHECK_LIB(rt, clock_gettime, [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])])
 952 AC_CHECK_LIB(rt, clock_getres, [AC_DEFINE(HAVE_CLOCK_GETRES, 1, [Define if you have clock_getres()])])
 953 AC_CHECK_LIB(rt, clock_nanosleep, [AC_DEFINE(HAVE_CLOCK_NANOSLEEP, 1, [Define if you have clock_nanosleep()])])
 954 AC_CHECK_LIB(pthread, pthread_setschedparam, [AC_DEFINE(HAVE_PTHREAD_SETSCHEDPARAM, 1, [Define if you have pthread_setschedparam()])])
 955
 956 AC_CHECK_FUNC(socket, , AC_CHECK_LIB(socket, socket))
 957
 958 AC_CHECK_FILE(/dev/ptmx, [AC_DEFINE(HAVE_DEV_PTMX, 1, [Define if you have /dev/ptmx])])
 959 AC_CHECK_LIB(util, openpty, [AC_DEFINE(HAVE_OPENPTY, 1, [Define if you have openpty()])])
 960
 961 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[
 962 #include <sys/types.h>
 963 #include <time.h>])
 964
 965 AC_CHECK_MEMBERS([struct tm.tm_zone],,,[
 966 #include <sys/types.h>
 967 #include <time.h>])
 968
 969 AC_CHECK_DECL([RLIMIT_MEMLOCK],
 970         [AC_DEFINE([HAVE_RLIMIT_MEMLOCK],[1],[RLIMIT_MEMLOCK constant for setrlimit])],,
 971         [#ifdef HAVE_SYS_RESOURCE_H
 972          #include <sys/resource.h>
 973          #endif])
 974
 975 AC_CHECK_DECL([SCHED_RR],
 976         [AC_DEFINE([HAVE_SCHED_RR],[1],[SCHED_RR constant for sched_setscheduler])],,
 977         [#ifdef HAVE_SCHED_H
 978          #include <sched.h>
 979          #endif])
 980
 981 AC_CHECK_DECL([SCHED_FIFO],
 982         [AC_DEFINE([HAVE_SCHED_FIFO],[1],[SCHED_FIFO constant for sched_setscheduler])],,
 983         [#ifdef HAVE_SCHED_H
 984          #include <sched.h>
 985          #endif])
 986
 987 #
 988 # use mlockall only on linux (for now; if available)
 989 #
 990 if test "x${ac_cv_func_mlockall}" = "xyes"; then
 991         AC_MSG_CHECKING([whether to use mlockall])
 992         case "$host" in
 993         *-linux-*)
 994                 AC_DEFINE([USE_MLOCKALL],[1],[Enable mlockall support])
 995                 AC_MSG_RESULT([yes])
 996                 USE_MLOCKALL=yes
 997                 ;;
 998         *-freebsd*)
 999                 APR_ADDTO(SWITCH_AM_CFLAGS, -fPIC)
1000                 APR_ADDTO(SWITCH_AM_CXXFLAGS, -fPIC)
1001                 AC_MSG_RESULT([no, broken for non-root users])
1002                 ;;
1003         *)
1004                 AC_MSG_RESULT([no])
1005                 ;;
1006         esac
1007
1008         #
1009         # setrlimit prerequisites
1010         #
1011         if test "x${USE_MLOCKALL}" = "xyes" -a \
1012                 "x${ac_cv_func_setrlimit}" = "xyes" -a \
1013                 "x${ac_cv_have_decl_RLIMIT_MEMLOCK}" = "xyes"
1014         then
1015                 AC_DEFINE([USE_SETRLIMIT],[1],[Use setrlimit to disable mlock limit for non-root users])
1016         fi
1017 fi
1018
1019 #
1020 # sched_setcheduler + round-robin scheduler prerequisites
1021 #
1022 if test "x${ac_cv_func_sched_setscheduler}" = "xyes" -a \
1023         "x${ac_cv_have_decl_SCHED_RR}" = "xyes"
1024 then
1025         AC_DEFINE([USE_SCHED_SETSCHEDULER],[1],[Enable round-robin scheduler using sched_setscheduler])
1026 fi
1027 #
1028 # xmlrpc-c checks
1029 #
1030
1031 AC_CHECK_FUNCS(setenv strtoll strtoull strtoq strtouq __strtoll __strtoull)
1032
1033 HAVE_LIBWWW_SSL_DEFINE=0
1034 AC_SUBST(HAVE_LIBWWW_SSL_DEFINE)
1035
1036 DIRECTORY_SEPARATOR="/"
1037 AC_SUBST(DIRECTORY_SEPARATOR)
1038
1039 va_list_is_array=no
1040 AC_MSG_CHECKING(whether va_list is an array)
1041 AC_TRY_COMPILE([
1042 #include <stdarg.h>
1043 ], [va_list list1, list2; list1 = list2;], ,
1044 va_list_is_array=yes)
1045 AC_MSG_RESULT($va_list_is_array)
1046 if test x"$va_list_is_array" = xyes; then
1047   VA_LIST_IS_ARRAY_DEFINE=1
1048 else
1049   VA_LIST_IS_ARRAY_DEFINE=0
1050 fi
1051 AC_SUBST(VA_LIST_IS_ARRAY_DEFINE)
1052
1053
1054 AC_MSG_CHECKING(whether compiler has __attribute__)
1055 AC_TRY_COMPILE(, [int x __attribute__((__unused__));],
1056 compiler_has_attribute=yes,
1057 compiler_has_attribute=no)
1058 AC_MSG_RESULT($compiler_has_attribute)
1059 if test x"$compiler_has_attribute" = xyes; then
1060     ATTR_UNUSED="__attribute__((__unused__))"
1061 else
1062     ATTR_UNUSED=
1063 fi
1064 AC_SUBST(ATTR_UNUSED)
1065
1066
1067 saved_CFLAGS="$CFLAGS"
1068 AC_CACHE_CHECK([whether compiler supports -Wdeclaration-after-statement], [ac_cv_gcc_declaration_after_statement], [
1069 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1070 AC_TRY_COMPILE([],[return 0;],[ac_cv_gcc_declaration_after_statement=yes],[ac_cv_gcc_declaration_after_statement=no])
1071 ])
1072 AC_MSG_RESULT($ac_cv_gcc_declaration_after_statement)
1073 if test x"$ac_cv_gcc_declaration_after_statement" = xyes; then
1074     APR_ADDTO(SWITCH_ANSI_CFLAGS, -Wdeclaration-after-statement)
1075 fi
1076 CFLAGS="$saved_CFLAGS"
1077
1078 if test "x${ax_cv_c_compiler_vendor}" = "xclang" ; then
1079      saved_CFLAGS="$CFLAGS"
1080      # Next check added for Xcode 5 and systems with clang 5 llvm 3.3 or above, extended offset must be off
1081      AC_CACHE_CHECK([whether compiler supports -Wextended-offsetof], [ac_cv_clang_extended_offsetof], [
1082        CFLAGS="$CFLAGS -Wno-extended-offsetof"
1083        AC_TRY_COMPILE([],[return 0;],[ac_cv_clang_extended_offsetof=yes],[ac_cv_clang_extended_offsetof=no])
1084      ])
1085      AC_MSG_RESULT($ac_cv_clang_extended_offsetof)
1086      if test x"$ac_cv_clang_extended_offsetof" = xyes; then
1087          APR_ADDTO(CFLAGS, -Wno-extended-offsetof)
1088      fi
1089      CFLAGS="$saved_CFLAGS"
1090 fi
1091
1092 # Tested and fixed lot of modules, but some are untested.  Will be added back when the core team decide it ready
1093 # Untested modules : mod_osp mod_soundtouch mod_sangoma_codec mod_dingaling mod_opal mod_h323 mod_khomp
1094 #                    mod_unimrcp mod_cepstral mod_erlang_event mod_snmp mod_perl mod_java mod_managed
1095 #
1096 #saved_CFLAGS="$CFLAGS"
1097 #AC_CACHE_CHECK([whether compiler supports -Wunused-but-set-variable], [ac_cv_gcc_unused_but_set_variable], [
1098 #CFLAGS="$CFLAGS -Wunused-but-set-variable"
1099 #AC_TRY_COMPILE([],[return 0;],[ac_cv_gcc_unused_but_set_variable=yes],[ac_cv_gcc_unused_but_set_variable=no])
1100 #])
1101 #AC_MSG_RESULT($ac_cv_gcc_unused_but_set_variable)
1102 #if test x"$ac_cv_gcc_unused_but_set_variable" = xyes; then
1103 #    APR_ADDTO(SWITCH_ANSI_CFLAGS, -Wunused-but-set-variable)
1104 #fi
1105 #CFLAGS="$saved_CFLAGS"
1106
1107 AC_C_BIGENDIAN(AC_DEFINE([SWITCH_BYTE_ORDER],__BIG_ENDIAN,[Big Endian]),AC_DEFINE([SWITCH_BYTE_ORDER],__LITTLE_ENDIAN,[Little Endian]))
1108
1109 # Checks for integer size
1110 AC_CHECK_SIZEOF(char, 1)
1111 AC_CHECK_SIZEOF(int, 4)
1112 AC_CHECK_SIZEOF(long, 4)
1113 AC_CHECK_SIZEOF(short, 2)
1114 AC_CHECK_SIZEOF(long long, 8)
1115 AC_TYPE_SIZE_T
1116 AC_CHECK_TYPE(ssize_t, int)
1117
1118 # Checks for pointer size
1119 AC_CHECK_SIZEOF(void*, 4)
1120
1121 if test "x$ac_cv_sizeof_voidp" != "x"; then
1122     voidp_size=$ac_cv_sizeof_voidp
1123 else
1124     AC_ERROR([Cannot determine size of void*])
1125 fi
1126
1127 if test "$ac_cv_sizeof_short" = "2"; then
1128     short_value=short
1129 fi
1130 if test "$ac_cv_sizeof_int" = "4"; then
1131     int_value=int
1132 fi
1133
1134 if test "$ac_cv_sizeof_int" = "8"; then
1135     int64_t_fmt='#define SWITCH_INT64_T_FMT "d"'
1136     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "u"'
1137     int64_value="int"
1138     long_value=int
1139 elif test "$ac_cv_sizeof_long" = "8"; then
1140     int64_t_fmt='#define SWITCH_INT64_T_FMT "ld"'
1141     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "lu"'
1142     int64_value="long"
1143     long_value=long
1144     case "$host" in
1145         *pc-solaris2*)
1146         ;;
1147         sparc-*-solaris2*)
1148         ;;
1149         *-solaris2*|*apple-darwin*|*-openbsd*)
1150             if test "$ac_cv_sizeof_long_long" = "8"; then
1151                 int64_t_fmt='#define SWITCH_INT64_T_FMT "lld"'
1152                 uint64_t_fmt='#define SWITCH_UINT64_T_FMT "llu"'
1153                 int64_value="long long"
1154                 long_value="long long"
1155             fi
1156         ;;
1157     esac
1158 elif test "$ac_cv_sizeof_long_long" = "8"; then
1159     int64_t_fmt='#define SWITCH_INT64_T_FMT "lld"'
1160     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "llu"'
1161     int64_value="long long"
1162     long_value="long long"
1163 elif test "$ac_cv_sizeof_longlong" = "8"; then
1164     int64_t_fmt='#define SWITCH_INT64_T_FMT "qd"'
1165     uint64_t_fmt='#define SWITCH_UINT64_T_FMT "qu"'
1166     int64_value="__int64"
1167     long_value="__int64"
1168 else
1169     AC_ERROR([could not detect a 64-bit integer type])
1170 fi
1171
1172 if test "$ac_cv_type_size_t" = "yes"; then
1173     size_t_value="size_t"
1174 else
1175     size_t_value="switch_int32_t"
1176 fi
1177
1178 if test "$ac_cv_type_ssize_t" = "yes"; then
1179     ssize_t_value="ssize_t"
1180 else
1181     ssize_t_value="switch_int32_t"
1182 fi
1183
1184 APR_CHECK_SIZEOF_EXTENDED([#include <sys/types.h>], ssize_t, 8)
1185
1186 if test "$ac_cv_sizeof_ssize_t" = "$ac_cv_sizeof_int"; then
1187     ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "d"'
1188 elif test "$ac_cv_sizeof_ssize_t" = "$ac_cv_sizeof_long"; then
1189     ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1190 else
1191     ssize_t_fmt='#error Can not determine the proper size for ssize_t'
1192 fi
1193
1194 APR_CHECK_SIZEOF_EXTENDED([#include <stddef.h>], size_t, 8)
1195
1196 if test "$ac_cv_sizeof_size_t" = "$ac_cv_sizeof_int"; then
1197     size_t_fmt='#define SWITCH_SIZE_T_FMT "d"'
1198 elif test "$ac_cv_sizeof_size_t" = "$ac_cv_sizeof_long"; then
1199     size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1200 else
1201     size_t_fmt='#define SWITCH_SIZE_T_FMT "zu"'
1202 fi
1203
1204 # Basically, we have tried to figure out the correct format strings
1205 # for SWITCH types which vary between platforms, but we don't always get
1206 # it right.  If you find that we don't get it right for your platform,
1207 # you can override our decision below.
1208 # NOTE: borrowed much of this logic from apr.
1209 case $host in
1210    s390*linux*)
1211        # uniquely, the 31-bit Linux/s390 uses "unsigned long int"
1212        # for size_t rather than "unsigned int":
1213        size_t_fmt='#define SWITCH_SIZE_T_FMT "lu"'
1214        ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1215        ;;
1216    *-os2*)
1217        size_t_fmt='#define SWITCH_SIZE_T_FMT "lu"'
1218        ;;
1219    *-openbsd*)
1220        size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1221        ;;
1222    *aix4*|*aix5*)
1223        ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1224        size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1225        ;;
1226     *beos*)
1227         ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1228         size_t_fmt='#define SWITCH_SIZE_T_FMT "ld"'
1229         ;;
1230     *apple-darwin*)
1231          ssize_t_fmt='#define SWITCH_SSIZE_T_FMT "ld"'
1232          size_t_fmt='#define SWITCH_SIZE_T_FMT "lu"'
1233         ;;
1234 esac
1235
1236 AC_SUBST(voidp_size)
1237 AC_SUBST(short_value)
1238 AC_SUBST(int_value)
1239 AC_SUBST(long_value)
1240 AC_SUBST(int64_value)
1241 AC_SUBST(size_t_value)
1242 AC_SUBST(ssize_t_value)
1243 AC_SUBST(int64_t_fmt)
1244 AC_SUBST(uint64_t_fmt)
1245 AC_SUBST(ssize_t_fmt)
1246 AC_SUBST(size_t_fmt)
1247
1248 case $host in
1249    *-openbsd*)
1250        # OpenBSD's gunzip and friends don't like -d because its redundant, only gzip does
1251        AC_PATH_PROGS(ZCAT, gzip)
1252        ;;
1253     *)
1254        AC_PATH_PROGS(ZCAT, gunzip gzcat gzip zcat)
1255        ;;
1256 esac
1257
1258 AC_PATH_PROGS(BZIP, bzip2)
1259 AC_PATH_PROGS(XZ, xz)
1260 AC_PATH_PROGS(TAR, gtar tar)
1261 AC_PATH_PROGS(WGET, wget)
1262 AC_PATH_PROGS(CURL, curl)
1263 GETLIB="cd $switch_srcdir/libs && ${SHELL} $switch_builddir/build/getlib.sh"
1264 AC_SUBST(GETLIB)
1265 GETG729="cd $switch_srcdir/libs && ${SHELL} $switch_builddir/build/getg729.sh"
1266 AC_SUBST(GETG729)
1267 GETSOUNDS="${SHELL} $switch_builddir/build/getsounds.sh"
1268 AC_SUBST(GETSOUNDS)
1269
1270 case $host in
1271    *-darwin*)
1272         path_push_unique PKG_CONFIG_PATH /usr/local/opt/curl/lib/pkgconfig
1273         path_push_unique PKG_CONFIG_PATH /usr/local/opt/sqlite/lib/pkgconfig/
1274         path_push_unique PKG_CONFIG_PATH /usr/local/opt/ldns/lib/pkgconfig/
1275         path_push_unique PKG_CONFIG_PATH /usr/local/opt/portaudio/lib/pkgconfig/
1276         path_push_unique PKG_CONFIG_PATH /usr/local/opt/ffmpeg/lib/pkgconfig/
1277        ;;
1278 esac
1279
1280 if ! (test -x "$PKG_CONFIG" || test -x "$(which pkg-config)"); then
1281   AC_MSG_ERROR([You need to install pkg-config to configure FreeSWITCH.])
1282 fi
1283
1284 # temporary workaround for Debian libldns-dev package bug
1285 if test "$cross_compiling" != "yes" && test -f /usr/lib/pkg-config/libldns.pc; then
1286   path_push_unique PKG_CONFIG_PATH /usr/lib/pkg-config
1287 fi
1288
1289 module_enabled() {
1290   grep -v -e "\#" -e "^\$" modules.conf | sed 's/|.*//' | sed -e "s|^.*/||" | grep "^${1}\$" >/dev/null
1291 }
1292
1293 AC_ARG_WITH(png,
1294   [AS_HELP_STRING([--without-png],
1295     [disable support for libpng])],
1296   [with_png="$withval"],
1297   [with_png="yes"])
1298 if test "$with_png" = "yes"; then
1299   PKG_CHECK_MODULES([LIBPNG], [libpng >= 1.6.16],[
1300     AM_CONDITIONAL([HAVE_PNG],[true])],[
1301       PKG_CHECK_MODULES([LIBPNG], [libpng16 >= 1.6.16],[
1302         AM_CONDITIONAL([HAVE_PNG],[true])],[
1303           PKG_CHECK_MODULES([LIBPNG], [libpng >= 1.2.49],[
1304             AM_CONDITIONAL([HAVE_PNG],[true])],[
1305             AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_PNG],[false])])])])
1306 else
1307   AM_CONDITIONAL([HAVE_PNG],[false])
1308 fi
1309
1310 AC_ARG_WITH(freetype,
1311   [AS_HELP_STRING([--without-freetype],
1312     [disable support for freetype])],
1313   [with_freetype="$withval"],
1314   [with_freetype="yes"])
1315 if test "$with_freetype" = "yes"; then
1316   PKG_CHECK_MODULES([FREETYPE], [freetype2 >= 2.4.9],[
1317     AM_CONDITIONAL([HAVE_FREETYPE],[true])],[
1318     AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_FREETYPE],[false])])
1319 else
1320   AM_CONDITIONAL([HAVE_FREETYPE],[false])
1321 fi
1322
1323 PKG_CHECK_MODULES([GUMBO], [gumbo >= 0.10.1],[
1324   AM_CONDITIONAL([HAVE_GUMBO],[true])],[
1325   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_GUMBO],[false])])
1326
1327 PKG_CHECK_MODULES([FVAD], [libfvad >= 1.0],[
1328   AM_CONDITIONAL([HAVE_FVAD],[true])],[
1329   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_FVAD],[false])])
1330
1331 PKG_CHECK_MODULES([TPL], [libtpl >= 1.5],[
1332   AC_DEFINE([HAVE_LIBTPL],[1],[Define to 1 if you have libtpl])],[
1333   AC_MSG_RESULT([no])])
1334
1335 PKG_CHECK_MODULES([SQLITE], [sqlite3 >= 3.6.20])
1336 PKG_CHECK_MODULES([CURL], [libcurl >= 7.19])
1337 PKG_CHECK_MODULES([PCRE], [libpcre >= 7.8])
1338 PKG_CHECK_MODULES([SPEEX], [speex >= 1.2rc1 speexdsp >= 1.2rc1])
1339 PKG_CHECK_MODULES([YAML], [yaml-0.1 >= 0.1.4],[
1340   AM_CONDITIONAL([HAVE_YAML],[true])],[
1341   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_YAML],[false])])
1342 PKG_CHECK_MODULES([PORTAUDIO], [portaudio-2.0 >= 19],[
1343   AM_CONDITIONAL([HAVE_PORTAUDIO],[true])],[
1344   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_PORTAUDIO],[false])])
1345 PKG_CHECK_MODULES([LDNS], [libldns-fs >= 1.6.6],[
1346   AM_CONDITIONAL([HAVE_LDNS],[true])],[
1347 PKG_CHECK_MODULES([LDNS], [libldns >= 1.6.6],[
1348   AM_CONDITIONAL([HAVE_LDNS],[true])],[
1349   AC_CHECK_LIB([ldns], [ldns_str2rdf_a], [LDNS_LIBS=-lldns])
1350   AS_IF([test -z "$LDNS_LIBS"],[
1351     if module_enabled mod_enum; then
1352       AC_MSG_ERROR([You need to either install libldns-dev or disable mod_enum in modules.conf])
1353     else
1354       AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_LDNS],[false])
1355     fi],[
1356     AM_CONDITIONAL([HAVE_LDNS],[true])])])])
1357 PKG_CHECK_MODULES([SNDFILE], [sndfile >= 1.0.20],[
1358   AM_CONDITIONAL([HAVE_SNDFILE],[true])],[
1359   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SNDFILE],[false])])
1360
1361 PKG_CHECK_MODULES([MPG123], [libmpg123 >= 1.16.0],[
1362   AM_CONDITIONAL([HAVE_MPG123],[true])],[
1363   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MPG123],[false])])
1364
1365 PKG_CHECK_MODULES([SHOUT], [shout >= 2.2.2],[
1366   AM_CONDITIONAL([HAVE_SHOUT],[true])],[
1367   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SHOUT],[false])])
1368
1369 mp3lame=false
1370 AC_CHECK_LIB([mp3lame], [lame_init],[
1371   AC_CHECK_HEADER([lame/lame.h],[
1372     mp3lame=true
1373     AC_SUBST([MP3LAME_LIBS], [-lmp3lame])
1374     AC_SUBST([MP3LAME_CFLAGS], [$CPPFLAGS])])])
1375 AM_CONDITIONAL([HAVE_MP3LAME],[$mp3lame])
1376
1377 PKG_CHECK_MODULES([AVCODEC], [libavcodec >= 53.35.0],[
1378   AM_CONDITIONAL([HAVE_AVCODEC],[true])],[
1379   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVCODEC],[false])])
1380
1381 PKG_CHECK_MODULES([X264], [x264 >= 0.142.2431],[
1382   AM_CONDITIONAL([HAVE_X264],[true])],[
1383   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_X264],[false])])
1384
1385 PKG_CHECK_MODULES([AVFORMAT], [libavformat >= 53.21.1],[
1386   AM_CONDITIONAL([HAVE_AVFORMAT],[true])],[
1387   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVFORMAT],[false])])
1388
1389 PKG_CHECK_MODULES([AVUTIL], [libavutil >= 54.3.0],[
1390   AM_CONDITIONAL([HAVE_AVUTIL],[true])],[
1391   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVUTIL],[false])])
1392
1393 PKG_CHECK_MODULES([AVRESAMPLE], [libavresample >= 2.1.0],[
1394   AM_CONDITIONAL([HAVE_AVRESAMPLE],[true])],[
1395   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AVRESAMPLE],[false])])
1396
1397 PKG_CHECK_MODULES([SWRESAMPLE], [libswresample >= 2.1.0],[
1398   AM_CONDITIONAL([HAVE_SWRESAMPLE],[true])],[
1399   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SWRESAMPLE],[false])])
1400
1401 PKG_CHECK_MODULES([SWSCALE], [libswscale >= 3.0.0],[
1402   AM_CONDITIONAL([HAVE_SWSCALE],[true])],[
1403   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SWSCALE],[false])])
1404
1405 PKG_CHECK_MODULES([VLC], [libvlc >= 2.1.0],[
1406   AM_CONDITIONAL([HAVE_VLC],[true])],[
1407   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_VLC],[false])])
1408
1409 PKG_CHECK_MODULES([OPENCV], [opencv >= 2.4.5],[
1410   AM_CONDITIONAL([HAVE_OPENCV],[true])],[
1411   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPENCV],[false])])
1412
1413 PKG_CHECK_MODULES([OPUSFILE_DECODE], [opusfile >= 0.5],[
1414    AM_CONDITIONAL([HAVE_OPUSFILE_DECODE],[true])],[
1415    AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPUSFILE_DECODE],[false])])
1416 PKG_CHECK_MODULES([OPUSFILE_ENCODE], [libopusenc >= 0.1],[
1417    AM_CONDITIONAL([HAVE_OPUSFILE_ENCODE],[true])],[
1418    AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPUSFILE_ENCODE],[false])])
1419
1420
1421 PKG_CHECK_MODULES([MAGICK], [ImageMagick >= 6.0.0],[
1422   AM_CONDITIONAL([HAVE_MAGICK],[true])],[
1423   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MAGICK],[false])])
1424
1425 PKG_CHECK_MODULES([MAGICK7], [ImageMagick >= 7.0.0],[
1426   AM_CONDITIONAL([HAVE_MAGICK7],[true])],[
1427   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MAGICK7],[false])])
1428
1429 PKG_CHECK_MODULES([SILK], [silk >= 1.0.8],[
1430   AM_CONDITIONAL([HAVE_SILK],[true])],[
1431   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SILK],[false])])
1432
1433 PKG_CHECK_MODULES([BROADVOICE], [broadvoice >= 0.1.0],[
1434   AM_CONDITIONAL([HAVE_BROADVOICE],[true])],[
1435   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_BROADVOICE],[false])])
1436
1437 PKG_CHECK_MODULES([ILBC], [ilbc2 >= 0.0.1],[
1438   AM_CONDITIONAL([HAVE_ILBC],[true])],[
1439     PKG_CHECK_MODULES([ILBC], [ilbc >= 0.0.1],[
1440       AM_CONDITIONAL([HAVE_ILBC],[true])],[
1441       AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_ILBC],[false])])])
1442
1443 PKG_CHECK_MODULES([G7221], [g722_1 >= 0.2.0],[
1444   AM_CONDITIONAL([HAVE_G7221],[true])],[
1445   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_G7221],[false])])
1446
1447 codec2="true"
1448 PKG_CHECK_MODULES([CODEC2], [codec2 >= 0.5],[],[
1449   AC_CHECK_LIB([codec2], [codec2_create],[
1450     AC_CHECK_HEADERS([codec2/codec2.h],[
1451       CODEC2_LIBS="-lcodec2"
1452       CODEC2_CFLAGS=""
1453     ], [
1454     codec2="false"
1455     if module_enabled mod_codec2; then
1456         AC_MSG_ERROR([You must install libcodec2-dev to build mod_codec2])
1457       else
1458         AC_MSG_RESULT([no])
1459       fi
1460     ])
1461   ])
1462 ])
1463
1464 AM_CONDITIONAL([HAVE_CODEC2],[$codec2])
1465
1466
1467 PKG_CHECK_MODULES([OPUS], [opus >= 1.1],[
1468   AM_CONDITIONAL([HAVE_OPUS],[true])],[
1469   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_OPUS],[false])])
1470
1471 PKG_CHECK_MODULES([SOUNDTOUCH], [soundtouch >= 1.7.0],[
1472   AM_CONDITIONAL([HAVE_SOUNDTOUCH],[true])],[
1473   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SOUNDTOUCH],[false])])
1474
1475 flite="true"
1476 PKG_CHECK_MODULES([FLITE], [flite >= 2],[],[
1477   AC_CHECK_LIB([flite], [flite_init],[
1478     AC_CHECK_HEADERS([flite/flite.h],[
1479       FLITE_LIBS="-lflite -lflite_cmu_grapheme_lang -lflite_cmu_grapheme_lex -lflite_cmu_indic_lang -lflite_cmu_indic_lex -lflite_cmulex -lflite_cmu_time_awb -lflite_cmu_us_awb -lflite_cmu_us_kal16 -lflite_cmu_us_kal -lflite_cmu_us_rms -lflite_cmu_us_slt -lflite_usenglish"
1480       FLITE_CFLAGS=""
1481     ], [
1482     flite="false"
1483     if module_enabled mod_flite; then
1484         AC_MSG_ERROR([You must install libflite-dev to build mod_flite])
1485       else
1486         AC_MSG_RESULT([no])
1487       fi
1488     ])
1489   ])
1490 ])
1491
1492 AM_CONDITIONAL([HAVE_FLITE],[$flite])
1493
1494 PKG_CHECK_MODULES([MONGOC], [libmongoc-1.0 >= 1.0.8],[
1495   AM_CONDITIONAL([HAVE_MONGOC],[true])],[
1496   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_MONGOC],[false])])
1497
1498 PKG_CHECK_MODULES([MEMCACHED], [libmemcached >= 0.31],[
1499   AM_CONDITIONAL([HAVE_MEMCACHED],[true])
1500   MEMCACHED_LIBS="${MEMCACHED_LIBS} -lpthread"
1501   save_LIBS="${LIBS}"
1502   save_CPPFLAGS="${CPPFLAGS}"
1503   LIBS="${MEMCACHED_LIBS}"
1504   CPPFLAGS="${MEMCACHED_CFLAGS}"
1505   AC_CHECK_FUNCS([memcached_server_name memcached_stat_execute])
1506   AC_CHECK_TYPES([memcached_instance_st*],,, [[#include <libmemcached/memcached.h>]])
1507   LIBS="${save_LIBS}"
1508   CPPFLAGS="${save_CPPFLAGS}"
1509 ],[
1510   AC_MSG_RESULT([no])
1511   AM_CONDITIONAL([HAVE_MEMCACHED],[false])
1512 ])
1513
1514 PKG_CHECK_MODULES([V8FS_STATIC], [v8-6.1_static >= 6.1.298],[
1515   AM_CONDITIONAL([HAVE_V8FS],[true])],[
1516   PKG_CHECK_MODULES([V8FS_STATIC], [v8fs_static >= 6.1.298],[
1517     AM_CONDITIONAL([HAVE_V8FS],[true])],[
1518     PKG_CHECK_MODULES([V8FS_STATIC], [v8 >= 6.1.298],[
1519       AM_CONDITIONAL([HAVE_V8FS],[true])],[
1520       if module_enabled mod_v8; then
1521         AC_MSG_ERROR([You need to either install libv8-6.1-dev (>= 6.1.298), libv8fs-dev (>= 6.1.298) or disable mod_v8 in modules.conf])
1522       else
1523         AC_MSG_RESULT([no])
1524         AM_CONDITIONAL([HAVE_V8FS],[false])
1525       fi
1526     ])
1527   ])
1528 ])
1529
1530 PKG_CHECK_MODULES([KS], [libks >= 1.1.0],[
1531   AM_CONDITIONAL([HAVE_KS],[true])],[
1532   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_KS],[false])])
1533
1534 PKG_CHECK_MODULES([SIGNALWIRE_CLIENT], [signalwire_client >= 1.0.0],[
1535   AM_CONDITIONAL([HAVE_SIGNALWIRE_CLIENT],[true])],[
1536   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SIGNALWIRE_CLIENT],[false])])
1537
1538 PKG_CHECK_MODULES([AMQP], [librabbitmq >= 0.5.2],[
1539   AM_CONDITIONAL([HAVE_AMQP],[true])],[
1540   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_AMQP],[false])])
1541
1542 PKG_CHECK_MODULES([H2O], [libh2o-evloop >= 0.11.0],[
1543   AM_CONDITIONAL([HAVE_H2O],[true])],[
1544   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_H2O],[false])])
1545
1546 PKG_CHECK_MODULES([BROTLIENC], [libbrotlienc >= 0.1.0],[
1547   AM_CONDITIONAL([HAVE_BROTLIENC],[true])],[
1548   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_BROTLIENC],[false])])
1549
1550 PKG_CHECK_MODULES([BROTLIDEC], [libbrotlidec >= 0.1.0],[
1551   AM_CONDITIONAL([HAVE_BROTLIDEC],[true])],[
1552   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_BROTLIDEC],[false])])
1553
1554 PKG_CHECK_MODULES([TAP], [tap >= 0.1.0],[
1555   AM_CONDITIONAL([HAVE_TAP],[true])],[
1556   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_TAP],[false])])
1557
1558 PKG_CHECK_MODULES([SMPP34], [libsmpp34 >= 1.10],[
1559   AM_CONDITIONAL([HAVE_SMPP34],[true])],[
1560   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_SMPP34],[false])])
1561
1562 PKG_CHECK_MODULES([HIREDIS], [hiredis >= 0.10.0],[
1563   AM_CONDITIONAL([HAVE_HIREDIS],[true])],[
1564   AC_MSG_RESULT([no]); AM_CONDITIONAL([HAVE_HIREDIS],[false])])
1565
1566 AC_ARG_ENABLE(core-libedit-support,
1567   [AS_HELP_STRING([--disable-core-libedit-support], [Compile without libedit Support])])
1568
1569 AS_IF([test "x$enable_core_libedit_support" != "xno"],[
1570   PKG_CHECK_MODULES([LIBEDIT], [libedit >= 2.11],,[
1571     AC_MSG_RESULT([no])
1572     AC_CHECK_LIB([edit], [el_line], [LIBEDIT_LIBS=-ledit])
1573     AC_CHECK_LIB([edit], [el_cursor], [ac_cv_has_el_cursor=yes])
1574     AC_CHECK_HEADER([histedit.h], [], [unset LIBEDIT_LIBS])
1575     AS_IF([test "x$LIBEDIT_LIBS" = "x"], [
1576       AC_MSG_ERROR([You need to either install libedit-dev (>= 2.11) or configure with --disable-core-libedit-support])
1577       ])])])
1578
1579 dnl ---------------------------------------------------------------------------
1580 dnl - OpenLDAP SDK
1581 dnl ---------------------------------------------------------------------------
1582
1583 AC_CHECK_LIB(ldap, ldap_search, with_ldap=yes)
1584 dnl Check for other libraries we need to link with to get the main routines.
1585 test "$with_ldap" != "yes" && { AC_CHECK_LIB(ldap, ldap_open, [with_ldap=yes with_ldap_lber=yes], , -llber) }
1586 test "$with_ldap" != "yes" && { AC_CHECK_LIB(ldap, ldap_open, [with_ldap=yes with_ldap_lber=yes with_ldap_krb=yes], , -llber -lkrb) }
1587 test "$with_ldap" != "yes" && { AC_CHECK_LIB(ldap, ldap_open, [with_ldap=yes with_ldap_lber=yes with_ldap_krb=yes with_ldap_des=yes], , -llber -lkrb -ldes) }
1588 test "$with_ldap_lber" != "yes" && { AC_CHECK_LIB(lber, ber_pvt_opt_on, with_ldap_lber=yes) }
1589
1590 if test "$with_ldap" = "yes"; then
1591    if test "$with_ldap_des" = "yes" ; then
1592       OPENLDAP_LIBS="${OPENLDAP_LIBS} -ldes"
1593    fi
1594    if test "$with_ldap_krb" = "yes" ; then
1595       OPENLDAP_LIBS="${OPENLDAP_LIBS} -lkrb"
1596    fi
1597    if test "$with_ldap_lber" = "yes" ; then
1598       OPENLDAP_LIBS="${OPENLDAP_LIBS} -llber"
1599    fi
1600    OPENLDAP_LIBS="${OPENLDAP_LIBS} -lldap"
1601 fi
1602
1603 AM_CONDITIONAL([HAVE_LDAP],[test "x$with_ldap" = "xyes"])
1604
1605 AC_SUBST(OPENLDAP_LIBS)
1606
1607 AS_IF([test "x$enable_core_libedit_support" != "xno"], [
1608   # If making changes here, don't forget to run autoheader and
1609   # update libs/esl/src/include/esl_config_auto.h.in manually.
1610   AC_DEFINE([HAVE_LIBEDIT], [1], [Define to 1 if you have libedit is available])
1611 if test x$ac_cv_has_el_cursor = xyes; then
1612   AC_DEFINE([HAVE_EL_CURSOR], [1], [Define to 1 if you have libedit el_cursor support])
1613 fi
1614   save_LIBS="${LIBS}"
1615   save_CPPFLAGS="${CPPFLAGS}"
1616   LIBS="${LIBEDIT_LIBS}"
1617   CPPFLAGS="${LIBEDIT_CFLAGS}"
1618   AC_CHECK_DECLS([EL_PROMPT_ESC, EL_REFRESH],,, [[#include <histedit.h>]])
1619   AC_CHECK_FUNCS([el_wset])
1620   LIBS="${save_LIBS}"
1621   CPPFLAGS="${save_CPPFLAGS}"
1622 ])
1623
1624 SAC_OPENSSL
1625
1626 if test x$HAVE_OPENSSL = x1; then
1627         openssl_CFLAGS="$openssl_CFLAGS -DHAVE_OPENSSL";
1628         APR_ADDTO(SWITCH_AM_CFLAGS, -DHAVE_OPENSSL)
1629         AC_CHECK_LIB(ssl, SSL_CTX_set_tlsext_use_srtp, AC_DEFINE_UNQUOTED(HAVE_OPENSSL_DTLS_SRTP, 1, HAVE_OPENSSL_DTLS_SRTP), AC_MSG_ERROR([OpenSSL >= 1.0.1e and associated developement headers required]))
1630         AC_CHECK_LIB(ssl, DTLSv1_method, AC_DEFINE_UNQUOTED(HAVE_OPENSSL_DTLS, 1, HAVE_OPENSSL_DTLS), AC_MSG_ERROR([OpenSSL >= 1.0.1e and associaed developement headers required]))
1631         AC_CHECK_LIB(ssl, DTLSv1_2_method, AC_DEFINE_UNQUOTED(HAVE_OPENSSL_DTLSv1_2_method, 1, [DTLS version 1.2 is available]))
1632 else
1633         AC_MSG_ERROR([OpenSSL >= 1.0.1e and associated developement headers required])
1634 fi
1635
1636 AX_CHECK_JAVA
1637
1638 AM_CONDITIONAL([HAVE_ODBC],[test "x$enable_core_odbc_support" != "xno"])
1639 AM_CONDITIONAL([HAVE_MYSQL],[test "$found_mysql" = "yes"])
1640
1641 #
1642 # perl checks
1643 #
1644
1645 AC_CHECK_PROG(PERL,perl,[ac_cv_have_perl=yes],[ac_cv_have_perl=no])
1646
1647 # -a "x$ac_cv_have_EXTERN_h" != "xno"
1648
1649 if test "x$ac_cv_have_perl" != "xno"; then
1650    PERL=perl
1651    PERL_SITEDIR="`$PERL -MConfig -e 'print $Config{archlib}'`"
1652    PERL_LIBDIR="-L`$PERL -MConfig -e 'print $Config{archlib}'`/CORE"
1653    PERL_LIBS="`$PERL -MConfig -e 'print $Config{libs}'`"
1654    PERL_CFLAGS="-w -DMULTIPLICITY `$PERL -MExtUtils::Embed -e ccopts | sed -e 's|-arch x86_64 -arch i386||'` -DEMBED_PERL"
1655    PERL_LDFLAGS="`$PERL -MExtUtils::Embed -e ldopts| sed -e 's|-arch x86_64 -arch i386||'`"
1656    PERL_INC="`$PERL -MExtUtils::Embed -e perl_inc`"
1657
1658    save_CFLAGS="$CFLAGS"
1659    CFLAGS="$PERL_CFLAGS"
1660    AC_CHECK_HEADER([EXTERN.h], [ac_cv_have_EXTERN_h=yes], [ac_cv_have_EXTERN_h=no], [[#include <EXTERN.h>
1661 # include <perl.h>]])
1662    CFLAGS="$save_CFLAGS"
1663
1664    save_LDFLAGS="$LDFLAGS"
1665    LDFLAGS="$PERL_LDFLAGS"
1666    AC_CHECK_LIB([perl], [perl_alloc], ac_cv_use_libperl=yes, ac_cv_use_libperl=no)
1667    LDFLAGS="$save_LDFLAGS"
1668
1669    AC_SUBST(PERL_SITEDIR)
1670    AC_SUBST(PERL_LIBDIR)
1671    AC_SUBST(PERL_LIBS)
1672    AC_SUBST(PERL_CFLAGS)
1673    AC_SUBST(PERL_LDFLAGS)
1674    AC_SUBST(PERL_INC)
1675 fi
1676
1677 AM_CONDITIONAL([HAVE_PERL],[test "x$ac_cv_have_perl" != "xno" -a "x$ac_cv_have_EXTERN_h" != "xno" -a "x$ac_cv_use_libperl" != "xno"])
1678
1679 #
1680 # php checks
1681 #
1682
1683 AC_CHECK_PROG(PHP,php,[ac_cv_have_php=yes],[ac_cv_have_php=no])
1684 AC_CHECK_PROG(PHP_CONFIG,php-config,[ac_cv_have_php_config=yes],[ac_cv_have_php_config=no])
1685 AM_CONDITIONAL([HAVE_PHP],[test "x$ac_cv_have_php" != "xno" -a "x$ac_cv_have_php_config" != "xno"])
1686
1687 if test "x$ac_cv_have_php" != "xno" -a "x$ac_cv_have_php_config" != "xno"; then
1688    PHP=php
1689    PHP_CONFIG=php-config
1690    PHP_LDFLAGS="`$PHP_CONFIG --ldflags`"
1691    PHP_LIBS="`$PHP_CONFIG --libs | sed -r 's/ ?-l(bz2|pcre2-8|xml2|gssapi_krb5|krb5|k5crypto|com_err|history|z|readline|gmp|ssl|crypto|argon2|sodium)//g'`"
1692    PHP_EXT_DIR="`$PHP_CONFIG --extension-dir`"
1693    PHP_INC_DIR="`$PHP -r 'echo ini_get("include_path");' | cut -d: -f2`"
1694    PHP_INI_DIR="`$PHP_CONFIG --configure-options | tr " " "\n" | grep -- --with-config-file-scan-dir | cut -f2 -d=`"
1695    PHP_CFLAGS="`$PHP_CONFIG --includes`"
1696    AC_SUBST(PHP_LDFLAGS)
1697    AC_SUBST(PHP_LIBS)
1698    AC_SUBST(PHP_EXT_DIR)
1699    AC_SUBST(PHP_INC_DIR)
1700    AC_SUBST(PHP_INI_DIR)
1701    AC_SUBST(PHP_CFLAGS)
1702 fi
1703
1704 #
1705 # Python checks for mod_python
1706 #
1707 AC_ARG_WITH(
1708         [python],
1709         [AS_HELP_STRING([--with-python], [Use system provided version of python (default: try)])],
1710         [with_python="$withval"],
1711         [with_python="try"]
1712 )
1713
1714 if test "$with_python" != "no"
1715 then
1716         save_CFLAGS="$CFLAGS"
1717         save_LIBS="$LIBS"
1718
1719         if test "$with_python" != "yes" -a "$with_python" != "try" ; then
1720                 AC_MSG_CHECKING([for python])
1721                 if test ! -x "$with_python" ; then
1722                         AC_MSG_ERROR([Specified python does not exist or is not executable: $with_python])
1723                 fi
1724                 AC_MSG_RESULT([$with_python])
1725                 AC_SUBST([PYTHON], ["$with_python"])
1726         else
1727                 AC_PATH_PROG([PYTHON], ["python"], ["no"], ["$PATH:/usr/bin:/usr/local/bin"])
1728         fi
1729
1730         if test "$PYTHON" != "no" ; then
1731                 AC_MSG_CHECKING([python version])
1732                 PYTHON_VER="`$PYTHON -V 2>&1 | cut -d' ' -f2`"
1733
1734                 if test -z "$PYTHON_VER" ; then
1735                         AC_MSG_ERROR([Unable to detect python version])
1736                 fi
1737                 AC_MSG_RESULT([$PYTHON_VER])
1738
1739                 AC_MSG_CHECKING([for python distutils])
1740                 python_result="`$PYTHON -c 'import distutils;' 2>&1`"
1741                 if test -z "$python_result" ; then
1742                         python_has_distutils="yes"
1743                 else
1744                         python_has_distutils="no"
1745                 fi
1746                 AC_MSG_RESULT([$python_has_distutils])
1747
1748                 if test "$python_has_distutils" != "no" ; then
1749                         AC_MSG_CHECKING([location of site-packages])
1750
1751                         PYTHON_SITE_DIR="`$PYTHON -c 'from distutils import sysconfig; print(sysconfig.get_python_lib(0));'`"
1752
1753                         if test -z "$PYTHON_SITE_DIR" ; then
1754                                 AC_MSG_ERROR([Unable to detect python site-packages path])
1755                         elif test ! -d "$PYTHON_SITE_DIR" ; then
1756                                 AC_MSG_ERROR([Path $PYTHON_SITE_DIR returned by python does not exist!])
1757                         fi
1758                         AC_MSG_RESULT([$PYTHON_SITE_DIR])
1759                         AC_SUBST([PYTHON_SITE_DIR], [$PYTHON_SITE_DIR])
1760
1761                         #
1762                         # python distutils found, get settings from python directly
1763                         #
1764                         PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; flags = [[\"-I\" + sysconfig.get_python_inc(0), \"-I\" + sysconfig.get_python_inc(1), \" \".join(sysconfig.get_config_var(\"CFLAGS\").split())]]; print(\" \".join(flags));' | sed -e 's/-arch i386//g;s/-arch x86_64//g'`"
1765                         PYTHON_LDFLAGS="`$PYTHON -c 'from distutils import sysconfig; libs = sysconfig.get_config_var(\"LIBS\").split() + sysconfig.get_config_var(\"SYSLIBS\").split(); libs.append(\"-lpython\"+sysconfig.get_config_var(\"VERSION\")); print(\" \".join(libs));'`"
1766                         PYTHON_LIB="`$PYTHON -c 'from distutils import sysconfig; print(\"python\" + sysconfig.get_config_var(\"VERSION\"));'`"
1767                         PYTHON_LIBDIR="`$PYTHON -c 'from distutils import sysconfig; print(sysconfig.get_config_var(\"LIBDIR\"));'`"
1768
1769                         # handle python being installed into /usr/local
1770                         AC_MSG_CHECKING([python libdir])
1771                         if test -z "`echo $PYTHON_LIBDIR | grep "/usr/lib"`" ; then
1772                                 PYTHON_LDFLAGS="-L$PYTHON_LIBDIR $PYTHON_LDFLAGS"
1773                                 LIBS="-L$PYTHON_LIBDIR $LIBS"
1774                         fi
1775                         AC_MSG_RESULT([$PYTHON_LIBDIR])
1776
1777                         # check libpython
1778                         AC_CHECK_LIB([$PYTHON_LIB], [main], [has_libpython="yes"], [has_libpython="no"])
1779
1780                         if test "$has_libpython" = "no" ; then
1781                                 AS_IF([test "$with_python" = "try"],
1782                                         [AC_MSG_WARN([$PYTHON_LIB is unusable])],
1783                                         [AC_MSG_ERROR([$PYTHON_LIB is unusable])]
1784                                 )
1785                         fi
1786
1787                         # check whether system libpython is usable and has threads support
1788                         CFLAGS="$PYTHON_CFLAGS"
1789                         LIBS="$PYTHON_LDFLAGS"
1790                         AC_CHECK_FUNC([PyThread_init_thread], [python_has_threads="yes"], [python_has_threads="no"])
1791
1792                         if test "$python_has_threads" = "no"; then
1793                                 AS_IF([test "$with_python" = "try"],
1794                                         [AC_MSG_WARN([Your python lacks threads support, can not build mod_python])],
1795                                         [AC_MSG_ERROR([Your python lacks threads support, can not build mod_python])]
1796                                 )
1797                         else
1798                                 AC_MSG_NOTICE([Your python seems OK, do not forget to enable mod_python in modules.conf])
1799                                 AC_SUBST([PYTHON_CFLAGS],  [$PYTHON_CFLAGS])
1800                                 AC_SUBST([PYTHON_LDFLAGS], [$PYTHON_LDFLAGS])
1801                         fi
1802                 else
1803                         AS_IF([test "$with_python" = "try"],
1804                                 [AC_MSG_WARN([Could not find or use python distutils module: $python_result])],
1805                                 [AC_MSG_ERROR([Could not find or use python distutils module: $python_result])]
1806                         )
1807                 fi
1808
1809                 LIBS="$save_LIBS"
1810                 CFLAGS="$save_CFLAGS"
1811
1812                 unset python_has_threads
1813                 unset python_has_distutils
1814                 unset python_result
1815         else
1816                 AS_IF([test "$with_python" = "try"],
1817                         [AC_MSG_WARN([Could not find python, mod_python will not build, use --with-python to specify the location])],
1818                         [AC_MSG_ERROR([Could not find python, use --with-python to specify the location])]
1819                 )
1820         fi
1821 else
1822         AC_MSG_WARN([python support disabled, building mod_python will fail!])
1823 fi
1824
1825 #
1826 # SNMP checks for mod_snmp
1827 #
1828 AC_PATH_PROG([NET_SNMP_CONFIG], [net-snmp-config], [no])
1829 if test "$NET_SNMP_CONFIG" != "no"; then
1830         AC_MSG_CHECKING([for Net-SNMP libraries via net-snmp-config])
1831         SNMP_LIBS="`$NET_SNMP_CONFIG --base-agent-libs`"
1832 else
1833         # net-snmp-config not in path, fallback to sensible defaults
1834         SNMP_LIBS="-lnetsnmpmibs -lnetsnmpagent -lnetsnmp"
1835 fi
1836
1837 # fix linking error on Solaris patched Net-SNMP
1838 AS_CASE([$host], [*-solaris2*], [AC_CHECK_LIB([dladm], [dladm_open], [SNMP_LIBS="$SNMP_LIBS -ldladm"])])
1839 AC_SUBST(SNMP_LIBS)
1840
1841 CHECK_ERLANG
1842
1843 #  Enable clang address sanitizer bit build
1844 AC_ARG_ENABLE(address_sanitizer,
1845   [AC_HELP_STRING([--enable-address-sanitizer],[build with address sanitizer])],
1846   [enable_address_sanitizer="$enable_address_sanitizer"],
1847   [enable_address_sanitizer="no"])
1848
1849 if test "${enable_address_sanitizer}" = "yes"; then
1850   APR_ADDTO(CFLAGS, -fsanitize=address -fno-omit-frame-pointer -fstack-protector-strong)
1851   APR_ADDTO(CXXFLAGS, -fsanitize=address -fno-omit-frame-pointer -fstack-protector-strong)
1852   APR_ADDTO(LDFLAGS, -fsanitize=address)
1853 fi
1854
1855 AC_ARG_ENABLE(,
1856   [AC_HELP_STRING([--enable-pool-sanitizer],[build with sanitizer friendly pool behavior])],
1857   [enable_pool_sanitizer="$enable_pool_sanitizer"],
1858   [enable_pool_sanitizer="no"])
1859
1860 if test "${enable_pool_sanitizer}" = "yes"; then
1861   APR_ADDTO(CFLAGS, -DDESTROY_POOLS)
1862   ac_configure_args="$ac_configure_args --enable-pool-debug=yes"
1863 fi
1864
1865 # we never use this, and hard setting it will make cross compile work better
1866 ac_cv_file_dbd_apr_dbd_mysql_c=no
1867
1868 AC_CONFIG_FILES([Makefile
1869                 build/Makefile
1870                 tests/unit/Makefile
1871                 src/Makefile
1872                 src/mod/Makefile
1873                 src/mod/applications/mod_abstraction/Makefile
1874                 src/mod/applications/mod_avmd/Makefile
1875                 src/mod/applications/mod_bert/Makefile
1876                 src/mod/applications/mod_blacklist/Makefile
1877                 src/mod/applications/mod_callcenter/Makefile
1878                 src/mod/applications/mod_cidlookup/Makefile
1879                 src/mod/applications/mod_cluechoo/Makefile
1880                 src/mod/applications/mod_commands/Makefile
1881                 src/mod/applications/mod_conference/Makefile
1882                 src/mod/applications/mod_curl/Makefile
1883                 src/mod/applications/mod_cv/Makefile
1884                 src/mod/applications/mod_db/Makefile
1885                 src/mod/applications/mod_directory/Makefile
1886                 src/mod/applications/mod_distributor/Makefile
1887                 src/mod/applications/mod_dptools/Makefile
1888                 src/mod/applications/mod_easyroute/Makefile
1889                 src/mod/applications/mod_enum/Makefile
1890                 src/mod/applications/mod_esf/Makefile
1891                 src/mod/applications/mod_esl/Makefile
1892                 src/mod/applications/mod_expr/Makefile
1893                 src/mod/applications/mod_fifo/Makefile
1894                 src/mod/applications/mod_fsk/Makefile
1895                 src/mod/applications/mod_fsv/Makefile
1896                 src/mod/applications/mod_hash/Makefile
1897                 src/mod/applications/mod_hiredis/Makefile
1898                 src/mod/applications/mod_httapi/Makefile
1899                 src/mod/applications/mod_http_cache/Makefile
1900                 src/mod/applications/mod_ladspa/Makefile
1901                 src/mod/applications/mod_lcr/Makefile
1902                 src/mod/applications/mod_limit/Makefile
1903                 src/mod/applications/mod_memcache/Makefile
1904                 src/mod/applications/mod_mongo/Makefile
1905                 src/mod/applications/mod_mp4/Makefile
1906                 src/mod/applications/mod_mp4v2/Makefile
1907                 src/mod/applications/mod_nibblebill/Makefile
1908                 src/mod/applications/mod_oreka/Makefile
1909                 src/mod/applications/mod_osp/Makefile
1910                 src/mod/applications/mod_prefix/Makefile
1911                 src/mod/applications/mod_rad_auth/Makefile
1912                 src/mod/applications/mod_random/Makefile
1913                 src/mod/applications/mod_redis/Makefile
1914                 src/mod/applications/mod_rss/Makefile
1915                 src/mod/applications/mod_skel/Makefile
1916                 src/mod/applications/mod_signalwire/Makefile
1917                 src/mod/applications/mod_sms/Makefile
1918                 src/mod/applications/mod_sms_flowroute/Makefile
1919                 src/mod/applications/mod_snapshot/Makefile
1920                 src/mod/applications/mod_snom/Makefile
1921                 src/mod/applications/mod_sonar/Makefile
1922                 src/mod/applications/mod_soundtouch/Makefile
1923                 src/mod/applications/mod_spandsp/Makefile
1924                 src/mod/applications/mod_spy/Makefile
1925                 src/mod/applications/mod_stress/Makefile
1926                 src/mod/applications/mod_test/Makefile
1927                 src/mod/applications/mod_translate/Makefile
1928                 src/mod/applications/mod_valet_parking/Makefile
1929                 src/mod/applications/mod_vmd/Makefile
1930                 src/mod/applications/mod_voicemail/Makefile
1931                 src/mod/applications/mod_voicemail_ivr/Makefile
1932                 src/mod/asr_tts/mod_cepstral/Makefile
1933                 src/mod/asr_tts/mod_flite/Makefile
1934                 src/mod/asr_tts/mod_pocketsphinx/Makefile
1935                 src/mod/asr_tts/mod_tts_commandline/Makefile
1936                 src/mod/asr_tts/mod_unimrcp/Makefile
1937                 src/mod/codecs/mod_amr/Makefile
1938                 src/mod/codecs/mod_amrwb/Makefile
1939                 src/mod/codecs/mod_b64/Makefile
1940                 src/mod/codecs/mod_bv/Makefile
1941                 src/mod/codecs/mod_clearmode/Makefile
1942                 src/mod/codecs/mod_codec2/Makefile
1943                 src/mod/codecs/mod_com_g729/Makefile
1944                 src/mod/codecs/mod_dahdi_codec/Makefile
1945                 src/mod/codecs/mod_g723_1/Makefile
1946                 src/mod/codecs/mod_g729/Makefile
1947                 src/mod/codecs/mod_h26x/Makefile
1948                 src/mod/codecs/mod_ilbc/Makefile
1949                 src/mod/codecs/mod_isac/Makefile
1950                 src/mod/codecs/mod_mp4v/Makefile
1951                 src/mod/codecs/mod_opus/Makefile
1952                 src/mod/codecs/mod_openh264/Makefile
1953                 src/mod/codecs/mod_sangoma_codec/Makefile
1954                 src/mod/codecs/mod_silk/Makefile
1955                 src/mod/codecs/mod_siren/Makefile
1956                 src/mod/codecs/mod_skel_codec/Makefile
1957                 src/mod/codecs/mod_theora/Makefile
1958                 src/mod/databases/mod_mariadb/Makefile
1959                 src/mod/databases/mod_pgsql/Makefile
1960                 src/mod/dialplans/mod_dialplan_asterisk/Makefile
1961                 src/mod/dialplans/mod_dialplan_directory/Makefile
1962                 src/mod/dialplans/mod_dialplan_xml/Makefile
1963                 src/mod/directories/mod_ldap/Makefile
1964                 src/mod/endpoints/mod_alsa/Makefile
1965                 src/mod/endpoints/mod_dingaling/Makefile
1966                 src/mod/endpoints/mod_gsmopen/Makefile
1967                 src/mod/endpoints/mod_h323/Makefile
1968                 src/mod/endpoints/mod_khomp/Makefile
1969                 src/mod/endpoints/mod_loopback/Makefile
1970                 src/mod/endpoints/mod_opal/Makefile
1971                 src/mod/endpoints/mod_portaudio/Makefile
1972                 src/mod/endpoints/mod_reference/Makefile
1973                 src/mod/endpoints/mod_rtmp/Makefile
1974                 src/mod/endpoints/mod_skinny/Makefile
1975                 src/mod/endpoints/mod_sofia/Makefile
1976                 src/mod/endpoints/mod_unicall/Makefile
1977                 src/mod/endpoints/mod_rtc/Makefile
1978                 src/mod/endpoints/mod_verto/Makefile
1979                 src/mod/event_handlers/mod_amqp/Makefile
1980                 src/mod/event_handlers/mod_cdr_csv/Makefile
1981                 src/mod/event_handlers/mod_cdr_mongodb/Makefile
1982                 src/mod/event_handlers/mod_cdr_pg_csv/Makefile
1983                 src/mod/event_handlers/mod_cdr_sqlite/Makefile
1984                 src/mod/event_handlers/mod_erlang_event/Makefile
1985                 src/mod/event_handlers/mod_event_multicast/Makefile
1986                 src/mod/event_handlers/mod_event_socket/Makefile
1987                 src/mod/event_handlers/mod_event_test/Makefile
1988                 src/mod/event_handlers/mod_fail2ban/Makefile
1989                 src/mod/event_handlers/mod_format_cdr/Makefile
1990                 src/mod/event_handlers/mod_json_cdr/Makefile
1991                 src/mod/event_handlers/mod_kazoo/Makefile
1992                 src/mod/event_handlers/mod_radius_cdr/Makefile
1993                 src/mod/event_handlers/mod_odbc_cdr/Makefile
1994                 src/mod/event_handlers/mod_rayo/Makefile
1995                 src/mod/event_handlers/mod_smpp/Makefile
1996                 src/mod/event_handlers/mod_snmp/Makefile
1997                 src/mod/event_handlers/mod_event_zmq/Makefile
1998                 src/mod/formats/mod_imagick/Makefile
1999                 src/mod/formats/mod_local_stream/Makefile
2000                 src/mod/formats/mod_native_file/Makefile
2001                 src/mod/formats/mod_opusfile/Makefile
2002                 src/mod/formats/mod_png/Makefile
2003                 src/mod/formats/mod_shell_stream/Makefile
2004                 src/mod/formats/mod_shout/Makefile
2005                 src/mod/formats/mod_sndfile/Makefile
2006                 src/mod/formats/mod_ssml/Makefile
2007                 src/mod/formats/mod_tone_stream/Makefile
2008                 src/mod/formats/mod_vlc/Makefile
2009                 src/mod/formats/mod_portaudio_stream/Makefile
2010                 src/mod/languages/mod_java/Makefile
2011                 src/mod/languages/mod_lua/Makefile
2012                 src/mod/languages/mod_managed/Makefile
2013                 src/mod/languages/mod_perl/Makefile
2014                 src/mod/languages/mod_python/Makefile
2015                 src/mod/languages/mod_v8/Makefile
2016                 src/mod/languages/mod_yaml/Makefile
2017                 src/mod/languages/mod_basic/Makefile
2018                 src/mod/loggers/mod_console/Makefile
2019                 src/mod/loggers/mod_graylog2/Makefile
2020                 src/mod/loggers/mod_logfile/Makefile
2021                 src/mod/loggers/mod_syslog/Makefile
2022                 src/mod/loggers/mod_raven/Makefile
2023                 src/mod/say/mod_say_de/Makefile
2024                 src/mod/say/mod_say_en/Makefile
2025                 src/mod/say/mod_say_es/Makefile
2026                 src/mod/say/mod_say_es_ar/Makefile
2027                 src/mod/say/mod_say_fa/Makefile
2028                 src/mod/say/mod_say_fr/Makefile
2029                 src/mod/say/mod_say_he/Makefile
2030                 src/mod/say/mod_say_hr/Makefile
2031                 src/mod/say/mod_say_hu/Makefile
2032                 src/mod/say/mod_say_it/Makefile
2033                 src/mod/say/mod_say_ja/Makefile
2034                 src/mod/say/mod_say_nl/Makefile
2035                 src/mod/say/mod_say_pl/Makefile
2036                 src/mod/say/mod_say_pt/Makefile
2037                 src/mod/say/mod_say_ru/Makefile
2038                 src/mod/say/mod_say_sv/Makefile
2039                 src/mod/say/mod_say_th/Makefile
2040                 src/mod/say/mod_say_zh/Makefile
2041                 src/mod/timers/mod_posix_timer/Makefile
2042                 src/mod/timers/mod_timerfd/Makefile
2043                 src/mod/xml_int/mod_xml_cdr/Makefile
2044                 src/mod/xml_int/mod_xml_curl/Makefile
2045                 src/mod/xml_int/mod_xml_ldap/Makefile
2046                 src/mod/xml_int/mod_xml_radius/Makefile
2047                 src/mod/xml_int/mod_xml_rpc/Makefile
2048                 src/mod/xml_int/mod_xml_scgi/Makefile
2049                 src/mod/applications/mod_av/Makefile
2050                 src/mod/applications/mod_video_filter/Makefile
2051                 src/include/switch_am_config.h
2052                 build/getsounds.sh
2053                 build/getlib.sh
2054                 build/getg729.sh
2055                 build/freeswitch.pc
2056                 build/standalone_module/freeswitch.pc
2057                 build/modmake.rules
2058                 libs/esl/Makefile
2059                 libs/esl/perl/Makefile
2060                 libs/esl/php/Makefile
2061                 libs/xmlrpc-c/include/xmlrpc-c/config.h
2062                 libs/xmlrpc-c/xmlrpc_config.h
2063                 libs/xmlrpc-c/config.mk
2064                 libs/xmlrpc-c/srcdir.mk
2065                 libs/xmlrpc-c/stamp-h
2066                 scripts/gentls_cert])
2067
2068 AM_CONDITIONAL(ISLINUX, [test `uname -s` = Linux])
2069 AM_CONDITIONAL(ISMAC, [test `uname -s` = Darwin])
2070 AM_CONDITIONAL(ISFREEBSD, [test `uname -s` = FreeBSD])
2071 AM_CONDITIONAL(IS64BITLINUX, [test `uname -m` = x86_64])
2072
2073 AM_CONDITIONAL(HAVE_G723_1, [ test -d ${switch_srcdir}/libs/libg723_1 ])
2074 AM_CONDITIONAL(HAVE_G729, [ test -d ${switch_srcdir}/libs/libg729 ])
2075
2076 #some vars to sub into the Makefile.am's
2077 #LIBS+=> core.log || error="yes";if test -n "$(VERBOSE)" -o "$$error" = "yes";then cat core.log;fi;if test "$$error" = "yes";then exit 1;fi
2078 LIBTOOL='$(SHELL) $(switch_builddir)/libtool'
2079 TOUCH_TARGET='if test -f "$@";then touch "$@";fi;'
2080 CONF_MODULES='$$(grep -v "\#" $(switch_builddir)/modules.conf | sed "s/|.*//" | sed -e "s|^.*/||" | sort | uniq )'
2081 CONF_DISABLED_MODULES='$$(grep "\#" $(switch_builddir)/modules.conf | grep -v "\#\#" | sed "s/|.*//" | sed "s/\#/\#\//"| sed -e "s|^.*/||" | sort | uniq )'
2082 OUR_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-all ; done )"; echo $$mods )'
2083 OUR_CLEAN_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-clean ; done )"; echo $$mods )'
2084 OUR_INSTALL_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-install ; done)"; echo $$mods )'
2085 OUR_UNINSTALL_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-uninstall ; done)"; echo $$mods )'
2086 OUR_TEST_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-print_tests ; done )"; echo $$mods )'
2087 OUR_CHECK_MODS='$$(if test -z "$(MODULES)" ; then tmp_mods="$(CONF_MODULES)"; else tmp_mods="$(MODULES)" ; fi ; mods="$$(for i in $$tmp_mods ; do echo $$i-check ; done )"; echo $$mods )'
2088 OUR_DISABLED_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)"; mods="$$(for i in $$tmp_mods ; do echo $$i-all ; done )"; echo $$mods )'
2089 OUR_DISABLED_CLEAN_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)";  mods="$$(for i in $$tmp_mods ; do echo $$i-clean ; done )"; echo $$mods )'
2090 OUR_DISABLED_INSTALL_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)"; mods="$$(for i in $$tmp_mods ; do echo $$i-install ; done)"; echo $$mods )'
2091 OUR_DISABLED_UNINSTALL_MODS='$$(tmp_mods="$(CONF_DISABLED_MODULES)"; mods="$$(for i in $$tmp_mods ; do echo $$i-uninstall ; done)"; echo $$mods )'
2092
2093 #AM_MAKEFLAGS='"OUR_MODULES=$(OUR_MODS)" "OUR_CLEAN_MODULES=$(OUR_CLEAN_MODS)" "OUR_INSTALL_MODULES=$(OUR_INSTALL_MODS)" "OUR_UNINSTALL_MODULES=$(OUR_UNINSTALL_MODS)" "OUR_DISABLED_MODULES=$(OUR_DISABLED_MODS)" "OUR_DISABLED_CLEAN_MODULES=$(OUR_DISABLED_CLEAN_MODS)" "OUR_DISABLED_INSTALL_MODULES=$(OUR_DISABLED_INSTALL_MODS)" "OUR_DISABLED_UNINSTALL_MODULES=$(OUR_DISABLED_UNINSTALL_MODS)" `test -n "$(VERBOSE)" || echo -s`'
2094 #AM_MAKEFLAGS='`test -n "$(VERBOSE)" || echo -s`'
2095 AC_SUBST(LIBTOOL)
2096 AC_SUBST(TOUCH_TARGET)
2097 AC_SUBST(CONF_DISABLED_MODULES)
2098 AC_SUBST(CONF_MODULES)
2099
2100 AC_SUBST(OUR_MODS)
2101 AC_SUBST(OUR_CLEAN_MODS)
2102 AC_SUBST(OUR_TEST_MODS)
2103 AC_SUBST(OUR_CHECK_MODS)
2104 AC_SUBST(OUR_INSTALL_MODS)
2105 AC_SUBST(OUR_UNINSTALL_MODS)
2106 AC_SUBST(OUR_DISABLED_MODS)
2107 AC_SUBST(OUR_DISABLED_CLEAN_MODS)
2108 AC_SUBST(OUR_DISABLED_INSTALL_MODS)
2109 AC_SUBST(OUR_DISABLED_UNINSTALL_MODS)
2110 AC_SUBST(AM_MAKEFLAGS)
2111
2112 ac_configure_args="$ac_configure_args --with-modinstdir=${modulesdir} CONFIGURE_CFLAGS='$CFLAGS $CPPFLAGS' CONFIGURE_CXXFLAGS='$CXXFLAGS $CPPFLAGS' CONFIGURE_LDFLAGS='$LDFLAGS' "
2113
2114 #       --prefix='$prefix' --exec_prefix='$exec_prefix' --libdir='$libdir' --libexecdir='$libexecdir' --bindir='$bindir' --sbindir='$sbindir' \
2115 #       --localstatedir='$localstatedir' --datadir='$datadir'"
2116
2117 # Run configure in all the subdirs
2118 AC_CONFIG_SUBDIRS([libs/srtp])
2119 if test "$use_system_apr" != "yes"; then
2120    AC_CONFIG_SUBDIRS([libs/apr])
2121 fi
2122 if test "$use_system_aprutil" != "yes"; then
2123    AC_CONFIG_SUBDIRS([libs/apr-util])
2124 fi
2125 AC_CONFIG_SUBDIRS([libs/iksemel])
2126 AC_CONFIG_SUBDIRS([libs/libdingaling])
2127 AC_CONFIG_SUBDIRS([libs/unimrcp])
2128 if test "x${enable_zrtp}" = "xyes"; then
2129    AC_CONFIG_SUBDIRS([libs/libzrtp])
2130 fi
2131
2132 case $host in
2133    *-openbsd*|*-netbsd*)
2134        # libtool won't link static libs against shared ones on NetBSD/OpenBSD unless we tell it not to be stupid
2135        AC_CONFIG_COMMANDS([hacklibtool], [cp libtool libtool.orig  && sed -e "s/deplibs_check_method=.*/deplibs_check_method=pass_all/g" libtool.orig > libtool])
2136        ;;
2137 esac
2138
2139
2140 AC_OUTPUT
2141
2142 ##
2143 ## Configuration summary
2144 ##
2145
2146 echo
2147 echo "-------------------------- FreeSWITCH configuration --------------------------"
2148 echo ""
2149 echo "  Locations:"
2150 echo ""
2151 echo "      prefix:          ${prefix}"
2152 echo "      exec_prefix:     ${exec_prefix}"
2153 echo "      bindir:          ${bindir}"
2154 echo "      confdir:         ${confdir}"
2155 echo "      libdir:          ${libdir}"
2156 echo "      datadir:         ${datadir}"
2157 echo "      localstatedir:   ${localstatedir}"
2158 echo "      includedir:      ${includedir}"
2159 echo ""
2160 echo "      certsdir:        ${certsdir}"
2161 echo "      dbdir:           ${dbdir}"
2162 echo "      grammardir:      ${grammardir}"
2163 echo "      htdocsdir:       ${htdocsdir}"
2164 echo "      fontsdir:        ${fontsdir}"
2165 echo "      logfiledir:      ${logfiledir}"
2166 echo "      modulesdir:      ${modulesdir}"
2167 echo "      pkgconfigdir:    ${pkgconfigdir}"
2168 echo "      recordingsdir:   ${recordingsdir}"
2169 echo "      imagesdir:       ${imagesdir}"
2170 echo "      runtimedir:      ${runtimedir}"
2171 echo "      scriptdir:       ${scriptdir}"
2172 echo "      soundsdir:       ${soundsdir}"
2173 echo "      storagedir:      ${storagedir}"
2174 echo "      cachedir:        ${cachedir}"
2175 echo ""
2176 echo "------------------------------------------------------------------------------"